qcsrc/common/animdecide.qc

   1 #if defined(CSQC)
   2         #include "../dpdefs/csprogsdefs.qh"
   3         #include "animdecide.qh"
   4 #elif defined(MENUQC)
   5 #elif defined(SVQC)
   6         #include "../dpdefs/progsdefs.qh"
   7     #include "../dpdefs/dpextensions.qh"
   8     #include "util.qh"
   9     #include "animdecide.qh"
  10     #include "../server/defs.qh"
  11 #endif
  12
  13 void animdecide_load_if_needed(entity e)
  14 {
  15         if(e.modelindex == e.animdecide_modelindex)
  16                 return;
  17         e.animdecide_modelindex = e.modelindex;
  18
  19         vector none = '0 0 0';
  20         e.anim_die1 = animfixfps(e, '0 1 0.5', none); // 2 seconds
  21         e.anim_die2 = animfixfps(e, '1 1 0.5', none); // 2 seconds
  22         e.anim_draw = animfixfps(e, '2 1 3', none);
  23         e.anim_duckwalk = animfixfps(e, '4 1 1', none);
  24         e.anim_duckjump = animfixfps(e, '5 1 10', none);
  25         e.anim_duckidle = animfixfps(e, '6 1 1', none);
  26         e.anim_idle = animfixfps(e, '7 1 1', none);
  27         e.anim_jump = animfixfps(e, '8 1 10', none);
  28         e.anim_pain1 = animfixfps(e, '9 1 2', none); // 0.5 seconds
  29         e.anim_pain2 = animfixfps(e, '10 1 2', none); // 0.5 seconds
  30         e.anim_shoot = animfixfps(e, '11 1 5', none); // analyze models and set framerate
  31         e.anim_taunt = animfixfps(e, '12 1 0.33', none);
  32         e.anim_run = animfixfps(e, '13 1 1', none);
  33         e.anim_runbackwards = animfixfps(e, '14 1 1', none);
  34         e.anim_strafeleft = animfixfps(e, '15 1 1', none);
  35         e.anim_straferight = animfixfps(e, '16 1 1', none);
  36         e.anim_forwardright = animfixfps(e, '19 1 1', '16 1 1');
  37         e.anim_forwardleft = animfixfps(e, '20 1 1', '15 1 1');
  38         e.anim_backright = animfixfps(e, '21 1 1', '16 1 1');
  39         e.anim_backleft  = animfixfps(e, '22 1 1', '15 1 1');
  40         e.anim_melee = animfixfps(e, '23 1 1', '11 1 1');
  41         e.anim_duckwalkbackwards = animfixfps(e, '24 1 1', '4 1 1');
  42         e.anim_duckwalkstrafeleft = animfixfps(e, '25 1 1', '4 1 1');
  43         e.anim_duckwalkstraferight = animfixfps(e, '26 1 1', '4 1 1');
  44         e.anim_duckwalkforwardright = animfixfps(e, '27 1 1', '4 1 1');
  45         e.anim_duckwalkforwardleft = animfixfps(e, '28 1 1', '4 1 1');
  46         e.anim_duckwalkbackright = animfixfps(e, '29 1 1', '4 1 1');
  47         e.anim_duckwalkbackleft  = animfixfps(e, '30 1 1', '4 1 1');
  48
  49         // these anims ought to stay until stopped explicitly by weaponsystem
  50         e.anim_shoot_z = 0.001;
  51         e.anim_melee_z = 0.001;
  52 }
  53
  54 const float ANIMPRIO_IDLE = 0;
  55 const float ANIMPRIO_ACTIVE = 1;
  56 const float ANIMPRIO_CROUCH = 2;
  57 const float ANIMPRIO_DEAD = 3;
  58
  59 vector animdecide_getupperanim(entity e)
  60 {
  61         // death etc.
  62         if(e.anim_state & ANIMSTATE_FROZEN)
  63                 return vec3(e.anim_idle.x, e.anim_time, ANIMPRIO_DEAD);
  64         if(e.anim_state & ANIMSTATE_DEAD1)
  65                 return vec3(e.anim_die1_x, e.anim_time, ANIMPRIO_DEAD);
  66         if(e.anim_state & ANIMSTATE_DEAD2)
  67                 return vec3(e.anim_die2_x, e.anim_time, ANIMPRIO_DEAD);
  68
  69         // is there an action?
  70         vector outframe = '-1 0 0';
  71         float t, a;
  72         if(e.anim_upper_time >= e.anim_upper_implicit_time)
  73         {
  74                 a = e.anim_upper_action;
  75                 t = e.anim_upper_time;
  76         }
  77         else
  78         {
  79                 a = e.anim_upper_implicit_action;
  80                 t = e.anim_upper_implicit_time;
  81         }
  82         switch(a)
  83         {
  84                 case ANIMACTION_DRAW: outframe = e.anim_draw; break;
  85                 case ANIMACTION_PAIN1: outframe = e.anim_pain1; break;
  86                 case ANIMACTION_PAIN2: outframe = e.anim_pain2; break;
  87                 case ANIMACTION_SHOOT: outframe = e.anim_shoot; break;
  88                 case ANIMACTION_TAUNT: outframe = e.anim_taunt; break;
  89                 case ANIMACTION_MELEE: outframe = e.anim_melee; break;
  90         }
  91         if(outframe.x >= 0)
  92         {
  93                 if(time <= t + outframe.y / outframe.z)
  94                 {
  95                         // animation is running!
  96                         return vec3(outframe.x, t, ANIMPRIO_ACTIVE);
  97                 }
  98         }
  99         // or, decide the anim by state
 100         t = max(e.anim_time, e.anim_implicit_time);
 101         // but all states are for lower body!
 102         return vec3(e.anim_idle.x, t, ANIMPRIO_IDLE);
 103 }
 104
 105 vector animdecide_getloweranim(entity e)
 106 {
 107         // death etc.
 108         if(e.anim_state & ANIMSTATE_FROZEN)
 109                 return vec3(e.anim_idle.x, e.anim_time, ANIMPRIO_DEAD);
 110         if(e.anim_state & ANIMSTATE_DEAD1)
 111                 return vec3(e.anim_die1_x, e.anim_time, ANIMPRIO_DEAD);
 112         if(e.anim_state & ANIMSTATE_DEAD2)
 113                 return vec3(e.anim_die2_x, e.anim_time, ANIMPRIO_DEAD);
 114
 115         // is there an action?
 116         vector outframe = '-1 0 0';
 117         float t, a;
 118         if(e.anim_lower_time >= e.anim_lower_implicit_time)
 119         {
 120                 a = e.anim_lower_action;
 121                 t = e.anim_lower_time;
 122         }
 123         else
 124         {
 125                 a = e.anim_lower_implicit_action;
 126                 t = e.anim_lower_implicit_time;
 127         }
 128         switch(a)
 129         {
 130                 case ANIMACTION_JUMP: if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) { if(e.anim_state & ANIMSTATE_DUCK) outframe = e.anim_duckjump; else outframe = e.anim_jump; } break;
 131         }
 132         if(outframe.x >= 0)
 133         {
 134                 if(time <= t + outframe.y / outframe.z)
 135                 {
 136                         // animation is running!
 137                         return vec3(outframe.x, t, ANIMPRIO_ACTIVE);
 138                 }
 139         }
 140         // or, decide the anim by state
 141         t = max(e.anim_time, e.anim_implicit_time);
 142         if(e.anim_state & ANIMSTATE_DUCK)
 143         {
 144                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 145                         return vec3(e.anim_duckjump.x, 0, ANIMPRIO_CROUCH); // play the END of the jump anim
 146                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 147                 {
 148                         case ANIMIMPLICITSTATE_FORWARD:
 149                                 return vec3(e.anim_duckwalk.x, t, ANIMPRIO_CROUCH);
 150                         case ANIMIMPLICITSTATE_BACKWARDS:
 151                                 return vec3(e.anim_duckwalkbackwards.x, t, ANIMPRIO_CROUCH);
 152                         case ANIMIMPLICITSTATE_RIGHT:
 153                                 return vec3(e.anim_duckwalkstraferight.x, t, ANIMPRIO_CROUCH);
 154                         case ANIMIMPLICITSTATE_LEFT:
 155                                 return vec3(e.anim_duckwalkstrafeleft.x, t, ANIMPRIO_CROUCH);
 156                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 157                                 return vec3(e.anim_duckwalkforwardright.x, t, ANIMPRIO_CROUCH);
 158                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 159                                 return vec3(e.anim_duckwalkforwardleft.x, t, ANIMPRIO_CROUCH);
 160                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 161                                 return vec3(e.anim_duckwalkbackright.x, t, ANIMPRIO_CROUCH);
 162                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 163                                 return vec3(e.anim_duckwalkbackleft.x, t, ANIMPRIO_CROUCH);
 164                         default:
 165                                 return vec3(e.anim_duckidle.x, t, ANIMPRIO_CROUCH);
 166                 }
 167         }
 168         else
 169         {
 170                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 171                         return vec3(e.anim_jump.x, 0, ANIMPRIO_ACTIVE); // play the END of the jump anim
 172                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 173                 {
 174                         case ANIMIMPLICITSTATE_FORWARD:
 175                                 return vec3(e.anim_run.x, t, ANIMPRIO_ACTIVE);
 176                         case ANIMIMPLICITSTATE_BACKWARDS:
 177                                 return vec3(e.anim_runbackwards.x, t, ANIMPRIO_ACTIVE);
 178                         case ANIMIMPLICITSTATE_RIGHT:
 179                                 return vec3(e.anim_straferight.x, t, ANIMPRIO_ACTIVE);
 180                         case ANIMIMPLICITSTATE_LEFT:
 181                                 return vec3(e.anim_strafeleft.x, t, ANIMPRIO_ACTIVE);
 182                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 183                                 return vec3(e.anim_forwardright.x, t, ANIMPRIO_ACTIVE);
 184                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 185                                 return vec3(e.anim_forwardleft.x, t, ANIMPRIO_ACTIVE);
 186                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 187                                 return vec3(e.anim_backright.x, t, ANIMPRIO_ACTIVE);
 188                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 189                                 return vec3(e.anim_backleft.x, t, ANIMPRIO_ACTIVE);
 190                         default:
 191                                 return vec3(e.anim_idle.x, t, ANIMPRIO_IDLE);
 192                 }
 193         }
 194         // can't get here
 195         return vec3(e.anim_idle.x, t, ANIMPRIO_IDLE);
 196 }
 197
 198 void animdecide_setimplicitstate(entity e, float onground)
 199 {
 200         int s = 0;
 201
 202         makevectors(e.angles);
 203         vector v;
 204         v.x = e.velocity * v_forward;
 205         v.y = e.velocity * v_right;
 206         v.z = 0;
 207
 208         // we want to match like this:
 209         // the 8 directions shall be "evenly spaced"
 210         // that means, the forward key includes anything from -67.5 to +67.5 degrees
 211         // which then means x > |y| * cot(3pi/8)
 212         //
 213         // BUT, the engine's clip-movement-to-keyboard function uses 0.5 here,
 214         // which would be an angle range from -63.43 to +63.43 degrees, making
 215         // it slightly less likely to "hit two keys at once", so let's do this
 216         // here too
 217
 218         if(vlen(v) > 10)
 219         {
 220                 if(v.x >  fabs(v.y) * 0.5)
 221                         s |= ANIMIMPLICITSTATE_FORWARD;
 222                 if(v.x < -fabs(v.y) * 0.5)
 223                         s |= ANIMIMPLICITSTATE_BACKWARDS;
 224                 if(v.y >  fabs(v.x) * 0.5)
 225                         s |= ANIMIMPLICITSTATE_RIGHT;
 226                 if(v.y < -fabs(v.x) * 0.5)
 227                         s |= ANIMIMPLICITSTATE_LEFT;
 228         }
 229         if(!onground)
 230                 s |= ANIMIMPLICITSTATE_INAIR;
 231
 232         // detect some kinds of otherwise misdetected jumps (ground to air transition)
 233         // NOTE: currently, in CSQC this is the only jump detection, as the explicit jump action is never called!
 234         if(!(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) && (s & ANIMIMPLICITSTATE_INAIR))
 235         {
 236                 e.anim_lower_implicit_action = ANIMACTION_JUMP;
 237                 e.anim_lower_implicit_time = time;
 238         }
 239
 240         if(s != e.anim_implicit_state)
 241         {
 242                 e.anim_implicit_state = s;
 243                 e.anim_implicit_time = time;
 244         }
 245 }
 246 void animdecide_setframes(entity e, float support_blending, .float fld_frame, .float fld_frame1time, .float fld_frame2, .float fld_frame2time)
 247 {
 248         // _x: frame
 249         // _y: start time
 250         // _z: priority
 251         vector upper = animdecide_getupperanim(e);
 252         vector lower = animdecide_getloweranim(e);
 253         //print("UPPER: ", vtos(upper), ", LOWER: ", vtos(lower), "\n");
 254         if(support_blending)
 255         {
 256                 if(upper.z && !lower.z)
 257                         lower = upper;
 258                 else if(lower.z && !upper.z)
 259                         upper = lower;
 260                 if(e.frame1time != upper.y || e.frame2time != lower.y)
 261                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 262                 e.(fld_frame) = upper.x;
 263                 e.(fld_frame1time) = upper.y;
 264                 e.(fld_frame2) = lower.x;
 265                 e.(fld_frame2time) = lower.y;
 266         }
 267         else
 268         {
 269                 if(upper.z > lower.z)
 270                         lower = upper;
 271                 else if(lower.z > upper.z)
 272                         upper = lower;
 273                 if(e.frame1time != upper.y)
 274                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 275                 e.(fld_frame) = upper.x;
 276                 e.(fld_frame1time) = upper.y;
 277         }
 278 }
 279
 280 void animdecide_setstate(entity e, int newstate, float restart)
 281 {
 282         if(!restart)
 283                 if(newstate == e.anim_state)
 284                         return;
 285         e.anim_state = newstate;
 286         e.anim_time = time;
 287 }
 288 void animdecide_setaction(entity e, float action, float restart)
 289 {
 290         if(action < 0)
 291         {
 292                 if(!restart)
 293                         if(action == e.anim_lower_action)
 294                                 return;
 295                 e.anim_lower_action = action;
 296                 e.anim_lower_time = time;
 297         }
 298         else
 299         {
 300                 if(!restart)
 301                         if(action == e.anim_upper_action)
 302                                 return;
 303                 e.anim_upper_action = action;
 304                 e.anim_upper_time = time;
 305         }
 306 }