qcsrc/common/command/rpn.qc

   1 #if defined(CSQC)
   2         #include "../../dpdefs/csprogsdefs.qh"
   3         #include "../../warpzonelib/mathlib.qh"
   4         #include "../util.qh"
   5         #include "rpn.qh"
   6         #include "generic.qh"
   7         #include "shared_defs.qh"
   8 #elif defined(MENUQC)
   9 #elif defined(SVQC)
  10         #include "../../dpdefs/progsdefs.qh"
  11     #include "../../dpdefs/dpextensions.qh"
  12     #include "../../warpzonelib/mathlib.qh"
  13     #include "../util.qh"
  14     #include "rpn.qh"
  15     #include "generic.qh"
  16     #include "shared_defs.qh"
  17 #endif
  18
  19 // ========================================
  20 //  RPN command code, written by divVerent
  21 //  Last updated: December 28th, 2011
  22 // ========================================
  23
  24 string rpn_pop()
  25 {
  26         if(rpn_sp > 0) {
  27                 --rpn_sp;
  28                 return rpn_stack[rpn_sp];
  29         } else {
  30                 print("rpn: stack underflow\n");
  31                 rpn_error = true;
  32                 return "";
  33         }
  34 }
  35 void rpn_push(string s)
  36 {
  37         if(rpn_sp < MAX_RPN_STACK) {
  38                 rpn_stack[rpn_sp] = s;
  39                 ++rpn_sp;
  40         } else {
  41                 print("rpn: stack overflow\n");
  42                 rpn_error = true;
  43         }
  44 }
  45 string rpn_get()
  46 {
  47         if(rpn_sp > 0) {
  48                 return rpn_stack[rpn_sp - 1];
  49         } else {
  50                 print("rpn: empty stack\n");
  51                 rpn_error = true;
  52                 return "";
  53         }
  54 }
  55 void rpn_set(string s)
  56 {
  57         if(rpn_sp > 0) {
  58                 rpn_stack[rpn_sp - 1] = s;
  59         } else {
  60                 print("rpn: empty stack\n");
  61                 rpn_error = true;
  62         }
  63 }
  64
  65 float rpn_getf() { return stof(rpn_get()); }
  66 float rpn_popf() { return stof(rpn_pop()); }
  67 void rpn_pushf(float f) { return rpn_push(sprintf("%.9g", f)); }
  68 void rpn_setf(float f) { return rpn_set(sprintf("%.9g", f)); }
  69
  70 void GenericCommand_rpn(float request, float argc, string command)
  71 {
  72         switch(request)
  73         {
  74                 case CMD_REQUEST_COMMAND:
  75                 {
  76                         float i, j, f, f2, f3, rpnpos;
  77                         //vector rgb;
  78                         string s, s2, rpncmd;
  79
  80                         if(!rpn_db)
  81                         {
  82                                 rpn_db = db_create();
  83                                 db_put(rpn_db, "stack.pointer", "0");
  84                                 db_put(rpn_db, "stack.pos", "-1");
  85                         }
  86
  87                         if(argc >= 2)
  88                         {
  89                                 rpn_sp = 0;
  90                                 rpn_error = false;
  91                                 for(rpnpos = 1; rpnpos < argc; ++rpnpos)
  92                                 {
  93                                         rpncmd = argv(rpnpos);
  94                                         f = strlen(rpncmd);
  95                                         if(rpncmd == "") {
  96                                         } else if(stof(substring(rpncmd, 0, 1)) > 0) {
  97                                                 rpn_push(rpncmd);
  98                                         } else if(substring(rpncmd, 0, 1) == "0") {
  99                                                 rpn_push(rpncmd);
 100                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
 101                                                 rpn_push(rpncmd);
 102                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
 103                                                 rpn_push(rpncmd);
 104                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
 105                                                 rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
 106                                         } else if(rpncmd == "clear") {
 107                                                 rpn_sp = 0;
 108                                         } else if(rpncmd == "def" || rpncmd == "=") {
 109                                                 s = rpn_pop();
 110                                                 s2 = rpn_pop();
 111
 112                                                 if(s2 != "")
 113                                                 {
 114                                                         #ifdef MENUQC
 115                                                         registercvar(s2, "", 0);
 116                                                         #else
 117                                                         registercvar(s2, "");
 118                                                         #endif
 119                                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 120                                                                 cvar_set(s2, s);
 121                                                 }
 122                                                 else
 123                                                 {
 124                                                         print("rpn: empty cvar name for 'def'\n");
 125                                                         rpn_error = true;
 126                                                 }
 127                                         } else if(rpncmd == "defs" || rpncmd == "@") {
 128                                                 s = "";
 129                                                 i = rpn_popf();
 130                                                 j = (i == 0);
 131                                                 while(rpn_sp > 1 && (j || i > 0))
 132                                                 {
 133                                                         s = strcat("/", rpn_pop(), " ", s);
 134                                                         --i;
 135                                                 }
 136                                                 s2 = rpn_pop();
 137                                                 if(s2 != "")
 138                                                 {
 139                                                         #ifdef MENUQC
 140                                                         registercvar(s2, "", 0);
 141                                                         #else
 142                                                         registercvar(s2, "");
 143                                                         #endif
 144                                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 145                                                                 cvar_set(s2, s);
 146                                                 }
 147                                                 else
 148                                                 {
 149                                                         print("rpn: empty cvar name for 'defs'\n");
 150                                                         rpn_error = true;
 151                                                 }
 152                                         } else if(rpncmd == "load") {
 153                                                 rpn_set(cvar_string(rpn_get()));
 154                                         } else if(rpncmd == "exch") {
 155                                                 s = rpn_pop();
 156                                                 s2 = rpn_get();
 157                                                 rpn_set(s);
 158                                                 rpn_push(s2);
 159                                         } else if(rpncmd == "dup") {
 160                                                 rpn_push(rpn_get());
 161                                         } else if(rpncmd == "pop") {
 162                                                 rpn_pop();
 163                                         } else if(rpncmd == "add" || rpncmd == "+") {
 164                                                 f = rpn_popf();
 165                                                 rpn_setf(rpn_getf() + f);
 166                                         } else if(rpncmd == "sub" || rpncmd == "-") {
 167                                                 f = rpn_popf();
 168                                                 rpn_setf(rpn_getf() - f);
 169                                         } else if(rpncmd == "mul" || rpncmd == "*") {
 170                                                 f = rpn_popf();
 171                                                 rpn_setf(rpn_getf() * f);
 172                                         } else if(rpncmd == "div" || rpncmd == "/") {
 173                                                 f = rpn_popf();
 174                                                 rpn_setf(rpn_getf() / f);
 175                                         } else if(rpncmd == "mod" || rpncmd == "%") {
 176                                                 f = rpn_popf();
 177                                                 f2 = rpn_getf();
 178                                                 rpn_setf(f2 - f * floor(f2 / f));
 179                                         } else if(rpncmd == "pow" || rpncmd == "**") {
 180                                                 f = rpn_popf();
 181                                                 rpn_setf(pow(rpn_getf(), f));
 182                                         } else if(rpncmd == "bitand" || rpncmd == "&") {
 183                                                 f = rpn_popf();
 184                                                 rpn_setf(rpn_getf() & f);
 185                                         } else if(rpncmd == "bitor" || rpncmd == "|") {
 186                                                 f = rpn_popf();
 187                                                 rpn_setf(rpn_getf() | f);
 188                                         } else if(rpncmd == "bitxor" || rpncmd == "^") {
 189                                                 f = rpn_popf();
 190                                                 rpn_setf(rpn_getf() ^ f);
 191                                         } else if(rpncmd == "and" || rpncmd == "&&") {
 192                                                 f = rpn_popf();
 193                                                 rpn_setf(rpn_getf() && f);
 194                                         } else if(rpncmd == "or" || rpncmd == "||") {
 195                                                 f = rpn_popf();
 196                                                 rpn_setf(rpn_getf() || f);
 197                                         } else if(rpncmd == "xor" || rpncmd == "^^") {
 198                                                 f = rpn_popf();
 199                                                 rpn_setf(!rpn_getf() != !f);
 200                                         } else if(rpncmd == "bitnot") {
 201                                                 rpn_setf(~rpn_popf());
 202                                         } else if(rpncmd == "not") {
 203                                                 rpn_setf(!rpn_popf());
 204                                         } else if(rpncmd == "abs") {
 205                                                 rpn_setf(fabs(rpn_getf()));
 206                                         } else if(rpncmd == "sgn") {
 207                                                 f = rpn_getf();
 208                                                 if(f < 0)
 209                                                         rpn_set("-1");
 210                                                 else if(f > 0)
 211                                                         rpn_set("1");
 212                                                 else
 213                                                         rpn_set("0");
 214                                         } else if(rpncmd == "neg" || rpncmd == "~") {
 215                                                 rpn_setf(-rpn_getf());
 216                                         } else if(rpncmd == "floor" || rpncmd == "f") {
 217                                                 rpn_setf(floor(rpn_getf()));
 218                                         } else if(rpncmd == "ceil" || rpncmd == "c") {
 219                                                 rpn_setf(ceil(rpn_getf()));
 220                                         } else if(rpncmd == "exp") {
 221                                                 rpn_setf(exp(rpn_getf()));
 222                                         } else if(rpncmd == "log") {
 223                                                 rpn_setf(exp(rpn_getf()));
 224                                         } else if(rpncmd == "sin") {
 225                                                 rpn_setf(sin(rpn_getf()));
 226                                         } else if(rpncmd == "cos") {
 227                                                 rpn_setf(cos(rpn_getf()));
 228                                         } else if(rpncmd == "max") {
 229                                                 f = rpn_popf();
 230                                                 f2 = rpn_getf();
 231                                                 rpn_setf(max(f2, f));
 232                                         } else if(rpncmd == "min") {
 233                                                 f = rpn_popf();
 234                                                 f2 = rpn_getf();
 235                                                 rpn_setf(min(f2, f));
 236                                         } else if(rpncmd == "bound") {
 237                                                 f = rpn_popf();
 238                                                 f2 = rpn_popf();
 239                                                 f3 = rpn_getf();
 240                                                 rpn_setf(bound(f3, f2, f));
 241                                         } else if(rpncmd == "when") {
 242                                                 f = rpn_popf();
 243                                                 s = rpn_pop();
 244                                                 s2 = rpn_get();
 245                                                 if(f)
 246                                                         rpn_set(s2);
 247                                                 else
 248                                                         rpn_set(s);
 249                                         } else if(rpncmd == ">" || rpncmd == "gt") {
 250                                                 f = rpn_popf();
 251                                                 rpn_setf(rpn_getf() > f);
 252                                         } else if(rpncmd == "<" || rpncmd == "lt") {
 253                                                 f = rpn_popf();
 254                                                 rpn_setf(rpn_getf() < f);
 255                                         } else if(rpncmd == "==" || rpncmd == "eq") {
 256                                                 f = rpn_popf();
 257                                                 rpn_setf(rpn_getf() == f);
 258                                         } else if(rpncmd == ">=" || rpncmd == "ge") {
 259                                                 f = rpn_popf();
 260                                                 rpn_setf(rpn_getf() >= f);
 261                                         } else if(rpncmd == "<=" || rpncmd == "le") {
 262                                                 f = rpn_popf();
 263                                                 rpn_setf(rpn_getf() <= f);
 264                                         } else if(rpncmd == "!=" || rpncmd == "ne") {
 265                                                 f = rpn_popf();
 266                                                 rpn_setf(rpn_getf() != f);
 267                                         } else if(rpncmd == "rand") {
 268                                                 rpn_setf(ceil(random() * rpn_getf()) - 1);
 269                                         } else if(rpncmd == "crc16") {
 270                                                 rpn_setf(crc16(false, rpn_get()));
 271                                         } else if(rpncmd == "put") {
 272                                                 s2 = rpn_pop();
 273                                                 if (!rpn_error)
 274                                                 {
 275                                                         s = rpn_pop();
 276                                                         if (!rpn_error)
 277                                                                 db_put(rpn_db, s, s2);
 278                                                 }
 279                                         } else if(rpncmd == "get") {
 280                                                 s = rpn_pop();
 281                                                 if (!rpn_error)
 282                                                         rpn_push(db_get(rpn_db, s));
 283                                         } else if(rpncmd == "dbpush") {
 284                                                 s = rpn_pop();
 285                                                 if(!rpn_error)
 286                                                 {
 287                                                         i = stof(db_get(rpn_db, "stack.pointer"));
 288                                                         db_put(rpn_db, "stack.pointer", ftos(i+1));
 289                                                         db_put(rpn_db, strcat("stack.", ftos(i)), s);
 290                                                         if(!i)
 291                                                                 db_put(rpn_db, "stack.pos", "0");
 292                                                 }
 293                                         } else if(rpncmd == "dbpop") {
 294                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 295                                                 if(i)
 296                                                 {
 297                                                         s = ftos(i-1);
 298                                                         db_put(rpn_db, "stack.pointer", s);
 299                                                         rpn_push(db_get(rpn_db, strcat("stack.", s)));
 300                                                         j = stof(db_get(rpn_db, "stack.pos"));
 301                                                         if(j >= i)
 302                                                                 db_put(rpn_db, "stack.pos", ftos(i-2));
 303                                                 } else {
 304                                                         rpn_error = 1;
 305                                                         print("rpn: database underflow\n");
 306                                                 }
 307                                         } else if(rpncmd == "dbget") {
 308
 309                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 310                                                 if(i)
 311                                                 {
 312                                                         rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 313                                                 } else {
 314                                                         rpn_error = 1;
 315                                                         print("rpn: database empty\n");
 316                                                 }
 317                                         } else if(rpncmd == "dblen") {
 318                                                 rpn_push(db_get(rpn_db, "stack.pointer"));
 319                                         } else if(rpncmd == "dbclr") {
 320                                                 db_close(rpn_db);
 321                                                 rpn_db = db_create();
 322                                                 db_put(rpn_db, "stack.pointer", "0");
 323                                                 db_put(rpn_db, "stack.pos", "-1");
 324                                         } else if(rpncmd == "dbsave") {
 325                                                 s = rpn_pop();
 326                                                 if(!rpn_error)
 327                                                         db_save(rpn_db, s);
 328                                         } else if(rpncmd == "dbload") {
 329                                                 s = rpn_pop();
 330                                                 if(!rpn_error)
 331                                                 {
 332                                                         db_close(rpn_db);
 333                                                         rpn_db = db_load(s);
 334                                                 }
 335                                         } else if(rpncmd == "dbins") {
 336                                                 s = rpn_pop();
 337                                                 if(!rpn_error)
 338                                                         //if(rpn_sp > 0)
 339                                                 {
 340                                                         j = stof(db_get(rpn_db, "stack.pointer"));
 341                                                         i = stof(db_get(rpn_db, "stack.pos"));
 342
 343                                                         if(i < 0)
 344                                                         {
 345                                                                 i = 0;
 346                                                                 db_put(rpn_db, "stack.pos", "0");
 347                                                         }
 348
 349                                                         db_put(rpn_db, "stack.pointer", ftos(j+1));
 350                                                         for(--j; j >= i; --j)
 351                                                         {
 352                                                                 db_put(rpn_db, strcat("stack.", ftos(j+1)),
 353                                                                                          db_get(rpn_db, (strcat("stack.", ftos(j))))
 354                                                                         );
 355                                                         }
 356                                                         db_put(rpn_db, strcat("stack.", ftos(i)), s);
 357                                                 }
 358                                         } else if(rpncmd == "dbext") {
 359                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 360                                                 i = stof(db_get(rpn_db, "stack.pos"));
 361                                                 if(!j)
 362                                                 {
 363                                                         rpn_error = true;
 364                                                         print("rpn: empty database\n");
 365                                                 } else {
 366                                                         --j;
 367                                                         rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 368                                                         db_put(rpn_db, "stack.pointer", ftos(j));
 369                                                         if(i == j)
 370                                                         {
 371                                                                 db_put(rpn_db, "stack.pos", ftos(j-1));
 372                                                         } else {
 373                                                                 while(i < j)
 374                                                                 {
 375                                                                         db_put(rpn_db, strcat("stack.", ftos(i)),
 376                                                                                                  db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 377                                                                                 );
 378                                                                         ++i;
 379                                                                 }
 380                                                         }
 381                                                 }
 382                                         } else if(rpncmd == "dbread") {
 383                                                 s = db_get(rpn_db, "stack.pos");
 384                                                 if(stof(s) >= 0)
 385                                                 {
 386                                                         rpn_push(db_get(rpn_db, strcat("stack.", s)));
 387                                                 } else {
 388                                                         rpn_error = 1;
 389                                                         print("rpn: empty database\n");
 390                                                 }
 391                                         } else if(rpncmd == "dbat") {
 392                                                 rpn_push(db_get(rpn_db, "stack.pos"));
 393                                         } else if(rpncmd == "dbmov") {
 394                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 395                                                 i = stof(db_get(rpn_db, "stack.pos"));
 396                                                 i += rpn_popf();
 397                                                 if(!rpn_error)
 398                                                 {
 399                                                         if(i < 0 || i >= j)
 400                                                         {
 401                                                                 print("rpn: database cursor out of bounds\n");
 402                                                                 rpn_error = true;
 403                                                         }
 404                                                         if(!rpn_error)
 405                                                         {
 406                                                                 db_put(rpn_db, "stack.pos", ftos(i));
 407                                                         }
 408                                                 }
 409                                         } else if(rpncmd == "dbgoto") {
 410                                                 s = rpn_pop();
 411                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 412                                                 if(!j)
 413                                                 {
 414                                                         rpn_error = true;
 415                                                         print("rpn: empty database, cannot move cursor\n");
 416                                                 }
 417                                                 if(!rpn_error)
 418                                                 {
 419                                                         if(s == "end")
 420                                                                 i = stof(db_get(rpn_db, "stack.pointer"))-1;
 421                                                         else if(s == "beg")
 422                                                                 i = 0;
 423                                                         else
 424                                                                 i = stof(s);
 425
 426                                                         j = stof(db_get(rpn_db, "stack.pointer"));
 427                                                         if(i < 0 || i >= j)
 428                                                         {
 429                                                                 print("rpn: database cursor destination out of bounds\n");
 430                                                                 rpn_error = true;
 431                                                         }
 432                                                         if(!rpn_error)
 433                                                         {
 434                                                                 db_put(rpn_db, "stack.pos", ftos(i));
 435                                                         }
 436                                                 }
 437                                         } else if(rpncmd == "union") {
 438                                                 // s s2 union
 439                                                 s2 = rpn_pop();
 440                                                 s = rpn_get();
 441                                                 f = tokenize_console(s);
 442                                                 f2 = tokenize_console(strcat(s, " ", s2));
 443                                                 // tokens 0..(f-1) represent s
 444                                                 // tokens f..f2 represent s2
 445                                                 // UNION: add all tokens to s that are in s2 but not in s
 446                                                 s = "";
 447                                                 for(i = 0; i < f; ++i)
 448                                                         s = strcat(s, " ", argv(i));
 449                                                 for(i = f; i < f2; ++i) {
 450                                                         for(j = 0; j < f; ++j)
 451                                                                 if(argv(i) == argv(j))
 452                                                                         goto skip_union;
 453                                                         s = strcat(s, " ", argv(i));
 454                                                         :skip_union
 455                                                 }
 456                                                 if(substring(s, 0, 1) == " ")
 457                                                         s = substring(s, 1, 99999);
 458                                                 rpn_set(s);
 459                                                 tokenize_console(command);
 460                                         } else if(rpncmd == "intersection") {
 461                                                 // s s2 intersection
 462                                                 s2 = rpn_pop();
 463                                                 s = rpn_get();
 464                                                 f = tokenize_console(s);
 465                                                 f2 = tokenize_console(strcat(s, " ", s2));
 466                                                 // tokens 0..(f-1) represent s
 467                                                 // tokens f..f2 represent s2
 468                                                 // INTERSECTION: keep only the tokens from s that are also in s2
 469                                                 s = "";
 470                                                 for(i = 0; i < f; ++i) {
 471                                                         for(j = f; j < f2; ++j)
 472                                                                 if(argv(i) == argv(j))
 473                                                                 {
 474                                                                         s = strcat(s, " ", argv(i));
 475                                                                         break;
 476                                                                 }
 477                                                 }
 478                                                 if(substring(s, 0, 1) == " ")
 479                                                         s = substring(s, 1, 99999);
 480                                                 rpn_set(s);
 481                                                 tokenize_console(command);
 482                                         } else if(rpncmd == "difference") {
 483                                                 // s s2 difference
 484                                                 s2 = rpn_pop();
 485                                                 s = rpn_get();
 486                                                 f = tokenize_console(s);
 487                                                 f2 = tokenize_console(strcat(s, " ", s2));
 488                                                 // tokens 0..(f-1) represent s
 489                                                 // tokens f..f2 represent s2
 490                                                 // DIFFERENCE: keep only the tokens from s that are not in s2
 491                                                 s = "";
 492                                                 for(i = 0; i < f; ++i) {
 493                                                         for(j = f; j < f2; ++j)
 494                                                                 if(argv(i) == argv(j))
 495                                                                         goto skip_difference;
 496                                                         s = strcat(s, " ", argv(i));
 497                                                         :skip_difference
 498                                                 }
 499                                                 if(substring(s, 0, 1) == " ")
 500                                                         s = substring(s, 1, 99999);
 501                                                 rpn_set(s);
 502                                                 tokenize_console(command);
 503                                         } else if(rpncmd == "shuffle") {
 504                                                 // s shuffle
 505                                                 s = rpn_get();
 506                                                 f = tokenize_console(s);
 507
 508                                                 for(i = 0; i < f - 1; ++i) {
 509                                                         // move a random item from i..f-1 to position i
 510                                                         s = "";
 511                                                         f2 = floor(random() * (f - i) + i);
 512                                                         for(j = 0; j < i; ++j)
 513                                                                 s = strcat(s, " ", argv(j));
 514                                                         s = strcat(s, " ", argv(f2));
 515                                                         for(j = i; j < f; ++j)
 516                                                                 if(j != f2)
 517                                                                         s = strcat(s, " ", argv(j));
 518                                                         f = tokenize_console(s);
 519                                                 }
 520
 521                                                 if(substring(s, 0, 1) == " ")
 522                                                         s = substring(s, 1, 99999);
 523                                                 rpn_set(s);
 524                                                 tokenize_console(command);
 525                                         } else if(rpncmd == "fexists_assert") {
 526                                                 s = rpn_pop();
 527                                                 if(!rpn_error)
 528                                                 {
 529                                                         if (!fexists(s))
 530                                                         {
 531                                                                 print("rpn: ERROR: ", s, " does not exist!\n");
 532                                                                 rpn_error = true;
 533                                                         }
 534                                                 }
 535                                         } else if(rpncmd == "fexists") {
 536                                                 s = rpn_get();
 537                                                 if(!rpn_error)
 538                                                 {
 539                                                         if (fexists(s))
 540                                                                 rpn_setf(1);
 541                                                         else
 542                                                                 rpn_setf(0);
 543                                                 }
 544                                         } else if(rpncmd == "localtime") {
 545                                                 rpn_set(strftime(true, rpn_get()));
 546                                         } else if(rpncmd == "gmtime") {
 547                                                 rpn_set(strftime(false, rpn_get()));
 548                                         } else if(rpncmd == "time") {
 549                                                 rpn_pushf(time);
 550                                         } else if(rpncmd == "digest") {
 551                                                 s = rpn_pop();
 552                                                 rpn_set(digest_hex(s, rpn_get()));
 553                                         } else if(rpncmd == "sprintf1s") {
 554                                                 s = rpn_pop();
 555                                                 rpn_set(sprintf(s, rpn_get()));
 556                                         } else if(rpncmd == "eval") {
 557                                                 s = rpn_pop();
 558                                                 command = strcat(s, substring(command, argv_end_index(rpnpos), -1));
 559                                                 argc = tokenize_console(command);
 560                                                 rpnpos = -1;
 561                                         } else {
 562                                                 rpn_push(cvar_string(rpncmd));
 563                                         }
 564                                         if(rpn_error)
 565                                                 break;
 566                                 }
 567                                 while(rpn_sp > 0)
 568                                 {
 569                                         s = rpn_pop();
 570                                         print("rpn: still on stack: ", s, "\n");
 571                                 }
 572                         }
 573
 574                         return;
 575                 }
 576
 577                 default:
 578                 case CMD_REQUEST_USAGE:
 579                 {
 580                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " rpn EXPRESSION...\n"));
 581                         print("    Operator description (x: string, s: set, f: float):\n");
 582                         print("    x pop ----------------------------->     : removes the top\n");
 583                         print("    x dup -----------------------------> x x : duplicates the top\n");
 584                         print("    x x exch --------------------------> x x : swap the top two\n");
 585                         print("    /cvarname load --------------------> x   : loads a cvar\n");
 586                         print("    /cvarname x def ------------------->     : writes to a cvar\n");
 587                         print("    f f add|sub|mul|div|mod|pow -------> f   : adds/... two numbers\n");
 588                         print("    f f and|or|xor|bitand|bitor|bitxor > f   : logical and bitwise operations\n");
 589                         print("    f f eq|ne|gt|ge|lt|le|max|min -----> f   : compares two numbers\n");
 590                         print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
 591                         print("    f not|bitnot ----------------------> f   : logical and bitwise negation\n");
 592                         print("    f exp|log|sin|cos -----------------> f   : exponential function & Co.\n");
 593                         print("    f f f bound -----------------------> f   : bounds the middle number\n");
 594                         print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
 595                         print("    s s union|intersection|difference -> s   : set operations\n");
 596                         print("    s shuffle -------------------------> s   : randomly arrange elements\n");
 597                         print("    /key /value put ------------------->     : set a database key\n");
 598                         print("    /key get --------------------------> s   : get a database value\n");
 599                         print("    x dbpush -------------------------->     : pushes the top onto the database\n");
 600                         print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
 601                         print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
 602                         print("    dbclr ----------------------------->     : clear the DB\n");
 603                         print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
 604                         print("    x dbins --------------------------->     : moves the top into the DB\n");
 605                         print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
 606                         print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
 607                         print("    s localtime -----------------------> s   : formats the current local time\n");
 608                         print("    s gmtime --------------------------> s   : formats the current UTC time\n");
 609                         print("    time ------------------------------> f   : seconds since VM start\n");
 610                         print("    s /MD4 digest ---------------------> s   : MD4 digest\n");
 611                         print("    s /SHA256 digest ------------------> s   : SHA256 digest\n");
 612                         print("    s /formatstring sprintf1s ---------> s   : sprintf with 1 string (pad, cut)\n");
 613                         print("    s eval ---------------------------->     : does something eval\n");
 614                         print("    Set operations operate on 'such''strings'.\n");
 615                         print("    Unknown tokens insert their cvar value.\n");
 616                         return;
 617                 }
 618         }
 619 }