qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(s == "")
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  57         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  58 }
  59
  60 float MapInfo_Cache_Retrieve(string map)
  61 {
  62         float i;
  63         string s;
  64         if(!_MapInfo_Cache_Active)
  65                 return 0;
  66
  67         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  68         if(s == "")
  69                 return 0;
  70         i = stof(s);
  71
  72         // now retrieve all the stuff
  73         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  74         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  77         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  78         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  80         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  81
  82         return 1;
  83 }
  84
  85 // GLOB HANDLING (for all BSP files)
  86 float _MapInfo_globopen;
  87 float _MapInfo_globcount;
  88 float _MapInfo_globhandle;
  89 string _MapInfo_GlobItem(float i)
  90 {
  91         string s;
  92         if(!_MapInfo_globopen)
  93                 return string_null;
  94         s = search_getfilename(_MapInfo_globhandle, i);
  95         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  96 }
  97
  98 void MapInfo_Enumerate()
  99 {
 100         if(_MapInfo_globopen)
 101         {
 102                 search_end(_MapInfo_globhandle);
 103                 _MapInfo_globopen = 0;
 104         }
 105         MapInfo_Cache_Invalidate();
 106         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 107         if(_MapInfo_globhandle >= 0)
 108         {
 109                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 110                 _MapInfo_globopen = 1;
 111         }
 112         else
 113                 _MapInfo_globcount = 0;
 114 }
 115
 116 // filter the info by game type mask (updates MapInfo_count)
 117 //
 118 float _MapInfo_filtered;
 119 float _MapInfo_filtered_allocated;
 120 float MapInfo_FilterList_Lookup(float i)
 121 {
 122         return stof(bufstr_get(_MapInfo_filtered, i));
 123 }
 124
 125 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 126 {
 127         string h;
 128         h = bufstr_get(_MapInfo_filtered, i);
 129         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 130         bufstr_set(_MapInfo_filtered, j, h);
 131 }
 132
 133 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 134 {
 135         string a, b;
 136         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 137         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 138         return strcasecmp(a, b);
 139 }
 140
 141 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 142 {
 143         float i, j;
 144         if (!_MapInfo_filtered_allocated)
 145         {
 146                 _MapInfo_filtered_allocated = 1;
 147                 _MapInfo_filtered = buf_create();
 148         }
 149         MapInfo_count = 0;
 150         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 151         {
 152                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 153                         if(pAbortOnGenerate)
 154                         {
 155                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 156                                 MapInfo_progress = i / _MapInfo_globcount;
 157                                 return 0;
 158                         }
 159                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 160                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 161                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 162                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 163                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 164         }
 165         MapInfo_count = j + 1;
 166         MapInfo_ClearTemps();
 167
 168         // sometimes the glob isn't sorted nicely, so fix it here...
 169         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 170
 171         return 1;
 172 }
 173
 174 void MapInfo_Filter_Free()
 175 {
 176         if(_MapInfo_filtered_allocated)
 177         {
 178                 buf_del(_MapInfo_filtered);
 179                 _MapInfo_filtered_allocated = 0;
 180         }
 181 }
 182
 183 // load info about the i-th map into the MapInfo_Map_* globals
 184 string MapInfo_BSPName_ByID(float i)
 185 {
 186         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 187 }
 188
 189 string unquote(string s)
 190 {
 191         float i, j, l;
 192         l = strlen(s);
 193         j = -1;
 194         for(i = 0; i < l; ++i)
 195         {
 196                 string ch;
 197                 ch = substring(s, i, 1);
 198                 if(ch != " ") if(ch != "\"")
 199                 {
 200                         for(j = strlen(s) - i - 1; j > 0; --j)
 201                         {
 202                                 ch = substring(s, i+j, 1);
 203                                 if(ch != " ") if(ch != "\"")
 204                                         return substring(s, i, j+1);
 205                         }
 206                         return substring(s, i, 1);
 207                 }
 208         }
 209         return "";
 210 }
 211
 212 float MapInfo_Get_ByID(float i)
 213 {
 214         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 215                 return 1;
 216         return 0;
 217 }
 218
 219 string _MapInfo_Map_worldspawn_music;
 220
 221 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 222 {
 223         string fn;
 224         float fh;
 225         string s, k, v;
 226         vector o;
 227         float i;
 228         float inWorldspawn;
 229         float r;
 230         float twoBaseModes;
 231         float diameter, spawnpoints;
 232         float spawnplaces;
 233
 234         vector mapMins, mapMaxs;
 235
 236         r = 1;
 237         fn = strcat("maps/", pFilename, ".ent");
 238         fh = fopen(fn, FILE_READ);
 239         if(fh < 0)
 240         {
 241                 r = 2;
 242                 fn = strcat("maps/", pFilename, ".bsp");
 243                 fh = fopen(fn, FILE_READ);
 244         }
 245         if(fh < 0)
 246                 return 0;
 247         print("Analyzing ", fn, " to generate initial mapinfo\n");
 248
 249         inWorldspawn = 2;
 250         MapInfo_Map_flags = 0;
 251         MapInfo_Map_supportedGametypes = 0;
 252         spawnpoints = 0;
 253         spawnplaces = 0;
 254         _MapInfo_Map_worldspawn_music = "";
 255         mapMins = '0 0 0';
 256         mapMaxs = '0 0 0';
 257
 258         for(;;)
 259         {
 260                 if (!((s = fgets(fh))))
 261                         break;
 262                 if(inWorldspawn == 1)
 263                         if(startsWith(s, "}"))
 264                                 inWorldspawn = 0;
 265                 k = unquote(car(s));
 266                 v = unquote(cdr(s));
 267                 if(inWorldspawn)
 268                 {
 269                         if(k == "classname" && v == "worldspawn")
 270                                 inWorldspawn = 1;
 271                         else if(k == "author")
 272                                 MapInfo_Map_author = v;
 273                         else if(k == "_description")
 274                                 MapInfo_Map_description = v;
 275                         else if(k == "music")
 276                                 _MapInfo_Map_worldspawn_music = v;
 277                         else if(k == "noise")
 278                                 _MapInfo_Map_worldspawn_music = v;
 279                         else if(k == "message")
 280                         {
 281                                 i = strstrofs(v, " by ", 0);
 282                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 283                                 {
 284                                         MapInfo_Map_title = substring(v, 0, i);
 285                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 286                                 }
 287                                 else
 288                                         MapInfo_Map_title = v;
 289                         }
 290                 }
 291                 else
 292                 {
 293                         if(k == "origin")
 294                         {
 295                                 o = stov(strcat("'", v, "'"));
 296                                 mapMins_x = min(mapMins_x, o_x);
 297                                 mapMins_y = min(mapMins_y, o_y);
 298                                 mapMins_z = min(mapMins_z, o_z);
 299                                 mapMaxs_x = max(mapMaxs_x, o_x);
 300                                 mapMaxs_y = max(mapMaxs_y, o_y);
 301                                 mapMaxs_z = max(mapMaxs_z, o_z);
 302                         }
 303                         else if(k == "race_place")
 304                         {
 305                                 if(stof(v) > 0)
 306                                         spawnplaces = 1;
 307                         }
 308                         else if(k == "classname")
 309                         {
 310                                 if(v == "dom_controlpoint")
 311                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 312                                 else if(v == "item_flag_team2")
 313                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 314                                 else if(v == "team_CTF_blueflag")
 315                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 316                                 else if(v == "invasion_spawnpoint")
 317                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_INVASION;
 318                                 else if(v == "target_assault_roundend")
 319                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 320                                 else if(v == "onslaught_generator")
 321                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 322                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 323                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 324                                 else if(v == "info_player_team1")
 325                                         ++spawnpoints;
 326                                 else if(v == "info_player_team2")
 327                                         ++spawnpoints;
 328                                 else if(v == "info_player_start")
 329                                         ++spawnpoints;
 330                                 else if(v == "info_player_deathmatch")
 331                                         ++spawnpoints;
 332                                 else if(v == "trigger_race_checkpoint")
 333                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 334                                 else if(v == "target_startTimer")
 335                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 336                                 else if(v == "weapon_nex")
 337                                         { }
 338                                 else if(v == "weapon_railgun")
 339                                         { }
 340                                 else if(startsWith(v, "weapon_"))
 341                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 342                                 else if(startsWith(v, "turret_"))
 343                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 344                                 else if(startsWith(v, "vehicle_"))
 345                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 346                                 else if(v == "target_music" || v == "trigger_music")
 347                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 348                         }
 349                 }
 350         }
 351         if(inWorldspawn)
 352         {
 353                 print(fn, " ended still in worldspawn, BUG\n");
 354                 return 0;
 355         }
 356         diameter = vlen(mapMaxs - mapMins);
 357
 358         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 359         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 360         {
 361                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 362                 // as the map is too symmetric for them.
 363         }
 364         else
 365         {
 366                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 367                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 368                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 369
 370                 if(spawnpoints >= 8  && diameter > 4096) {
 371                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 372                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 373                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 374                 }
 375                 if(spawnpoints >= 12 && diameter > 5120)
 376                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 377         }
 378
 379         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 380         if(!spawnplaces)
 381         {
 382                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE;
 383                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 384         }
 385
 386         dprint("-> diameter ",    ftos(diameter));
 387         dprint(";  spawnpoints ", ftos(spawnpoints));
 388         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 389
 390         fclose(fh);
 391
 392         return r;
 393 }
 394
 395 void _MapInfo_Map_Reset()
 396 {
 397         MapInfo_Map_title = "<TITLE>";
 398         MapInfo_Map_titlestring = "<TITLE>";
 399         MapInfo_Map_description = "<DESCRIPTION>";
 400         MapInfo_Map_author = "<AUTHOR>";
 401         MapInfo_Map_supportedGametypes = 0;
 402         MapInfo_Map_supportedFeatures = 0;
 403         MapInfo_Map_flags = 0;
 404         MapInfo_Map_clientstuff = "";
 405         MapInfo_Map_fog = "";
 406         MapInfo_Map_mins = '0 0 0';
 407         MapInfo_Map_maxs = '0 0 0';
 408 }
 409
 410 string _MapInfo_GetDefault(float t)
 411 {
 412         switch(t)
 413         {
 414                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 415                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 416                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 417                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 418                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 419                 case MAPINFO_TYPE_CA:              return "10 20 0";
 420                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 421                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 422                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 423                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 424                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 425                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 426                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 427                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 428                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 429                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 430                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 431                 default:                           return "";
 432         }
 433 }
 434
 435 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
 436 {
 437         string sa;
 438         MapInfo_Map_supportedGametypes |= pThisType;
 439         if(!(pThisType & pWantedType))
 440                 return;
 441
 442         if(load_default)
 443                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
 444
 445         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 446         {
 447                 cvar_set("fraglimit", "0");
 448         }
 449         else
 450         {
 451                 sa = car(s);
 452                 if(sa != "")
 453                         cvar_set("fraglimit", sa);
 454                 s = cdr(s);
 455         }
 456
 457         sa = car(s);
 458         if(sa != "")
 459                 cvar_set("timelimit", sa);
 460         s = cdr(s);
 461
 462         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 463         {
 464                 sa = car(s);
 465                 if(sa != "")
 466                         cvar_set("g_tdm_teams", sa);
 467                 s = cdr(s);
 468         }
 469
 470         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 471         {
 472                 sa = car(s);
 473                 if(sa != "")
 474                         cvar_set("g_keyhunt_teams", sa);
 475                 s = cdr(s);
 476         }
 477
 478         if(pWantedType == MAPINFO_TYPE_CA)
 479         {
 480                 sa = car(s);
 481                 if(sa != "")
 482                         cvar_set("g_ca_teams", sa);
 483                 s = cdr(s);
 484         }
 485
 486         if(pWantedType == MAPINFO_TYPE_FREEZETAG)
 487         {
 488                 sa = car(s);
 489                 if(sa != "")
 490                         cvar_set("g_freezetag_teams", sa);
 491                 s = cdr(s);
 492         }
 493
 494         if(pWantedType == MAPINFO_TYPE_CTF)
 495         {
 496                 sa = car(s);
 497                 if(sa != "")
 498                         cvar_set("fraglimit", sa);
 499                 s = cdr(s);
 500         }
 501
 502         /* keepaway wuz here
 503         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 504         {
 505                 sa = car(s);
 506                 if(sa != "")
 507                         cvar_set("fraglimit", sa);
 508                 s = cdr(s);
 509         }
 510         */
 511
 512         // rc = timelimit timelimit_qualification laps laps_teamplay
 513         if(pWantedType == MAPINFO_TYPE_RACE)
 514         {
 515                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 516                 cvar_set("g_race_qualifying_timelimit", sa);
 517                 s = cdr(s);
 518
 519                 sa = car(s);
 520                 if(sa != "")
 521                         if(cvar("g_race_teams") < 2)
 522                                 cvar_set("fraglimit", sa);
 523                 s = cdr(s);
 524
 525                 sa = car(s);
 526                 if(sa != "")
 527                         if(cvar("g_race_teams") >= 2)
 528                                 cvar_set("fraglimit", sa);
 529                 s = cdr(s);
 530         }
 531
 532         if(pWantedType == MAPINFO_TYPE_CTS)
 533         {
 534                 sa = car(s);
 535
 536                 // this is the skill of the map
 537                 // not parsed by anything yet
 538                 // for map databases
 539                 //if(sa != "")
 540                 //      cvar_set("fraglimit", sa);
 541
 542                 s = cdr(s);
 543         }
 544
 545         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 546         {
 547                 cvar_set("leadlimit", "0");
 548         }
 549         else
 550         {
 551                 sa = car(s);
 552                 if(sa != "")
 553                         cvar_set("leadlimit", sa);
 554                 s = cdr(s);
 555         }
 556 }
 557
 558 string _MapInfo_GetDefaultEx(float t)
 559 {
 560         entity e;
 561         for(e = MapInfo_Type_first; e; e = e.enemy)
 562                 if(t == e.items)
 563                         return e.model2;
 564         return "";
 565 }
 566
 567 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
 568 {
 569         string sa, k, v;
 570         float p;
 571         string fraglimit_normal;
 572         string fraglimit_teams;
 573
 574         MapInfo_Map_supportedGametypes |= pThisType;
 575         if(!(pThisType & pWantedType))
 576                 return;
 577
 578         // reset all the cvars to their defaults
 579
 580         cvar_set("timelimit", cvar_defstring("timelimit"));
 581         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 582         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 583         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 584         cvar_set("g_ca_teams", cvar_defstring("g_ca_teams"));
 585         cvar_set("g_freezetag_teams", cvar_defstring("g_freezetag_teams"));
 586         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 587         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 588         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 589
 590         fraglimit_normal = string_null;
 591         fraglimit_teams = string_null;
 592
 593         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
 594         while(s != "")
 595         {
 596                 sa = car(s);
 597                 s = cdr(s);
 598
 599                 if(sa == "")
 600                         continue;
 601
 602                 p = strstrofs(sa, "=", 0);
 603                 if(p < 0)
 604                 {
 605                         print("Invalid gametype setting in mapinfo for gametype ", MapInfo_Type_ToString(pWantedType), ": ", sa, "\n");
 606                         continue;
 607                 }
 608                 k = substring(sa, 0, p);
 609                 v = substring(sa, p+1, -1);
 610
 611                 if(k == "timelimit")
 612                 {
 613                         cvar_set("timelimit", v);
 614                 }
 615                 else if(k == "leadlimit")
 616                 {
 617                         cvar_set("leadlimit", v);
 618                 }
 619                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit" || k == "caplimit")
 620                 {
 621                         fraglimit_normal = v;
 622                 }
 623                 else if(k == "teampointlimit" || k == "teamlaplimit")
 624                 {
 625                         fraglimit_teams = v;
 626                 }
 627                 else if(k == "teams")
 628                 {
 629                         cvar_set("g_tdm_teams", v);
 630                         cvar_set("g_ca_teams", v);
 631                         cvar_set("g_freezetag_teams", v);
 632                         cvar_set("g_keyhunt_teams", v);
 633                         cvar_set("g_domination_default_teams", v);
 634                 }
 635                 else if(k == "qualifying_timelimit")
 636                 {
 637                         cvar_set("g_race_qualifying_timelimit", v);
 638                 }
 639                 else if(k == "skill")
 640                 {
 641                         // ignore
 642                 }
 643                 else
 644                 {
 645                         print("Invalid gametype setting in mapinfo for gametype ", MapInfo_Type_ToString(pWantedType), ": ", sa, "\n");
 646                 }
 647         }
 648
 649         if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 650         {
 651                 if(fraglimit_teams)
 652                         cvar_set("fraglimit", fraglimit_teams);
 653         }
 654         else
 655         {
 656                 if(fraglimit_normal)
 657                         cvar_set("fraglimit", fraglimit_normal);
 658         }
 659 }
 660
 661 float MapInfo_Type_FromString(string t)
 662 {
 663         entity e;
 664         if(t == "nexball")
 665         {
 666                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 667                 t = "nb";
 668                 print("'. Should use '", t, "'.\n");
 669         }
 670         if(t == "freezetag")
 671         {
 672                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 673                 t = "ft";
 674                 print("'. Should use '", t, "'.\n");
 675         }
 676         if(t == "keepaway")
 677         {
 678                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 679                 t = "ka";
 680                 print("'. Should use '", t, "'.\n");
 681         }
 682         if(t == "invasion")
 683         {
 684                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 685                 t = "inv";
 686                 print("'. Should use '", t, "'.\n");
 687         }
 688         if(t == "all")
 689                 return MAPINFO_TYPE_ALL;
 690         for(e = MapInfo_Type_first; e; e = e.enemy)
 691                 if(t == e.mdl)
 692                         return e.items;
 693         return 0;
 694 }
 695
 696 string MapInfo_Type_Description(float t)
 697 {
 698         entity e;
 699         for(e = MapInfo_Type_first; e; e = e.enemy)
 700                 if(t == e.items)
 701                         return e.gametype_description;
 702         return "";
 703 }
 704
 705 string MapInfo_Type_ToString(float t)
 706 {
 707         entity e;
 708         if(t == MAPINFO_TYPE_ALL)
 709                 return "all";
 710         for(e = MapInfo_Type_first; e; e = e.enemy)
 711                 if(t == e.items)
 712                         return e.mdl;
 713         return "";
 714 }
 715
 716 string MapInfo_Type_ToText(float t)
 717 {
 718         entity e;
 719         for(e = MapInfo_Type_first; e; e = e.enemy)
 720                 if(t == e.items)
 721                         return e.message;
 722         /* xgettext:no-c-format */
 723         return _("@!#%'n Tuba Throwing");
 724 }
 725
 726 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 727 {
 728         string t;
 729         float fh, o;
 730         t = car(s); s = cdr(s);
 731
 732         // limited support of "" and comments
 733         //   remove trailing and leading " of t
 734         if(substring(t, 0, 1) == "\"")
 735         {
 736                 if(substring(t, -1, 1) == "\"")
 737                         t = substring(t, 1, -2);
 738         }
 739
 740         //   remove leading " of s
 741         if(substring(s, 0, 1) == "\"")
 742         {
 743                 s = substring(s, 1, -1);
 744         }
 745         //   remove trailing " of s, and all that follows (cvar description)
 746         o = strstrofs(s, "\"", 0);
 747         if(o >= 0)
 748                 s = substring(s, 0, o);
 749
 750         //   remove // comments
 751         o = strstrofs(s, "//", 0);
 752         if(o >= 0)
 753                 s = substring(s, 0, o);
 754
 755         //   remove trailing spaces
 756         while(substring(s, -1, 1) == " ")
 757                 s = substring(s, 0, -2);
 758
 759         if(t == "#include")
 760         {
 761                 if(recurse > 0)
 762                 {
 763                         fh = fopen(s, FILE_READ);
 764                         if(fh < 0)
 765                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 766                         else
 767                         {
 768                                 for(;;)
 769                                 {
 770                                         if (!((s = fgets(fh))))
 771                                                 break;
 772
 773                                         // catch different sorts of comments
 774                                         if(s == "")                    // empty lines
 775                                                 continue;
 776                                         if(substring(s, 0, 1) == "#")  // UNIX style
 777                                                 continue;
 778                                         if(substring(s, 0, 2) == "//") // C++ style
 779                                                 continue;
 780                                         if(substring(s, 0, 1) == "_")  // q3map style
 781                                                 continue;
 782
 783                                         if(substring(s, 0, 4) == "set ")
 784                                                 s = substring(s, 4, -1);
 785                                         if(substring(s, 0, 5) == "seta ")
 786                                                 s = substring(s, 5, -1);
 787
 788                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 789                                 }
 790                                 fclose(fh);
 791                         }
 792                 }
 793                 else
 794                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 795         }
 796         else if(t == "")
 797                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 798         else if (!cvar_value_issafe(t))
 799                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 800         else if (!cvar_value_issafe(s))
 801                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 802         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 803                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 804         else if(matchacl(acl, t) <= 0)
 805                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 806         else
 807         {
 808                 if(type == 0) // server set
 809                 {
 810                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 811                         if(cvar("g_campaign"))
 812                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 813                         else
 814                                 cvar_settemp(t, s);
 815                 }
 816                 else
 817                 {
 818                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 819                         MapInfo_Map_clientstuff = strcat(
 820                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 821                                         );
 822                 }
 823         }
 824 }
 825
 826 float MapInfo_isRedundant(string fn, string t)
 827 {
 828         // normalize file name
 829         fn = strreplace("_", "-", fn);
 830
 831         // normalize visible title
 832         t = strreplace(": ", "-", t);
 833         t = strreplace(":", "-", t);
 834         t = strreplace(" ", "-", t);
 835         t = strreplace("_", "-", t);
 836         t = strreplace("'", "-", t);
 837
 838         if(!strcasecmp(fn, t))
 839                 return TRUE;
 840
 841         // we allow the visible title to have punctuation the file name does
 842         // not, but not vice versa
 843         t = strreplace("-", "", t);
 844
 845         if(!strcasecmp(fn, t))
 846                 return TRUE;
 847
 848         return FALSE;
 849 }
 850
 851 // load info about a map by name into the MapInfo_Map_* globals
 852 float MapInfo_Get_ByName_NoFallbacks(string pFilename, float pAllowGenerate, float pGametypeToSet)
 853 {
 854         string fn;
 855         string s, t;
 856         float fh;
 857         float r, f, n, i, p;
 858         string acl;
 859
 860         acl = MAPINFO_SETTEMP_ACL_USER;
 861
 862         if(strstrofs(pFilename, "/", 0) >= 0)
 863         {
 864                 print("Invalid character in map name, ignored\n");
 865                 return 0;
 866         }
 867
 868         if(pGametypeToSet == 0)
 869                 if(MapInfo_Cache_Retrieve(pFilename))
 870                         return 1;
 871
 872         r = 1;
 873
 874         MapInfo_Map_bspname = pFilename;
 875
 876         // default all generic fields so they have "good" values in case something fails
 877         fn = strcat("maps/", pFilename, ".mapinfo");
 878         fh = fopen(fn, FILE_READ);
 879         if(fh < 0)
 880         {
 881                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 882                 fh = fopen(fn, FILE_READ);
 883                 if(fh < 0)
 884                 {
 885                         if(!pAllowGenerate)
 886                                 return 0;
 887                         _MapInfo_Map_Reset();
 888                         r = _MapInfo_Generate(pFilename);
 889                         if(!r)
 890                                 return 0;
 891                         fh = fopen(fn, FILE_WRITE);
 892                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 893                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 894                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 895                         if(_MapInfo_Map_worldspawn_music != "")
 896                         {
 897                                 if(
 898                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 899                                         ||
 900                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 901                                 )
 902                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 903                                 else
 904                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 905                         }
 906                         else
 907                         {
 908                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 909                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 910                                 for(;;)
 911                                 {
 912                                         i = floor(random() * n);
 913                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 914                                                 break;
 915                                 }
 916                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 917                         }
 918                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 919                                 fputs(fh, "has weapons\n");
 920                         else
 921                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 922                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 923                                 fputs(fh, "has turrets\n");
 924                         else
 925                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 926                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 927                                 fputs(fh, "has vehicles\n");
 928                         else
 929                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 930                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 931                                 fputs(fh, "frustrating\n");
 932
 933                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 934                                 if(MapInfo_Map_supportedGametypes & i)
 935                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 936
 937                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 938                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 939
 940                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 941                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 942                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 943                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 944                         fputs(fh, "// optional: hidden\n");
 945
 946                         fclose(fh);
 947                         r = 2;
 948                         // return r;
 949                         fh = fopen(fn, FILE_READ);
 950                         if(fh < 0)
 951                                 error("... but I just wrote it!");
 952                 }
 953
 954                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 955         }
 956
 957         _MapInfo_Map_Reset();
 958         for(;;)
 959         {
 960                 if (!((s = fgets(fh))))
 961                         break;
 962
 963                 // catch different sorts of comments
 964                 if(s == "")                    // empty lines
 965                         continue;
 966                 if(substring(s, 0, 1) == "#")  // UNIX style
 967                         continue;
 968                 if(substring(s, 0, 2) == "//") // C++ style
 969                         continue;
 970                 if(substring(s, 0, 1) == "_")  // q3map style
 971                         continue;
 972
 973                 p = strstrofs(s, "//", 0);
 974                 if(p >= 0)
 975                         s = substring(s, 0, p);
 976
 977                 t = car(s); s = cdr(s);
 978                 if(t == "title")
 979                         MapInfo_Map_title = s;
 980                 else if(t == "description")
 981                         MapInfo_Map_description = s;
 982                 else if(t == "author")
 983                         MapInfo_Map_author = s;
 984                 else if(t == "has")
 985                 {
 986                         t = car(s); // s = cdr(s);
 987                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 988                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 989                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 990                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 991                         else
 992                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 993                 }
 994                 else if(t == "hidden")
 995                 {
 996                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 997                 }
 998                 else if(t == "forbidden")
 999                 {
1000                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1001                 }
1002                 else if(t == "frustrating")
1003                 {
1004                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1005                 }
1006                 else if(t == "noautomaplist")
1007                 {
1008                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1009                 }
1010                 else if(t == "type")
1011                 {
1012                         t = car(s); s = cdr(s);
1013                         f = MapInfo_Type_FromString(t);
1014                         print("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
1015                         if(f)
1016                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
1017                         else
1018                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1019                 }
1020                 else if(t == "gametype")
1021                 {
1022                         t = car(s); s = cdr(s);
1023                         f = MapInfo_Type_FromString(t);
1024                         if(f)
1025                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1026                         else
1027                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1028                 }
1029                 else if(t == "size")
1030                 {
1031                         float a, b, c, d, e;
1032                         t = car(s); s = cdr(s); a = stof(t);
1033                         t = car(s); s = cdr(s); b = stof(t);
1034                         t = car(s); s = cdr(s); c = stof(t);
1035                         t = car(s); s = cdr(s); d = stof(t);
1036                         t = car(s); s = cdr(s); e = stof(t);
1037                         if(s == "")
1038                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1039                         else
1040                         {
1041                                 t = car(s); s = cdr(s); f = stof(t);
1042                                 if(s != "")
1043                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1044                                 else
1045                                 {
1046                                         if(a >= d || b >= e || c >= f)
1047                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1048                                         else
1049                                         {
1050                                                 MapInfo_Map_mins_x = a;
1051                                                 MapInfo_Map_mins_y = b;
1052                                                 MapInfo_Map_mins_z = c;
1053                                                 MapInfo_Map_maxs_x = d;
1054                                                 MapInfo_Map_maxs_y = e;
1055                                                 MapInfo_Map_maxs_z = f;
1056                                         }
1057                                 }
1058                         }
1059                 }
1060                 else if(t == "settemp_for_type")
1061                 {
1062                         t = car(s); s = cdr(s);
1063                         if((f = MapInfo_Type_FromString(t)))
1064                         {
1065                                 if(f & pGametypeToSet)
1066                                 {
1067                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1068                                 }
1069                         }
1070                         else
1071                         {
1072                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1073                         }
1074                 }
1075                 else if(t == "clientsettemp_for_type")
1076                 {
1077                         t = car(s); s = cdr(s);
1078                         if((f = MapInfo_Type_FromString(t)))
1079                         {
1080                                 if(f & pGametypeToSet)
1081                                 {
1082                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1083                                 }
1084                         }
1085                         else
1086                         {
1087                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1088                         }
1089                 }
1090                 else if(t == "fog")
1091                 {
1092                         if (!cvar_value_issafe(s))
1093                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1094                         else
1095                                 MapInfo_Map_fog = s;
1096                 }
1097                 else if(t == "cdtrack")
1098                 {
1099                         t = car(s); s = cdr(s);
1100                         if(pGametypeToSet) // FIXME is this check right here?
1101                         {
1102                                 if (!cvar_value_issafe(t))
1103                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1104                                 else
1105                                         MapInfo_Map_clientstuff = strcat(
1106                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1107                                         );
1108                         }
1109                 }
1110                 else
1111                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1112         }
1113         fclose(fh);
1114
1115         if(MapInfo_Map_title == "<TITLE>")
1116                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1117         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1118                 MapInfo_Map_titlestring = MapInfo_Map_title;
1119         else
1120                 MapInfo_Map_titlestring = sprintf(_("%s: %s"), MapInfo_Map_bspname, MapInfo_Map_title);
1121
1122         MapInfo_Cache_Store();
1123         if(MapInfo_Map_supportedGametypes != 0)
1124                 return r;
1125         dprint("Map ", pFilename, " supports no game types, ignored\n");
1126         return 0;
1127 }
1128 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
1129 {
1130         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1131
1132         if(cvar("g_tdm_on_dm_maps"))
1133         {
1134                 // if this is set, all DM maps support TDM too
1135                 if (!(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH))
1136                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1137                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1138         }
1139
1140         if(pGametypeToSet)
1141         {
1142                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1143                 {
1144                         //error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1145                         return 0;
1146                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1147                         //return;
1148                 }
1149         }
1150
1151         return r;
1152 }
1153
1154 float MapInfo_FindName(string s)
1155 {
1156         // if there is exactly one map of prefix s, return it
1157         // if not, return the null string
1158         // note that DP sorts glob results... so I can use a binary search
1159         float l, r, m, cmp;
1160         l = 0;
1161         r = MapInfo_count;
1162         // invariants: r is behind s, l-1 is equal or before
1163         while(l != r)
1164         {
1165                 m = floor((l + r) / 2);
1166                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1167                 cmp = strcasecmp(MapInfo_FindName_match, s);
1168                 if(cmp == 0)
1169                         return m; // found and good
1170                 if(cmp < 0)
1171                         l = m + 1; // l-1 is before s
1172                 else
1173                         r = m; // behind s
1174         }
1175         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1176         MapInfo_FindName_firstResult = l;
1177         // r == l, so: l is behind s, l-1 is before
1178         // SO: if there is any, l is the one with the right prefix
1179         //     and l+1 may be one too
1180         if(l == MapInfo_count)
1181         {
1182                 MapInfo_FindName_match = string_null;
1183                 MapInfo_FindName_firstResult = -1;
1184                 return -1; // no MapInfo_FindName_match, behind last item
1185         }
1186         if(!startsWithNocase(MapInfo_FindName_match, s))
1187         {
1188                 MapInfo_FindName_match = string_null;
1189                 MapInfo_FindName_firstResult = -1;
1190                 return -1; // wrong prefix
1191         }
1192         if(l == MapInfo_count - 1)
1193                 return l; // last one, nothing can follow => unique
1194         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1195         {
1196                 MapInfo_FindName_match = string_null;
1197                 return -1; // ambigous MapInfo_FindName_match
1198         }
1199         return l;
1200 }
1201
1202 string MapInfo_FixName(string s)
1203 {
1204         MapInfo_FindName(s);
1205         return MapInfo_FindName_match;
1206 }
1207
1208 float MapInfo_CurrentFeatures()
1209 {
1210         float req;
1211         req = 0;
1212         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1213                 req |= MAPINFO_FEATURE_WEAPONS;
1214         return req;
1215 }
1216
1217 float MapInfo_CurrentGametype()
1218 {
1219         float prev;
1220         entity e;
1221         prev = cvar("gamecfg");
1222         for(e = MapInfo_Type_first; e; e = e.enemy)
1223                 if(cvar(e.netname))
1224                         if(prev != e.items)
1225                                 return e.items;
1226         if(prev)
1227                 return prev;
1228         return MAPINFO_TYPE_DEATHMATCH;
1229 }
1230
1231 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1232 {
1233         if(!MapInfo_Get_ByName(s, 1, 0))
1234                 return 0;
1235         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1236                 return 0;
1237         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1238                 return 0;
1239         return 1;
1240 }
1241
1242 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1243 {
1244         float r;
1245         r = _MapInfo_CheckMap(s);
1246         MapInfo_ClearTemps();
1247         return r;
1248 }
1249
1250 void MapInfo_SwitchGameType(float t)
1251 {
1252         entity e;
1253         for(e = MapInfo_Type_first; e; e = e.enemy)
1254                 cvar_set(e.netname, (t == e.items) ? "1" : "0");
1255 }
1256
1257 void MapInfo_LoadMap(string s, float reinit)
1258 {
1259         MapInfo_Map_supportedGametypes = 0;
1260         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1261         //if(!MapInfo_CheckMap(s))
1262         //{
1263         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1264         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1265         //}
1266
1267         cvar_settemp_restore();
1268         if(reinit)
1269                 localcmd(strcat("\nmap ", s, "\n"));
1270         else
1271                 localcmd(strcat("\nchangelevel ", s, "\n"));
1272 }
1273
1274 string MapInfo_ListAllowedMaps(float type, float pRequiredFlags, float pForbiddenFlags)
1275 {
1276         string out;
1277         float i;
1278
1279         // to make absolutely sure:
1280         MapInfo_Enumerate();
1281         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1282
1283         out = "";
1284         for(i = 0; i < MapInfo_count; ++i)
1285                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1286         return substring(out, 1, strlen(out) - 1);
1287 }
1288
1289 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1290 {
1291         string out;
1292         float i;
1293
1294         // to make absolutely sure:
1295         MapInfo_Enumerate();
1296         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1297
1298         out = "";
1299         for(i = 0; i < MapInfo_count; ++i)
1300                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1301
1302         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1303
1304         return substring(out, 1, strlen(out) - 1);
1305 }
1306
1307 void MapInfo_LoadMapSettings_SaveGameType(float t)
1308 {
1309         MapInfo_SwitchGameType(t);
1310         cvar_set("gamecfg", ftos(t));
1311         MapInfo_LoadedGametype = t;
1312 }
1313
1314 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1315 {
1316         float t;
1317
1318         t = MapInfo_CurrentGametype();
1319         MapInfo_LoadMapSettings_SaveGameType(t);
1320
1321         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1322         {
1323                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1324                 {
1325                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1326                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1327                         return; // do not call Get_ByName!
1328                 }
1329
1330                 if(MapInfo_Map_supportedGametypes == 0)
1331                 {
1332                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1333                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1334                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1335                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1336                         return; // do not call Get_ByName!
1337                 }
1338
1339                 t = 1;
1340                 while(!(MapInfo_Map_supportedGametypes & 1))
1341                 {
1342                         t *= 2;
1343                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1344                 }
1345
1346                 // t is now a supported mode!
1347                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1348                 MapInfo_LoadMapSettings_SaveGameType(t);
1349         }
1350         MapInfo_Get_ByName(s, 1, t);
1351 }
1352
1353 void MapInfo_ClearTemps()
1354 {
1355         MapInfo_Map_bspname = string_null;
1356         MapInfo_Map_title = string_null;
1357         MapInfo_Map_titlestring = string_null;
1358         MapInfo_Map_description = string_null;
1359         MapInfo_Map_author = string_null;
1360         MapInfo_Map_clientstuff = string_null;
1361         MapInfo_Map_supportedGametypes = 0;
1362         MapInfo_Map_supportedFeatures = 0;
1363 }
1364
1365 void MapInfo_Shutdown()
1366 {
1367         MapInfo_ClearTemps();
1368         MapInfo_Filter_Free();
1369         MapInfo_Cache_Destroy();
1370         if(_MapInfo_globopen)
1371         {
1372                 search_end(_MapInfo_globhandle);
1373                 _MapInfo_globhandle = -1;
1374                 _MapInfo_globopen = FALSE;
1375         }
1376 }
1377
1378 float MapInfo_ForbiddenFlags()
1379 {
1380         float f;
1381         f = MAPINFO_FLAG_FORBIDDEN;
1382
1383 #ifndef MENUQC
1384         if (!cvar("g_maplist_allow_hidden"))
1385 #endif
1386                 f |= MAPINFO_FLAG_HIDDEN;
1387
1388         if (!cvar("g_maplist_allow_frustrating"))
1389                 f |= MAPINFO_FLAG_FRUSTRATING;
1390
1391         return f;
1392 }
1393
1394 float MapInfo_RequiredFlags()
1395 {
1396         float f;
1397         f = 0;
1398
1399         if(cvar("g_maplist_allow_frustrating") > 1)
1400                 f |= MAPINFO_FLAG_FRUSTRATING;
1401
1402         return f;
1403 }