qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include "mutators/events.qh"
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/debug.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/gamemodes/_mod.qh>
  23 #include <common/physics/player.qh>
  24 #include <common/stats.qh>
  25 #include <common/triggers/target/music.qh>
  26 #include <common/teams.qh>
  27 #include <common/wepent.qh>
  28
  29 #include <common/weapons/weapon/tuba.qh>
  30
  31 #include <common/vehicles/all.qh>
  32 #include <common/weapons/_all.qh>
  33 #include <common/viewloc.qh>
  34 #include <common/triggers/trigger/viewloc.qh>
  35 #include <common/minigames/cl_minigames.qh>
  36 #include <common/minigames/cl_minigames_hud.qh>
  37
  38 #include <lib/csqcmodel/cl_player.qh>
  39 #include <lib/csqcmodel/cl_model.qh>
  40 #include "csqcmodel_hooks.qh"
  41
  42 #include <lib/warpzone/client.qh>
  43 #include <lib/warpzone/common.qh>
  44
  45 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  46
  47 float autocvar_cl_viewmodel_scale;
  48
  49 bool autocvar_cl_bobmodel;
  50 float autocvar_cl_bobmodel_speed;
  51 float autocvar_cl_bobmodel_side;
  52 float autocvar_cl_bobmodel_up;
  53
  54 float autocvar_cl_followmodel;
  55 float autocvar_cl_followmodel_speed = 0.3;
  56 float autocvar_cl_followmodel_limit = 135;
  57 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  58 float autocvar_cl_followmodel_highpass = 0.05;
  59 float autocvar_cl_followmodel_lowpass = 0.03;
  60 bool autocvar_cl_followmodel_velocity_absolute;
  61
  62 float autocvar_cl_leanmodel;
  63 float autocvar_cl_leanmodel_speed = 0.3;
  64 float autocvar_cl_leanmodel_limit = 30;
  65 float autocvar_cl_leanmodel_highpass1 = 0.2;
  66 float autocvar_cl_leanmodel_highpass = 0.2;
  67 float autocvar_cl_leanmodel_lowpass = 0.05;
  68
  69 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  70
  71 #define lowpass(value, frac, ref_store, ret) \
  72         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  73
  74 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  75 { \
  76         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  77         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  78 } MACRO_END
  79
  80 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  81 { \
  82         float __f = 0; lowpass(value, frac, ref_store, __f); \
  83         ret = (value) - __f; \
  84 } MACRO_END
  85
  86 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  87 { \
  88         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  89         ret = (value) - __f; \
  90 } MACRO_END
  91
  92 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  93 { \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 } MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99 { \
 100         highpass(value.x, frac, ref_store.x, ref_out.x); \
 101         highpass(value.y, frac, ref_store.y, ref_out.y); \
 102 } MACRO_END
 103
 104 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 105 { \
 106         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 107         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 108 } MACRO_END
 109
 110 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 113         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 114         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 118 { \
 119         highpass(value.x, frac, ref_store.x, ref_out.x); \
 120         highpass(value.y, frac, ref_store.y, ref_out.y); \
 121         highpass(value.z, frac, ref_store.z, ref_out.z); \
 122 } MACRO_END
 123
 124 void calc_followmodel_ofs(entity view)
 125 {
 126         if(cl_followmodel_time == time)
 127                 return; // cl_followmodel_ofs already calculated for this frame
 128
 129         float frac;
 130         vector gunorg = '0 0 0';
 131         static vector vel_average;
 132         static vector gunorg_adjustment_highpass;
 133         static vector gunorg_adjustment_lowpass;
 134
 135         vector vel;
 136         if (autocvar_cl_followmodel_velocity_absolute)
 137                 vel = view.velocity;
 138         else
 139         {
 140                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 141                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 142                 vel.x = view.velocity * forward;
 143                 vel.y = view.velocity * right * -1;
 144                 vel.z = view.velocity * up;
 145         }
 146
 147         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 148         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 149         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 150
 151         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 152         lowpass3(vel, frac, vel_average, gunorg);
 153
 154         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 155
 156         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 157         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 158         frac = avg_factor(autocvar_cl_followmodel_highpass);
 159         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 160         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 161         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 162
 163         if (autocvar_cl_followmodel_velocity_absolute)
 164         {
 165                 vector fixed_gunorg;
 166                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 167                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 168                 fixed_gunorg.x = gunorg * forward;
 169                 fixed_gunorg.y = gunorg * right * -1;
 170                 fixed_gunorg.z = gunorg * up;
 171                 gunorg = fixed_gunorg;
 172         }
 173
 174         cl_followmodel_ofs = gunorg;
 175         cl_followmodel_time = time;
 176 }
 177
 178 vector leanmodel_ofs(entity view)
 179 {
 180         float frac;
 181         vector gunangles = '0 0 0';
 182         static vector gunangles_prev = '0 0 0';
 183         static vector gunangles_highpass = '0 0 0';
 184         static vector gunangles_adjustment_highpass;
 185         static vector gunangles_adjustment_lowpass;
 186
 187         if (view.csqcmodel_teleported)
 188                 gunangles_prev = view_angles;
 189
 190         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 191         gunangles_highpass += gunangles_prev;
 192         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 193         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 194         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 195         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 196         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 197         gunangles_prev = view_angles;
 198         gunangles_highpass -= gunangles_prev;
 199
 200         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 201         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 202
 203         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 204         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 205         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 206         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 207         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 208
 209         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 210
 211         return gunangles;
 212 }
 213
 214 vector bobmodel_ofs(entity view)
 215 {
 216         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 217         static bool oldonground;
 218         static float hitgroundtime;
 219         if (clonground)
 220         {
 221                 float f = time; // cl.movecmd[0].time
 222                 if (!oldonground)
 223                         hitgroundtime = f;
 224         }
 225         oldonground = clonground;
 226
 227         // calculate for swinging gun model
 228         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 229         vector gunorg = '0 0 0';
 230         static float bobmodel_scale = 0;
 231         static float time_ofs = 0; // makes the effect always restart in the same way
 232         if (clonground)
 233         {
 234                 if (time - hitgroundtime > 0.05)
 235                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 236         }
 237         else
 238                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 239
 240         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 241         if (bobmodel_scale && xyspeed)
 242         {
 243                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 244                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 245                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 246                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 247         }
 248         else
 249                 time_ofs = time;
 250
 251         return gunorg;
 252 }
 253
 254 void viewmodel_animate(entity this)
 255 {
 256         if (autocvar_chase_active) return;
 257         if (STAT(HEALTH) <= 0) return;
 258
 259         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 260
 261         if (autocvar_cl_followmodel)
 262         {
 263                 calc_followmodel_ofs(view);
 264                 this.origin += cl_followmodel_ofs;
 265         }
 266
 267         if (autocvar_cl_leanmodel)
 268                 this.angles += leanmodel_ofs(view);
 269
 270         // vertical view bobbing code
 271         // TODO: cl_bob
 272
 273         // horizontal view bobbing code
 274         // TODO: cl_bob2
 275
 276         // fall bobbing code
 277         // causes the view to swing down and back up when touching the ground
 278         // TODO: cl_bobfall
 279
 280         // gun model bobbing code
 281         if (autocvar_cl_bobmodel)
 282                 this.origin += bobmodel_ofs(view);
 283 }
 284
 285 .vector viewmodel_origin, viewmodel_angles;
 286 .float weapon_nextthink;
 287 .float weapon_eta_last;
 288 .float weapon_switchdelay;
 289
 290 .string name_last;
 291
 292 void viewmodel_draw(entity this)
 293 {
 294         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 295                 return;
 296         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 297         float a = this.alpha;
 298         static bool wasinvehicle;
 299         bool invehicle = player_localentnum > maxclients;
 300         if (invehicle) a = -1;
 301         else if (wasinvehicle) a = 1;
 302         wasinvehicle = invehicle;
 303         Weapon wep = this.activeweapon;
 304         int c = entcs_GetClientColors(current_player);
 305         vector g = weaponentity_glowmod(wep, NULL, c, this);
 306         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 307         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 308                 | EF_NODEPTHTEST)
 309                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 310         for (entity e = this; e; e = e.weaponchild)
 311         {
 312                 e.drawmask = mask;
 313                 e.alpha = a;
 314                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 315                 e.glowmod = g;
 316                 e.csqcmodel_effects = fx;
 317                 CSQCModel_Effects_Apply(e);
 318         }
 319         if(a >= 0)
 320         {
 321                 string name = wep.mdl;
 322                 string newname = wep.wr_viewmodel(wep, this);
 323                 if(newname)
 324                         name = newname;
 325                 bool swap = name != this.name_last;
 326                 // if (swap)
 327                 {
 328                         this.name_last = name;
 329                         CL_WeaponEntity_SetModel(this, name, swap);
 330                         this.viewmodel_origin = this.origin;
 331                         this.viewmodel_angles = this.angles;
 332                 }
 333                 anim_update(this);
 334                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 335                         anim_set(this, this.anim_idle, true, false, false);
 336         }
 337         float f = 0; // 0..1; 0: fully active
 338         float rate = STAT(WEAPONRATEFACTOR);
 339         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 340         if (eta <= 0) f = this.weapon_eta_last;
 341         else switch (this.state)
 342         {
 343                 case WS_RAISE:
 344                 {
 345                         f = eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_DROP:
 349                 {
 350                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 351                         break;
 352                 }
 353                 case WS_CLEAR:
 354                 {
 355                         f = 1;
 356                         break;
 357                 }
 358         }
 359         this.weapon_eta_last = f;
 360         this.origin = this.viewmodel_origin;
 361         this.angles = this.viewmodel_angles;
 362         this.angles_x = (-90 * f * f);
 363         viewmodel_animate(this);
 364         MUTATOR_CALLHOOK(DrawViewModel, this);
 365         setorigin(this, this.origin);
 366 }
 367
 368 STATIC_INIT(viewmodel) {
 369     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 370         viewmodels[slot] = new(viewmodel);
 371 }
 372
 373 void Porto_Draw(entity this);
 374 STATIC_INIT(Porto)
 375 {
 376         entity e = new_pure(porto);
 377         e.draw = Porto_Draw;
 378         IL_PUSH(g_drawables, e);
 379         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 380 }
 381
 382 const int polyline_length = 16;
 383 .vector polyline[polyline_length];
 384 void Porto_Draw(entity this)
 385 {
 386         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 387         {
 388                 entity wepent = viewmodels[slot];
 389
 390                 if (wepent.activeweapon != WEP_PORTO) continue;
 391                 if (spectatee_status) continue;
 392                 if (WEP_CVAR(porto, secondary)) continue;
 393                 if (intermission == 1) continue;
 394                 if (intermission == 2) continue;
 395                 if (STAT(HEALTH) <= 0) continue;
 396
 397                 vector pos = view_origin;
 398                 vector dir = view_forward;
 399                 if (wepent.angles_held_status)
 400                 {
 401                         makevectors(wepent.angles_held);
 402                         dir = v_forward;
 403                 }
 404
 405                 wepent.polyline[0] = pos;
 406
 407                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 408                 int n = 1 + 2;  // 2 lines == 3 points
 409                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 410                 {
 411                         traceline(pos, pos + 65536 * dir, true, this);
 412                         dir = reflect(dir, trace_plane_normal);
 413                         pos = trace_endpos;
 414                         wepent.polyline[++idx] = pos;
 415                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 416                         {
 417                                 n += 1;
 418                                 continue;
 419                         }
 420                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 421                         {
 422                                 n = max(2, idx);
 423                                 break;
 424                         }
 425                         // check size
 426                         {
 427                                 vector ang = vectoangles2(trace_plane_normal, dir);
 428                                 ang.x = -ang.x;
 429                                 makevectors(ang);
 430                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 431                                 {
 432                                         n = max(2, idx);
 433                                         break;
 434                                 }
 435                         }
 436                         portal_number += 1;
 437                         if (portal_number >= portal_max) break;
 438                         if (portal_number == 1) portal1_idx = idx;
 439                 }
 440                 for (int idx = 0; idx < n - 1; ++idx)
 441                 {
 442                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 443                         if (idx == 0) p -= view_up * 16;  // line from player
 444                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 445                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 446                 }
 447         }
 448 }
 449
 450 float drawtime;
 451 float avgspeed;
 452 vector GetCurrentFov(float fov)
 453 {
 454         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 455         float velocityzoom, curspeed;
 456         vector v;
 457
 458         zoomsensitivity = autocvar_cl_zoomsensitivity;
 459         zoomfactor = autocvar_cl_zoomfactor;
 460         if(zoomfactor < 1 || zoomfactor > 30)
 461                 zoomfactor = 2.5;
 462         zoomspeed = autocvar_cl_zoomspeed;
 463         if(zoomspeed >= 0)
 464         if(zoomspeed < 0.5 || zoomspeed > 16)
 465                         zoomspeed = 3.5;
 466
 467         zoomdir = button_zoom;
 468
 469         if(hud == HUD_NORMAL && !spectatee_status)
 470         {
 471                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 472                 {
 473                         entity wepent = viewmodels[slot];
 474                         if(wepent.switchweapon == wepent.activeweapon)
 475                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 476                                 zoomdir += button_attack2;
 477                 }
 478         }
 479         if(spectatee_status > 0 || isdemo())
 480         {
 481                 if(spectatorbutton_zoom)
 482                 {
 483                         if(zoomdir)
 484                                 zoomdir = 0;
 485                         else
 486                                 zoomdir = 1;
 487                 }
 488                 // fteqcc failed twice here already, don't optimize this
 489         }
 490
 491         if(zoomdir) { zoomin_effect = 0; }
 492
 493         if(camera_active)
 494         {
 495                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 496         }
 497         else if(autocvar_cl_spawnzoom && zoomin_effect)
 498         {
 499                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 500
 501                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 502                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 503                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 504         }
 505         else
 506         {
 507                 if(zoomspeed < 0) // instant zoom
 508                 {
 509                         if(zoomdir)
 510                                 current_viewzoom = 1 / zoomfactor;
 511                         else
 512                                 current_viewzoom = 1;
 513                 }
 514                 else
 515                 {
 516                         if(zoomdir)
 517                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 518                         else
 519                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 520                 }
 521         }
 522
 523         if(almost_equals(current_viewzoom, 1))
 524                 current_zoomfraction = 0;
 525         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 526                 current_zoomfraction = 1;
 527         else
 528                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 529
 530         if(zoomsensitivity < 1)
 531                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 532         else
 533                 setsensitivityscale(1);
 534
 535         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 536         {
 537                 if(intermission) { curspeed = 0; }
 538                 else
 539                 {
 540
 541                         makevectors(view_angles);
 542                         v = pmove_vel;
 543                         if(csqcplayer)
 544                                 v = csqcplayer.velocity;
 545
 546                         switch(autocvar_cl_velocityzoom_type)
 547                         {
 548                                 case 3: curspeed = max(0, v_forward * v); break;
 549                                 case 2: curspeed = (v_forward * v); break;
 550                                 case 1: default: curspeed = vlen(v); break;
 551                         }
 552                 }
 553
 554                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 555                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 556                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 557
 558                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 559         }
 560         else
 561                 velocityzoom = 1;
 562
 563         float frustumx, frustumy, fovx, fovy;
 564         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 565         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 566         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 567         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 568
 569         return '1 0 0' * fovx + '0 1 0' * fovy;
 570 }
 571
 572 vector GetViewLocationFOV(float fov)
 573 {
 574         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 575         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 576         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 577         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 578         return '1 0 0' * fovx + '0 1 0' * fovy;
 579 }
 580
 581 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 582 {
 583         float fovx, fovy;
 584         float width = (ov_worldmax.x - ov_worldmin.x);
 585         float height = (ov_worldmax.y - ov_worldmin.y);
 586         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 587         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 588         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 589         return '1 0 0' * fovx + '0 1 0' * fovy;
 590 }
 591
 592 // this function must match W_SetupShot!
 593 float zoomscript_caught;
 594
 595 vector wcross_origin;
 596 float wcross_scale_prev, wcross_alpha_prev;
 597 vector wcross_color_prev;
 598 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 599 vector wcross_color_goal_prev;
 600 float wcross_changedonetime;
 601
 602 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 603 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 604 float wcross_name_changestarttime, wcross_name_changedonetime;
 605 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 606
 607 float wcross_ring_prev;
 608
 609 entity trueaim;
 610 entity trueaim_rifle;
 611
 612 const float SHOTTYPE_HITTEAM = 1;
 613 const float SHOTTYPE_HITOBSTRUCTION = 2;
 614 const float SHOTTYPE_HITWORLD = 3;
 615 const float SHOTTYPE_HITENEMY = 4;
 616
 617 void TrueAim_Init()
 618 {
 619         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 620         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 621 }
 622
 623 float EnemyHitCheck()
 624 {
 625         float t, n;
 626         wcross_origin = project_3d_to_2d(trace_endpos);
 627         wcross_origin.z = 0;
 628         if(trace_ent)
 629                 n = trace_ent.entnum;
 630         else
 631                 n = trace_networkentity;
 632         if(n < 1)
 633                 return SHOTTYPE_HITWORLD;
 634         if(n > maxclients)
 635                 return SHOTTYPE_HITWORLD;
 636         t = entcs_GetTeam(n - 1);
 637         if(teamplay)
 638                 if(t == myteam)
 639                         return SHOTTYPE_HITTEAM;
 640         if(t == NUM_SPECTATOR)
 641                 return SHOTTYPE_HITWORLD;
 642         return SHOTTYPE_HITENEMY;
 643 }
 644
 645 float TrueAimCheck(entity wepent)
 646 {
 647         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 648         vector vecs, trueaimpoint, w_shotorg;
 649         vector mi, ma, dv;
 650         float shottype;
 651         entity ta;
 652         float mv;
 653
 654         mi = ma = '0 0 0';
 655         ta = trueaim;
 656         mv = MOVE_NOMONSTERS;
 657
 658         switch(wepent.activeweapon) // WEAPONTODO
 659         {
 660                 case WEP_TUBA: // no aim
 661                 case WEP_PORTO: // shoots from eye
 662                 case WEP_NEXBALL: // shoots from eye
 663                 case WEP_HOOK: // no trueaim
 664                 case WEP_MORTAR: // toss curve
 665                         return SHOTTYPE_HITWORLD;
 666                 case WEP_VORTEX:
 667                 case WEP_VAPORIZER:
 668                         mv = MOVE_NORMAL;
 669                         break;
 670                 case WEP_RIFLE:
 671                         ta = trueaim_rifle;
 672                         mv = MOVE_NORMAL;
 673                         if(zoomscript_caught)
 674                         {
 675                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 676                                 return EnemyHitCheck();
 677                         }
 678                         break;
 679                 case WEP_DEVASTATOR: // projectile has a size!
 680                         mi = '-3 -3 -3';
 681                         ma = '3 3 3';
 682                         break;
 683                 case WEP_FIREBALL: // projectile has a size!
 684                         mi = '-16 -16 -16';
 685                         ma = '16 16 16';
 686                         break;
 687                 case WEP_SEEKER: // projectile has a size!
 688                         mi = '-2 -2 -2';
 689                         ma = '2 2 2';
 690                         break;
 691                 case WEP_ELECTRO: // projectile has a size!
 692                         mi = '0 0 -3';
 693                         ma = '0 0 -3';
 694                         break;
 695         }
 696
 697         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 698
 699         vecs = decompressShotOrigin(STAT(SHOTORG));
 700
 701         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 702         trueaimpoint = trace_endpos;
 703
 704         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 705                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 706
 707         if(vecs.x > 0)
 708                 vecs.y = -vecs.y;
 709         else
 710                 vecs = '0 0 0';
 711
 712         dv = view_right * vecs.y + view_up * vecs.z;
 713         w_shotorg = traceorigin + dv;
 714
 715         // now move the vecs forward as much as requested if possible
 716         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 717         w_shotorg = trace_endpos - view_forward * nudge;
 718
 719         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 720         shottype = EnemyHitCheck();
 721         if(shottype != SHOTTYPE_HITWORLD)
 722                 return shottype;
 723
 724 #if 0
 725         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 726         // or rather, I know why, but see no fix
 727         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 728                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 729                 return SHOTTYPE_HITOBSTRUCTION;
 730 #endif
 731
 732         return SHOTTYPE_HITWORLD;
 733 }
 734
 735 void PostInit();
 736 void CSQC_Demo_Camera();
 737 float camera_mode;
 738 const float CAMERA_FREE = 1;
 739 const float CAMERA_CHASE = 2;
 740 float reticle_type;
 741 string NextFrameCommand;
 742
 743 vector freeze_org, freeze_ang;
 744 entity nightvision_noise, nightvision_noise2;
 745
 746 const float MAX_TIME_DIFF = 5;
 747 float pickup_crosshair_time, pickup_crosshair_size;
 748 float hitindication_crosshair_size;
 749 float use_vortex_chargepool;
 750
 751 float myhealth, myhealth_prev;
 752 float myhealth_flash;
 753
 754 float old_blurradius, old_bluralpha;
 755 float old_sharpen_intensity;
 756
 757 vector myhealth_gentlergb;
 758
 759 float contentavgalpha, liquidalpha_prev;
 760 vector liquidcolor_prev;
 761
 762 float eventchase_current_distance;
 763 float eventchase_running;
 764 bool WantEventchase(entity this)
 765 {
 766         if(autocvar_cl_orthoview)
 767                 return false;
 768         if(STAT(GAME_STOPPED) || intermission)
 769                 return true;
 770         if(this.viewloc)
 771                 return true;
 772         if(spectatee_status >= 0)
 773         {
 774                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 775                         return true;
 776                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 777                         return true;
 778                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 779                         return true;
 780                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 781                 {
 782                         if(autocvar_cl_eventchase_death == 2)
 783                         {
 784                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 785                                 if(this.velocity == '0 0 0' || eventchase_running)
 786                                         return true;
 787                         }
 788                         else return true;
 789                 }
 790         }
 791         return false;
 792 }
 793
 794 void HUD_Crosshair_Vehicle(entity this)
 795 {
 796         if(hud != HUD_BUMBLEBEE_GUN)
 797         {
 798                 Vehicle info = Vehicles_from(hud);
 799                 info.vr_crosshair(info, this);
 800         }
 801 }
 802
 803 vector damage_blurpostprocess, content_blurpostprocess;
 804
 805 float unaccounted_damage = 0;
 806 void UpdateDamage()
 807 {
 808         // accumulate damage with each stat update
 809         static float damage_total_prev = 0;
 810         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 811         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 812         damage_total_prev = damage_total;
 813
 814         static float damage_dealt_time_prev = 0;
 815         float damage_dealt_time = STAT(HIT_TIME);
 816         if (damage_dealt_time != damage_dealt_time_prev)
 817         {
 818                 unaccounted_damage += unaccounted_damage_new;
 819                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 820         }
 821         damage_dealt_time_prev = damage_dealt_time;
 822
 823         // prevent hitsound when switching spectatee
 824         static float spectatee_status_prev = 0;
 825         if (spectatee_status != spectatee_status_prev)
 826                 unaccounted_damage = 0;
 827         spectatee_status_prev = spectatee_status;
 828 }
 829
 830 void HitSound()
 831 {
 832         // varying sound pitch
 833
 834         bool have_arc = false;
 835         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 836         {
 837                 entity wepent = viewmodels[slot];
 838
 839                 if(wepent.activeweapon == WEP_ARC)
 840                         have_arc = true;
 841         }
 842
 843         static float hitsound_time_prev = 0;
 844         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 845         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 846         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 847         {
 848                 if (autocvar_cl_hitsound && unaccounted_damage)
 849                 {
 850                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 851                         float a = autocvar_cl_hitsound_max_pitch;
 852                         float b = autocvar_cl_hitsound_min_pitch;
 853                         float c = autocvar_cl_hitsound_nom_damage;
 854                         float d = unaccounted_damage;
 855                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 856
 857                         // if sound variation is disabled, set pitch_shift to 1
 858                         if (autocvar_cl_hitsound == 1)
 859                                 pitch_shift = 1;
 860
 861                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 862                         if (autocvar_cl_hitsound == 3)
 863                         {
 864                                 float mirror_value = (a-b)/2 + b;
 865                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 866                         }
 867
 868                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 869
 870                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 871                         // todo: normalize sound pressure levels? seems unnecessary
 872
 873                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 874                 }
 875                 unaccounted_damage = 0;
 876                 hitsound_time_prev = time;
 877         }
 878
 879         static float typehit_time_prev = 0;
 880         float typehit_time = STAT(TYPEHIT_TIME);
 881         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 882         {
 883                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 884                 typehit_time_prev = typehit_time;
 885         }
 886
 887         static float kill_time_prev = 0;
 888         float kill_time = STAT(KILL_TIME);
 889         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 890         {
 891                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 892                 kill_time_prev = kill_time;
 893         }
 894 }
 895
 896 vector crosshair_getcolor(entity this, float health_stat)
 897 {
 898         static float rainbow_last_flicker;
 899         static vector rainbow_prev_color;
 900         vector wcross_color = '0 0 0';
 901         switch(autocvar_crosshair_color_special)
 902         {
 903                 case 1: // crosshair_color_per_weapon
 904                 {
 905                         if(this != WEP_Null && hud == HUD_NORMAL)
 906                         {
 907                                 wcross_color = this.wpcolor;
 908                                 break;
 909                         }
 910                         else { goto normalcolor; }
 911                 }
 912
 913                 case 2: // crosshair_color_by_health
 914                 {
 915                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 916                         float hp = floor(v.x + 1);
 917
 918                         //x = red
 919                         //y = green
 920                         //z = blue
 921
 922                         wcross_color.z = 0;
 923
 924                         if(hp > 200)
 925                         {
 926                                 wcross_color.x = 0;
 927                                 wcross_color.y = 1;
 928                         }
 929                         else if(hp > 150)
 930                         {
 931                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 932                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 933                         }
 934                         else if(hp > 100)
 935                         {
 936                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 937                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 938                                 wcross_color.z = 1 - (hp-100)*0.02;
 939                         }
 940                         else if(hp > 50)
 941                         {
 942                                 wcross_color.x = 1;
 943                                 wcross_color.y = 1;
 944                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 945                         }
 946                         else if(hp > 20)
 947                         {
 948                                 wcross_color.x = 1;
 949                                 wcross_color.y = (hp-20)*90/27/100;
 950                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 951                         }
 952                         else
 953                         {
 954                                 wcross_color.x = 1;
 955                                 wcross_color.y = 0;
 956                         }
 957                         break;
 958                 }
 959
 960                 case 3: // crosshair_color_rainbow
 961                 {
 962                         if(time >= rainbow_last_flicker)
 963                         {
 964                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 965                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 966                         }
 967                         wcross_color = rainbow_prev_color;
 968                         break;
 969                 }
 970 LABEL(normalcolor)
 971                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 972         }
 973
 974         return wcross_color;
 975 }
 976
 977 void HUD_Crosshair(entity this)
 978 {
 979         float f, i, j;
 980         vector v;
 981         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 982                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 983                 !HUD_MinigameMenu_IsOpened() )
 984         {
 985                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 986                         return;
 987
 988                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 989                         return;
 990
 991                 if (hud != HUD_NORMAL)
 992                 {
 993                         HUD_Crosshair_Vehicle(this);
 994                         return;
 995                 }
 996
 997                 string wcross_style;
 998                 float wcross_alpha, wcross_resolution;
 999                 wcross_style = autocvar_crosshair;
1000                 if (wcross_style == "0")
1001                         return;
1002                 wcross_resolution = autocvar_crosshair_size;
1003                 if (wcross_resolution == 0)
1004                         return;
1005                 wcross_alpha = autocvar_crosshair_alpha;
1006                 if (wcross_alpha == 0)
1007                         return;
1008
1009                 // TrueAim check
1010                 float shottype;
1011
1012                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1013                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1014                         wcross_origin = viewloc_mousepos;
1015                 else
1016                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1017                 wcross_origin.z = 0;
1018                 if(autocvar_crosshair_hittest)
1019                 {
1020                         vector wcross_oldorigin;
1021                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1022                         wcross_oldorigin = wcross_origin;
1023                         shottype = TrueAimCheck(thiswep);
1024                         if(shottype == SHOTTYPE_HITWORLD)
1025                         {
1026                                 v = wcross_origin - wcross_oldorigin;
1027                                 v.x /= vid_conwidth;
1028                                 v.y /= vid_conheight;
1029                                 if(vdist(v, >, 0.01))
1030                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1031                         }
1032                         if(!autocvar_crosshair_hittest_showimpact)
1033                                 wcross_origin = wcross_oldorigin;
1034                 }
1035                 else
1036                         shottype = SHOTTYPE_HITWORLD;
1037
1038                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1039                 string wcross_name = "";
1040                 float wcross_scale, wcross_blur;
1041
1042         entity e = WEP_Null;
1043                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1044                 {
1045                         entity wepent = viewmodels[0]; // TODO: unhardcode
1046                         e = wepent.switchingweapon;
1047                         if(e)
1048                         {
1049                                 if(autocvar_crosshair_per_weapon)
1050                                 {
1051                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1052                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1053                                         //if (wcross_resolution == 0)
1054                                                 //return;
1055
1056                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1057                                         wcross_resolution *= e.w_crosshair_size;
1058                                         wcross_name = e.w_crosshair;
1059                                 }
1060                         }
1061                 }
1062
1063                 if(wcross_name == "")
1064                         wcross_name = strcat("gfx/crosshair", wcross_style);
1065
1066                 // MAIN CROSSHAIR COLOR DECISION
1067                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1068
1069                 if(autocvar_crosshair_effect_scalefade)
1070                 {
1071                         wcross_scale = wcross_resolution;
1072                         wcross_resolution = 1;
1073                 }
1074                 else
1075                 {
1076                         wcross_scale = 1;
1077                 }
1078
1079                 if(autocvar_crosshair_pickup)
1080                 {
1081                         float stat_pickup_time = STAT(LAST_PICKUP);
1082
1083                         if(pickup_crosshair_time < stat_pickup_time)
1084                         {
1085                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1086                                         pickup_crosshair_size = 1;
1087
1088                                 pickup_crosshair_time = stat_pickup_time;
1089                         }
1090
1091                         if(pickup_crosshair_size > 0)
1092                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1093                         else
1094                                 pickup_crosshair_size = 0;
1095
1096                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1097                 }
1098
1099                 // todo: make crosshair hit indication dependent on damage dealt
1100                 if(autocvar_crosshair_hitindication)
1101                 {
1102                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1103
1104                         if(unaccounted_damage)
1105                         {
1106                                 hitindication_crosshair_size = 1;
1107                         }
1108
1109                         if(hitindication_crosshair_size > 0)
1110                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1111                         else
1112                                 hitindication_crosshair_size = 0;
1113
1114                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1115                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1116                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1117                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1118                 }
1119
1120                 if(shottype == SHOTTYPE_HITENEMY)
1121                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1122                 if(shottype == SHOTTYPE_HITTEAM)
1123                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1124
1125                 f = fabs(autocvar_crosshair_effect_time);
1126                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1127                 {
1128                         wcross_changedonetime = time + f;
1129                 }
1130                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1131                 {
1132                         wcross_name_changestarttime = time;
1133                         wcross_name_changedonetime = time + f;
1134                         if(wcross_name_goal_prev_prev)
1135                                 strunzone(wcross_name_goal_prev_prev);
1136                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1137                         wcross_name_goal_prev = strzone(wcross_name);
1138                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1139                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1140                         wcross_resolution_goal_prev = wcross_resolution;
1141                 }
1142
1143                 wcross_scale_goal_prev = wcross_scale;
1144                 wcross_alpha_goal_prev = wcross_alpha;
1145                 wcross_color_goal_prev = wcross_color;
1146
1147                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1148                 {
1149                         wcross_blur = 1;
1150                         wcross_alpha *= 0.75;
1151                 }
1152                 else
1153                         wcross_blur = 0;
1154                 // *_prev is at time-frametime
1155                 // * is at wcross_changedonetime+f
1156                 // what do we have at time?
1157                 if(time < wcross_changedonetime)
1158                 {
1159                         f = frametime / (wcross_changedonetime - time + frametime);
1160                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1161                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1162                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1163                 }
1164
1165                 wcross_scale_prev = wcross_scale;
1166                 wcross_alpha_prev = wcross_alpha;
1167                 wcross_color_prev = wcross_color;
1168
1169                 MUTATOR_CALLHOOK(UpdateCrosshair);
1170
1171                 wcross_scale *= 1 - autocvar__menu_alpha;
1172                 wcross_alpha *= 1 - autocvar__menu_alpha;
1173                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1174
1175                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1176                 {
1177                         // crosshair rings for weapon stats
1178                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1179                         {
1180                                 // declarations and stats
1181                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1182                                 string ring_image = string_null, ring_inner_image = string_null;
1183                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1184
1185                                 ring_scale = autocvar_crosshair_ring_size;
1186
1187                                 float weapon_clipload, weapon_clipsize;
1188                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1189                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1190
1191                                 float vortex_charge, vortex_chargepool;
1192                                 vortex_charge = STAT(VORTEX_CHARGE);
1193                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1194
1195                                 float arc_heat = STAT(ARC_HEAT);
1196
1197                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1198                                         vortex_charge_movingavg = vortex_charge;
1199
1200                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1201
1202                                 // handle the values
1203                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1204                                 {
1205                                         if (vortex_chargepool || use_vortex_chargepool) {
1206                                                 use_vortex_chargepool = 1;
1207                                                 ring_inner_value = vortex_chargepool;
1208                                         } else {
1209                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1210                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1211                                         }
1212
1213                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1214                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1215                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1216
1217                                         // draw the outer ring to show the current charge of the weapon
1218                                         ring_value = vortex_charge;
1219                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1220                                         ring_rgb = wcross_color;
1221                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1222                                 }
1223                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1224                                 {
1225                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1226                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1227                                         ring_rgb = wcross_color;
1228                                         ring_image = "gfx/crosshair_ring.tga";
1229                                 }
1230                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1231                                 {
1232                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1233                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1234                                         ring_rgb = wcross_color;
1235                                         ring_image = "gfx/crosshair_ring.tga";
1236                                 }
1237                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1238                                 {
1239                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1240                                         ring_scale = autocvar_crosshair_ring_reload_size;
1241                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1242                                         ring_rgb = wcross_color;
1243
1244                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1245                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1246                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1247                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1248                                         else
1249                                                 ring_image = "gfx/crosshair_ring.tga";
1250                                 }
1251                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1252                                 {
1253                                         ring_value = arc_heat;
1254                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1255                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1256                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1257                                         ring_image = "gfx/crosshair_ring.tga";
1258                                 }
1259
1260                                 // if in weapon switch animation, fade ring out/in
1261                                 if(autocvar_crosshair_effect_time > 0)
1262                                 {
1263                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1264                                         if (f >= 1)
1265                                         {
1266                                                 wcross_ring_prev = ((ring_image) ? true : false);
1267                                         }
1268
1269                                         if(wcross_ring_prev)
1270                                         {
1271                                                 if(f < 1)
1272                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1273                                         }
1274                                         else
1275                                         {
1276                                                 if(f < 1)
1277                                                         ring_alpha *= bound(0, f, 1);
1278                                         }
1279                                 }
1280
1281                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1282                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1283
1284                                 if (ring_value)
1285                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1286                         }
1287
1288 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1289                         MACRO_BEGIN { \
1290                                 if(wcross_blur > 0) \
1291                                 { \
1292                                         for(i = -2; i <= 2; ++i) \
1293                                         for(j = -2; j <= 2; ++j) \
1294                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1295                                 } \
1296                                 else \
1297                                 { \
1298                                         M(0,0,sz,wcross_name,wcross_alpha); \
1299                                 } \
1300                         } MACRO_END
1301
1302 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1303                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1304
1305 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1306                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1307
1308                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1309                         {
1310                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1311                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1312                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1313                                 f = 1 - f;
1314                         }
1315                         else
1316                         {
1317                                 f = 1;
1318                         }
1319                         wcross_name_alpha_goal_prev = f;
1320
1321                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1322                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1323
1324                         if(autocvar_crosshair_dot)
1325                         {
1326                                 vector wcross_color_old;
1327                                 wcross_color_old = wcross_color;
1328
1329                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1330                                         wcross_color = stov(autocvar_crosshair_dot_color);
1331
1332                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1333                                 // FIXME why don't we use wcross_alpha here?
1334                                 wcross_color = wcross_color_old;
1335                         }
1336                 }
1337         }
1338         else
1339         {
1340                 wcross_scale_prev = 0;
1341                 wcross_alpha_prev = 0;
1342                 wcross_scale_goal_prev = 0;
1343                 wcross_alpha_goal_prev = 0;
1344                 wcross_changedonetime = 0;
1345                 if(wcross_name_goal_prev)
1346                         strunzone(wcross_name_goal_prev);
1347                 wcross_name_goal_prev = string_null;
1348                 if(wcross_name_goal_prev_prev)
1349                         strunzone(wcross_name_goal_prev_prev);
1350                 wcross_name_goal_prev_prev = string_null;
1351                 wcross_name_changestarttime = 0;
1352                 wcross_name_changedonetime = 0;
1353                 wcross_name_alpha_goal_prev = 0;
1354                 wcross_name_alpha_goal_prev_prev = 0;
1355                 wcross_resolution_goal_prev = 0;
1356                 wcross_resolution_goal_prev_prev = 0;
1357         }
1358 }
1359
1360 const int MAX_SPECIALCOMMAND = 15;
1361 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1362 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1363 const float SPECIALCOMMAND_SPEED = 150;
1364 const float SPECIALCOMMAND_TURNSPEED = 2;
1365 const float SPECIALCOMMAND_SIZE = 0.025;
1366 const float SPECIALCOMMAND_CHANCE = 0.35;
1367 float sc_spawntime, sc_changetime;
1368 vector sc_color = '1 1 1';
1369 void SpecialCommand()
1370 {
1371         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1372                 return;
1373
1374         if(time >= sc_changetime)
1375         {
1376                 sc_changetime = time + 1;
1377                 sc_color = randomvec() * 1.5;
1378                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1379                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1380                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1381         }
1382         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1383
1384         if(!precache_pic("gfx/smile"))
1385                 return; // damn party poopers
1386
1387         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1388         {
1389                 vector slot = specialcommand_slots[j];
1390                 if(slot.y)
1391                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1392                 if(slot.z)
1393                         slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1394                 if(slot.y >= vid_conheight)
1395                         slot = '0 0 0';
1396
1397                 if(slot == '0 0 0')
1398                 {
1399                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1400                         {
1401                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1402                                 slot.y = 1; // start it off 0 so we can use it
1403                                 slot.z = random();
1404                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1405                                 vector newcolor = randomvec() * 2;
1406                                 newcolor.x = bound(0.4, newcolor.x, 1);
1407                                 newcolor.y = bound(0.4, newcolor.y, 1);
1408                                 newcolor.z = bound(0.4, newcolor.z, 1);
1409                                 specialcommand_colors[j] = newcolor;
1410                         }
1411                 }
1412                 else
1413                 {
1414                         vector splash_size = '0 0 0';
1415                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1416                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1417                         drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1418                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1419                 }
1420
1421                 specialcommand_slots[j] = slot;
1422         }
1423 }
1424
1425 void HUD_Draw(entity this)
1426 {
1427         // if we don't know gametype and scores yet avoid drawing the scoreboard
1428         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1429         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1430         // cl_deathscoreboard would show the scoreboard and so on
1431         if(!gametype)
1432                 return;
1433
1434         Hud_Dynamic_Frame();
1435
1436         if(!intermission)
1437         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1438         {
1439                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1440         }
1441         else if(STAT(FROZEN))
1442         {
1443                 vector col = '0.25 0.90 1';
1444                 if(STAT(REVIVE_PROGRESS))
1445                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1446                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1447         }
1448
1449         HUD_Scale_Enable();
1450         if(!intermission)
1451         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1452         {
1453                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1454                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1455                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1456         }
1457         else if(STAT(CAPTURE_PROGRESS))
1458         {
1459                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1460                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1461         }
1462         else if(STAT(REVIVE_PROGRESS))
1463         {
1464                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1465                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1466         }
1467         HUD_Scale_Disable();
1468
1469         if(autocvar_r_letterbox == 0)
1470                 if(autocvar_viewsize < 120)
1471                 {
1472                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1473                                 Accuracy_LoadLevels();
1474
1475                         HUD_Main();
1476                         HUD_Scale_Disable();
1477                 }
1478
1479         // crosshair goes VERY LAST
1480         SpecialCommand();
1481         UpdateDamage();
1482         HUD_Crosshair(this);
1483         HitSound();
1484 }
1485
1486 void ViewLocation_Mouse()
1487 {
1488         if(spectatee_status)
1489                 return; // don't draw it as spectator!
1490
1491         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1492         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1493         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1494
1495         //float cursor_alpha = 1 - autocvar__menu_alpha;
1496         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1497 }
1498
1499 bool ov_enabled;
1500 float oldr_nearclip;
1501 float oldr_farclip_base;
1502 float oldr_farclip_world;
1503 float oldr_novis;
1504 float oldr_useportalculling;
1505 float oldr_useinfinitefarclip;
1506
1507 void cl_notice_run();
1508
1509 float prev_myteam;
1510 int lasthud;
1511 float vh_notice_time;
1512 void WaypointSprite_Load();
1513 void CSQC_UpdateView(entity this, float w, float h)
1514 {
1515     TC(int, w); TC(int, h);
1516         entity e;
1517         float fov;
1518         float f;
1519         vector vf_size, vf_min;
1520         float a;
1521
1522         execute_next_frame();
1523
1524         ++framecount;
1525
1526         stats_get();
1527         hud = STAT(HUD);
1528
1529         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1530                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1531
1532         lasthud = hud;
1533
1534         HUD_Scale_Disable();
1535
1536         if(autocvar__hud_showbinds_reload) // menu can set this one
1537         {
1538                 db_close(binddb);
1539                 binddb = db_create();
1540                 cvar_set("_hud_showbinds_reload", "0");
1541         }
1542
1543         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1544                 view_quality = getproperty(VF_MINFPS_QUALITY);
1545         else
1546                 view_quality = 1;
1547
1548         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1549         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1550
1551         vf_size = getpropertyvec(VF_SIZE);
1552         vf_min = getpropertyvec(VF_MIN);
1553         vid_width = vf_size.x;
1554         vid_height = vf_size.y;
1555
1556         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1557         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1558
1559         WaypointSprite_Load();
1560
1561         CSQCPlayer_SetCamera();
1562
1563         if(player_localentnum <= maxclients) // is it a client?
1564                 current_player = player_localentnum - 1;
1565         else // then player_localentnum is the vehicle I'm driving
1566                 current_player = player_localnum;
1567         myteam = entcs_GetTeam(current_player);
1568
1569         if(myteam != prev_myteam)
1570         {
1571                 myteamcolors = colormapPaletteColor(myteam, 1);
1572                 FOREACH(hud_panels, true, it.update_time = time);
1573                 prev_myteam = myteam;
1574         }
1575
1576         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1577
1578         float is_dead = (STAT(HEALTH) <= 0);
1579
1580         // FIXME do we need this hack?
1581         if(isdemo())
1582         {
1583                 // in demos, input_buttons do not work
1584                 button_zoom = (autocvar__togglezoom == "-");
1585         }
1586         else if(button_zoom
1587                 && autocvar_cl_unpress_zoom_on_death
1588                 && (spectatee_status >= 0)
1589                 && (is_dead || intermission))
1590         {
1591                 // no zoom while dead or in intermission please
1592                 localcmd("-zoom\n");
1593                 button_zoom = false;
1594         }
1595
1596         // abused multiple places below
1597         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1598         if(!local_player)
1599                 local_player = this; // fall back!
1600
1601         // event chase camera
1602         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1603         {
1604                 if(STAT(CAMERA_SPECTATOR))
1605                 {
1606                         if(spectatee_status > 0)
1607                         {
1608                                 if(!autocvar_chase_active)
1609                                 {
1610                                         cvar_set("chase_active", "-2");
1611                                         goto skip_eventchase_death;
1612                                 }
1613                         }
1614                         else if(autocvar_chase_active == -2)
1615                                 cvar_set("chase_active", "0");
1616
1617                         if(autocvar_chase_active == -2)
1618                                 goto skip_eventchase_death;
1619                 }
1620                 else if(autocvar_chase_active == -2)
1621                         cvar_set("chase_active", "0");
1622
1623                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1624
1625                 float vehicle_viewdist = 0;
1626                 vector vehicle_viewofs = '0 0 0';
1627
1628                 if(vehicle_chase)
1629                 {
1630                         if(hud != HUD_BUMBLEBEE_GUN)
1631                         {
1632                                 Vehicle info = Vehicles_from(hud);
1633                                 vehicle_viewdist = info.height;
1634                                 vehicle_viewofs = info.view_ofs;
1635                         }
1636                 }
1637
1638                 if(WantEventchase(this))
1639                 {
1640                         vector current_view_origin_override = '0 0 0';
1641                         vector view_offset_override = '0 0 0';
1642                         float chase_distance_override = 0;
1643                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1644                         if(custom_eventchase)
1645                         {
1646                                 current_view_origin_override = M_ARGV(0, vector);
1647                                 view_offset_override = M_ARGV(1, vector);
1648                                 chase_distance_override = M_ARGV(0, float);
1649                         }
1650                         eventchase_running = true;
1651
1652                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1653                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1654                         if (custom_eventchase)
1655                                 current_view_origin = current_view_origin_override;
1656
1657                         // detect maximum viewoffset and use it
1658                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1659                         if(vehicle_chase)
1660                         {
1661                                 if(vehicle_viewofs)
1662                                         view_offset = vehicle_viewofs;
1663                                 else
1664                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1665                         }
1666                         if (custom_eventchase)
1667                                 view_offset = view_offset_override;
1668
1669                         if(view_offset)
1670                         {
1671                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1672                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1673                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1674                         }
1675
1676                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1677                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1678                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1679                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1680
1681                         // make the camera smooth back
1682                         float chase_distance = autocvar_cl_eventchase_distance;
1683                         if(vehicle_chase)
1684                         {
1685                                 if(vehicle_viewofs)
1686                                         chase_distance = vehicle_viewdist;
1687                                 else
1688                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1689                         }
1690                         if (custom_eventchase)
1691                                 chase_distance = chase_distance_override;
1692
1693                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1694                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1695                         else if(eventchase_current_distance != chase_distance)
1696                                 eventchase_current_distance = chase_distance;
1697
1698                         makevectors(view_angles);
1699
1700                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1701                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1702
1703                         // If the boxtrace fails, revert back to line tracing.
1704                         if(!local_player.viewloc)
1705                         if(trace_startsolid)
1706                         {
1707                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1708                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1709                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1710                         }
1711                         else { setproperty(VF_ORIGIN, trace_endpos); }
1712
1713                         if(!local_player.viewloc)
1714                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1715                 }
1716                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1717                 {
1718                         eventchase_running = false;
1719                         cvar_set("chase_active", "0");
1720                         eventchase_current_distance = 0; // start from 0 next time
1721                 }
1722         }
1723         // workaround for camera stuck between player's legs when using chase_active 1
1724         // because the engine stops updating the chase_active camera when the game ends
1725         else if(intermission)
1726         {
1727                 cvar_settemp("chase_active", "-1");
1728                 eventchase_current_distance = 0;
1729         }
1730
1731         LABEL(skip_eventchase_death);
1732
1733         // do lockview after event chase camera so that it still applies whenever necessary.
1734         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1735         {
1736                 setproperty(VF_ORIGIN, freeze_org);
1737                 setproperty(VF_ANGLES, freeze_ang);
1738         }
1739         else
1740         {
1741                 freeze_org = getpropertyvec(VF_ORIGIN);
1742                 freeze_ang = getpropertyvec(VF_ANGLES);
1743         }
1744
1745         WarpZone_FixView();
1746         //WarpZone_FixPMove();
1747
1748         vector ov_org = '0 0 0';
1749         vector ov_mid = '0 0 0';
1750         vector ov_worldmin = '0 0 0';
1751         vector ov_worldmax = '0 0 0';
1752         if(autocvar_cl_orthoview)
1753         {
1754                 ov_worldmin = mi_picmin;
1755                 ov_worldmax = mi_picmax;
1756
1757                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1758                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1759                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1760
1761                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1762                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1763
1764                 float ov_nearest = vlen(ov_org - vec3(
1765                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1766                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1767                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1768                 ));
1769
1770                 float ov_furthest = 0;
1771                 float dist = 0;
1772
1773                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1774                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1775                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1776                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1777                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1778                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1779                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1780                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1781
1782                 if(!ov_enabled)
1783                 {
1784                         oldr_nearclip = cvar("r_nearclip");
1785                         oldr_farclip_base = cvar("r_farclip_base");
1786                         oldr_farclip_world = cvar("r_farclip_world");
1787                         oldr_novis = cvar("r_novis");
1788                         oldr_useportalculling = cvar("r_useportalculling");
1789                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1790                 }
1791
1792                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1793                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1794                 cvar_settemp("r_farclip_world", "0");
1795                 cvar_settemp("r_novis", "1");
1796                 cvar_settemp("r_useportalculling", "0");
1797                 cvar_settemp("r_useinfinitefarclip", "0");
1798
1799                 setproperty(VF_ORIGIN, ov_org);
1800                 setproperty(VF_ANGLES, '90 0 0');
1801
1802                 ov_enabled = true;
1803
1804                 #if 0
1805                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1806                         vtos(ov_org),
1807                         vtos(getpropertyvec(VF_ANGLES)),
1808                         ov_distance,
1809                         ov_nearest,
1810                         ov_furthest);
1811                 #endif
1812         }
1813         else
1814         {
1815                 if(ov_enabled)
1816                 {
1817                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1818                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1819                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1820                         cvar_set("r_novis", ftos(oldr_novis));
1821                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1822                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1823                 }
1824                 ov_enabled = false;
1825         }
1826
1827         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1828         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1829         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1830                 viewmodel_draw(viewmodels[slot]);
1831
1832         // Render the Scene
1833         view_origin = getpropertyvec(VF_ORIGIN);
1834         view_angles = getpropertyvec(VF_ANGLES);
1835         makevectors(view_angles);
1836         view_forward = v_forward;
1837         view_right = v_right;
1838         view_up = v_up;
1839
1840 #ifdef BLURTEST
1841         if(time > blurtest_time0 && time < blurtest_time1)
1842         {
1843                 float r, t;
1844
1845                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1846                 r = t * blurtest_radius;
1847                 f = 1 / (t ** blurtest_power) - 1;
1848
1849                 cvar_set("r_glsl_postprocess", "1");
1850                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1851         }
1852         else
1853         {
1854                 cvar_set("r_glsl_postprocess", "0");
1855                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1856         }
1857 #endif
1858
1859         TargetMusic_Advance();
1860         Fog_Force();
1861
1862         if(drawtime == 0)
1863                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1864         else
1865                 drawframetime = bound(0.000001, time - drawtime, 1);
1866         drawtime = time;
1867
1868         // watch for gametype changes here...
1869         // in ParseStuffCMD the cmd isn't executed yet :/
1870         // might even be better to add the gametype to TE_CSQC_INIT...?
1871         if(!postinit)
1872                 PostInit();
1873
1874         if(intermission && !intermission_time)
1875                 intermission_time = time;
1876
1877         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1878         {
1879                 if(calledhooks & HOOK_START)
1880                 {
1881                         localcmd("\ncl_hook_gameend\n");
1882                         calledhooks |= HOOK_END;
1883                 }
1884         }
1885
1886         Announcer();
1887
1888         fov = autocvar_fov;
1889         if(fov <= 59.5)
1890         {
1891                 if(!zoomscript_caught)
1892                 {
1893                         localcmd("+button9\n");
1894                         zoomscript_caught = 1;
1895                 }
1896         }
1897         else
1898         {
1899                 if(zoomscript_caught)
1900                 {
1901                         localcmd("-button9\n");
1902                         zoomscript_caught = 0;
1903                 }
1904         }
1905
1906         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1907
1908         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1909         {
1910                 entity wepent = viewmodels[slot];
1911
1912                 if(wepent.last_switchweapon != wepent.switchweapon)
1913                 {
1914                         weapontime = time;
1915                         wepent.last_switchweapon = wepent.switchweapon;
1916                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1917                         {
1918                                 localcmd("-zoom\n");
1919                                 button_zoom = false;
1920                         }
1921                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1922                         {
1923                                 localcmd("-fire\n");
1924                                 localcmd("-fire2\n");
1925                                 button_attack2 = false;
1926                         }
1927                 }
1928                 if(wepent.last_activeweapon != wepent.activeweapon)
1929                 {
1930                         wepent.last_activeweapon = wepent.activeweapon;
1931
1932                         e = wepent.activeweapon;
1933                         if(e.netname != "")
1934                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1935                         else if(slot == 0)
1936                                 localcmd("\ncl_hook_activeweapon none\n");
1937                 }
1938         }
1939
1940         // ALWAYS Clear Current Scene First
1941         clearscene();
1942
1943         setproperty(VF_ORIGIN, view_origin);
1944         setproperty(VF_ANGLES, view_angles);
1945
1946         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1947         setproperty(VF_SIZE, vf_size);
1948         setproperty(VF_MIN, vf_min);
1949
1950         // Assign Standard Viewflags
1951         // Draw the World (and sky)
1952         setproperty(VF_DRAWWORLD, 1);
1953
1954         // Set the console size vars
1955         vid_conwidth = autocvar_vid_conwidth;
1956         vid_conheight = autocvar_vid_conheight;
1957         vid_pixelheight = autocvar_vid_pixelheight;
1958
1959         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1960         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1961         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1962
1963         if(camera_active) // Camera for demo playback
1964         {
1965                 if(autocvar_camera_enable)
1966                         CSQC_Demo_Camera();
1967                 else
1968                 {
1969                         cvar_set("chase_active", ftos(chase_active_backup));
1970                         cvar_set("cl_demo_mousegrab", "0");
1971                         camera_active = false;
1972                 }
1973         }
1974         else
1975         {
1976 #ifdef CAMERATEST
1977                 if(autocvar_camera_enable)
1978 #else
1979                 if(autocvar_camera_enable && isdemo())
1980 #endif
1981                 {
1982                         // Enable required Darkplaces cvars
1983                         chase_active_backup = autocvar_chase_active;
1984                         cvar_set("chase_active", "2");
1985                         cvar_set("cl_demo_mousegrab", "1");
1986                         camera_active = true;
1987                         camera_mode = false;
1988                 }
1989         }
1990
1991         // Draw the Crosshair
1992         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1993
1994         // Draw the Engine Status Bar (the default Quake HUD)
1995         setproperty(VF_DRAWENGINESBAR, 0);
1996
1997         // Update the mouse position
1998         /*
1999            mousepos_x = vid_conwidth;
2000            mousepos_y = vid_conheight;
2001            mousepos = mousepos*0.5 + getmousepos();
2002          */
2003
2004         IL_EACH(g_drawables, it.draw, it.draw(it));
2005
2006         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
2007         renderscene();
2008
2009         // now switch to 2D drawing mode by calling a 2D drawing function
2010         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2011         // next R_RenderScene call
2012         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2013
2014         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2015         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2016         {
2017                 // apply night vision effect
2018                 vector tc_00, tc_01, tc_10, tc_11;
2019                 vector rgb = '0 0 0';
2020
2021                 if(!nightvision_noise)
2022                 {
2023                         nightvision_noise = new(nightvision_noise);
2024                 }
2025                 if(!nightvision_noise2)
2026                 {
2027                         nightvision_noise2 = new(nightvision_noise2);
2028                 }
2029
2030                 // color tint in yellow
2031                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2032
2033                 // draw BG
2034                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2035                 rgb = '1 1 1';
2036                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2037                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2038                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2039                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2040                 tc_11 = tc_01 + tc_10 - tc_00;
2041                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2042                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2043                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2044                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2045                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2046                 R_EndPolygon();
2047
2048                 // draw FG
2049                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2050                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2051                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2052                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2053                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2054                 tc_11 = tc_01 + tc_10 - tc_00;
2055                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2056                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2057                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2058                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2059                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2060                 R_EndPolygon();
2061         }
2062
2063         if(autocvar_cl_reticle)
2064         {
2065                 string reticle_image = string_null;
2066                 bool wep_zoomed = false;
2067                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2068                 {
2069                         entity wepe = viewmodels[slot];
2070                         Weapon wep = wepe.activeweapon;
2071                         if(wep != WEP_Null && wep.wr_zoom)
2072                         {
2073                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2074                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2075                                         reticle_image = wep.w_reticle;
2076                                 wep_zoomed += do_zoom;
2077                         }
2078                 }
2079                 // Draw the aiming reticle for weapons that use it
2080                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2081                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2082                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2083                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2084                 {
2085                         // no zoom reticle while dead
2086                         reticle_type = 0;
2087                 }
2088                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2089                 {
2090                         if(reticle_image) { reticle_type = 2; }
2091                         else { reticle_type = 0; }
2092                 }
2093                 else if(button_zoom || zoomscript_caught)
2094                 {
2095                         // normal zoom
2096                         reticle_type = 1;
2097                 }
2098
2099                 if(reticle_type)
2100                 {
2101                         if(autocvar_cl_reticle_stretch)
2102                         {
2103                                 reticle_size.x = vid_conwidth;
2104                                 reticle_size.y = vid_conheight;
2105                                 reticle_pos.x = 0;
2106                                 reticle_pos.y = 0;
2107                         }
2108                         else
2109                         {
2110                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2111                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2112                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2113                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2114                         }
2115
2116                         if(zoomscript_caught)
2117                                 f = 1;
2118                         else
2119                                 f = current_zoomfraction;
2120
2121                         if(f)
2122                         {
2123                                 switch(reticle_type)
2124                                 {
2125                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2126                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2127                                 }
2128                         }
2129                 }
2130         }
2131         else
2132         {
2133                 if(reticle_type != 0) { reticle_type = 0; }
2134         }
2135
2136
2137         // improved polyblend
2138         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2139         {
2140                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2141                 vector liquidcolor;
2142
2143                 switch(pointcontents(view_origin))
2144                 {
2145                         case CONTENT_WATER:
2146                                 liquidalpha = autocvar_hud_contents_water_alpha;
2147                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2148                                 incontent = 1;
2149                                 break;
2150
2151                         case CONTENT_LAVA:
2152                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2153                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2154                                 incontent = 1;
2155                                 break;
2156
2157                         case CONTENT_SLIME:
2158                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2159                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2160                                 incontent = 1;
2161                                 break;
2162
2163                         default:
2164                                 liquidalpha = 0;
2165                                 liquidcolor = '0 0 0';
2166                                 incontent = 0;
2167                                 break;
2168                 }
2169
2170                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2171                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2172                         contentfadetime = autocvar_hud_contents_fadeintime;
2173                         liquidalpha_prev = liquidalpha;
2174                         liquidcolor_prev = liquidcolor;
2175                 }
2176                 else
2177                         contentfadetime = autocvar_hud_contents_fadeouttime;
2178
2179                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2180                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2181
2182                 if(contentavgalpha)
2183                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2184
2185                 if(autocvar_hud_postprocessing)
2186                 {
2187                         if(autocvar_hud_contents_blur && contentavgalpha)
2188                         {
2189                                 content_blurpostprocess.x = 1;
2190                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2191                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2192                         }
2193                         else
2194                         {
2195                                 content_blurpostprocess.x = 0;
2196                                 content_blurpostprocess.y = 0;
2197                                 content_blurpostprocess.z = 0;
2198                         }
2199                 }
2200         }
2201
2202         if(autocvar_hud_damage && !STAT(FROZEN))
2203         {
2204                 splash_size.x = max(vid_conwidth, vid_conheight);
2205                 splash_size.y = max(vid_conwidth, vid_conheight);
2206                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2207                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2208
2209                 float myhealth_flash_temp;
2210                 myhealth = STAT(HEALTH);
2211
2212                 // fade out
2213                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2214                 // add new damage
2215                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2216
2217                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2218                 pain_threshold = autocvar_hud_damage_pain_threshold;
2219                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2220                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2221
2222                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2223                 {
2224                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2225                 }
2226
2227                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2228
2229                 if(myhealth_prev < 1)
2230                 {
2231                         if(myhealth >= 1)
2232                         {
2233                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2234                                 myhealth_flash_temp = 0;
2235                         }
2236                         else
2237                         {
2238                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2239                         }
2240                 }
2241
2242                 if(spectatee_status == -1 || intermission)
2243                 {
2244                         myhealth_flash = 0; // observing, or match ended
2245                         myhealth_flash_temp = 0;
2246                 }
2247
2248                 myhealth_prev = myhealth;
2249
2250                 // IDEA: change damage color/picture based on player model for robot/alien species?
2251                 // pro: matches model better
2252                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2253                 // maybe different reddish pics?
2254                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2255                 {
2256                         if(autocvar_cl_gentle_damage == 2)
2257                         {
2258                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2259                                         myhealth_gentlergb = randomvec();
2260                         }
2261                         else
2262                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2263
2264                         if(myhealth_flash_temp > 0)
2265                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2266                 }
2267                 else if(myhealth_flash_temp > 0)
2268                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2269
2270                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2271                 {
2272                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2273                         {
2274                                 damage_blurpostprocess.x = 1;
2275                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2276                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2277                         }
2278                         else
2279                         {
2280                                 damage_blurpostprocess.x = 0;
2281                                 damage_blurpostprocess.y = 0;
2282                                 damage_blurpostprocess.z = 0;
2283                         }
2284                 }
2285         }
2286
2287         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2288         float e2 = (autocvar_hud_powerup != 0);
2289         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2290         {
2291                 // enable or disable rendering types if they are used or not
2292                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2293                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2294
2295                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2296                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2297                 {
2298                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2299                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2300                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2301                         {
2302                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2303                                 old_blurradius = blurradius;
2304                                 old_bluralpha = bluralpha;
2305                         }
2306                 }
2307                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2308                 {
2309                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2310                         old_blurradius = 0;
2311                         old_bluralpha = 0;
2312                 }
2313
2314                 // edge detection postprocess handling done second (used by hud_powerup)
2315                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2316                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2317                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2318
2319                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2320
2321                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2322                 {
2323                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2324                         {
2325                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2326                                 old_sharpen_intensity = sharpen_intensity;
2327                         }
2328                 }
2329                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2330                 {
2331                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2332                         old_sharpen_intensity = 0;
2333                 }
2334
2335                 if(cvar("r_glsl_postprocess") == 0)
2336                         cvar_set("r_glsl_postprocess", "2");
2337         }
2338         else if(cvar("r_glsl_postprocess") == 2)
2339                 cvar_set("r_glsl_postprocess", "0");
2340
2341         /*if(gametype == MAPINFO_TYPE_CTF)
2342           {
2343           ctf_view();
2344           } else */
2345
2346         // draw 2D entities
2347         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2348         Draw_ShowNames_All();
2349 #if ENABLE_DEBUGDRAW
2350         Debug_Draw();
2351 #endif
2352
2353         scoreboard_active = Scoreboard_WouldDraw();
2354
2355         HUD_Draw(this); // this parameter for deep vehicle function
2356
2357         if(NextFrameCommand)
2358         {
2359                 localcmd("\n", NextFrameCommand, "\n");
2360                 NextFrameCommand = string_null;
2361         }
2362
2363         // we must do this check AFTER a frame was rendered, or it won't work
2364         if(cs_project_is_b0rked == 0)
2365         {
2366                 string w0, h0;
2367                 w0 = ftos(autocvar_vid_conwidth);
2368                 h0 = ftos(autocvar_vid_conheight);
2369                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2370                 //setproperty(VF_FOV, '90 90 0');
2371                 setproperty(VF_ORIGIN, '0 0 0');
2372                 setproperty(VF_ANGLES, '0 0 0');
2373                 setproperty(VF_PERSPECTIVE, 1);
2374                 makevectors('0 0 0');
2375                 vector v1, v2;
2376                 cvar_set("vid_conwidth", "800");
2377                 cvar_set("vid_conheight", "600");
2378                 v1 = cs_project(v_forward);
2379                 cvar_set("vid_conwidth", "640");
2380                 cvar_set("vid_conheight", "480");
2381                 v2 = cs_project(v_forward);
2382                 if(v1 == v2)
2383                         cs_project_is_b0rked = 1;
2384                 else
2385                         cs_project_is_b0rked = -1;
2386                 cvar_set("vid_conwidth", w0);
2387                 cvar_set("vid_conheight", h0);
2388         }
2389
2390         if(autocvar__hud_configure)
2391                 HUD_Panel_Mouse();
2392         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2393                 HUD_Minigame_Mouse();
2394         else if(QuickMenu_IsOpened())
2395                 QuickMenu_Mouse();
2396         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2397                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2398         else
2399                 HUD_Radar_Mouse();
2400
2401         cl_notice_run();
2402         unpause_update();
2403         Net_Flush();
2404
2405         // let's reset the view back to normal for the end
2406         setproperty(VF_MIN, '0 0 0');
2407         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2408
2409         IL_ENDFRAME();
2410 }
2411
2412
2413 // following vectors must be global to allow seamless switching between camera modes
2414 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2415 void CSQC_Demo_Camera()
2416 {
2417         float speed, attenuation, dimensions;
2418         vector tmp, delta;
2419
2420         if( autocvar_camera_reset || !camera_mode )
2421         {
2422                 camera_offset = '0 0 0';
2423                 current_angles = '0 0 0';
2424                 camera_direction = '0 0 0';
2425                 camera_offset.z += 30;
2426                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2427                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2428                 current_origin = view_origin;
2429                 current_camera_offset  = camera_offset;
2430                 cvar_set("camera_reset", "0");
2431                 camera_mode = CAMERA_CHASE;
2432         }
2433
2434         // Camera angles
2435         if( camera_roll )
2436                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2437
2438         if(autocvar_camera_look_player)
2439         {
2440                 vector dir;
2441                 float n;
2442
2443                 dir = normalize(view_origin - current_position);
2444                 n = mouse_angles.z;
2445                 mouse_angles = vectoangles(dir);
2446                 mouse_angles.x = mouse_angles.x * -1;
2447                 mouse_angles.z = n;
2448         }
2449         else
2450         {
2451                 tmp = getmousepos() * 0.1;
2452                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2453                 {
2454                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2455                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2456                 }
2457         }
2458
2459         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2460         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2461         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2462         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2463
2464         // Fix difference when angles don't have the same sign
2465         delta = '0 0 0';
2466         if(mouse_angles.y < -60 && current_angles.y > 60)
2467                 delta = '0 360 0';
2468         if(mouse_angles.y > 60 && current_angles.y < -60)
2469                 delta = '0 -360 0';
2470
2471         if(autocvar_camera_look_player)
2472                 attenuation = autocvar_camera_look_attenuation;
2473         else
2474                 attenuation = autocvar_camera_speed_attenuation;
2475
2476         attenuation = 1 / max(1, attenuation);
2477         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2478
2479         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2480         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2481         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2482         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2483
2484         // Camera position
2485         tmp = '0 0 0';
2486         dimensions = 0;
2487
2488         if( camera_direction.x )
2489         {
2490                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2491                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2492                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2493                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2494                 ++dimensions;
2495         }
2496
2497         if( camera_direction.y )
2498         {
2499                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2500                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2501                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2502                 ++dimensions;
2503         }
2504
2505         if( camera_direction.z )
2506         {
2507                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2508                 ++dimensions;
2509         }
2510
2511         if(autocvar_camera_free)
2512                 speed = autocvar_camera_speed_free;
2513         else
2514                 speed = autocvar_camera_speed_chase;
2515
2516         if(dimensions)
2517         {
2518                 speed = speed * sqrt(1 / dimensions);
2519                 camera_offset += tmp * speed;
2520         }
2521
2522         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2523
2524         // Camera modes
2525         if( autocvar_camera_free )
2526         {
2527                 if ( camera_mode == CAMERA_CHASE )
2528                 {
2529                         current_camera_offset = current_origin + current_camera_offset;
2530                         camera_offset = current_origin + camera_offset;
2531                 }
2532
2533                 camera_mode = CAMERA_FREE;
2534                 current_position = current_camera_offset;
2535         }
2536         else
2537         {
2538                 if ( camera_mode == CAMERA_FREE )
2539                 {
2540                         current_origin = view_origin;
2541                         camera_offset = camera_offset - current_origin;
2542                         current_camera_offset = current_camera_offset - current_origin;
2543                 }
2544
2545                 camera_mode = CAMERA_CHASE;
2546
2547                 if(autocvar_camera_chase_smoothly)
2548                         current_origin += (view_origin - current_origin) * attenuation;
2549                 else
2550                         current_origin = view_origin;
2551
2552                 current_position = current_origin + current_camera_offset;
2553         }
2554
2555         setproperty(VF_ANGLES, current_angles);
2556         setproperty(VF_ORIGIN, current_position);
2557 }