qcsrc/common/mapinfo.qc

   1 #if defined(CSQC)
   2     #include "../client/defs.qh"
   3     #include "util.qh"
   4     #include "buffs/all.qh"
   5     #include "weapons/all.qh"
   6     #include "mapinfo.qh"
   7 #elif defined(MENUQC)
   8 #elif defined(SVQC)
   9     #include "util.qh"
  10     #include "buffs/all.qh"
  11     #include "monsters/all.qh"
  12     #include "mapinfo.qh"
  13 #endif
  14
  15 // generic string stuff
  16
  17 int _MapInfo_Cache_Active;
  18 int _MapInfo_Cache_DB_NameToIndex;
  19 int _MapInfo_Cache_Buf_IndexToMapData;
  20
  21 void MapInfo_Cache_Destroy()
  22 {
  23         if(!_MapInfo_Cache_Active)
  24                 return;
  25
  26         db_close(_MapInfo_Cache_DB_NameToIndex);
  27         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  28         _MapInfo_Cache_Active = 0;
  29 }
  30
  31 void MapInfo_Cache_Create()
  32 {
  33         MapInfo_Cache_Destroy();
  34         _MapInfo_Cache_DB_NameToIndex = db_create();
  35         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  36         _MapInfo_Cache_Active = 1;
  37 }
  38
  39 void MapInfo_Cache_Invalidate()
  40 {
  41         if(!_MapInfo_Cache_Active)
  42                 return;
  43
  44         MapInfo_Cache_Create();
  45 }
  46
  47 void MapInfo_Cache_Store()
  48 {
  49         float i;
  50         string s;
  51         if(!_MapInfo_Cache_Active)
  52                 return;
  53
  54         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  55         if(s == "")
  56         {
  57                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  58                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  59         }
  60         else
  61                 i = stof(s);
  62
  63         // now store all the stuff
  64         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  65         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  66         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  67         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  68         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  71         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  72 }
  73
  74 float MapInfo_Cache_Retrieve(string map)
  75 {
  76         float i;
  77         string s;
  78         if(!_MapInfo_Cache_Active)
  79                 return 0;
  80
  81         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  82         if(s == "")
  83                 return 0;
  84         i = stof(s);
  85
  86         // now retrieve all the stuff
  87         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  88         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  89         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  90         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  91         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  92         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  93         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  94         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  95
  96         return 1;
  97 }
  98
  99 // GLOB HANDLING (for all BSP files)
 100 float _MapInfo_globopen;
 101 float _MapInfo_globcount;
 102 float _MapInfo_globhandle;
 103 string _MapInfo_GlobItem(float i)
 104 {
 105         string s;
 106         if(!_MapInfo_globopen)
 107                 return string_null;
 108         s = search_getfilename(_MapInfo_globhandle, i);
 109         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 110 }
 111
 112 void MapInfo_Enumerate()
 113 {
 114         if(_MapInfo_globopen)
 115         {
 116                 search_end(_MapInfo_globhandle);
 117                 _MapInfo_globopen = 0;
 118         }
 119         MapInfo_Cache_Invalidate();
 120         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 121         if(_MapInfo_globhandle >= 0)
 122         {
 123                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 124                 _MapInfo_globopen = 1;
 125         }
 126         else
 127                 _MapInfo_globcount = 0;
 128 }
 129
 130 // filter the info by game type mask (updates MapInfo_count)
 131 //
 132 float _MapInfo_filtered;
 133 float _MapInfo_filtered_allocated;
 134 float MapInfo_FilterList_Lookup(float i)
 135 {
 136         return stof(bufstr_get(_MapInfo_filtered, i));
 137 }
 138
 139 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 140 {
 141         string h;
 142         h = bufstr_get(_MapInfo_filtered, i);
 143         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 144         bufstr_set(_MapInfo_filtered, j, h);
 145 }
 146
 147 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 148 {
 149         string a, b;
 150         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 151         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 152         return strcasecmp(a, b);
 153 }
 154
 155 float MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 156 {
 157         float i, j;
 158         if (!_MapInfo_filtered_allocated)
 159         {
 160                 _MapInfo_filtered_allocated = 1;
 161                 _MapInfo_filtered = buf_create();
 162         }
 163         MapInfo_count = 0;
 164         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 165         {
 166                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 167                         if(pAbortOnGenerate)
 168                         {
 169                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.\n");
 170                                 MapInfo_progress = i / _MapInfo_globcount;
 171                                 return 0;
 172                         }
 173                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 174                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 175                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 176                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 177                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 178         }
 179         MapInfo_count = j + 1;
 180         MapInfo_ClearTemps();
 181
 182         // sometimes the glob isn't sorted nicely, so fix it here...
 183         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 184
 185         return 1;
 186 }
 187 void MapInfo_FilterString(string sf)
 188 {
 189         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 190         float i, j;
 191         string title;
 192
 193         for(i = 0, j = -1; i < MapInfo_count; ++i)
 194         {
 195                 if (MapInfo_Get_ByID(i))
 196                 {
 197                         // prepare for keyword filter
 198                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 199                                 title = MapInfo_Map_title;
 200                         else
 201                                 title = MapInfo_Map_bspname;
 202                         // keyword filter
 203                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 204                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 205                 }
 206         }
 207         MapInfo_count = j + 1;
 208         MapInfo_ClearTemps();
 209
 210         // sometimes the glob isn't sorted nicely, so fix it here...
 211         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 212 }
 213
 214 void MapInfo_Filter_Free()
 215 {
 216         if(_MapInfo_filtered_allocated)
 217         {
 218                 buf_del(_MapInfo_filtered);
 219                 _MapInfo_filtered_allocated = 0;
 220         }
 221 }
 222
 223 // load info about the i-th map into the MapInfo_Map_* globals
 224 string MapInfo_BSPName_ByID(float i)
 225 {
 226         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 227 }
 228
 229 string unquote(string s)
 230 {
 231         float i, j, l;
 232         l = strlen(s);
 233         j = -1;
 234         for(i = 0; i < l; ++i)
 235         {
 236                 string ch;
 237                 ch = substring(s, i, 1);
 238                 if(ch != " ") if(ch != "\"")
 239                 {
 240                         for(j = strlen(s) - i - 1; j > 0; --j)
 241                         {
 242                                 ch = substring(s, i+j, 1);
 243                                 if(ch != " ") if(ch != "\"")
 244                                         return substring(s, i, j+1);
 245                         }
 246                         return substring(s, i, 1);
 247                 }
 248         }
 249         return "";
 250 }
 251
 252 float MapInfo_Get_ByID(float i)
 253 {
 254         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 255                 return 1;
 256         return 0;
 257 }
 258
 259 string _MapInfo_Map_worldspawn_music;
 260
 261 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 262 {
 263         string fn;
 264         float fh;
 265         string s, k, v;
 266         vector o;
 267         float i;
 268         float inWorldspawn;
 269         float r;
 270         float twoBaseModes;
 271         float diameter, spawnpoints;
 272         float spawnplaces;
 273
 274         vector mapMins, mapMaxs;
 275
 276         r = 1;
 277         fn = strcat("maps/", pFilename, ".ent");
 278         fh = fopen(fn, FILE_READ);
 279         if(fh < 0)
 280         {
 281                 r = 2;
 282                 fn = strcat("maps/", pFilename, ".bsp");
 283                 fh = fopen(fn, FILE_READ);
 284         }
 285         if(fh < 0)
 286                 return 0;
 287         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo\n");
 288
 289         inWorldspawn = 2;
 290         MapInfo_Map_flags = 0;
 291         MapInfo_Map_supportedGametypes = 0;
 292         spawnpoints = 0;
 293         spawnplaces = 0;
 294         _MapInfo_Map_worldspawn_music = "";
 295         mapMins = '0 0 0';
 296         mapMaxs = '0 0 0';
 297
 298         for (;;)
 299         {
 300                 if (!((s = fgets(fh))))
 301                         break;
 302                 if(inWorldspawn == 1)
 303                         if(startsWith(s, "}"))
 304                                 inWorldspawn = 0;
 305                 k = unquote(car(s));
 306                 v = unquote(cdr(s));
 307                 if(inWorldspawn)
 308                 {
 309                         if(k == "classname" && v == "worldspawn")
 310                                 inWorldspawn = 1;
 311                         else if(k == "author")
 312                                 MapInfo_Map_author = v;
 313                         else if(k == "_description")
 314                                 MapInfo_Map_description = v;
 315                         else if(k == "music")
 316                                 _MapInfo_Map_worldspawn_music = v;
 317                         else if(k == "noise")
 318                                 _MapInfo_Map_worldspawn_music = v;
 319                         else if(k == "message")
 320                         {
 321                                 i = strstrofs(v, " by ", 0);
 322                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 323                                 {
 324                                         MapInfo_Map_title = substring(v, 0, i);
 325                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 326                                 }
 327                                 else
 328                                         MapInfo_Map_title = v;
 329                         }
 330                 }
 331                 else
 332                 {
 333                         if(k == "origin")
 334                         {
 335                                 o = stov(strcat("'", v, "'"));
 336                                 mapMins.x = min(mapMins.x, o.x);
 337                                 mapMins.y = min(mapMins.y, o.y);
 338                                 mapMins.z = min(mapMins.z, o.z);
 339                                 mapMaxs.x = max(mapMaxs.x, o.x);
 340                                 mapMaxs.y = max(mapMaxs.y, o.y);
 341                                 mapMaxs.z = max(mapMaxs.z, o.z);
 342                         }
 343                         else if(k == "race_place")
 344                         {
 345                                 if(stof(v) > 0)
 346                                         spawnplaces = 1;
 347                         }
 348                         else if(k == "classname")
 349                         {
 350                                 if(v == "dom_controlpoint")
 351                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 352                                 else if(v == "item_flag_team2")
 353                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 354                                 else if(v == "team_CTF_blueflag")
 355                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 356                                 else if(v == "invasion_spawnpoint")
 357                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_INVASION;
 358                                 else if(v == "target_assault_roundend")
 359                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 360                                 else if(v == "onslaught_generator")
 361                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 362                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 363                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 364                                 else if(v == "info_player_team1")
 365                                         ++spawnpoints;
 366                                 else if(v == "info_player_team2")
 367                                         ++spawnpoints;
 368                                 else if(v == "info_player_start")
 369                                         ++spawnpoints;
 370                                 else if(v == "info_player_deathmatch")
 371                                         ++spawnpoints;
 372                                 else if(v == "trigger_race_checkpoint")
 373                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 374                                 else if(v == "target_startTimer")
 375                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 376                                 else if(v == "weapon_nex")
 377                                         { }
 378                                 else if(v == "weapon_railgun")
 379                                         { }
 380                                 else if(startsWith(v, "weapon_"))
 381                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 382                                 else if(startsWith(v, "turret_"))
 383                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 384                                 else if(startsWith(v, "vehicle_"))
 385                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 386                                 else if(startsWith(v, "monster_"))
 387                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 388                                 else if(v == "target_music" || v == "trigger_music")
 389                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 390                         }
 391                 }
 392         }
 393         if(inWorldspawn)
 394         {
 395                 LOG_INFO(fn, " ended still in worldspawn, BUG\n");
 396                 return 0;
 397         }
 398         diameter = vlen(mapMaxs - mapMins);
 399
 400         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 401         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 402         {
 403                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 404                 // as the map is too symmetric for them.
 405         }
 406         else
 407         {
 408                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 409                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 410                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 411
 412                 if(spawnpoints >= 8  && diameter > 4096) {
 413                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 414                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 415                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 416                 }
 417                 if(spawnpoints >= 12 && diameter > 5120)
 418                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 419         }
 420
 421         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 422         if(!spawnplaces)
 423         {
 424                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE;
 425                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 426         }
 427
 428         LOG_TRACE("-> diameter ",    ftos(diameter));
 429         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 430         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 431
 432         fclose(fh);
 433
 434         return r;
 435 }
 436
 437 void _MapInfo_Map_Reset()
 438 {
 439         MapInfo_Map_title = "<TITLE>";
 440         MapInfo_Map_titlestring = "<TITLE>";
 441         MapInfo_Map_description = "<DESCRIPTION>";
 442         MapInfo_Map_author = "<AUTHOR>";
 443         MapInfo_Map_supportedGametypes = 0;
 444         MapInfo_Map_supportedFeatures = 0;
 445         MapInfo_Map_flags = 0;
 446         MapInfo_Map_clientstuff = "";
 447         MapInfo_Map_fog = "";
 448         MapInfo_Map_mins = '0 0 0';
 449         MapInfo_Map_maxs = '0 0 0';
 450 }
 451
 452 string _MapInfo_GetDefault(float t)
 453 {
 454         switch(t)
 455         {
 456                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 457                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 458                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 459                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 460                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 461                 case MAPINFO_TYPE_CA:              return "10 20 0";
 462                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 463                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 464                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 465                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 466                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 467                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 468                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 469                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 470                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 471                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 472                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 473                 default:                           return "";
 474         }
 475 }
 476
 477 void _MapInfo_Map_ApplyGametype(string s, int pWantedType, int pThisType, int load_default)
 478 {
 479         string sa;
 480         MapInfo_Map_supportedGametypes |= pThisType;
 481         if(!(pThisType & pWantedType))
 482                 return;
 483
 484         if(load_default)
 485                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 486
 487         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 488         {
 489                 cvar_set("fraglimit", "0");
 490         }
 491         else
 492         {
 493                 sa = car(s);
 494                 if(sa != "")
 495                         cvar_set("fraglimit", sa);
 496                 s = cdr(s);
 497         }
 498
 499         sa = car(s);
 500         if(sa != "")
 501                 cvar_set("timelimit", sa);
 502         s = cdr(s);
 503
 504         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 505         {
 506                 sa = car(s);
 507                 if(sa != "")
 508                         cvar_set("g_tdm_teams", sa);
 509                 s = cdr(s);
 510         }
 511
 512         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 513         {
 514                 sa = car(s);
 515                 if(sa != "")
 516                         cvar_set("g_keyhunt_teams", sa);
 517                 s = cdr(s);
 518         }
 519
 520         if(pWantedType == MAPINFO_TYPE_CA)
 521         {
 522                 sa = car(s);
 523                 if(sa != "")
 524                         cvar_set("g_ca_teams", sa);
 525                 s = cdr(s);
 526         }
 527
 528         if(pWantedType == MAPINFO_TYPE_FREEZETAG)
 529         {
 530                 sa = car(s);
 531                 if(sa != "")
 532                         cvar_set("g_freezetag_teams", sa);
 533                 s = cdr(s);
 534         }
 535
 536         if(pWantedType == MAPINFO_TYPE_CTF)
 537         {
 538                 sa = car(s);
 539                 if(sa != "")
 540                         cvar_set("fraglimit", sa);
 541                 s = cdr(s);
 542         }
 543
 544         /* keepaway wuz here
 545         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 546         {
 547                 sa = car(s);
 548                 if(sa != "")
 549                         cvar_set("fraglimit", sa);
 550                 s = cdr(s);
 551         }
 552         */
 553
 554         // rc = timelimit timelimit_qualification laps laps_teamplay
 555         if(pWantedType == MAPINFO_TYPE_RACE)
 556         {
 557                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 558                 cvar_set("g_race_qualifying_timelimit", sa);
 559                 s = cdr(s);
 560
 561                 sa = car(s);
 562                 if(sa != "")
 563                         if(cvar("g_race_teams") < 2)
 564                                 cvar_set("fraglimit", sa);
 565                 s = cdr(s);
 566
 567                 sa = car(s);
 568                 if(sa != "")
 569                         if(cvar("g_race_teams") >= 2)
 570                                 cvar_set("fraglimit", sa);
 571                 s = cdr(s);
 572         }
 573
 574         if(pWantedType == MAPINFO_TYPE_CTS)
 575         {
 576                 sa = car(s);
 577
 578                 // this is the skill of the map
 579                 // not parsed by anything yet
 580                 // for map databases
 581                 //if(sa != "")
 582                 //      cvar_set("fraglimit", sa);
 583
 584                 s = cdr(s);
 585         }
 586
 587         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 588         {
 589                 cvar_set("leadlimit", "0");
 590         }
 591         else
 592         {
 593                 sa = car(s);
 594                 if(sa != "")
 595                         cvar_set("leadlimit", sa);
 596                 s = cdr(s);
 597         }
 598 }
 599
 600 string _MapInfo_GetDefaultEx(float t)
 601 {
 602         FOREACH(Gametypes, it.items == t, LAMBDA(return it.model2));
 603         return "";
 604 }
 605
 606 float _MapInfo_GetTeamPlayBool(float t)
 607 {
 608         FOREACH(Gametypes, it.items == t, LAMBDA(return it.team));
 609         return false;
 610 }
 611
 612 void _MapInfo_Map_ApplyGametypeEx(string s, int pWantedType, int pThisType)
 613 {
 614         MapInfo_Map_supportedGametypes |= pThisType;
 615         if (!(pThisType & pWantedType))
 616                 return;
 617
 618         // reset all the cvars to their defaults
 619
 620         cvar_set("timelimit", cvar_defstring("timelimit"));
 621         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 622         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 623         FOREACH(Gametypes, true, LAMBDA(it.m_parse_mapinfo(string_null, string_null)));
 624
 625         string fraglimit_normal = string_null;
 626         string fraglimit_teams = string_null;
 627
 628         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 629                 string sa = car(s);
 630                 if (sa == "") continue;
 631                 int p = strstrofs(sa, "=", 0);
 632                 if (p < 0) {
 633                         LOG_WARNINGF("Invalid gametype setting in mapinfo for gametype %s: %s\n", MapInfo_Type_ToString(pWantedType), sa);
 634                         continue;
 635                 }
 636                 string k = substring(sa, 0, p);
 637                 string v = substring(sa, p + 1, -1);
 638                 bool handled = true;
 639                 switch (k) {
 640                         case "timelimit":
 641                         {
 642                                 cvar_set("timelimit", v);
 643                                 break;
 644                         }
 645                         case "leadlimit":
 646                         {
 647                                 cvar_set("leadlimit", v);
 648                                 break;
 649                         }
 650                         case "pointlimit":
 651                         case "fraglimit":
 652                         case "lives":
 653                         case "laplimit":
 654                         case "caplimit":
 655                         {
 656                                 fraglimit_normal = v;
 657                                 break;
 658                         }
 659                         case "teampointlimit":
 660                         case "teamlaplimit":
 661                         {
 662                                 fraglimit_teams = v;
 663                                 break;
 664                         }
 665                         default:
 666                         {
 667                             handled = false;
 668                             break;
 669                         }
 670                 }
 671                 FOREACH(Gametypes, true, LAMBDA(handled |= it.m_parse_mapinfo(k, v)));
 672                 if (!handled)
 673             LOG_WARNINGF("Invalid gametype setting in mapinfo for gametype %s: %s\n", MapInfo_Type_ToString(pWantedType), sa);
 674         }
 675
 676         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 677         {
 678                 if(fraglimit_teams)
 679                         cvar_set("fraglimit", fraglimit_teams);
 680         }
 681         else
 682         {
 683                 if(fraglimit_normal)
 684                         cvar_set("fraglimit", fraglimit_normal);
 685         }
 686 }
 687
 688 Gametype MapInfo_Type(int t)
 689 {
 690         FOREACH(Gametypes, it.items == t, LAMBDA(return it));
 691         return NULL;
 692 }
 693
 694 int MapInfo_Type_FromString(string t)
 695 {
 696 #define deprecate(from, to) do { \
 697         if (t == #from) { \
 698                 string replacement = #to; \
 699                 LOG_WARNINGF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.\n", MapInfo_Map_bspname, t, replacement); \
 700                 t = replacement; \
 701         } \
 702 } while (0)
 703         deprecate(nexball, nb);
 704         deprecate(freezetag, ft);
 705         deprecate(keepaway, ka);
 706         deprecate(invasion, inv);
 707         deprecate(assault, as);
 708         deprecate(race, rc);
 709         if (t == "all") return MAPINFO_TYPE_ALL;
 710         FOREACH(Gametypes, it.mdl == t, LAMBDA(return it.items));
 711         return 0;
 712 #undef deprecate
 713 }
 714
 715 string MapInfo_Type_Description(float t)
 716 {
 717         FOREACH(Gametypes, it.items == t, LAMBDA(return it.gametype_description));
 718         return "";
 719 }
 720
 721 string MapInfo_Type_ToString(float t)
 722 {
 723         if(t == MAPINFO_TYPE_ALL)
 724                 return "all";
 725         FOREACH(Gametypes, it.items == t, LAMBDA(return it.mdl));
 726         return "";
 727 }
 728
 729 string MapInfo_Type_ToText(float t)
 730 {
 731         FOREACH(Gametypes, it.items == t, LAMBDA(return it.message));
 732         /* xgettext:no-c-format */
 733         return _("@!#%'n Tuba Throwing");
 734 }
 735
 736 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 737 {
 738         string t;
 739         float fh, o;
 740         t = car(s); s = cdr(s);
 741
 742         // limited support of "" and comments
 743         //   remove trailing and leading " of t
 744         if(substring(t, 0, 1) == "\"")
 745         {
 746                 if(substring(t, -1, 1) == "\"")
 747                         t = substring(t, 1, -2);
 748         }
 749
 750         //   remove leading " of s
 751         if(substring(s, 0, 1) == "\"")
 752         {
 753                 s = substring(s, 1, -1);
 754         }
 755         //   remove trailing " of s, and all that follows (cvar description)
 756         o = strstrofs(s, "\"", 0);
 757         if(o >= 0)
 758                 s = substring(s, 0, o);
 759
 760         //   remove // comments
 761         o = strstrofs(s, "//", 0);
 762         if(o >= 0)
 763                 s = substring(s, 0, o);
 764
 765         //   remove trailing spaces
 766         while(substring(s, -1, 1) == " ")
 767                 s = substring(s, 0, -2);
 768
 769         if(t == "#include")
 770         {
 771                 if(recurse > 0)
 772                 {
 773                         fh = fopen(s, FILE_READ);
 774                         if(fh < 0)
 775                                 LOG_INFO("Map ", pFilename, " references not existing config file ", s, "\n");
 776                         else
 777                         {
 778                                 for (;;)
 779                                 {
 780                                         if (!((s = fgets(fh))))
 781                                                 break;
 782
 783                                         // catch different sorts of comments
 784                                         if(s == "")                    // empty lines
 785                                                 continue;
 786                                         if(substring(s, 0, 1) == "#")  // UNIX style
 787                                                 continue;
 788                                         if(substring(s, 0, 2) == "//") // C++ style
 789                                                 continue;
 790                                         if(substring(s, 0, 1) == "_")  // q3map style
 791                                                 continue;
 792
 793                                         if(substring(s, 0, 4) == "set ")
 794                                                 s = substring(s, 4, -1);
 795                                         if(substring(s, 0, 5) == "seta ")
 796                                                 s = substring(s, 5, -1);
 797
 798                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 799                                 }
 800                                 fclose(fh);
 801                         }
 802                 }
 803                 else
 804                         LOG_INFO("Map ", pFilename, " uses too many levels of inclusion\n");
 805         }
 806         else if(t == "")
 807                 LOG_INFO("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 808         else if (!cvar_value_issafe(t))
 809                 LOG_INFO("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 810         else if (!cvar_value_issafe(s))
 811                 LOG_INFO("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 812         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 813                 LOG_INFO("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 814         else if(matchacl(acl, t) <= 0)
 815                 LOG_INFO("Map ", pFilename, " contains a denied setting, ignored\n");
 816         else
 817         {
 818                 if(type == 0) // server set
 819                 {
 820                         LOG_TRACE("Applying temporary setting ", t, " := ", s, "\n");
 821                         if(cvar("g_campaign"))
 822                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 823                         else
 824                                 cvar_settemp(t, s);
 825                 }
 826                 else
 827                 {
 828                         LOG_TRACE("Applying temporary client setting ", t, " := ", s, "\n");
 829                         MapInfo_Map_clientstuff = strcat(
 830                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 831                                         );
 832                 }
 833         }
 834 }
 835
 836 float MapInfo_isRedundant(string fn, string t)
 837 {
 838         // normalize file name
 839         fn = strreplace("_", "-", fn);
 840
 841         // normalize visible title
 842         t = strreplace(": ", "-", t);
 843         t = strreplace(":", "-", t);
 844         t = strreplace(" ", "-", t);
 845         t = strreplace("_", "-", t);
 846         t = strreplace("'", "-", t);
 847
 848         if(!strcasecmp(fn, t))
 849                 return true;
 850
 851         // we allow the visible title to have punctuation the file name does
 852         // not, but not vice versa
 853         t = strreplace("-", "", t);
 854
 855         if(!strcasecmp(fn, t))
 856                 return true;
 857
 858         return false;
 859 }
 860
 861 // load info about a map by name into the MapInfo_Map_* globals
 862 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, int pGametypeToSet)
 863 {
 864         string fn;
 865         string s, t;
 866         float fh;
 867         int f, i;
 868         float r, n, p;
 869         string acl;
 870
 871         acl = MAPINFO_SETTEMP_ACL_USER;
 872
 873         if(strstrofs(pFilename, "/", 0) >= 0)
 874         {
 875                 LOG_INFO("Invalid character in map name, ignored\n");
 876                 return 0;
 877         }
 878
 879         if(pGametypeToSet == 0)
 880                 if(MapInfo_Cache_Retrieve(pFilename))
 881                         return 1;
 882
 883         r = 1;
 884
 885         MapInfo_Map_bspname = pFilename;
 886
 887         // default all generic fields so they have "good" values in case something fails
 888         fn = strcat("maps/", pFilename, ".mapinfo");
 889         fh = fopen(fn, FILE_READ);
 890         if(fh < 0)
 891         {
 892                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 893                 fh = fopen(fn, FILE_READ);
 894                 if(fh < 0)
 895                 {
 896                         if(!pAllowGenerate)
 897                                 return 0;
 898                         _MapInfo_Map_Reset();
 899                         r = _MapInfo_Generate(pFilename);
 900                         if(!r)
 901                                 return 0;
 902                         fh = fopen(fn, FILE_WRITE);
 903                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 904                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 905                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 906                         if(_MapInfo_Map_worldspawn_music != "")
 907                         {
 908                                 if(
 909                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 910                                         ||
 911                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 912                                 )
 913                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 914                                 else
 915                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 916                         }
 917                         else
 918                         {
 919                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 920                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 921                                 for (;;)
 922                                 {
 923                                         i = floor(random() * n);
 924                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 925                                                 break;
 926                                 }
 927                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 928                         }
 929                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 930                                 fputs(fh, "has weapons\n");
 931                         else
 932                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 933                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 934                                 fputs(fh, "has turrets\n");
 935                         else
 936                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 937                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 938                                 fputs(fh, "has vehicles\n");
 939                         else
 940                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 941                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 942                                 fputs(fh, "frustrating\n");
 943
 944                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 945                                 if(MapInfo_Map_supportedGametypes & i)
 946                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 947
 948                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 949                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 950
 951                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 952                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 953                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 954                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 955                         fputs(fh, "// optional: hidden\n");
 956
 957                         fclose(fh);
 958                         r = 2;
 959                         // return r;
 960                         fh = fopen(fn, FILE_READ);
 961                         if(fh < 0)
 962                                 error("... but I just wrote it!");
 963                 }
 964
 965                 LOG_INFO("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 966         }
 967
 968         _MapInfo_Map_Reset();
 969         for (;;)
 970         {
 971                 if (!((s = fgets(fh))))
 972                         break;
 973
 974                 // catch different sorts of comments
 975                 if(s == "")                    // empty lines
 976                         continue;
 977                 if(substring(s, 0, 1) == "#")  // UNIX style
 978                         continue;
 979                 if(substring(s, 0, 2) == "//") // C++ style
 980                         continue;
 981                 if(substring(s, 0, 1) == "_")  // q3map style
 982                         continue;
 983
 984                 p = strstrofs(s, "//", 0);
 985                 if(p >= 0)
 986                         s = substring(s, 0, p);
 987
 988                 t = car(s); s = cdr(s);
 989                 if(t == "title")
 990                         MapInfo_Map_title = s;
 991                 else if(t == "description")
 992                         MapInfo_Map_description = s;
 993                 else if(t == "author")
 994                         MapInfo_Map_author = s;
 995                 else if(t == "has")
 996                 {
 997                         t = car(s); // s = cdr(s);
 998                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 999                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
1000                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
1001                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
1002                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1003                         else
1004                                 LOG_TRACE("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
1005                 }
1006                 else if(t == "hidden")
1007                 {
1008                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
1009                 }
1010                 else if(t == "forbidden")
1011                 {
1012                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1013                 }
1014                 else if(t == "frustrating")
1015                 {
1016                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1017                 }
1018                 else if(t == "noautomaplist")
1019                 {
1020                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1021                 }
1022                 else if(t == "type")
1023                 {
1024                         t = car(s); s = cdr(s);
1025                         f = MapInfo_Type_FromString(t);
1026                         LOG_WARNING("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
1027                         if(f)
1028                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
1029                         else
1030                                 LOG_TRACE("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1031                 }
1032                 else if(t == "gametype")
1033                 {
1034                         t = car(s); s = cdr(s);
1035                         f = MapInfo_Type_FromString(t);
1036                         if(f)
1037                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1038                         else
1039                                 LOG_TRACE("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1040                 }
1041                 else if(t == "size")
1042                 {
1043                         float a, b, c, d, e;
1044                         t = car(s); s = cdr(s); a = stof(t);
1045                         t = car(s); s = cdr(s); b = stof(t);
1046                         t = car(s); s = cdr(s); c = stof(t);
1047                         t = car(s); s = cdr(s); d = stof(t);
1048                         t = car(s); s = cdr(s); e = stof(t);
1049                         if(s == "")
1050                                 LOG_INFO("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1051                         else
1052                         {
1053                                 t = car(s); s = cdr(s); f = stof(t);
1054                                 if(s != "")
1055                                         LOG_INFO("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1056                                 else
1057                                 {
1058                                         if(a >= d || b >= e || c >= f)
1059                                                 LOG_INFO("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1060                                         else
1061                                         {
1062                                                 MapInfo_Map_mins.x = a;
1063                                                 MapInfo_Map_mins.y = b;
1064                                                 MapInfo_Map_mins.z = c;
1065                                                 MapInfo_Map_maxs.x = d;
1066                                                 MapInfo_Map_maxs.y = e;
1067                                                 MapInfo_Map_maxs.z = f;
1068                                         }
1069                                 }
1070                         }
1071                 }
1072                 else if(t == "settemp_for_type")
1073                 {
1074                         t = car(s); s = cdr(s);
1075                         if((f = MapInfo_Type_FromString(t)))
1076                         {
1077                                 if(f & pGametypeToSet)
1078                                 {
1079                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1080                                 }
1081                         }
1082                         else
1083                         {
1084                                 LOG_TRACE("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1085                         }
1086                 }
1087                 else if(t == "clientsettemp_for_type")
1088                 {
1089                         t = car(s); s = cdr(s);
1090                         if((f = MapInfo_Type_FromString(t)))
1091                         {
1092                                 if(f & pGametypeToSet)
1093                                 {
1094                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1095                                 }
1096                         }
1097                         else
1098                         {
1099                                 LOG_TRACE("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1100                         }
1101                 }
1102                 else if(t == "fog")
1103                 {
1104                         if (!cvar_value_issafe(s))
1105                                 LOG_INFO("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1106                         else
1107                                 MapInfo_Map_fog = s;
1108                 }
1109                 else if(t == "cdtrack")
1110                 {
1111                         t = car(s); s = cdr(s);
1112                         // We do this only if pGametypeToSet even though this
1113                         // content is theoretically game type independent,
1114                         // because MapInfo_Map_clientstuff contains otherwise
1115                         // game type dependent stuff. That way this value stays
1116                         // empty when not setting a game type to not set any
1117                         // false expectations.
1118                         if(pGametypeToSet)
1119                         {
1120                                 if (!cvar_value_issafe(t))
1121                                         LOG_INFO("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1122                                 else
1123                                         MapInfo_Map_clientstuff = strcat(
1124                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1125                                         );
1126                         }
1127                 }
1128                 else
1129                         LOG_TRACE("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1130         }
1131         fclose(fh);
1132
1133         if(MapInfo_Map_title == "<TITLE>")
1134                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1135         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1136                 MapInfo_Map_titlestring = MapInfo_Map_title;
1137         else
1138                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1139
1140         MapInfo_Cache_Store();
1141         if(MapInfo_Map_supportedGametypes != 0)
1142                 return r;
1143         LOG_TRACE("Map ", pFilename, " supports no game types, ignored\n");
1144         return 0;
1145 }
1146 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, int pGametypeToSet)
1147 {
1148         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1149
1150         if(cvar("g_tdm_on_dm_maps"))
1151         {
1152                 // if this is set, all DM maps support TDM too
1153                 if (!(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH))
1154                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1155                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1156         }
1157
1158         if(pGametypeToSet)
1159         {
1160                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1161                 {
1162                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1163                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1164                         //return;
1165                 }
1166         }
1167
1168         return r;
1169 }
1170
1171 float MapInfo_FindName(string s)
1172 {
1173         // if there is exactly one map of prefix s, return it
1174         // if not, return the null string
1175         // note that DP sorts glob results... so I can use a binary search
1176         float l, r, m, cmp;
1177         l = 0;
1178         r = MapInfo_count;
1179         // invariants: r is behind s, l-1 is equal or before
1180         while(l != r)
1181         {
1182                 m = floor((l + r) / 2);
1183                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1184                 cmp = strcasecmp(MapInfo_FindName_match, s);
1185                 if(cmp == 0)
1186                         return m; // found and good
1187                 if(cmp < 0)
1188                         l = m + 1; // l-1 is before s
1189                 else
1190                         r = m; // behind s
1191         }
1192         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1193         MapInfo_FindName_firstResult = l;
1194         // r == l, so: l is behind s, l-1 is before
1195         // SO: if there is any, l is the one with the right prefix
1196         //     and l+1 may be one too
1197         if(l == MapInfo_count)
1198         {
1199                 MapInfo_FindName_match = string_null;
1200                 MapInfo_FindName_firstResult = -1;
1201                 return -1; // no MapInfo_FindName_match, behind last item
1202         }
1203         if(!startsWithNocase(MapInfo_FindName_match, s))
1204         {
1205                 MapInfo_FindName_match = string_null;
1206                 MapInfo_FindName_firstResult = -1;
1207                 return -1; // wrong prefix
1208         }
1209         if(l == MapInfo_count - 1)
1210                 return l; // last one, nothing can follow => unique
1211         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1212         {
1213                 MapInfo_FindName_match = string_null;
1214                 return -1; // ambigous MapInfo_FindName_match
1215         }
1216         return l;
1217 }
1218
1219 string MapInfo_FixName(string s)
1220 {
1221         MapInfo_FindName(s);
1222         return MapInfo_FindName_match;
1223 }
1224
1225 int MapInfo_CurrentFeatures()
1226 {
1227         int req = 0;
1228         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1229                 req |= MAPINFO_FEATURE_WEAPONS;
1230         return req;
1231 }
1232
1233 int MapInfo_CurrentGametype()
1234 {
1235         int prev = cvar("gamecfg");
1236         FOREACH(Gametypes, cvar(it.netname) && it.items != prev, LAMBDA(return it.items));
1237         if (prev) return prev;
1238         return MAPINFO_TYPE_DEATHMATCH;
1239 }
1240
1241 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1242 {
1243         if(!MapInfo_Get_ByName(s, 1, 0))
1244                 return 0;
1245         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1246                 return 0;
1247         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1248                 return 0;
1249         return 1;
1250 }
1251
1252 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1253 {
1254         float r;
1255         r = _MapInfo_CheckMap(s);
1256         MapInfo_ClearTemps();
1257         return r;
1258 }
1259
1260 void MapInfo_SwitchGameType(int t)
1261 {
1262         FOREACH(Gametypes, true, LAMBDA(
1263                 cvar_set(it.netname, (it.items == t) ? "1" : "0")
1264         ));
1265 }
1266
1267 void MapInfo_LoadMap(string s, float reinit)
1268 {
1269         MapInfo_Map_supportedGametypes = 0;
1270         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1271         //if(!MapInfo_CheckMap(s))
1272         //{
1273         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1274         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1275         //}
1276
1277         cvar_settemp_restore();
1278         if(reinit)
1279                 localcmd(strcat("\nmap ", s, "\n"));
1280         else
1281                 localcmd(strcat("\nchangelevel ", s, "\n"));
1282 }
1283
1284 string MapInfo_ListAllowedMaps(float type, float pRequiredFlags, float pForbiddenFlags)
1285 {
1286         string out;
1287         float i;
1288
1289         // to make absolutely sure:
1290         MapInfo_Enumerate();
1291         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1292
1293         out = "";
1294         for(i = 0; i < MapInfo_count; ++i)
1295                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1296         return substring(out, 1, strlen(out) - 1);
1297 }
1298
1299 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1300 {
1301         string out;
1302         float i;
1303
1304         // to make absolutely sure:
1305         MapInfo_Enumerate();
1306         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1307
1308         out = "";
1309         for(i = 0; i < MapInfo_count; ++i)
1310                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1311
1312         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1313
1314         return substring(out, 1, strlen(out) - 1);
1315 }
1316
1317 void MapInfo_LoadMapSettings_SaveGameType(float t)
1318 {
1319         MapInfo_SwitchGameType(t);
1320         cvar_set("gamecfg", ftos(t));
1321         MapInfo_LoadedGametype = t;
1322 }
1323
1324 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1325 {
1326         float t;
1327
1328         t = MapInfo_CurrentGametype();
1329         MapInfo_LoadMapSettings_SaveGameType(t);
1330
1331         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1332         {
1333                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1334                 {
1335                         LOG_INFO("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1336                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1337                         return; // do not call Get_ByName!
1338                 }
1339
1340                 if(MapInfo_Map_supportedGametypes == 0)
1341                 {
1342                         LOG_INFO("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1343                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1344                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1345                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1346                         return; // do not call Get_ByName!
1347                 }
1348
1349                 t = 1;
1350                 while(!(MapInfo_Map_supportedGametypes & 1))
1351                 {
1352                         t *= 2;
1353                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1354                 }
1355
1356                 // t is now a supported mode!
1357                 LOG_INFO("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1358                 MapInfo_LoadMapSettings_SaveGameType(t);
1359         }
1360         MapInfo_Get_ByName(s, 1, t);
1361 }
1362
1363 void MapInfo_ClearTemps()
1364 {
1365         MapInfo_Map_bspname = string_null;
1366         MapInfo_Map_title = string_null;
1367         MapInfo_Map_titlestring = string_null;
1368         MapInfo_Map_description = string_null;
1369         MapInfo_Map_author = string_null;
1370         MapInfo_Map_clientstuff = string_null;
1371         MapInfo_Map_supportedGametypes = 0;
1372         MapInfo_Map_supportedFeatures = 0;
1373 }
1374
1375 void MapInfo_Shutdown()
1376 {
1377         MapInfo_ClearTemps();
1378         MapInfo_Filter_Free();
1379         MapInfo_Cache_Destroy();
1380         if(_MapInfo_globopen)
1381         {
1382                 search_end(_MapInfo_globhandle);
1383                 _MapInfo_globhandle = -1;
1384                 _MapInfo_globopen = false;
1385         }
1386 }
1387
1388 int MapInfo_ForbiddenFlags()
1389 {
1390         int f = MAPINFO_FLAG_FORBIDDEN;
1391
1392 #ifndef MENUQC
1393         if (!cvar("g_maplist_allow_hidden"))
1394 #endif
1395                 f |= MAPINFO_FLAG_HIDDEN;
1396
1397         if (!cvar("g_maplist_allow_frustrating"))
1398                 f |= MAPINFO_FLAG_FRUSTRATING;
1399
1400         return f;
1401 }
1402
1403 int MapInfo_RequiredFlags()
1404 {
1405         int f = 0;
1406
1407         if(cvar("g_maplist_allow_frustrating") > 1)
1408                 f |= MAPINFO_FLAG_FRUSTRATING;
1409
1410         return f;
1411 }