qcsrc/common/minigames/minigame/bd.qc

   1 REGISTER_MINIGAME(bd, "Bulldozer");
   2
   3 const int BD_TURN_MOVE  = 0x0100; // player must move the bulldozer
   4 const int BD_TURN_WIN   = 0x0200; // victory
   5 const int BD_TURN_LOSS  = 0x0400; // they did it?!
   6 const int BD_TURN_EDIT  = 0x0800; // editing mode
   7 const int BD_TURN_TYPE  = 0x0f00; // turn type mask
   8
   9 const int BD_SF_PLAYERMOVES = MINIG_SF_CUSTOM;
  10
  11 // 240 tiles...
  12 const int BD_LET_CNT = 20;
  13 const int BD_NUM_CNT = 20;
  14
  15 const int BD_TILE_SIZE = 20;
  16
  17 const int BD_TEAMS = 1;
  18
  19 .vector bd_dir;
  20
  21 .int bd_moves;
  22
  23 .string bd_levelname;
  24 .string bd_nextlevel;
  25
  26 #ifdef SVQC
  27 .bool bd_canedit;
  28 #endif
  29
  30 .int bd_tiletype;
  31 const int BD_TILE_DOZER = 1;
  32 const int BD_TILE_TARGET = 2;
  33 const int BD_TILE_BOULDER = 3;
  34 const int BD_TILE_BRICK1 = 4;
  35 const int BD_TILE_BRICK2 = 5;
  36 const int BD_TILE_BRICK3 = 6;
  37 const int BD_TILE_BRICK4 = 7;
  38 const int BD_TILE_BRICK5 = 8;
  39 const int BD_TILE_BRICK6 = 9;
  40 const int BD_TILE_BRICK7 = 10;
  41 const int BD_TILE_BRICK8 = 11;
  42 const int BD_TILE_LAST = 11;
  43
  44 string autocvar_sv_minigames_bulldozer_startlevel = "level1";
  45
  46 // find same game piece given its tile name
  47 entity bd_find_piece(entity minig, string tile, bool check_target)
  48 {
  49         entity e = world;
  50         while ( ( e = findentity(e,owner,minig) ) )
  51                 if ( e.classname == "minigame_board_piece" && e.netname == tile && ((check_target) ? e.bd_tiletype == BD_TILE_TARGET : e.bd_tiletype != BD_TILE_TARGET) )
  52                         return e;
  53         return world;
  54 }
  55
  56 // check if the tile name is valid (15x15 grid)
  57 bool bd_valid_tile(string tile)
  58 {
  59         if ( !tile )
  60                 return false;
  61         int number = minigame_tile_number(tile);
  62         int letter = minigame_tile_letter(tile);
  63         return 0 <= number && number < BD_NUM_CNT && 0 <= letter && letter < BD_LET_CNT;
  64 }
  65
  66 entity bd_find_dozer(entity minig)
  67 {
  68         entity e = world;
  69         while ( ( e = findentity(e,owner,minig) ) )
  70                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
  71                         return e;
  72         return world;
  73 }
  74
  75 void bd_check_winner(entity minig)
  76 {
  77         int total = 0, valid = 0;
  78         entity e = world;
  79         while ( ( e = findentity(e,owner,minig) ) )
  80                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET )
  81                 {
  82                         ++total;
  83                         if(bd_find_piece(minig, e.netname, false).bd_tiletype == BD_TILE_BOULDER)
  84                                 ++valid;
  85                 }
  86
  87         if(valid >= total)
  88         {
  89                 minig.minigame_flags = BD_TURN_WIN;
  90                 minigame_server_sendflags(minig,MINIG_SF_UPDATE);
  91         }
  92 }
  93
  94 bool bd_canfill(int ttype)
  95 {
  96         switch(ttype)
  97         {
  98                 case BD_TILE_BRICK8:
  99                 case BD_TILE_BRICK7:
 100                 case BD_TILE_BRICK6:
 101                 case BD_TILE_BRICK5:
 102                 case BD_TILE_BRICK4:
 103                 case BD_TILE_BRICK3:
 104                 case BD_TILE_BRICK2:
 105                 case BD_TILE_BRICK1: return true;
 106         }
 107
 108         return false;
 109 }
 110
 111 bool bd_move_dozer(entity minigame, entity dozer)
 112 {
 113         if(!dozer.bd_dir_x && !dozer.bd_dir_y)
 114                 return false; // nope!
 115
 116         int myx = minigame_tile_letter(dozer.netname);
 117         int myy = minigame_tile_number(dozer.netname);
 118
 119         myx += dozer.bd_dir_x;
 120         myy += dozer.bd_dir_y;
 121
 122         string newpos = minigame_tile_buildname(myx, myy);
 123         entity hit = bd_find_piece(minigame, newpos, false);
 124
 125         if(!bd_valid_tile(newpos))
 126                 return false;
 127
 128         if(hit)
 129         switch(hit.bd_tiletype)
 130         {
 131                 case BD_TILE_DOZER: // wtf, but let's do this incase
 132                 case BD_TILE_BRICK8:
 133                 case BD_TILE_BRICK7:
 134                 case BD_TILE_BRICK6:
 135                 case BD_TILE_BRICK5:
 136                 case BD_TILE_BRICK4:
 137                 case BD_TILE_BRICK3:
 138                 case BD_TILE_BRICK2:
 139                 case BD_TILE_BRICK1: return false;
 140                 case BD_TILE_BOULDER:
 141                 {
 142                         string testpos;
 143                         int tx = minigame_tile_letter(hit.netname);
 144                         int ty = minigame_tile_number(hit.netname);
 145
 146                         tx += dozer.bd_dir_x;
 147                         ty += dozer.bd_dir_y;
 148
 149                         testpos = minigame_tile_buildname(tx, ty);
 150                         entity testhit = bd_find_piece(minigame, testpos, false);
 151
 152                         if(!bd_valid_tile(testpos) || testhit)
 153                                 return false;
 154
 155                         if(hit.netname) { strunzone(hit.netname); }
 156                         hit.netname = strzone(testpos);
 157                         minigame_server_sendflags(hit,MINIG_SF_UPDATE);
 158                         break;
 159                 }
 160         }
 161
 162         if(dozer.netname) { strunzone(dozer.netname); }
 163         dozer.netname = strzone(newpos);
 164
 165         return true;
 166 }
 167
 168 // make a move
 169 void bd_move(entity minigame, entity player, string dir)
 170 {
 171         if ( minigame.minigame_flags & BD_TURN_MOVE )
 172         if ( dir )
 173         {
 174                 //if ( bd_valid_tile(pos) )
 175                 //if ( bd_find_piece(minigame, pos, false) )
 176                 {
 177                         entity dozer = bd_find_dozer(minigame);
 178                         if(!dozer)
 179                         {
 180                                 LOG_INFO("Dozer wasn't found!\n");
 181                                 return; // should not happen... TODO: end match?
 182                         }
 183
 184                         int dxs = 0, dys = 0;
 185                         string thedir = strtolower(dir);
 186                         if(thedir == "up" || thedir == "u") { dxs = 0; dys = 1; }
 187                         if(thedir == "down" || thedir == "dn" || thedir == "d") { dxs = 0; dys = -1; }
 188                         if(thedir == "left" || thedir == "lt" || thedir == "l") { dxs = -1; dys = 0; }
 189                         if(thedir == "right" || thedir == "rt" || thedir == "r") { dxs = 1; dys = 0; }
 190
 191                         int dx = bound(-1, dxs, 1);
 192                         int dy = bound(-1, dys, 1);
 193
 194                         dozer.bd_dir_x = dx;
 195                         dozer.bd_dir_y = dy;
 196                         dozer.bd_dir_z = 0;
 197
 198                         if(bd_move_dozer(minigame, dozer))
 199                                 player.bd_moves++;
 200
 201                         bd_check_winner(minigame);
 202
 203                         minigame_server_sendflags(dozer,MINIG_SF_UPDATE); // update anyway
 204                         minigame_server_sendflags(player,BD_SF_PLAYERMOVES);
 205                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 206                 }
 207         }
 208 }
 209
 210 // editor
 211 void bd_editor_place(entity minigame, entity player, string pos, int thetile, string thedir)
 212 {
 213         if ( minigame.minigame_flags & BD_TURN_EDIT )
 214         if ( pos && thetile )
 215         {
 216                 if ( bd_valid_tile(pos) )
 217                 {
 218                         entity found_piece = bd_find_piece(minigame, pos, false);
 219                         entity targ = bd_find_piece(minigame, pos, true);
 220
 221                         if(found_piece.bd_tiletype == BD_TILE_DOZER && thedir != "")
 222                         {
 223                                 int dxs = 0, dys = 0;
 224                                 string newdir = strtolower(thedir);
 225                                 if(newdir == "up" || newdir == "u") { dxs = 0; dys = 1; }
 226                                 if(newdir == "down" || newdir == "dn" || newdir == "d") { dxs = 0; dys = -1; }
 227                                 if(newdir == "left" || newdir == "lt" || newdir == "l") { dxs = -1; dys = 0; }
 228                                 if(newdir == "right" || newdir == "rt" || newdir == "r") { dxs = 1; dys = 0; }
 229
 230                                 int dx = bound(-1, dxs, 1);
 231                                 int dy = bound(-1, dys, 1);
 232
 233                                 found_piece.bd_dir_x = dx;
 234                                 found_piece.bd_dir_y = dy;
 235                                 found_piece.bd_dir_z = 0;
 236                                 minigame_server_sendflags(found_piece,MINIG_SF_UPDATE); // update anyway
 237                                 return;
 238                         }
 239
 240                         entity dozer = bd_find_dozer(minigame);
 241                         if(dozer && thetile == BD_TILE_DOZER && pos != dozer.netname)
 242                                 return; // nice try
 243
 244                         if(found_piece || (targ && thetile != BD_TILE_BOULDER))
 245                         {
 246                                 entity piece = bd_find_piece(minigame, pos, false);
 247                                 if(!piece) piece = bd_find_piece(minigame, pos, true);
 248                                 if(!piece)
 249                                         return; // how?!
 250
 251                                 if(piece.netname) { strunzone(piece.netname); }
 252                                 remove(piece);
 253                                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 254                                 return;
 255                         }
 256
 257                         entity piece = msle_spawn(minigame,"minigame_board_piece");
 258                         piece.team = 1;
 259                         piece.netname = strzone(pos);
 260                         piece.bd_tiletype = thetile;
 261                         piece.bd_dir = '0 -1 0';
 262                         minigame_server_sendflags(piece,MINIG_SF_UPDATE);
 263
 264                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 265                 }
 266         }
 267 }
 268
 269 void bd_do_move(entity minigame, entity player, string dir, string thetile, string thedir)
 270 {
 271         if(minigame.minigame_flags & BD_TURN_MOVE)
 272                 bd_move(minigame, player, dir);
 273
 274         if(minigame.minigame_flags & BD_TURN_EDIT)
 275                 bd_editor_place(minigame, player, dir, stof(thetile), thedir);
 276 }
 277
 278 void bd_fill_recurse(entity minigame, entity player, int thetype, int letter, int number)
 279 {
 280         string pos = minigame_tile_buildname(letter,number);
 281         if(!bd_valid_tile(pos))
 282                 return;
 283         if(bd_find_piece(minigame, pos, false) || bd_find_piece(minigame, pos, true))
 284                 return;
 285
 286         bd_editor_place(minigame, player, pos, thetype, "");
 287
 288         bd_fill_recurse(minigame, player, thetype, letter - 1, number);
 289         bd_fill_recurse(minigame, player, thetype, letter + 1, number);
 290         bd_fill_recurse(minigame, player, thetype, letter, number - 1);
 291         bd_fill_recurse(minigame, player, thetype, letter, number + 1);
 292 }
 293
 294 void bd_unfill_recurse(entity minigame, entity player, int thetype, int letter, int number)
 295 {
 296         string pos = minigame_tile_buildname(letter,number);
 297         if(!bd_valid_tile(pos))
 298                 return;
 299
 300         entity targ = bd_find_piece(minigame, pos, true);
 301         entity piece = bd_find_piece(minigame, pos, false);
 302
 303         if(targ && thetype == targ.bd_tiletype)
 304         {
 305                 if(targ.netname) { strunzone(targ.netname); }
 306                 remove(targ);
 307         }
 308         else if(piece && thetype == piece.bd_tiletype)
 309         {
 310                 if(piece.netname) { strunzone(piece.netname); }
 311                 remove(piece);
 312         }
 313         else return;
 314
 315         bd_unfill_recurse(minigame, player, thetype, letter - 1, number);
 316         bd_unfill_recurse(minigame, player, thetype, letter + 1, number);
 317         bd_unfill_recurse(minigame, player, thetype, letter, number - 1);
 318         bd_unfill_recurse(minigame, player, thetype, letter, number + 1);
 319 }
 320
 321 void bd_do_fill(entity minigame, entity player, string dir, string thetile)
 322 {
 323 #ifdef SVQC
 324         if(!player.minigame_players.bd_canedit)
 325         {
 326                 sprint(player.minigame_players, "You're not allowed to edit levels, sorry!\n");
 327                 return;
 328         }
 329 #endif
 330
 331         if(minigame.minigame_flags & BD_TURN_EDIT)
 332         {
 333                 int thetype = stof(thetile);
 334
 335                 entity targ = bd_find_piece(minigame, dir, true);
 336                 entity piece = bd_find_piece(minigame, dir, false);
 337
 338                 if(!bd_canfill(thetype) || (piece || targ))
 339                 {
 340                         int killtype = 0;
 341
 342                         if(targ) { killtype = targ.bd_tiletype; }
 343                         if(piece) { killtype = piece.bd_tiletype; }
 344
 345                         if(killtype)
 346                         {
 347                                 int letter = minigame_tile_letter(dir);
 348                                 int number = minigame_tile_number(dir);
 349                                 bd_unfill_recurse(minigame, player, killtype, letter, number);
 350                         }
 351
 352                         return;
 353                 }
 354
 355                 int letter = minigame_tile_letter(dir);
 356                 int number = minigame_tile_number(dir);
 357
 358                 bd_fill_recurse(minigame, player, thetype, letter, number);
 359         }
 360 }
 361
 362 void bd_reset_moves(entity minigame)
 363 {
 364         entity e;
 365 #ifdef SVQC
 366         for(e = minigame.minigame_players; e; e = e.list_next)
 367 #elif defined(CSQC)
 368         e = world;
 369         while( (e = findentity(e,owner,minigame)) )
 370                 if ( e.classname == "minigame_player" )
 371 #endif
 372                 {
 373                         e.bd_moves = 0;
 374                         minigame_server_sendflags(e,BD_SF_PLAYERMOVES);
 375                 }
 376 }
 377
 378 void bd_load_level(entity minigame);
 379 void bd_setup_pieces(entity minigame)
 380 {
 381         entity e = world;
 382         while( (e = findentity(e, owner, minigame)) )
 383                 if(e.classname == "minigame_board_piece")
 384                 {
 385                         if(e.netname) { strunzone(e.netname); }
 386                         remove(e);
 387                 }
 388
 389         bd_load_level(minigame);
 390 }
 391
 392 void bd_do_next_match(entity minigame, entity player)
 393 {
 394         minigame.minigame_flags = BD_TURN_MOVE;
 395         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 396
 397         if(minigame.bd_nextlevel && minigame.bd_nextlevel != "")
 398         {
 399                 if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 400                 minigame.bd_levelname = strzone(minigame.bd_nextlevel);
 401         }
 402
 403         bd_setup_pieces(minigame);
 404
 405         bd_reset_moves(minigame);
 406 }
 407
 408 void bd_set_next_match(entity minigame, string next)
 409 {
 410         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 411         minigame.bd_nextlevel = strzone(next);
 412 }
 413
 414 void bd_next_match(entity minigame, entity player, string next)
 415 {
 416         if(minigame.minigame_flags & BD_TURN_WIN)
 417                 bd_do_next_match(minigame, player);
 418         if(minigame.minigame_flags & BD_TURN_EDIT)
 419                 bd_set_next_match(minigame, next);
 420 }
 421
 422 // request a new match
 423 void bd_restart_match(entity minigame, entity player)
 424 {
 425         minigame.minigame_flags = BD_TURN_MOVE;
 426         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 427
 428         bd_setup_pieces(minigame);
 429
 430         bd_reset_moves(minigame);
 431 }
 432
 433 void bd_activate_editor(entity minigame, entity player)
 434 {
 435 #ifdef SVQC
 436         if(!player.minigame_players.bd_canedit)
 437         {
 438                 sprint(player.minigame_players, "You're not allowed to edit levels, sorry!\n");
 439                 return;
 440         }
 441 #endif
 442
 443         minigame.minigame_flags = BD_TURN_EDIT;
 444         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 445
 446         bd_reset_moves(minigame);
 447
 448         bd_setup_pieces(minigame);
 449 }
 450
 451 string bd_save_piece(entity minigame, entity e)
 452 {
 453         string bd_string = "";
 454
 455         bd_string = strcat(bd_string, "\"", e.netname, "\" ");
 456         bd_string = strcat(bd_string, ftos(e.bd_tiletype), " ");
 457         bd_string = strcat(bd_string, sprintf("\"%.9v\"", e.bd_dir));
 458
 459         return bd_string;
 460 }
 461
 462 void bd_set_nextlevel(entity minigame, string s)
 463 {
 464         tokenize_console(s);
 465
 466         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 467         minigame.bd_nextlevel = strzone(argv(2));
 468 }
 469
 470 entity bd_load_piece(entity minigame, string s)
 471 {
 472         // separate pieces between the ; symbols
 473         string bd_string = s;
 474
 475         tokenize_console(bd_string);
 476
 477         entity e = msle_spawn(minigame,"minigame_board_piece");
 478         e.team = 1;
 479         e.bd_dir = '0 -1 0';
 480
 481         int argv_num = 0;
 482         e.netname = strzone(argv(argv_num)); ++argv_num;
 483         e.bd_tiletype = stof(argv(argv_num)); ++argv_num;
 484         e.bd_dir = stov(argv(argv_num)); ++argv_num;
 485
 486         minigame_server_sendflags(e,MINIG_SF_ALL);
 487
 488         return e;
 489 }
 490
 491 bool bd_save_level(entity minigame)
 492 {
 493         if(minigame.bd_levelname && minigame.bd_levelname != "")
 494         {
 495                 int target_count = 0, boulder_count = 0;
 496                 entity piece = world;
 497                 while((piece = findentity(piece,owner,minigame)))
 498                 if(piece.classname == "minigame_board_piece")
 499                         if(piece.bd_tiletype == BD_TILE_BOULDER)
 500                                 ++boulder_count;
 501                         else if(piece.bd_tiletype == BD_TILE_TARGET)
 502                                 ++target_count;
 503
 504                 if(boulder_count != target_count)
 505                 {
 506                         LOG_INFO("Not enough targets or boulders, fix your level!\n");
 507                         return false;
 508                 }
 509
 510                 // saves all objects to the database file
 511                 string file_name;
 512                 float file_get;
 513
 514                 file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 515                 file_get = fopen(file_name, FILE_WRITE);
 516                 fputs(file_get, strcat("// bulldozer storage \"", minigame.bd_levelname, "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S"), "\n"));
 517
 518                 if(minigame.bd_nextlevel && minigame.bd_nextlevel != "" && fexists(strcat("minigames/bulldozer/storage_", minigame.bd_nextlevel, ".txt")))
 519                         fputs(file_get, strcat("nextlevel = \"", minigame.bd_nextlevel, "\"\n"));
 520
 521                 entity e = world;
 522                 while ( ( e = findentity(e,owner,minigame) ) )
 523                 if ( e.classname == "minigame_board_piece" )
 524                 {
 525                         // use a line of text for each object, listing all properties
 526                         fputs(file_get, strcat(bd_save_piece(minigame, e), "\n"));
 527                 }
 528                 fclose(file_get);
 529
 530                 return true;
 531         }
 532
 533         return false;
 534 }
 535
 536 void bd_load_level(entity minigame)
 537 {
 538         // loads all items from the database file
 539         string file_read, file_name;
 540         float file_get;
 541
 542         file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 543         file_get = fopen(file_name, FILE_READ);
 544         if(file_get < 0)
 545         {
 546                 LOG_INFO("^3BULLDOZER: ^7could not find storage file ^3", file_name, "^7, no items were loaded\n");
 547         }
 548         else
 549         {
 550                 for(;;)
 551                 {
 552                         file_read = fgets(file_get);
 553                         if(file_read == "")
 554                                 break;
 555                         if(substring(file_read, 0, 2) == "//")
 556                                 continue;
 557                         if(substring(file_read, 0, 1) == "#")
 558                                 continue;
 559                         if(substring(file_read, 0, 9) == "nextlevel")
 560                         {
 561                                 bd_set_nextlevel(minigame, file_read);
 562                                 continue;
 563                         }
 564
 565                         entity e;
 566                         e = bd_load_piece(minigame, file_read);
 567                 }
 568         }
 569         fclose(file_get);
 570 }
 571
 572 void bd_close_editor(entity minigame, entity player)
 573 {
 574 #ifdef SVQC
 575         if(!player.minigame_players.bd_canedit)
 576         {
 577                 sprint(player.minigame_players, "You're not allowed to edit levels, sorry!\n");
 578                 return;
 579         }
 580 #endif
 581
 582         entity dozer = bd_find_dozer(minigame);
 583         if(!dozer)
 584         {
 585                 LOG_INFO("You need to place a bulldozer on the level to save it!\n");
 586                 return;
 587         }
 588
 589         if(bd_save_level(minigame))
 590         {
 591                 minigame.minigame_flags = BD_TURN_MOVE;
 592                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 593         }
 594         else
 595         {
 596                 LOG_INFO("You need to set the level name!\n");
 597                 return;
 598         }
 599 }
 600
 601 #ifdef SVQC
 602
 603 // required function, handle server side events
 604 int bd_server_event(entity minigame, string event, ...)
 605 {
 606         switch(event)
 607         {
 608                 case "start":
 609                 {
 610                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 611                         minigame.bd_levelname = strzone(autocvar_sv_minigames_bulldozer_startlevel);
 612                         bd_setup_pieces(minigame);
 613                         minigame.minigame_flags = BD_TURN_MOVE;
 614
 615                         return true;
 616                 }
 617                 case "end":
 618                 {
 619                         entity e = world;
 620                         while( (e = findentity(e, owner, minigame)) )
 621                         if(e.classname == "minigame_board_piece")
 622                         {
 623                                 if(e.netname) { strunzone(e.netname); }
 624                                 remove(e);
 625                         }
 626
 627                         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 628                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 629                         return false;
 630                 }
 631                 case "join":
 632                 {
 633                         int pl_num = minigame_count_players(minigame);
 634
 635                         if(pl_num >= BD_TEAMS) { return false; }
 636
 637                         return 1;
 638                 }
 639                 case "cmd":
 640                 {
 641                         switch(argv(0))
 642                         {
 643                                 case "move":
 644                                         bd_do_move(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null), ((...(1,int)) >= 4 ? argv(3) : string_null));
 645                                         return true;
 646                                 case "next":
 647                                         bd_next_match(minigame,...(0,entity), ((...(1,int) >= 2 ? argv(1) : string_null)));
 648                                         return true;
 649                                 case "restart":
 650                                         bd_restart_match(minigame,...(0,entity));
 651                                         return true;
 652                                 case "edit":
 653                                         bd_activate_editor(minigame,...(0,entity));
 654                                         return true;
 655                                 case "save":
 656                                         bd_close_editor(minigame,...(0,entity));
 657                                         return true;
 658                                 case "fill":
 659                                         bd_do_fill(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null));
 660                                         return true;
 661                         }
 662
 663                         return false;
 664                 }
 665                 case "network_send":
 666                 {
 667                         entity sent = ...(0,entity);
 668                         int sf = ...(1,int);
 669                         if ( sent.classname == "minigame_board_piece" && (sf & MINIG_SF_UPDATE) )
 670                         {
 671                                 int letter = minigame_tile_letter(sent.netname);
 672                                 int number = minigame_tile_number(sent.netname);
 673
 674                                 WriteByte(MSG_ENTITY,letter);
 675                                 WriteByte(MSG_ENTITY,number);
 676
 677                                 WriteByte(MSG_ENTITY,sent.bd_tiletype);
 678
 679                                 int dx = sent.bd_dir_x;
 680                                 int dy = sent.bd_dir_y;
 681                                 if(dx == -1) dx = 2;
 682                                 if(dy == -1) dy = 2;
 683                                 WriteByte(MSG_ENTITY,dx);
 684                                 WriteByte(MSG_ENTITY,dy);
 685                         }
 686                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
 687                                 WriteShort(MSG_ENTITY,sent.bd_moves);
 688                         return false;
 689                 }
 690         }
 691
 692         return false;
 693 }
 694
 695
 696 #elif defined(CSQC)
 697
 698 int bd_curr_tile;
 699 string bd_curr_pos;
 700
 701 .entity bd_enemy;
 702 .bool bd_hide;
 703
 704 vector bd_boardpos; // HUD board position
 705 vector bd_boardsize;// HUD board size
 706
 707 string bd_get_tile_pic(int tileid)
 708 {
 709         switch(tileid)
 710         {
 711                 case BD_TILE_BOULDER: return "bd/boulder";
 712                 case BD_TILE_BRICK1: return "bd/brick1";
 713                 case BD_TILE_BRICK2: return "bd/brick2";
 714                 case BD_TILE_BRICK3: return "bd/brick3";
 715                 case BD_TILE_BRICK4: return "bd/brick4";
 716                 case BD_TILE_BRICK5: return "bd/brick5";
 717                 case BD_TILE_BRICK6: return "bd/brick6";
 718                 case BD_TILE_BRICK7: return "bd/brick7";
 719                 case BD_TILE_BRICK8: return "bd/brick8";
 720                 case BD_TILE_TARGET: return "bd/target";
 721                 case BD_TILE_DOZER: return "bd/dozer";
 722         }
 723
 724         return string_null;
 725 }
 726
 727 // Required function, draw the game board
 728 void bd_hud_board(vector pos, vector mySize)
 729 {
 730         minigame_hud_fitsqare(pos, mySize);
 731         bd_boardpos = pos;
 732         bd_boardsize = mySize;
 733
 734         minigame_hud_simpleboard(pos,mySize,minigame_texture("bd/board"));
 735
 736         vector tile_size = minigame_hud_denormalize_size('1 1 0' / BD_TILE_SIZE,pos,mySize);
 737         vector tile_pos;
 738
 739         entity e;
 740         FOREACH_MINIGAME_ENTITY(e)
 741         {
 742                 if(e.classname == "minigame_board_piece")
 743                 {
 744                         if(e.bd_tiletype == BD_TILE_TARGET)
 745                         {
 746                                 e.bd_enemy = world;
 747                                 e.bd_enemy = bd_find_piece(active_minigame, e.netname, false);
 748                         }
 749                         else if(e.bd_tiletype == BD_TILE_BOULDER)
 750                         {
 751                                 e.bd_hide = false; // reset either way
 752                                 e.bd_hide = ((bd_find_piece(active_minigame, e.netname, true)) != world);
 753                         }
 754                 }
 755         }
 756         FOREACH_MINIGAME_ENTITY(e)
 757         {
 758                 if ( e.classname == "minigame_board_piece" )
 759                 {
 760                         if(e.bd_tiletype != BD_TILE_DOZER && !e.bd_hide) // hide boulders
 761                         {
 762                                 tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 763                                 tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 764
 765                                 string thepiece = bd_get_tile_pic(e.bd_tiletype);
 766
 767                                 if(e.bd_enemy)
 768                                         thepiece = "bd/boulder_target";
 769
 770                                 minigame_drawpic_centered( tile_pos,
 771                                                 minigame_texture(thepiece),
 772                                                 tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 773                         }
 774                 }
 775         }
 776
 777         // draw dozers on top, always
 778         FOREACH_MINIGAME_ENTITY(e)
 779         {
 780                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
 781                 {
 782                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 783                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 784
 785                         vector thedir = e.bd_dir;
 786                         float theang = 0;
 787
 788                         if(thedir_y == -1) { theang = M_PI; }
 789                         if(thedir_x == 1) { theang = M_PI/2; }
 790                         if(thedir_x == -1) { theang = M_PI*3/2; }
 791
 792                         drawrotpic(tile_pos, theang, minigame_texture("bd/dozer"),
 793                                                 tile_size, tile_size/2, '1 1 1',
 794                                                 panel_fg_alpha, DRAWFLAG_NORMAL );
 795                 }
 796         }
 797
 798         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 799         if(bd_valid_tile(bd_curr_pos))
 800         {
 801                 entity piece = bd_find_piece(active_minigame, bd_curr_pos, false);
 802                 entity targ = bd_find_piece(active_minigame, bd_curr_pos, true);
 803                 string thepiece = ((piece || (targ && bd_curr_tile != BD_TILE_BOULDER)) ? "bd/delete" : bd_get_tile_pic(bd_curr_tile));
 804
 805                 tile_pos = minigame_tile_pos(bd_curr_pos,BD_LET_CNT,BD_NUM_CNT);
 806                 tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 807                 if(bd_curr_tile == BD_TILE_DOZER)
 808                 {
 809                         drawrotpic(tile_pos, M_PI, minigame_texture("bd/dozer"),
 810                                                 tile_size, tile_size/2, '1 1 1',
 811                                                 panel_fg_alpha/2, DRAWFLAG_NORMAL );
 812                 }
 813                 else
 814                 {
 815                         minigame_drawpic_centered( tile_pos,
 816                                         minigame_texture(thepiece),
 817                                         tile_size, '1 1 1', panel_fg_alpha/2, DRAWFLAG_NORMAL );
 818                 }
 819         }
 820
 821         if ( (active_minigame.minigame_flags & BD_TURN_LOSS) || (active_minigame.minigame_flags & BD_TURN_WIN) )
 822         {
 823                 vector winfs = hud_fontsize*2;
 824                 string victory_text = "Game over!";
 825
 826                 if(active_minigame.minigame_flags & BD_TURN_WIN)
 827                         victory_text = "Well done! Click 'Next Level' to continue";
 828
 829                 vector win_pos = pos+eY*(mySize_y-winfs_y)/2;
 830                 vector win_sz;
 831                 win_sz = minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 832                         sprintf("%s", victory_text),
 833                         winfs, 0, DRAWFLAG_NORMAL, 0.5);
 834
 835                 drawfill(win_pos-eY*hud_fontsize_y,win_sz+2*eY*hud_fontsize_y,'0.3 0.3 1',0.8,DRAWFLAG_ADDITIVE);
 836
 837                 minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 838                         sprintf("%s", victory_text),
 839                         winfs, panel_fg_alpha, DRAWFLAG_NORMAL, 0.5);
 840         }
 841 }
 842
 843
 844 // Required function, draw the game status panel
 845 void bd_hud_status(vector pos, vector mySize)
 846 {
 847         HUD_Panel_DrawBg(1);
 848         vector ts;
 849         ts = minigame_drawstring_wrapped(mySize_x,pos,active_minigame.descriptor.message,
 850                 hud_fontsize * 2, '0.25 0.47 0.72', panel_fg_alpha, DRAWFLAG_NORMAL,0.5);
 851
 852         pos_y += ts_y;
 853         mySize_y -= ts_y;
 854
 855         vector player_fontsize = hud_fontsize * 1.75;
 856         ts_y = ( mySize_y - 2*player_fontsize_y ) / BD_TEAMS;
 857         ts_x = mySize_x;
 858         vector mypos;
 859         vector tile_size = '48 48 0';
 860
 861         mypos = pos;
 862         drawfill(mypos,eX*mySize_x+eY*player_fontsize_y,'1 1 1',0.5,DRAWFLAG_ADDITIVE);
 863         mypos_y += player_fontsize_y;
 864         drawfill(mypos,eX*mySize_x+eY*tile_size_y,'1 1 1',0.25,DRAWFLAG_ADDITIVE);
 865
 866         entity e;
 867         FOREACH_MINIGAME_ENTITY(e)
 868         {
 869                 if ( e.classname == "minigame_player" )
 870                 {
 871                         mypos = pos;
 872                         minigame_drawcolorcodedstring_trunc(mySize_x,mypos,
 873                                 entcs_GetName(e.minigame_playerslot-1),
 874                                 player_fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 875
 876                         mypos_y += player_fontsize_y;
 877                         string thepiece = "bd/dozer";
 878                         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 879                                 thepiece = bd_get_tile_pic(bd_curr_tile);
 880                         drawpic( mypos,
 881                                         minigame_texture(thepiece),
 882                                         tile_size * 0.7, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 883
 884                         mypos_x += tile_size_x;
 885
 886                         drawstring(mypos,ftos(e.bd_moves),tile_size,
 887                                            '0.7 0.84 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 888                 }
 889         }
 890 }
 891
 892 // Turn a set of flags into a help message
 893 string bd_turn_to_string(int turnflags)
 894 {
 895         if ( turnflags & BD_TURN_LOSS )
 896                 return _("Better luck next time!");
 897
 898         if ( turnflags & BD_TURN_WIN )
 899                 if(random() > 0.5)
 900                         return _("Tubular! Press \"Next Level\" to continue!");
 901                 else
 902                         return _("Wicked! Press \"Next Level\" to continue!");
 903
 904         if( turnflags & BD_TURN_EDIT )
 905                 return _("Press the space bar to change your currently selected tile");
 906
 907         if ( turnflags & BD_TURN_MOVE )
 908                 return _("Push the boulders onto the targets");
 909
 910         return "";
 911 }
 912
 913 // Make the correct move
 914 void bd_make_move(entity minigame, string dir)
 915 {
 916         if ( minigame.minigame_flags == BD_TURN_MOVE )
 917         {
 918                 minigame_cmd("move ", dir);
 919         }
 920 }
 921
 922 void bd_editor_make_move(entity minigame, string dir)
 923 {
 924         if ( minigame.minigame_flags == BD_TURN_EDIT )
 925         {
 926                 minigame_cmd("move ", bd_curr_pos, " ", ftos(bd_curr_tile), " ", dir);
 927         }
 928 }
 929
 930 void bd_editor_fill(entity minigame)
 931 {
 932         if ( minigame.minigame_flags == BD_TURN_EDIT )
 933         {
 934                 minigame_cmd("fill ", bd_curr_pos, " ", ftos(bd_curr_tile));
 935         }
 936 }
 937
 938 void bd_set_curr_pos(string s)
 939 {
 940         if ( bd_curr_pos )
 941                 strunzone(bd_curr_pos);
 942         if ( s )
 943                 s = strzone(s);
 944         bd_curr_pos = s;
 945 }
 946
 947 bool bd_normal_move(entity minigame, int themove)
 948 {
 949         switch ( themove )
 950         {
 951                 case K_RIGHTARROW:
 952                 case K_KP_RIGHTARROW:
 953                         bd_make_move(minigame, "r");
 954                         return true;
 955                 case K_LEFTARROW:
 956                 case K_KP_LEFTARROW:
 957                         bd_make_move(minigame, "l");
 958                         return true;
 959                 case K_UPARROW:
 960                 case K_KP_UPARROW:
 961                         bd_make_move(minigame, "u");
 962                         return true;
 963                 case K_DOWNARROW:
 964                 case K_KP_DOWNARROW:
 965                         bd_make_move(minigame, "d");
 966                         return true;
 967         }
 968
 969         return false;
 970 }
 971
 972 bool bd_change_dozer_angle(entity minigame)
 973 {
 974         entity dozer = bd_find_piece(minigame, bd_curr_pos, false);
 975         if(!dozer || dozer.bd_tiletype != BD_TILE_DOZER)
 976                 return false;
 977
 978         string thedir = "";
 979         vector dir = dozer.bd_dir;
 980         if(dir.x == 0 && dir.y == 0) { thedir = "r"; }
 981
 982         if(dir.x == 0 && dir.y == 1) { thedir = "r"; }
 983         if(dir.x == 0 && dir.y ==-1) { thedir = "l"; }
 984         if(dir.x ==-1 && dir.y == 0) { thedir = "u"; }
 985         if(dir.x == 1 && dir.y == 0) { thedir = "d"; }
 986
 987         bd_editor_make_move(minigame, thedir);
 988         return true;
 989 }
 990
 991 bool bd_editor_move(entity minigame, int themove)
 992 {
 993         switch ( themove )
 994         {
 995                 case K_RIGHTARROW:
 996                 case K_KP_RIGHTARROW:
 997                         if ( ! bd_curr_pos )
 998                                 bd_set_curr_pos("a3");
 999                         else
1000                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,1,0,BD_NUM_CNT,BD_LET_CNT));
1001                         return true;
1002                 case K_LEFTARROW:
1003                 case K_KP_LEFTARROW:
1004                         if ( ! bd_curr_pos )
1005                                 bd_set_curr_pos("c3");
1006                         else
1007                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,-1,0,BD_NUM_CNT,BD_LET_CNT));
1008                         return true;
1009                 case K_UPARROW:
1010                 case K_KP_UPARROW:
1011                         if ( ! bd_curr_pos )
1012                                 bd_set_curr_pos("a1");
1013                         else
1014                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,1,BD_NUM_CNT,BD_LET_CNT));
1015                         return true;
1016                 case K_DOWNARROW:
1017                 case K_KP_DOWNARROW:
1018                         if ( ! bd_curr_pos )
1019                                 bd_set_curr_pos("a3");
1020                         else
1021                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,-1,BD_NUM_CNT,BD_LET_CNT));
1022                         return true;
1023                 case K_ENTER:
1024                 case K_KP_ENTER:
1025                         bd_editor_make_move(minigame, "");
1026                         return true;
1027                 case K_SPACE:
1028                         if(bd_change_dozer_angle(minigame))
1029                                 return true;
1030                         bd_curr_tile += 1;
1031                         if(bd_curr_tile > BD_TILE_LAST)
1032                                 bd_curr_tile = 1;
1033                         return true;
1034         }
1035
1036         return false;
1037 }
1038
1039 // Required function, handle client events
1040 int bd_client_event(entity minigame, string event, ...)
1041 {
1042         switch(event)
1043         {
1044                 case "activate":
1045                 {
1046                         minigame.message = bd_turn_to_string(minigame.minigame_flags);
1047                         bd_set_curr_pos("");
1048                         bd_curr_tile = BD_TILE_BRICK1;
1049                         return false;
1050                 }
1051                 case "key_pressed":
1052                 {
1053                         if(minigame.minigame_flags & BD_TURN_MOVE)
1054                         {
1055                                 if(bd_normal_move(minigame, ...(0,int)))
1056                                         return true;
1057                         }
1058
1059                         if(minigame.minigame_flags & BD_TURN_EDIT)
1060                         {
1061                                 if(bd_editor_move(minigame, ...(0,int)))
1062                                         return true;
1063                         }
1064
1065                         return false;
1066                 }
1067                 case "mouse_pressed":
1068                 {
1069                         if(minigame.minigame_flags & BD_TURN_EDIT)
1070                         {
1071                                 if(...(0,int) == K_MOUSE1)
1072                                 {
1073                                         bd_editor_make_move(minigame, "");
1074                                         return true;
1075                                 }
1076
1077                                 if(...(0,int) == K_MOUSE2)
1078                                 {
1079                                         bd_editor_fill(minigame);
1080                                         return true;
1081                                 }
1082                         }
1083
1084                         return false;
1085                 }
1086                 case "mouse_moved":
1087                 {
1088                         if(minigame.minigame_flags & BD_TURN_EDIT)
1089                         {
1090                                 vector mouse_pos = minigame_hud_normalize(mousepos,bd_boardpos,bd_boardsize);
1091                                 bd_set_curr_pos(minigame_tile_name(mouse_pos,BD_LET_CNT,BD_NUM_CNT));
1092                                 if ( ! bd_valid_tile(bd_curr_pos) )
1093                                         bd_set_curr_pos("");
1094                         }
1095                         return true;
1096                 }
1097                 case "network_receive":
1098                 {
1099                         entity sent = ...(0,entity);
1100                         int sf = ...(1,int);
1101                         if ( sent.classname == "minigame" )
1102                         {
1103                                 if ( sf & MINIG_SF_UPDATE )
1104                                 {
1105                                         sent.message = bd_turn_to_string(sent.minigame_flags);
1106                                         //if ( sent.minigame_flags & minigame_self.team )
1107                                                 minigame_prompt();
1108                                 }
1109                         }
1110                         else if(sent.classname == "minigame_board_piece")
1111                         {
1112                                 if(sf & MINIG_SF_UPDATE)
1113                                 {
1114                                         int letter = ReadByte();
1115                                         int number = ReadByte();
1116                                         if(sent.netname) { strunzone(sent.netname); }
1117                                         sent.netname = strzone(minigame_tile_buildname(letter, number));
1118
1119                                         sent.bd_tiletype = ReadByte();
1120
1121                                         int dx = ReadByte();
1122                                         int dy = ReadByte();
1123
1124                                         if(dx == 2) dx = -1;
1125                                         if(dy == 2) dy = -1;
1126
1127                                         sent.bd_dir_x = dx;
1128                                         sent.bd_dir_y = dy;
1129                                         sent.bd_dir_z = 0;
1130                                 }
1131                         }
1132                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
1133                                 sent.bd_moves = ReadShort(); // make this a byte when possible
1134
1135                         return false;
1136                 }
1137                 case "menu_show":
1138                 {
1139                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Next Level"),"next");
1140                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Restart"),"restart");
1141                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Editor"),"edit");
1142                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Save"),"save");
1143                         return false;
1144                 }
1145                 case "menu_click":
1146                 {
1147                         if(...(0,string) == "next")
1148                                 minigame_cmd("next");
1149                         if(...(0,string) == "restart")
1150                                 minigame_cmd("restart");
1151                         if(...(0,string) == "edit")
1152                                 minigame_cmd("edit");
1153                         if(...(0,string) == "save")
1154                                 minigame_cmd("save");
1155                         return false;
1156                 }
1157         }
1158
1159         return false;
1160 }
1161
1162 #endif