Merge branch 'master' into terencehill/ft_autorevive_progress
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / gamemodes / gamemode / freezetag / sv_freezetag.qc
1 #include "sv_freezetag.qh"
2
3 #include <server/resources.qh>
4
5 float autocvar_g_freezetag_frozen_maxtime;
6 float autocvar_g_freezetag_revive_clearspeed;
7 float autocvar_g_freezetag_round_timelimit;
8 //int autocvar_g_freezetag_teams;
9 int autocvar_g_freezetag_teams_override;
10 float autocvar_g_freezetag_warmup;
11
12 void freezetag_count_alive_players()
13 {
14         total_players = 0;
15         for (int i = 1; i <= NUM_TEAMS; ++i)
16         {
17                 Team_SetNumberOfAlivePlayers(Team_GetTeamFromIndex(i), 0);
18         }
19         FOREACH_CLIENT(IS_PLAYER(it) && Entity_HasValidTeam(it),
20         {
21                 ++total_players;
22                 if (GetResource(it, RES_HEALTH) < 1 || STAT(FROZEN, it) == FROZEN_NORMAL)
23                 {
24                         continue;
25                 }
26                 entity team_ = Entity_GetTeam(it);
27                 int num_alive = Team_GetNumberOfAlivePlayers(team_);
28                 ++num_alive;
29                 Team_SetNumberOfAlivePlayers(team_, num_alive);
30         });
31         FOREACH_CLIENT(IS_REAL_CLIENT(it),
32         {
33                 STAT(REDALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(
34                         1));
35                 STAT(BLUEALIVE, it) = Team_GetNumberOfAlivePlayers(
36                         Team_GetTeamFromIndex(2));
37                 STAT(YELLOWALIVE, it) = Team_GetNumberOfAlivePlayers(
38                         Team_GetTeamFromIndex(3));
39                 STAT(PINKALIVE, it) = Team_GetNumberOfAlivePlayers(
40                         Team_GetTeamFromIndex(4));
41         });
42
43         eliminatedPlayers.SendFlags |= 1;
44 }
45
46 bool freezetag_CheckTeams()
47 {
48         static float prev_missing_teams_mask;
49         if (Team_GetNumberOfAliveTeams() == NumTeams(freezetag_teams))
50         {
51                 if(prev_missing_teams_mask > 0)
52                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
53                 prev_missing_teams_mask = -1;
54                 return true;
55         }
56         if(total_players == 0)
57         {
58                 if(prev_missing_teams_mask > 0)
59                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
60                 prev_missing_teams_mask = -1;
61                 return false;
62         }
63         int missing_teams_mask = 0;
64         for (int i = 1; i <= NUM_TEAMS; ++i)
65         {
66                 if ((freezetag_teams & Team_IndexToBit(i)) &&
67                         (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) == 0))
68                 {
69                         missing_teams_mask |= Team_IndexToBit(i);
70                 }
71         }
72         if(prev_missing_teams_mask != missing_teams_mask)
73         {
74                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
75                 prev_missing_teams_mask = missing_teams_mask;
76         }
77         return false;
78 }
79
80 int freezetag_getWinnerTeam()
81 {
82         int winner_team = 0;
83         if (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(1)) >= 1)
84         {
85                 winner_team = NUM_TEAM_1;
86         }
87         for (int i = 2; i <= NUM_TEAMS; ++i)
88         {
89                 if (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) >= 1)
90                 {
91                         if (winner_team != 0)
92                         {
93                                 return 0;
94                         }
95                         winner_team = Team_IndexToTeam(i);
96                 }
97         }
98         if (winner_team)
99         {
100                 return winner_team;
101         }
102         return -1; // no player left
103 }
104
105 void nades_Clear(entity);
106 void nades_GiveBonus(entity player, float score);
107
108 bool freezetag_CheckWinner()
109 {
110         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
111         {
112                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
113                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
114                 FOREACH_CLIENT(IS_PLAYER(it), {
115                         it.freezetag_frozen_timeout = 0;
116                         nades_Clear(it);
117                 });
118                 game_stopped = true;
119                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
120                 return true;
121         }
122
123         if (Team_GetNumberOfAliveTeams() > 1)
124         {
125                 return false;
126         }
127
128         int winner_team = freezetag_getWinnerTeam();
129         if(winner_team > 0)
130         {
131                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
132                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
133                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
134         }
135         else if(winner_team == -1)
136         {
137                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
138                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
139         }
140
141         FOREACH_CLIENT(IS_PLAYER(it), {
142                 it.freezetag_frozen_timeout = 0;
143                 nades_Clear(it);
144         });
145
146         game_stopped = true;
147         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
148         return true;
149 }
150
151 entity freezetag_LastPlayerForTeam(entity this)
152 {
153         entity last_pl = NULL;
154         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
155                 if (STAT(FROZEN, it) != FROZEN_NORMAL && GetResource(it, RES_HEALTH) >= 1)
156                 {
157                         if (!last_pl)
158                                 last_pl = it;
159                         else
160                                 return NULL;
161                 }
162         });
163         return last_pl;
164 }
165
166 void freezetag_LastPlayerForTeam_Notify(entity this)
167 {
168         if(round_handler_IsActive())
169         if(round_handler_IsRoundStarted())
170         {
171                 entity pl = freezetag_LastPlayerForTeam(this);
172                 if(pl)
173                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
174         }
175 }
176
177 void freezetag_Add_Score(entity targ, entity attacker)
178 {
179         if(attacker == targ)
180         {
181                 // you froze your own dumb targ
182                 // counted as "suicide" already
183                 GameRules_scoring_add(targ, SCORE, -1);
184         }
185         else if(IS_PLAYER(attacker))
186         {
187                 // got frozen by an enemy
188                 // counted as "kill" and "death" already
189                 GameRules_scoring_add(targ, SCORE, -1);
190                 GameRules_scoring_add(attacker, SCORE, +1);
191         }
192         // else nothing - got frozen by the game type rules themselves
193 }
194
195 // to be called when the player is frozen by freezetag (on death, spectator join etc), gives the score
196 void freezetag_Freeze(entity targ, entity attacker)
197 {
198         if(STAT(FROZEN, targ))
199                 return;
200
201         targ.freezetag_frozen_time = time;
202         if (autocvar_g_freezetag_revive_auto && autocvar_g_freezetag_frozen_maxtime > 0)
203                 targ.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
204
205         Freeze(targ, 0, FROZEN_NORMAL, true);
206
207         freezetag_count_alive_players();
208
209         freezetag_Add_Score(targ, attacker);
210 }
211
212 bool freezetag_isEliminated(entity e)
213 {
214         if(IS_PLAYER(e) && (STAT(FROZEN, e) == FROZEN_NORMAL || IS_DEAD(e)))
215                 return true;
216         return false;
217 }
218
219
220 // ================
221 // Bot player logic
222 // ================
223
224 void(entity this) havocbot_role_ft_freeing;
225 void(entity this) havocbot_role_ft_offense;
226
227 void havocbot_goalrating_ft_freeplayers(entity this, float ratingscale, vector org, float sradius)
228 {
229         entity best_pl = NULL;
230         float best_dist2 = FLOAT_MAX;
231         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
232                 if (STAT(FROZEN, it) == FROZEN_NORMAL)
233                 {
234                         if(vdist(it.origin - org, >, sradius))
235                                 continue;
236                         navigation_routerating(this, it, ratingscale, 2000);
237                 }
238                 else if (best_dist2
239                         && GetResource(it, RES_HEALTH) < GetResource(this, RES_HEALTH) + 30
240                         && vlen2(it.origin - org) < best_dist2)
241                 {
242                         // If teamate is not frozen still seek them out as fight better
243                         // in a group.
244                         best_dist2 = vlen2(it.origin - org);
245                         if (best_dist2 < 700 ** 2)
246                         {
247                                 best_pl = NULL;
248                                 best_dist2 = 0; // already close to a teammate
249                         }
250                         else
251                                 best_pl = it;
252                 }
253         });
254         if (best_pl)
255                 navigation_routerating(this, best_pl, ratingscale / 2, 2000);
256 }
257
258 void havocbot_role_ft_offense(entity this)
259 {
260         if(IS_DEAD(this))
261                 return;
262
263         if (!this.havocbot_role_timeout)
264                 this.havocbot_role_timeout = time + random() * 10 + 20;
265
266         // Count how many players on team are unfrozen.
267         int unfrozen = 0;
268         FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, this) && STAT(FROZEN, it) != FROZEN_NORMAL, {
269                 unfrozen++;
270         });
271
272         // If only one left on team or if role has timed out then start trying to free players.
273         if ((!unfrozen && STAT(FROZEN, this) != FROZEN_NORMAL) || time > this.havocbot_role_timeout)
274         {
275                 LOG_TRACE("changing role to freeing");
276                 this.havocbot_role = havocbot_role_ft_freeing;
277                 this.havocbot_role_timeout = 0;
278                 return;
279         }
280
281         if (navigation_goalrating_timeout(this))
282         {
283                 navigation_goalrating_start(this);
284                 havocbot_goalrating_items(this, 12000, this.origin, 10000);
285                 havocbot_goalrating_enemyplayers(this, 10000, this.origin, 10000);
286                 havocbot_goalrating_ft_freeplayers(this, 9000, this.origin, 10000);
287                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
288                 navigation_goalrating_end(this);
289
290                 navigation_goalrating_timeout_set(this);
291         }
292 }
293
294 void havocbot_role_ft_freeing(entity this)
295 {
296         if(IS_DEAD(this))
297                 return;
298
299         if (!this.havocbot_role_timeout)
300                 this.havocbot_role_timeout = time + random() * 10 + 20;
301
302         if (time > this.havocbot_role_timeout)
303         {
304                 LOG_TRACE("changing role to offense");
305                 this.havocbot_role = havocbot_role_ft_offense;
306                 this.havocbot_role_timeout = 0;
307                 return;
308         }
309
310         if (navigation_goalrating_timeout(this))
311         {
312                 navigation_goalrating_start(this);
313                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
314                 havocbot_goalrating_enemyplayers(this, 5000, this.origin, 10000);
315                 havocbot_goalrating_ft_freeplayers(this, 20000, this.origin, 10000);
316                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
317                 navigation_goalrating_end(this);
318
319                 navigation_goalrating_timeout_set(this);
320         }
321 }
322
323
324 // ==============
325 // Hook Functions
326 // ==============
327
328 void ft_RemovePlayer(entity this)
329 {
330         if (STAT(FROZEN, this) != FROZEN_NORMAL)
331                 freezetag_LastPlayerForTeam_Notify(this);
332         Unfreeze(this, false);
333
334         SetResourceExplicit(this, RES_HEALTH, 0); // neccessary to correctly count alive players
335         freezetag_count_alive_players();
336 }
337
338 MUTATOR_HOOKFUNCTION(ft, ClientDisconnect)
339 {
340         entity player = M_ARGV(0, entity);
341
342         ft_RemovePlayer(player);
343         return true;
344 }
345
346 MUTATOR_HOOKFUNCTION(ft, MakePlayerObserver)
347 {
348         entity player = M_ARGV(0, entity);
349
350         ft_RemovePlayer(player);
351 }
352
353 MUTATOR_HOOKFUNCTION(ft, PlayerDies)
354 {
355         entity frag_attacker = M_ARGV(1, entity);
356         entity frag_target = M_ARGV(2, entity);
357         float frag_deathtype = M_ARGV(3, float);
358
359         if(round_handler_IsActive())
360         if(round_handler_CountdownRunning())
361         {
362                 if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
363                         Unfreeze(frag_target, true);
364                 freezetag_count_alive_players();
365                 frag_target.respawn_time = time;
366                 frag_target.respawn_flags |= RESPAWN_FORCE;
367                 return true;
368         }
369
370         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
371         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
372         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
373                 || frag_deathtype == DEATH_TEAMCHANGE.m_id || frag_deathtype == DEATH_AUTOTEAMCHANGE.m_id)
374         {
375                 // let the player die, he will be automatically frozen when he respawns
376                 if (STAT(FROZEN, frag_target) != FROZEN_NORMAL)
377                 {
378                         freezetag_Add_Score(frag_target, frag_attacker);
379                         freezetag_count_alive_players();
380                         freezetag_LastPlayerForTeam_Notify(frag_target);
381                 }
382                 else
383                         Unfreeze(frag_target, false); // remove ice
384                 frag_target.freezetag_frozen_timeout = -2; // freeze on respawn
385                 return true;
386         }
387
388         if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
389                 return true;
390
391         freezetag_Freeze(frag_target, frag_attacker);
392         freezetag_LastPlayerForTeam_Notify(frag_target);
393
394         if(frag_attacker == frag_target || frag_attacker == NULL)
395         {
396                 if(IS_PLAYER(frag_target))
397                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
398                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
399         }
400         else
401         {
402                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
403         }
404
405         return true;
406 }
407
408 MUTATOR_HOOKFUNCTION(ft, PlayerSpawn)
409 {
410         entity player = M_ARGV(0, entity);
411
412         if(player.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
413                 return true; // do nothing, round is starting right now
414
415         if(player.freezetag_frozen_timeout == -2) // player was dead
416         {
417                 freezetag_Freeze(player, NULL);
418                 return true;
419         }
420
421         freezetag_count_alive_players();
422
423         if(round_handler_IsActive())
424         if(round_handler_IsRoundStarted())
425         {
426                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
427                 freezetag_Freeze(player, NULL);
428         }
429
430         return true;
431 }
432
433 MUTATOR_HOOKFUNCTION(ft, reset_map_players)
434 {
435         FOREACH_CLIENT(IS_PLAYER(it), {
436                 CS(it).killcount = 0;
437                 it.freezetag_frozen_timeout = -1;
438                 PutClientInServer(it);
439                 it.freezetag_frozen_timeout = 0;
440         });
441         freezetag_count_alive_players();
442         return true;
443 }
444
445 MUTATOR_HOOKFUNCTION(ft, GiveFragsForKill, CBC_ORDER_FIRST)
446 {
447         M_ARGV(2, float) = 0; // no frags counted in Freeze Tag
448         return true;
449 }
450
451 MUTATOR_HOOKFUNCTION(ft, Unfreeze)
452 {
453         entity targ = M_ARGV(0, entity);
454         targ.freezetag_frozen_time = 0;
455         targ.freezetag_frozen_timeout = 0;
456 }
457
458 MUTATOR_HOOKFUNCTION(ft, Damage_Calculate)
459 {
460         entity frag_attacker = M_ARGV(1, entity);
461         entity frag_target = M_ARGV(2, entity);
462         //float frag_deathtype = M_ARGV(3, float);
463         //float frag_damage = M_ARGV(4, float);
464         vector frag_force = M_ARGV(6, vector);
465
466         if (STAT(FROZEN, frag_target) == FROZEN_NORMAL && autocvar_g_freezetag_revive_auto_reducible
467                 && autocvar_g_freezetag_frozen_maxtime > 0 && autocvar_g_freezetag_revive_auto)
468         {
469                 float t = 0;
470                 if ((autocvar_g_freezetag_revive_auto_reducible > 0 || DIFF_TEAM(frag_attacker, frag_target))
471                         && frag_target.freezetag_frozen_timeout > time)
472                 {
473                         if (fabs(autocvar_g_freezetag_revive_auto_reducible) == 1)
474                                 t = vlen(frag_force) * autocvar_g_freezetag_revive_auto_reducible_forcefactor;
475                         frag_target.freezetag_frozen_timeout -= t;
476                         if (frag_target.freezetag_frozen_timeout < time)
477                                 frag_target.freezetag_frozen_timeout = time;
478                 }
479         }
480 }
481
482 #ifdef IS_REVIVING
483         #undef IS_REVIVING
484 #endif
485
486 // returns true if player is reviving it
487 #define IS_REVIVING(player, it, revive_extra_size) \
488         (it != player && !STAT(FROZEN, it) && !IS_DEAD(it) && SAME_TEAM(it, player) \
489         && boxesoverlap(player.absmin - revive_extra_size, player.absmax + revive_extra_size, it.absmin, it.absmax))
490
491 MUTATOR_HOOKFUNCTION(ft, PlayerPreThink, CBC_ORDER_FIRST)
492 {
493         if(game_stopped)
494                 return true;
495
496         if(round_handler_IsActive())
497         if(!round_handler_IsRoundStarted())
498                 return true;
499
500         int n;
501         entity player = M_ARGV(0, entity);
502         //if (STAT(FROZEN, player) == FROZEN_NORMAL)
503         //if(player.freezetag_frozen_timeout > 0 && time < player.freezetag_frozen_timeout)
504                 //player.iceblock.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (player.freezetag_frozen_timeout - time) / (player.freezetag_frozen_timeout - player.freezetag_frozen_time);
505
506         entity reviving_players_last = NULL;
507         entity reviving_players_first = NULL;
508
509         if(player.freezetag_frozen_timeout > 0 && time >= player.freezetag_frozen_timeout)
510                 n = -1;
511         else
512         {
513                 n = 0;
514                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
515                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REVIVING(player, it, revive_extra_size), {
516                         if (reviving_players_last)
517                                 reviving_players_last.chain = it;
518                         reviving_players_last = it;
519                         if (!reviving_players_first)
520                                 reviving_players_first = it;
521                         ++n;
522                 });
523                 if (reviving_players_last)
524                         reviving_players_last.chain = NULL;
525         }
526
527         float base_progress = 0;
528         if  (STAT(FROZEN, player) == FROZEN_NORMAL && autocvar_g_freezetag_revive_auto
529                 && autocvar_g_freezetag_frozen_maxtime > 0 && autocvar_g_freezetag_revive_auto_progress)
530         {
531                 base_progress = bound(0, (1 - (player.freezetag_frozen_timeout - time) / autocvar_g_freezetag_frozen_maxtime), 1);
532         }
533
534         if (!n) // no teammate nearby
535         {
536                 if (STAT(FROZEN, player) == FROZEN_NORMAL)
537                 {
538                         STAT(REVIVE_PROGRESS, player) = bound(base_progress, STAT(REVIVE_PROGRESS, player) - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
539                         SetResourceExplicit(player, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, player) * ((warmup_stage) ? warmup_start_health : start_health)));
540                 }
541                 else if (!STAT(FROZEN, player))
542                         STAT(REVIVE_PROGRESS, player) = base_progress; // thawing nobody
543         }
544         else if (STAT(FROZEN, player) == FROZEN_NORMAL) // OK, there is at least one teammate reviving us
545         {
546                 STAT(REVIVE_PROGRESS, player) = bound(base_progress, STAT(REVIVE_PROGRESS, player) + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
547                 SetResourceExplicit(player, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, player) * ((warmup_stage) ? warmup_start_health : start_health)));
548
549                 if(STAT(REVIVE_PROGRESS, player) >= 1)
550                 {
551                         float frozen_time = time - player.freezetag_frozen_time;
552                         Unfreeze(player, false);
553                         freezetag_count_alive_players();
554
555                         if(n == -1)
556                         {
557                                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_AUTO_REVIVED, frozen_time);
558                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_AUTO_REVIVED, player.netname, frozen_time);
559                                 return true;
560                         }
561
562                         // EVERY team mate nearby gets a point (even if multiple!)
563                         for(entity it = reviving_players_first; it; it = it.chain)
564                         {
565                                 GameRules_scoring_add(it, FREEZETAG_REVIVALS, +1);
566                                 GameRules_scoring_add(it, SCORE, +1);
567                                 nades_GiveBonus(it, autocvar_g_nades_bonus_score_low);
568                         }
569
570                         entity first = reviving_players_first;
571                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_REVIVED, first.netname);
572                         Send_Notification(NOTIF_ONE, first, MSG_CENTER, CENTER_FREEZETAG_REVIVE, player.netname);
573                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_REVIVED, player.netname, first.netname);
574                 }
575
576                 for(entity it = reviving_players_first; it; it = it.chain)
577                         STAT(REVIVE_PROGRESS, it) = STAT(REVIVE_PROGRESS, player);
578         }
579
580         return true;
581 }
582
583 MUTATOR_HOOKFUNCTION(ft, SetStartItems)
584 {
585         start_items &= ~(IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS);
586         //start_health       = warmup_start_health       = cvar("g_lms_start_health");
587         //start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
588         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
589         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
590         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
591         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
592         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
593         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
594 }
595
596 MUTATOR_HOOKFUNCTION(ft, HavocBot_ChooseRole)
597 {
598         entity bot = M_ARGV(0, entity);
599
600         if (!IS_DEAD(bot))
601         {
602                 if (random() < 0.5)
603                         bot.havocbot_role = havocbot_role_ft_freeing;
604                 else
605                         bot.havocbot_role = havocbot_role_ft_offense;
606         }
607
608         // if bots spawn all at once assign them a more appropriated role after a while
609         if (time < CS(bot).jointime + 1)
610                 bot.havocbot_role_timeout = time + 10 + random() * 10;
611
612         return true;
613 }
614
615 MUTATOR_HOOKFUNCTION(ft, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
616 {
617         M_ARGV(0, float) = freezetag_teams;
618         return true;
619 }
620
621 MUTATOR_HOOKFUNCTION(ft, SetWeaponArena)
622 {
623         if(M_ARGV(0, string) == "0" || M_ARGV(0, string) == "")
624                 M_ARGV(0, string) = autocvar_g_freezetag_weaponarena;
625 }
626
627 MUTATOR_HOOKFUNCTION(ft, FragCenterMessage)
628 {
629         entity frag_attacker = M_ARGV(0, entity);
630         entity frag_target = M_ARGV(1, entity);
631         //float frag_deathtype = M_ARGV(2, float);
632         int kill_count_to_attacker = M_ARGV(3, int);
633         int kill_count_to_target = M_ARGV(4, int);
634
635         if(STAT(FROZEN, frag_target) == FROZEN_NORMAL)
636                 return; // target was already frozen, so this is just pushing them off the cliff
637
638         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CHOICE, CHOICE_FRAG_FREEZE, frag_target.netname, kill_count_to_attacker, (IS_BOT_CLIENT(frag_target) ? -1 : CS(frag_target).ping));
639         Send_Notification(NOTIF_ONE, frag_target, MSG_CHOICE, CHOICE_FRAGGED_FREEZE, frag_attacker.netname, kill_count_to_target,
640                 GetResource(frag_attacker, RES_HEALTH), GetResource(frag_attacker, RES_ARMOR), (IS_BOT_CLIENT(frag_attacker) ? -1 : CS(frag_attacker).ping));
641
642         return true;
643 }
644
645 MUTATOR_HOOKFUNCTION(ft, SV_ParseServerCommand)
646 {
647         string cmd_name = M_ARGV(0, string);
648         if (cmd_name == "shuffleteams")
649                 shuffleteams_on_reset_map = !(round_handler_IsActive() && !round_handler_IsRoundStarted());
650         return false;
651 }
652
653 void freezetag_Initialize()
654 {
655         freezetag_teams = autocvar_g_freezetag_teams_override;
656         if(freezetag_teams < 2)
657                 freezetag_teams = cvar("g_freezetag_teams"); // read the cvar directly as it gets written earlier in the same frame
658
659         freezetag_teams = BITS(bound(2, freezetag_teams, 4));
660         GameRules_scoring(freezetag_teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, {
661                 field(SP_FREEZETAG_REVIVALS, "revivals", 0);
662         });
663
664         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
665         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
666
667         EliminatedPlayers_Init(freezetag_isEliminated);
668 }