qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include "mutators/events.qh"
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/debug.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/gamemodes/_mod.qh>
  23 #include <common/physics/player.qh>
  24 #include <common/stats.qh>
  25 #include <common/triggers/target/music.qh>
  26 #include <common/teams.qh>
  27 #include <common/wepent.qh>
  28
  29 #include <common/weapons/weapon/tuba.qh>
  30
  31 #include <common/vehicles/all.qh>
  32 #include <common/weapons/_all.qh>
  33 #include <common/mutators/mutator/overkill/oknex.qh>
  34 #include <common/viewloc.qh>
  35 #include <common/triggers/trigger/viewloc.qh>
  36 #include <common/minigames/cl_minigames.qh>
  37 #include <common/minigames/cl_minigames_hud.qh>
  38
  39 #include <lib/csqcmodel/cl_player.qh>
  40 #include <lib/csqcmodel/cl_model.qh>
  41 #include "csqcmodel_hooks.qh"
  42
  43 #include <lib/warpzone/client.qh>
  44 #include <lib/warpzone/common.qh>
  45
  46 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  47
  48 float autocvar_cl_viewmodel_scale;
  49
  50 bool autocvar_cl_bobmodel;
  51 float autocvar_cl_bobmodel_speed;
  52 float autocvar_cl_bobmodel_side;
  53 float autocvar_cl_bobmodel_up;
  54
  55 float autocvar_cl_followmodel;
  56 float autocvar_cl_followmodel_speed = 0.3;
  57 float autocvar_cl_followmodel_limit = 135;
  58 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  59 float autocvar_cl_followmodel_highpass = 0.05;
  60 float autocvar_cl_followmodel_lowpass = 0.03;
  61 bool autocvar_cl_followmodel_velocity_absolute;
  62
  63 float autocvar_cl_leanmodel;
  64 float autocvar_cl_leanmodel_speed = 0.3;
  65 float autocvar_cl_leanmodel_limit = 30;
  66 float autocvar_cl_leanmodel_highpass1 = 0.2;
  67 float autocvar_cl_leanmodel_highpass = 0.2;
  68 float autocvar_cl_leanmodel_lowpass = 0.05;
  69
  70 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  71
  72 #define lowpass(value, frac, ref_store, ret) \
  73         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  74
  75 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  76 { \
  77         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  78         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  79 } MACRO_END
  80
  81 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  82 { \
  83         float __f = 0; lowpass(value, frac, ref_store, __f); \
  84         ret = (value) - __f; \
  85 } MACRO_END
  86
  87 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  88 { \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 } MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94 { \
  95         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  96         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  97 } MACRO_END
  98
  99 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
 100 { \
 101         highpass(value.x, frac, ref_store.x, ref_out.x); \
 102         highpass(value.y, frac, ref_store.y, ref_out.y); \
 103 } MACRO_END
 104
 105 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 106 { \
 107         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 108         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 109 } MACRO_END
 110
 111 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 112 { \
 113         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 114         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 115         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 116 } MACRO_END
 117
 118 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 119 { \
 120         highpass(value.x, frac, ref_store.x, ref_out.x); \
 121         highpass(value.y, frac, ref_store.y, ref_out.y); \
 122         highpass(value.z, frac, ref_store.z, ref_out.z); \
 123 } MACRO_END
 124
 125 void calc_followmodel_ofs(entity view)
 126 {
 127         if(cl_followmodel_time == time)
 128                 return; // cl_followmodel_ofs already calculated for this frame
 129
 130         float frac;
 131         vector gunorg = '0 0 0';
 132         static vector vel_average;
 133         static vector gunorg_adjustment_highpass;
 134         static vector gunorg_adjustment_lowpass;
 135
 136         vector vel;
 137         if (autocvar_cl_followmodel_velocity_absolute)
 138                 vel = view.velocity;
 139         else
 140         {
 141                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 142                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 143                 vel.x = view.velocity * forward;
 144                 vel.y = view.velocity * right * -1;
 145                 vel.z = view.velocity * up;
 146         }
 147
 148         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 149         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 150         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 151
 152         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 153         lowpass3(vel, frac, vel_average, gunorg);
 154
 155         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 156
 157         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 158         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 159         frac = avg_factor(autocvar_cl_followmodel_highpass);
 160         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 161         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 162         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 163
 164         if (autocvar_cl_followmodel_velocity_absolute)
 165         {
 166                 vector fixed_gunorg;
 167                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 168                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 169                 fixed_gunorg.x = gunorg * forward;
 170                 fixed_gunorg.y = gunorg * right * -1;
 171                 fixed_gunorg.z = gunorg * up;
 172                 gunorg = fixed_gunorg;
 173         }
 174
 175         cl_followmodel_ofs = gunorg;
 176         cl_followmodel_time = time;
 177 }
 178
 179 vector leanmodel_ofs(entity view)
 180 {
 181         float frac;
 182         vector gunangles = '0 0 0';
 183         static vector gunangles_prev = '0 0 0';
 184         static vector gunangles_highpass = '0 0 0';
 185         static vector gunangles_adjustment_highpass;
 186         static vector gunangles_adjustment_lowpass;
 187
 188         if (view.csqcmodel_teleported)
 189                 gunangles_prev = view_angles;
 190
 191         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 192         gunangles_highpass += gunangles_prev;
 193         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 194         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 195         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 196         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 197         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 198         gunangles_prev = view_angles;
 199         gunangles_highpass -= gunangles_prev;
 200
 201         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 202         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 203
 204         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 205         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 206         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 207         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 208         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 209
 210         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 211
 212         return gunangles;
 213 }
 214
 215 vector bobmodel_ofs(entity view)
 216 {
 217         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 218         static bool oldonground;
 219         static float hitgroundtime;
 220         if (clonground)
 221         {
 222                 float f = time; // cl.movecmd[0].time
 223                 if (!oldonground)
 224                         hitgroundtime = f;
 225         }
 226         oldonground = clonground;
 227
 228         // calculate for swinging gun model
 229         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 230         vector gunorg = '0 0 0';
 231         static float bobmodel_scale = 0;
 232         static float time_ofs = 0; // makes the effect always restart in the same way
 233         if (clonground)
 234         {
 235                 if (time - hitgroundtime > 0.05)
 236                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 237         }
 238         else
 239                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 240
 241         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 242         if (bobmodel_scale && xyspeed)
 243         {
 244                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 245                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 246                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 247                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 248         }
 249         else
 250                 time_ofs = time;
 251
 252         return gunorg;
 253 }
 254
 255 void viewmodel_animate(entity this)
 256 {
 257         if (autocvar_chase_active) return;
 258         if (STAT(HEALTH) <= 0) return;
 259
 260         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 261
 262         if (autocvar_cl_followmodel)
 263         {
 264                 calc_followmodel_ofs(view);
 265                 this.origin += cl_followmodel_ofs;
 266         }
 267
 268         if (autocvar_cl_leanmodel)
 269                 this.angles += leanmodel_ofs(view);
 270
 271         // vertical view bobbing code
 272         // TODO: cl_bob
 273
 274         // horizontal view bobbing code
 275         // TODO: cl_bob2
 276
 277         // fall bobbing code
 278         // causes the view to swing down and back up when touching the ground
 279         // TODO: cl_bobfall
 280
 281         // gun model bobbing code
 282         if (autocvar_cl_bobmodel)
 283                 this.origin += bobmodel_ofs(view);
 284 }
 285
 286 .vector viewmodel_origin, viewmodel_angles;
 287 .float weapon_nextthink;
 288 .float weapon_eta_last;
 289 .float weapon_switchdelay;
 290
 291 .string name_last;
 292
 293 void viewmodel_draw(entity this)
 294 {
 295         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 296                 return;
 297         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 298         float a = this.alpha;
 299         static bool wasinvehicle;
 300         bool invehicle = player_localentnum > maxclients;
 301         if (invehicle) a = -1;
 302         else if (wasinvehicle) a = 1;
 303         wasinvehicle = invehicle;
 304         Weapon wep = this.activeweapon;
 305         int c = entcs_GetClientColors(current_player);
 306         vector g = weaponentity_glowmod(wep, NULL, c, this);
 307         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 308         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 309                 | EF_NODEPTHTEST)
 310                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 311         for (entity e = this; e; e = e.weaponchild)
 312         {
 313                 e.drawmask = mask;
 314                 e.alpha = a;
 315                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 316                 e.glowmod = g;
 317                 e.csqcmodel_effects = fx;
 318                 CSQCModel_Effects_Apply(e);
 319         }
 320         if(a >= 0)
 321         {
 322                 string name = wep.mdl;
 323                 string newname = wep.wr_viewmodel(wep, this);
 324                 if(newname)
 325                         name = newname;
 326                 bool swap = name != this.name_last;
 327                 // if (swap)
 328                 {
 329                         this.name_last = name;
 330                         CL_WeaponEntity_SetModel(this, name, swap);
 331                         this.viewmodel_origin = this.origin;
 332                         this.viewmodel_angles = this.angles;
 333                 }
 334                 anim_update(this);
 335                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 336                         anim_set(this, this.anim_idle, true, false, false);
 337         }
 338         float f = 0; // 0..1; 0: fully active
 339         float rate = STAT(WEAPONRATEFACTOR);
 340         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 341         if (eta <= 0) f = this.weapon_eta_last;
 342         else switch (this.state)
 343         {
 344                 case WS_RAISE:
 345                 {
 346                         f = eta / max(eta, this.weapon_switchdelay);
 347                         break;
 348                 }
 349                 case WS_DROP:
 350                 {
 351                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 352                         break;
 353                 }
 354                 case WS_CLEAR:
 355                 {
 356                         f = 1;
 357                         break;
 358                 }
 359         }
 360         this.weapon_eta_last = f;
 361         this.origin = this.viewmodel_origin;
 362         this.angles = this.viewmodel_angles;
 363         this.angles_x = (-90 * f * f);
 364         viewmodel_animate(this);
 365         MUTATOR_CALLHOOK(DrawViewModel, this);
 366         setorigin(this, this.origin);
 367 }
 368
 369 STATIC_INIT(viewmodel) {
 370     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 371         viewmodels[slot] = new(viewmodel);
 372 }
 373
 374 void Porto_Draw(entity this);
 375 STATIC_INIT(Porto)
 376 {
 377         entity e = new_pure(porto);
 378         e.draw = Porto_Draw;
 379         IL_PUSH(g_drawables, e);
 380         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 381 }
 382
 383 const int polyline_length = 16;
 384 .vector polyline[polyline_length];
 385 void Porto_Draw(entity this)
 386 {
 387         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 388         {
 389                 entity wepent = viewmodels[slot];
 390
 391                 if (wepent.activeweapon != WEP_PORTO) continue;
 392                 if (spectatee_status) continue;
 393                 if (WEP_CVAR(porto, secondary)) continue;
 394                 if (intermission == 1) continue;
 395                 if (intermission == 2) continue;
 396                 if (STAT(HEALTH) <= 0) continue;
 397
 398                 vector pos = view_origin;
 399                 vector dir = view_forward;
 400                 if (wepent.angles_held_status)
 401                 {
 402                         makevectors(wepent.angles_held);
 403                         dir = v_forward;
 404                 }
 405
 406                 wepent.polyline[0] = pos;
 407
 408                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 409                 int n = 1 + 2;  // 2 lines == 3 points
 410                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 411                 {
 412                         traceline(pos, pos + 65536 * dir, true, this);
 413                         dir = reflect(dir, trace_plane_normal);
 414                         pos = trace_endpos;
 415                         wepent.polyline[++idx] = pos;
 416                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 417                         {
 418                                 n += 1;
 419                                 continue;
 420                         }
 421                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 422                         {
 423                                 n = max(2, idx);
 424                                 break;
 425                         }
 426                         // check size
 427                         {
 428                                 vector ang = vectoangles2(trace_plane_normal, dir);
 429                                 ang.x = -ang.x;
 430                                 makevectors(ang);
 431                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 432                                 {
 433                                         n = max(2, idx);
 434                                         break;
 435                                 }
 436                         }
 437                         portal_number += 1;
 438                         if (portal_number >= portal_max) break;
 439                         if (portal_number == 1) portal1_idx = idx;
 440                 }
 441                 for (int idx = 0; idx < n - 1; ++idx)
 442                 {
 443                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 444                         if (idx == 0) p -= view_up * 16;  // line from player
 445                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 446                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 447                 }
 448         }
 449 }
 450
 451 float drawtime;
 452 float avgspeed;
 453 vector GetCurrentFov(float fov)
 454 {
 455         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 456         float velocityzoom, curspeed;
 457         vector v;
 458
 459         zoomsensitivity = autocvar_cl_zoomsensitivity;
 460         zoomfactor = autocvar_cl_zoomfactor;
 461         if(zoomfactor < 1 || zoomfactor > 30)
 462                 zoomfactor = 2.5;
 463         zoomspeed = autocvar_cl_zoomspeed;
 464         if(zoomspeed >= 0)
 465         if(zoomspeed < 0.5 || zoomspeed > 16)
 466                         zoomspeed = 3.5;
 467
 468         zoomdir = button_zoom;
 469
 470         if(hud == HUD_NORMAL && !spectatee_status)
 471         {
 472                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 473                 {
 474                         entity wepent = viewmodels[slot];
 475                         if(wepent.switchweapon != wepent.activeweapon)
 476                                 continue;
 477                         Weapon wep = wepent.activeweapon;
 478                         if(wep != WEP_Null && wep.wr_zoomdir)
 479                         {
 480                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 481                                 zoomdir += do_zoom;
 482                         }
 483                 }
 484         }
 485         if(spectatee_status > 0 || isdemo())
 486         {
 487                 if(spectatorbutton_zoom)
 488                 {
 489                         if(zoomdir)
 490                                 zoomdir = 0;
 491                         else
 492                                 zoomdir = 1;
 493                 }
 494                 // fteqcc failed twice here already, don't optimize this
 495         }
 496
 497         if(zoomdir) { zoomin_effect = 0; }
 498
 499         if(camera_active)
 500         {
 501                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 502         }
 503         else if(autocvar_cl_spawnzoom && zoomin_effect)
 504         {
 505                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 506
 507                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 508                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 509                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 510         }
 511         else
 512         {
 513                 if(zoomspeed < 0) // instant zoom
 514                 {
 515                         if(zoomdir)
 516                                 current_viewzoom = 1 / zoomfactor;
 517                         else
 518                                 current_viewzoom = 1;
 519                 }
 520                 else
 521                 {
 522                         if(zoomdir)
 523                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 524                         else
 525                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 526                 }
 527         }
 528
 529         if(almost_equals(current_viewzoom, 1))
 530                 current_zoomfraction = 0;
 531         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 532                 current_zoomfraction = 1;
 533         else
 534                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 535
 536         if(zoomsensitivity < 1)
 537                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 538         else
 539                 setsensitivityscale(1);
 540
 541         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 542         {
 543                 if(intermission) { curspeed = 0; }
 544                 else
 545                 {
 546
 547                         makevectors(view_angles);
 548                         v = pmove_vel;
 549                         if(csqcplayer)
 550                                 v = csqcplayer.velocity;
 551
 552                         switch(autocvar_cl_velocityzoom_type)
 553                         {
 554                                 case 3: curspeed = max(0, v_forward * v); break;
 555                                 case 2: curspeed = (v_forward * v); break;
 556                                 case 1: default: curspeed = vlen(v); break;
 557                         }
 558                 }
 559
 560                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 561                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 562                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 563
 564                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 565         }
 566         else
 567                 velocityzoom = 1;
 568
 569         float frustumx, frustumy, fovx, fovy;
 570         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 571         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 572         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 573         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 574
 575         return '1 0 0' * fovx + '0 1 0' * fovy;
 576 }
 577
 578 vector GetViewLocationFOV(float fov)
 579 {
 580         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 581         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 582         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 583         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 584         return '1 0 0' * fovx + '0 1 0' * fovy;
 585 }
 586
 587 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 588 {
 589         float fovx, fovy;
 590         float width = (ov_worldmax.x - ov_worldmin.x);
 591         float height = (ov_worldmax.y - ov_worldmin.y);
 592         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 593         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 594         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 595         return '1 0 0' * fovx + '0 1 0' * fovy;
 596 }
 597
 598 // this function must match W_SetupShot!
 599 float zoomscript_caught;
 600
 601 vector wcross_origin;
 602 float wcross_scale_prev, wcross_alpha_prev;
 603 vector wcross_color_prev;
 604 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 605 vector wcross_color_goal_prev;
 606 float wcross_changedonetime;
 607
 608 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 609 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 610 float wcross_name_changestarttime, wcross_name_changedonetime;
 611 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 612
 613 float wcross_ring_prev;
 614
 615 entity trueaim;
 616 entity trueaim_rifle;
 617
 618 const float SHOTTYPE_HITTEAM = 1;
 619 const float SHOTTYPE_HITOBSTRUCTION = 2;
 620 const float SHOTTYPE_HITWORLD = 3;
 621 const float SHOTTYPE_HITENEMY = 4;
 622
 623 void TrueAim_Init()
 624 {
 625         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 626         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 627 }
 628
 629 float EnemyHitCheck()
 630 {
 631         float t, n;
 632         wcross_origin = project_3d_to_2d(trace_endpos);
 633         wcross_origin.z = 0;
 634         if(trace_ent)
 635                 n = trace_ent.entnum;
 636         else
 637                 n = trace_networkentity;
 638         if(n < 1)
 639                 return SHOTTYPE_HITWORLD;
 640         if(n > maxclients)
 641                 return SHOTTYPE_HITWORLD;
 642         t = entcs_GetTeam(n - 1);
 643         if(teamplay)
 644                 if(t == myteam)
 645                         return SHOTTYPE_HITTEAM;
 646         if(t == NUM_SPECTATOR)
 647                 return SHOTTYPE_HITWORLD;
 648         return SHOTTYPE_HITENEMY;
 649 }
 650
 651 float TrueAimCheck(entity wepent)
 652 {
 653         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 654         vector vecs, trueaimpoint, w_shotorg;
 655         vector mi, ma, dv;
 656         float shottype;
 657         entity ta;
 658         float mv;
 659
 660         mi = ma = '0 0 0';
 661         ta = trueaim;
 662         mv = MOVE_NOMONSTERS;
 663
 664         switch(wepent.activeweapon) // WEAPONTODO
 665         {
 666                 case WEP_TUBA: // no aim
 667                 case WEP_PORTO: // shoots from eye
 668                 case WEP_NEXBALL: // shoots from eye
 669                 case WEP_HOOK: // no trueaim
 670                 case WEP_MORTAR: // toss curve
 671                         return SHOTTYPE_HITWORLD;
 672                 case WEP_VORTEX:
 673                 case WEP_OVERKILL_NEX:
 674                 case WEP_VAPORIZER:
 675                         mv = MOVE_NORMAL;
 676                         break;
 677                 case WEP_RIFLE:
 678                         ta = trueaim_rifle;
 679                         mv = MOVE_NORMAL;
 680                         if(zoomscript_caught)
 681                         {
 682                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 683                                 return EnemyHitCheck();
 684                         }
 685                         break;
 686                 case WEP_DEVASTATOR: // projectile has a size!
 687                         mi = '-3 -3 -3';
 688                         ma = '3 3 3';
 689                         break;
 690                 case WEP_FIREBALL: // projectile has a size!
 691                         mi = '-16 -16 -16';
 692                         ma = '16 16 16';
 693                         break;
 694                 case WEP_SEEKER: // projectile has a size!
 695                         mi = '-2 -2 -2';
 696                         ma = '2 2 2';
 697                         break;
 698                 case WEP_ELECTRO: // projectile has a size!
 699                         mi = '0 0 -3';
 700                         ma = '0 0 -3';
 701                         break;
 702         }
 703
 704         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 705
 706         vecs = decompressShotOrigin(STAT(SHOTORG));
 707
 708         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 709         trueaimpoint = trace_endpos;
 710
 711         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 712                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 713
 714         if(vecs.x > 0)
 715                 vecs.y = -vecs.y;
 716         else
 717                 vecs = '0 0 0';
 718
 719         dv = view_right * vecs.y + view_up * vecs.z;
 720         w_shotorg = traceorigin + dv;
 721
 722         // now move the vecs forward as much as requested if possible
 723         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 724         w_shotorg = trace_endpos - view_forward * nudge;
 725
 726         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 727         shottype = EnemyHitCheck();
 728         if(shottype != SHOTTYPE_HITWORLD)
 729                 return shottype;
 730
 731 #if 0
 732         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 733         // or rather, I know why, but see no fix
 734         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 735                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 736                 return SHOTTYPE_HITOBSTRUCTION;
 737 #endif
 738
 739         return SHOTTYPE_HITWORLD;
 740 }
 741
 742 void PostInit();
 743 void CSQC_Demo_Camera();
 744 float camera_mode;
 745 const float CAMERA_FREE = 1;
 746 const float CAMERA_CHASE = 2;
 747 float reticle_type;
 748 string NextFrameCommand;
 749
 750 vector freeze_org, freeze_ang;
 751 entity nightvision_noise, nightvision_noise2;
 752
 753 const float MAX_TIME_DIFF = 5;
 754 float pickup_crosshair_time, pickup_crosshair_size;
 755 float hitindication_crosshair_size;
 756 float use_vortex_chargepool;
 757
 758 float myhealth, myhealth_prev;
 759 float myhealth_flash;
 760
 761 float old_blurradius, old_bluralpha;
 762 float old_sharpen_intensity;
 763
 764 vector myhealth_gentlergb;
 765
 766 float contentavgalpha, liquidalpha_prev;
 767 vector liquidcolor_prev;
 768
 769 float eventchase_current_distance;
 770 float eventchase_running;
 771 bool WantEventchase(entity this)
 772 {
 773         if(autocvar_cl_orthoview)
 774                 return false;
 775         if(STAT(GAME_STOPPED) || intermission)
 776                 return true;
 777         if(this.viewloc)
 778                 return true;
 779         if(spectatee_status >= 0)
 780         {
 781                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 782                         return true;
 783                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 784                         return true;
 785                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 786                         return true;
 787                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 788                 {
 789                         if(autocvar_cl_eventchase_death == 2)
 790                         {
 791                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 792                                 if(this.velocity == '0 0 0' || eventchase_running)
 793                                         return true;
 794                         }
 795                         else return true;
 796                 }
 797         }
 798         return false;
 799 }
 800
 801 void HUD_Crosshair_Vehicle(entity this)
 802 {
 803         if(hud != HUD_BUMBLEBEE_GUN)
 804         {
 805                 Vehicle info = Vehicles_from(hud);
 806                 info.vr_crosshair(info, this);
 807         }
 808 }
 809
 810 vector damage_blurpostprocess, content_blurpostprocess;
 811
 812 float unaccounted_damage = 0;
 813 void UpdateDamage()
 814 {
 815         // accumulate damage with each stat update
 816         static float damage_total_prev = 0;
 817         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 818         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 819         damage_total_prev = damage_total;
 820
 821         static float damage_dealt_time_prev = 0;
 822         float damage_dealt_time = STAT(HIT_TIME);
 823         if (damage_dealt_time != damage_dealt_time_prev)
 824         {
 825                 unaccounted_damage += unaccounted_damage_new;
 826                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 827         }
 828         damage_dealt_time_prev = damage_dealt_time;
 829
 830         // prevent hitsound when switching spectatee
 831         static float spectatee_status_prev = 0;
 832         if (spectatee_status != spectatee_status_prev)
 833                 unaccounted_damage = 0;
 834         spectatee_status_prev = spectatee_status;
 835 }
 836
 837 void HitSound()
 838 {
 839         // varying sound pitch
 840
 841         bool have_arc = false;
 842         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 843         {
 844                 entity wepent = viewmodels[slot];
 845
 846                 if(wepent.activeweapon == WEP_ARC)
 847                         have_arc = true;
 848         }
 849
 850         static float hitsound_time_prev = 0;
 851         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 852         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 853         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 854         {
 855                 if (autocvar_cl_hitsound && unaccounted_damage)
 856                 {
 857                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 858                         float a = autocvar_cl_hitsound_max_pitch;
 859                         float b = autocvar_cl_hitsound_min_pitch;
 860                         float c = autocvar_cl_hitsound_nom_damage;
 861                         float d = unaccounted_damage;
 862                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 863
 864                         // if sound variation is disabled, set pitch_shift to 1
 865                         if (autocvar_cl_hitsound == 1)
 866                                 pitch_shift = 1;
 867
 868                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 869                         if (autocvar_cl_hitsound == 3)
 870                         {
 871                                 float mirror_value = (a-b)/2 + b;
 872                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 873                         }
 874
 875                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 876
 877                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 878                         // todo: normalize sound pressure levels? seems unnecessary
 879
 880                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 881                 }
 882                 unaccounted_damage = 0;
 883                 hitsound_time_prev = time;
 884         }
 885
 886         static float typehit_time_prev = 0;
 887         float typehit_time = STAT(TYPEHIT_TIME);
 888         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 889         {
 890                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 891                 typehit_time_prev = typehit_time;
 892         }
 893
 894         static float kill_time_prev = 0;
 895         float kill_time = STAT(KILL_TIME);
 896         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 897         {
 898                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 899                 kill_time_prev = kill_time;
 900         }
 901 }
 902
 903 vector crosshair_getcolor(entity this, float health_stat)
 904 {
 905         static float rainbow_last_flicker;
 906         static vector rainbow_prev_color;
 907         vector wcross_color = '0 0 0';
 908         switch(autocvar_crosshair_color_special)
 909         {
 910                 case 1: // crosshair_color_per_weapon
 911                 {
 912                         if(this != WEP_Null && hud == HUD_NORMAL)
 913                         {
 914                                 wcross_color = this.wpcolor;
 915                                 break;
 916                         }
 917                         else { goto normalcolor; }
 918                 }
 919
 920                 case 2: // crosshair_color_by_health
 921                 {
 922                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 923                         float hp = floor(v.x + 1);
 924
 925                         //x = red
 926                         //y = green
 927                         //z = blue
 928
 929                         wcross_color.z = 0;
 930
 931                         if(hp > 200)
 932                         {
 933                                 wcross_color.x = 0;
 934                                 wcross_color.y = 1;
 935                         }
 936                         else if(hp > 150)
 937                         {
 938                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 939                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 940                         }
 941                         else if(hp > 100)
 942                         {
 943                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 944                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 945                                 wcross_color.z = 1 - (hp-100)*0.02;
 946                         }
 947                         else if(hp > 50)
 948                         {
 949                                 wcross_color.x = 1;
 950                                 wcross_color.y = 1;
 951                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 952                         }
 953                         else if(hp > 20)
 954                         {
 955                                 wcross_color.x = 1;
 956                                 wcross_color.y = (hp-20)*90/27/100;
 957                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 958                         }
 959                         else
 960                         {
 961                                 wcross_color.x = 1;
 962                                 wcross_color.y = 0;
 963                         }
 964                         break;
 965                 }
 966
 967                 case 3: // crosshair_color_rainbow
 968                 {
 969                         if(time >= rainbow_last_flicker)
 970                         {
 971                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 972                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 973                         }
 974                         wcross_color = rainbow_prev_color;
 975                         break;
 976                 }
 977 LABEL(normalcolor)
 978                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 979         }
 980
 981         return wcross_color;
 982 }
 983
 984 void HUD_Crosshair(entity this)
 985 {
 986         float f, i, j;
 987         vector v;
 988         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 989                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 990                 !HUD_MinigameMenu_IsOpened() )
 991         {
 992                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 993                         return;
 994
 995                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 996                         return;
 997
 998                 if (hud != HUD_NORMAL)
 999                 {
1000                         HUD_Crosshair_Vehicle(this);
1001                         return;
1002                 }
1003
1004                 string wcross_style;
1005                 float wcross_alpha, wcross_resolution;
1006                 wcross_style = autocvar_crosshair;
1007                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1008                         wcross_style = autocvar_crosshair_2d;
1009                 if (wcross_style == "0")
1010                         return;
1011                 wcross_resolution = autocvar_crosshair_size;
1012                 if (wcross_resolution == 0)
1013                         return;
1014                 wcross_alpha = autocvar_crosshair_alpha;
1015                 if (wcross_alpha == 0)
1016                         return;
1017
1018                 // TrueAim check
1019                 float shottype;
1020
1021                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1022                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1023                         wcross_origin = viewloc_mousepos;
1024                 else
1025                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1026                 wcross_origin.z = 0;
1027                 if(autocvar_crosshair_hittest)
1028                 {
1029                         vector wcross_oldorigin;
1030                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1031                         wcross_oldorigin = wcross_origin;
1032                         shottype = TrueAimCheck(thiswep);
1033                         if(shottype == SHOTTYPE_HITWORLD)
1034                         {
1035                                 v = wcross_origin - wcross_oldorigin;
1036                                 v.x /= vid_conwidth;
1037                                 v.y /= vid_conheight;
1038                                 if(vdist(v, >, 0.01))
1039                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1040                         }
1041                         if(!autocvar_crosshair_hittest_showimpact)
1042                                 wcross_origin = wcross_oldorigin;
1043                 }
1044                 else
1045                         shottype = SHOTTYPE_HITWORLD;
1046
1047                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1048                 string wcross_name = "";
1049                 float wcross_scale, wcross_blur;
1050
1051         entity e = WEP_Null;
1052                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1053                 {
1054                         entity wepent = viewmodels[0]; // TODO: unhardcode
1055                         e = wepent.switchingweapon;
1056                         if(e)
1057                         {
1058                                 if(autocvar_crosshair_per_weapon)
1059                                 {
1060                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1061                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1062                                         //if (wcross_resolution == 0)
1063                                                 //return;
1064
1065                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1066                                         wcross_resolution *= e.w_crosshair_size;
1067                                         wcross_name = e.w_crosshair;
1068                                 }
1069                         }
1070                 }
1071
1072                 if(wcross_name == "")
1073                         wcross_name = strcat("gfx/crosshair", wcross_style);
1074
1075                 // MAIN CROSSHAIR COLOR DECISION
1076                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1077
1078                 if(autocvar_crosshair_effect_scalefade)
1079                 {
1080                         wcross_scale = wcross_resolution;
1081                         wcross_resolution = 1;
1082                 }
1083                 else
1084                 {
1085                         wcross_scale = 1;
1086                 }
1087
1088                 if(autocvar_crosshair_pickup)
1089                 {
1090                         float stat_pickup_time = STAT(LAST_PICKUP);
1091
1092                         if(pickup_crosshair_time < stat_pickup_time)
1093                         {
1094                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1095                                         pickup_crosshair_size = 1;
1096
1097                                 pickup_crosshair_time = stat_pickup_time;
1098                         }
1099
1100                         if(pickup_crosshair_size > 0)
1101                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1102                         else
1103                                 pickup_crosshair_size = 0;
1104
1105                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1106                 }
1107
1108                 // todo: make crosshair hit indication dependent on damage dealt
1109                 if(autocvar_crosshair_hitindication)
1110                 {
1111                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1112
1113                         if(unaccounted_damage)
1114                         {
1115                                 hitindication_crosshair_size = 1;
1116                         }
1117
1118                         if(hitindication_crosshair_size > 0)
1119                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1120                         else
1121                                 hitindication_crosshair_size = 0;
1122
1123                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1124                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1125                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1126                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1127                 }
1128
1129                 if(shottype == SHOTTYPE_HITENEMY)
1130                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1131                 if(shottype == SHOTTYPE_HITTEAM)
1132                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1133
1134                 f = fabs(autocvar_crosshair_effect_time);
1135                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1136                 {
1137                         wcross_changedonetime = time + f;
1138                 }
1139                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1140                 {
1141                         wcross_name_changestarttime = time;
1142                         wcross_name_changedonetime = time + f;
1143                         if(wcross_name_goal_prev_prev)
1144                                 strunzone(wcross_name_goal_prev_prev);
1145                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1146                         wcross_name_goal_prev = strzone(wcross_name);
1147                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1148                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1149                         wcross_resolution_goal_prev = wcross_resolution;
1150                 }
1151
1152                 wcross_scale_goal_prev = wcross_scale;
1153                 wcross_alpha_goal_prev = wcross_alpha;
1154                 wcross_color_goal_prev = wcross_color;
1155
1156                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1157                 {
1158                         wcross_blur = 1;
1159                         wcross_alpha *= 0.75;
1160                 }
1161                 else
1162                         wcross_blur = 0;
1163                 // *_prev is at time-frametime
1164                 // * is at wcross_changedonetime+f
1165                 // what do we have at time?
1166                 if(time < wcross_changedonetime)
1167                 {
1168                         f = frametime / (wcross_changedonetime - time + frametime);
1169                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1170                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1171                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1172                 }
1173
1174                 wcross_scale_prev = wcross_scale;
1175                 wcross_alpha_prev = wcross_alpha;
1176                 wcross_color_prev = wcross_color;
1177
1178                 MUTATOR_CALLHOOK(UpdateCrosshair);
1179
1180                 wcross_scale *= 1 - autocvar__menu_alpha;
1181                 wcross_alpha *= 1 - autocvar__menu_alpha;
1182                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1183
1184                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1185                 {
1186                         // crosshair rings for weapon stats
1187                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1188                         {
1189                                 // declarations and stats
1190                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1191                                 string ring_image = string_null, ring_inner_image = string_null;
1192                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1193
1194                                 ring_scale = autocvar_crosshair_ring_size;
1195
1196                                 float weapon_clipload, weapon_clipsize;
1197                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1198                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1199
1200                                 float vortex_charge, vortex_chargepool;
1201                                 vortex_charge = STAT(VORTEX_CHARGE);
1202                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1203
1204                                 float oknex_charge, oknex_chargepool;
1205                                 oknex_charge = STAT(OVERKILL_NEX_CHARGE);
1206                                 oknex_chargepool = STAT(OVERKILL_NEX_CHARGEPOOL);
1207
1208                                 float arc_heat = STAT(ARC_HEAT);
1209
1210                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1211                                         vortex_charge_movingavg = vortex_charge;
1212
1213                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1214
1215                                 // handle the values
1216                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1217                                 {
1218                                         if (vortex_chargepool || use_vortex_chargepool) {
1219                                                 use_vortex_chargepool = 1;
1220                                                 ring_inner_value = vortex_chargepool;
1221                                         } else {
1222                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1223                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1224                                         }
1225
1226                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1227                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1228                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1229
1230                                         // draw the outer ring to show the current charge of the weapon
1231                                         ring_value = vortex_charge;
1232                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1233                                         ring_rgb = wcross_color;
1234                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1235                                 }
1236                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge && autocvar_crosshair_ring_vortex)
1237                                 {
1238                                         if (oknex_chargepool || use_vortex_chargepool) {
1239                                                 use_vortex_chargepool = 1;
1240                                                 ring_inner_value = oknex_chargepool;
1241                                         } else {
1242                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge;
1243                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge - vortex_charge_movingavg), 1);
1244                                         }
1245
1246                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1247                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1248                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1249
1250                                         // draw the outer ring to show the current charge of the weapon
1251                                         ring_value = oknex_charge;
1252                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1253                                         ring_rgb = wcross_color;
1254                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1255                                 }
1256                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1257                                 {
1258                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1259                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1260                                         ring_rgb = wcross_color;
1261                                         ring_image = "gfx/crosshair_ring.tga";
1262                                 }
1263                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1264                                 {
1265                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1266                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1267                                         ring_rgb = wcross_color;
1268                                         ring_image = "gfx/crosshair_ring.tga";
1269                                 }
1270                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1271                                 {
1272                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1273                                         ring_scale = autocvar_crosshair_ring_reload_size;
1274                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1275                                         ring_rgb = wcross_color;
1276
1277                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1278                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1279                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1280                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1281                                         else
1282                                                 ring_image = "gfx/crosshair_ring.tga";
1283                                 }
1284                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1285                                 {
1286                                         ring_value = arc_heat;
1287                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1288                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1289                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1290                                         ring_image = "gfx/crosshair_ring.tga";
1291                                 }
1292
1293                                 // if in weapon switch animation, fade ring out/in
1294                                 if(autocvar_crosshair_effect_time > 0)
1295                                 {
1296                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1297                                         if (f >= 1)
1298                                         {
1299                                                 wcross_ring_prev = ((ring_image) ? true : false);
1300                                         }
1301
1302                                         if(wcross_ring_prev)
1303                                         {
1304                                                 if(f < 1)
1305                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1306                                         }
1307                                         else
1308                                         {
1309                                                 if(f < 1)
1310                                                         ring_alpha *= bound(0, f, 1);
1311                                         }
1312                                 }
1313
1314                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1315                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1316
1317                                 if (ring_value)
1318                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1319                         }
1320
1321 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1322                         MACRO_BEGIN { \
1323                                 if(wcross_blur > 0) \
1324                                 { \
1325                                         for(i = -2; i <= 2; ++i) \
1326                                         for(j = -2; j <= 2; ++j) \
1327                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1328                                 } \
1329                                 else \
1330                                 { \
1331                                         M(0,0,sz,wcross_name,wcross_alpha); \
1332                                 } \
1333                         } MACRO_END
1334
1335 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1336                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1337
1338 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1339                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1340
1341                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1342                         {
1343                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1344                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1345                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1346                                 f = 1 - f;
1347                         }
1348                         else
1349                         {
1350                                 f = 1;
1351                         }
1352                         wcross_name_alpha_goal_prev = f;
1353
1354                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1355                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1356
1357                         if(autocvar_crosshair_dot)
1358                         {
1359                                 vector wcross_color_old;
1360                                 wcross_color_old = wcross_color;
1361
1362                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1363                                         wcross_color = stov(autocvar_crosshair_dot_color);
1364
1365                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1366                                 // FIXME why don't we use wcross_alpha here?
1367                                 wcross_color = wcross_color_old;
1368                         }
1369                 }
1370         }
1371         else
1372         {
1373                 wcross_scale_prev = 0;
1374                 wcross_alpha_prev = 0;
1375                 wcross_scale_goal_prev = 0;
1376                 wcross_alpha_goal_prev = 0;
1377                 wcross_changedonetime = 0;
1378                 if(wcross_name_goal_prev)
1379                         strunzone(wcross_name_goal_prev);
1380                 wcross_name_goal_prev = string_null;
1381                 if(wcross_name_goal_prev_prev)
1382                         strunzone(wcross_name_goal_prev_prev);
1383                 wcross_name_goal_prev_prev = string_null;
1384                 wcross_name_changestarttime = 0;
1385                 wcross_name_changedonetime = 0;
1386                 wcross_name_alpha_goal_prev = 0;
1387                 wcross_name_alpha_goal_prev_prev = 0;
1388                 wcross_resolution_goal_prev = 0;
1389                 wcross_resolution_goal_prev_prev = 0;
1390         }
1391 }
1392
1393 const int MAX_SPECIALCOMMAND = 15;
1394 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1395 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1396 const float SPECIALCOMMAND_SPEED = 150;
1397 const float SPECIALCOMMAND_TURNSPEED = 2;
1398 const float SPECIALCOMMAND_SIZE = 0.025;
1399 const float SPECIALCOMMAND_CHANCE = 0.35;
1400 float sc_spawntime, sc_changetime;
1401 vector sc_color = '1 1 1';
1402 void SpecialCommand()
1403 {
1404         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1405                 return;
1406
1407         if(time >= sc_changetime)
1408         {
1409                 sc_changetime = time + 1;
1410                 sc_color = randomvec() * 1.5;
1411                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1412                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1413                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1414         }
1415         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1416
1417         if(!precache_pic("gfx/smile"))
1418                 return; // damn party poopers
1419
1420         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1421         {
1422                 vector slot = specialcommand_slots[j];
1423                 if(slot.y)
1424                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1425                 if(slot.z)
1426                         slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1427                 if(slot.y >= vid_conheight)
1428                         slot = '0 0 0';
1429
1430                 if(slot == '0 0 0')
1431                 {
1432                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1433                         {
1434                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1435                                 slot.y = 1; // start it off 0 so we can use it
1436                                 slot.z = random();
1437                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1438                                 vector newcolor = randomvec() * 2;
1439                                 newcolor.x = bound(0.4, newcolor.x, 1);
1440                                 newcolor.y = bound(0.4, newcolor.y, 1);
1441                                 newcolor.z = bound(0.4, newcolor.z, 1);
1442                                 specialcommand_colors[j] = newcolor;
1443                         }
1444                 }
1445                 else
1446                 {
1447                         vector splash_size = '0 0 0';
1448                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1449                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1450                         drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1451                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1452                 }
1453
1454                 specialcommand_slots[j] = slot;
1455         }
1456 }
1457
1458 void HUD_Draw(entity this)
1459 {
1460         // if we don't know gametype and scores yet avoid drawing the scoreboard
1461         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1462         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1463         // cl_deathscoreboard would show the scoreboard and so on
1464         if(!gametype)
1465                 return;
1466
1467         Hud_Dynamic_Frame();
1468
1469         if(!intermission)
1470         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1471         {
1472                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1473         }
1474         else if(STAT(FROZEN))
1475         {
1476                 vector col = '0.25 0.90 1';
1477                 if(STAT(REVIVE_PROGRESS))
1478                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1479                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1480         }
1481
1482         HUD_Scale_Enable();
1483         if(!intermission)
1484         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1485         {
1486                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1487                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1488                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1489         }
1490         else if(STAT(CAPTURE_PROGRESS))
1491         {
1492                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1493                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1494         }
1495         else if(STAT(REVIVE_PROGRESS))
1496         {
1497                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1498                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1499         }
1500         HUD_Scale_Disable();
1501
1502         if(autocvar_r_letterbox == 0)
1503                 if(autocvar_viewsize < 120)
1504                 {
1505                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1506                                 Accuracy_LoadLevels();
1507
1508                         HUD_Main();
1509                         HUD_Scale_Disable();
1510                 }
1511
1512         // crosshair goes VERY LAST
1513         SpecialCommand();
1514         UpdateDamage();
1515         HUD_Crosshair(this);
1516         HitSound();
1517 }
1518
1519 void ViewLocation_Mouse()
1520 {
1521         if(spectatee_status)
1522                 return; // don't draw it as spectator!
1523
1524         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1525         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1526         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1527
1528         //float cursor_alpha = 1 - autocvar__menu_alpha;
1529         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1530 }
1531
1532 bool ov_enabled;
1533 float oldr_nearclip;
1534 float oldr_farclip_base;
1535 float oldr_farclip_world;
1536 float oldr_novis;
1537 float oldr_useportalculling;
1538 float oldr_useinfinitefarclip;
1539
1540 void cl_notice_run();
1541
1542 float prev_myteam;
1543 int lasthud;
1544 float vh_notice_time;
1545 void WaypointSprite_Load();
1546 void CSQC_UpdateView(entity this, float w, float h)
1547 {
1548     TC(int, w); TC(int, h);
1549         entity e;
1550         float fov;
1551         float f;
1552         vector vf_size, vf_min;
1553         float a;
1554
1555         execute_next_frame();
1556
1557         ++framecount;
1558
1559         stats_get();
1560         hud = STAT(HUD);
1561
1562         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1563                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1564
1565         lasthud = hud;
1566
1567         HUD_Scale_Disable();
1568
1569         if(autocvar__hud_showbinds_reload) // menu can set this one
1570         {
1571                 db_close(binddb);
1572                 binddb = db_create();
1573                 cvar_set("_hud_showbinds_reload", "0");
1574         }
1575
1576         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1577                 view_quality = getproperty(VF_MINFPS_QUALITY);
1578         else
1579                 view_quality = 1;
1580
1581         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1582         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1583
1584         vf_size = getpropertyvec(VF_SIZE);
1585         vf_min = getpropertyvec(VF_MIN);
1586         vid_width = vf_size.x;
1587         vid_height = vf_size.y;
1588
1589         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1590         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1591
1592         WaypointSprite_Load();
1593
1594         CSQCPlayer_SetCamera();
1595
1596         if(player_localentnum <= maxclients) // is it a client?
1597                 current_player = player_localentnum - 1;
1598         else // then player_localentnum is the vehicle I'm driving
1599                 current_player = player_localnum;
1600         myteam = entcs_GetTeam(current_player);
1601
1602         if(myteam != prev_myteam)
1603         {
1604                 myteamcolors = colormapPaletteColor(myteam, 1);
1605                 FOREACH(hud_panels, true, it.update_time = time);
1606                 prev_myteam = myteam;
1607         }
1608
1609         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1610
1611         float is_dead = (STAT(HEALTH) <= 0);
1612
1613         // FIXME do we need this hack?
1614         if(isdemo())
1615         {
1616                 // in demos, input_buttons do not work
1617                 button_zoom = (autocvar__togglezoom == "-");
1618         }
1619         else if(button_zoom
1620                 && autocvar_cl_unpress_zoom_on_death
1621                 && (spectatee_status >= 0)
1622                 && (is_dead || intermission))
1623         {
1624                 // no zoom while dead or in intermission please
1625                 localcmd("-zoom\n");
1626                 button_zoom = false;
1627         }
1628
1629         // abused multiple places below
1630         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1631         if(!local_player)
1632                 local_player = this; // fall back!
1633
1634         // event chase camera
1635         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1636         {
1637                 if(STAT(CAMERA_SPECTATOR))
1638                 {
1639                         if(spectatee_status > 0)
1640                         {
1641                                 if(!autocvar_chase_active)
1642                                 {
1643                                         cvar_set("chase_active", "-2");
1644                                         goto skip_eventchase_death;
1645                                 }
1646                         }
1647                         else if(autocvar_chase_active == -2)
1648                                 cvar_set("chase_active", "0");
1649
1650                         if(autocvar_chase_active == -2)
1651                                 goto skip_eventchase_death;
1652                 }
1653                 else if(autocvar_chase_active == -2)
1654                         cvar_set("chase_active", "0");
1655
1656                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1657
1658                 float vehicle_viewdist = 0;
1659                 vector vehicle_viewofs = '0 0 0';
1660
1661                 if(vehicle_chase)
1662                 {
1663                         if(hud != HUD_BUMBLEBEE_GUN)
1664                         {
1665                                 Vehicle info = Vehicles_from(hud);
1666                                 vehicle_viewdist = info.height;
1667                                 vehicle_viewofs = info.view_ofs;
1668                         }
1669                 }
1670
1671                 if(WantEventchase(this))
1672                 {
1673                         vector current_view_origin_override = '0 0 0';
1674                         vector view_offset_override = '0 0 0';
1675                         float chase_distance_override = 0;
1676                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1677                         if(custom_eventchase)
1678                         {
1679                                 current_view_origin_override = M_ARGV(0, vector);
1680                                 view_offset_override = M_ARGV(1, vector);
1681                                 chase_distance_override = M_ARGV(0, float);
1682                         }
1683                         eventchase_running = true;
1684
1685                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1686                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1687                         if (custom_eventchase)
1688                                 current_view_origin = current_view_origin_override;
1689
1690                         // detect maximum viewoffset and use it
1691                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1692                         if(vehicle_chase)
1693                         {
1694                                 if(vehicle_viewofs)
1695                                         view_offset = vehicle_viewofs;
1696                                 else
1697                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1698                         }
1699                         if (custom_eventchase)
1700                                 view_offset = view_offset_override;
1701
1702                         if(view_offset)
1703                         {
1704                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1705                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1706                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1707                         }
1708
1709                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1710                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1711                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1712                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1713
1714                         // make the camera smooth back
1715                         float chase_distance = autocvar_cl_eventchase_distance;
1716                         if(vehicle_chase)
1717                         {
1718                                 if(vehicle_viewofs)
1719                                         chase_distance = vehicle_viewdist;
1720                                 else
1721                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1722                         }
1723                         if (custom_eventchase)
1724                                 chase_distance = chase_distance_override;
1725
1726                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1727                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1728                         else if(eventchase_current_distance != chase_distance)
1729                                 eventchase_current_distance = chase_distance;
1730
1731                         makevectors(view_angles);
1732
1733                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1734                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1735
1736                         // If the boxtrace fails, revert back to line tracing.
1737                         if(!local_player.viewloc)
1738                         if(trace_startsolid)
1739                         {
1740                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1741                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1742                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1743                         }
1744                         else { setproperty(VF_ORIGIN, trace_endpos); }
1745
1746                         if(!local_player.viewloc)
1747                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1748                 }
1749                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1750                 {
1751                         eventchase_running = false;
1752                         cvar_set("chase_active", "0");
1753                         eventchase_current_distance = 0; // start from 0 next time
1754                 }
1755         }
1756         // workaround for camera stuck between player's legs when using chase_active 1
1757         // because the engine stops updating the chase_active camera when the game ends
1758         else if(intermission)
1759         {
1760                 cvar_settemp("chase_active", "-1");
1761                 eventchase_current_distance = 0;
1762         }
1763
1764         LABEL(skip_eventchase_death);
1765
1766         // do lockview after event chase camera so that it still applies whenever necessary.
1767         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1768         {
1769                 setproperty(VF_ORIGIN, freeze_org);
1770                 setproperty(VF_ANGLES, freeze_ang);
1771         }
1772         else
1773         {
1774                 freeze_org = getpropertyvec(VF_ORIGIN);
1775                 freeze_ang = getpropertyvec(VF_ANGLES);
1776         }
1777
1778         WarpZone_FixView();
1779         //WarpZone_FixPMove();
1780
1781         vector ov_org = '0 0 0';
1782         vector ov_mid = '0 0 0';
1783         vector ov_worldmin = '0 0 0';
1784         vector ov_worldmax = '0 0 0';
1785         if(autocvar_cl_orthoview)
1786         {
1787                 ov_worldmin = mi_picmin;
1788                 ov_worldmax = mi_picmax;
1789
1790                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1791                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1792                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1793
1794                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1795                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1796
1797                 float ov_nearest = vlen(ov_org - vec3(
1798                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1799                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1800                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1801                 ));
1802
1803                 float ov_furthest = 0;
1804                 float dist = 0;
1805
1806                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1807                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1808                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1809                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1810                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1811                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1812                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1813                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1814
1815                 if(!ov_enabled)
1816                 {
1817                         oldr_nearclip = cvar("r_nearclip");
1818                         oldr_farclip_base = cvar("r_farclip_base");
1819                         oldr_farclip_world = cvar("r_farclip_world");
1820                         oldr_novis = cvar("r_novis");
1821                         oldr_useportalculling = cvar("r_useportalculling");
1822                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1823                 }
1824
1825                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1826                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1827                 cvar_settemp("r_farclip_world", "0");
1828                 cvar_settemp("r_novis", "1");
1829                 cvar_settemp("r_useportalculling", "0");
1830                 cvar_settemp("r_useinfinitefarclip", "0");
1831
1832                 setproperty(VF_ORIGIN, ov_org);
1833                 setproperty(VF_ANGLES, '90 0 0');
1834
1835                 ov_enabled = true;
1836
1837                 #if 0
1838                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1839                         vtos(ov_org),
1840                         vtos(getpropertyvec(VF_ANGLES)),
1841                         ov_distance,
1842                         ov_nearest,
1843                         ov_furthest);
1844                 #endif
1845         }
1846         else
1847         {
1848                 if(ov_enabled)
1849                 {
1850                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1851                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1852                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1853                         cvar_set("r_novis", ftos(oldr_novis));
1854                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1855                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1856                 }
1857                 ov_enabled = false;
1858         }
1859
1860         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1861         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1862         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1863                 viewmodel_draw(viewmodels[slot]);
1864
1865         // Render the Scene
1866         view_origin = getpropertyvec(VF_ORIGIN);
1867         view_angles = getpropertyvec(VF_ANGLES);
1868         makevectors(view_angles);
1869         view_forward = v_forward;
1870         view_right = v_right;
1871         view_up = v_up;
1872
1873 #ifdef BLURTEST
1874         if(time > blurtest_time0 && time < blurtest_time1)
1875         {
1876                 float r, t;
1877
1878                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1879                 r = t * blurtest_radius;
1880                 f = 1 / (t ** blurtest_power) - 1;
1881
1882                 cvar_set("r_glsl_postprocess", "1");
1883                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1884         }
1885         else
1886         {
1887                 cvar_set("r_glsl_postprocess", "0");
1888                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1889         }
1890 #endif
1891
1892         TargetMusic_Advance();
1893         Fog_Force();
1894
1895         if(drawtime == 0)
1896                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1897         else
1898                 drawframetime = bound(0.000001, time - drawtime, 1);
1899         drawtime = time;
1900
1901         // watch for gametype changes here...
1902         // in ParseStuffCMD the cmd isn't executed yet :/
1903         // might even be better to add the gametype to TE_CSQC_INIT...?
1904         if(!postinit)
1905                 PostInit();
1906
1907         if(intermission && !intermission_time)
1908                 intermission_time = time;
1909
1910         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1911         {
1912                 if(calledhooks & HOOK_START)
1913                 {
1914                         localcmd("\ncl_hook_gameend\n");
1915                         calledhooks |= HOOK_END;
1916                 }
1917         }
1918
1919         Announcer();
1920
1921         fov = autocvar_fov;
1922         if(fov <= 59.5)
1923         {
1924                 if(!zoomscript_caught)
1925                 {
1926                         localcmd("+button9\n");
1927                         zoomscript_caught = 1;
1928                 }
1929         }
1930         else
1931         {
1932                 if(zoomscript_caught)
1933                 {
1934                         localcmd("-button9\n");
1935                         zoomscript_caught = 0;
1936                 }
1937         }
1938
1939         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1940
1941         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1942         {
1943                 entity wepent = viewmodels[slot];
1944
1945                 if(wepent.last_switchweapon != wepent.switchweapon)
1946                 {
1947                         weapontime = time;
1948                         wepent.last_switchweapon = wepent.switchweapon;
1949                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1950                         {
1951                                 localcmd("-zoom\n");
1952                                 button_zoom = false;
1953                         }
1954                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1955                         {
1956                                 localcmd("-fire\n");
1957                                 localcmd("-fire2\n");
1958                                 button_attack2 = false;
1959                         }
1960                 }
1961                 if(wepent.last_activeweapon != wepent.activeweapon)
1962                 {
1963                         wepent.last_activeweapon = wepent.activeweapon;
1964
1965                         e = wepent.activeweapon;
1966                         if(e.netname != "")
1967                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1968                         else if(slot == 0)
1969                                 localcmd("\ncl_hook_activeweapon none\n");
1970                 }
1971         }
1972
1973         // ALWAYS Clear Current Scene First
1974         clearscene();
1975
1976         setproperty(VF_ORIGIN, view_origin);
1977         setproperty(VF_ANGLES, view_angles);
1978
1979         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1980         setproperty(VF_SIZE, vf_size);
1981         setproperty(VF_MIN, vf_min);
1982
1983         // Assign Standard Viewflags
1984         // Draw the World (and sky)
1985         setproperty(VF_DRAWWORLD, 1);
1986
1987         // Set the console size vars
1988         vid_conwidth = autocvar_vid_conwidth;
1989         vid_conheight = autocvar_vid_conheight;
1990         vid_pixelheight = autocvar_vid_pixelheight;
1991
1992         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1993         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1994         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1995
1996         if(camera_active) // Camera for demo playback
1997         {
1998                 if(autocvar_camera_enable)
1999                         CSQC_Demo_Camera();
2000                 else
2001                 {
2002                         cvar_set("chase_active", ftos(chase_active_backup));
2003                         cvar_set("cl_demo_mousegrab", "0");
2004                         camera_active = false;
2005                 }
2006         }
2007         else
2008         {
2009 #ifdef CAMERATEST
2010                 if(autocvar_camera_enable)
2011 #else
2012                 if(autocvar_camera_enable && isdemo())
2013 #endif
2014                 {
2015                         // Enable required Darkplaces cvars
2016                         chase_active_backup = autocvar_chase_active;
2017                         cvar_set("chase_active", "2");
2018                         cvar_set("cl_demo_mousegrab", "1");
2019                         camera_active = true;
2020                         camera_mode = false;
2021                 }
2022         }
2023
2024         // Draw the Crosshair
2025         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2026
2027         // Draw the Engine Status Bar (the default Quake HUD)
2028         setproperty(VF_DRAWENGINESBAR, 0);
2029
2030         // Update the mouse position
2031         /*
2032            mousepos_x = vid_conwidth;
2033            mousepos_y = vid_conheight;
2034            mousepos = mousepos*0.5 + getmousepos();
2035          */
2036
2037         IL_EACH(g_drawables, it.draw, it.draw(it));
2038
2039         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
2040         renderscene();
2041
2042         // now switch to 2D drawing mode by calling a 2D drawing function
2043         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2044         // next R_RenderScene call
2045         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2046
2047         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2048         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2049         {
2050                 // apply night vision effect
2051                 vector tc_00, tc_01, tc_10, tc_11;
2052                 vector rgb = '0 0 0';
2053
2054                 if(!nightvision_noise)
2055                 {
2056                         nightvision_noise = new(nightvision_noise);
2057                 }
2058                 if(!nightvision_noise2)
2059                 {
2060                         nightvision_noise2 = new(nightvision_noise2);
2061                 }
2062
2063                 // color tint in yellow
2064                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2065
2066                 // draw BG
2067                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2068                 rgb = '1 1 1';
2069                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2070                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2071                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2072                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2073                 tc_11 = tc_01 + tc_10 - tc_00;
2074                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2075                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2076                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2077                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2078                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2079                 R_EndPolygon();
2080
2081                 // draw FG
2082                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2083                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2084                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2085                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2086                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2087                 tc_11 = tc_01 + tc_10 - tc_00;
2088                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2089                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2090                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2091                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2092                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2093                 R_EndPolygon();
2094         }
2095
2096         if(autocvar_cl_reticle)
2097         {
2098                 string reticle_image = string_null;
2099                 bool wep_zoomed = false;
2100                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2101                 {
2102                         entity wepe = viewmodels[slot];
2103                         Weapon wep = wepe.activeweapon;
2104                         if(wep != WEP_Null && wep.wr_zoom)
2105                         {
2106                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2107                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2108                                         reticle_image = wep.w_reticle;
2109                                 wep_zoomed += do_zoom;
2110                         }
2111                 }
2112                 // Draw the aiming reticle for weapons that use it
2113                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2114                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2115                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2116                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2117                 {
2118                         // no zoom reticle while dead
2119                         reticle_type = 0;
2120                 }
2121                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2122                 {
2123                         if(reticle_image) { reticle_type = 2; }
2124                         else { reticle_type = 0; }
2125                 }
2126                 else if(button_zoom || zoomscript_caught)
2127                 {
2128                         // normal zoom
2129                         reticle_type = 1;
2130                 }
2131
2132                 if(reticle_type)
2133                 {
2134                         if(autocvar_cl_reticle_stretch)
2135                         {
2136                                 reticle_size.x = vid_conwidth;
2137                                 reticle_size.y = vid_conheight;
2138                                 reticle_pos.x = 0;
2139                                 reticle_pos.y = 0;
2140                         }
2141                         else
2142                         {
2143                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2144                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2145                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2146                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2147                         }
2148
2149                         if(zoomscript_caught)
2150                                 f = 1;
2151                         else
2152                                 f = current_zoomfraction;
2153
2154                         if(f)
2155                         {
2156                                 switch(reticle_type)
2157                                 {
2158                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2159                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2160                                 }
2161                         }
2162                 }
2163         }
2164         else
2165         {
2166                 if(reticle_type != 0) { reticle_type = 0; }
2167         }
2168
2169
2170         // improved polyblend
2171         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2172         {
2173                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2174                 vector liquidcolor;
2175
2176                 switch(pointcontents(view_origin))
2177                 {
2178                         case CONTENT_WATER:
2179                                 liquidalpha = autocvar_hud_contents_water_alpha;
2180                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2181                                 incontent = 1;
2182                                 break;
2183
2184                         case CONTENT_LAVA:
2185                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2186                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2187                                 incontent = 1;
2188                                 break;
2189
2190                         case CONTENT_SLIME:
2191                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2192                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2193                                 incontent = 1;
2194                                 break;
2195
2196                         default:
2197                                 liquidalpha = 0;
2198                                 liquidcolor = '0 0 0';
2199                                 incontent = 0;
2200                                 break;
2201                 }
2202
2203                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2204                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2205                         contentfadetime = autocvar_hud_contents_fadeintime;
2206                         liquidalpha_prev = liquidalpha;
2207                         liquidcolor_prev = liquidcolor;
2208                 }
2209                 else
2210                         contentfadetime = autocvar_hud_contents_fadeouttime;
2211
2212                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2213                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2214
2215                 if(contentavgalpha)
2216                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2217
2218                 if(autocvar_hud_postprocessing)
2219                 {
2220                         if(autocvar_hud_contents_blur && contentavgalpha)
2221                         {
2222                                 content_blurpostprocess.x = 1;
2223                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2224                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2225                         }
2226                         else
2227                         {
2228                                 content_blurpostprocess.x = 0;
2229                                 content_blurpostprocess.y = 0;
2230                                 content_blurpostprocess.z = 0;
2231                         }
2232                 }
2233         }
2234
2235         if(autocvar_hud_damage && !STAT(FROZEN))
2236         {
2237                 splash_size.x = max(vid_conwidth, vid_conheight);
2238                 splash_size.y = max(vid_conwidth, vid_conheight);
2239                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2240                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2241
2242                 float myhealth_flash_temp;
2243                 myhealth = STAT(HEALTH);
2244
2245                 // fade out
2246                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2247                 // add new damage
2248                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2249
2250                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2251                 pain_threshold = autocvar_hud_damage_pain_threshold;
2252                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2253                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2254
2255                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2256                 {
2257                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2258                 }
2259
2260                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2261
2262                 if(myhealth_prev < 1)
2263                 {
2264                         if(myhealth >= 1)
2265                         {
2266                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2267                                 myhealth_flash_temp = 0;
2268                         }
2269                         else
2270                         {
2271                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2272                         }
2273                 }
2274
2275                 if(spectatee_status == -1 || intermission)
2276                 {
2277                         myhealth_flash = 0; // observing, or match ended
2278                         myhealth_flash_temp = 0;
2279                 }
2280
2281                 myhealth_prev = myhealth;
2282
2283                 // IDEA: change damage color/picture based on player model for robot/alien species?
2284                 // pro: matches model better
2285                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2286                 // maybe different reddish pics?
2287                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2288                 {
2289                         if(autocvar_cl_gentle_damage == 2)
2290                         {
2291                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2292                                         myhealth_gentlergb = randomvec();
2293                         }
2294                         else
2295                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2296
2297                         if(myhealth_flash_temp > 0)
2298                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2299                 }
2300                 else if(myhealth_flash_temp > 0)
2301                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2302
2303                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2304                 {
2305                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2306                         {
2307                                 damage_blurpostprocess.x = 1;
2308                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2309                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2310                         }
2311                         else
2312                         {
2313                                 damage_blurpostprocess.x = 0;
2314                                 damage_blurpostprocess.y = 0;
2315                                 damage_blurpostprocess.z = 0;
2316                         }
2317                 }
2318         }
2319
2320         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2321         float e2 = (autocvar_hud_powerup != 0);
2322         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2323         {
2324                 // enable or disable rendering types if they are used or not
2325                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2326                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2327
2328                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2329                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2330                 {
2331                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2332                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2333                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2334                         {
2335                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2336                                 old_blurradius = blurradius;
2337                                 old_bluralpha = bluralpha;
2338                         }
2339                 }
2340                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2341                 {
2342                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2343                         old_blurradius = 0;
2344                         old_bluralpha = 0;
2345                 }
2346
2347                 // edge detection postprocess handling done second (used by hud_powerup)
2348                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2349                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2350                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2351
2352                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2353
2354                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2355                 {
2356                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2357                         {
2358                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2359                                 old_sharpen_intensity = sharpen_intensity;
2360                         }
2361                 }
2362                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2363                 {
2364                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2365                         old_sharpen_intensity = 0;
2366                 }
2367
2368                 if(cvar("r_glsl_postprocess") == 0)
2369                         cvar_set("r_glsl_postprocess", "2");
2370         }
2371         else if(cvar("r_glsl_postprocess") == 2)
2372                 cvar_set("r_glsl_postprocess", "0");
2373
2374         /*if(gametype == MAPINFO_TYPE_CTF)
2375           {
2376           ctf_view();
2377           } else */
2378
2379         // draw 2D entities
2380         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2381         Draw_ShowNames_All();
2382 #if ENABLE_DEBUGDRAW
2383         Debug_Draw();
2384 #endif
2385
2386         scoreboard_active = Scoreboard_WouldDraw();
2387
2388         HUD_Draw(this); // this parameter for deep vehicle function
2389
2390         if(NextFrameCommand)
2391         {
2392                 localcmd("\n", NextFrameCommand, "\n");
2393                 NextFrameCommand = string_null;
2394         }
2395
2396         // we must do this check AFTER a frame was rendered, or it won't work
2397         if(cs_project_is_b0rked == 0)
2398         {
2399                 string w0, h0;
2400                 w0 = ftos(autocvar_vid_conwidth);
2401                 h0 = ftos(autocvar_vid_conheight);
2402                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2403                 //setproperty(VF_FOV, '90 90 0');
2404                 setproperty(VF_ORIGIN, '0 0 0');
2405                 setproperty(VF_ANGLES, '0 0 0');
2406                 setproperty(VF_PERSPECTIVE, 1);
2407                 makevectors('0 0 0');
2408                 vector v1, v2;
2409                 cvar_set("vid_conwidth", "800");
2410                 cvar_set("vid_conheight", "600");
2411                 v1 = cs_project(v_forward);
2412                 cvar_set("vid_conwidth", "640");
2413                 cvar_set("vid_conheight", "480");
2414                 v2 = cs_project(v_forward);
2415                 if(v1 == v2)
2416                         cs_project_is_b0rked = 1;
2417                 else
2418                         cs_project_is_b0rked = -1;
2419                 cvar_set("vid_conwidth", w0);
2420                 cvar_set("vid_conheight", h0);
2421         }
2422
2423         if(autocvar__hud_configure)
2424                 HUD_Panel_Mouse();
2425         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2426                 HUD_Minigame_Mouse();
2427         else if(QuickMenu_IsOpened())
2428                 QuickMenu_Mouse();
2429         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2430                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2431         else
2432                 HUD_Radar_Mouse();
2433
2434         cl_notice_run();
2435         unpause_update();
2436         Net_Flush();
2437
2438         // let's reset the view back to normal for the end
2439         setproperty(VF_MIN, '0 0 0');
2440         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2441
2442         IL_ENDFRAME();
2443 }
2444
2445
2446 // following vectors must be global to allow seamless switching between camera modes
2447 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2448 void CSQC_Demo_Camera()
2449 {
2450         float speed, attenuation, dimensions;
2451         vector tmp, delta;
2452
2453         if( autocvar_camera_reset || !camera_mode )
2454         {
2455                 camera_offset = '0 0 0';
2456                 current_angles = '0 0 0';
2457                 camera_direction = '0 0 0';
2458                 camera_offset.z += 30;
2459                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2460                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2461                 current_origin = view_origin;
2462                 current_camera_offset  = camera_offset;
2463                 cvar_set("camera_reset", "0");
2464                 camera_mode = CAMERA_CHASE;
2465         }
2466
2467         // Camera angles
2468         if( camera_roll )
2469                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2470
2471         if(autocvar_camera_look_player)
2472         {
2473                 vector dir;
2474                 float n;
2475
2476                 dir = normalize(view_origin - current_position);
2477                 n = mouse_angles.z;
2478                 mouse_angles = vectoangles(dir);
2479                 mouse_angles.x = mouse_angles.x * -1;
2480                 mouse_angles.z = n;
2481         }
2482         else
2483         {
2484                 tmp = getmousepos() * 0.1;
2485                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2486                 {
2487                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2488                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2489                 }
2490         }
2491
2492         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2493         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2494         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2495         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2496
2497         // Fix difference when angles don't have the same sign
2498         delta = '0 0 0';
2499         if(mouse_angles.y < -60 && current_angles.y > 60)
2500                 delta = '0 360 0';
2501         if(mouse_angles.y > 60 && current_angles.y < -60)
2502                 delta = '0 -360 0';
2503
2504         if(autocvar_camera_look_player)
2505                 attenuation = autocvar_camera_look_attenuation;
2506         else
2507                 attenuation = autocvar_camera_speed_attenuation;
2508
2509         attenuation = 1 / max(1, attenuation);
2510         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2511
2512         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2513         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2514         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2515         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2516
2517         // Camera position
2518         tmp = '0 0 0';
2519         dimensions = 0;
2520
2521         if( camera_direction.x )
2522         {
2523                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2524                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2525                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2526                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2527                 ++dimensions;
2528         }
2529
2530         if( camera_direction.y )
2531         {
2532                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2533                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2534                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2535                 ++dimensions;
2536         }
2537
2538         if( camera_direction.z )
2539         {
2540                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2541                 ++dimensions;
2542         }
2543
2544         if(autocvar_camera_free)
2545                 speed = autocvar_camera_speed_free;
2546         else
2547                 speed = autocvar_camera_speed_chase;
2548
2549         if(dimensions)
2550         {
2551                 speed = speed * sqrt(1 / dimensions);
2552                 camera_offset += tmp * speed;
2553         }
2554
2555         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2556
2557         // Camera modes
2558         if( autocvar_camera_free )
2559         {
2560                 if ( camera_mode == CAMERA_CHASE )
2561                 {
2562                         current_camera_offset = current_origin + current_camera_offset;
2563                         camera_offset = current_origin + camera_offset;
2564                 }
2565
2566                 camera_mode = CAMERA_FREE;
2567                 current_position = current_camera_offset;
2568         }
2569         else
2570         {
2571                 if ( camera_mode == CAMERA_FREE )
2572                 {
2573                         current_origin = view_origin;
2574                         camera_offset = camera_offset - current_origin;
2575                         current_camera_offset = current_camera_offset - current_origin;
2576                 }
2577
2578                 camera_mode = CAMERA_CHASE;
2579
2580                 if(autocvar_camera_chase_smoothly)
2581                         current_origin += (view_origin - current_origin) * attenuation;
2582                 else
2583                         current_origin = view_origin;
2584
2585                 current_position = current_origin + current_camera_offset;
2586         }
2587
2588         setproperty(VF_ANGLES, current_angles);
2589         setproperty(VF_ORIGIN, current_position);
2590 }