qcsrc/common/command/generic.qc

   1 // =========================================================
   2 //  Generic program common command code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 // used by generic commands for better help/usage information
   7 string GetProgramCommandPrefix(void)
   8 {
   9         #ifdef SVQC
  10         return "sv_cmd";
  11         #endif
  12         #ifdef CSQC
  13         return "cl_cmd";
  14         #endif
  15         #ifdef MENUQC
  16         return "menu_cmd";
  17         #endif
  18 }
  19
  20 #define NUM_MARKUPS     41
  21 float markup_init;
  22 string markup_from[NUM_MARKUPS];
  23 string markup_to[NUM_MARKUPS];
  24 void GameCommand_MarkupInit()
  25 {
  26         float i;
  27         if (markup_init)
  28                 return;
  29         markup_init = 1;
  30         i = 0;
  31         markup_from[i] = "&alien"; markup_to[i] = "\x12"; ++i;
  32         markup_from[i] = "&:-)"; markup_to[i] = "\x13"; ++i;
  33         markup_from[i] = "&:-("; markup_to[i] = "\x14"; ++i;
  34         markup_from[i] = "&x-P"; markup_to[i] = "\x15"; ++i;
  35         markup_from[i] = "&:-/"; markup_to[i] = "\x16"; ++i;
  36         markup_from[i] = "&:-D"; markup_to[i] = "\x17"; ++i;
  37         markup_from[i] = "&<<"; markup_to[i] = "\x18"; ++i;
  38         markup_from[i] = "&>>"; markup_to[i] = "\x19"; ++i;
  39         markup_from[i] = "&dot"; markup_to[i] = "\x1a"; ++i;
  40         markup_from[i] = "&^_"; markup_to[i] = "\x1b"; ++i;
  41         markup_from[i] = "&ysplat"; markup_to[i] = "\x1c"; ++i;
  42         markup_from[i] = "&-]"; markup_to[i] = "\x1d"; ++i;
  43         markup_from[i] = "&--"; markup_to[i] = "\x1e"; ++i;
  44         markup_from[i] = "&[-"; markup_to[i] = "\x1f"; ++i;
  45         markup_from[i] = "&s<"; markup_to[i] = "\x2c"; ++i;
  46         markup_from[i] = "&s>"; markup_to[i] = "\x2e"; ++i;
  47         markup_from[i] = "&<-"; markup_to[i] = "\x7f"; ++i;
  48         markup_from[i] = "&[="; markup_to[i] = "\x80"; ++i;
  49         markup_from[i] = "&=="; markup_to[i] = "\x81"; ++i;
  50         markup_from[i] = "&=]"; markup_to[i] = "\x82"; ++i;
  51         markup_from[i] = "&r!"; markup_to[i] = "\x84"; ++i;
  52         markup_from[i] = "&|o|"; markup_to[i] = "\x85"; ++i;
  53         markup_from[i] = "&|u|"; markup_to[i] = "\x86"; ++i;
  54         markup_from[i] = "&|i|"; markup_to[i] = "\x87"; ++i;
  55         markup_from[i] = "&|c|"; markup_to[i] = "\x88"; ++i;
  56         markup_from[i] = "&[c]"; markup_to[i] = "\x89"; ++i;
  57         markup_from[i] = "&[n]"; markup_to[i] = "\x8a"; ++i;
  58         markup_from[i] = "&[]"; markup_to[i] = "\x8b"; ++i;
  59         markup_from[i] = "&r?"; markup_to[i] = "\x8c"; ++i;
  60         markup_from[i] = "&|>"; markup_to[i] = "\x8d"; ++i;
  61         markup_from[i] = "&splat0"; markup_to[i] = "\x8e"; ++i;
  62         markup_from[i] = "&splat1"; markup_to[i] = "\x8f"; ++i;
  63         markup_from[i] = "&[["; markup_to[i] = "\x90"; ++i;
  64         markup_from[i] = "&]]"; markup_to[i] = "\x91"; ++i;
  65         markup_from[i] = "&splat2"; markup_to[i] = "\x9a"; ++i;
  66         markup_from[i] = "&)("; markup_to[i] = "\x9b"; ++i;
  67         markup_from[i] = "&splat3"; markup_to[i] = "\x9c"; ++i;
  68         markup_from[i] = "&(."; markup_to[i] = "\x9d"; ++i;
  69         markup_from[i] = "&.."; markup_to[i] = "\x9e"; ++i;
  70         markup_from[i] = "&.)"; markup_to[i] = "\x9f"; ++i;
  71         markup_from[i] = "&<|"; markup_to[i] = "\xff"; ++i;
  72 }
  73
  74 string GameCommand_Markup(string s2)
  75 {
  76         float red, ccase, i, j;
  77         string s, s3;
  78
  79         GameCommand_MarkupInit();
  80
  81         s = "";
  82
  83         red = 0;
  84         ccase = 0;
  85         for(i = 0; i < strlen(s2); ++i)
  86         {
  87                 for(j = 0; j < NUM_MARKUPS; ++j)
  88                 {
  89                         s3 = substring(s2, i, strlen(markup_from[j]));
  90                         if (s3 == markup_from[j])
  91                         {
  92                                 s = strcat(s, markup_to[j]);
  93                                 i += strlen(markup_from[j]) - 1;
  94                                 break;
  95                         }
  96                 }
  97
  98                 if(j == NUM_MARKUPS)
  99                 {
 100                         if(substring(s2, i, 2) == "&&")
 101                         {
 102                                 s = strcat(s, strconv(ccase, red, red, "&"));
 103                                 ++i;
 104                         }
 105                         else if(substring(s2, i, 2) == "&d")
 106                         {
 107                                 red = 2;
 108                                 ccase = 0;
 109                                 ++i;
 110                         }
 111                         else if(substring(s2, i, 2) == "&a")
 112                         {
 113                                 red = 2;
 114                                 ccase = 2;
 115                                 ++i;
 116                         }
 117                         else if(substring(s2, i, 2) == "&n")
 118                         {
 119                                 red = 0;
 120                                 ccase = 0;
 121                                 ++i;
 122                         }
 123                         else
 124                                 s = strcat(s, strconv(ccase, red, red, substring(s2, i, 1)));
 125                 }
 126         }
 127
 128         return s;
 129 }
 130
 131 void GenericCommand_addtolist(float request, float argc)
 132 {
 133         switch(request)
 134         {
 135                 case CMD_REQUEST_COMMAND:
 136                 {
 137                         float i;
 138
 139                         if(argc >= 2)
 140                         {
 141                                 if(cvar_string(argv(1)) == "") // cvar was empty
 142                                 {
 143                                         cvar_set(argv(1), argv(2));
 144                                 }
 145                                 else // add it to the end of the list if the list doesn't already have it
 146                                 {
 147                                         argc = tokenizebyseparator(cvar_string(argv(1)), " ");
 148                                         for(i = 0; i < argc; ++i)
 149                                                 if(argv(i) == argv(2))
 150                                                         return; // already in list
 151
 152                                         cvar_set(argv(1), strcat(argv(2), " ", cvar_string(argv(1))));
 153                                 }
 154                                 return;
 155                         }
 156                 }
 157
 158                 default:
 159                         // todo
 160                 case CMD_REQUEST_USAGE:
 161                 {
 162                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " addtolist variable [value]"));
 163                         print("  Where 'variable' is what to add to the list,\n");
 164                         print("  and 'value' is any extra optional paramaters to add with quotes.");
 165                         return;
 166                 }
 167         }
 168 }
 169
 170 void GenericCommand_maplist(float request, float argc)
 171 {
 172         switch(request)
 173         {
 174                 case CMD_REQUEST_COMMAND:
 175                 {
 176                         string tmp_string;
 177                         float i;
 178
 179                         switch(argv(1))
 180                         {
 181                                 case "add": // appends new maps to the maplist
 182                                 {
 183                                         if(argc == 3)
 184                                         {
 185                                                 if (!fexists(strcat("maps/", argv(2), ".bsp")))
 186                                                 {
 187                                                         print("maplist: ERROR: ", argv(2), " does not exist!\n");
 188                                                         break;
 189                                                 }
 190
 191                                                 if(cvar_string("g_maplist") == "")
 192                                                         cvar_set("g_maplist", argv(2));
 193                                                 else
 194                                                         cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 195
 196                                                 return;
 197                                         }
 198                                         break; // go to usage
 199                                 }
 200
 201                                 case "remove": // scans maplist and only adds back whatever maps were not provided in argv(2)
 202                                 {
 203                                         if(argc == 3)
 204                                         {
 205                                                 argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 206
 207                                                 for(i = 0; i < argc; ++i)
 208                                                         if(argv(i) != argv(2))
 209                                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 210
 211                                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 212                                                 cvar_set("g_maplist", tmp_string);
 213
 214                                                 return;
 215                                         }
 216                                         break; // go to usage
 217                                 }
 218
 219                                 case "shuffle": // randomly shuffle the maplist
 220                                 {
 221                                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
 222                                         return;
 223                                 }
 224
 225                                 case "cleanup": // scans maplist and only adds back the ones which are really usable
 226                                 {
 227                                         MapInfo_Enumerate();
 228                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 229                                         argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 230
 231                                         for(i = 0; i < argc; ++i)
 232                                                 if(MapInfo_CheckMap(argv(i)))
 233                                                         tmp_string = strcat(tmp_string, " ", argv(i));
 234
 235                                         tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 236                                         cvar_set("g_maplist", tmp_string);
 237
 238                                         return;
 239                                 }
 240
 241                                 default: break;
 242                         }
 243                 }
 244
 245                 default:
 246                 case CMD_REQUEST_USAGE:
 247                 {
 248                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " maplist command [map]")); // todo
 249                         print("  No arguments required.\n");
 250                         return;
 251                 }
 252         }
 253 }
 254
 255 void GenericCommand_settemp(float request, float argc)
 256 {
 257         switch(request)
 258         {
 259                 case CMD_REQUEST_COMMAND:
 260                 {
 261                         if(argc >= 3)
 262                         {
 263                                 if(cvar_settemp(argv(1), argv(2)))
 264                                         dprint("Creating new settemp tracker for ", argv(1), " and setting it to \"", argv(2), "\" temporarily.\n");
 265                                 else
 266                                         dprint("Already had a tracker for ", argv(1), ", updating it to \"", argv(2), "\".\n");
 267
 268                                 return;
 269                         }
 270                 }
 271
 272                 default:
 273                         print("Incorrect parameters for ^2settemp^7\n");
 274                 case CMD_REQUEST_USAGE:
 275                 {
 276                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp \"cvar\" \"arguments\"\n"));
 277                         print("  Where 'cvar' is the cvar you want to temporarily set with 'arguments'.\n");
 278                         return;
 279                 }
 280         }
 281 }
 282
 283 void GenericCommand_settemp_restore(float request, float argc)
 284 {
 285         switch(request)
 286         {
 287                 case CMD_REQUEST_COMMAND:
 288                 {
 289                         float i = cvar_settemp_restore();
 290
 291                         if(i)
 292                                 dprint("Restored ", ftos(i), " temporary cvar settings to their original values.\n");
 293                         else
 294                                 dprint("Nothing to restore.\n");
 295
 296                         return;
 297                 }
 298
 299                 default:
 300                 case CMD_REQUEST_USAGE:
 301                 {
 302                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp_restore\n"));
 303                         print("  No arguments required.\n");
 304                         return;
 305                 }
 306         }
 307 }
 308
 309 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 310 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 311 void GenericCommand_(float request)
 312 {
 313         switch(request)
 314         {
 315                 case CMD_REQUEST_COMMAND:
 316                 {
 317
 318                         return;
 319                 }
 320
 321                 default:
 322                 case CMD_REQUEST_USAGE:
 323                 {
 324                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " ")));
 325                         print("  No arguments required.\n");
 326                         return;
 327                 }
 328         }
 329 }
 330 */
 331
 332 // ==================================
 333 //  Macro system for server commands
 334 // ==================================
 335
 336 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 337 #define GENERIC_COMMANDS(request,arguments,command) \
 338         GENERIC_COMMAND("addtolist", GenericCommand_addtolist(request, arguments), "Add a string to a cvar at the end of a list") \
 339         GENERIC_COMMAND("maplist", GenericCommand_maplist(request, arguments), "Automatic control of maplist") \
 340         GENERIC_COMMAND("rpn", GenericCommand_rpn(request, arguments, command), "RPN calculator") \
 341         GENERIC_COMMAND("settemp", GenericCommand_settemp(request, arguments), "Temporarily set a value to a cvar which is restored later") \
 342         GENERIC_COMMAND("settemp_restore", GenericCommand_settemp_restore(request, arguments), "Restore all cvars set by settemp command") \
 343         /* nothing */
 344
 345 void GenericCommand_macro_help()
 346 {
 347         #define GENERIC_COMMAND(name,function,description) \
 348                 { print("  ^2", name, "^7: ", description, "\n"); }
 349
 350         GENERIC_COMMANDS(0, 0, "")
 351         #undef GENERIC_COMMAND
 352
 353         return;
 354 }
 355
 356 float GenericCommand_macro_command(float argc, string command)
 357 {
 358         #define GENERIC_COMMAND(name,function,description) \
 359                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 360
 361         GENERIC_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 362         #undef GENERIC_COMMAND
 363
 364         return FALSE;
 365 }
 366
 367 float GenericCommand_macro_usage(float argc)
 368 {
 369         #define GENERIC_COMMAND(name,function,description) \
 370                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 371
 372         GENERIC_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 373         #undef GENERIC_COMMAND
 374
 375         return FALSE;
 376 }
 377
 378
 379 // ===========================================
 380 //  Main Common Function For Generic Commands
 381 // ===========================================
 382 // Commands spread out among all programs (menu, client, and server)
 383
 384 float GenericCommand(string command)
 385 {
 386         float argc = tokenize_console(command);
 387         float n, j, f, i;
 388         string s, s2, c;
 389         vector rgb;
 390
 391         // Guide for working with argc arguments by example:
 392         // argc:   1    - 2      - 3     - 4
 393         // argv:   0    - 1      - 2     - 3
 394         // cmd     vote - master - login - password
 395
 396         if(strtolower(argv(0)) == "help")
 397         {
 398                 if(argc == 1)
 399                 {
 400                         GenericCommand_macro_help();
 401                         return TRUE;
 402                 }
 403                 else if(GenericCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
 404                 {
 405                         return TRUE;
 406                 }
 407         }
 408         else if(GenericCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 409         {
 410                 return TRUE; // handled by one of the above GenericCommand_* functions
 411         }
 412         else if(argc >= 3 && argv(0) == "red")
 413         {
 414                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 415                 localcmd(strcat(argv(1), " ", GameCommand_Markup(s)));
 416                 return TRUE;
 417         }
 418         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
 419         {
 420                 // other test case
 421                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 422
 423                 n = floor(random() * 6 + 2);
 424
 425                 s2 = "";
 426                 for(i = 0; i < n; ++i)
 427                 {
 428                         s2 = strcat(s2, "AH");
 429                 }
 430
 431                 if(random() < 0.1)
 432                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
 433
 434                 if(s == "")
 435                         s = s2;
 436                 else
 437                         if(random() < 0.8)
 438                                 s = strcat(s, " ", s2);
 439                         else
 440                                 s = strcat(s2, " ", s);
 441
 442                 s2 = substring(s, strlen(s) - 2, 2);
 443                 if(s2 == "AH" || s2 == "AY")
 444                         s = strcat(s, "))");
 445                 else
 446                         s = strcat(s, " ))");
 447
 448                 if(random() < 0.1)
 449                         s = substring(s, 0, strlen(s) - 1);
 450
 451                 if(random() < 0.1)
 452                         s = strconv(1, 0, 0, s);
 453
 454                 localcmd(strcat(argv(1), " ", s));
 455
 456                 return TRUE;
 457         }
 458         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55790)
 459         {
 460                 // test case for terencehill's color codes
 461                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 462                 s2 = "";
 463
 464                 n = strlen(s);
 465                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
 466                 f = random() * 6;
 467
 468                 for(i = 0; i < n; ++i)
 469                 {
 470                         c = substring(s, i, 1);
 471
 472                         if(c == ";")
 473                                 c = ":";
 474                         else if(c == "^")
 475                         {
 476                                 c = "^^";
 477                                 if(substring(s, i+1, 1) == "^")
 478                                         ++i;
 479                         }
 480
 481                         if(c != " ")
 482                         {
 483                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 484                                 c = strcat(rgb_to_hexcolor(rgb), c);
 485                         }
 486                         s2 = strcat(s2, c);
 487                 }
 488
 489                 localcmd(strcat(argv(1), " ", s2));
 490
 491                 return TRUE;
 492         }
 493
 494         return FALSE;
 495 }