qcsrc/common/minigames/minigame/bd.qc

   1 REGISTER_MINIGAME(bd, "Bulldozer");
   2
   3 const int BD_TURN_MOVE  = 0x0100; // player must move the bulldozer
   4 const int BD_TURN_WIN   = 0x0200; // victory
   5 const int BD_TURN_LOSS  = 0x0400; // they did it?!
   6 const int BD_TURN_EDIT  = 0x0800; // editing mode
   7 const int BD_TURN_TYPE  = 0x0f00; // turn type mask
   8
   9 const int BD_SF_PLAYERMOVES = MINIG_SF_CUSTOM;
  10
  11 // 240 tiles...
  12 const int BD_LET_CNT = 20;
  13 const int BD_NUM_CNT = 20;
  14
  15 const int BD_TILE_SIZE = 20;
  16
  17 const int BD_TEAMS = 1;
  18
  19 .vector bd_dir;
  20
  21 .int bd_moves;
  22
  23 .string bd_levelname;
  24 .string bd_nextlevel;
  25
  26 #ifdef SVQC
  27 .bool bd_canedit;
  28 #endif
  29
  30 .int bd_tiletype;
  31 const int BD_TILE_DOZER = 1;
  32 const int BD_TILE_TARGET = 2;
  33 const int BD_TILE_BOULDER = 3;
  34 const int BD_TILE_BRICK1 = 4;
  35 const int BD_TILE_BRICK2 = 5;
  36 const int BD_TILE_BRICK3 = 6;
  37 const int BD_TILE_BRICK4 = 7;
  38 const int BD_TILE_BRICK5 = 8;
  39 const int BD_TILE_BRICK6 = 9;
  40 const int BD_TILE_LAST = 9;
  41
  42 string autocvar_sv_minigames_bulldozer_startlevel = "level1";
  43
  44 // find same game piece given its tile name
  45 entity bd_find_piece(entity minig, string tile, bool check_target)
  46 {
  47         entity e = world;
  48         while ( ( e = findentity(e,owner,minig) ) )
  49                 if ( e.classname == "minigame_board_piece" && e.netname == tile && ((check_target) ? e.bd_tiletype == BD_TILE_TARGET : e.bd_tiletype != BD_TILE_TARGET) )
  50                         return e;
  51         return world;
  52 }
  53
  54 // check if the tile name is valid (15x15 grid)
  55 bool bd_valid_tile(string tile)
  56 {
  57         if ( !tile )
  58                 return false;
  59         int number = minigame_tile_number(tile);
  60         int letter = minigame_tile_letter(tile);
  61         return 0 <= number && number < BD_NUM_CNT && 0 <= letter && letter < BD_LET_CNT;
  62 }
  63
  64 entity bd_find_dozer(entity minig)
  65 {
  66         entity e = world;
  67         while ( ( e = findentity(e,owner,minig) ) )
  68                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
  69                         return e;
  70         return world;
  71 }
  72
  73 void bd_check_winner(entity minig)
  74 {
  75         int total = 0, valid = 0;
  76         entity e = world;
  77         while ( ( e = findentity(e,owner,minig) ) )
  78                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET )
  79                 {
  80                         ++total;
  81                         if(bd_find_piece(minig, e.netname, false).bd_tiletype == BD_TILE_BOULDER)
  82                                 ++valid;
  83                 }
  84
  85         if(valid >= total)
  86         {
  87                 minig.minigame_flags = BD_TURN_WIN;
  88                 minigame_server_sendflags(minig,MINIG_SF_UPDATE);
  89         }
  90 }
  91
  92 bool bd_canfill(int ttype)
  93 {
  94         switch(ttype)
  95         {
  96                 case BD_TILE_BRICK6:
  97                 case BD_TILE_BRICK5:
  98                 case BD_TILE_BRICK4:
  99                 case BD_TILE_BRICK3:
 100                 case BD_TILE_BRICK2:
 101                 case BD_TILE_BRICK1: return true;
 102         }
 103
 104         return false;
 105 }
 106
 107 bool bd_move_dozer(entity minigame, entity dozer)
 108 {
 109         if(!dozer.bd_dir_x && !dozer.bd_dir_y)
 110                 return false; // nope!
 111
 112         int myx = minigame_tile_letter(dozer.netname);
 113         int myy = minigame_tile_number(dozer.netname);
 114
 115         myx += dozer.bd_dir_x;
 116         myy += dozer.bd_dir_y;
 117
 118         string newpos = minigame_tile_buildname(myx, myy);
 119         entity hit = bd_find_piece(minigame, newpos, false);
 120
 121         if(!bd_valid_tile(newpos))
 122                 return false;
 123
 124         if(hit)
 125         switch(hit.bd_tiletype)
 126         {
 127                 case BD_TILE_DOZER: // wtf, but let's do this incase
 128                 case BD_TILE_BRICK6:
 129                 case BD_TILE_BRICK5:
 130                 case BD_TILE_BRICK4:
 131                 case BD_TILE_BRICK3:
 132                 case BD_TILE_BRICK2:
 133                 case BD_TILE_BRICK1: return false;
 134                 case BD_TILE_BOULDER:
 135                 {
 136                         string testpos;
 137                         int tx = minigame_tile_letter(hit.netname);
 138                         int ty = minigame_tile_number(hit.netname);
 139
 140                         tx += dozer.bd_dir_x;
 141                         ty += dozer.bd_dir_y;
 142
 143                         testpos = minigame_tile_buildname(tx, ty);
 144                         entity testhit = bd_find_piece(minigame, testpos, false);
 145
 146                         if(!bd_valid_tile(testpos) || testhit)
 147                                 return false;
 148
 149                         if(hit.netname) { strunzone(hit.netname); }
 150                         hit.netname = strzone(testpos);
 151                         minigame_server_sendflags(hit,MINIG_SF_UPDATE);
 152                         break;
 153                 }
 154         }
 155
 156         if(dozer.netname) { strunzone(dozer.netname); }
 157         dozer.netname = strzone(newpos);
 158
 159         return true;
 160 }
 161
 162 // make a move
 163 void bd_move(entity minigame, entity player, string dir)
 164 {
 165         if ( minigame.minigame_flags & BD_TURN_MOVE )
 166         if ( dir )
 167         {
 168                 //if ( bd_valid_tile(pos) )
 169                 //if ( bd_find_piece(minigame, pos, false) )
 170                 {
 171                         entity dozer = bd_find_dozer(minigame);
 172                         if(!dozer)
 173                         {
 174                                 LOG_INFO("Dozer wasn't found!\n");
 175                                 return; // should not happen... TODO: end match?
 176                         }
 177
 178                         int dxs = 0, dys = 0;
 179                         string thedir = strtolower(dir);
 180                         if(thedir == "up" || thedir == "u") { dxs = 0; dys = 1; }
 181                         if(thedir == "down" || thedir == "dn" || thedir == "d") { dxs = 0; dys = -1; }
 182                         if(thedir == "left" || thedir == "lt" || thedir == "l") { dxs = -1; dys = 0; }
 183                         if(thedir == "right" || thedir == "rt" || thedir == "r") { dxs = 1; dys = 0; }
 184
 185                         int dx = bound(-1, dxs, 1);
 186                         int dy = bound(-1, dys, 1);
 187
 188                         dozer.bd_dir_x = dx;
 189                         dozer.bd_dir_y = dy;
 190                         dozer.bd_dir_z = 0;
 191
 192                         if(bd_move_dozer(minigame, dozer))
 193                                 player.bd_moves++;
 194
 195                         bd_check_winner(minigame);
 196
 197                         minigame_server_sendflags(dozer,MINIG_SF_UPDATE); // update anyway
 198                         minigame_server_sendflags(player,BD_SF_PLAYERMOVES);
 199                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 200                 }
 201         }
 202 }
 203
 204 // editor
 205 void bd_editor_place(entity minigame, entity player, string pos, int thetile, string thedir)
 206 {
 207         if ( minigame.minigame_flags & BD_TURN_EDIT )
 208         if ( pos && thetile )
 209         {
 210                 if ( bd_valid_tile(pos) )
 211                 {
 212                         entity found_piece = bd_find_piece(minigame, pos, false);
 213                         entity targ = bd_find_piece(minigame, pos, true);
 214
 215                         if(found_piece.bd_tiletype == BD_TILE_DOZER && thedir != "")
 216                         {
 217                                 int dxs = 0, dys = 0;
 218                                 string newdir = strtolower(thedir);
 219                                 if(newdir == "up" || newdir == "u") { dxs = 0; dys = 1; }
 220                                 if(newdir == "down" || newdir == "dn" || newdir == "d") { dxs = 0; dys = -1; }
 221                                 if(newdir == "left" || newdir == "lt" || newdir == "l") { dxs = -1; dys = 0; }
 222                                 if(newdir == "right" || newdir == "rt" || newdir == "r") { dxs = 1; dys = 0; }
 223
 224                                 int dx = bound(-1, dxs, 1);
 225                                 int dy = bound(-1, dys, 1);
 226
 227                                 found_piece.bd_dir_x = dx;
 228                                 found_piece.bd_dir_y = dy;
 229                                 found_piece.bd_dir_z = 0;
 230                                 minigame_server_sendflags(found_piece,MINIG_SF_UPDATE); // update anyway
 231                                 return;
 232                         }
 233
 234                         entity dozer = bd_find_dozer(minigame);
 235                         if(dozer && thetile == BD_TILE_DOZER && pos != dozer.netname)
 236                                 return; // nice try
 237
 238                         if(found_piece || (targ && thetile != BD_TILE_BOULDER))
 239                         {
 240                                 entity piece = bd_find_piece(minigame, pos, false);
 241                                 if(!piece) piece = bd_find_piece(minigame, pos, true);
 242                                 if(!piece)
 243                                         return; // how?!
 244
 245                                 if(piece.netname) { strunzone(piece.netname); }
 246                                 remove(piece);
 247                                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 248                                 return;
 249                         }
 250
 251                         entity piece = msle_spawn(minigame,"minigame_board_piece");
 252                         piece.team = 1;
 253                         piece.netname = strzone(pos);
 254                         piece.bd_tiletype = thetile;
 255                         piece.bd_dir = '0 -1 0';
 256                         minigame_server_sendflags(piece,MINIG_SF_UPDATE);
 257
 258                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 259                 }
 260         }
 261 }
 262
 263 void bd_do_move(entity minigame, entity player, string dir, string thetile, string thedir)
 264 {
 265         if(minigame.minigame_flags & BD_TURN_MOVE)
 266                 bd_move(minigame, player, dir);
 267
 268         if(minigame.minigame_flags & BD_TURN_EDIT)
 269                 bd_editor_place(minigame, player, dir, stof(thetile), thedir);
 270 }
 271
 272 void bd_fill_recurse(entity minigame, entity player, int thetype, int letter, int number)
 273 {
 274         string pos = minigame_tile_buildname(letter,number);
 275         if(!bd_valid_tile(pos))
 276                 return;
 277         if(bd_find_piece(minigame, pos, false) || bd_find_piece(minigame, pos, true))
 278                 return;
 279
 280         bd_editor_place(minigame, player, pos, thetype, "");
 281
 282         bd_fill_recurse(minigame, player, thetype, letter - 1, number);
 283         bd_fill_recurse(minigame, player, thetype, letter + 1, number);
 284         bd_fill_recurse(minigame, player, thetype, letter, number - 1);
 285         bd_fill_recurse(minigame, player, thetype, letter, number + 1);
 286 }
 287
 288 void bd_unfill_recurse(entity minigame, entity player, int thetype, int letter, int number)
 289 {
 290         string pos = minigame_tile_buildname(letter,number);
 291         if(!bd_valid_tile(pos))
 292                 return;
 293
 294         entity targ = bd_find_piece(minigame, pos, true);
 295         entity piece = bd_find_piece(minigame, pos, false);
 296
 297         if(targ && thetype == targ.bd_tiletype)
 298         {
 299                 if(targ.netname) { strunzone(targ.netname); }
 300                 remove(targ);
 301         }
 302         else if(piece && thetype == piece.bd_tiletype)
 303         {
 304                 if(piece.netname) { strunzone(piece.netname); }
 305                 remove(piece);
 306         }
 307         else return;
 308
 309         bd_unfill_recurse(minigame, player, thetype, letter - 1, number);
 310         bd_unfill_recurse(minigame, player, thetype, letter + 1, number);
 311         bd_unfill_recurse(minigame, player, thetype, letter, number - 1);
 312         bd_unfill_recurse(minigame, player, thetype, letter, number + 1);
 313 }
 314
 315 void bd_do_fill(entity minigame, entity player, string dir, string thetile)
 316 {
 317         if(minigame.minigame_flags & BD_TURN_EDIT)
 318         {
 319                 int thetype = stof(thetile);
 320
 321                 entity targ = bd_find_piece(minigame, dir, true);
 322                 entity piece = bd_find_piece(minigame, dir, false);
 323
 324                 if(!bd_canfill(thetype) || (piece || targ))
 325                 {
 326                         int killtype = 0;
 327
 328                         if(targ) { killtype = targ.bd_tiletype; }
 329                         if(piece) { killtype = piece.bd_tiletype; }
 330
 331                         if(killtype)
 332                         {
 333                                 int letter = minigame_tile_letter(dir);
 334                                 int number = minigame_tile_number(dir);
 335                                 bd_unfill_recurse(minigame, player, killtype, letter, number);
 336                         }
 337
 338                         return;
 339                 }
 340
 341                 int letter = minigame_tile_letter(dir);
 342                 int number = minigame_tile_number(dir);
 343
 344                 bd_fill_recurse(minigame, player, thetype, letter, number);
 345         }
 346 }
 347
 348 void bd_reset_moves(entity minigame)
 349 {
 350         entity e;
 351 #ifdef SVQC
 352         for(e = minigame.minigame_players; e; e = e.list_next)
 353 #elif defined(CSQC)
 354         e = world;
 355         while( (e = findentity(e,owner,minigame)) )
 356                 if ( e.classname == "minigame_player" )
 357 #endif
 358                 {
 359                         e.bd_moves = 0;
 360                         minigame_server_sendflags(e,BD_SF_PLAYERMOVES);
 361                 }
 362 }
 363
 364 void bd_load_level(entity minigame);
 365 void bd_setup_pieces(entity minigame)
 366 {
 367         entity e = world;
 368         while( (e = findentity(e, owner, minigame)) )
 369                 if(e.classname == "minigame_board_piece")
 370                 {
 371                         if(e.netname) { strunzone(e.netname); }
 372                         remove(e);
 373                 }
 374
 375         bd_load_level(minigame);
 376 }
 377
 378 void bd_do_next_match(entity minigame, entity player)
 379 {
 380         minigame.minigame_flags = BD_TURN_MOVE;
 381         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 382
 383         if(minigame.bd_nextlevel && minigame.bd_nextlevel != "")
 384         {
 385                 if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 386                 minigame.bd_levelname = strzone(minigame.bd_nextlevel);
 387         }
 388
 389         bd_setup_pieces(minigame);
 390
 391         bd_reset_moves(minigame);
 392 }
 393
 394 void bd_set_next_match(entity minigame, string next)
 395 {
 396         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 397         minigame.bd_nextlevel = strzone(next);
 398 }
 399
 400 void bd_next_match(entity minigame, entity player, string next)
 401 {
 402         if(minigame.minigame_flags & BD_TURN_WIN)
 403                 bd_do_next_match(minigame, player);
 404         if(minigame.minigame_flags & BD_TURN_EDIT)
 405                 bd_set_next_match(minigame, next);
 406 }
 407
 408 // request a new match
 409 void bd_restart_match(entity minigame, entity player)
 410 {
 411         minigame.minigame_flags = BD_TURN_MOVE;
 412         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 413
 414         bd_setup_pieces(minigame);
 415
 416         bd_reset_moves(minigame);
 417 }
 418
 419 void bd_activate_editor(entity minigame, entity player)
 420 {
 421 #ifdef SVQC
 422         if(!player.minigame_players.bd_canedit)
 423         {
 424                 sprint(player.minigame_players, "You're not allowed to edit levels, sorry!\n");
 425                 return;
 426         }
 427 #endif
 428
 429         minigame.minigame_flags = BD_TURN_EDIT;
 430         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 431
 432         bd_reset_moves(minigame);
 433
 434         bd_setup_pieces(minigame);
 435 }
 436
 437 string bd_save_piece(entity minigame, entity e)
 438 {
 439         string bd_string = "";
 440
 441         bd_string = strcat(bd_string, "\"", e.netname, "\" ");
 442         bd_string = strcat(bd_string, ftos(e.bd_tiletype), " ");
 443         bd_string = strcat(bd_string, sprintf("\"%.9v\"", e.bd_dir));
 444
 445         return bd_string;
 446 }
 447
 448 void bd_set_nextlevel(entity minigame, string s)
 449 {
 450         tokenize_console(s);
 451
 452         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 453         minigame.bd_nextlevel = strzone(argv(2));
 454 }
 455
 456 entity bd_load_piece(entity minigame, string s)
 457 {
 458         // separate pieces between the ; symbols
 459         string bd_string = s;
 460
 461         tokenize_console(bd_string);
 462
 463         entity e = msle_spawn(minigame,"minigame_board_piece");
 464         e.team = 1;
 465         e.bd_dir = '0 -1 0';
 466
 467         int argv_num = 0;
 468         e.netname = strzone(argv(argv_num)); ++argv_num;
 469         e.bd_tiletype = stof(argv(argv_num)); ++argv_num;
 470         e.bd_dir = stov(argv(argv_num)); ++argv_num;
 471
 472         minigame_server_sendflags(e,MINIG_SF_ALL);
 473
 474         return e;
 475 }
 476
 477 bool bd_save_level(entity minigame)
 478 {
 479         if(minigame.bd_levelname && minigame.bd_levelname != "")
 480         {
 481                 int target_count = 0, boulder_count = 0;
 482                 entity piece = world;
 483                 while((piece = findentity(piece,owner,minigame)))
 484                 if(piece.classname == "minigame_board_piece")
 485                         if(piece.bd_tiletype == BD_TILE_BOULDER)
 486                                 ++boulder_count;
 487                         else if(piece.bd_tiletype == BD_TILE_TARGET)
 488                                 ++target_count;
 489
 490                 if(boulder_count != target_count)
 491                 {
 492                         LOG_INFO("Not enough targets or boulders, fix your level!\n");
 493                         return false;
 494                 }
 495
 496                 // saves all objects to the database file
 497                 string file_name;
 498                 float file_get;
 499
 500                 file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 501                 file_get = fopen(file_name, FILE_WRITE);
 502                 fputs(file_get, strcat("// bulldozer storage \"", minigame.bd_levelname, "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S"), "\n"));
 503
 504                 if(minigame.bd_nextlevel && minigame.bd_nextlevel != "" && fexists(strcat("minigames/bulldozer/storage_", minigame.bd_nextlevel, ".txt")))
 505                         fputs(file_get, strcat("nextlevel = \"", minigame.bd_nextlevel, "\"\n"));
 506
 507                 entity e = world;
 508                 while ( ( e = findentity(e,owner,minigame) ) )
 509                 if ( e.classname == "minigame_board_piece" )
 510                 {
 511                         // use a line of text for each object, listing all properties
 512                         fputs(file_get, strcat(bd_save_piece(minigame, e), "\n"));
 513                 }
 514                 fclose(file_get);
 515
 516                 return true;
 517         }
 518
 519         return false;
 520 }
 521
 522 void bd_load_level(entity minigame)
 523 {
 524         // loads all items from the database file
 525         string file_read, file_name;
 526         float file_get;
 527
 528         file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 529         file_get = fopen(file_name, FILE_READ);
 530         if(file_get < 0)
 531         {
 532                 LOG_INFO("^3BULLDOZER: ^7could not find storage file ^3", file_name, "^7, no items were loaded\n");
 533         }
 534         else
 535         {
 536                 for(;;)
 537                 {
 538                         file_read = fgets(file_get);
 539                         if(file_read == "")
 540                                 break;
 541                         if(substring(file_read, 0, 2) == "//")
 542                                 continue;
 543                         if(substring(file_read, 0, 1) == "#")
 544                                 continue;
 545                         if(substring(file_read, 0, 9) == "nextlevel")
 546                         {
 547                                 bd_set_nextlevel(minigame, file_read);
 548                                 continue;
 549                         }
 550
 551                         entity e;
 552                         e = bd_load_piece(minigame, file_read);
 553                 }
 554         }
 555         fclose(file_get);
 556 }
 557
 558 void bd_close_editor(entity minigame)
 559 {
 560         entity dozer = bd_find_dozer(minigame);
 561         if(!dozer)
 562         {
 563                 LOG_INFO("You need to place a bulldozer on the level to save it!\n");
 564                 return;
 565         }
 566
 567         if(bd_save_level(minigame))
 568         {
 569                 minigame.minigame_flags = BD_TURN_MOVE;
 570                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 571         }
 572         else
 573         {
 574                 LOG_INFO("You need to set the level name!\n");
 575                 return;
 576         }
 577 }
 578
 579 #ifdef SVQC
 580
 581 // required function, handle server side events
 582 int bd_server_event(entity minigame, string event, ...)
 583 {
 584         switch(event)
 585         {
 586                 case "start":
 587                 {
 588                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 589                         minigame.bd_levelname = strzone(autocvar_sv_minigames_bulldozer_startlevel);
 590                         bd_setup_pieces(minigame);
 591                         minigame.minigame_flags = BD_TURN_MOVE;
 592
 593                         return true;
 594                 }
 595                 case "end":
 596                 {
 597                         entity e = world;
 598                         while( (e = findentity(e, owner, minigame)) )
 599                         if(e.classname == "minigame_board_piece")
 600                         {
 601                                 if(e.netname) { strunzone(e.netname); }
 602                                 remove(e);
 603                         }
 604
 605                         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 606                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 607                         return false;
 608                 }
 609                 case "join":
 610                 {
 611                         int pl_num = minigame_count_players(minigame);
 612
 613                         if(pl_num >= BD_TEAMS) { return false; }
 614
 615                         return 1;
 616                 }
 617                 case "cmd":
 618                 {
 619                         switch(argv(0))
 620                         {
 621                                 case "move":
 622                                         bd_do_move(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null), ((...(1,int)) >= 4 ? argv(3) : string_null));
 623                                         return true;
 624                                 case "next":
 625                                         bd_next_match(minigame,...(0,entity), ((...(1,int) >= 2 ? argv(1) : string_null)));
 626                                         return true;
 627                                 case "restart":
 628                                         bd_restart_match(minigame,...(0,entity));
 629                                         return true;
 630                                 case "edit":
 631                                         bd_activate_editor(minigame,...(0,entity));
 632                                         return true;
 633                                 case "save":
 634                                         bd_close_editor(minigame);
 635                                         return true;
 636                                 case "fill":
 637                                         bd_do_fill(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null));
 638                                         return true;
 639                         }
 640
 641                         return false;
 642                 }
 643                 case "network_send":
 644                 {
 645                         entity sent = ...(0,entity);
 646                         int sf = ...(1,int);
 647                         if ( sent.classname == "minigame_board_piece" && (sf & MINIG_SF_UPDATE) )
 648                         {
 649                                 int letter = minigame_tile_letter(sent.netname);
 650                                 int number = minigame_tile_number(sent.netname);
 651
 652                                 WriteByte(MSG_ENTITY,letter);
 653                                 WriteByte(MSG_ENTITY,number);
 654
 655                                 WriteByte(MSG_ENTITY,sent.bd_tiletype);
 656
 657                                 int dx = sent.bd_dir_x;
 658                                 int dy = sent.bd_dir_y;
 659                                 if(dx == -1) dx = 2;
 660                                 if(dy == -1) dy = 2;
 661                                 WriteByte(MSG_ENTITY,dx);
 662                                 WriteByte(MSG_ENTITY,dy);
 663                         }
 664                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
 665                                 WriteShort(MSG_ENTITY,sent.bd_moves);
 666                         return false;
 667                 }
 668         }
 669
 670         return false;
 671 }
 672
 673
 674 #elif defined(CSQC)
 675
 676 int bd_curr_tile;
 677 string bd_curr_pos;
 678
 679 vector bd_boardpos; // HUD board position
 680 vector bd_boardsize;// HUD board size
 681
 682 string bd_get_tile_pic(int tileid)
 683 {
 684         switch(tileid)
 685         {
 686                 case BD_TILE_BOULDER: return "bd/boulder";
 687                 case BD_TILE_BRICK1: return "bd/brick1";
 688                 case BD_TILE_BRICK2: return "bd/brick2";
 689                 case BD_TILE_BRICK3: return "bd/brick3";
 690                 case BD_TILE_BRICK4: return "bd/brick4";
 691                 case BD_TILE_BRICK5: return "bd/brick5";
 692                 case BD_TILE_BRICK6: return "bd/brick6";
 693                 case BD_TILE_TARGET: return "bd/target";
 694                 case BD_TILE_DOZER: return "bd/dozer";
 695         }
 696
 697         return string_null;
 698 }
 699
 700 // Required function, draw the game board
 701 void bd_hud_board(vector pos, vector mySize)
 702 {
 703         minigame_hud_fitsqare(pos, mySize);
 704         bd_boardpos = pos;
 705         bd_boardsize = mySize;
 706
 707         minigame_hud_simpleboard(pos,mySize,minigame_texture("bd/board"));
 708
 709         vector tile_size = minigame_hud_denormalize_size('1 1 0' / BD_TILE_SIZE,pos,mySize);
 710         vector tile_pos;
 711
 712         entity e;
 713         FOREACH_MINIGAME_ENTITY(e)
 714         {
 715                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype != BD_TILE_TARGET && e.bd_tiletype != BD_TILE_DOZER )
 716                 {
 717                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 718                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 719
 720                         string thepiece = bd_get_tile_pic(e.bd_tiletype);
 721
 722                         minigame_drawpic_centered( tile_pos,
 723                                         minigame_texture(thepiece),
 724                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 725                 }
 726
 727                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET && e.bd_tiletype != BD_TILE_DOZER )
 728                 {
 729                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 730                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 731
 732                         minigame_drawpic_centered( tile_pos,
 733                                         minigame_texture("bd/target"),
 734                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 735                 }
 736
 737                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype != BD_TILE_TARGET && e.bd_tiletype == BD_TILE_DOZER )
 738                 {
 739                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 740                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 741
 742                         vector thedir = e.bd_dir;
 743                         float theang = 0;
 744
 745                         if(thedir_y == -1) { theang = M_PI; }
 746                         if(thedir_x == 1) { theang = M_PI/2; }
 747                         if(thedir_x == -1) { theang = M_PI*3/2; }
 748
 749                         drawrotpic(tile_pos, theang, minigame_texture("bd/dozer"),
 750                                                 tile_size, tile_size/2, '1 1 1',
 751                                                 panel_fg_alpha, DRAWFLAG_NORMAL );
 752                 }
 753         }
 754
 755         FOREACH_MINIGAME_ENTITY(e)
 756         {
 757                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET )
 758                 {
 759                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 760                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 761
 762                         minigame_drawpic_centered( tile_pos,
 763                                         minigame_texture("bd/target"),
 764                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 765                 }
 766         }
 767
 768         FOREACH_MINIGAME_ENTITY(e)
 769         {
 770                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
 771                 {
 772                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 773                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 774
 775                         vector thedir = e.bd_dir;
 776                         float theang = 0;
 777
 778                         if(thedir_y == -1) { theang = M_PI; }
 779                         if(thedir_x == 1) { theang = M_PI/2; }
 780                         if(thedir_x == -1) { theang = M_PI*3/2; }
 781
 782                         drawrotpic(tile_pos, theang, minigame_texture("bd/dozer"),
 783                                                 tile_size, tile_size/2, '1 1 1',
 784                                                 panel_fg_alpha, DRAWFLAG_NORMAL );
 785                 }
 786         }
 787
 788         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 789         if(bd_valid_tile(bd_curr_pos))
 790         {
 791                 entity piece = bd_find_piece(active_minigame, bd_curr_pos, false);
 792                 entity targ = bd_find_piece(active_minigame, bd_curr_pos, true);
 793                 string thepiece = ((piece || (targ && bd_curr_tile != BD_TILE_BOULDER)) ? "bd/delete" : bd_get_tile_pic(bd_curr_tile));
 794
 795                 tile_pos = minigame_tile_pos(bd_curr_pos,BD_LET_CNT,BD_NUM_CNT);
 796                 tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 797                 if(bd_curr_tile == BD_TILE_DOZER)
 798                 {
 799                         drawrotpic(tile_pos, M_PI, minigame_texture("bd/dozer"),
 800                                                 tile_size, tile_size/2, '1 1 1',
 801                                                 panel_fg_alpha/2, DRAWFLAG_NORMAL );
 802                 }
 803                 else
 804                 {
 805                         minigame_drawpic_centered( tile_pos,
 806                                         minigame_texture(thepiece),
 807                                         tile_size, '1 1 1', panel_fg_alpha/2, DRAWFLAG_NORMAL );
 808                 }
 809         }
 810
 811         if ( (active_minigame.minigame_flags & BD_TURN_LOSS) || (active_minigame.minigame_flags & BD_TURN_WIN) )
 812         {
 813                 vector winfs = hud_fontsize*2;
 814                 string victory_text = "Game over!";
 815
 816                 if(active_minigame.minigame_flags & BD_TURN_WIN)
 817                         victory_text = "Well done! Click 'Next Level' to continue";
 818
 819                 vector win_pos = pos+eY*(mySize_y-winfs_y)/2;
 820                 vector win_sz;
 821                 win_sz = minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 822                         sprintf("%s", victory_text),
 823                         winfs, 0, DRAWFLAG_NORMAL, 0.5);
 824
 825                 drawfill(win_pos-eY*hud_fontsize_y,win_sz+2*eY*hud_fontsize_y,'0.3 0.3 1',0.8,DRAWFLAG_ADDITIVE);
 826
 827                 minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 828                         sprintf("%s", victory_text),
 829                         winfs, panel_fg_alpha, DRAWFLAG_NORMAL, 0.5);
 830         }
 831 }
 832
 833
 834 // Required function, draw the game status panel
 835 void bd_hud_status(vector pos, vector mySize)
 836 {
 837         HUD_Panel_DrawBg(1);
 838         vector ts;
 839         ts = minigame_drawstring_wrapped(mySize_x,pos,active_minigame.descriptor.message,
 840                 hud_fontsize * 2, '0.25 0.47 0.72', panel_fg_alpha, DRAWFLAG_NORMAL,0.5);
 841
 842         pos_y += ts_y;
 843         mySize_y -= ts_y;
 844
 845         vector player_fontsize = hud_fontsize * 1.75;
 846         ts_y = ( mySize_y - 2*player_fontsize_y ) / BD_TEAMS;
 847         ts_x = mySize_x;
 848         vector mypos;
 849         vector tile_size = '48 48 0';
 850
 851         mypos = pos;
 852         drawfill(mypos,eX*mySize_x+eY*player_fontsize_y,'1 1 1',0.5,DRAWFLAG_ADDITIVE);
 853         mypos_y += player_fontsize_y;
 854         drawfill(mypos,eX*mySize_x+eY*tile_size_y,'1 1 1',0.25,DRAWFLAG_ADDITIVE);
 855
 856         entity e;
 857         FOREACH_MINIGAME_ENTITY(e)
 858         {
 859                 if ( e.classname == "minigame_player" )
 860                 {
 861                         mypos = pos;
 862                         minigame_drawcolorcodedstring_trunc(mySize_x,mypos,
 863                                 GetPlayerName(e.minigame_playerslot-1),
 864                                 player_fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 865
 866                         mypos_y += player_fontsize_y;
 867                         string thepiece = "bd/dozer";
 868                         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 869                                 thepiece = bd_get_tile_pic(bd_curr_tile);
 870                         drawpic( mypos,
 871                                         minigame_texture(thepiece),
 872                                         tile_size * 0.7, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 873
 874                         mypos_x += tile_size_x;
 875
 876                         drawstring(mypos,ftos(e.bd_moves),tile_size,
 877                                            '0.7 0.84 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 878                 }
 879         }
 880 }
 881
 882 // Turn a set of flags into a help message
 883 string bd_turn_to_string(int turnflags)
 884 {
 885         if ( turnflags & BD_TURN_LOSS )
 886                 return _("Better luck next time!");
 887
 888         if ( turnflags & BD_TURN_WIN )
 889                 if(random() > 0.5)
 890                         return _("Tubular! Press \"Next Level\" to continue!");
 891                 else
 892                         return _("Wicked! Press \"Next Level\" to continue!");
 893
 894         if( turnflags & BD_TURN_EDIT )
 895                 return _("Press the space bar to change your currently selected tile");
 896
 897         if ( turnflags & BD_TURN_MOVE )
 898                 return _("Push the boulders onto the targets");
 899
 900         return "";
 901 }
 902
 903 // Make the correct move
 904 void bd_make_move(entity minigame, string dir)
 905 {
 906         if ( minigame.minigame_flags == BD_TURN_MOVE )
 907         {
 908                 minigame_cmd("move ", dir);
 909         }
 910 }
 911
 912 void bd_editor_make_move(entity minigame, string dir)
 913 {
 914         if ( minigame.minigame_flags == BD_TURN_EDIT )
 915         {
 916                 minigame_cmd("move ", bd_curr_pos, " ", ftos(bd_curr_tile), " ", dir);
 917         }
 918 }
 919
 920 void bd_editor_fill(entity minigame)
 921 {
 922         if ( minigame.minigame_flags == BD_TURN_EDIT )
 923         {
 924                 minigame_cmd("fill ", bd_curr_pos, " ", ftos(bd_curr_tile));
 925         }
 926 }
 927
 928 void bd_set_curr_pos(string s)
 929 {
 930         if ( bd_curr_pos )
 931                 strunzone(bd_curr_pos);
 932         if ( s )
 933                 s = strzone(s);
 934         bd_curr_pos = s;
 935 }
 936
 937 bool bd_normal_move(entity minigame, int themove)
 938 {
 939         switch ( themove )
 940         {
 941                 case K_RIGHTARROW:
 942                 case K_KP_RIGHTARROW:
 943                         bd_make_move(minigame, "r");
 944                         return true;
 945                 case K_LEFTARROW:
 946                 case K_KP_LEFTARROW:
 947                         bd_make_move(minigame, "l");
 948                         return true;
 949                 case K_UPARROW:
 950                 case K_KP_UPARROW:
 951                         bd_make_move(minigame, "u");
 952                         return true;
 953                 case K_DOWNARROW:
 954                 case K_KP_DOWNARROW:
 955                         bd_make_move(minigame, "d");
 956                         return true;
 957         }
 958
 959         return false;
 960 }
 961
 962 bool bd_change_dozer_angle(entity minigame)
 963 {
 964         entity dozer = bd_find_piece(minigame, bd_curr_pos, false);
 965         if(!dozer || dozer.bd_tiletype != BD_TILE_DOZER)
 966                 return false;
 967
 968         string thedir = "";
 969         vector dir = dozer.bd_dir;
 970         if(dir.x == 0 && dir.y == 0) { thedir = "r"; }
 971
 972         if(dir.x == 0 && dir.y == 1) { thedir = "r"; }
 973         if(dir.x == 0 && dir.y ==-1) { thedir = "l"; }
 974         if(dir.x ==-1 && dir.y == 0) { thedir = "u"; }
 975         if(dir.x == 1 && dir.y == 0) { thedir = "d"; }
 976
 977         bd_editor_make_move(minigame, thedir);
 978         return true;
 979 }
 980
 981 bool bd_editor_move(entity minigame, int themove)
 982 {
 983         switch ( themove )
 984         {
 985                 case K_RIGHTARROW:
 986                 case K_KP_RIGHTARROW:
 987                         if ( ! bd_curr_pos )
 988                                 bd_set_curr_pos("a3");
 989                         else
 990                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,1,0,BD_NUM_CNT,BD_LET_CNT));
 991                         return true;
 992                 case K_LEFTARROW:
 993                 case K_KP_LEFTARROW:
 994                         if ( ! bd_curr_pos )
 995                                 bd_set_curr_pos("c3");
 996                         else
 997                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,-1,0,BD_NUM_CNT,BD_LET_CNT));
 998                         return true;
 999                 case K_UPARROW:
1000                 case K_KP_UPARROW:
1001                         if ( ! bd_curr_pos )
1002                                 bd_set_curr_pos("a1");
1003                         else
1004                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,1,BD_NUM_CNT,BD_LET_CNT));
1005                         return true;
1006                 case K_DOWNARROW:
1007                 case K_KP_DOWNARROW:
1008                         if ( ! bd_curr_pos )
1009                                 bd_set_curr_pos("a3");
1010                         else
1011                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,-1,BD_NUM_CNT,BD_LET_CNT));
1012                         return true;
1013                 case K_ENTER:
1014                 case K_KP_ENTER:
1015                         bd_editor_make_move(minigame, "");
1016                         return true;
1017                 case K_SPACE:
1018                         if(bd_change_dozer_angle(minigame))
1019                                 return true;
1020                         bd_curr_tile += 1;
1021                         if(bd_curr_tile > BD_TILE_LAST)
1022                                 bd_curr_tile = 1;
1023                         return true;
1024         }
1025
1026         return false;
1027 }
1028
1029 // Required function, handle client events
1030 int bd_client_event(entity minigame, string event, ...)
1031 {
1032         switch(event)
1033         {
1034                 case "activate":
1035                 {
1036                         minigame.message = bd_turn_to_string(minigame.minigame_flags);
1037                         bd_set_curr_pos("");
1038                         bd_curr_tile = BD_TILE_BRICK1;
1039                         return false;
1040                 }
1041                 case "key_pressed":
1042                 {
1043                         if(minigame.minigame_flags & BD_TURN_MOVE)
1044                         {
1045                                 if(bd_normal_move(minigame, ...(0,int)))
1046                                         return true;
1047                         }
1048
1049                         if(minigame.minigame_flags & BD_TURN_EDIT)
1050                         {
1051                                 if(bd_editor_move(minigame, ...(0,int)))
1052                                         return true;
1053                         }
1054
1055                         return false;
1056                 }
1057                 case "mouse_pressed":
1058                 {
1059                         if(minigame.minigame_flags & BD_TURN_EDIT)
1060                         {
1061                                 if(...(0,int) == K_MOUSE1)
1062                                 {
1063                                         bd_editor_make_move(minigame, "");
1064                                         return true;
1065                                 }
1066
1067                                 if(...(0,int) == K_MOUSE2)
1068                                 {
1069                                         bd_editor_fill(minigame);
1070                                         return true;
1071                                 }
1072                         }
1073
1074                         return false;
1075                 }
1076                 case "mouse_moved":
1077                 {
1078                         if(minigame.minigame_flags & BD_TURN_EDIT)
1079                         {
1080                                 vector mouse_pos = minigame_hud_normalize(mousepos,bd_boardpos,bd_boardsize);
1081                                 bd_set_curr_pos(minigame_tile_name(mouse_pos,BD_LET_CNT,BD_NUM_CNT));
1082                                 if ( ! bd_valid_tile(bd_curr_pos) )
1083                                         bd_set_curr_pos("");
1084                         }
1085                         return true;
1086                 }
1087                 case "network_receive":
1088                 {
1089                         entity sent = ...(0,entity);
1090                         int sf = ...(1,int);
1091                         if ( sent.classname == "minigame" )
1092                         {
1093                                 if ( sf & MINIG_SF_UPDATE )
1094                                 {
1095                                         sent.message = bd_turn_to_string(sent.minigame_flags);
1096                                         //if ( sent.minigame_flags & minigame_self.team )
1097                                                 minigame_prompt();
1098                                 }
1099                         }
1100                         else if(sent.classname == "minigame_board_piece")
1101                         {
1102                                 if(sf & MINIG_SF_UPDATE)
1103                                 {
1104                                         int letter = ReadByte();
1105                                         int number = ReadByte();
1106                                         if(sent.netname) { strunzone(sent.netname); }
1107                                         sent.netname = strzone(minigame_tile_buildname(letter, number));
1108
1109                                         sent.bd_tiletype = ReadByte();
1110
1111                                         int dx = ReadByte();
1112                                         int dy = ReadByte();
1113
1114                                         if(dx == 2) dx = -1;
1115                                         if(dy == 2) dy = -1;
1116
1117                                         sent.bd_dir_x = dx;
1118                                         sent.bd_dir_y = dy;
1119                                         sent.bd_dir_z = 0;
1120                                 }
1121                         }
1122                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
1123                                 sent.bd_moves = ReadShort(); // make this a byte when possible
1124
1125                         return false;
1126                 }
1127                 case "menu_show":
1128                 {
1129                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Next Level"),"next");
1130                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Restart"),"restart");
1131                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Editor"),"edit");
1132                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Save"),"save");
1133                         return false;
1134                 }
1135                 case "menu_click":
1136                 {
1137                         if(...(0,string) == "next")
1138                                 minigame_cmd("next");
1139                         if(...(0,string) == "restart")
1140                                 minigame_cmd("restart");
1141                         if(...(0,string) == "edit")
1142                                 minigame_cmd("edit");
1143                         if(...(0,string) == "save")
1144                                 minigame_cmd("save");
1145                         return false;
1146                 }
1147         }
1148
1149         return false;
1150 }
1151
1152 #endif