qcsrc/common/effects/qc/globalsound.qc

   1 #include "globalsound.qh"
   2
   3 #include <common/ent_cs.qh>
   4
   5 #ifdef IMPLEMENTATION
   6         #include <common/animdecide.qh>
   7
   8         #ifdef SVQC
   9                 #include <server/cl_player.qh>
  10         #endif
  11
  12         REGISTER_NET_TEMP(globalsound)
  13         REGISTER_NET_TEMP(playersound)
  14
  15         string GlobalSound_sample(string pair, float r);
  16
  17         #ifdef SVQC
  18                 /** Use new sound handling. TODO: use when sounds play correctly on clients */
  19                 bool autocvar_g_debug_globalsounds = false;
  20                 /**
  21                  * @param from the source entity, its position is sent
  22                  * @param gs the global sound def
  23                  * @param r a random number in 0..1
  24                  */
  25                 void globalsound(int channel, entity from, entity gs, float r, int chan, float vol, float atten)
  26                 {
  27                         assert(IS_PLAYER(from), eprint(from));
  28                         if (channel == MSG_ONE && !IS_REAL_CLIENT(msg_entity)) return;
  29                         if (!autocvar_g_debug_globalsounds) {
  30                                 string sample = GlobalSound_sample(gs.m_globalsoundstr, r);
  31                                 switch (channel) {
  32                                         case MSG_ONE:
  33                                                 soundto(channel, from, chan, sample, vol, atten);
  34                                                 break;
  35                                         case MSG_ALL:
  36                                                 _sound(from, chan, sample, vol, atten);
  37                                                 break;
  38                                 }
  39                                 return;
  40                         }
  41                         WriteHeader(channel, globalsound);
  42                         WriteByte(channel, gs.m_id);
  43                         WriteByte(channel, r * 255);
  44                         WriteByte(channel, etof(from));
  45                         WriteByte(channel, chan);
  46                         WriteByte(channel, floor(vol * 255));
  47                         WriteByte(channel, floor(atten * 64));
  48                         entcs_force_origin(from);
  49                         vector o = from.origin + 0.5 * (from.mins + from.maxs);
  50                         WriteCoord(channel, o.x);
  51                         WriteCoord(channel, o.y);
  52                         WriteCoord(channel, o.z);
  53                 }
  54
  55                 /**
  56                 * @param from the source entity, its position is sent
  57                 * @param ps the player sound def
  58                 * @param r a random number in 0..1
  59                 */
  60                 void playersound(int channel, entity from, entity ps, float r, int chan, float vol, float atten)
  61                 {
  62                         assert(IS_PLAYER(from), eprint(from));
  63                         if (channel == MSG_ONE && !IS_REAL_CLIENT(msg_entity)) return;
  64                         if (!autocvar_g_debug_globalsounds) {
  65                                 UpdatePlayerSounds(from);
  66                                 string s = from.(ps.m_playersoundfld);
  67                                 string sample = GlobalSound_sample(s, r);
  68                                 switch (channel) {
  69                                         case MSG_ONE:
  70                                                 soundto(channel, from, chan, sample, vol, atten);
  71                                                 break;
  72                                         case MSG_ALL:
  73                                                 _sound(from, chan, sample, vol, atten);
  74                                                 break;
  75                                 }
  76                                 return;
  77                         }
  78                         WriteHeader(channel, playersound);
  79                         WriteByte(channel, ps.m_id);
  80                         WriteByte(channel, r * 255);
  81                         WriteByte(channel, etof(from));
  82                         WriteByte(channel, chan);
  83                         WriteByte(channel, floor(vol * 255));
  84                         WriteByte(channel, floor(atten * 64));
  85                         entcs_force_origin(from);
  86                         vector o = from.origin + 0.5 * (from.mins + from.maxs);
  87                         WriteCoord(channel, o.x);
  88                         WriteCoord(channel, o.y);
  89                         WriteCoord(channel, o.z);
  90                 }
  91         #endif
  92
  93         #ifdef CSQC
  94
  95                 NET_HANDLE(globalsound, bool isnew)
  96                 {
  97                         entity gs = GlobalSounds_from(ReadByte());
  98                         float r = ReadByte() / 255;
  99                         string sample = GlobalSound_sample(gs.m_globalsoundstr, r);
 100                         int who = ReadByte();
 101                         entity e = entcs_receiver(who - 1);
 102                         int chan = ReadSByte();
 103                         float vol = ReadByte() / 255;
 104                         float atten = ReadByte() / 64;
 105                         vector o;
 106                         o.x = ReadCoord();
 107                         o.y = ReadCoord();
 108                         o.z = ReadCoord();
 109                         // TODO: is this really what we want to be doing? Footsteps that follow the player at head height?
 110                         if (who == player_currententnum) e = findfloat(world, entnum, who);  // play at camera position for full volume
 111                         else if (e) e.origin = o;
 112                         if (e)
 113                         {
 114                                 sound7(e, chan, sample, vol, atten, 0, 0);
 115                         }
 116                         else
 117                         {
 118                                 // Can this happen?
 119                                 LOG_WARNINGF("Missing entcs data for player %d\n", who);
 120                                 sound8(e, o, chan, sample, vol, atten, 0, 0);
 121                         }
 122                         return true;
 123                 }
 124
 125                 NET_HANDLE(playersound, bool isnew)
 126                 {
 127                         entity ps = PlayerSounds_from(ReadByte());
 128                         float r = ReadByte() / 255;
 129                         int who = ReadByte();
 130                         entity e = entcs_receiver(who - 1);
 131                         UpdatePlayerSounds(e);
 132                         string s = e.(ps.m_playersoundfld);
 133                         string sample = GlobalSound_sample(s, r);
 134                         int chan = ReadSByte();
 135                         float vol = ReadByte() / 255;
 136                         float atten = ReadByte() / 64;
 137                         vector o;
 138                         o.x = ReadCoord();
 139                         o.y = ReadCoord();
 140                         o.z = ReadCoord();
 141                         if (who == player_currententnum) e = findfloat(world, entnum, who);  // play at camera position for full volume
 142                         else if (e) e.origin = o;
 143                         if (e)
 144                         {
 145                                 // TODO: for non-visible players, origin should probably continue to be updated as long as the sound is playing
 146                                 sound7(e, chan, sample, vol, atten, 0, 0);
 147                         }
 148                         else
 149                         {
 150                                 // Can this happen?
 151                                 LOG_WARNINGF("Missing entcs data for player %d\n", who);
 152                                 sound8(e, o, chan, sample, vol, atten, 0, 0);
 153                         }
 154                         return true;
 155                 }
 156
 157         #endif
 158
 159         string GlobalSound_sample(string pair, float r)
 160         {
 161                 int n;
 162                 {
 163                         string s = cdr(pair);
 164                         if (s) n = stof(s);
 165                         else n = 0;
 166                 }
 167                 string sample = car(pair);
 168                 if (n > 0) sample = sprintf("%s%d.wav", sample, floor(r * n + 1));  // randomization
 169                 else sample = sprintf("%s.wav", sample);
 170                 return sample;
 171         }
 172
 173         void PrecacheGlobalSound(string sample)
 174         {
 175                 int n;
 176                 {
 177                         string s = cdr(sample);
 178                         if (s) n = stof(s);
 179                         else n = 0;
 180                 }
 181                 sample = car(sample);
 182                 if (n > 0)
 183                 {
 184                         for (int i = 1; i <= n; ++i)
 185                                 precache_sound(sprintf("%s%d.wav", sample, i));
 186                 }
 187                 else
 188                 {
 189                         precache_sound(sprintf("%s.wav", sample));
 190                 }
 191         }
 192
 193         entity GetVoiceMessage(string type)
 194         {
 195                 FOREACH(PlayerSounds, it.m_playersoundstr == type && it.instanceOfVoiceMessage == true, return it);
 196                 return NULL;
 197         }
 198
 199         entity GetPlayerSound(string type)
 200         {
 201                 FOREACH(PlayerSounds, it.m_playersoundstr == type && it.instanceOfVoiceMessage == false, return it);
 202                 return NULL;
 203         }
 204
 205         string allvoicesamples;
 206         STATIC_INIT(allvoicesamples)
 207         {
 208                 FOREACH(PlayerSounds, it.instanceOfVoiceMessage, allvoicesamples = strcat(allvoicesamples, " ", it.m_playersoundstr));
 209                 allvoicesamples = strzone(substring(allvoicesamples, 1, -1));
 210         }
 211
 212         .string _GetPlayerSoundSampleField(string type, bool voice)
 213         {
 214                 GetPlayerSoundSampleField_notFound = false;
 215                 entity e = voice ? GetVoiceMessage(type) : GetPlayerSound(type);
 216                 if (e) return e.m_playersoundfld;
 217                 GetPlayerSoundSampleField_notFound = true;
 218                 return playersound_taunt.m_playersoundfld;
 219         }
 220
 221         .string GetVoiceMessageSampleField(string type)
 222         {
 223                 return _GetPlayerSoundSampleField(type, true);
 224         }
 225
 226         void PrecachePlayerSounds(string f)
 227         {
 228                 int fh = fopen(f, FILE_READ);
 229                 if (fh < 0)
 230                 {
 231                         LOG_WARNINGF("Player sound file not found: %s\n", f);
 232                         return;
 233                 }
 234                 for (string s; (s = fgets(fh)); )
 235                 {
 236                         int n = tokenize_console(s);
 237                         if (n != 3)
 238                         {
 239                                 if (n != 0) LOG_WARNINGF("Invalid sound info line: %s\n", s);
 240                                 continue;
 241                         }
 242                         string file = argv(1);
 243                         string variants = argv(2);
 244                         PrecacheGlobalSound(strcat(file, " ", variants));
 245                 }
 246                 fclose(fh);
 247         }
 248
 249         //#ifdef CSQC
 250
 251                 .string GetPlayerSoundSampleField(string type)
 252                 {
 253                         return _GetPlayerSoundSampleField(type, false);
 254                 }
 255
 256                 void ClearPlayerSounds(entity this)
 257                 {
 258                         FOREACH(PlayerSounds, true, {
 259                                 .string fld = it.m_playersoundfld;
 260                                 if (this.(fld))
 261                                 {
 262                                         strunzone(this.(fld));
 263                                         this.(fld) = string_null;
 264                                 }
 265                         });
 266                 }
 267
 268                 bool LoadPlayerSounds(entity this, string f, bool strict)
 269                 {
 270                         int fh = fopen(f, FILE_READ);
 271                         if (fh < 0)
 272                         {
 273                                 if (strict) LOG_WARNINGF("Player sound file not found: %s\n", f);
 274                                 return false;
 275                         }
 276                         for (string s; (s = fgets(fh)); )
 277                         {
 278                                 int n = tokenize_console(s);
 279                                 if (n != 3)
 280                                 {
 281                                         if (n != 0) LOG_WARNINGF("Invalid sound info line: %s\n", s);
 282                                         continue;
 283                                 }
 284                                 string key = argv(0);
 285                                 var.string field = GetPlayerSoundSampleField(key);
 286                                 if (GetPlayerSoundSampleField_notFound) field = GetVoiceMessageSampleField(key);
 287                                 if (GetPlayerSoundSampleField_notFound)
 288                                 {
 289                                         LOG_TRACEF("Invalid sound info field: %s\n", key);
 290                                         continue;
 291                                 }
 292                                 string file = argv(1);
 293                                 string variants = argv(2);
 294                                 if (this.(field)) strunzone(this.(field));
 295                                 this.(field) = strzone(strcat(file, " ", variants));
 296                         }
 297                         fclose(fh);
 298                         return true;
 299                 }
 300
 301                 .string model_for_playersound;
 302                 .int skin_for_playersound;
 303
 304                 bool autocvar_g_debug_defaultsounds;
 305
 306                 void UpdatePlayerSounds(entity this)
 307                 {
 308                         if (this.model == this.model_for_playersound && this.skin == this.skin_for_playersound) return;
 309                         if (this.model_for_playersound) strunzone(this.model_for_playersound);
 310                         this.model_for_playersound = strzone(this.model);
 311                         this.skin_for_playersound = this.skin;
 312                         ClearPlayerSounds(this);
 313                         LoadPlayerSounds(this, "sound/player/default.sounds", true);
 314                         if (this.model == "null" || autocvar_g_debug_defaultsounds) return;
 315                         if (LoadPlayerSounds(this, get_model_datafilename(this.model, this.skin, "sounds"), false)) return;
 316                         LoadPlayerSounds(this, get_model_datafilename(this.model, 0, "sounds"), true);
 317                 }
 318
 319         //#endif
 320
 321         #ifdef SVQC
 322
 323                 void _GlobalSound(entity this, entity gs, entity ps, string sample, int chan, int voicetype, bool fake)
 324                 {
 325                         if (gs == NULL && ps == NULL && sample == "") return;
 326                         if(this.classname == "body") return;
 327                         float r = random();
 328                         if (sample != "") sample = GlobalSound_sample(sample, r);
 329                         switch (voicetype)
 330                         {
 331                                 case VOICETYPE_LASTATTACKER_ONLY:
 332                                 case VOICETYPE_LASTATTACKER:
 333                                 {
 334                                         if (!fake)
 335                                         {
 336                                                 if (!this.pusher) break;
 337                                                 msg_entity = this.pusher;
 338                                                 if (IS_REAL_CLIENT(msg_entity))
 339                                                 {
 340                                                         float atten = (msg_entity.cvar_cl_voice_directional == 1) ? ATTEN_MIN : ATTEN_NONE;
 341                                                         if (gs) globalsound(MSG_ONE, this, gs, r, chan, VOL_BASEVOICE, atten);
 342                                                         else if (ps) playersound(MSG_ONE, this, ps, r, chan, VOL_BASEVOICE, atten);
 343                                                         else soundto(MSG_ONE, this, chan, sample, VOL_BASEVOICE, atten);
 344                                                 }
 345                                         }
 346                                         if (voicetype == VOICETYPE_LASTATTACKER_ONLY) break;
 347                                         msg_entity = this;
 348                                         if (IS_REAL_CLIENT(msg_entity))
 349                                         {
 350                                                 if (gs) globalsound(MSG_ONE, this, gs, r, chan, VOL_BASE, ATTEN_NONE);
 351                                                 else if (ps) playersound(MSG_ONE, this, ps, r, chan, VOL_BASE, ATTEN_NONE);
 352                                                 else soundto(MSG_ONE, this, chan, sample, VOL_BASE, ATTEN_NONE);
 353                                         }
 354                                         break;
 355                                 }
 356                                 case VOICETYPE_TEAMRADIO:
 357                                 {
 358                                         #define X() \
 359                                                 MACRO_BEGIN \
 360                                                 { \
 361                                                         float atten = (msg_entity.cvar_cl_voice_directional == 1) ? ATTEN_MIN : ATTEN_NONE; \
 362                                                         if (gs) globalsound(MSG_ONE, this, gs, r, chan, VOL_BASEVOICE, atten); \
 363                                                         else if (ps) playersound(MSG_ONE, this, ps, r, chan, VOL_BASEVOICE, atten); \
 364                                                         else soundto(MSG_ONE, this, chan, sample, VOL_BASEVOICE, atten); \
 365                                                 } MACRO_END
 366
 367                                         if (fake) { msg_entity = this; X(); }
 368                                         else
 369                                         {
 370                                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && (!teamplay || msg_entity.team == this.team), {
 371                                                         msg_entity = it;
 372                                                         X();
 373                                                 });
 374                                         }
 375                 #undef X
 376                                         break;
 377                                 }
 378                                 case VOICETYPE_AUTOTAUNT:
 379                                 case VOICETYPE_TAUNT:
 380                                 {
 381                                         if (voicetype == VOICETYPE_AUTOTAUNT) if (!sv_autotaunt) { break; }else {}
 382                                         else if (IS_PLAYER(this) && !IS_DEAD(this)) animdecide_setaction(this, ANIMACTION_TAUNT,
 383                                                         true);
 384                                         if (!sv_taunt) break;
 385                                         if (autocvar_sv_gentle) break;
 386                                         float tauntrand = 0;
 387                                         if (voicetype == VOICETYPE_AUTOTAUNT) tauntrand = random();
 388                                         #define X() \
 389                                                 MACRO_BEGIN \
 390                                                 { \
 391                                                         if (voicetype != VOICETYPE_AUTOTAUNT || tauntrand < msg_entity.cvar_cl_autotaunt) \
 392                                                         { \
 393                                                                 float atten = (msg_entity.cvar_cl_voice_directional >= 1) \
 394                                                                     ? bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, \
 395                                                                         ATTEN_MAX) \
 396                                                                         : ATTEN_NONE; \
 397                                                                 if (gs) globalsound(MSG_ONE, this, gs, r, chan, VOL_BASEVOICE, atten); \
 398                                                                 else if (ps) playersound(MSG_ONE, this, ps, r, chan, VOL_BASEVOICE, atten); \
 399                                                                 else soundto(MSG_ONE, this, chan, sample, VOL_BASEVOICE, atten); \
 400                                                         } \
 401                                                 } MACRO_END
 402                                         if (fake)
 403                                         {
 404                                                 msg_entity = this;
 405                                                 X();
 406                                         }
 407                                         else
 408                                         {
 409                                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 410                                                         msg_entity = it;
 411                                                         X();
 412                                                 });
 413                                         }
 414                 #undef X
 415                                         break;
 416                                 }
 417                                 case VOICETYPE_PLAYERSOUND:
 418                                 {
 419                                         msg_entity = this;
 420                                         if (fake)
 421                                         {
 422                                                 if (gs) globalsound(MSG_ONE, this, gs, r, chan, VOL_BASE, ATTEN_NORM);
 423                                                 else if (ps) playersound(MSG_ONE, this, ps, r, chan, VOL_BASE, ATTEN_NORM);
 424                                                 else soundto(MSG_ONE, this, chan, sample, VOL_BASE, ATTEN_NORM);
 425                                         }
 426                                         else
 427                                         {
 428                                                 if (gs) globalsound(MSG_ALL, this, gs, r, chan, VOL_BASE, ATTEN_NORM);
 429                                                 else if (ps) playersound(MSG_ALL, this, ps, r, chan, VOL_BASE, ATTEN_NORM);
 430                                                 else _sound(this, chan, sample, VOL_BASE, ATTEN_NORM);
 431                                         }
 432                                         break;
 433                                 }
 434                                 default:
 435                                 {
 436                                         backtrace("Invalid voice type!");
 437                                         break;
 438                                 }
 439                         }
 440                 }
 441
 442         #endif
 443 #endif