qcsrc/common/gamemodes/gamemode/cts/sv_cts.qc

   1 #include "sv_cts.qh"
   2
   3 #include <server/client.qh>
   4 #include <server/race.qh>
   5 #include <server/world.qh>
   6 #include <server/gamelog.qh>
   7 #include <server/intermission.qh>
   8 #include <server/items/spawning.qh>
   9 #include <server/weapons/common.qh>
  10 #include <common/mapobjects/triggers.qh>
  11
  12 float autocvar_g_cts_finish_kill_delay;
  13 bool autocvar_g_cts_selfdamage;
  14 bool autocvar_g_cts_removeprojectiles;
  15
  16 // legacy bot roles
  17 .float race_checkpoint;
  18 void havocbot_role_cts(entity this)
  19 {
  20         if(IS_DEAD(this))
  21                 return;
  22
  23         if (navigation_goalrating_timeout(this))
  24         {
  25                 navigation_goalrating_start(this);
  26
  27                 bool raw_touch_check = true;
  28                 int cp = this.race_checkpoint;
  29
  30                 LABEL(search_racecheckpoints)
  31                 IL_EACH(g_racecheckpoints, true,
  32                 {
  33                         if(it.cnt == cp || cp == -1)
  34                         {
  35                                 // redirect bot to next goal if it touched the waypoint of an untouchable checkpoint
  36                                 // e.g. checkpoint in front of Stormkeep's warpzone
  37                                 // the same workaround is applied in Race game mode
  38                                 if (raw_touch_check && vdist(this.origin - it.nearestwaypoint.origin, <, 30))
  39                                 {
  40                                         cp = race_NextCheckpoint(cp);
  41                                         raw_touch_check = false;
  42                                         goto search_racecheckpoints;
  43                                 }
  44                                 navigation_routerating(this, it, 1000000, 5000);
  45                         }
  46                 });
  47
  48                 navigation_goalrating_end(this);
  49
  50                 navigation_goalrating_timeout_set(this);
  51         }
  52 }
  53
  54 void cts_ScoreRules()
  55 {
  56     GameRules_score_enabled(false);
  57     GameRules_scoring(0, 0, 0, {
  58         if (g_race_qualifying) {
  59             field(SP_RACE_FASTEST, "fastest", SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  60         } else {
  61             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  62             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  63             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
  64         }
  65     });
  66 }
  67
  68 void cts_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  69 {
  70         if(autocvar_sv_eventlog)
  71                 GameLogEcho(strcat(":cts:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  72 }
  73
  74 MUTATOR_HOOKFUNCTION(cts, PlayerPreThink)
  75 {
  76         entity player = M_ARGV(0, entity);
  77
  78         if(!IS_PLAYER(player))
  79                 return;
  80
  81         // we need to perform this in PlayerPreThink as PlayerPhysics may not be called (vehicle support)
  82         float dt = frametime;
  83         player.race_movetime_frac += dt;
  84         float f = floor(player.race_movetime_frac);
  85         player.race_movetime_frac -= f;
  86         player.race_movetime_count += f;
  87         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
  88 }
  89
  90 MUTATOR_HOOKFUNCTION(cts, PlayerPhysics)
  91 {
  92         entity player = M_ARGV(0, entity);
  93         //float dt = M_ARGV(1, float);
  94
  95         if(IS_PLAYER(player))
  96         {
  97                 if (player.race_penalty)
  98                         if (time > player.race_penalty)
  99                                 player.race_penalty = 0;
 100                 if(player.race_penalty)
 101                 {
 102                         player.velocity = '0 0 0';
 103                         set_movetype(player, MOVETYPE_NONE);
 104                         player.disableclientprediction = 2;
 105                 }
 106         }
 107
 108         // force kbd movement for fairness
 109         float wishspeed;
 110         vector wishvel;
 111
 112         // if record times matter
 113         // ensure nothing EVIL is being done (i.e. div0_evade)
 114         // this hinders joystick users though
 115         // but it still gives SOME analog control
 116         wishvel.x = fabs(CS(player).movement.x);
 117         wishvel.y = fabs(CS(player).movement.y);
 118         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 119         {
 120                 wishvel.z = 0;
 121                 wishspeed = vlen(wishvel);
 122                 if(wishvel.x >= 2 * wishvel.y)
 123                 {
 124                         // pure X motion
 125                         if(CS(player).movement.x > 0)
 126                                 CS(player).movement_x = wishspeed;
 127                         else
 128                                 CS(player).movement_x = -wishspeed;
 129                         CS(player).movement_y = 0;
 130                 }
 131                 else if(wishvel.y >= 2 * wishvel.x)
 132                 {
 133                         // pure Y motion
 134                         CS(player).movement_x = 0;
 135                         if(CS(player).movement.y > 0)
 136                                 CS(player).movement_y = wishspeed;
 137                         else
 138                                 CS(player).movement_y = -wishspeed;
 139                 }
 140                 else
 141                 {
 142                         // diagonal
 143                         if(CS(player).movement.x > 0)
 144                                 CS(player).movement_x = M_SQRT1_2 * wishspeed;
 145                         else
 146                                 CS(player).movement_x = -M_SQRT1_2 * wishspeed;
 147                         if(CS(player).movement.y > 0)
 148                                 CS(player).movement_y = M_SQRT1_2 * wishspeed;
 149                         else
 150                                 CS(player).movement_y = -M_SQRT1_2 * wishspeed;
 151                 }
 152         }
 153 }
 154
 155 MUTATOR_HOOKFUNCTION(cts, reset_map_global)
 156 {
 157         float s;
 158
 159         Score_NicePrint(NULL);
 160
 161         race_ClearRecords();
 162         PlayerScore_Sort(race_place, 0, true, false);
 163
 164         FOREACH_CLIENT(true, {
 165                 if(it.race_place)
 166                 {
 167                         s = GameRules_scoring_add(it, RACE_FASTEST, 0);
 168                         if(!s)
 169                                 it.race_place = 0;
 170                 }
 171                 cts_EventLog(ftos(it.race_place), it);
 172         });
 173
 174         if(g_race_qualifying == 2)
 175         {
 176                 g_race_qualifying = 0;
 177                 independent_players = 0;
 178                 cvar_set("fraglimit", ftos(race_fraglimit));
 179                 cvar_set("leadlimit", ftos(race_leadlimit));
 180                 cvar_set("timelimit", ftos(race_timelimit));
 181                 cts_ScoreRules();
 182         }
 183 }
 184
 185 MUTATOR_HOOKFUNCTION(cts, ClientConnect)
 186 {
 187         entity player = M_ARGV(0, entity);
 188
 189         race_PreparePlayer(player);
 190         player.race_checkpoint = -1;
 191
 192         if(IS_REAL_CLIENT(player))
 193         {
 194                 string rr = CTS_RECORD;
 195
 196                 msg_entity = player;
 197                 race_send_recordtime(MSG_ONE);
 198                 race_send_speedaward(MSG_ONE);
 199
 200                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 201                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 202                 race_send_speedaward_alltimebest(MSG_ONE);
 203
 204                 float i;
 205                 int m = min(RANKINGS_CNT, autocvar_g_cts_send_rankings_cnt);
 206                 race_send_rankings_cnt(MSG_ONE);
 207                 for (i = 1; i <= m; ++i)
 208                 {
 209                         race_SendRankings(i, 0, 0, MSG_ONE);
 210                 }
 211         }
 212 }
 213
 214 MUTATOR_HOOKFUNCTION(cts, AbortSpeedrun)
 215 {
 216         entity player = M_ARGV(0, entity);
 217
 218         if(autocvar_g_allow_checkpoints)
 219                 race_PreparePlayer(player); // nice try
 220 }
 221
 222 MUTATOR_HOOKFUNCTION(cts, MakePlayerObserver)
 223 {
 224         entity player = M_ARGV(0, entity);
 225
 226         if(GameRules_scoring_add(player, RACE_FASTEST, 0))
 227                 player.frags = FRAGS_PLAYER_OUT_OF_GAME;
 228         else
 229                 player.frags = FRAGS_SPECTATOR;
 230
 231         race_PreparePlayer(player);
 232         player.race_checkpoint = -1;
 233 }
 234
 235 MUTATOR_HOOKFUNCTION(cts, PlayerSpawn)
 236 {
 237         entity player = M_ARGV(0, entity);
 238         entity spawn_spot = M_ARGV(1, entity);
 239
 240         if(spawn_spot.target == "")
 241                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 242                 race_PreparePlayer(player);
 243
 244         // if we need to respawn, do it right
 245         player.race_respawn_checkpoint = player.race_checkpoint;
 246         player.race_respawn_spotref = spawn_spot;
 247
 248         player.race_place = 0;
 249 }
 250
 251 MUTATOR_HOOKFUNCTION(cts, PutClientInServer)
 252 {
 253         entity player = M_ARGV(0, entity);
 254
 255         if(IS_PLAYER(player))
 256         if(!game_stopped)
 257         {
 258                 if(CS(player).killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 259                         race_PreparePlayer(player);
 260                 else // respawn
 261                         race_RetractPlayer(player);
 262
 263                 race_AbandonRaceCheck(player);
 264         }
 265 }
 266
 267 MUTATOR_HOOKFUNCTION(cts, PlayerDies)
 268 {
 269         entity frag_target = M_ARGV(2, entity);
 270
 271         frag_target.respawn_flags |= RESPAWN_FORCE;
 272         race_AbandonRaceCheck(frag_target);
 273
 274         if(autocvar_g_cts_removeprojectiles)
 275         {
 276                 IL_EACH(g_projectiles, it.owner == frag_target && (it.flags & FL_PROJECTILE),
 277                 {
 278                         delete(it);
 279                 });
 280         }
 281 }
 282
 283 MUTATOR_HOOKFUNCTION(cts, HavocBot_ChooseRole)
 284 {
 285         entity bot = M_ARGV(0, entity);
 286
 287         bot.havocbot_role = havocbot_role_cts;
 288         return true;
 289 }
 290
 291 MUTATOR_HOOKFUNCTION(cts, GetPressedKeys)
 292 {
 293         entity player = M_ARGV(0, entity);
 294
 295         if(CS_CVAR(player).cvar_cl_allow_uidtracking == 1 && CS_CVAR(player).cvar_cl_allow_uid2name == 1)
 296         {
 297                 if (!player.stored_netname)
 298                         player.stored_netname = strzone(uid2name(player.crypto_idfp));
 299                 if(player.stored_netname != player.netname)
 300                 {
 301                         db_put(ServerProgsDB, strcat("/uid2name/", player.crypto_idfp), player.netname);
 302                         strcpy(player.stored_netname, player.netname);
 303                 }
 304         }
 305
 306         if (!IS_OBSERVER(player))
 307         {
 308                 if(vdist(player.velocity - player.velocity_z * '0 0 1', >, speedaward_speed))
 309                 {
 310                         speedaward_speed = vlen(player.velocity - player.velocity_z * '0 0 1');
 311                         speedaward_holder = player.netname;
 312                         speedaward_uid = player.crypto_idfp;
 313                         speedaward_lastupdate = time;
 314                 }
 315                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
 316                 {
 317                         string rr = CTS_RECORD;
 318                         race_send_speedaward(MSG_ALL);
 319                         speedaward_lastsent = speedaward_speed;
 320                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
 321                         {
 322                                 speedaward_alltimebest = speedaward_speed;
 323                                 speedaward_alltimebest_holder = speedaward_holder;
 324                                 speedaward_alltimebest_uid = speedaward_uid;
 325                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
 326                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
 327                                 race_send_speedaward_alltimebest(MSG_ALL);
 328                         }
 329                 }
 330         }
 331 }
 332
 333 MUTATOR_HOOKFUNCTION(cts, ForbidThrowCurrentWeapon)
 334 {
 335         // no weapon dropping in CTS
 336         return true;
 337 }
 338
 339 MUTATOR_HOOKFUNCTION(cts, FilterItem)
 340 {
 341         entity item = M_ARGV(0, entity);
 342
 343         if (Item_IsLoot(item))
 344         {
 345                 return true;
 346         }
 347 }
 348
 349 MUTATOR_HOOKFUNCTION(cts, Damage_Calculate)
 350 {
 351         entity frag_attacker = M_ARGV(1, entity);
 352         entity frag_target = M_ARGV(2, entity);
 353         float frag_deathtype = M_ARGV(3, float);
 354         float frag_damage = M_ARGV(4, float);
 355
 356         if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL.m_id)
 357         if(!autocvar_g_cts_selfdamage)
 358         {
 359                 frag_damage = 0;
 360                 M_ARGV(4, float) = frag_damage;
 361         }
 362 }
 363
 364 MUTATOR_HOOKFUNCTION(cts, ForbidPlayerScore_Clear)
 365 {
 366         return true; // in CTS, you don't lose score by observing
 367 }
 368
 369 MUTATOR_HOOKFUNCTION(cts, GetRecords)
 370 {
 371         int record_page = M_ARGV(0, int);
 372         string ret_string = M_ARGV(1, string);
 373
 374         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 375         {
 376                 if(MapInfo_Get_ByID(i))
 377                 {
 378                         float r = race_readTime(MapInfo_Map_bspname, 1);
 379
 380                         if(!r)
 381                                 continue;
 382
 383                         string h = race_readName(MapInfo_Map_bspname, 1);
 384                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 385                 }
 386         }
 387
 388         M_ARGV(1, string) = ret_string;
 389 }
 390
 391 MUTATOR_HOOKFUNCTION(cts, ClientKill)
 392 {
 393         M_ARGV(1, float) = 0; // kill delay
 394 }
 395
 396 MUTATOR_HOOKFUNCTION(cts, Race_FinalCheckpoint)
 397 {
 398         entity player = M_ARGV(0, entity);
 399
 400         // useful to prevent cheating by running back to the start line and starting out with more speed
 401         if(autocvar_g_cts_finish_kill_delay)
 402                 ClientKill_Silent(player, autocvar_g_cts_finish_kill_delay);
 403 }
 404
 405 MUTATOR_HOOKFUNCTION(cts, HideTeamNagger)
 406 {
 407         return true; // doesn't work so well (but isn't cts a teamless mode?)
 408 }
 409
 410 MUTATOR_HOOKFUNCTION(cts, FixClientCvars)
 411 {
 412         entity player = M_ARGV(0, entity);
 413
 414         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 415 }
 416
 417 MUTATOR_HOOKFUNCTION(cts, WantWeapon)
 418 {
 419         M_ARGV(1, float) = (M_ARGV(0, entity) == WEP_SHOTGUN); // want weapon = weapon info
 420         M_ARGV(3, bool) = true; // want mutator blocked
 421         return true;
 422 }
 423
 424 MUTATOR_HOOKFUNCTION(cts, ForbidDropCurrentWeapon)
 425 {
 426         return true;
 427 }
 428
 429 void cts_Initialize()
 430 {
 431         cts_ScoreRules();
 432 }