qcsrc/common/effects/qc/globalsound.qc

   1 #include "globalsound.qh"
   2
   3 #include <common/ent_cs.qh>
   4
   5 #ifdef IMPLEMENTATION
   6         #include <common/animdecide.qh>
   7
   8         #ifdef SVQC
   9                 #include <server/cl_player.qh>
  10         #endif
  11
  12         REGISTER_NET_TEMP(globalsound)
  13         REGISTER_NET_TEMP(playersound)
  14
  15         string GlobalSound_sample(string pair, float r);
  16
  17         #ifdef SVQC
  18                 /** Use new sound handling. TODO: use when sounds play correctly on clients */
  19                 bool autocvar_g_debug_globalsounds = false;
  20                 /**
  21                  * @param from the source entity, its position is sent
  22                  * @param gs the global sound def
  23                  * @param r a random number in 0..1
  24                  */
  25                 void globalsound(int channel, entity from, entity gs, float r, int chan, float _vol, float _atten)
  26                 {
  27                         assert(IS_PLAYER(from), eprint(from));
  28                         if (channel == MSG_ONE && !IS_REAL_CLIENT(msg_entity)) return;
  29                         if (!autocvar_g_debug_globalsounds) {
  30                                 string sample = GlobalSound_sample(gs.m_globalsoundstr, r);
  31                                 switch (channel) {
  32                                         case MSG_ONE:
  33                                                 soundto(channel, from, chan, sample, _vol, _atten);
  34                                                 break;
  35                                         case MSG_ALL:
  36                                                 _sound(from, chan, sample, _vol, _atten);
  37                                                 break;
  38                                 }
  39                                 return;
  40                         }
  41                         WriteHeader(channel, globalsound);
  42                         WriteByte(channel, gs.m_id);
  43                         WriteByte(channel, r * 255);
  44                         WriteByte(channel, etof(from));
  45                         WriteByte(channel, chan);
  46                         WriteByte(channel, floor(_vol * 255));
  47                         WriteByte(channel, floor(_atten * 64));
  48                         entcs_force_origin(from);
  49                         vector o = from.origin + 0.5 * (from.mins + from.maxs);
  50                         WriteCoord(channel, o.x);
  51                         WriteCoord(channel, o.y);
  52                         WriteCoord(channel, o.z);
  53                 }
  54
  55                 /**
  56                 * @param from the source entity, its position is sent
  57                 * @param ps the player sound def
  58                 * @param r a random number in 0..1
  59                 */
  60                 void playersound(int channel, entity from, entity ps, float r, int chan, float _vol, float _atten)
  61                 {
  62                         assert(IS_PLAYER(from), eprint(from));
  63                         if (channel == MSG_ONE && !IS_REAL_CLIENT(msg_entity)) return;
  64                         if (!autocvar_g_debug_globalsounds) {
  65                                 UpdatePlayerSounds(from);
  66                                 string s = from.(ps.m_playersoundfld);
  67                                 string sample = GlobalSound_sample(s, r);
  68                                 switch (channel) {
  69                                         case MSG_ONE:
  70                                                 soundto(channel, from, chan, sample, _vol, _atten);
  71                                                 break;
  72                                         case MSG_ALL:
  73                                                 _sound(from, chan, sample, _vol, _atten);
  74                                                 break;
  75                                 }
  76                                 return;
  77                         }
  78                         WriteHeader(channel, playersound);
  79                         WriteByte(channel, ps.m_id);
  80                         WriteByte(channel, r * 255);
  81                         WriteByte(channel, etof(from));
  82                         WriteByte(channel, chan);
  83                         WriteByte(channel, floor(_vol * 255));
  84                         WriteByte(channel, floor(_atten * 64));
  85                         entcs_force_origin(from);
  86                         vector o = from.origin + 0.5 * (from.mins + from.maxs);
  87                         WriteCoord(channel, o.x);
  88                         WriteCoord(channel, o.y);
  89                         WriteCoord(channel, o.z);
  90                 }
  91         #endif
  92
  93         #ifdef CSQC
  94
  95                 NET_HANDLE(globalsound, bool isnew)
  96                 {
  97                         entity gs = GlobalSounds_from(ReadByte());
  98                         float r = ReadByte() / 255;
  99                         string sample = GlobalSound_sample(gs.m_globalsoundstr, r);
 100                         int who = ReadByte();
 101                         entity e = entcs_receiver(who - 1);
 102                         int chan = ReadSByte();
 103                         float vol = ReadByte() / 255;
 104                         float atten = ReadByte() / 64;
 105                         vector o;
 106                         o.x = ReadCoord();
 107                         o.y = ReadCoord();
 108                         o.z = ReadCoord();
 109                         // TODO: is this really what we want to be doing? Footsteps that follow the player at head height?
 110                         if (who == player_currententnum) e = findfloat(world, entnum, who);  // play at camera position for full volume
 111                         else if (e) e.origin = o;
 112                         if (e)
 113                         {
 114                                 sound7(e, chan, sample, vol, atten, 0, 0);
 115                         }
 116                         else
 117                         {
 118                                 // Can this happen?
 119                                 LOG_WARNINGF("Missing entcs data for player %d\n", who);
 120                                 sound8(e, o, chan, sample, vol, atten, 0, 0);
 121                         }
 122                         return true;
 123                 }
 124
 125                 NET_HANDLE(playersound, bool isnew)
 126                 {
 127                         entity ps = PlayerSounds_from(ReadByte());
 128                         float r = ReadByte() / 255;
 129                         int who = ReadByte();
 130                         entity e = entcs_receiver(who - 1);
 131                         UpdatePlayerSounds(e);
 132                         string s = e.(ps.m_playersoundfld);
 133                         string sample = GlobalSound_sample(s, r);
 134                         int chan = ReadSByte();
 135                         float vol = ReadByte() / 255;
 136                         float atten = ReadByte() / 64;
 137                         vector o;
 138                         o.x = ReadCoord();
 139                         o.y = ReadCoord();
 140                         o.z = ReadCoord();
 141                         if (who == player_currententnum) e = findfloat(world, entnum, who);  // play at camera position for full volume
 142                         else if (e) e.origin = o;
 143                         if (e)
 144                         {
 145                                 // TODO: for non-visible players, origin should probably continue to be updated as long as the sound is playing
 146                                 sound7(e, chan, sample, vol, atten, 0, 0);
 147                         }
 148                         else
 149                         {
 150                                 // Can this happen?
 151                                 LOG_WARNINGF("Missing entcs data for player %d\n", who);
 152                                 sound8(e, o, chan, sample, vol, atten, 0, 0);
 153                         }
 154                         return true;
 155                 }
 156
 157         #endif
 158
 159         string GlobalSound_sample(string pair, float r)
 160         {
 161                 int n;
 162                 {
 163                         string s = cdr(pair);
 164                         if (s) n = stof(s);
 165                         else n = 0;
 166                 }
 167                 string sample = car(pair);
 168                 if (n > 0) sample = sprintf("%s%d.wav", sample, floor(r * n + 1));  // randomization
 169                 else sample = sprintf("%s.wav", sample);
 170                 return sample;
 171         }
 172
 173         void PrecacheGlobalSound(string sample)
 174         {
 175                 int n;
 176                 {
 177                         string s = cdr(sample);
 178                         if (s) n = stof(s);
 179                         else n = 0;
 180                 }
 181                 sample = car(sample);
 182                 if (n > 0)
 183                 {
 184                         for (int i = 1; i <= n; ++i)
 185                                 precache_sound(sprintf("%s%d.wav", sample, i));
 186                 }
 187                 else
 188                 {
 189                         precache_sound(sprintf("%s.wav", sample));
 190                 }
 191         }
 192
 193         entity GetVoiceMessage(string type)
 194         {
 195                 FOREACH(PlayerSounds, it.m_playersoundstr == type && it.instanceOfVoiceMessage == true, return it);
 196                 return NULL;
 197         }
 198
 199         entity GetPlayerSound(string type)
 200         {
 201                 FOREACH(PlayerSounds, it.m_playersoundstr == type && it.instanceOfVoiceMessage == false, return it);
 202                 return NULL;
 203         }
 204
 205         .string _GetPlayerSoundSampleField(string type, bool voice)
 206         {
 207                 GetPlayerSoundSampleField_notFound = false;
 208                 entity e = voice ? GetVoiceMessage(type) : GetPlayerSound(type);
 209                 if (e) return e.m_playersoundfld;
 210                 GetPlayerSoundSampleField_notFound = true;
 211                 return playersound_taunt.m_playersoundfld;
 212         }
 213
 214         .string GetVoiceMessageSampleField(string type)
 215         {
 216                 return _GetPlayerSoundSampleField(type, true);
 217         }
 218
 219         void PrecachePlayerSounds(string f)
 220         {
 221                 int fh = fopen(f, FILE_READ);
 222                 if (fh < 0)
 223                 {
 224                         LOG_WARNINGF("Player sound file not found: %s\n", f);
 225                         return;
 226                 }
 227                 for (string s; (s = fgets(fh)); )
 228                 {
 229                         int n = tokenize_console(s);
 230                         if (n != 3)
 231                         {
 232                                 if (n != 0) LOG_WARNINGF("Invalid sound info line: %s\n", s);
 233                                 continue;
 234                         }
 235                         string file = argv(1);
 236                         string variants = argv(2);
 237                         PrecacheGlobalSound(strcat(file, " ", variants));
 238                 }
 239                 fclose(fh);
 240         }
 241
 242         //#ifdef CSQC
 243
 244                 .string GetPlayerSoundSampleField(string type)
 245                 {
 246                         return _GetPlayerSoundSampleField(type, false);
 247                 }
 248
 249                 void ClearPlayerSounds(entity this)
 250                 {
 251                         FOREACH(PlayerSounds, true, {
 252                                 .string fld = it.m_playersoundfld;
 253                                 if (this.(fld))
 254                                 {
 255                                         strunzone(this.(fld));
 256                                         this.(fld) = string_null;
 257                                 }
 258                         });
 259                 }
 260
 261                 bool LoadPlayerSounds(entity this, string f, bool strict)
 262                 {
 263                         int fh = fopen(f, FILE_READ);
 264                         if (fh < 0)
 265                         {
 266                                 if (strict) LOG_WARNINGF("Player sound file not found: %s\n", f);
 267                                 return false;
 268                         }
 269                         for (string s; (s = fgets(fh)); )
 270                         {
 271                                 int n = tokenize_console(s);
 272                                 if (n != 3)
 273                                 {
 274                                         if (n != 0) LOG_WARNINGF("Invalid sound info line: %s\n", s);
 275                                         continue;
 276                                 }
 277                                 string key = argv(0);
 278                                 var.string field = GetPlayerSoundSampleField(key);
 279                                 if (GetPlayerSoundSampleField_notFound) field = GetVoiceMessageSampleField(key);
 280                                 if (GetPlayerSoundSampleField_notFound)
 281                                 {
 282                                         LOG_TRACEF("Invalid sound info field: %s\n", key);
 283                                         continue;
 284                                 }
 285                                 string file = argv(1);
 286                                 string variants = argv(2);
 287                                 if (this.(field)) strunzone(this.(field));
 288                                 this.(field) = strzone(strcat(file, " ", variants));
 289                         }
 290                         fclose(fh);
 291                         return true;
 292                 }
 293
 294                 .string model_for_playersound;
 295                 .int skin_for_playersound;
 296
 297                 bool autocvar_g_debug_defaultsounds;
 298
 299                 void UpdatePlayerSounds(entity this)
 300                 {
 301                         if (this.model == this.model_for_playersound && this.skin == this.skin_for_playersound) return;
 302                         if (this.model_for_playersound) strunzone(this.model_for_playersound);
 303                         this.model_for_playersound = strzone(this.model);
 304                         this.skin_for_playersound = this.skin;
 305                         ClearPlayerSounds(this);
 306                         LoadPlayerSounds(this, "sound/player/default.sounds", true);
 307                         if (this.model == "null" || autocvar_g_debug_defaultsounds) return;
 308                         if (LoadPlayerSounds(this, get_model_datafilename(this.model, this.skin, "sounds"), false)) return;
 309                         LoadPlayerSounds(this, get_model_datafilename(this.model, 0, "sounds"), true);
 310                 }
 311
 312         //#endif
 313
 314         #ifdef SVQC
 315
 316                 void _GlobalSound(entity this, entity gs, entity ps, string sample, int chan, int voicetype, bool fake)
 317                 {
 318                         if (gs == NULL && ps == NULL && sample == "") return;
 319                         if(this.classname == "body") return;
 320                         float r = random();
 321                         if (sample != "") sample = GlobalSound_sample(sample, r);
 322                         switch (voicetype)
 323                         {
 324                                 case VOICETYPE_LASTATTACKER_ONLY:
 325                                 case VOICETYPE_LASTATTACKER:
 326                                 {
 327                                         if (!fake)
 328                                         {
 329                                                 if (!this.pusher) break;
 330                                                 msg_entity = this.pusher;
 331                                                 if (IS_REAL_CLIENT(msg_entity))
 332                                                 {
 333                                                         float atten = (msg_entity.cvar_cl_voice_directional == 1) ? ATTEN_MIN : ATTEN_NONE;
 334                                                         if (gs) globalsound(MSG_ONE, this, gs, r, chan, VOL_BASEVOICE, atten);
 335                                                         else if (ps) playersound(MSG_ONE, this, ps, r, chan, VOL_BASEVOICE, atten);
 336                                                         else soundto(MSG_ONE, this, chan, sample, VOL_BASEVOICE, atten);
 337                                                 }
 338                                         }
 339                                         if (voicetype == VOICETYPE_LASTATTACKER_ONLY) break;
 340                                         msg_entity = this;
 341                                         if (IS_REAL_CLIENT(msg_entity))
 342                                         {
 343                                                 if (gs) globalsound(MSG_ONE, this, gs, r, chan, VOL_BASE, ATTEN_NONE);
 344                                                 else if (ps) playersound(MSG_ONE, this, ps, r, chan, VOL_BASE, ATTEN_NONE);
 345                                                 else soundto(MSG_ONE, this, chan, sample, VOL_BASE, ATTEN_NONE);
 346                                         }
 347                                         break;
 348                                 }
 349                                 case VOICETYPE_TEAMRADIO:
 350                                 {
 351                                         #define X() \
 352                                                 MACRO_BEGIN \
 353                                                 { \
 354                                                         float atten = (msg_entity.cvar_cl_voice_directional == 1) ? ATTEN_MIN : ATTEN_NONE; \
 355                                                         if (gs) globalsound(MSG_ONE, this, gs, r, chan, VOL_BASEVOICE, atten); \
 356                                                         else if (ps) playersound(MSG_ONE, this, ps, r, chan, VOL_BASEVOICE, atten); \
 357                                                         else soundto(MSG_ONE, this, chan, sample, VOL_BASEVOICE, atten); \
 358                                                 } MACRO_END
 359
 360                                         if (fake) { msg_entity = this; X(); }
 361                                         else
 362                                         {
 363                                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && (!teamplay || msg_entity.team == this.team), {
 364                                                         msg_entity = it;
 365                                                         X();
 366                                                 });
 367                                         }
 368                 #undef X
 369                                         break;
 370                                 }
 371                                 case VOICETYPE_AUTOTAUNT:
 372                                 case VOICETYPE_TAUNT:
 373                                 {
 374                                         if (voicetype == VOICETYPE_AUTOTAUNT) if (!sv_autotaunt) { break; }else {}
 375                                         else if (IS_PLAYER(this) && !IS_DEAD(this)) animdecide_setaction(this, ANIMACTION_TAUNT,
 376                                                         true);
 377                                         if (!sv_taunt) break;
 378                                         if (autocvar_sv_gentle) break;
 379                                         float tauntrand = 0;
 380                                         if (voicetype == VOICETYPE_AUTOTAUNT) tauntrand = random();
 381                                         #define X() \
 382                                                 MACRO_BEGIN \
 383                                                 { \
 384                                                         if (voicetype != VOICETYPE_AUTOTAUNT || tauntrand < msg_entity.cvar_cl_autotaunt) \
 385                                                         { \
 386                                                                 float atten = (msg_entity.cvar_cl_voice_directional >= 1) \
 387                                                                     ? bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, \
 388                                                                         ATTEN_MAX) \
 389                                                                         : ATTEN_NONE; \
 390                                                                 if (gs) globalsound(MSG_ONE, this, gs, r, chan, VOL_BASEVOICE, atten); \
 391                                                                 else if (ps) playersound(MSG_ONE, this, ps, r, chan, VOL_BASEVOICE, atten); \
 392                                                                 else soundto(MSG_ONE, this, chan, sample, VOL_BASEVOICE, atten); \
 393                                                         } \
 394                                                 } MACRO_END
 395                                         if (fake)
 396                                         {
 397                                                 msg_entity = this;
 398                                                 X();
 399                                         }
 400                                         else
 401                                         {
 402                                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 403                                                         msg_entity = it;
 404                                                         X();
 405                                                 });
 406                                         }
 407                 #undef X
 408                                         break;
 409                                 }
 410                                 case VOICETYPE_PLAYERSOUND:
 411                                 {
 412                                         msg_entity = this;
 413                                         if (fake)
 414                                         {
 415                                                 if (gs) globalsound(MSG_ONE, this, gs, r, chan, VOL_BASE, ATTEN_NORM);
 416                                                 else if (ps) playersound(MSG_ONE, this, ps, r, chan, VOL_BASE, ATTEN_NORM);
 417                                                 else soundto(MSG_ONE, this, chan, sample, VOL_BASE, ATTEN_NORM);
 418                                         }
 419                                         else
 420                                         {
 421                                                 if (gs) globalsound(MSG_ALL, this, gs, r, chan, VOL_BASE, ATTEN_NORM);
 422                                                 else if (ps) playersound(MSG_ALL, this, ps, r, chan, VOL_BASE, ATTEN_NORM);
 423                                                 else _sound(this, chan, sample, VOL_BASE, ATTEN_NORM);
 424                                         }
 425                                         break;
 426                                 }
 427                                 default:
 428                                 {
 429                                         backtrace("Invalid voice type!");
 430                                         break;
 431                                 }
 432                         }
 433                 }
 434
 435         #endif
 436 #endif