qcsrc/common/gamemodes/gamemode/invasion/sv_invasion.qc

   1 #include "sv_invasion.qh"
   2
   3 #include <common/mapobjects/triggers.qh>
   4 #include <common/monsters/sv_spawn.qh>
   5 #include <common/monsters/sv_spawner.qh>
   6 #include <common/monsters/sv_monsters.qh>
   7 #include <common/mutators/mutator/status_effects/_mod.qh>
   8
   9 #include <server/bot/api.qh>
  10 #include <server/world.qh>
  11 #include <server/teamplay.qh>
  12
  13 float autocvar_g_invasion_round_timelimit;
  14 float autocvar_g_invasion_spawnpoint_spawn_delay;
  15 float autocvar_g_invasion_warmup;
  16 int autocvar_g_invasion_monster_count;
  17 bool autocvar_g_invasion_zombies_only;
  18 float autocvar_g_invasion_spawn_delay;
  19
  20 bool victent_present;
  21 .bool inv_endreached;
  22
  23 bool inv_warning_shown; // spammy
  24
  25 void target_invasion_roundend_use(entity this, entity actor, entity trigger)
  26 {
  27         if(!IS_PLAYER(actor)) { return; }
  28
  29         actor.inv_endreached = true;
  30
  31         int plnum = 0;
  32         int realplnum = 0;
  33         // let's not count bots
  34         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
  35                 ++realplnum;
  36                 if(it.inv_endreached)
  37                         ++plnum;
  38         });
  39         if(plnum < ceil(realplnum * min(1, this.count))) // 70% of players
  40                 return;
  41
  42         this.winning = true;
  43 }
  44
  45 spawnfunc(target_invasion_roundend)
  46 {
  47         if(!g_invasion) { delete(this); return; }
  48
  49         victent_present = true; // a victory entity is present, we don't need to rely on monster count TODO: merge this with the intrusive list (can check empty)
  50
  51         if(!this.count) { this.count = 0.7; } // require at least 70% of the players to reach the end before triggering victory
  52
  53         this.use = target_invasion_roundend_use;
  54
  55         IL_PUSH(g_invasion_roundends, this);
  56 }
  57
  58 spawnfunc(invasion_wave)
  59 {
  60         if(!g_invasion) { delete(this); return; }
  61
  62         IL_PUSH(g_invasion_waves, this);
  63 }
  64
  65 spawnfunc(invasion_spawnpoint)
  66 {
  67         if(!g_invasion) { delete(this); return; }
  68
  69         IL_PUSH(g_invasion_spawns, this);
  70 }
  71
  72 void ClearWinners();
  73
  74 // Invasion stage mode winning condition: If the attackers triggered a round end (by fulfilling all objectives)
  75 // they win.
  76 int WinningCondition_Invasion()
  77 {
  78         WinningConditionHelper(NULL); // set worldstatus
  79
  80         int status = WINNING_NO;
  81
  82         if(autocvar_g_invasion_type == INV_TYPE_STAGE)
  83         {
  84                 SetWinners(inv_endreached, true);
  85
  86                 int found = 0;
  87                 IL_EACH(g_invasion_roundends, true,
  88                 {
  89                         ++found;
  90                         if(it.winning)
  91                         {
  92                                 bprint("Invasion: round completed.\n");
  93                                 // winners already set (TODO: teamplay support)
  94
  95                                 status = WINNING_YES;
  96                                 break;
  97                         }
  98                 });
  99
 100                 if(!found)
 101                         status = WINNING_YES; // just end it? TODO: should warn mapper!
 102         }
 103         else if(autocvar_g_invasion_type == INV_TYPE_HUNT)
 104         {
 105                 ClearWinners();
 106
 107                 int found = 0; // NOTE: this ends the round if no monsters are placed
 108                 IL_EACH(g_monsters, !(it.spawnflags & MONSTERFLAG_RESPAWNED),
 109                 {
 110                         ++found;
 111                 });
 112
 113                 if(found <= 0)
 114                 {
 115                         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
 116                         {
 117                                 it.winning = true;
 118                         });
 119                         status = WINNING_YES;
 120                 }
 121         }
 122
 123         return status;
 124 }
 125
 126 Monster invasion_PickMonster(int supermonster_count)
 127 {
 128         RandomSelection_Init();
 129
 130         FOREACH(Monsters, it != MON_Null,
 131         {
 132                 if((it.spawnflags & MON_FLAG_HIDDEN) || (it.spawnflags & MONSTER_TYPE_PASSIVE) || (it.spawnflags & MONSTER_TYPE_FLY) || (it.spawnflags & MONSTER_TYPE_SWIM) ||
 133                         (it.spawnflags & MONSTER_SIZE_QUAKE) || ((it.spawnflags & MON_FLAG_SUPERMONSTER) && supermonster_count >= 1))
 134                         continue;
 135                 if(autocvar_g_invasion_zombies_only && !(it.spawnflags & MONSTER_TYPE_UNDEAD))
 136                         continue;
 137         RandomSelection_AddEnt(it, 1, 1);
 138         });
 139
 140         return RandomSelection_chosen_ent;
 141 }
 142
 143 entity invasion_PickSpawn()
 144 {
 145         RandomSelection_Init();
 146
 147         IL_EACH(g_invasion_spawns, true,
 148         {
 149                 RandomSelection_AddEnt(it, 1, ((time < it.spawnshieldtime) ? 0.2 : 1)); // give recently used spawnpoints a very low rating
 150                 it.spawnshieldtime = time + autocvar_g_invasion_spawnpoint_spawn_delay;
 151         });
 152
 153         return RandomSelection_chosen_ent;
 154 }
 155
 156 entity invasion_GetWaveEntity(int wavenum)
 157 {
 158         IL_EACH(g_invasion_waves, it.cnt == wavenum,
 159         {
 160                 return it; // found one
 161         });
 162
 163         // if no specific one is found, find the last existing wave ent
 164         entity best = NULL;
 165         IL_EACH(g_invasion_waves, it.cnt <= wavenum,
 166         {
 167                 if(!best || it.cnt > best.cnt)
 168                         best = it;
 169         });
 170
 171         return best;
 172 }
 173
 174 void invasion_SpawnChosenMonster(Monster mon)
 175 {
 176         entity monster;
 177         entity spawn_point = invasion_PickSpawn();
 178         entity wave_ent = invasion_GetWaveEntity(inv_roundcnt);
 179
 180         string tospawn = "";
 181         if(wave_ent && wave_ent.spawnmob && wave_ent.spawnmob != "")
 182         {
 183                 RandomSelection_Init();
 184                 FOREACH_WORD(wave_ent.spawnmob, true,
 185                 {
 186                         RandomSelection_AddString(it, 1, 1);
 187                 });
 188
 189                 tospawn = RandomSelection_chosen_string;
 190         }
 191
 192         if(spawn_point == NULL)
 193         {
 194                 if(!inv_warning_shown)
 195                 {
 196                         inv_warning_shown = true;
 197                         LOG_TRACE("Warning: couldn't find any invasion_spawnpoint spawnpoints, attempting to spawn monsters in random locations");
 198                 }
 199                 entity e = spawn();
 200                 setsize(e, mon.m_mins, mon.m_maxs);
 201
 202                 if(MoveToRandomMapLocation(e, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
 203                         monster = spawnmonster(e, tospawn, mon, NULL, NULL, e.origin, false, false, 2);
 204                 else
 205                 {
 206                         delete(e);
 207                         return;
 208                 }
 209         }
 210         else // if spawnmob field falls through (unset), fallback to mon (relying on spawnmonster for that behaviour)
 211                 monster = spawnmonster(spawn(), ((spawn_point.spawnmob && spawn_point.spawnmob != "") ? spawn_point.spawnmob : tospawn), mon, spawn_point, spawn_point, spawn_point.origin, false, false, 2);
 212
 213         if(!monster)
 214                 return;
 215
 216         StatusEffects_remove(STATUSEFFECT_SpawnShield, monster, STATUSEFFECT_REMOVE_NORMAL);
 217
 218         if(spawn_point)
 219         {
 220                 if(spawn_point.target_range)
 221                         monster.target_range = spawn_point.target_range;
 222                 monster.target2 = spawn_point.target2;
 223         }
 224
 225         if(teamplay)
 226         {
 227                 if(spawn_point && spawn_point.team && inv_monsters_perteam[spawn_point.team] > 0)
 228                         monster.team = spawn_point.team;
 229                 else
 230                 {
 231                         RandomSelection_Init();
 232                         if(inv_monsters_perteam[NUM_TEAM_1] > 0) RandomSelection_AddFloat(NUM_TEAM_1, 1, 1);
 233                         if(inv_monsters_perteam[NUM_TEAM_2] > 0) RandomSelection_AddFloat(NUM_TEAM_2, 1, 1);
 234                         if(invasion_teams >= 3) if(inv_monsters_perteam[NUM_TEAM_3] > 0) { RandomSelection_AddFloat(NUM_TEAM_3, 1, 1); }
 235                         if(invasion_teams >= 4) if(inv_monsters_perteam[NUM_TEAM_4] > 0) { RandomSelection_AddFloat(NUM_TEAM_4, 1, 1); }
 236
 237                         monster.team = RandomSelection_chosen_float;
 238                 }
 239
 240                 monster_setupcolors(monster);
 241
 242                 if(monster.sprite)
 243                 {
 244                         WaypointSprite_UpdateTeamRadar(monster.sprite, RADARICON_DANGER, ((monster.team) ? Team_ColorRGB(monster.team) : '1 0 0'));
 245
 246                         monster.sprite.team = 0;
 247                         monster.sprite.SendFlags |= 1;
 248                 }
 249         }
 250
 251         if(monster.monster_attack)
 252                 IL_REMOVE(g_monster_targets, monster);
 253         monster.monster_attack = false; // it's the player's job to kill all the monsters
 254
 255         if(inv_roundcnt >= inv_maxrounds)
 256                 monster.spawnflags |= MONSTERFLAG_MINIBOSS; // last round spawns minibosses
 257 }
 258
 259 void invasion_SpawnMonsters(int supermonster_count)
 260 {
 261         Monster chosen_monster = invasion_PickMonster(supermonster_count);
 262
 263         invasion_SpawnChosenMonster(chosen_monster);
 264 }
 265
 266 bool Invasion_CheckWinner()
 267 {
 268         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 269         {
 270                 IL_EACH(g_monsters, true,
 271                 {
 272                         Monster_Remove(it);
 273                 });
 274                 IL_CLEAR(g_monsters);
 275
 276                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
 277                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
 278                 round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 279                 return 1;
 280         }
 281
 282         float total_alive_monsters = 0, supermonster_count = 0, red_alive = 0, blue_alive = 0, yellow_alive = 0, pink_alive = 0;
 283
 284         IL_EACH(g_monsters, GetResource(it, RES_HEALTH) > 0,
 285         {
 286                 if(it.monsterdef.spawnflags & MON_FLAG_SUPERMONSTER)
 287                         ++supermonster_count;
 288                 ++total_alive_monsters;
 289
 290                 if(teamplay)
 291                 switch(it.team)
 292                 {
 293                         case NUM_TEAM_1: ++red_alive; break;
 294                         case NUM_TEAM_2: ++blue_alive; break;
 295                         case NUM_TEAM_3: ++yellow_alive; break;
 296                         case NUM_TEAM_4: ++pink_alive; break;
 297                 }
 298         });
 299
 300         if((total_alive_monsters + inv_numkilled) < inv_maxspawned && inv_maxcurrent < inv_maxspawned)
 301         {
 302                 if(time >= inv_lastcheck)
 303                 {
 304                         invasion_SpawnMonsters(supermonster_count);
 305                         inv_lastcheck = time + autocvar_g_invasion_spawn_delay;
 306                 }
 307
 308                 return 0;
 309         }
 310
 311         if(inv_numspawned < 1)
 312                 return 0; // nothing has spawned yet
 313
 314         if(teamplay)
 315         {
 316                 if(((red_alive > 0) + (blue_alive > 0) + (yellow_alive > 0) + (pink_alive > 0)) > 1)
 317                         return 0;
 318         }
 319         else if(inv_numkilled < inv_maxspawned)
 320                 return 0;
 321
 322         entity winner = NULL;
 323         float winning_score = 0, winner_team = 0;
 324
 325
 326         if(teamplay)
 327         {
 328                 if(red_alive > 0) { winner_team = NUM_TEAM_1; }
 329                 if(blue_alive > 0)
 330                 {
 331                         if(winner_team) { winner_team = 0; }
 332                         else { winner_team = NUM_TEAM_2; }
 333                 }
 334                 if(yellow_alive > 0)
 335                 {
 336                         if(winner_team) { winner_team = 0; }
 337                         else { winner_team = NUM_TEAM_3; }
 338                 }
 339                 if(pink_alive > 0)
 340                 {
 341                         if(winner_team) { winner_team = 0; }
 342                         else { winner_team = NUM_TEAM_4; }
 343                 }
 344         }
 345         else
 346         {
 347                 FOREACH_CLIENT(IS_PLAYER(it), {
 348                         float cs = GameRules_scoring_add(it, KILLS, 0);
 349                         if(cs > winning_score)
 350                         {
 351                                 winning_score = cs;
 352                                 winner = it;
 353                         }
 354                 });
 355         }
 356
 357         IL_EACH(g_monsters, true,
 358         {
 359                 Monster_Remove(it);
 360         });
 361         IL_CLEAR(g_monsters);
 362
 363         if(teamplay)
 364         {
 365                 if(winner_team)
 366                 {
 367                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 368                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 369                 }
 370         }
 371         else if(winner)
 372         {
 373                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_PLAYER_WIN, winner.netname);
 374                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_PLAYER_WIN, winner.netname);
 375         }
 376
 377         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 378
 379         return 1;
 380 }
 381
 382 bool Invasion_CheckPlayers()
 383 {
 384         return true;
 385 }
 386
 387 void Invasion_RoundStart()
 388 {
 389         int numplayers = 0;
 390         FOREACH_CLIENT(IS_PLAYER(it), {
 391                 it.player_blocked = false;
 392                 ++numplayers;
 393         });
 394
 395         if(inv_roundcnt < inv_maxrounds)
 396                 inv_roundcnt += 1; // a limiter to stop crazy counts
 397
 398         inv_monsterskill = inv_roundcnt + max(1, numplayers * 0.3);
 399
 400         inv_maxcurrent = 0;
 401         inv_numspawned = 0;
 402         inv_numkilled = 0;
 403
 404         inv_maxspawned = rint(max(autocvar_g_invasion_monster_count, autocvar_g_invasion_monster_count * (inv_roundcnt * 0.5)));
 405
 406         if(teamplay)
 407         {
 408                 DistributeEvenly_Init(inv_maxspawned, invasion_teams);
 409                 inv_monsters_perteam[NUM_TEAM_1] = DistributeEvenly_Get(1);
 410                 inv_monsters_perteam[NUM_TEAM_2] = DistributeEvenly_Get(1);
 411                 if(invasion_teams >= 3) inv_monsters_perteam[NUM_TEAM_3] = DistributeEvenly_Get(1);
 412                 if(invasion_teams >= 4) inv_monsters_perteam[NUM_TEAM_4] = DistributeEvenly_Get(1);
 413         }
 414 }
 415
 416 MUTATOR_HOOKFUNCTION(inv, MonsterDies)
 417 {
 418         entity frag_target = M_ARGV(0, entity);
 419         entity frag_attacker = M_ARGV(1, entity);
 420
 421         if(!(frag_target.spawnflags & MONSTERFLAG_RESPAWNED))
 422         {
 423                 if(autocvar_g_invasion_type == INV_TYPE_ROUND)
 424                 {
 425                         inv_numkilled += 1;
 426                         inv_maxcurrent -= 1;
 427                 }
 428                 if(teamplay) { inv_monsters_perteam[frag_target.team] -= 1; }
 429
 430                 if(IS_PLAYER(frag_attacker))
 431                 {
 432                         if(SAME_TEAM(frag_attacker, frag_target)) // in non-teamplay modes, same team = same player, so this works
 433                                 GameRules_scoring_add(frag_attacker, KILLS, -1);
 434                         else
 435                         {
 436                                 GameRules_scoring_add(frag_attacker, KILLS, +1);
 437                                 if(teamplay)
 438                                         TeamScore_AddToTeam(frag_attacker.team, ST_INV_KILLS, +1);
 439                         }
 440                 }
 441         }
 442 }
 443
 444 MUTATOR_HOOKFUNCTION(inv, MonsterSpawn)
 445 {
 446         entity mon = M_ARGV(0, entity);
 447         mon.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
 448
 449         if(autocvar_g_invasion_type == INV_TYPE_HUNT)
 450                 return false; // allowed
 451
 452         if(!(mon.spawnflags & MONSTERFLAG_SPAWNED))
 453                 return true;
 454
 455         if(!(mon.spawnflags & MONSTERFLAG_RESPAWNED))
 456         {
 457                 inv_numspawned += 1;
 458                 inv_maxcurrent += 1;
 459         }
 460
 461         mon.monster_skill = inv_monsterskill;
 462
 463         if(mon.monsterdef.spawnflags & MON_FLAG_SUPERMONSTER)
 464                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_INVASION_SUPERMONSTER, mon.monster_name);
 465 }
 466
 467 MUTATOR_HOOKFUNCTION(inv, SV_StartFrame)
 468 {
 469         if(autocvar_g_invasion_type != INV_TYPE_ROUND)
 470                 return; // uses map spawned monsters
 471
 472         monsters_total = inv_maxspawned; // TODO: make sure numspawned never exceeds maxspawned
 473         monsters_killed = inv_numkilled;
 474 }
 475
 476 MUTATOR_HOOKFUNCTION(inv, PlayerRegen)
 477 {
 478         // no regeneration in invasion, regardless of the game type
 479         return true;
 480 }
 481
 482 MUTATOR_HOOKFUNCTION(inv, PlayerSpawn)
 483 {
 484         entity player = M_ARGV(0, entity);
 485
 486         if(player.bot_attack)
 487                 IL_REMOVE(g_bot_targets, player);
 488         player.bot_attack = false;
 489 }
 490
 491 MUTATOR_HOOKFUNCTION(inv, Damage_Calculate)
 492 {
 493         entity frag_attacker = M_ARGV(1, entity);
 494         entity frag_target = M_ARGV(2, entity);
 495         float frag_damage = M_ARGV(4, float);
 496         vector frag_force = M_ARGV(6, vector);
 497
 498         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target) && frag_attacker != frag_target)
 499         {
 500                 frag_damage = 0;
 501                 frag_force = '0 0 0';
 502
 503                 M_ARGV(4, float) = frag_damage;
 504                 M_ARGV(6, vector) = frag_force;
 505         }
 506 }
 507
 508 MUTATOR_HOOKFUNCTION(inv, BotShouldAttack)
 509 {
 510         entity targ = M_ARGV(1, entity);
 511
 512         if(!IS_MONSTER(targ))
 513                 return true;
 514 }
 515
 516 MUTATOR_HOOKFUNCTION(inv, SetStartItems)
 517 {
 518         if(autocvar_g_invasion_type == INV_TYPE_ROUND)
 519         {
 520                 start_health = 200;
 521                 start_armorvalue = 200;
 522         }
 523 }
 524
 525 MUTATOR_HOOKFUNCTION(inv, AccuracyTargetValid)
 526 {
 527         entity frag_target = M_ARGV(1, entity);
 528
 529         if(IS_MONSTER(frag_target))
 530                 return MUT_ACCADD_INVALID;
 531         return MUT_ACCADD_INDIFFERENT;
 532 }
 533
 534 MUTATOR_HOOKFUNCTION(inv, AllowMobSpawning)
 535 {
 536         // monster spawning disabled during an invasion
 537         M_ARGV(1, string) = "You cannot spawn monsters during an invasion!";
 538         return true;
 539 }
 540
 541 MUTATOR_HOOKFUNCTION(inv, CheckRules_World)
 542 {
 543         if(autocvar_g_invasion_type == INV_TYPE_ROUND)
 544                 return false;
 545
 546         M_ARGV(0, float) = WinningCondition_Invasion();
 547         return true;
 548 }
 549
 550 MUTATOR_HOOKFUNCTION(inv, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 551 {
 552         M_ARGV(0, float) = invasion_teams;
 553         return true;
 554 }
 555
 556 MUTATOR_HOOKFUNCTION(inv, AllowMobButcher)
 557 {
 558         M_ARGV(0, string) = "This command does not work during an invasion!";
 559         return true;
 560 }
 561
 562 void invasion_ScoreRules(int inv_teams)
 563 {
 564         GameRules_score_enabled(false);
 565         GameRules_scoring(inv_teams, 0, 0, {
 566             if (inv_teams) {
 567             field_team(ST_INV_KILLS, "frags", SFL_SORT_PRIO_PRIMARY);
 568             }
 569             field(SP_KILLS, "frags", ((inv_teams) ? SFL_SORT_PRIO_SECONDARY : SFL_SORT_PRIO_PRIMARY));
 570         });
 571 }
 572
 573 void invasion_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up.
 574 {
 575         if(autocvar_g_invasion_type == INV_TYPE_HUNT || autocvar_g_invasion_type == INV_TYPE_STAGE)
 576                 cvar_set("fraglimit", "0");
 577
 578         if(autocvar_g_invasion_teams)
 579         {
 580                 invasion_teams = BITS(bound(2, autocvar_g_invasion_teams, 4));
 581         }
 582         else
 583                 invasion_teams = 0;
 584
 585         independent_players = 1; // to disable extra useless scores
 586
 587         invasion_ScoreRules(invasion_teams);
 588
 589         independent_players = 0;
 590
 591         if(autocvar_g_invasion_type == INV_TYPE_ROUND)
 592         {
 593                 round_handler_Spawn(Invasion_CheckPlayers, Invasion_CheckWinner, Invasion_RoundStart);
 594                 round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 595
 596                 inv_roundcnt = 0;
 597                 inv_maxrounds = 15; // 15?
 598         }
 599 }
 600
 601 void invasion_Initialize()
 602 {
 603         InitializeEntity(NULL, invasion_DelayedInit, INITPRIO_GAMETYPE);
 604 }