qcsrc/client/weapons/projectile.qc

   1 #if defined(CSQC)
   2         #include "../../dpdefs/csprogsdefs.qc"
   3     #include "../Defs.qc"
   4     #include "../../common/constants.qh"
   5     #include "../../warpzonelib/anglestransform.qh"
   6     #include "../../common/util.qh"
   7     #include "../../common/nades.qh"
   8     #include "../../common/buffs.qh"
   9     #include "../autocvars.qh"
  10     #include "../../csqcmodellib/interpolate.qh"
  11     #include "../movetypes.qh"
  12     #include "../main.qh"
  13     #include "../../csqcmodellib/cl_model.qh"
  14     #include "projectile.qh"
  15     #include "../../server/t_items.qh"
  16 #elif defined(MENUQC)
  17 #elif defined(SVQC)
  18 #endif
  19
  20 .vector iorigin1, iorigin2;
  21 .float spawntime;
  22 .vector trail_oldorigin;
  23 .float trail_oldtime;
  24 .float fade_time, fade_rate;
  25
  26 void SUB_Stop()
  27 {
  28         self.move_velocity = self.move_avelocity = '0 0 0';
  29         self.move_movetype = MOVETYPE_NONE;
  30 }
  31
  32 .float alphamod;
  33 .int count; // set if clientside projectile
  34 .int cnt; // sound index
  35 .float gravity;
  36 .int snd_looping;
  37 .bool silent;
  38
  39 void Projectile_ResetTrail(vector to)
  40 {
  41         self.trail_oldorigin = to;
  42         self.trail_oldtime = time;
  43 }
  44
  45 void Projectile_DrawTrail(vector to)
  46 {
  47         vector from;
  48         float t0;
  49
  50         from = self.trail_oldorigin;
  51         t0 = self.trail_oldtime;
  52         self.trail_oldorigin = to;
  53         self.trail_oldtime = time;
  54
  55         // force the effect even for stationary firemine
  56         if(self.cnt == PROJECTILE_FIREMINE)
  57                 if(from == to)
  58                         from.z += 1;
  59
  60         if (self.traileffect)
  61         {
  62                 particles_alphamin = particles_alphamax = particles_fade = sqrt(self.alpha);
  63                 boxparticles(self.traileffect, self, from, to, self.velocity, self.velocity, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE | PARTICLES_DRAWASTRAIL);
  64         }
  65 }
  66
  67 void Projectile_Draw()
  68 {
  69         vector rot;
  70         vector trailorigin;
  71         int f;
  72         bool drawn;
  73         float t;
  74         float a;
  75
  76         f = self.move_flags;
  77
  78         if(self.count & 0x80)
  79         {
  80                 //self.move_flags &= ~FL_ONGROUND;
  81                 if(self.move_movetype == MOVETYPE_NONE || self.move_movetype == MOVETYPE_FLY)
  82                         Movetype_Physics_NoMatchServer();
  83                         // the trivial movetypes do not have to match the
  84                         // server's ticrate as they are ticrate independent
  85                         // NOTE: this assumption is only true if MOVETYPE_FLY
  86                         // projectiles detonate on impact. If they continue
  87                         // moving, we might still be ticrate dependent.
  88                 else
  89                         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  90                 if(!(self.move_flags & FL_ONGROUND))
  91                         if(self.velocity != '0 0 0')
  92                                 self.move_angles = self.angles = vectoangles(self.velocity);
  93         }
  94         else
  95         {
  96                 InterpolateOrigin_Do();
  97         }
  98
  99         if(self.count & 0x80)
 100         {
 101                 drawn = (time >= self.spawntime - 0.02);
 102                 t = max(time, self.spawntime);
 103         }
 104         else
 105         {
 106                 drawn = (self.iflags & IFLAG_VALID);
 107                 t = time;
 108         }
 109
 110         if(!(f & FL_ONGROUND))
 111         {
 112                 rot = '0 0 0';
 113                 switch(self.cnt)
 114                 {
 115                         /*
 116                         case PROJECTILE_GRENADE:
 117                                 rot = '-2000 0 0'; // forward
 118                                 break;
 119                         */
 120                         case PROJECTILE_GRENADE_BOUNCING:
 121                                 rot = '0 -1000 0'; // sideways
 122                                 break;
 123                         case PROJECTILE_HOOKBOMB:
 124                                 rot = '1000 0 0'; // forward
 125                                 break;
 126                         default:
 127                                 break;
 128                 }
 129
 130                 if(Nade_IDFromProjectile(self.cnt) != 0)
 131                         rot = self.avelocity;
 132
 133                 self.angles = AnglesTransform_ToAngles(AnglesTransform_Multiply(AnglesTransform_FromAngles(self.angles), rot * (t - self.spawntime)));
 134         }
 135
 136         vector ang;
 137         ang = self.angles;
 138         ang_x = -ang.x;
 139         makevectors(ang);
 140
 141         a = 1 - (time - self.fade_time) * self.fade_rate;
 142         self.alpha = bound(0, self.alphamod * a, 1);
 143         if(self.alpha <= 0)
 144                 drawn = 0;
 145         self.renderflags = 0;
 146
 147         trailorigin = self.origin;
 148         switch(self.cnt)
 149         {
 150                 case PROJECTILE_GRENADE:
 151                 case PROJECTILE_GRENADE_BOUNCING:
 152                         trailorigin += v_right * 1 + v_forward * -10;
 153                         break;
 154                 default:
 155                         break;
 156         }
 157
 158         if(Nade_IDFromProjectile(self.cnt) != 0)
 159                 trailorigin += v_up * 4;
 160
 161         if(drawn)
 162                 Projectile_DrawTrail(trailorigin);
 163         else
 164                 Projectile_ResetTrail(trailorigin);
 165
 166         self.drawmask = 0;
 167
 168         if(!drawn)
 169                 return;
 170
 171         switch(self.cnt)
 172         {
 173                 // Possibly add dlights here.
 174                 default:
 175                         break;
 176         }
 177
 178         self.drawmask = MASK_NORMAL;
 179 }
 180
 181 void loopsound(entity e, int ch, string samp, float vol, float attn)
 182 {
 183         if(self.silent)
 184                 return;
 185
 186         sound(e, ch, samp, vol, attn);
 187         e.snd_looping = ch;
 188 }
 189
 190 void Ent_RemoveProjectile()
 191 {
 192         if(self.count & 0x80)
 193         {
 194                 tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.05, MOVE_NORMAL, self);
 195                 Projectile_DrawTrail(trace_endpos);
 196         }
 197 }
 198
 199 void Ent_Projectile()
 200 {
 201         int f;
 202
 203         // projectile properties:
 204         //   kind (interpolated, or clientside)
 205         //
 206         //   modelindex
 207         //   origin
 208         //   scale
 209         //   if clientside:
 210         //     velocity
 211         //     gravity
 212         //   soundindex (hardcoded list)
 213         //   effects
 214         //
 215         // projectiles don't send angles, because they always follow the velocity
 216
 217         f = ReadByte();
 218         self.count = (f & 0x80);
 219         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES | IFLAG_ORIGIN;
 220         self.solid = SOLID_TRIGGER;
 221         //self.effects = EF_NOMODELFLAGS;
 222
 223         // this should make collisions with bmodels more exact, but it leads to
 224         // projectiles no longer being able to lie on a bmodel
 225         self.move_nomonsters = MOVE_WORLDONLY;
 226         if(f & 0x40)
 227                 self.move_flags |= FL_ONGROUND;
 228         else
 229                 self.move_flags &= ~FL_ONGROUND;
 230
 231         if(!self.move_time)
 232         {
 233                 // for some unknown reason, we don't need to care for
 234                 // sv_gameplayfix_delayprojectiles here.
 235                 self.move_time = time;
 236                 self.spawntime = time;
 237         }
 238         else
 239                 self.move_time = max(self.move_time, time);
 240
 241         if(!(self.count & 0x80))
 242                 InterpolateOrigin_Undo();
 243
 244         if(f & 1)
 245         {
 246                 self.origin_x = ReadCoord();
 247                 self.origin_y = ReadCoord();
 248                 self.origin_z = ReadCoord();
 249                 setorigin(self, self.origin);
 250                 if(self.count & 0x80)
 251                 {
 252                         self.velocity_x = ReadCoord();
 253                         self.velocity_y = ReadCoord();
 254                         self.velocity_z = ReadCoord();
 255                         if(f & 0x10)
 256                                 self.gravity = ReadCoord();
 257                         else
 258                                 self.gravity = 0; // none
 259                         self.move_origin = self.origin;
 260                         self.move_velocity = self.velocity;
 261                 }
 262
 263                 if(time == self.spawntime || (self.count & 0x80) || (f & 0x08))
 264                 {
 265                         self.trail_oldorigin = self.origin;
 266                         if(!(self.count & 0x80))
 267                                 InterpolateOrigin_Reset();
 268                 }
 269
 270                 if(f & 0x20)
 271                 {
 272                         self.fade_time = time + ReadByte() * ticrate;
 273                         self.fade_rate = 1 / (ReadByte() * ticrate);
 274                 }
 275                 else
 276                 {
 277                         self.fade_time = 0;
 278                         self.fade_rate = 0;
 279                 }
 280
 281                 self.team = ReadByte() - 1;
 282         }
 283
 284         if(f & 2)
 285         {
 286                 self.cnt = ReadByte();
 287
 288                 self.silent = (self.cnt & 0x80);
 289                 self.cnt = (self.cnt & 0x7F);
 290
 291                 self.scale = 1;
 292                 self.traileffect = 0;
 293                 switch(self.cnt)
 294                 {
 295                         case PROJECTILE_ELECTRO: setmodel(self, "models/ebomb.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 296                         case PROJECTILE_ROCKET: setmodel(self, "models/rocket.md3");self.traileffect = particleeffectnum("TR_ROCKET"); self.scale = 2; break;
 297                         case PROJECTILE_CRYLINK: setmodel(self, "models/plasmatrail.mdl");self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 298                         case PROJECTILE_CRYLINK_BOUNCING: setmodel(self, "models/plasmatrail.mdl");self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 299                         case PROJECTILE_ELECTRO_BEAM: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 300                         case PROJECTILE_GRENADE: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 301                         case PROJECTILE_GRENADE_BOUNCING: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 302                         case PROJECTILE_MINE: setmodel(self, "models/mine.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 303                         case PROJECTILE_BLASTER: setmodel(self, "models/laser.mdl");self.traileffect = particleeffectnum(""); break;
 304                         case PROJECTILE_HLAC: setmodel(self, "models/hlac_bullet.md3");self.traileffect = particleeffectnum(""); break;
 305                         case PROJECTILE_PORTO_RED: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_WIZSPIKE"); self.scale = 4; break;
 306                         case PROJECTILE_PORTO_BLUE: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_WIZSPIKE"); self.scale = 4; break;
 307                         case PROJECTILE_HOOKBOMB: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_KNIGHTSPIKE"); break;
 308                         case PROJECTILE_HAGAR: setmodel(self, "models/hagarmissile.mdl");self.traileffect = particleeffectnum("tr_hagar"); self.scale = 0.75; break;
 309                         case PROJECTILE_HAGAR_BOUNCING: setmodel(self, "models/hagarmissile.mdl");self.traileffect = particleeffectnum("tr_hagar"); self.scale = 0.75; break;
 310                         case PROJECTILE_NAPALM_FOUNTAIN: //self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("torch_small"); break;
 311                         case PROJECTILE_FIREBALL: self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("fireball"); break; // particle effect is good enough
 312                         case PROJECTILE_FIREMINE: self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("firemine"); break; // particle effect is good enough
 313                         case PROJECTILE_TAG: setmodel(self, "models/laser.mdl"); self.traileffect = particleeffectnum("TR_ROCKET"); break;
 314                         case PROJECTILE_FLAC: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; self.traileffect = particleeffectnum("TR_SEEKER"); break;
 315                         case PROJECTILE_SEEKER: setmodel(self, "models/tagrocket.md3"); self.traileffect = particleeffectnum("TR_SEEKER"); break;
 316
 317                         case PROJECTILE_MAGE_SPIKE: setmodel(self, "models/ebomb.mdl"); self.traileffect = particleeffectnum("TR_VORESPIKE"); break;
 318                         case PROJECTILE_SHAMBLER_LIGHTNING: setmodel(self, "models/ebomb.mdl"); self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 319
 320                         case PROJECTILE_RAPTORBOMB:    setmodel(self, "models/vehicles/clusterbomb.md3"); self.gravity = 1; self.avelocity = '0 0 180'; self.traileffect = particleeffectnum(""); break;
 321                         case PROJECTILE_RAPTORBOMBLET: setmodel(self, "models/vehicles/bomblet.md3");     self.gravity = 1; self.avelocity = '0 0 180'; self.traileffect = particleeffectnum(""); break;
 322                         case PROJECTILE_RAPTORCANNON:  setmodel(self, "models/plasmatrail.mdl"); self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 323
 324                         case PROJECTILE_SPIDERROCKET: setmodel(self, "models/vehicles/rocket02.md3"); self.traileffect = particleeffectnum("spiderbot_rocket_thrust"); break;
 325                         case PROJECTILE_WAKIROCKET:   setmodel(self, "models/vehicles/rocket01.md3");  self.traileffect = particleeffectnum("wakizashi_rocket_thrust"); break;
 326                         case PROJECTILE_WAKICANNON:   setmodel(self, "models/laser.mdl");  self.traileffect = particleeffectnum(""); break;
 327
 328                         case PROJECTILE_BUMBLE_GUN: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 329                         case PROJECTILE_BUMBLE_BEAM: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 330
 331                         case PROJECTILE_RPC: setmodel(self, "models/weapons/ok_rocket.md3");self.traileffect = particleeffectnum("TR_ROCKET"); break;
 332
 333                         default:
 334                                 if(Nade_IDFromProjectile(self.cnt) != 0) { setmodel(self, "models/weapons/v_ok_grenade.md3");self.traileffect = particleeffectnum(Nade_TrailEffect(self.cnt, self.team)); break; }
 335                                 error("Received invalid CSQC projectile, can't work with this!");
 336                                 break;
 337                 }
 338
 339                 self.mins = '0 0 0';
 340                 self.maxs = '0 0 0';
 341                 self.colormod = '0 0 0';
 342                 self.move_touch = SUB_Stop;
 343                 self.move_movetype = MOVETYPE_TOSS;
 344                 self.alphamod = 1;
 345
 346                 switch(self.cnt)
 347                 {
 348                         case PROJECTILE_ELECTRO:
 349                                 // only new engines support sound moving with object
 350                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/electro_fly.wav", VOL_BASE, ATTEN_NORM);
 351                                 self.mins = '0 0 -4';
 352                                 self.maxs = '0 0 -4';
 353                                 self.move_movetype = MOVETYPE_BOUNCE;
 354                                 self.move_touch = func_null;
 355                                 self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 356                                 self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 357                                 break;
 358                         case PROJECTILE_RPC:
 359                         case PROJECTILE_ROCKET:
 360                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 361                                 self.mins = '-3 -3 -3';
 362                                 self.maxs = '3 3 3';
 363                                 break;
 364                         case PROJECTILE_GRENADE:
 365                                 self.mins = '-3 -3 -3';
 366                                 self.maxs = '3 3 3';
 367                                 break;
 368                         case PROJECTILE_GRENADE_BOUNCING:
 369                                 self.mins = '-3 -3 -3';
 370                                 self.maxs = '3 3 3';
 371                                 self.move_movetype = MOVETYPE_BOUNCE;
 372                                 self.move_touch = func_null;
 373                                 self.move_bounce_factor = g_balance_mortar_bouncefactor;
 374                                 self.move_bounce_stopspeed = g_balance_mortar_bouncestop;
 375                                 break;
 376                         case PROJECTILE_SHAMBLER_LIGHTNING:
 377                                 self.mins = '-8 -8 -8';
 378                                 self.maxs = '8 8 8';
 379                                 self.scale = 2.5;
 380                                 self.avelocity = randomvec() * 720;
 381                                 break;
 382                         case PROJECTILE_MINE:
 383                                 self.mins = '-4 -4 -4';
 384                                 self.maxs = '4 4 4';
 385                                 break;
 386                         case PROJECTILE_PORTO_RED:
 387                                 self.colormod = '2 1 1';
 388                                 self.alphamod = 0.5;
 389                                 self.move_movetype = MOVETYPE_BOUNCE;
 390                                 self.move_touch = func_null;
 391                                 break;
 392                         case PROJECTILE_PORTO_BLUE:
 393                                 self.colormod = '1 1 2';
 394                                 self.alphamod = 0.5;
 395                                 self.move_movetype = MOVETYPE_BOUNCE;
 396                                 self.move_touch = func_null;
 397                                 break;
 398                         case PROJECTILE_HAGAR_BOUNCING:
 399                                 self.move_movetype = MOVETYPE_BOUNCE;
 400                                 self.move_touch = func_null;
 401                                 break;
 402                         case PROJECTILE_CRYLINK_BOUNCING:
 403                                 self.move_movetype = MOVETYPE_BOUNCE;
 404                                 self.move_touch = func_null;
 405                                 break;
 406                         case PROJECTILE_NAPALM_FOUNTAIN:
 407                         case PROJECTILE_FIREBALL:
 408                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/fireball_fly2.wav", VOL_BASE, ATTEN_NORM);
 409                                 self.mins = '-16 -16 -16';
 410                                 self.maxs = '16 16 16';
 411                                 break;
 412                         case PROJECTILE_FIREMINE:
 413                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/fireball_fly.wav", VOL_BASE, ATTEN_NORM);
 414                                 self.move_movetype = MOVETYPE_BOUNCE;
 415                                 self.move_touch = func_null;
 416                                 self.mins = '-4 -4 -4';
 417                                 self.maxs = '4 4 4';
 418                                 break;
 419                         case PROJECTILE_TAG:
 420                                 self.mins = '-2 -2 -2';
 421                                 self.maxs = '2 2 2';
 422                                 break;
 423                         case PROJECTILE_FLAC:
 424                                 self.mins = '-2 -2 -2';
 425                                 self.maxs = '2 2 2';
 426                                 break;
 427                         case PROJECTILE_SEEKER:
 428                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 429                                 self.mins = '-4 -4 -4';
 430                                 self.maxs = '4 4 4';
 431                                 break;
 432             case PROJECTILE_RAPTORBOMB:
 433                                 self.mins = '-3 -3 -3';
 434                                 self.maxs = '3 3 3';
 435                                 break;
 436             case PROJECTILE_RAPTORBOMBLET:
 437                                 break;
 438             case PROJECTILE_RAPTORCANNON:
 439                                 break;
 440             case PROJECTILE_SPIDERROCKET:
 441                 loopsound(self, CH_SHOTS_SINGLE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 442                                 break;
 443             case PROJECTILE_WAKIROCKET:
 444                 loopsound(self, CH_SHOTS_SINGLE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 445                                 break;
 446             /*
 447             case PROJECTILE_WAKICANNON:
 448                                 break;
 449                         case PROJECTILE_BUMBLE_GUN:
 450                                 // only new engines support sound moving with object
 451                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/electro_fly.wav", VOL_BASE, ATTEN_NORM);
 452                                 self.mins = '0 0 -4';
 453                                 self.maxs = '0 0 -4';
 454                                 self.move_movetype = MOVETYPE_BOUNCE;
 455                                 self.move_touch = func_null;
 456                                 self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 457                                 self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 458                                 break;
 459                         */
 460                         default:
 461                                 break;
 462                 }
 463
 464                 if(Nade_IDFromProjectile(self.cnt) != 0)
 465                 {
 466                         int nade_type = Nade_IDFromProjectile(self.cnt);
 467                         self.mins = '-16 -16 -16';
 468                         self.maxs = '16 16 16';
 469                         self.colormod = Nade_Color(nade_type);
 470                         self.move_movetype = MOVETYPE_BOUNCE;
 471                         self.move_touch = func_null;
 472                         self.scale = 1.5;
 473                         self.avelocity = randomvec() * 720;
 474
 475                         if(nade_type == NADE_TYPE_TRANSLOCATE || nade_type == NADE_TYPE_SPAWN)
 476                                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 477                         else
 478                                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 479                 }
 480
 481                 setsize(self, self.mins, self.maxs);
 482         }
 483
 484         if(self.gravity)
 485         {
 486                 if(self.move_movetype == MOVETYPE_FLY)
 487                         self.move_movetype = MOVETYPE_TOSS;
 488                 if(self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 489                         self.move_movetype = MOVETYPE_BOUNCE;
 490         }
 491         else
 492         {
 493                 if(self.move_movetype == MOVETYPE_TOSS)
 494                         self.move_movetype = MOVETYPE_FLY;
 495                 if(self.move_movetype == MOVETYPE_BOUNCE)
 496                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 497         }
 498
 499         if(!(self.count & 0x80))
 500                 InterpolateOrigin_Note();
 501
 502         self.draw = Projectile_Draw;
 503         self.entremove = Ent_RemoveProjectile;
 504 }
 505
 506 void Projectile_Precache()
 507 {
 508         precache_model("models/ebomb.mdl");
 509         precache_model("models/elaser.mdl");
 510         precache_model("models/grenademodel.md3");
 511         precache_model("models/mine.md3");
 512         precache_model("models/hagarmissile.mdl");
 513         precache_model("models/hlac_bullet.md3");
 514         precache_model("models/laser.mdl");
 515         precache_model("models/plasmatrail.mdl");
 516         precache_model("models/rocket.md3");
 517         precache_model("models/tagrocket.md3");
 518         precache_model("models/tracer.mdl");
 519         precache_model("models/sphere/sphere.md3");
 520
 521         precache_model("models/weapons/v_ok_grenade.md3");
 522         precache_model("models/weapons/ok_rocket.md3");
 523
 524         precache_sound("weapons/electro_fly.wav");
 525         precache_sound("weapons/rocket_fly.wav");
 526         precache_sound("weapons/fireball_fly.wav");
 527         precache_sound("weapons/fireball_fly2.wav");
 528         precache_sound("weapons/tag_rocket_fly.wav");
 529
 530 }