qcsrc/common/command/rpn.qc

   1 string rpn_pop()
   2 {
   3         if(rpn_sp > 0) {
   4                 --rpn_sp;
   5                 return rpn_stack[rpn_sp];
   6         } else {
   7                 print("rpn: stack underflow\n");
   8                 rpn_error = TRUE;
   9                 return "";
  10         }
  11 }
  12 void rpn_push(string s)
  13 {
  14         if(rpn_sp < MAX_RPN_STACK) {
  15                 rpn_stack[rpn_sp] = s;
  16                 ++rpn_sp;
  17         } else {
  18                 print("rpn: stack overflow\n");
  19                 rpn_error = TRUE;
  20         }
  21 }
  22 string rpn_get()
  23 {
  24         if(rpn_sp > 0) {
  25                 return rpn_stack[rpn_sp - 1];
  26         } else {
  27                 print("rpn: empty stack\n");
  28                 rpn_error = TRUE;
  29                 return "";
  30         }
  31 }
  32 void rpn_set(string s)
  33 {
  34         if(rpn_sp > 0) {
  35                 rpn_stack[rpn_sp - 1] = s;
  36         } else {
  37                 print("rpn: empty stack\n");
  38                 rpn_error = TRUE;
  39         }
  40 }
  41
  42 float rpn_getf() { return stof(rpn_get()); }
  43 float rpn_popf() { return stof(rpn_pop()); }
  44 void rpn_pushf(float f) { return rpn_push(ftos(f)); }
  45 void rpn_setf(float f) { return rpn_set(ftos(f)); }
  46
  47 void GenericCommand_rpn(float request, float argc, string command)
  48 {
  49         switch(request)
  50         {
  51                 case CMD_REQUEST_COMMAND:
  52                 {
  53                         float i, j, f, n, f2, f3, rpnpos;
  54                         vector rgb;
  55                         string s, s2, c, rpncmd;
  56
  57                         if(!rpn_db)
  58                         {
  59                                 rpn_db = db_create();
  60                                 db_put(rpn_db, "stack.pointer", "0");
  61                                 db_put(rpn_db, "stack.pos", "-1");
  62                         }
  63
  64                         if(argc >= 2)
  65                         {
  66                                 float rpnpos;
  67                                 string rpncmd;
  68                                 float f2, f3;
  69                                 rpn_sp = 0;
  70                                 rpn_error = FALSE;
  71                                 for(rpnpos = 1; rpnpos < argc; ++rpnpos)
  72                                 {
  73                                         rpncmd = argv(rpnpos);
  74                                         f = strlen(rpncmd);
  75                                         if(rpncmd == "") {
  76                                         } else if(stof(substring(rpncmd, 0, 1)) > 0) {
  77                                                 rpn_push(rpncmd);
  78                                         } else if(substring(rpncmd, 0, 1) == "0") {
  79                                                 rpn_push(rpncmd);
  80                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
  81                                                 rpn_push(rpncmd);
  82                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
  83                                                 rpn_push(rpncmd);
  84                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
  85                                                 rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
  86                                         } else if(rpncmd == "clear") {
  87                                                 rpn_sp = 0;
  88                                         } else if(rpncmd == "def" || rpncmd == "=") {
  89                                                 s = rpn_pop();
  90                                                 s2 = rpn_pop();
  91
  92                                                 if(s2 != "")
  93                                                 {
  94                                                         #ifdef MENUQC
  95                                                         registercvar(s2, "", 0);
  96                                                         #else
  97                                                         registercvar(s2, "");
  98                                                         #endif
  99                                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 100                                                                 cvar_set(s2, s);
 101                                                 }
 102                                                 else
 103                                                 {
 104                                                         print("rpn: empty cvar name for 'def'\n");
 105                                                         rpn_error = TRUE;
 106                                                 }
 107                                         } else if(rpncmd == "defs" || rpncmd == "@") {
 108                                                 s = "";
 109                                                 i = rpn_popf();
 110                                                 j = (i == 0);
 111                                                 while(rpn_sp > 1 && (j || i > 0))
 112                                                 {
 113                                                         s = strcat("/", rpn_pop(), " ", s);
 114                                                         --i;
 115                                                 }
 116                                                 s2 = rpn_pop();
 117                                                 if(s2 != "")
 118                                                 {
 119                                                         #ifdef MENUQC
 120                                                         registercvar(s2, "", 0);
 121                                                         #else
 122                                                         registercvar(s2, "");
 123                                                         #endif
 124                                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 125                                                                 cvar_set(s2, s);
 126                                                 }
 127                                                 else
 128                                                 {
 129                                                         print("rpn: empty cvar name for 'defs'\n");
 130                                                         rpn_error = TRUE;
 131                                                 }
 132                                         } else if(rpncmd == "load") {
 133                                                 rpn_set(cvar_string(rpn_get()));
 134                                         } else if(rpncmd == "exch") {
 135                                                 s = rpn_pop();
 136                                                 s2 = rpn_get();
 137                                                 rpn_set(s);
 138                                                 rpn_push(s2);
 139                                         } else if(rpncmd == "dup") {
 140                                                 rpn_push(rpn_get());
 141                                         } else if(rpncmd == "pop") {
 142                                                 rpn_pop();
 143                                         } else if(rpncmd == "add" || rpncmd == "+") {
 144                                                 f = rpn_popf();
 145                                                 rpn_setf(rpn_getf() + f);
 146                                         } else if(rpncmd == "sub" || rpncmd == "-") {
 147                                                 f = rpn_popf();
 148                                                 rpn_setf(rpn_getf() - f);
 149                                         } else if(rpncmd == "mul" || rpncmd == "*") {
 150                                                 f = rpn_popf();
 151                                                 rpn_setf(rpn_getf() * f);
 152                                         } else if(rpncmd == "div" || rpncmd == "/") {
 153                                                 f = rpn_popf();
 154                                                 rpn_setf(rpn_getf() / f);
 155                                         } else if(rpncmd == "mod" || rpncmd == "%") {
 156                                                 f = rpn_popf();
 157                                                 f2 = rpn_getf();
 158                                                 rpn_setf(f2 - f * floor(f2 / f));
 159                                         } else if(rpncmd == "abs") {
 160                                                 rpn_setf(fabs(rpn_getf()));
 161                                         } else if(rpncmd == "sgn") {
 162                                                 f = rpn_getf();
 163                                                 if(f < 0)
 164                                                         rpn_set("-1");
 165                                                 else if(f > 0)
 166                                                         rpn_set("1");
 167                                                 else
 168                                                         rpn_set("0");
 169                                         } else if(rpncmd == "neg" || rpncmd == "~") {
 170                                                 rpn_setf(-rpn_getf());
 171                                         } else if(rpncmd == "floor" || rpncmd == "f") {
 172                                                 rpn_setf(floor(rpn_getf()));
 173                                         } else if(rpncmd == "ceil" || rpncmd == "c") {
 174                                                 rpn_setf(ceil(rpn_getf()));
 175                                         } else if(rpncmd == "max") {
 176                                                 f = rpn_popf();
 177                                                 f2 = rpn_getf();
 178                                                 rpn_setf(max(f2, f));
 179                                         } else if(rpncmd == "min") {
 180                                                 f = rpn_popf();
 181                                                 f2 = rpn_getf();
 182                                                 rpn_setf(min(f2, f));
 183                                         } else if(rpncmd == "bound") {
 184                                                 f = rpn_popf();
 185                                                 f2 = rpn_popf();
 186                                                 f3 = rpn_getf();
 187                                                 rpn_setf(bound(f3, f2, f));
 188                                         } else if(rpncmd == "when") {
 189                                                 f = rpn_popf();
 190                                                 f2 = rpn_popf();
 191                                                 f3 = rpn_getf();
 192                                                 if(f)
 193                                                         rpn_setf(f3);
 194                                                 else
 195                                                         rpn_setf(f2);
 196                                         } else if(rpncmd == ">" || rpncmd == "gt") {
 197                                                 f = rpn_popf();
 198                                                 rpn_setf(rpn_getf() > f);
 199                                         } else if(rpncmd == "<" || rpncmd == "lt") {
 200                                                 f = rpn_popf();
 201                                                 rpn_setf(rpn_getf() < f);
 202                                         } else if(rpncmd == "==" || rpncmd == "eq") {
 203                                                 f = rpn_popf();
 204                                                 rpn_setf(rpn_getf() == f);
 205                                         } else if(rpncmd == ">=" || rpncmd == "ge") {
 206                                                 f = rpn_popf();
 207                                                 rpn_setf(rpn_getf() >= f);
 208                                         } else if(rpncmd == "<=" || rpncmd == "le") {
 209                                                 f = rpn_popf();
 210                                                 rpn_setf(rpn_getf() <= f);
 211                                         } else if(rpncmd == "!=" || rpncmd == "ne") {
 212                                                 f = rpn_popf();
 213                                                 rpn_setf(rpn_getf() != f);
 214                                         } else if(rpncmd == "rand") {
 215                                                 rpn_setf(ceil(random() * rpn_getf()) - 1);
 216                                         } else if(rpncmd == "crc16") {
 217                                                 rpn_setf(crc16(FALSE, rpn_get()));
 218                                         } else if(rpncmd == "put") {
 219                                                 s2 = rpn_pop();
 220                                                 if (!rpn_error)
 221                                                 {
 222                                                         s = rpn_pop();
 223                                                         if (!rpn_error)
 224                                                                 db_put(rpn_db, s, s2);
 225                                                 }
 226                                         } else if(rpncmd == "get") {
 227                                                 s = rpn_pop();
 228                                                 if (!rpn_error)
 229                                                         rpn_push(db_get(rpn_db, s));
 230                                         } else if(rpncmd == "dbpush") {
 231                                                 s = rpn_pop();
 232                                                 if(!rpn_error)
 233                                                 {
 234                                                         i = stof(db_get(rpn_db, "stack.pointer"));
 235                                                         db_put(rpn_db, "stack.pointer", ftos(i+1));
 236                                                         db_put(rpn_db, strcat("stack.", ftos(i)), s);
 237                                                 }
 238                                                 if(!i)
 239                                                         db_put(rpn_db, "stack.pos", "0");
 240                                         } else if(rpncmd == "dbpop") {
 241                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 242                                                 if(i)
 243                                                 {
 244                                                         s = ftos(i-1);
 245                                                         db_put(rpn_db, "stack.pointer", s);
 246                                                         rpn_push(db_get(rpn_db, strcat("stack.", s)));
 247                                                         j = stof(db_get(rpn_db, "stack.pos"));
 248                                                         if(j >= i)
 249                                                                 db_put(rpn_db, "stack.pos", ftos(i-2));
 250                                                 } else {
 251                                                         rpn_error = 1;
 252                                                         print("rpn: database underflow\n");
 253                                                 }
 254                                         } else if(rpncmd == "dbget") {
 255
 256                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 257                                                 if(i)
 258                                                 {
 259                                                         rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 260                                                 } else {
 261                                                         rpn_error = 1;
 262                                                         print("rpn: database empty\n");
 263                                                 }
 264                                         } else if(rpncmd == "dblen") {
 265                                                 rpn_push(db_get(rpn_db, "stack.pointer"));
 266                                         } else if(rpncmd == "dbclr") {
 267                                                 db_close(rpn_db);
 268                                                 rpn_db = db_create();
 269                                                 db_put(rpn_db, "stack.pointer", "0");
 270                                                 db_put(rpn_db, "stack.pos", "-1");
 271                                         } else if(rpncmd == "dbsave") {
 272                                                 s = rpn_pop();
 273                                                 if(!rpn_error)
 274                                                         db_save(rpn_db, s);
 275                                         } else if(rpncmd == "dbload") {
 276                                                 s = rpn_pop();
 277                                                 if(!rpn_error)
 278                                                 {
 279                                                         db_close(rpn_db);
 280                                                         rpn_db = db_load(s);
 281                                                 }
 282                                         } else if(rpncmd == "dbins") {
 283                                                 s = rpn_pop();
 284                                                 if(!rpn_error)
 285                                                         //if(rpn_sp > 0)
 286                                                 {
 287                                                         j = stof(db_get(rpn_db, "stack.pointer"));
 288                                                         i = stof(db_get(rpn_db, "stack.pos"));
 289
 290                                                         if(i < 0)
 291                                                         {
 292                                                                 i = 0;
 293                                                                 db_put(rpn_db, "stack.pos", "0");
 294                                                         }
 295
 296                                                         db_put(rpn_db, "stack.pointer", ftos(j+1));
 297                                                         for(--j; j >= i; --j)
 298                                                         {
 299                                                                 db_put(rpn_db, strcat("stack.", ftos(j+1)),
 300                                                                                          db_get(rpn_db, (strcat("stack.", ftos(j))))
 301                                                                         );
 302                                                         }
 303                                                         db_put(rpn_db, strcat("stack.", ftos(i)), s);
 304                                                 }
 305                                         } else if(rpncmd == "dbext") {
 306                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 307                                                 i = stof(db_get(rpn_db, "stack.pos"));
 308                                                 if(!j)
 309                                                 {
 310                                                         rpn_error = TRUE;
 311                                                         print("rpn: empty database\n");
 312                                                 } else {
 313                                                         --j;
 314                                                         rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 315                                                         db_put(rpn_db, "stack.pointer", ftos(j));
 316                                                         if(i == j)
 317                                                         {
 318                                                                 db_put(rpn_db, "stack.pos", ftos(j-1));
 319                                                         } else {
 320                                                                 while(i < j)
 321                                                                 {
 322                                                                         db_put(rpn_db, strcat("stack.", ftos(i)),
 323                                                                                                  db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 324                                                                                 );
 325                                                                         ++i;
 326                                                                 }
 327                                                         }
 328                                                 }
 329                                         } else if(rpncmd == "dbread") {
 330                                                 s = db_get(rpn_db, "stack.pos");
 331                                                 if(stof(s) >= 0)
 332                                                 {
 333                                                         rpn_push(db_get(rpn_db, strcat("stack.", s)));
 334                                                 } else {
 335                                                         rpn_error = 1;
 336                                                         print("rpn: empty database\n");
 337                                                 }
 338                                         } else if(rpncmd == "dbat") {
 339                                                 rpn_push(db_get(rpn_db, "stack.pos"));
 340                                         } else if(rpncmd == "dbmov") {
 341                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 342                                                 i = stof(db_get(rpn_db, "stack.pos"));
 343                                                 i += rpn_popf();
 344                                                 if(!rpn_error)
 345                                                 {
 346                                                         if(i < 0 || i >= j)
 347                                                         {
 348                                                                 print("rpn: database cursor out of bounds\n");
 349                                                                 rpn_error = TRUE;
 350                                                         }
 351                                                         if(!rpn_error)
 352                                                         {
 353                                                                 db_put(rpn_db, "stack.pos", ftos(i));
 354                                                         }
 355                                                 }
 356                                         } else if(rpncmd == "dbgoto") {
 357                                                 s = rpn_pop();
 358                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 359                                                 if(!j)
 360                                                 {
 361                                                         rpn_error = TRUE;
 362                                                         print("rpn: empty database, cannot move cursor\n");
 363                                                 }
 364                                                 if(!rpn_error)
 365                                                 {
 366                                                         if(s == "end")
 367                                                                 i = stof(db_get(rpn_db, "stack.pointer"))-1;
 368                                                         else if(s == "beg")
 369                                                                 i = 0;
 370                                                         else
 371                                                                 i = stof(s);
 372
 373                                                         j = stof(db_get(rpn_db, "stack.pointer"));
 374                                                         if(i < 0 || i >= j)
 375                                                         {
 376                                                                 print("rpn: database cursor destination out of bounds\n");
 377                                                                 rpn_error = TRUE;
 378                                                         }
 379                                                         if(!rpn_error)
 380                                                         {
 381                                                                 db_put(rpn_db, "stack.pos", ftos(i));
 382                                                         }
 383                                                 }
 384                                         } else if(rpncmd == "union") {
 385                                                 // s s2 union
 386                                                 s2 = rpn_pop();
 387                                                 s = rpn_get();
 388                                                 f = tokenize_console(s);
 389                                                 f2 = tokenize_console(strcat(s, " ", s2));
 390                                                 // tokens 0..(f-1) represent s
 391                                                 // tokens f..f2 represent s2
 392                                                 // UNION: add all tokens to s that are in s2 but not in s
 393                                                 s = "";
 394                                                 for(i = 0; i < f; ++i)
 395                                                         s = strcat(s, " ", argv(i));
 396                                                 for(i = f; i < f2; ++i) {
 397                                                         for(j = 0; j < f; ++j)
 398                                                                 if(argv(i) == argv(j))
 399                                                                         goto skip_union;
 400                                                         s = strcat(s, " ", argv(i));
 401                                                         :skip_union
 402                                                 }
 403                                                 if(substring(s, 0, 1) == " ")
 404                                                         s = substring(s, 1, 99999);
 405                                                 rpn_set(s);
 406                                                 tokenize_console(command);
 407                                         } else if(rpncmd == "intersection") {
 408                                                 // s s2 intersection
 409                                                 s2 = rpn_pop();
 410                                                 s = rpn_get();
 411                                                 f = tokenize_console(s);
 412                                                 f2 = tokenize_console(strcat(s, " ", s2));
 413                                                 // tokens 0..(f-1) represent s
 414                                                 // tokens f..f2 represent s2
 415                                                 // INTERSECTION: keep only the tokens from s that are also in s2
 416                                                 s = "";
 417                                                 for(i = 0; i < f; ++i) {
 418                                                         for(j = f; j < f2; ++j)
 419                                                                 if(argv(i) == argv(j))
 420                                                                 {
 421                                                                         s = strcat(s, " ", argv(i));
 422                                                                         break;
 423                                                                 }
 424                                                 }
 425                                                 if(substring(s, 0, 1) == " ")
 426                                                         s = substring(s, 1, 99999);
 427                                                 rpn_set(s);
 428                                                 tokenize_console(command);
 429                                         } else if(rpncmd == "difference") {
 430                                                 // s s2 difference
 431                                                 s2 = rpn_pop();
 432                                                 s = rpn_get();
 433                                                 f = tokenize_console(s);
 434                                                 f2 = tokenize_console(strcat(s, " ", s2));
 435                                                 // tokens 0..(f-1) represent s
 436                                                 // tokens f..f2 represent s2
 437                                                 // DIFFERENCE: keep only the tokens from s that are not in s2
 438                                                 s = "";
 439                                                 for(i = 0; i < f; ++i) {
 440                                                         for(j = f; j < f2; ++j)
 441                                                                 if(argv(i) == argv(j))
 442                                                                         goto skip_difference;
 443                                                         s = strcat(s, " ", argv(i));
 444                                                         :skip_difference
 445                                                 }
 446                                                 if(substring(s, 0, 1) == " ")
 447                                                         s = substring(s, 1, 99999);
 448                                                 rpn_set(s);
 449                                                 tokenize_console(command);
 450                                         } else if(rpncmd == "shuffle") {
 451                                                 // s shuffle
 452                                                 s = rpn_get();
 453                                                 f = tokenize_console(s);
 454
 455                                                 for(i = 0; i < f - 1; ++i) {
 456                                                         // move a random item from i..f-1 to position i
 457                                                         s = "";
 458                                                         f2 = floor(random() * (f - i) + i);
 459                                                         for(j = 0; j < i; ++j)
 460                                                                 s = strcat(s, " ", argv(j));
 461                                                         s = strcat(s, " ", argv(f2));
 462                                                         for(j = i; j < f; ++j)
 463                                                                 if(j != f2)
 464                                                                         s = strcat(s, " ", argv(j));
 465                                                         f = tokenize_console(s);
 466                                                 }
 467
 468                                                 if(substring(s, 0, 1) == " ")
 469                                                         s = substring(s, 1, 99999);
 470                                                 rpn_set(s);
 471                                                 tokenize_console(command);
 472                                         } else if(rpncmd == "fexists_assert") {
 473                                                 s = rpn_pop();
 474                                                 if(!rpn_error)
 475                                                 {
 476                                                         if (!fexists(s))
 477                                                         {
 478                                                                 print("rpn: ERROR: ", s, " does not exist!\n");
 479                                                                 rpn_error = TRUE;
 480                                                         }
 481                                                 }
 482                                         } else if(rpncmd == "fexists") {
 483                                                 s = rpn_get();
 484                                                 if(!rpn_error)
 485                                                 {
 486                                                         if (fexists(s))
 487                                                                 rpn_setf(1);
 488                                                         else
 489                                                                 rpn_setf(0);
 490                                                 }
 491                                         } else if(rpncmd == "localtime") {
 492                                                 rpn_set(strftime(TRUE, rpn_get()));
 493                                         } else if(rpncmd == "gmtime") {
 494                                                 rpn_set(strftime(FALSE, rpn_get()));
 495                                         } else if(rpncmd == "time") {
 496                                                 rpn_pushf(time);
 497                                         } else if(rpncmd == "digest") {
 498                                                 s = rpn_pop();
 499                                                 rpn_set(digest_hex(s, rpn_get()));
 500                                         } else if(rpncmd == "sprintf1s") {
 501                                                 s = rpn_pop();
 502                                                 rpn_set(sprintf(s, rpn_get()));
 503                                         } else {
 504                                                 rpn_push(cvar_string(rpncmd));
 505                                         }
 506                                         if(rpn_error)
 507                                                 break;
 508                                 }
 509                                 while(rpn_sp > 0)
 510                                 {
 511                                         s = rpn_pop();
 512                                         print("rpn: still on stack: ", s, "\n");
 513                                 }
 514                         }
 515
 516                         return;
 517                 }
 518
 519                 default:
 520                 case CMD_REQUEST_USAGE:
 521                 {
 522                         print("  rpn EXPRESSION... - a RPN calculator.\n");
 523                         print("    Operator description (x: string, s: set, f: float):\n");
 524                         print("    x pop ----------------------------->     : removes the top\n");
 525                         print("    x dup -----------------------------> x x : duplicates the top\n");
 526                         print("    x x exch --------------------------> x x : swap the top two\n");
 527                         print("    /cvarname load --------------------> x   : loads a cvar\n");
 528                         print("    /cvarname x def ------------------->     : writes to a cvar\n");
 529                         print("    f f add|sub|mul|div|mod|max|min ---> f   : adds/... two numbers\n");
 530                         print("    f f eq|ne|gt|ge|lt|le -------------> f   : compares two numbers\n");
 531                         print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
 532                         print("    f f f bound -----------------------> f   : bounds the middle number\n");
 533                         print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
 534                         print("    s s union|intersection|difference -> s   : set operations\n");
 535                         print("    s shuffle -------------------------> s   : randomly arrange elements\n");
 536                         print("    /key /value put ------------------->     : set a database key\n");
 537                         print("    /key get --------------------------> s   : get a database value\n");
 538                         print("    x dbpush -------------------------->     : pushes the top onto the database\n");
 539                         print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
 540                         print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
 541                         print("    dbclr ----------------------------->     : clear the DB\n");
 542                         print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
 543                         print("    x dbins --------------------------->     : moves the top into the DB\n");
 544                         print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
 545                         print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
 546                         print("    s localtime -----------------------> s   : formats the current local time\n");
 547                         print("    s gmtime --------------------------> s   : formats the current UTC time\n");
 548                         print("    time ------------------------------> f   : seconds since VM start\n");
 549                         print("    s /MD4 digest ---------------------> s   : MD4 digest\n");
 550                         print("    s /SHA256 digest ------------------> s   : SHA256 digest\n");
 551                         print("    s /formatstring sprintf1s ---------> s   : sprintf with 1 string (pad, cut)\n");
 552                         print("    Set operations operate on 'such''strings'.\n");
 553                         print("    Unknown tokens insert their cvar value.\n");
 554                         return;
 555                 }
 556         }
 557 }