qcsrc/common/gamemodes/gamemode/keyhunt/sv_keyhunt.qc

   1 #include "sv_keyhunt.qh"
   2
   3 #include <server/command/vote.qh>
   4 #include <server/gamelog.qh>
   5 #include <server/damage.qh>
   6 #include <server/items/items.qh>
   7 #include <common/mapobjects/triggers.qh>
   8
   9 float autocvar_g_balance_keyhunt_damageforcescale;
  10 float autocvar_g_balance_keyhunt_delay_collect;
  11 float autocvar_g_balance_keyhunt_delay_damage_return;
  12 float autocvar_g_balance_keyhunt_delay_return;
  13 float autocvar_g_balance_keyhunt_delay_round;
  14 float autocvar_g_balance_keyhunt_delay_tracking;
  15 float autocvar_g_balance_keyhunt_return_when_unreachable;
  16 float autocvar_g_balance_keyhunt_dropvelocity;
  17 float autocvar_g_balance_keyhunt_maxdist;
  18 float autocvar_g_balance_keyhunt_protecttime;
  19
  20 int autocvar_g_balance_keyhunt_score_capture;
  21 int autocvar_g_balance_keyhunt_score_carrierfrag;
  22 int autocvar_g_balance_keyhunt_score_collect;
  23 int autocvar_g_balance_keyhunt_score_destroyed;
  24 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  25 int autocvar_g_balance_keyhunt_score_push;
  26 float autocvar_g_balance_keyhunt_throwvelocity;
  27
  28 //int autocvar_g_keyhunt_teams;
  29 int autocvar_g_keyhunt_teams_override;
  30
  31 // #define KH_PLAYER_USE_ATTACHMENT
  32 // TODO? no model exists for this
  33 // #define KH_PLAYER_USE_CARRIEDMODEL
  34
  35 #ifdef KH_PLAYER_USE_ATTACHMENT
  36 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  37 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  38 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  39 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  40 const string KH_PLAYER_ATTACHMENT_BONE = "";
  41 #else
  42 const float KH_KEY_ZSHIFT = 22;
  43 const float KH_KEY_XYDIST = 24;
  44 const float KH_KEY_XYSPEED = 45;
  45 #endif
  46 const float KH_KEY_WP_ZSHIFT = 20;
  47
  48 const vector KH_KEY_MIN = '-25 -25 -46'; // 0.8.6 used '-10 -10 -46' with sv_legacy_bbox_expand 1 and FL_ITEM
  49 const vector KH_KEY_MAX = '25 25 4';     // 0.8.6 used '10 10 3'     with sv_legacy_bbox_expand 1 and FL_ITEM
  50 const float KH_KEY_BRIGHTNESS = 2;
  51
  52 bool kh_no_radar_circles;
  53
  54 // kh_state
  55 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  56 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  57 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  58 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  59 .float siren_time;  //  time delay the siren
  60 //.float stuff_time;  //  time delay to stuffcmd a cvar
  61
  62 int kh_Team_ByID(int t)
  63 {
  64         if(t == 0) return NUM_TEAM_1;
  65         if(t == 1) return NUM_TEAM_2;
  66         if(t == 2) return NUM_TEAM_3;
  67         if(t == 3) return NUM_TEAM_4;
  68         return 0;
  69 }
  70
  71 entity kh_controller;
  72 //bool kh_tracking_enabled;
  73 int kh_teams;
  74 int kh_interferemsg_team;
  75 float kh_interferemsg_time;
  76 .entity kh_next, kh_prev; // linked list
  77 .float kh_droptime;
  78 .int kh_dropperteam;
  79 .entity kh_previous_owner;
  80 .int kh_previous_owner_playerid;
  81
  82 int kh_key_dropped, kh_key_carried;
  83
  84 int kh_Key_AllOwnedByWhichTeam();
  85
  86 const int ST_KH_CAPS = 1;
  87 void kh_ScoreRules(int teams)
  88 {
  89         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, {
  90         field_team(ST_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  91         field(SP_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  92         field(SP_KH_PUSHES, "pushes", 0);
  93         field(SP_KH_DESTRUCTIONS, "destructions", SFL_LOWER_IS_BETTER);
  94         field(SP_KH_PICKUPS, "pickups", 0);
  95         field(SP_KH_KCKILLS, "kckills", 0);
  96         field(SP_KH_LOSSES, "losses", SFL_LOWER_IS_BETTER);
  97         });
  98 }
  99
 100 bool kh_KeyCarrier_waypointsprite_visible_for_player(entity this, entity player, entity view)  // runs all the time
 101 {
 102         if(!IS_PLAYER(view) || DIFF_TEAM(this, view))
 103                 if(!kh_tracking_enabled)
 104                         return false;
 105
 106         return true;
 107 }
 108
 109 bool kh_Key_waypointsprite_visible_for_player(entity this, entity player, entity view)
 110 {
 111         if(!kh_tracking_enabled)
 112                 return false;
 113         if(!this.owner)
 114                 return true;
 115         if(!this.owner.owner)
 116                 return true;
 117         return false;  // draw only when key is not owned
 118 }
 119
 120 void kh_update_state()
 121 {
 122         entity key;
 123         int f;
 124         int s = 0;
 125         FOR_EACH_KH_KEY(key)
 126         {
 127                 if(key.owner)
 128                         f = key.team;
 129                 else
 130                         f = 30;
 131                 s |= (32 ** key.count) * f;
 132         }
 133
 134         FOREACH_CLIENT(true, { STAT(OBJECTIVE_STATUS, it) = s; });
 135
 136         FOR_EACH_KH_KEY(key)
 137         {
 138                 if(key.owner)
 139                         STAT(OBJECTIVE_STATUS, key.owner) |= (32 ** key.count) * 31;
 140         }
 141         //print(ftos((nextent(NULL)).kh_state), "\n");
 142 }
 143
 144
 145
 146
 147 var kh_Think_t kh_Controller_Thinkfunc;
 148 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 149 {
 150         kh_Controller_Thinkfunc = func;
 151         kh_controller.cnt = ceil(t);
 152         if(t == 0)
 153                 kh_controller.nextthink = time; // force
 154 }
 155 void kh_WaitForPlayers();
 156 void kh_Controller_Think(entity this)  // called a lot
 157 {
 158         if(game_stopped)
 159                 return;
 160         if(this.cnt > 0)
 161         {
 162                 if(getthink(this) != kh_WaitForPlayers)
 163                         this.cnt -= 1;
 164         }
 165         else if(this.cnt == 0)
 166         {
 167                 this.cnt -= 1;
 168                 kh_Controller_Thinkfunc();
 169         }
 170         this.nextthink = time + 1;
 171 }
 172
 173 // frags f: take from cvar * f
 174 // frags 0: no frags
 175 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 176 {
 177         string s;
 178         if(game_stopped)
 179                 return;
 180
 181         if(frags_player)
 182                 UpdateFrags(player, frags_player);
 183
 184         if(key && key.owner && frags_owner)
 185                 UpdateFrags(key.owner, frags_owner);
 186
 187         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 188                 return;
 189
 190         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 191
 192         if(key && key.owner)
 193                 s = strcat(s, ":", ftos(key.owner.playerid));
 194         else
 195                 s = strcat(s, ":0");
 196
 197         s = strcat(s, ":", ftos(frags_owner), ":");
 198
 199         if(key)
 200                 s = strcat(s, key.netname);
 201
 202         GameLogEcho(s);
 203 }
 204
 205 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 206 {
 207         if(e.tag_entity)
 208         {
 209                 makevectors(e.tag_entity.angles);
 210                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 211         }
 212         else
 213                 return e.origin;
 214 }
 215
 216 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 217 {
 218         key.solid = SOLID_NOT; // before setorigin to prevent area grid linking
 219 #ifdef KH_PLAYER_USE_ATTACHMENT
 220         entity first = key.owner.kh_next;
 221         if(key == first)
 222         {
 223                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 224                 if(key.kh_next)
 225                 {
 226                         setattachment(key.kh_next, key, "");
 227                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 228                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 229                         key.kh_next.angles = '0 0 0';
 230                 }
 231                 else
 232                         setorigin(key, KH_PLAYER_ATTACHMENT);
 233                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 234         }
 235         else
 236         {
 237                 setattachment(key, key.kh_prev, "");
 238                 if(key.kh_next)
 239                         setattachment(key.kh_next, key, "");
 240                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 241                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 242                 key.angles = '0 0 0';
 243         }
 244 #else
 245         setattachment(key, key.owner, "");
 246         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 247         key.angles_y -= key.owner.angles.y;
 248 #endif
 249         key.flags = 0;
 250         if(IL_CONTAINS(g_items, key))
 251                 IL_REMOVE(g_items, key);
 252         set_movetype(key, MOVETYPE_NONE);
 253         key.team = key.owner.team;
 254         key.nextthink = time;
 255         key.damageforcescale = 0;
 256         key.takedamage = DAMAGE_NO;
 257         key.modelindex = kh_key_carried;
 258         navigation_dynamicgoal_unset(key);
 259 }
 260
 261 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 262 {
 263         key.solid = SOLID_TRIGGER; // before setorigin to ensure area grid linking
 264 #ifdef KH_PLAYER_USE_ATTACHMENT
 265         entity first = key.owner.kh_next;
 266         if(key == first)
 267         {
 268                 if(key.kh_next)
 269                 {
 270                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 271                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 272                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 273                 }
 274         }
 275         else
 276         {
 277                 if(key.kh_next)
 278                         setattachment(key.kh_next, key.kh_prev, "");
 279                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 280         }
 281         // in any case:
 282         setattachment(key, NULL, "");
 283         setorigin(key, key.owner.origin + '0 0 1' * (STAT(PL_MIN, key.owner).z - KH_KEY_MIN_z));
 284         key.angles = key.owner.angles;
 285 #else
 286         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 287         setattachment(key, NULL, "");
 288         key.angles_y += key.owner.angles.y;
 289 #endif
 290         key.flags = FL_ITEM;
 291         if(!IL_CONTAINS(g_items, key))
 292                 IL_PUSH(g_items, key);
 293         set_movetype(key, MOVETYPE_TOSS);
 294         nudgeoutofsolid(key); // a key has a bigger bbox than a player
 295         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 296         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 297         key.takedamage = DAMAGE_YES;
 298         // let key.team stay
 299         key.modelindex = kh_key_dropped;
 300         navigation_dynamicgoal_set(key, key.owner);
 301         key.kh_previous_owner = key.owner;
 302         key.kh_previous_owner_playerid = key.owner.playerid;
 303 }
 304
 305 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 306 {
 307         if(key.owner == player)
 308                 return;
 309
 310         int ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 311
 312         if(key.owner)
 313         {
 314                 kh_Key_Detach(key);
 315
 316                 // remove from linked list
 317                 if(key.kh_next)
 318                         key.kh_next.kh_prev = key.kh_prev;
 319                 key.kh_prev.kh_next = key.kh_next;
 320                 key.kh_next = NULL;
 321                 key.kh_prev = NULL;
 322
 323                 if(key.owner.kh_next == NULL)
 324                 {
 325                         // No longer a key carrier
 326                         if(!kh_no_radar_circles)
 327                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 328                         WaypointSprite_DetachCarrier(key.owner);
 329                 }
 330         }
 331
 332         key.owner = player;
 333
 334         if(player)
 335         {
 336                 // insert into linked list
 337                 key.kh_next = player.kh_next;
 338                 key.kh_prev = player;
 339                 player.kh_next = key;
 340                 if(key.kh_next)
 341                         key.kh_next.kh_prev = key;
 342
 343                 kh_Key_Attach(key);
 344
 345                 if(key.kh_next == NULL)
 346                 {
 347                         // player is now a key carrier
 348                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 349                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 350                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 351                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 352                         if(player.team == NUM_TEAM_1)
 353                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 354                         else if(player.team == NUM_TEAM_2)
 355                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 356                         else if(player.team == NUM_TEAM_3)
 357                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 358                         else if(player.team == NUM_TEAM_4)
 359                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 360                         if(!kh_no_radar_circles)
 361                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 362                 }
 363         }
 364
 365         // moved that here, also update if there's no player
 366         kh_update_state();
 367
 368         key.pusher = NULL;
 369
 370         int ownerteam = kh_Key_AllOwnedByWhichTeam();
 371         if(ownerteam != ownerteam0)
 372         {
 373                 entity k;
 374                 if(ownerteam != -1)
 375                 {
 376                         kh_interferemsg_time = time + 0.2;
 377                         kh_interferemsg_team = player.team;
 378
 379                         // audit all key carrier sprites, update them to "Run here"
 380                         FOR_EACH_KH_KEY(k)
 381                         {
 382                                 if (!k.owner) continue;
 383                                 entity first = WP_Null;
 384                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 385                                 entity third = WP_Null;
 386                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 387                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 388                         }
 389                 }
 390                 else
 391                 {
 392                         kh_interferemsg_time = 0;
 393
 394                         // audit all key carrier sprites, update them to "Key Carrier"
 395                         FOR_EACH_KH_KEY(k)
 396                         {
 397                                 if (!k.owner) continue;
 398                                 entity first = WP_Null;
 399                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 400                                 entity third = WP_Null;
 401                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 402                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 403                         }
 404                 }
 405         }
 406 }
 407
 408 void kh_Key_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 409 {
 410         if(this.owner)
 411                 return;
 412         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 413         {
 414                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 415                 return;
 416         }
 417         if(force == '0 0 0')
 418                 return;
 419         if(time > this.pushltime)
 420                 if(IS_PLAYER(attacker))
 421                         this.team = attacker.team;
 422 }
 423
 424 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 425 {
 426         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 427
 428         if(key.kh_dropperteam != player.team)
 429         {
 430                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 431                 GameRules_scoring_add(player, KH_PICKUPS, 1);
 432         }
 433         key.kh_dropperteam = 0;
 434         int realteam = kh_Team_ByID(key.count);
 435         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PICKUP), player.netname);
 436
 437         kh_Key_AssignTo(key, player); // this also updates .kh_state
 438 }
 439
 440 void kh_Key_Touch(entity this, entity toucher)  // runs many, many times when a key has been dropped and can be picked up
 441 {
 442         if(game_stopped)
 443                 return;
 444
 445         if(this.owner) // already carried
 446                 return;
 447
 448         if(ITEM_TOUCH_NEEDKILL())
 449         {
 450                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 451                 return;
 452         }
 453
 454         if (!IS_PLAYER(toucher))
 455                 return;
 456         if(IS_DEAD(toucher))
 457                 return;
 458         if(toucher == this.enemy)
 459                 if(time < this.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 460                         return;  // you just dropped it!
 461         kh_Key_Collect(this, toucher);
 462 }
 463
 464 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 465 {
 466         entity o = key.owner;
 467         kh_Key_AssignTo(key, NULL);
 468         if(o) // it was attached
 469                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 470         else // it was dropped
 471                 WaypointSprite_DetachCarrier(key);
 472
 473         // remove key from key list
 474         if (kh_worldkeylist == key)
 475                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 476         else
 477         {
 478                 o = kh_worldkeylist;
 479                 while (o)
 480                 {
 481                         if (o.kh_worldkeynext == key)
 482                         {
 483                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 484                                 break;
 485                         }
 486                         o = o.kh_worldkeynext;
 487                 }
 488         }
 489
 490         delete(key);
 491
 492         kh_update_state();
 493 }
 494
 495 void kh_FinishRound()  // runs when a team captures the keys
 496 {
 497         // prepare next round
 498         kh_interferemsg_time = 0;
 499         entity key;
 500
 501         kh_no_radar_circles = true;
 502         FOR_EACH_KH_KEY(key)
 503                 kh_Key_Remove(key);
 504         kh_no_radar_circles = false;
 505
 506         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 507         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 508 }
 509
 510 void nades_GiveBonus(entity player, float score);
 511
 512 void kh_WinnerTeam(int winner_team)  // runs when a team wins
 513 {
 514         // all key carriers get some points
 515         entity key;
 516         float score = (NumTeams(kh_teams) - 1) * autocvar_g_balance_keyhunt_score_capture;
 517         DistributeEvenly_Init(score, NumTeams(kh_teams));
 518         // twice the score for 3 team games, three times the score for 4 team games!
 519         // note: for a win by destroying the key, this should NOT be applied
 520         FOR_EACH_KH_KEY(key)
 521         {
 522                 float f = DistributeEvenly_Get(1);
 523                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 524                 GameRules_scoring_add_team(key.owner, KH_CAPS, 1);
 525                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 526         }
 527
 528         bool first = true;
 529         string keyowner = "";
 530         FOR_EACH_KH_KEY(key)
 531                 if(key.owner.kh_next == key)
 532                 {
 533                         if(!first)
 534                                 keyowner = strcat(keyowner, ", ");
 535                         keyowner = key.owner.netname;
 536                         first = false;
 537                 }
 538
 539         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 540         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_KEYHUNT_CAPTURE), keyowner);
 541
 542         first = true;
 543         vector firstorigin = '0 0 0', lastorigin = '0 0 0', midpoint = '0 0 0';
 544         FOR_EACH_KH_KEY(key)
 545         {
 546                 vector thisorigin = kh_AttachedOrigin(key);
 547                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 548                 midpoint += thisorigin;
 549
 550                 if(!first)
 551                 {
 552                         // TODO: this effect has been replaced due to a possible crash it causes
 553                         // see https://gitlab.com/xonotic/darkplaces/issues/123
 554                         //te_lightning2(NULL, lastorigin, thisorigin);
 555                         Send_Effect(EFFECT_TR_NEXUIZPLASMA, lastorigin, thisorigin, 1);
 556                 }
 557                 lastorigin = thisorigin;
 558                 if(first)
 559                         firstorigin = thisorigin;
 560                 first = false;
 561         }
 562         if(NumTeams(kh_teams) > 2)
 563         {
 564                 //te_lightning2(NULL, lastorigin, firstorigin); // TODO see above
 565                 Send_Effect(EFFECT_TR_NEXUIZPLASMA, lastorigin, firstorigin, 1);
 566         }
 567         midpoint = midpoint * (1 / NumTeams(kh_teams));
 568         te_customflash(midpoint, 1000, 1, Team_ColorRGB(winner_team) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 569
 570         play2all(SND(KH_CAPTURE));
 571         kh_FinishRound();
 572 }
 573
 574 void kh_LoserTeam(int loser_team, entity lostkey)  // runs when a player pushes a flag carrier off the map
 575 {
 576         float f;
 577         entity attacker = NULL;
 578         if(lostkey.pusher)
 579                 if(lostkey.pusher.team != loser_team)
 580                         if(IS_PLAYER(lostkey.pusher))
 581                                 attacker = lostkey.pusher;
 582
 583         if(attacker)
 584         {
 585                 if(lostkey.kh_previous_owner)
 586                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 587                         // don't actually GIVE them the -nn points, just log
 588                 kh_Scores_Event(attacker, NULL, "push", autocvar_g_balance_keyhunt_score_push, 0);
 589                 GameRules_scoring_add(attacker, KH_PUSHES, 1);
 590                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 591         }
 592         else
 593         {
 594                 int players = 0;
 595                 float of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 596
 597                 FOREACH_CLIENT(IS_PLAYER(it) && it.team != loser_team, { ++players; });
 598
 599                 entity key;
 600                 int keys = 0;
 601                 FOR_EACH_KH_KEY(key)
 602                         if(key.owner && key.team != loser_team)
 603                                 ++keys;
 604
 605                 if(lostkey.kh_previous_owner)
 606                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 607                         // don't actually GIVE them the -nn points, just log
 608
 609                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 610                         GameRules_scoring_add(lostkey.kh_previous_owner, KH_DESTRUCTIONS, 1);
 611
 612                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 613
 614                 FOR_EACH_KH_KEY(key)
 615                         if(key.owner && key.team != loser_team)
 616                         {
 617                                 f = DistributeEvenly_Get(of);
 618                                 kh_Scores_Event(key.owner, NULL, "destroyed_holdingkey", f, 0);
 619                         }
 620
 621                 int fragsleft = DistributeEvenly_Get(players);
 622
 623                 // Now distribute these among all other teams...
 624                 int j = NumTeams(kh_teams) - 1;
 625                 for(int i = 0; i < NumTeams(kh_teams); ++i)
 626                 {
 627                         int thisteam = kh_Team_ByID(i);
 628                         if(thisteam == loser_team) // bad boy, no cookie - this WILL happen
 629                                 continue;
 630
 631                         players = 0;
 632                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, { ++players; });
 633
 634                         DistributeEvenly_Init(fragsleft, j);
 635                         fragsleft = DistributeEvenly_Get(j - 1);
 636                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 637
 638                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, {
 639                                 f = DistributeEvenly_Get(1);
 640                                 kh_Scores_Event(it, NULL, "destroyed", f, 0);
 641                         });
 642
 643                         --j;
 644                 }
 645         }
 646
 647         int realteam = kh_Team_ByID(lostkey.count);
 648         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(loser_team, CENTER_ROUND_TEAM_LOSS));
 649         if(attacker)
 650                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PUSHED), attacker.netname, lostkey.kh_previous_owner.netname);
 651         else
 652                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DESTROYED), lostkey.kh_previous_owner.netname);
 653
 654         play2all(SND(KH_DESTROY));
 655         te_tarexplosion(lostkey.origin);
 656
 657         kh_FinishRound();
 658 }
 659
 660 void kh_Key_Think(entity this)  // runs all the time
 661 {
 662         if(game_stopped)
 663                 return;
 664
 665         if(this.owner)
 666         {
 667 #ifndef KH_PLAYER_USE_ATTACHMENT
 668                 makevectors('0 1 0' * (this.cnt + (time % 360) * KH_KEY_XYSPEED));
 669                 setorigin(this, v_forward * KH_KEY_XYDIST + '0 0 1' * this.origin.z);
 670 #endif
 671         }
 672
 673         // if in nodrop or time over, end the round
 674         if(!this.owner)
 675                 if(time > this.pain_finished)
 676                         kh_LoserTeam(this.team, this);
 677
 678         if(this.owner)
 679         if(kh_Key_AllOwnedByWhichTeam() != -1)
 680         {
 681                 if(this.siren_time < time)
 682                 {
 683                         sound(this.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 684                         this.siren_time = time + 2.5;  // repeat every 2.5 seconds
 685                 }
 686
 687                 entity key;
 688                 vector p = this.owner.origin;
 689                 FOR_EACH_KH_KEY(key)
 690                         if(vdist(key.owner.origin - p, >, autocvar_g_balance_keyhunt_maxdist))
 691                                 goto not_winning;
 692                 kh_WinnerTeam(this.team);
 693 LABEL(not_winning)
 694         }
 695
 696         if(kh_interferemsg_time && time > kh_interferemsg_time)
 697         {
 698                 kh_interferemsg_time = 0;
 699                 FOREACH_CLIENT(IS_PLAYER(it), {
 700                         if(it.team == kh_interferemsg_team)
 701                         {
 702                                 if(it.kh_next)
 703                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_MEET);
 704                                 else
 705                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_HELP);
 706                         }
 707                         else
 708                                 Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE));
 709                 });
 710         }
 711
 712         this.nextthink = time + 0.05;
 713 }
 714
 715 void key_reset(entity this)
 716 {
 717         kh_Key_AssignTo(this, NULL);
 718         kh_Key_Remove(this);
 719 }
 720
 721 void kh_Key_Spawn(entity initial_owner, float _angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 722 {
 723         entity key = new(item_kh_key);
 724         key.count = i;
 725         settouch(key, kh_Key_Touch);
 726         setthink(key, kh_Key_Think);
 727         key.nextthink = time;
 728         key.cnt = _angle;
 729         key.angles = '0 360 0' * random();
 730         key.event_damage = kh_Key_Damage;
 731         key.takedamage = DAMAGE_YES;
 732         key.damagedbytriggers = autocvar_g_balance_keyhunt_return_when_unreachable;
 733         key.damagedbycontents = autocvar_g_balance_keyhunt_return_when_unreachable;
 734         key.modelindex = kh_key_dropped;
 735         key.model = "key";
 736         key.kh_dropperteam = 0;
 737         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 738         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 739         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 740         key.reset = key_reset;
 741         navigation_dynamicgoal_init(key, false);
 742
 743         switch(initial_owner.team)
 744         {
 745                 case NUM_TEAM_1:
 746                         key.netname = "^1red key";
 747                         break;
 748                 case NUM_TEAM_2:
 749                         key.netname = "^4blue key";
 750                         break;
 751                 case NUM_TEAM_3:
 752                         key.netname = "^3yellow key";
 753                         break;
 754                 case NUM_TEAM_4:
 755                         key.netname = "^6pink key";
 756                         break;
 757                 default:
 758                         key.netname = "NETGIER key";
 759                         break;
 760         }
 761
 762         // link into key list
 763         key.kh_worldkeynext = kh_worldkeylist;
 764         kh_worldkeylist = key;
 765
 766         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM(initial_owner.team, CENTER_KEYHUNT_START));
 767
 768         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, NULL, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 769         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 770
 771         kh_Key_AssignTo(key, initial_owner);
 772 }
 773
 774 // -1 when no team completely owns all keys yet
 775 int kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 776 {
 777         entity key;
 778         int teem = -1;
 779         int keys = NumTeams(kh_teams);
 780         FOR_EACH_KH_KEY(key)
 781         {
 782                 if(!key.owner)
 783                         return -1;
 784                 if(teem == -1)
 785                         teem = key.team;
 786                 else if(teem != key.team)
 787                         return -1;
 788                 --keys;
 789         }
 790         if(keys != 0)
 791                 return -1;
 792         return teem;
 793 }
 794
 795 void kh_Key_DropOne(entity key)
 796 {
 797         // prevent collecting this one for some time
 798         entity player = key.owner;
 799
 800         key.kh_droptime = time;
 801         key.enemy = player;
 802
 803         kh_Scores_Event(player, key, "dropkey", 0, 0);
 804         GameRules_scoring_add(player, KH_LOSSES, 1);
 805         int realteam = kh_Team_ByID(key.count);
 806         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DROP), player.netname);
 807
 808         kh_Key_AssignTo(key, NULL);
 809         makevectors(player.v_angle);
 810         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 811         key.pusher = NULL;
 812         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 813         key.kh_dropperteam = key.team;
 814
 815         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 816 }
 817
 818 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 819 {
 820         if(player.kh_next)
 821         {
 822                 entity mypusher = NULL;
 823                 if(player.pusher)
 824                         if(time < player.pushltime)
 825                                 mypusher = player.pusher;
 826
 827                 entity key;
 828                 while((key = player.kh_next))
 829                 {
 830                         kh_Scores_Event(player, key, "losekey", 0, 0);
 831                         GameRules_scoring_add(player, KH_LOSSES, 1);
 832                         int realteam = kh_Team_ByID(key.count);
 833                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_LOST), player.netname);
 834                         kh_Key_AssignTo(key, NULL);
 835                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 836                         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 837                         key.pusher = mypusher;
 838                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 839                         if(suicide)
 840                                 key.kh_dropperteam = player.team;
 841                 }
 842                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 843         }
 844 }
 845
 846 int kh_GetMissingTeams()
 847 {
 848         int missing_teams = 0;
 849         for(int i = 0; i < NumTeams(kh_teams); ++i)
 850         {
 851                 int teem = kh_Team_ByID(i);
 852                 int players = 0;
 853                 FOREACH_CLIENT(IS_PLAYER(it), {
 854                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 855                                 ++players;
 856                 });
 857                 if (!players)
 858                         missing_teams |= BIT(i);
 859         }
 860         return missing_teams;
 861 }
 862
 863 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 864 {
 865         static int prev_missing_teams_mask;
 866         if(time < game_starttime)
 867         {
 868                 if (prev_missing_teams_mask > 0)
 869                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 870                 prev_missing_teams_mask = -1;
 871                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 872                 return;
 873         }
 874
 875         int missing_teams_mask = kh_GetMissingTeams();
 876         if(!missing_teams_mask)
 877         {
 878                 if(prev_missing_teams_mask > 0)
 879                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 880                 prev_missing_teams_mask = -1;
 881                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 882                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 883         }
 884         else
 885         {
 886                 if(player_count == 0)
 887                 {
 888                         if(prev_missing_teams_mask > 0)
 889                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 890                         prev_missing_teams_mask = -1;
 891                 }
 892                 else
 893                 {
 894                         if(prev_missing_teams_mask != missing_teams_mask)
 895                         {
 896                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 897                                 prev_missing_teams_mask = missing_teams_mask;
 898                         }
 899                 }
 900                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 901         }
 902 }
 903
 904 void kh_EnableTrackingDevice()  // runs after each round
 905 {
 906         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 907         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 908
 909         kh_tracking_enabled = true;
 910 }
 911
 912 void kh_StartRound()  // runs at the start of each round
 913 {
 914         if(time < game_starttime)
 915         {
 916                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 917                 return;
 918         }
 919
 920         if(kh_GetMissingTeams())
 921         {
 922                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 923                 return;
 924         }
 925
 926         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 927         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 928
 929         for(int i = 0; i < NumTeams(kh_teams); ++i)
 930         {
 931                 int teem = kh_Team_ByID(i);
 932                 int players = 0;
 933                 entity my_player = NULL;
 934                 FOREACH_CLIENT(IS_PLAYER(it), {
 935                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 936                         {
 937                                 ++players;
 938                                 if(random() * players <= 1)
 939                                         my_player = it;
 940                         }
 941                 });
 942                 kh_Key_Spawn(my_player, 360 * i / NumTeams(kh_teams), i);
 943         }
 944
 945         kh_tracking_enabled = false;
 946         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 947         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 948 }
 949
 950 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 951 {
 952         if(attacker == targ)
 953                 return f;
 954
 955         if(targ.kh_next)
 956         {
 957                 if(attacker.team == targ.team)
 958                 {
 959                         int nk = 0;
 960                         for(entity k = targ.kh_next; k != NULL; k = k.kh_next)
 961                                 ++nk;
 962                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 963                 }
 964                 else
 965                 {
 966                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 967                         GameRules_scoring_add(attacker, KH_KCKILLS, 1);
 968                         // the frag gets added later
 969                 }
 970         }
 971
 972         return f;
 973 }
 974
 975 void kh_Initialize()  // sets up th KH environment
 976 {
 977         // setup variables
 978         kh_teams = autocvar_g_keyhunt_teams_override;
 979         if(kh_teams < 2)
 980                 kh_teams = cvar("g_keyhunt_teams"); // read the cvar directly as it gets written earlier in the same frame
 981         kh_teams = BITS(bound(2, kh_teams, 4));
 982
 983         // use a temp entity to avoid linking kh_controller to the world with setmodel
 984         entity tmp_ent = spawn();
 985         setmodel(tmp_ent, MDL_KH_KEY);
 986         kh_key_dropped = tmp_ent.modelindex;
 987
 988 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 989         setmodel(tmp_ent, MDL_KH_KEY_CARRIED);
 990         kh_key_carried = tmp_ent.modelindex;
 991 #else
 992         kh_key_carried = kh_key_dropped;
 993 #endif
 994
 995         delete(tmp_ent);
 996
 997         // make a KH entity for controlling the game
 998         kh_controller = new_pure(kh_controller);
 999         setthink(kh_controller, kh_Controller_Think);
1000         kh_Controller_SetThink(0, kh_WaitForPlayers);
1001
1002         kh_ScoreRules(kh_teams);
1003 }
1004
1005 void kh_finalize()
1006 {
1007         // to be called before intermission
1008         kh_FinishRound();
1009         delete(kh_controller);
1010         kh_controller = NULL;
1011 }
1012
1013 // legacy bot role
1014
1015 void(entity this) havocbot_role_kh_carrier;
1016 void(entity this) havocbot_role_kh_defense;
1017 void(entity this) havocbot_role_kh_offense;
1018 void(entity this) havocbot_role_kh_freelancer;
1019
1020
1021 void havocbot_goalrating_kh(entity this, float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1022 {
1023         entity head;
1024         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1025         {
1026                 if(head.owner == this)
1027                         continue;
1028                 if(!kh_tracking_enabled)
1029                 {
1030                         // if it's carried by our team we know about it
1031                         // otherwise we have to see it to know about it
1032                         if(!head.owner || head.team != this.team)
1033                         {
1034                                 traceline(this.origin + this.view_ofs, head.origin, MOVE_NOMONSTERS, this);
1035                                 if (trace_fraction < 1 && trace_ent != head)
1036                                         continue; // skip what I can't see
1037                         }
1038                 }
1039                 if(!head.owner)
1040                         navigation_routerating(this, head, ratingscale_dropped * 10000, 100000);
1041                 else if(head.team == this.team)
1042                         navigation_routerating(this, head.owner, ratingscale_team * 10000, 100000);
1043                 else
1044                         navigation_routerating(this, head.owner, ratingscale_enemy * 10000, 100000);
1045         }
1046
1047         havocbot_goalrating_items(this, 80000, this.origin, 10000);
1048 }
1049
1050 void havocbot_role_kh_carrier(entity this)
1051 {
1052         if(IS_DEAD(this))
1053                 return;
1054
1055         if (!(this.kh_next))
1056         {
1057                 LOG_TRACE("changing role to freelancer");
1058                 this.havocbot_role = havocbot_role_kh_freelancer;
1059                 this.havocbot_role_timeout = 0;
1060                 return;
1061         }
1062
1063         if (navigation_goalrating_timeout(this))
1064         {
1065                 navigation_goalrating_start(this);
1066
1067                 if(kh_Key_AllOwnedByWhichTeam() == this.team)
1068                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // bring home
1069                 else
1070                         havocbot_goalrating_kh(this, 4, 4, 0.5); // play defensively
1071
1072                 navigation_goalrating_end(this);
1073
1074                 navigation_goalrating_timeout_set(this);
1075         }
1076 }
1077
1078 void havocbot_role_kh_defense(entity this)
1079 {
1080         if(IS_DEAD(this))
1081                 return;
1082
1083         if (this.kh_next)
1084         {
1085                 LOG_TRACE("changing role to carrier");
1086                 this.havocbot_role = havocbot_role_kh_carrier;
1087                 this.havocbot_role_timeout = 0;
1088                 return;
1089         }
1090
1091         if (!this.havocbot_role_timeout)
1092                 this.havocbot_role_timeout = time + random() * 10 + 20;
1093         if (time > this.havocbot_role_timeout)
1094         {
1095                 LOG_TRACE("changing role to freelancer");
1096                 this.havocbot_role = havocbot_role_kh_freelancer;
1097                 this.havocbot_role_timeout = 0;
1098                 return;
1099         }
1100
1101         if (navigation_goalrating_timeout(this))
1102         {
1103                 float key_owner_team;
1104                 navigation_goalrating_start(this);
1105
1106                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1107                 if(key_owner_team == this.team)
1108                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend key carriers
1109                 else if(key_owner_team == -1)
1110                         havocbot_goalrating_kh(this, 4, 1, 0.05); // play defensively
1111                 else
1112                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1113
1114                 navigation_goalrating_end(this);
1115
1116                 navigation_goalrating_timeout_set(this);
1117         }
1118 }
1119
1120 void havocbot_role_kh_offense(entity this)
1121 {
1122         if(IS_DEAD(this))
1123                 return;
1124
1125         if (this.kh_next)
1126         {
1127                 LOG_TRACE("changing role to carrier");
1128                 this.havocbot_role = havocbot_role_kh_carrier;
1129                 this.havocbot_role_timeout = 0;
1130                 return;
1131         }
1132
1133         if (!this.havocbot_role_timeout)
1134                 this.havocbot_role_timeout = time + random() * 10 + 20;
1135         if (time > this.havocbot_role_timeout)
1136         {
1137                 LOG_TRACE("changing role to freelancer");
1138                 this.havocbot_role = havocbot_role_kh_freelancer;
1139                 this.havocbot_role_timeout = 0;
1140                 return;
1141         }
1142
1143         if (navigation_goalrating_timeout(this))
1144         {
1145                 float key_owner_team;
1146
1147                 navigation_goalrating_start(this);
1148
1149                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1150                 if(key_owner_team == this.team)
1151                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1152                 else if(key_owner_team == -1)
1153                         havocbot_goalrating_kh(this, 0.1, 1, 2); // play offensively
1154                 else
1155                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK! EMERGENCY!
1156
1157                 navigation_goalrating_end(this);
1158
1159                 navigation_goalrating_timeout_set(this);
1160         }
1161 }
1162
1163 void havocbot_role_kh_freelancer(entity this)
1164 {
1165         if(IS_DEAD(this))
1166                 return;
1167
1168         if (this.kh_next)
1169         {
1170                 LOG_TRACE("changing role to carrier");
1171                 this.havocbot_role = havocbot_role_kh_carrier;
1172                 this.havocbot_role_timeout = 0;
1173                 return;
1174         }
1175
1176         if (!this.havocbot_role_timeout)
1177                 this.havocbot_role_timeout = time + random() * 10 + 10;
1178         if (time > this.havocbot_role_timeout)
1179         {
1180                 if (random() < 0.5)
1181                 {
1182                         LOG_TRACE("changing role to offense");
1183                         this.havocbot_role = havocbot_role_kh_offense;
1184                 }
1185                 else
1186                 {
1187                         LOG_TRACE("changing role to defense");
1188                         this.havocbot_role = havocbot_role_kh_defense;
1189                 }
1190                 this.havocbot_role_timeout = 0;
1191                 return;
1192         }
1193
1194         if (navigation_goalrating_timeout(this))
1195         {
1196                 navigation_goalrating_start(this);
1197
1198                 int key_owner_team = kh_Key_AllOwnedByWhichTeam();
1199                 if(key_owner_team == this.team)
1200                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1201                 else if(key_owner_team == -1)
1202                         havocbot_goalrating_kh(this, 1, 10, 2); // prefer dropped keys
1203                 else
1204                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1205
1206                 navigation_goalrating_end(this);
1207
1208                 navigation_goalrating_timeout_set(this);
1209         }
1210 }
1211
1212
1213 // register this as a mutator
1214
1215 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1216 {
1217         entity player = M_ARGV(0, entity);
1218
1219         kh_Key_DropAll(player, true);
1220 }
1221
1222 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1223 {
1224         entity player = M_ARGV(0, entity);
1225
1226         kh_Key_DropAll(player, true);
1227 }
1228
1229 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1230 {
1231         entity frag_attacker = M_ARGV(1, entity);
1232         entity frag_target = M_ARGV(2, entity);
1233
1234         if(frag_target == frag_attacker)
1235                 kh_Key_DropAll(frag_target, true);
1236         else if(IS_PLAYER(frag_attacker))
1237                 kh_Key_DropAll(frag_target, false);
1238         else
1239                 kh_Key_DropAll(frag_target, true);
1240 }
1241
1242 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1243 {
1244         entity frag_attacker = M_ARGV(0, entity);
1245         entity frag_target = M_ARGV(1, entity);
1246         float frag_score = M_ARGV(2, float);
1247         M_ARGV(2, float) = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1248 }
1249
1250 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1251 {
1252         kh_finalize();
1253 }
1254
1255 MUTATOR_HOOKFUNCTION(kh, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
1256 {
1257         M_ARGV(0, float) = kh_teams;
1258         return true;
1259 }
1260
1261 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1262 {
1263         entity player = M_ARGV(0, entity);
1264
1265         if(MUTATOR_RETURNVALUE == 0)
1266         {
1267                 entity k = player.kh_next;
1268                 if(k)
1269                 {
1270                         kh_Key_DropOne(k);
1271                         return true;
1272                 }
1273         }
1274 }
1275
1276 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1277 {
1278     entity bot = M_ARGV(0, entity);
1279
1280         if(IS_DEAD(bot))
1281                 return true;
1282
1283         float r = random() * 3;
1284         if (r < 1)
1285                 bot.havocbot_role = havocbot_role_kh_offense;
1286         else if (r < 2)
1287                 bot.havocbot_role = havocbot_role_kh_defense;
1288         else
1289                 bot.havocbot_role = havocbot_role_kh_freelancer;
1290
1291         return true;
1292 }
1293
1294 MUTATOR_HOOKFUNCTION(kh, LogDeath_AppendItemCodes)
1295 {
1296         entity player = M_ARGV(0, entity);
1297         if(player.kh_next)
1298                 M_ARGV(1, string) = strcat(M_ARGV(1, string), "K"); // item codes
1299 }
1300
1301 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1302 {
1303         entity frag_target = M_ARGV(0, entity);
1304
1305         kh_Key_DropAll(frag_target, false);
1306 }
1307
1308 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1309 {
1310         kh_WaitForPlayers(); // takes care of killing the "missing teams" message
1311 }