qcsrc/common/ent_cs.qc

   1 #include "ent_cs.qh"
   2
   3 // #define PROP(public, fld, sv, cl)
   4 #define ENTCS_NETPROPS(PROP) \
   5         PROP(true, sv_entnum, \
   6         { WriteByte(chan, etof(player) - 1); }, \
   7         { this.sv_entnum = ReadByte(); }) \
   8     \
   9         PROP(false, origin, \
  10         { WriteShort(chan, this.origin.x);  WriteShort(chan, this.origin.y); \
  11           WriteShort(chan, this.origin.z); }, \
  12         { this.has_sv_origin = true; vector v; v.x = ReadShort(); v.y = ReadShort(); v.z = ReadShort(); setorigin(this, v); }) \
  13     \
  14         PROP(false, angles_y, \
  15         { WriteByte(chan, this.angles.y / 360 * 256); }, \
  16         { vector v = '0 0 0'; v.y = ReadByte() / 256 * 360; this.angles = v; }) \
  17     \
  18         PROP(false, health, \
  19         { WriteByte(chan, this.health / 10);  /* FIXME: use a better scale? */ }, \
  20         { this.healthvalue = ReadByte() * 10; }) \
  21     \
  22         PROP(false, armorvalue, \
  23         { WriteByte(chan, this.armorvalue / 10);  /* FIXME: use a better scale? */ }, \
  24         { this.armorvalue = ReadByte() * 10; }) \
  25     \
  26         PROP(true, netname, \
  27         { WriteString(chan, this.netname); }, \
  28         { if (this.netname) strunzone(this.netname); this.netname = strzone(ReadString()); }) \
  29     \
  30         PROP(true, model, \
  31         { WriteString(chan, this.model); }, \
  32         { if (this.model) strunzone(this.model); this.model = strzone(ReadString()); }) \
  33     \
  34         PROP(true, skin, \
  35         { WriteByte(chan, this.skin); }, \
  36         { this.skin = ReadByte(); }) \
  37     \
  38         /**/
  39
  40 #ifdef SVQC
  41
  42         int ENTCS_PUBLICMASK = 0;
  43         STATIC_INIT(ENTCS_PUBLICMASK)
  44         {
  45                 int i = 1;
  46                 #define X(public, fld, sv, cl) { if (public) ENTCS_PUBLICMASK |= BIT(i); } i += 1;
  47                 ENTCS_NETPROPS(X);
  48         #undef X
  49                 if (i >= BITS(16 - 1)) LOG_FATAL("Exceeded ENTCS_NETPROPS limit");
  50         }
  51
  52         bool _entcs_send(entity this, entity to, int sf, int chan)
  53         {
  54                 entity player = this.owner;
  55                 sf |= BIT(0) | BIT(1);
  56                 if (IS_PLAYER(to) || to.caplayer)                                  // unless spectating,
  57                 {
  58                         bool same_team = (to == player) || (teamplay && player.team == to.team);
  59                         if (!same_team && !radar_showennemies) sf &= ENTCS_PUBLICMASK; // no private updates
  60                 }
  61                 sf |= this.m_forceupdate;
  62                 this.m_forceupdate = 0;
  63                 bool valid =
  64                     IS_PLAYER(player)             // player must be active
  65                     || player == to               // player is self
  66                 ;
  67                 if (!valid) sf = 0;
  68                 if (chan == MSG_ENTITY)
  69                         WriteHeader(chan, ENT_CLIENT_ENTCS);
  70                 else
  71                         WriteHeader(chan, CLIENT_ENTCS);
  72                 WriteByte(chan, etof(player) - 1);
  73                 WriteShort(chan, sf);
  74                 int i = 1;
  75                 #define X(public, fld, sv, cl) { if (sf & BIT(i)) sv; } i += 1;
  76                 ENTCS_NETPROPS(X);
  77         #undef X
  78                 return true;
  79         }
  80
  81         bool entcs_send(entity this, entity to, int sf)
  82         {
  83                 return _entcs_send(this, to, sf, MSG_ENTITY);
  84         }
  85
  86         void entcs_think()
  87         {
  88                 SELFPARAM();
  89                 this.nextthink = time + 0.033333333333;  // TODO: increase this to like 0.15 once the client can do smoothing
  90                 entity o = this.owner;
  91                 int i = 1;
  92                 #define X(public, fld, sv, cl) \
  93                         if (o.fld != this.fld) \
  94                         { \
  95                                 this.fld = o.fld; \
  96                                 this.SendFlags |= BIT(i); \
  97                         } \
  98                         i += 1;
  99                 ENTCS_NETPROPS(X);
 100         #undef X
 101         }
 102
 103         void entcs_attach(entity player)
 104         {
 105                 entity e = player.entcs = new(entcs_sender);
 106                 make_pure(e);
 107                 e.owner = player;
 108                 e.think = entcs_think;
 109                 e.nextthink = time;
 110                 Net_LinkEntity(e, false, 0, entcs_send);
 111                 if (!IS_REAL_CLIENT(player)) return;
 112                 FOR_EACH_CLIENT(e)
 113                 {
 114                         assert(e.entcs);
 115                         _entcs_send(e.entcs, msg_entity = player, BITS(23), MSG_ONE);
 116                 }
 117         }
 118
 119         void entcs_detach(entity player)
 120         {
 121                 if (!player.entcs) return;
 122                 remove(player.entcs);
 123                 player.entcs = NULL;
 124         }
 125
 126 #endif
 127
 128 #ifdef CSQC
 129
 130         void Ent_RemoveEntCS()
 131         {
 132                 SELFPARAM();
 133                 int n = this.sv_entnum;
 134                 entity e = entcs_receiver(n);
 135                 entcs_receiver(n, NULL);
 136                 if (e != this) remove(e);
 137         }
 138
 139         void entcs_think()
 140         {
 141                 SELFPARAM();
 142                 entity e = CSQCModel_server2csqc(this.sv_entnum);
 143                 if (e == NULL)
 144                 {
 145                         this.has_origin = this.has_sv_origin;
 146                         return;
 147                 }
 148                 this.has_origin = true;
 149                 this.origin = e.origin;
 150                 // `cl_forceplayermodels 1` sounds will be wrong until the player has been in the PVS, but so be it
 151                 if (this.model != e.model)
 152                 {
 153                         if (this.model) strunzone(this.model);
 154                         this.model = strzone(e.model);
 155                 }
 156         }
 157
 158         bool ReadEntcs(entity this)
 159         {
 160                 int n = ReadByte();
 161                 entity e = entcs_receiver(n);
 162                 if (e == NULL)
 163                 {
 164                         if (this)
 165                         {
 166                                 e = this;
 167                         }
 168                         else
 169                         {
 170                                 e = new(entcs_receiver);
 171                                 make_pure(e);
 172                         }
 173                         e.sv_entnum = n;
 174                         e.think = entcs_think;
 175                         entcs_receiver(n, e);
 176                 }
 177                 else if (this && e != this)
 178                 {
 179                         this.classname = "entcs_gc";
 180                         this.sv_entnum = n;
 181                 }
 182                 this = e;
 183                 InterpolateOrigin_Undo(this);
 184                 this.sv_entnum = n;
 185                 int sf = ReadShort();
 186                 this.has_sv_origin = false;
 187                 this.m_entcs_private = boolean(sf & BIT(0));
 188                 int i = 1;
 189                 #define X(public, fld, sv, cl) { if (sf & BIT(i)) cl; } i += 1;
 190                 ENTCS_NETPROPS(X);
 191         #undef X
 192                 this.iflags |= IFLAG_ORIGIN;
 193                 InterpolateOrigin_Note(this);
 194                 WITH(entity, self, this, this.think());
 195                 return true;
 196         }
 197
 198         NET_HANDLE(ENT_CLIENT_ENTCS, bool isnew)
 199         {
 200                 if (isnew)
 201                 {
 202                         make_pure(this);
 203                         this.classname = "entcs_receiver";
 204                         this.entremove = Ent_RemoveEntCS;
 205                 }
 206                 return ReadEntcs(this);
 207         }
 208
 209         NET_HANDLE(CLIENT_ENTCS, bool isnew)
 210         {
 211                 return ReadEntcs(NULL);
 212         }
 213
 214 #endif