qcsrc/common/gamemodes/gamemode/onslaught/sv_onslaught.qc

   1 #include "sv_onslaught.qh"
   2 #include "sv_controlpoint.qh"
   3 #include "sv_generator.qh"
   4
   5 bool g_onslaught;
   6
   7 float autocvar_g_onslaught_teleport_wait;
   8 bool autocvar_g_onslaught_spawn_at_controlpoints;
   9 bool autocvar_g_onslaught_spawn_at_generator;
  10 float autocvar_g_onslaught_cp_proxydecap;
  11 float autocvar_g_onslaught_cp_proxydecap_distance = 512;
  12 float autocvar_g_onslaught_cp_proxydecap_dps = 100;
  13 float autocvar_g_onslaught_spawn_at_controlpoints_chance = 0.5;
  14 float autocvar_g_onslaught_spawn_at_controlpoints_random;
  15 float autocvar_g_onslaught_spawn_at_generator_chance;
  16 float autocvar_g_onslaught_spawn_at_generator_random;
  17 float autocvar_g_onslaught_cp_buildhealth;
  18 float autocvar_g_onslaught_cp_buildtime;
  19 float autocvar_g_onslaught_cp_health;
  20 float autocvar_g_onslaught_cp_regen;
  21 float autocvar_g_onslaught_gen_health;
  22 float autocvar_g_onslaught_shield_force = 100;
  23 float autocvar_g_onslaught_allow_vehicle_touch;
  24 float autocvar_g_onslaught_round_timelimit;
  25 float autocvar_g_onslaught_warmup;
  26 float autocvar_g_onslaught_teleport_radius;
  27 float autocvar_g_onslaught_spawn_choose;
  28 float autocvar_g_onslaught_click_radius;
  29
  30 void FixSize(entity e);
  31 entity cam;
  32
  33 // =======================
  34 // CaptureShield Functions
  35 // =======================
  36
  37 bool clientcamera_send(entity this, entity to, int sf)
  38 {
  39         WriteHeader(MSG_ENTITY, ENT_ONSCAMERA);
  40
  41         WriteCoord(MSG_ENTITY, this.origin_x);
  42         WriteCoord(MSG_ENTITY, this.origin_y);
  43         WriteCoord(MSG_ENTITY, this.origin_z);
  44
  45         WriteAngle(MSG_ENTITY, this.angles_x);
  46         WriteAngle(MSG_ENTITY, this.angles_y);
  47         WriteAngle(MSG_ENTITY, this.angles_z);
  48
  49         return true;
  50 }
  51
  52 bool ons_CaptureShield_Customize(entity this, entity client)
  53 {
  54         entity e = WaypointSprite_getviewentity(client);
  55
  56         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, e.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return false; }
  57         if(SAME_TEAM(this, e)) { return false; }
  58
  59         return true;
  60 }
  61
  62 void ons_CaptureShield_Touch(entity this, entity toucher)
  63 {
  64         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, toucher.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return; }
  65         if(!IS_PLAYER(toucher)) { return; }
  66         if(SAME_TEAM(toucher, this)) { return; }
  67
  68         vector mymid = (this.absmin + this.absmax) * 0.5;
  69         vector theirmid = (toucher.absmin + toucher.absmax) * 0.5;
  70
  71         Damage(toucher, this, this, 0, DEATH_HURTTRIGGER.m_id, mymid, normalize(theirmid - mymid) * ons_captureshield_force);
  72
  73         if(IS_REAL_CLIENT(toucher))
  74         {
  75                 play2(toucher, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
  76
  77                 if(this.enemy.classname == "onslaught_generator")
  78                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_GENERATOR_SHIELDED);
  79                 else
  80                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_CONTROLPOINT_SHIELDED);
  81         }
  82 }
  83
  84 void ons_CaptureShield_Reset(entity this)
  85 {
  86         this.colormap = this.enemy.colormap;
  87         this.team = this.enemy.team;
  88 }
  89
  90 void ons_CaptureShield_Spawn(entity generator, bool is_generator)
  91 {
  92         entity shield = new(ons_captureshield);
  93         IL_PUSH(g_onsshields, shield);
  94
  95         shield.enemy = generator;
  96         shield.team = generator.team;
  97         shield.colormap = generator.colormap;
  98         shield.reset = ons_CaptureShield_Reset;
  99         settouch(shield, ons_CaptureShield_Touch);
 100         setcefc(shield, ons_CaptureShield_Customize);
 101         shield.effects = EF_ADDITIVE;
 102         set_movetype(shield, MOVETYPE_NOCLIP);
 103         shield.solid = SOLID_TRIGGER;
 104         shield.avelocity = '7 0 11';
 105         shield.scale = 1;
 106         shield.model = ((is_generator) ? "models/onslaught/generator_shield.md3" : "models/onslaught/controlpoint_shield.md3");
 107
 108         precache_model(shield.model);
 109         setorigin(shield, generator.origin);
 110         _setmodel(shield, shield.model);
 111         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
 112 }
 113
 114
 115 // ==========
 116 // Junk Pile
 117 // ==========
 118
 119 void setmodel_fixsize(entity e, Model m)
 120 {
 121         setmodel(e, m);
 122         FixSize(e);
 123 }
 124
 125 void onslaught_updatelinks()
 126 {
 127         entity l;
 128         // first check if the game has ended
 129         LOG_DEBUG("--- updatelinks ---");
 130         // mark generators as being shielded and networked
 131         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 132         {
 133                 if (l.iscaptured)
 134                         LOG_DEBUG(etos(l), " (generator) belongs to team ", ftos(l.team));
 135                 else
 136                         LOG_DEBUG(etos(l), " (generator) is destroyed");
 137                 l.islinked = l.iscaptured;
 138                 l.isshielded = l.iscaptured;
 139                 l.sprite.SendFlags |= 16;
 140         }
 141         // mark points as shielded and not networked
 142         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 143         {
 144                 l.islinked = false;
 145                 l.isshielded = true;
 146                 int i;
 147                 for(i = 0; i < 17; ++i) { l.isgenneighbor[i] = false; l.iscpneighbor[i] = false; }
 148                 LOG_DEBUG(etos(l), " (point) belongs to team ", ftos(l.team));
 149                 l.sprite.SendFlags |= 16;
 150         }
 151         // flow power outward from the generators through the network
 152         bool stop = false;
 153         while (!stop)
 154         {
 155                 stop = true;
 156                 for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 157                 {
 158                         // if both points are captured by the same team, and only one of
 159                         // them is powered, mark the other one as powered as well
 160                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
 161                                 if (l.enemy.islinked != l.goalentity.islinked)
 162                                         if(SAME_TEAM(l.enemy, l.goalentity))
 163                                         {
 164                                                 if (!l.goalentity.islinked)
 165                                                 {
 166                                                         stop = false;
 167                                                         l.goalentity.islinked = true;
 168                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)");
 169                                                 }
 170                                                 else if (!l.enemy.islinked)
 171                                                 {
 172                                                         stop = false;
 173                                                         l.enemy.islinked = true;
 174                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)");
 175                                                 }
 176                                         }
 177                 }
 178         }
 179         // now that we know which points are powered we can mark their neighbors
 180         // as unshielded if team differs
 181         for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 182         {
 183                 if (l.goalentity.islinked)
 184                 {
 185                         if(DIFF_TEAM(l.goalentity, l.enemy))
 186                         {
 187                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)");
 188                                 l.enemy.isshielded = false;
 189                         }
 190                         if(l.goalentity.classname == "onslaught_generator")
 191                                 l.enemy.isgenneighbor[l.goalentity.team] = true;
 192                         else
 193                                 l.enemy.iscpneighbor[l.goalentity.team] = true;
 194                 }
 195                 if (l.enemy.islinked)
 196                 {
 197                         if(DIFF_TEAM(l.goalentity, l.enemy))
 198                         {
 199                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)");
 200                                 l.goalentity.isshielded = false;
 201                         }
 202                         if(l.enemy.classname == "onslaught_generator")
 203                                 l.goalentity.isgenneighbor[l.enemy.team] = true;
 204                         else
 205                                 l.goalentity.iscpneighbor[l.enemy.team] = true;
 206                 }
 207         }
 208         // now update the generators
 209         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 210         {
 211                 if (l.isshielded)
 212                 {
 213                         LOG_DEBUG(etos(l), " (generator) is shielded");
 214                         l.takedamage = DAMAGE_NO;
 215                         if(l.bot_attack)
 216                                 IL_REMOVE(g_bot_targets, l);
 217                         l.bot_attack = false;
 218                 }
 219                 else
 220                 {
 221                         LOG_DEBUG(etos(l), " (generator) is not shielded");
 222                         l.takedamage = DAMAGE_AIM;
 223                         if(!l.bot_attack)
 224                                 IL_PUSH(g_bot_targets, l);
 225                         l.bot_attack = true;
 226                 }
 227
 228                 ons_Generator_UpdateSprite(l);
 229         }
 230         // now update the takedamage and alpha variables on control point icons
 231         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 232         {
 233                 if (l.isshielded)
 234                 {
 235                         LOG_DEBUG(etos(l), " (point) is shielded");
 236                         if (l.goalentity)
 237                         {
 238                                 l.goalentity.takedamage = DAMAGE_NO;
 239                                 if(l.goalentity.bot_attack)
 240                                         IL_REMOVE(g_bot_targets, l.goalentity);
 241                                 l.goalentity.bot_attack = false;
 242                         }
 243                 }
 244                 else
 245                 {
 246                         LOG_DEBUG(etos(l), " (point) is not shielded");
 247                         if (l.goalentity)
 248                         {
 249                                 l.goalentity.takedamage = DAMAGE_AIM;
 250                                 if(!l.goalentity.bot_attack)
 251                                         IL_PUSH(g_bot_targets, l.goalentity);
 252                                 l.goalentity.bot_attack = true;
 253                         }
 254                 }
 255                 ons_ControlPoint_UpdateSprite(l);
 256         }
 257         IL_EACH(g_onsshields, true,
 258         {
 259                 it.team = it.enemy.team;
 260                 it.colormap = it.enemy.colormap;
 261         });
 262 }
 263
 264
 265 // ===================
 266 // Main Link Functions
 267 // ===================
 268
 269 bool ons_Link_Send(entity this, entity to, int sendflags)
 270 {
 271         WriteHeader(MSG_ENTITY, ENT_CLIENT_RADARLINK);
 272         WriteByte(MSG_ENTITY, sendflags);
 273         if(sendflags & 1)
 274         {
 275                 WriteCoord(MSG_ENTITY, this.goalentity.origin_x);
 276                 WriteCoord(MSG_ENTITY, this.goalentity.origin_y);
 277                 WriteCoord(MSG_ENTITY, this.goalentity.origin_z);
 278         }
 279         if(sendflags & 2)
 280         {
 281                 WriteCoord(MSG_ENTITY, this.enemy.origin_x);
 282                 WriteCoord(MSG_ENTITY, this.enemy.origin_y);
 283                 WriteCoord(MSG_ENTITY, this.enemy.origin_z);
 284         }
 285         if(sendflags & 4)
 286         {
 287                 WriteByte(MSG_ENTITY, this.clientcolors); // which is goalentity's color + enemy's color * 16
 288         }
 289         return true;
 290 }
 291
 292 void ons_Link_CheckUpdate(entity this)
 293 {
 294         // TODO check if the two sides have moved (currently they won't move anyway)
 295         float cc = 0, cc1 = 0, cc2 = 0;
 296
 297         if(this.goalentity.islinked || this.goalentity.iscaptured) { cc1 = (this.goalentity.team - 1) * 0x01; }
 298         if(this.enemy.islinked || this.enemy.iscaptured) { cc2 = (this.enemy.team - 1) * 0x10; }
 299
 300         cc = cc1 + cc2;
 301
 302         if(cc != this.clientcolors)
 303         {
 304                 this.clientcolors = cc;
 305                 this.SendFlags |= 4;
 306         }
 307
 308         this.nextthink = time;
 309 }
 310
 311 void ons_DelayedLinkSetup(entity this)
 312 {
 313         this.goalentity = find(NULL, targetname, this.target);
 314         this.enemy = find(NULL, targetname, this.target2);
 315         if(!this.goalentity) { objerror(this, "can not find target\n"); }
 316         if(!this.enemy) { objerror(this, "can not find target2\n"); }
 317
 318         LOG_DEBUG(etos(this.goalentity), " linked with ", etos(this.enemy));
 319         this.SendFlags |= 3;
 320         setthink(this, ons_Link_CheckUpdate);
 321         this.nextthink = time;
 322 }
 323
 324
 325 // =============================
 326 // Main Control Point Functions
 327 // =============================
 328
 329 int ons_ControlPoint_CanBeLinked(entity cp, int teamnumber)
 330 {
 331         if(cp.isgenneighbor[teamnumber]) { return 2; }
 332         if(cp.iscpneighbor[teamnumber]) { return 1; }
 333
 334         return 0;
 335 }
 336
 337 int ons_ControlPoint_Attackable(entity cp, int teamnumber)
 338         // -2: SAME TEAM, attackable by enemy!
 339         // -1: SAME TEAM!
 340         // 0: off limits
 341         // 1: attack it
 342         // 2: touch it
 343         // 3: attack it (HIGH PRIO)
 344         // 4: touch it (HIGH PRIO)
 345 {
 346         int a;
 347
 348         if(cp.isshielded)
 349         {
 350                 return 0;
 351         }
 352         else if(cp.goalentity)
 353         {
 354                 // if there's already an icon built, nothing happens
 355                 if(cp.team == teamnumber)
 356                 {
 357                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 358                         if(a) // attackable by enemy?
 359                                 return -2; // EMERGENCY!
 360                         return -1;
 361                 }
 362                 // we know it can be linked, so no need to check
 363                 // but...
 364                 a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 365                 if(a == 2) // near our generator?
 366                         return 3; // EMERGENCY!
 367                 return 1;
 368         }
 369         else
 370         {
 371                 // free point
 372                 if(ons_ControlPoint_CanBeLinked(cp, teamnumber))
 373                 {
 374                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber); // why was this here NUM_TEAM_1 + NUM_TEAM_2 - t
 375                         if(a == 2)
 376                                 return 4; // GET THIS ONE NOW!
 377                         else
 378                                 return 2; // TOUCH ME
 379                 }
 380         }
 381         return 0;
 382 }
 383
 384 void ons_ControlPoint_Icon_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 385 {
 386         if(damage <= 0) { return; }
 387
 388         if (this.owner.isshielded)
 389         {
 390                 // this is protected by a shield, so ignore the damage
 391                 if (time > this.pain_finished)
 392                         if (IS_PLAYER(attacker))
 393                         {
 394                                 play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 395                                 this.pain_finished = time + 1;
 396                                 attacker.typehitsound += 1; // play both sounds (shield is way too quiet)
 397                         }
 398
 399                 return;
 400         }
 401
 402         if(IS_PLAYER(attacker))
 403         if(time - ons_notification_time[this.team] > 10)
 404         {
 405                 play2team(this.team, SND(ONS_CONTROLPOINT_UNDERATTACK));
 406                 ons_notification_time[this.team] = time;
 407         }
 408
 409         this.health = this.health - damage;
 410         if(this.owner.iscaptured)
 411                 WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 412         else
 413                 WaypointSprite_UpdateBuildFinished(this.owner.sprite, time + (this.max_health - this.health) / (this.count / ONS_CP_THINKRATE));
 414         this.pain_finished = time + 1;
 415         // particles on every hit
 416         pointparticles(EFFECT_SPARKS, hitloc, force*-1, 1);
 417         //sound on every hit
 418         if (random() < 0.5)
 419                 sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE+0.3, ATTEN_NORM);
 420         else
 421                 sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE+0.3, ATTEN_NORM);
 422
 423         if (this.health < 0)
 424         {
 425                 sound(this, CH_TRIGGER, SND_GRENADE_IMPACT, VOL_BASE, ATTEN_NORM);
 426                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 427                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_CPDESTROYED), this.owner.message, attacker.netname);
 428
 429                 PlayerScore_Add(attacker, SP_ONS_TAKES, 1);
 430                 PlayerScore_Add(attacker, SP_SCORE, 10);
 431
 432                 this.owner.goalentity = NULL;
 433                 this.owner.islinked = false;
 434                 this.owner.iscaptured = false;
 435                 this.owner.team = 0;
 436                 this.owner.colormap = 1024;
 437
 438                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, 0);
 439
 440                 onslaught_updatelinks();
 441
 442                 // Use targets now (somebody make sure this is in the right place..)
 443                 SUB_UseTargets(this.owner, this, NULL);
 444
 445                 this.owner.waslinked = this.owner.islinked;
 446                 if(this.owner.model != "models/onslaught/controlpoint_pad.md3")
 447                         setmodel_fixsize(this.owner, MDL_ONS_CP_PAD1);
 448                 //setsize(this, '-32 -32 0', '32 32 8');
 449
 450                 delete(this);
 451         }
 452
 453         this.SendFlags |= CPSF_STATUS;
 454 }
 455
 456 void ons_ControlPoint_Icon_Think(entity this)
 457 {
 458         this.nextthink = time + ONS_CP_THINKRATE;
 459
 460         if(autocvar_g_onslaught_cp_proxydecap)
 461         {
 462                 int _enemy_count = 0;
 463                 int _friendly_count = 0;
 464
 465                 FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
 466                         if(vdist(it.origin - this.origin, <, autocvar_g_onslaught_cp_proxydecap_distance))
 467                         {
 468                                 if(SAME_TEAM(it, this))
 469                                         ++_friendly_count;
 470                                 else
 471                                         ++_enemy_count;
 472                         }
 473                 });
 474
 475                 _friendly_count = _friendly_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 476                 _enemy_count = _enemy_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 477
 478                 this.health = bound(0, this.health + (_friendly_count - _enemy_count), this.max_health);
 479                 this.SendFlags |= CPSF_STATUS;
 480                 if(this.health <= 0)
 481                 {
 482                         ons_ControlPoint_Icon_Damage(this, this, this, 1, 0, this.origin, '0 0 0');
 483                         return;
 484                 }
 485         }
 486
 487         if (time > this.pain_finished + 5)
 488         {
 489                 if(this.health < this.max_health)
 490                 {
 491                         this.health = this.health + this.count;
 492                         if (this.health >= this.max_health)
 493                                 this.health = this.max_health;
 494                         WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 495                 }
 496         }
 497
 498         if(this.owner.islinked != this.owner.waslinked)
 499         {
 500                 // unteam the spawnpoint if needed
 501                 int t = this.owner.team;
 502                 if(!this.owner.islinked)
 503                         this.owner.team = 0;
 504
 505                 SUB_UseTargets(this.owner, this, NULL);
 506
 507                 this.owner.team = t;
 508
 509                 this.owner.waslinked = this.owner.islinked;
 510         }
 511
 512         // damaged fx
 513         if(random() < 0.6 - this.health / this.max_health)
 514         {
 515                 Send_Effect(EFFECT_ELECTRIC_SPARKS, this.origin + randompos('-10 -10 -20', '10 10 20'), '0 0 0', 1);
 516
 517                 if(random() > 0.8)
 518                         sound(this, CH_PAIN, SND_ONS_SPARK1, VOL_BASE, ATTEN_NORM);
 519                 else if (random() > 0.5)
 520                         sound(this, CH_PAIN, SND_ONS_SPARK2, VOL_BASE, ATTEN_NORM);
 521         }
 522 }
 523
 524 void ons_ControlPoint_Icon_BuildThink(entity this)
 525 {
 526         int a;
 527
 528         this.nextthink = time + ONS_CP_THINKRATE;
 529
 530         // only do this if there is power
 531         a = ons_ControlPoint_CanBeLinked(this.owner, this.owner.team);
 532         if(!a)
 533                 return;
 534
 535         this.health = this.health + this.count;
 536
 537         this.SendFlags |= CPSF_STATUS;
 538
 539         if (this.health >= this.max_health)
 540         {
 541                 this.health = this.max_health;
 542                 this.count = autocvar_g_onslaught_cp_regen * ONS_CP_THINKRATE; // slow repair rate from now on
 543                 setthink(this, ons_ControlPoint_Icon_Think);
 544                 sound(this, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILT, VOL_BASE, ATTEN_NORM);
 545                 this.owner.iscaptured = true;
 546                 this.solid = SOLID_BBOX;
 547
 548                 Send_Effect(EFFECT_CAP(this.owner.team), this.owner.origin, '0 0 0', 1);
 549
 550                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, this.max_health);
 551                 WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 552
 553                 if(IS_PLAYER(this.owner.ons_toucher))
 554                 {
 555                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ONSLAUGHT_CAPTURE, this.owner.ons_toucher.netname, this.owner.message);
 556                         Send_Notification(NOTIF_ALL_EXCEPT, this.owner.ons_toucher, MSG_CENTER, APP_TEAM_NUM(this.owner.ons_toucher.team, CENTER_ONS_CAPTURE_TEAM), this.owner.message);
 557                         Send_Notification(NOTIF_ONE, this.owner.ons_toucher, MSG_CENTER, CENTER_ONS_CAPTURE, this.owner.message);
 558                         PlayerScore_Add(this.owner.ons_toucher, SP_ONS_CAPS, 1);
 559                         PlayerTeamScore_AddScore(this.owner.ons_toucher, 10);
 560                 }
 561
 562                 this.owner.ons_toucher = NULL;
 563
 564                 onslaught_updatelinks();
 565
 566                 // Use targets now (somebody make sure this is in the right place..)
 567                 SUB_UseTargets(this.owner, this, NULL);
 568
 569                 this.SendFlags |= CPSF_SETUP;
 570         }
 571         if(this.owner.model != MDL_ONS_CP_PAD2.model_str())
 572                 setmodel_fixsize(this.owner, MDL_ONS_CP_PAD2);
 573
 574         if(random() < 0.9 - this.health / this.max_health)
 575                 Send_Effect(EFFECT_RAGE, this.origin + 10 * randomvec(), '0 0 -1', 1);
 576 }
 577
 578 void onslaught_controlpoint_icon_link(entity e, void(entity this) spawnproc);
 579
 580 void ons_ControlPoint_Icon_Spawn(entity cp, entity player)
 581 {
 582         entity e = new(onslaught_controlpoint_icon);
 583
 584         setsize(e, CPICON_MIN, CPICON_MAX);
 585         setorigin(e, cp.origin + CPICON_OFFSET);
 586
 587         e.owner = cp;
 588         e.max_health = autocvar_g_onslaught_cp_health;
 589         e.health = autocvar_g_onslaught_cp_buildhealth;
 590         e.solid = SOLID_NOT;
 591         e.takedamage = DAMAGE_AIM;
 592         e.bot_attack = true;
 593         IL_PUSH(g_bot_targets, e);
 594         e.event_damage = ons_ControlPoint_Icon_Damage;
 595         e.team = player.team;
 596         e.colormap = 1024 + (e.team - 1) * 17;
 597         e.count = (e.max_health - e.health) * ONS_CP_THINKRATE / autocvar_g_onslaught_cp_buildtime; // how long it takes to build
 598
 599         sound(e, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILD, VOL_BASE, ATTEN_NORM);
 600
 601         cp.goalentity = e;
 602         cp.team = e.team;
 603         cp.colormap = e.colormap;
 604
 605         Send_Effect(EFFECT_FLAG_TOUCH(player.team), e.origin, '0 0 0', 1);
 606
 607         WaypointSprite_UpdateBuildFinished(cp.sprite, time + (e.max_health - e.health) / (e.count / ONS_CP_THINKRATE));
 608         WaypointSprite_UpdateRule(cp.sprite,cp.team,SPRITERULE_TEAMPLAY);
 609         cp.sprite.SendFlags |= 16;
 610
 611         onslaught_controlpoint_icon_link(e, ons_ControlPoint_Icon_BuildThink);
 612 }
 613
 614 entity ons_ControlPoint_Waypoint(entity e)
 615 {
 616         if(e.team)
 617         {
 618                 int a = ons_ControlPoint_Attackable(e, e.team);
 619
 620                 if(a == -2) { return WP_OnsCPDefend; } // defend now
 621                 if(a == -1 || a == 1 || a == 2) { return WP_OnsCP; } // touch
 622                 if(a == 3 || a == 4) { return WP_OnsCPAttack; } // attack
 623         }
 624         else
 625                 return WP_OnsCP;
 626
 627         return WP_Null;
 628 }
 629
 630 void ons_ControlPoint_UpdateSprite(entity e)
 631 {
 632         entity s1 = ons_ControlPoint_Waypoint(e);
 633         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 634
 635         bool sh;
 636         sh = !(ons_ControlPoint_CanBeLinked(e, NUM_TEAM_1) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_2) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_3) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_4));
 637
 638         if(e.lastteam != e.team + 2 || e.lastshielded != sh || e.iscaptured != e.lastcaptured)
 639         {
 640                 if(e.iscaptured) // don't mess up build bars!
 641                 {
 642                         if(sh)
 643                         {
 644                                 WaypointSprite_UpdateMaxHealth(e.sprite, 0);
 645                         }
 646                         else
 647                         {
 648                                 WaypointSprite_UpdateMaxHealth(e.sprite, e.goalentity.max_health);
 649                                 WaypointSprite_UpdateHealth(e.sprite, e.goalentity.health);
 650                         }
 651                 }
 652                 if(e.lastshielded)
 653                 {
 654                         if(e.team)
 655                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, 0.5 * colormapPaletteColor(e.team - 1, false));
 656                         else
 657                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
 658                 }
 659                 else
 660                 {
 661                         if(e.team)
 662                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, colormapPaletteColor(e.team - 1, false));
 663                         else
 664                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
 665                 }
 666                 WaypointSprite_Ping(e.sprite);
 667
 668                 e.lastteam = e.team + 2;
 669                 e.lastshielded = sh;
 670                 e.lastcaptured = e.iscaptured;
 671         }
 672 }
 673
 674 void ons_ControlPoint_Touch(entity this, entity toucher)
 675 {
 676         int attackable;
 677
 678         if(IS_VEHICLE(toucher) && toucher.owner)
 679         if(autocvar_g_onslaught_allow_vehicle_touch)
 680                 toucher = toucher.owner;
 681         else
 682                 return;
 683
 684         if(!IS_PLAYER(toucher)) { return; }
 685         if(STAT(FROZEN, toucher)) { return; }
 686         if(IS_DEAD(toucher)) { return; }
 687
 688         if ( SAME_TEAM(this,toucher) )
 689         if ( this.iscaptured )
 690         {
 691                 if(time <= toucher.teleport_antispam)
 692                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT_ANTISPAM, rint(toucher.teleport_antispam - time));
 693                 else
 694                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
 695         }
 696
 697         attackable = ons_ControlPoint_Attackable(this, toucher.team);
 698         if(attackable != 2 && attackable != 4)
 699                 return;
 700         // we've verified that this player has a legitimate claim to this point,
 701         // so start building the captured point icon (which only captures this
 702         // point if it successfully builds without being destroyed first)
 703         ons_ControlPoint_Icon_Spawn(this, toucher);
 704
 705         this.ons_toucher = toucher;
 706
 707         onslaught_updatelinks();
 708 }
 709
 710 void ons_ControlPoint_Think(entity this)
 711 {
 712         this.nextthink = time + ONS_CP_THINKRATE;
 713         CSQCMODEL_AUTOUPDATE(this);
 714 }
 715
 716 void ons_ControlPoint_Reset(entity this)
 717 {
 718         if(this.goalentity)
 719                 delete(this.goalentity);
 720
 721         this.goalentity = NULL;
 722         this.team = 0;
 723         this.colormap = 1024;
 724         this.iscaptured = false;
 725         this.islinked = false;
 726         this.isshielded = true;
 727         setthink(this, ons_ControlPoint_Think);
 728         this.ons_toucher = NULL;
 729         this.nextthink = time + ONS_CP_THINKRATE;
 730         setmodel_fixsize(this, MDL_ONS_CP_PAD1);
 731
 732         WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 733         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 734
 735         onslaught_updatelinks();
 736
 737         SUB_UseTargets(this, this, NULL); // to reset the structures, playerspawns etc.
 738
 739         CSQCMODEL_AUTOUPDATE(this);
 740 }
 741
 742 void ons_DelayedControlPoint_Setup(entity this)
 743 {
 744         onslaught_updatelinks();
 745
 746         // captureshield setup
 747         ons_CaptureShield_Spawn(this, false);
 748
 749         CSQCMODEL_AUTOINIT(this);
 750 }
 751
 752 void ons_ControlPoint_Setup(entity cp)
 753 {
 754         // main setup
 755         cp.ons_worldcpnext = ons_worldcplist; // link control point into ons_worldcplist
 756         ons_worldcplist = cp;
 757
 758         cp.netname = "Control point";
 759         cp.team = 0;
 760         cp.solid = SOLID_BBOX;
 761         set_movetype(cp, MOVETYPE_NONE);
 762         settouch(cp, ons_ControlPoint_Touch);
 763         setthink(cp, ons_ControlPoint_Think);
 764         cp.nextthink = time + ONS_CP_THINKRATE;
 765         cp.reset = ons_ControlPoint_Reset;
 766         cp.colormap = 1024;
 767         cp.iscaptured = false;
 768         cp.islinked = false;
 769         cp.isshielded = true;
 770
 771         if(cp.message == "") { cp.message = "a"; }
 772
 773         // appearence
 774         setmodel_fixsize(cp, MDL_ONS_CP_PAD1);
 775
 776         // control point placement
 777         if((cp.spawnflags & 1) || cp.noalign) // don't drop to floor, just stay at fixed location
 778         {
 779                 cp.noalign = true;
 780                 set_movetype(cp, MOVETYPE_NONE);
 781         }
 782         else // drop to floor, automatically find a platform and set that as spawn origin
 783         {
 784                 setorigin(cp, cp.origin + '0 0 20');
 785                 cp.noalign = false;
 786                 droptofloor(cp);
 787                 set_movetype(cp, MOVETYPE_TOSS);
 788         }
 789
 790         // waypointsprites
 791         WaypointSprite_SpawnFixed(WP_Null, cp.origin + CPGEN_WAYPOINT_OFFSET, cp, sprite, RADARICON_NONE);
 792         WaypointSprite_UpdateRule(cp.sprite, cp.team, SPRITERULE_TEAMPLAY);
 793
 794         InitializeEntity(cp, ons_DelayedControlPoint_Setup, INITPRIO_SETLOCATION);
 795 }
 796
 797
 798 // =========================
 799 // Main Generator Functions
 800 // =========================
 801
 802 entity ons_Generator_Waypoint(entity e)
 803 {
 804         if (e.isshielded)
 805                 return WP_OnsGenShielded;
 806         return WP_OnsGen;
 807 }
 808
 809 void ons_Generator_UpdateSprite(entity e)
 810 {
 811         entity s1 = ons_Generator_Waypoint(e);
 812         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 813
 814         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
 815         {
 816                 e.lastteam = e.team + 2;
 817                 e.lastshielded = e.isshielded;
 818                 if(e.lastshielded)
 819                 {
 820                         if(e.team)
 821                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, 0.5 * colormapPaletteColor(e.team - 1, false));
 822                         else
 823                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
 824                 }
 825                 else
 826                 {
 827                         if(e.team)
 828                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, colormapPaletteColor(e.team - 1, false));
 829                         else
 830                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
 831                 }
 832                 WaypointSprite_Ping(e.sprite);
 833         }
 834 }
 835
 836 void ons_camSetup(entity this)
 837 {
 838         vector dir;
 839         vector ang = '0 0 0';
 840         vector best_ang = '0 0 0';
 841         float best_trace_fraction = 0;
 842         while(ang.y < 360)
 843         {
 844                 dir = eX * cos(ang.y * DEG2RAD) + eY * sin(ang.y * DEG2RAD);
 845                 dir *= 500;
 846                 traceline(this.origin, this.origin - dir, MOVE_WORLDONLY, this);
 847                 if(trace_fraction > best_trace_fraction)
 848                 {
 849                         best_trace_fraction = trace_fraction;
 850                         best_ang = ang;
 851                         if(trace_fraction == 1)
 852                                 break;
 853                 }
 854                 ang.y += 90;
 855                 if(ang.y == 360)
 856                         ang.y = 45;
 857         }
 858         cam.origin = this.origin;
 859         setorigin(cam, cam.origin);
 860         cam.angles = best_ang;
 861         Net_LinkEntity(cam, false, 0, clientcamera_send);
 862
 863         FOREACH_CLIENT(true, it.clientcamera = cam;);
 864
 865         WriteByte(MSG_ALL, SVC_SETVIEWANGLES);
 866         WriteAngle(MSG_ALL, cam.angles_x);
 867         WriteAngle(MSG_ALL, cam.angles_y);
 868         WriteAngle(MSG_ALL, cam.angles_z);
 869 }
 870
 871 void ons_GeneratorDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 872 {
 873         if(damage <= 0) return;
 874         if(warmup_stage || game_stopped) return;
 875         if(!round_handler_IsRoundStarted()) return;
 876
 877         if (attacker != this)
 878         {
 879                 if (this.isshielded)
 880                 {
 881                         // generator is protected by a shield, so ignore the damage
 882                         if (time > this.pain_finished)
 883                                 if (IS_PLAYER(attacker))
 884                                 {
 885                                         play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 886                                         attacker.typehitsound += 1;
 887                                         this.pain_finished = time + 1;
 888                                 }
 889                         return;
 890                 }
 891                 if (time > this.pain_finished)
 892                 {
 893                         this.pain_finished = time + 10;
 894                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && SAME_TEAM(it, this), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_GENERATOR_UNDERATTACK));
 895                         play2team(this.team, SND(ONS_GENERATOR_UNDERATTACK));
 896                 }
 897         }
 898         this.health = this.health - damage;
 899         WaypointSprite_UpdateHealth(this.sprite, this.health);
 900         // choose an animation frame based on health
 901         this.frame = 10 * bound(0, (1 - this.health / this.max_health), 1);
 902         // see if the generator is still functional, or dying
 903         if (this.health > 0)
 904         {
 905                 this.lasthealth = this.health;
 906         }
 907         else
 908         {
 909                 if (attacker == this)
 910                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED_OVERTIME));
 911                 else
 912                 {
 913                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED));
 914                         PlayerScore_Add(attacker, SP_SCORE, 100);
 915                 }
 916                 this.iscaptured = false;
 917                 this.islinked = false;
 918                 this.isshielded = false;
 919                 this.takedamage = DAMAGE_NO; // can't be hurt anymore
 920                 this.event_damage = func_null; // won't do anything if hurt
 921                 this.count = 0; // reset counter
 922                 setthink(this, func_null);
 923                 this.nextthink = 0;
 924                 //this.think(); // do the first explosion now
 925
 926                 WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 927                 WaypointSprite_Ping(this.sprite);
 928                 //WaypointSprite_Kill(this.sprite); // can't do this yet, code too poor
 929
 930                 onslaught_updatelinks();
 931
 932                 ons_camSetup(this);
 933         }
 934
 935         // Throw some flaming gibs on damage, more damage = more chance for gib
 936         if(random() < damage/220)
 937         {
 938                 sound(this, CH_TRIGGER, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 939         }
 940         else
 941         {
 942                 // particles on every hit
 943                 Send_Effect(EFFECT_SPARKS, hitloc, force * -1, 1);
 944
 945                 //sound on every hit
 946                 if (random() < 0.5)
 947                         sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE, ATTEN_NORM);
 948                 else
 949                         sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);
 950         }
 951
 952         this.SendFlags |= GSF_STATUS;
 953 }
 954
 955 void ons_GeneratorThink(entity this)
 956 {
 957         this.nextthink = time + GEN_THINKRATE;
 958         if (!game_stopped)
 959         {
 960                 if(!this.isshielded && this.wait < time)
 961                 {
 962                         this.wait = time + 5;
 963                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 964                                 if(SAME_TEAM(it, this))
 965                                 {
 966                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_ONS_NOTSHIELDED_TEAM);
 967                                         soundto(MSG_ONE, it, CHAN_AUTO, SND(KH_ALARM), VOL_BASE, ATTEN_NONE);    // FIXME: unique sound?
 968                                 }
 969                                 else
 970                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(this.team, CENTER_ONS_NOTSHIELDED));
 971                         });
 972                 }
 973         }
 974 }
 975
 976 void ons_GeneratorReset(entity this)
 977 {
 978         this.team = this.team_saved;
 979         this.lasthealth = this.max_health = this.health = autocvar_g_onslaught_gen_health;
 980         this.takedamage = DAMAGE_AIM;
 981         this.bot_attack = true;
 982         if(!IL_CONTAINS(g_bot_targets, this))
 983                 IL_PUSH(g_bot_targets, this);
 984         this.iscaptured = true;
 985         this.islinked = true;
 986         this.isshielded = true;
 987         this.event_damage = ons_GeneratorDamage;
 988         setthink(this, ons_GeneratorThink);
 989         this.nextthink = time + GEN_THINKRATE;
 990
 991         Net_LinkEntity(this, false, 0, generator_send);
 992
 993         this.SendFlags = GSF_SETUP; // just incase
 994         this.SendFlags |= GSF_STATUS;
 995
 996         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
 997         WaypointSprite_UpdateHealth(this.sprite, this.health);
 998         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 999
1000         onslaught_updatelinks();
1001 }
1002
1003 void ons_DelayedGeneratorSetup(entity this)
1004 {
1005         // bot waypoints
1006         waypoint_spawnforitem_force(this, this.origin);
1007         this.nearestwaypointtimeout = 0; // activate waypointing again
1008         this.bot_basewaypoint = this.nearestwaypoint;
1009
1010         // captureshield setup
1011         ons_CaptureShield_Spawn(this, true);
1012
1013         onslaught_updatelinks();
1014
1015         Net_LinkEntity(this, false, 0, generator_send);
1016 }
1017
1018
1019 void onslaught_generator_touch(entity this, entity toucher)
1020 {
1021         if ( IS_PLAYER(toucher) )
1022         if ( SAME_TEAM(this,toucher) )
1023         if ( this.iscaptured )
1024         {
1025                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
1026         }
1027 }
1028
1029 void ons_GeneratorSetup(entity gen) // called when spawning a generator entity on the map as a spawnfunc
1030 {
1031         // declarations
1032         int teamnumber = gen.team;
1033
1034         // main setup
1035         gen.ons_worldgeneratornext = ons_worldgeneratorlist; // link generator into ons_worldgeneratorlist
1036         ons_worldgeneratorlist = gen;
1037
1038         gen.netname = sprintf("%s generator", Team_ColoredFullName(teamnumber));
1039         gen.classname = "onslaught_generator";
1040         gen.solid = SOLID_BBOX;
1041         gen.team_saved = teamnumber;
1042         set_movetype(gen, MOVETYPE_NONE);
1043         gen.lasthealth = gen.max_health = gen.health = autocvar_g_onslaught_gen_health;
1044         gen.takedamage = DAMAGE_AIM;
1045         gen.bot_attack = true;
1046         IL_PUSH(g_bot_targets, gen);
1047         gen.event_damage = ons_GeneratorDamage;
1048         gen.reset = ons_GeneratorReset;
1049         setthink(gen, ons_GeneratorThink);
1050         gen.nextthink = time + GEN_THINKRATE;
1051         gen.iscaptured = true;
1052         gen.islinked = true;
1053         gen.isshielded = true;
1054         settouch(gen, onslaught_generator_touch);
1055
1056         // appearence
1057         // model handled by CSQC
1058         setsize(gen, GENERATOR_MIN, GENERATOR_MAX);
1059         setorigin(gen, (gen.origin + CPGEN_SPAWN_OFFSET));
1060         gen.colormap = 1024 + (teamnumber - 1) * 17;
1061
1062         // generator placement
1063         droptofloor(gen);
1064
1065         // waypointsprites
1066         WaypointSprite_SpawnFixed(WP_Null, gen.origin + CPGEN_WAYPOINT_OFFSET, gen, sprite, RADARICON_NONE);
1067         WaypointSprite_UpdateRule(gen.sprite, gen.team, SPRITERULE_TEAMPLAY);
1068         WaypointSprite_UpdateMaxHealth(gen.sprite, gen.max_health);
1069         WaypointSprite_UpdateHealth(gen.sprite, gen.health);
1070
1071         InitializeEntity(gen, ons_DelayedGeneratorSetup, INITPRIO_SETLOCATION);
1072 }
1073
1074
1075 // ===============
1076 //  Round Handler
1077 // ===============
1078
1079 int total_generators;
1080 void Onslaught_count_generators()
1081 {
1082         entity e;
1083         total_generators = redowned = blueowned = yellowowned = pinkowned = 0;
1084         for(e = ons_worldgeneratorlist; e; e = e.ons_worldgeneratornext)
1085         {
1086                 ++total_generators;
1087                 redowned += (e.team == NUM_TEAM_1 && e.health > 0);
1088                 blueowned += (e.team == NUM_TEAM_2 && e.health > 0);
1089                 yellowowned += (e.team == NUM_TEAM_3 && e.health > 0);
1090                 pinkowned += (e.team == NUM_TEAM_4 && e.health > 0);
1091         }
1092 }
1093
1094 int Onslaught_GetWinnerTeam()
1095 {
1096         int winner_team = 0;
1097         if(redowned > 0)
1098                 winner_team = NUM_TEAM_1;
1099         if(blueowned > 0)
1100         {
1101                 if(winner_team) return 0;
1102                 winner_team = NUM_TEAM_2;
1103         }
1104         if(yellowowned > 0)
1105         {
1106                 if(winner_team) return 0;
1107                 winner_team = NUM_TEAM_3;
1108         }
1109         if(pinkowned > 0)
1110         {
1111                 if(winner_team) return 0;
1112                 winner_team = NUM_TEAM_4;
1113         }
1114         if(winner_team)
1115                 return winner_team;
1116         return -1; // no generators left?
1117 }
1118
1119 void nades_Clear(entity e);
1120
1121 #define ONS_OWNED_GENERATORS() ((redowned > 0) + (blueowned > 0) + (yellowowned > 0) + (pinkowned > 0))
1122 #define ONS_OWNED_GENERATORS_OK() (ONS_OWNED_GENERATORS() > 1)
1123 bool Onslaught_CheckWinner()
1124 {
1125         if ((autocvar_timelimit && time > game_starttime + autocvar_timelimit * 60) || (round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0))
1126         {
1127                 ons_stalemate = true;
1128
1129                 if (!wpforenemy_announced)
1130                 {
1131                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT);
1132                         sound(NULL, CH_INFO, SND_ONS_GENERATOR_DECAY, VOL_BASE, ATTEN_NONE);
1133
1134                         wpforenemy_announced = true;
1135                 }
1136
1137                 entity tmp_entity; // temporary entity
1138                 float d;
1139                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext) if(time >= tmp_entity.ons_overtime_damagedelay)
1140                 {
1141                         // tmp_entity.max_health / 300 gives 5 minutes of overtime.
1142                         // control points reduce the overtime duration.
1143                         d = 1;
1144                         entity e;
1145                         for(e = ons_worldcplist; e; e = e.ons_worldcpnext)
1146                         {
1147                                 if(DIFF_TEAM(e, tmp_entity))
1148                                 if(e.islinked)
1149                                         d = d + 1;
1150                         }
1151
1152                         if(autocvar_g_campaign && autocvar__campaign_testrun)
1153                                 d = d * tmp_entity.max_health;
1154                         else
1155                                 d = d * tmp_entity.max_health / max(30, 60 * autocvar_timelimit_suddendeath);
1156
1157                         Damage(tmp_entity, tmp_entity, tmp_entity, d, DEATH_HURTTRIGGER.m_id, tmp_entity.origin, '0 0 0');
1158
1159                         tmp_entity.sprite.SendFlags |= 16;
1160
1161                         tmp_entity.ons_overtime_damagedelay = time + 1;
1162                 }
1163         }
1164         else { wpforenemy_announced = false; ons_stalemate = false; }
1165
1166         Onslaught_count_generators();
1167
1168         if(ONS_OWNED_GENERATORS_OK())
1169                 return 0;
1170
1171         int winner_team = Onslaught_GetWinnerTeam();
1172
1173         if(winner_team > 0)
1174         {
1175                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
1176                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
1177                 TeamScore_AddToTeam(winner_team, ST_ONS_CAPS, +1);
1178         }
1179         else if(winner_team == -1)
1180         {
1181                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
1182                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
1183         }
1184
1185         ons_stalemate = false;
1186
1187         play2all(SND(CTF_CAPTURE(winner_team)));
1188
1189         round_handler_Init(7, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
1190
1191         FOREACH_CLIENT(IS_PLAYER(it), {
1192                 STAT(ROUNDLOST, it) = true;
1193                 it.player_blocked = true;
1194
1195                 nades_Clear(it);
1196         });
1197
1198         game_stopped = true;
1199         return 1;
1200 }
1201
1202 bool Onslaught_CheckPlayers()
1203 {
1204         return 1;
1205 }
1206
1207 void Onslaught_RoundStart()
1208 {
1209         entity tmp_entity;
1210         FOREACH_CLIENT(IS_PLAYER(it), it.player_blocked = false);
1211
1212         for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1213                 tmp_entity.sprite.SendFlags |= 16;
1214
1215         for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1216                 tmp_entity.sprite.SendFlags |= 16;
1217 }
1218
1219
1220 // ================
1221 // Bot player logic
1222 // ================
1223
1224 // NOTE: LEGACY CODE, needs to be re-written!
1225
1226 void havocbot_goalrating_ons_offenseitems(entity this, float ratingscale, vector org, float sradius)
1227 {
1228         bool needarmor = false, needweapons = false;
1229
1230         // Needs armor/health?
1231         if(this.health<100)
1232                 needarmor = true;
1233
1234         // Needs weapons?
1235         int c = 0;
1236         FOREACH(Weapons, it != WEP_Null, {
1237                 if(this.weapons & (it.m_wepset))
1238                 if(++c >= 4)
1239                         break;
1240         });
1241
1242         if(c<4)
1243                 needweapons = true;
1244
1245         if(!needweapons && !needarmor)
1246                 return;
1247
1248         LOG_DEBUG(this.netname, " needs weapons ", ftos(needweapons));
1249         LOG_DEBUG(this.netname, " needs armor ", ftos(needarmor));
1250
1251         // See what is around
1252         IL_EACH(g_items, it.bot_pickup,
1253         {
1254                 // gather health and armor only
1255                 if (it.solid)
1256                 if ( ((it.health || it.armorvalue) && needarmor) || (it.weapons && needweapons ) )
1257                 if (vdist(it.origin - org, <, sradius))
1258                 {
1259                         int t = it.bot_pickupevalfunc(this, it);
1260                         if (t > 0)
1261                                 navigation_routerating(this, it, t * ratingscale, 500);
1262                 }
1263         });
1264 }
1265
1266 void havocbot_role_ons_setrole(entity this, int role)
1267 {
1268         LOG_DEBUG(this.netname," switched to ");
1269         switch(role)
1270         {
1271                 case HAVOCBOT_ONS_ROLE_DEFENSE:
1272                         LOG_DEBUG("defense");
1273                         this.havocbot_role = havocbot_role_ons_defense;
1274                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_DEFENSE;
1275                         this.havocbot_role_timeout = 0;
1276                         break;
1277                 case HAVOCBOT_ONS_ROLE_ASSISTANT:
1278                         LOG_DEBUG("assistant");
1279                         this.havocbot_role = havocbot_role_ons_assistant;
1280                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_ASSISTANT;
1281                         this.havocbot_role_timeout = 0;
1282                         break;
1283                 case HAVOCBOT_ONS_ROLE_OFFENSE:
1284                         LOG_DEBUG("offense");
1285                         this.havocbot_role = havocbot_role_ons_offense;
1286                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_OFFENSE;
1287                         this.havocbot_role_timeout = 0;
1288                         break;
1289         }
1290         LOG_DEBUG("");
1291 }
1292
1293 void havocbot_goalrating_ons_controlpoints_attack(entity this, float ratingscale)
1294 {
1295         entity cp, cp1, cp2, best, wp;
1296         float radius, bestvalue;
1297         int c;
1298         bool found;
1299
1300         // Filter control points
1301         for(cp2 = ons_worldcplist; cp2; cp2 = cp2.ons_worldcpnext)
1302         {
1303                 cp2.wpcost = c = 0;
1304                 cp2.wpconsidered = false;
1305
1306                 if(cp2.isshielded)
1307                         continue;
1308
1309                 // Ignore owned controlpoints
1310                 if(!(cp2.isgenneighbor[this.team] || cp2.iscpneighbor[this.team]))
1311                         continue;
1312
1313                 // Count team mates interested in this control point
1314                 // (easier and cleaner than keeping counters per cp and teams)
1315                 FOREACH_CLIENT(IS_PLAYER(it), {
1316                         if(SAME_TEAM(it, this))
1317                         if(it.havocbot_role_flags & HAVOCBOT_ONS_ROLE_OFFENSE)
1318                         if(it.havocbot_ons_target == cp2)
1319                                 ++c;
1320                 });
1321
1322                 // NOTE: probably decrease the cost of attackable control points
1323                 cp2.wpcost = c;
1324                 cp2.wpconsidered = true;
1325         }
1326
1327         // We'll consider only the best case
1328         bestvalue = 99999999999;
1329         cp = NULL;
1330         for(cp1 = ons_worldcplist; cp1; cp1 = cp1.ons_worldcpnext)
1331         {
1332                 if (!cp1.wpconsidered)
1333                         continue;
1334
1335                 if(cp1.wpcost<bestvalue)
1336                 {
1337                         bestvalue = cp1.wpcost;
1338                         cp = cp1;
1339                         this.havocbot_ons_target = cp1;
1340                 }
1341         }
1342
1343         if (!cp)
1344                 return;
1345
1346         LOG_DEBUG(this.netname, " chose cp ranked ", ftos(bestvalue));
1347
1348         if(cp.goalentity)
1349         {
1350                 // Should be attacked
1351                 // Rate waypoints near it
1352                 found = false;
1353                 best = NULL;
1354                 bestvalue = 99999999999;
1355                 for(radius=0; radius<1000 && !found; radius+=500)
1356                 {
1357                         for(wp=findradius(cp.origin,radius); wp; wp=wp.chain)
1358                         {
1359                                 if(!(wp.wpflags & WAYPOINTFLAG_GENERATED))
1360                                 if(wp.classname=="waypoint")
1361                                 if(checkpvs(wp.origin,cp))
1362                                 {
1363                                         found = true;
1364                                         if(wp.cnt<bestvalue)
1365                                         {
1366                                                 best = wp;
1367                                                 bestvalue = wp.cnt;
1368                                         }
1369                                 }
1370                         }
1371                 }
1372
1373                 if(best)
1374                 {
1375                         navigation_routerating(this, best, ratingscale, 10000);
1376                         best.cnt += 1;
1377
1378                         this.havocbot_attack_time = 0;
1379                         if(checkpvs(this.view_ofs,cp))
1380                         if(checkpvs(this.view_ofs,best))
1381                                 this.havocbot_attack_time = time + 2;
1382                 }
1383                 else
1384                 {
1385                         navigation_routerating(this, cp, ratingscale, 10000);
1386                 }
1387                 LOG_DEBUG(this.netname, " found an attackable controlpoint at ", vtos(cp.origin));
1388         }
1389         else
1390         {
1391                 // Should be touched
1392                 LOG_DEBUG(this.netname, " found a touchable controlpoint at ", vtos(cp.origin));
1393                 found = false;
1394
1395                 // Look for auto generated waypoint
1396                 if (!bot_waypoints_for_items)
1397                 for (wp = findradius(cp.origin,100); wp; wp = wp.chain)
1398                 {
1399                         if(wp.classname=="waypoint")
1400                         {
1401                                 navigation_routerating(this, wp, ratingscale, 10000);
1402                                 found = true;
1403                         }
1404                 }
1405
1406                 // Nothing found, rate the controlpoint itself
1407                 if (!found)
1408                         navigation_routerating(this, cp, ratingscale, 10000);
1409         }
1410 }
1411
1412 bool havocbot_goalrating_ons_generator_attack(entity this, float ratingscale)
1413 {
1414         entity g, wp, bestwp;
1415         bool found;
1416         int best;
1417
1418         for(g = ons_worldgeneratorlist; g; g = g.ons_worldgeneratornext)
1419         {
1420                 if(SAME_TEAM(g, this) || g.isshielded)
1421                         continue;
1422
1423                 // Should be attacked
1424                 // Rate waypoints near it
1425                 found = false;
1426                 bestwp = NULL;
1427                 best = 99999999999;
1428
1429                 for(wp=findradius(g.origin,400); wp; wp=wp.chain)
1430                 {
1431                         if(wp.classname=="waypoint")
1432                         if(checkpvs(wp.origin,g))
1433                         {
1434                                 found = true;
1435                                 if(wp.cnt<best)
1436                                 {
1437                                         bestwp = wp;
1438                                         best = wp.cnt;
1439                                 }
1440                         }
1441                 }
1442
1443                 if(bestwp)
1444                 {
1445                         LOG_DEBUG("waypoints found around generator");
1446                         navigation_routerating(this, bestwp, ratingscale, 10000);
1447                         bestwp.cnt += 1;
1448
1449                         this.havocbot_attack_time = 0;
1450                         if(checkpvs(this.view_ofs,g))
1451                         if(checkpvs(this.view_ofs,bestwp))
1452                                 this.havocbot_attack_time = time + 5;
1453
1454                         return true;
1455                 }
1456                 else
1457                 {
1458                         LOG_DEBUG("generator found without waypoints around");
1459                         // if there aren't waypoints near the generator go straight to it
1460                         navigation_routerating(this, g, ratingscale, 10000);
1461                         this.havocbot_attack_time = 0;
1462                         return true;
1463                 }
1464         }
1465         return false;
1466 }
1467
1468 void havocbot_role_ons_offense(entity this)
1469 {
1470         if(IS_DEAD(this))
1471         {
1472                 this.havocbot_attack_time = 0;
1473                 havocbot_ons_reset_role(this);
1474                 return;
1475         }
1476
1477         // Set the role timeout if necessary
1478         if (!this.havocbot_role_timeout)
1479                 this.havocbot_role_timeout = time + 120;
1480
1481         if (time > this.havocbot_role_timeout)
1482         {
1483                 havocbot_ons_reset_role(this);
1484                 return;
1485         }
1486
1487         if(this.havocbot_attack_time>time)
1488                 return;
1489
1490         if (this.bot_strategytime < time)
1491         {
1492                 navigation_goalrating_start(this);
1493                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 650);
1494                 if(!havocbot_goalrating_ons_generator_attack(this, 20000))
1495                         havocbot_goalrating_ons_controlpoints_attack(this, 20000);
1496                 havocbot_goalrating_ons_offenseitems(this, 10000, this.origin, 10000);
1497                 navigation_goalrating_end(this);
1498
1499                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1500         }
1501 }
1502
1503 void havocbot_role_ons_assistant(entity this)
1504 {
1505         havocbot_ons_reset_role(this);
1506 }
1507
1508 void havocbot_role_ons_defense(entity this)
1509 {
1510         havocbot_ons_reset_role(this);
1511 }
1512
1513 void havocbot_ons_reset_role(entity this)
1514 {
1515         if(IS_DEAD(this))
1516                 return;
1517
1518         this.havocbot_ons_target = NULL;
1519
1520         // TODO: Defend control points or generator if necessary
1521
1522         havocbot_role_ons_setrole(this, HAVOCBOT_ONS_ROLE_OFFENSE);
1523 }
1524
1525
1526 /*
1527  * Find control point or generator owned by the same team self which is nearest to pos
1528  * if max_dist is positive, only control points within this range will be considered
1529  */
1530 entity ons_Nearest_ControlPoint(entity this, vector pos, float max_dist)
1531 {
1532         entity closest_target = NULL;
1533         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1534         {
1535                 if(SAME_TEAM(cp, this))
1536                 if(cp.iscaptured)
1537                 if(max_dist <= 0 || vdist(cp.origin - pos, <=, max_dist))
1538                 if(vlen2(cp.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1539                         closest_target = cp;
1540         }
1541         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1542         {
1543                 if(SAME_TEAM(gen, this))
1544                 if(max_dist <= 0 || vdist(gen.origin - pos, <, max_dist))
1545                 if(vlen2(gen.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1546                         closest_target = gen;
1547         }
1548
1549         return closest_target;
1550 }
1551
1552 /*
1553  * Find control point or generator owned by the same team self which is nearest to pos
1554  * if max_dist is positive, only control points within this range will be considered
1555  * This function only check distances on the XY plane, disregarding Z
1556  */
1557 entity ons_Nearest_ControlPoint_2D(entity this, vector pos, float max_dist)
1558 {
1559         entity closest_target = NULL;
1560         vector delta;
1561         float smallest_distance = 0, distance;
1562
1563         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1564         {
1565                 delta = cp.origin - pos;
1566                 delta_z = 0;
1567                 distance = vlen(delta);
1568
1569                 if(SAME_TEAM(cp, this))
1570                 if(cp.iscaptured)
1571                 if(max_dist <= 0 || distance <= max_dist)
1572                 if(closest_target == NULL || distance <= smallest_distance )
1573                 {
1574                         closest_target = cp;
1575                         smallest_distance = distance;
1576                 }
1577         }
1578         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1579         {
1580                 delta = gen.origin - pos;
1581                 delta_z = 0;
1582                 distance = vlen(delta);
1583
1584                 if(SAME_TEAM(gen, this))
1585                 if(max_dist <= 0 || distance <= max_dist)
1586                 if(closest_target == NULL || distance <= smallest_distance )
1587                 {
1588                         closest_target = gen;
1589                         smallest_distance = distance;
1590                 }
1591         }
1592
1593         return closest_target;
1594 }
1595 /**
1596  * find the number of control points and generators in the same team as this
1597  */
1598 int ons_Count_SelfControlPoints(entity this)
1599 {
1600         int n = 0;
1601         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1602         {
1603                 if(SAME_TEAM(cp, this))
1604                 if(cp.iscaptured)
1605                         n++;
1606         }
1607         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1608         {
1609                 if(SAME_TEAM(gen, this))
1610                         n++;
1611         }
1612         return n;
1613 }
1614
1615 /**
1616  * Teleport player to a random position near tele_target
1617  * if tele_effects is true, teleport sound+particles are created
1618  * return false on failure
1619  */
1620 bool ons_Teleport(entity player, entity tele_target, float range, bool tele_effects)
1621 {
1622         if ( !tele_target )
1623                 return false;
1624
1625         int i;
1626         vector loc;
1627         float theta;
1628         // narrow the range for each iteration to increase chances that a spawnpoint
1629         // can be found even if there's little room around the control point
1630         float iteration_scale = 1;
1631         for(i = 0; i < 16; ++i)
1632         {
1633                 iteration_scale -= i / 16;
1634                 theta = random() * 2 * M_PI;
1635                 loc_y = sin(theta);
1636                 loc_x = cos(theta);
1637                 loc_z = 0;
1638                 loc *= random() * range * iteration_scale;
1639
1640                 loc += tele_target.origin + '0 0 128' * iteration_scale;
1641
1642                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1643                 if(trace_fraction == 1.0 && !trace_startsolid)
1644                 {
1645                         traceline(tele_target.origin, loc, MOVE_NOMONSTERS, tele_target); // double check to make sure we're not spawning outside the NULL
1646                         if(trace_fraction == 1.0 && !trace_startsolid)
1647                         {
1648                                 if ( tele_effects )
1649                                 {
1650                                         Send_Effect(EFFECT_TELEPORT, player.origin, '0 0 0', 1);
1651                                         sound (player, CH_TRIGGER, SND_TELEPORT, VOL_BASE, ATTEN_NORM);
1652                                 }
1653                                 setorigin(player, loc);
1654                                 player.angles = '0 1 0' * ( theta * RAD2DEG + 180 );
1655                                 makevectors(player.angles);
1656                                 player.fixangle = true;
1657                                 player.teleport_antispam = time + autocvar_g_onslaught_teleport_wait;
1658
1659                                 if ( tele_effects )
1660                                         Send_Effect(EFFECT_TELEPORT, player.origin + v_forward * 32, '0 0 0', 1);
1661                                 return true;
1662                         }
1663                 }
1664         }
1665
1666         return false;
1667 }
1668
1669 // ==============
1670 // Hook Functions
1671 // ==============
1672
1673 MUTATOR_HOOKFUNCTION(ons, reset_map_global)
1674 {
1675         FOREACH_CLIENT(IS_PLAYER(it), {
1676                 STAT(ROUNDLOST, it) = false;
1677                 it.ons_deathloc = '0 0 0';
1678                 PutClientInServer(it);
1679                 it.clientcamera = it;
1680         });
1681         return false;
1682 }
1683
1684 MUTATOR_HOOKFUNCTION(ons, ClientDisconnect)
1685 {
1686         entity player = M_ARGV(0, entity);
1687
1688         player.ons_deathloc = '0 0 0';
1689 }
1690
1691 MUTATOR_HOOKFUNCTION(ons, MakePlayerObserver)
1692 {
1693         entity player = M_ARGV(0, entity);
1694
1695         player.ons_deathloc = '0 0 0';
1696 }
1697
1698 MUTATOR_HOOKFUNCTION(ons, PlayerSpawn)
1699 {
1700         entity player = M_ARGV(0, entity);
1701
1702         if(!round_handler_IsRoundStarted())
1703         {
1704                 player.player_blocked = true;
1705                 return false;
1706         }
1707
1708         entity l;
1709         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1710         {
1711                 l.sprite.SendFlags |= 16;
1712         }
1713         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1714         {
1715                 l.sprite.SendFlags |= 16;
1716         }
1717
1718         if(ons_stalemate) { Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT); }
1719
1720         if ( autocvar_g_onslaught_spawn_choose )
1721         if ( player.ons_spawn_by )
1722         if ( ons_Teleport(player,player.ons_spawn_by,autocvar_g_onslaught_teleport_radius,false) )
1723         {
1724                 player.ons_spawn_by = NULL;
1725                 return false;
1726         }
1727
1728         if(autocvar_g_onslaught_spawn_at_controlpoints)
1729         if(random() <= autocvar_g_onslaught_spawn_at_controlpoints_chance)
1730         {
1731                 float random_target = autocvar_g_onslaught_spawn_at_controlpoints_random;
1732                 entity tmp_entity, closest_target = NULL;
1733                 vector spawn_loc = player.ons_deathloc;
1734
1735                 // new joining player or round reset, don't bother checking
1736                 if(spawn_loc == '0 0 0') { return false; }
1737
1738                 if(random_target) { RandomSelection_Init(); }
1739
1740                 for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1741                 {
1742                         if(SAME_TEAM(tmp_entity, player))
1743                         if(random_target)
1744                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1745                         else if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1746                                 closest_target = tmp_entity;
1747                 }
1748
1749                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1750
1751                 if(closest_target)
1752                 {
1753                         float i;
1754                         vector loc;
1755                         float iteration_scale = 1;
1756                         for(i = 0; i < 10; ++i)
1757                         {
1758                                 iteration_scale -= i / 10;
1759                                 loc = closest_target.origin + '0 0 96' * iteration_scale;
1760                                 loc += ('0 1 0' * random()) * 128 * iteration_scale;
1761                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1762                                 if(trace_fraction == 1.0 && !trace_startsolid)
1763                                 {
1764                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1765                                         if(trace_fraction == 1.0 && !trace_startsolid)
1766                                         {
1767                                                 setorigin(player, loc);
1768                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1769                                                 return false;
1770                                         }
1771                                 }
1772                         }
1773                 }
1774         }
1775
1776         if(autocvar_g_onslaught_spawn_at_generator)
1777         if(random() <= autocvar_g_onslaught_spawn_at_generator_chance)
1778         {
1779                 float random_target = autocvar_g_onslaught_spawn_at_generator_random;
1780                 entity tmp_entity, closest_target = NULL;
1781                 vector spawn_loc = player.ons_deathloc;
1782
1783                 // new joining player or round reset, don't bother checking
1784                 if(spawn_loc == '0 0 0') { return false; }
1785
1786                 if(random_target) { RandomSelection_Init(); }
1787
1788                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1789                 {
1790                         if(random_target)
1791                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1792                         else
1793                         {
1794                                 if(SAME_TEAM(tmp_entity, player))
1795                                 if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1796                                         closest_target = tmp_entity;
1797                         }
1798                 }
1799
1800                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1801
1802                 if(closest_target)
1803                 {
1804                         float i;
1805                         vector loc;
1806                         float iteration_scale = 1;
1807                         for(i = 0; i < 10; ++i)
1808                         {
1809                                 iteration_scale -= i / 10;
1810                                 loc = closest_target.origin + '0 0 128' * iteration_scale;
1811                                 loc += ('0 1 0' * random()) * 256 * iteration_scale;
1812                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1813                                 if(trace_fraction == 1.0 && !trace_startsolid)
1814                                 {
1815                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1816                                         if(trace_fraction == 1.0 && !trace_startsolid)
1817                                         {
1818                                                 setorigin(player, loc);
1819                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1820                                                 return false;
1821                                         }
1822                                 }
1823                         }
1824                 }
1825         }
1826
1827         return false;
1828 }
1829
1830 MUTATOR_HOOKFUNCTION(ons, PlayerDies)
1831 {
1832         entity frag_target = M_ARGV(2, entity);
1833
1834         frag_target.ons_deathloc = frag_target.origin;
1835         entity l;
1836         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1837         {
1838                 l.sprite.SendFlags |= 16;
1839         }
1840         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1841         {
1842                 l.sprite.SendFlags |= 16;
1843         }
1844
1845         if ( autocvar_g_onslaught_spawn_choose )
1846         if ( ons_Count_SelfControlPoints(frag_target) > 1 )
1847                 stuffcmd(frag_target, "qc_cmd_cl hud clickradar\n");
1848
1849         return false;
1850 }
1851
1852 MUTATOR_HOOKFUNCTION(ons, MonsterMove)
1853 {
1854         entity mon = M_ARGV(0, entity);
1855
1856         entity e = find(NULL, targetname, mon.target);
1857         if (e != NULL)
1858                 mon.team = e.team;
1859 }
1860
1861 void ons_MonsterSpawn_Delayed(entity this)
1862 {
1863         entity own = this.owner;
1864
1865         if(!own) { delete(this); return; }
1866
1867         if(own.targetname)
1868         {
1869                 entity e = find(NULL, target, own.targetname);
1870                 if(e != NULL)
1871                 {
1872                         own.team = e.team;
1873
1874                         own.use(own, e, NULL);
1875                 }
1876         }
1877
1878         delete(this);
1879 }
1880
1881 MUTATOR_HOOKFUNCTION(ons, MonsterSpawn)
1882 {
1883         entity mon = M_ARGV(0, entity);
1884
1885         entity e = spawn();
1886         e.owner = mon;
1887         InitializeEntity(e, ons_MonsterSpawn_Delayed, INITPRIO_FINDTARGET);
1888 }
1889
1890 void ons_TurretSpawn_Delayed(entity this)
1891 {
1892         entity own = this.owner;
1893
1894         if(!own) { delete(this); return; }
1895
1896         if(own.targetname)
1897         {
1898                 entity e = find(NULL, target, own.targetname);
1899                 if(e != NULL)
1900                 {
1901                         own.team = e.team;
1902                         own.active = ACTIVE_NOT;
1903
1904                         own.use(own, e, NULL);
1905                 }
1906         }
1907
1908         delete(this);
1909 }
1910
1911 MUTATOR_HOOKFUNCTION(ons, TurretSpawn)
1912 {
1913         entity turret = M_ARGV(0, entity);
1914
1915         entity e = spawn();
1916         e.owner = turret;
1917         InitializeEntity(e, ons_TurretSpawn_Delayed, INITPRIO_FINDTARGET);
1918
1919         return false;
1920 }
1921
1922 MUTATOR_HOOKFUNCTION(ons, HavocBot_ChooseRole)
1923 {
1924         entity bot = M_ARGV(0, entity);
1925
1926         havocbot_ons_reset_role(bot);
1927         return true;
1928 }
1929
1930 MUTATOR_HOOKFUNCTION(ons, CheckAllowedTeams)
1931 {
1932         // onslaught is special
1933         for(entity tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1934         {
1935                 switch(tmp_entity.team)
1936                 {
1937                         case NUM_TEAM_1: c1 = 0; break;
1938                         case NUM_TEAM_2: c2 = 0; break;
1939                         case NUM_TEAM_3: c3 = 0; break;
1940                         case NUM_TEAM_4: c4 = 0; break;
1941                 }
1942         }
1943
1944         return true;
1945 }
1946
1947 MUTATOR_HOOKFUNCTION(ons, SpectateCopy)
1948 {
1949         entity spectatee = M_ARGV(0, entity);
1950         entity client = M_ARGV(1, entity);
1951
1952         STAT(ROUNDLOST, client) = STAT(ROUNDLOST, spectatee); // make spectators see it too
1953 }
1954
1955 MUTATOR_HOOKFUNCTION(ons, SV_ParseClientCommand)
1956 {
1957         if(MUTATOR_RETURNVALUE) // command was already handled?
1958                 return false;
1959
1960         entity player = M_ARGV(0, entity);
1961         string cmd_name = M_ARGV(1, string);
1962         int cmd_argc = M_ARGV(2, int);
1963
1964         if ( cmd_name == "ons_spawn" )
1965         {
1966                 vector pos = player.origin;
1967                 if(cmd_argc > 1)
1968                         pos_x = stof(argv(1));
1969                 if(cmd_argc > 2)
1970                         pos_y = stof(argv(2));
1971                 if(cmd_argc > 3)
1972                         pos_z = stof(argv(3));
1973
1974                 if ( IS_PLAYER(player) )
1975                 {
1976                         if ( !STAT(FROZEN, player) )
1977                         {
1978                                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
1979
1980                                 if ( !source_point && player.health > 0 )
1981                                 {
1982                                         sprint(player, "\nYou need to be next to a control point\n");
1983                                         return true;
1984                                 }
1985
1986
1987                                 entity closest_target = ons_Nearest_ControlPoint_2D(player, pos, autocvar_g_onslaught_click_radius);
1988
1989                                 if ( closest_target == NULL )
1990                                 {
1991                                         sprint(player, "\nNo control point found\n");
1992                                         return true;
1993                                 }
1994
1995                                 if ( player.health <= 0 )
1996                                 {
1997                                         player.ons_spawn_by = closest_target;
1998                                         player.respawn_flags = player.respawn_flags | RESPAWN_FORCE;
1999                                 }
2000                                 else
2001                                 {
2002                                         if ( source_point == closest_target )
2003                                         {
2004                                                 sprint(player, "\nTeleporting to the same point\n");
2005                                                 return true;
2006                                         }
2007
2008                                         if ( !ons_Teleport(player,closest_target,autocvar_g_onslaught_teleport_radius,true) )
2009                                                 sprint(player, "\nUnable to teleport there\n");
2010                                 }
2011
2012                                 return true;
2013                         }
2014
2015                         sprint(player, "\nNo teleportation for you\n");
2016                 }
2017
2018                 return true;
2019         }
2020         return false;
2021 }
2022
2023 MUTATOR_HOOKFUNCTION(ons, PlayerUseKey)
2024 {
2025         if(MUTATOR_RETURNVALUE || game_stopped) return false;
2026
2027         entity player = M_ARGV(0, entity);
2028
2029         if((time > player.teleport_antispam) && (!IS_DEAD(player)) && !player.vehicle)
2030         {
2031                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
2032                 if ( source_point )
2033                 {
2034                         stuffcmd(player, "qc_cmd_cl hud clickradar\n");
2035                         return true;
2036                 }
2037         }
2038 }
2039
2040 MUTATOR_HOOKFUNCTION(ons, PlayHitsound)
2041 {
2042         entity frag_victim = M_ARGV(0, entity);
2043
2044         return (frag_victim.classname == "onslaught_generator" && !frag_victim.isshielded)
2045                 || (frag_victim.classname == "onslaught_controlpoint_icon" && !frag_victim.owner.isshielded);
2046 }
2047
2048 MUTATOR_HOOKFUNCTION(ons, SendWaypoint)
2049 {
2050     entity wp = M_ARGV(0, entity);
2051     entity to = M_ARGV(1, entity);
2052     int sf = M_ARGV(2, int);
2053     int wp_flag = M_ARGV(3, int);
2054
2055         if(sf & 16)
2056         {
2057                 if(wp.owner.classname == "onslaught_controlpoint")
2058                 {
2059                         entity wp_owner = wp.owner;
2060                         entity e = WaypointSprite_getviewentity(to);
2061                         if(SAME_TEAM(e, wp_owner) && wp_owner.goalentity.health >= wp_owner.goalentity.max_health) { wp_flag |= 2; }
2062                         if(!ons_ControlPoint_Attackable(wp_owner, e.team)) { wp_flag |= 2; }
2063                 }
2064                 if(wp.owner.classname == "onslaught_generator")
2065                 {
2066                         entity wp_owner = wp.owner;
2067                         if(wp_owner.isshielded && wp_owner.health >= wp_owner.max_health) { wp_flag |= 2; }
2068                         if(wp_owner.health <= 0) { wp_flag |= 2; }
2069                 }
2070         }
2071
2072         M_ARGV(3, int) = wp_flag;
2073 }
2074
2075 MUTATOR_HOOKFUNCTION(ons, TurretValidateTarget)
2076 {
2077         entity turret_target = M_ARGV(1, entity);
2078
2079         if(substring(turret_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
2080         {
2081                 M_ARGV(3, float) = -3;
2082                 return true;
2083         }
2084
2085         return false;
2086 }
2087
2088 MUTATOR_HOOKFUNCTION(ons, TurretThink)
2089 {
2090     entity turret = M_ARGV(0, entity);
2091
2092         // ONS uses somewhat backwards linking.
2093         if(turret.target)
2094         {
2095                 entity e = find(NULL, targetname, turret.target);
2096                 if (e != NULL)
2097                         turret.team = e.team;
2098         }
2099
2100         if(turret.team != turret.tur_head.team)
2101                 turret_respawn(turret);
2102 }
2103
2104
2105 // ==========
2106 // Spawnfuncs
2107 // ==========
2108
2109 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
2110   Link between control points.
2111
2112   This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
2113
2114 keys:
2115 "target" - first control point.
2116 "target2" - second control point.
2117  */
2118 spawnfunc(onslaught_link)
2119 {
2120         if(!g_onslaught) { delete(this); return; }
2121
2122         if (this.target == "" || this.target2 == "")
2123                 objerror(this, "target and target2 must be set\n");
2124
2125         this.ons_worldlinknext = ons_worldlinklist; // link into ons_worldlinklist
2126         ons_worldlinklist = this;
2127
2128         InitializeEntity(this, ons_DelayedLinkSetup, INITPRIO_FINDTARGET);
2129         Net_LinkEntity(this, false, 0, ons_Link_Send);
2130 }
2131
2132 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
2133   Control point. Be sure to give this enough clearance so that the shootable part has room to exist
2134
2135   This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
2136
2137 keys:
2138 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2139 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
2140 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
2141  */
2142
2143 spawnfunc(onslaught_controlpoint)
2144 {
2145         if(!g_onslaught) { delete(this); return; }
2146
2147         ons_ControlPoint_Setup(this);
2148 }
2149
2150 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
2151   Base generator.
2152
2153   spawnfunc_onslaught_link entities can target this.
2154
2155 keys:
2156 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
2157 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2158  */
2159 spawnfunc(onslaught_generator)
2160 {
2161         if(!g_onslaught) { delete(this); return; }
2162         if(!this.team) { objerror(this, "team must be set"); }
2163
2164         ons_GeneratorSetup(this);
2165 }
2166
2167 // scoreboard setup
2168 void ons_ScoreRules()
2169 {
2170         CheckAllowedTeams(NULL);
2171         int teams = 0;
2172         if(c1 >= 0) teams |= BIT(0);
2173         if(c2 >= 0) teams |= BIT(1);
2174         if(c3 >= 0) teams |= BIT(2);
2175         if(c4 >= 0) teams |= BIT(3);
2176         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, 0, true);
2177         ScoreInfo_SetLabel_TeamScore  (ST_ONS_CAPS,     "destroyed", SFL_SORT_PRIO_PRIMARY);
2178         ScoreInfo_SetLabel_PlayerScore(SP_ONS_CAPS,    "caps",      SFL_SORT_PRIO_SECONDARY);
2179         ScoreInfo_SetLabel_PlayerScore(SP_ONS_TAKES,    "takes",     0);
2180         ScoreRules_basics_end();
2181 }
2182
2183 void ons_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up
2184 {
2185         ons_ScoreRules();
2186
2187         round_handler_Spawn(Onslaught_CheckPlayers, Onslaught_CheckWinner, Onslaught_RoundStart);
2188         round_handler_Init(5, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
2189 }
2190
2191 void ons_Initialize()
2192 {
2193         g_onslaught = true;
2194         ons_captureshield_force = autocvar_g_onslaught_shield_force;
2195
2196         cam = new(objective_camera);
2197
2198         InitializeEntity(NULL, ons_DelayedInit, INITPRIO_GAMETYPE);
2199 }