qcsrc/common/minigames/sv_minigames.qc

   1 #include "minigames.qh"
   2
   3 void player_clear_minigame(entity player)
   4 {
   5         player.active_minigame = world;
   6         player.minigame_players = world;
   7         if ( IS_PLAYER(player) )
   8                 player.movetype = MOVETYPE_WALK;
   9         else
  10                 player.movetype = MOVETYPE_FLY_WORLDONLY;
  11         player.team_forced = 0;
  12 }
  13
  14 void minigame_rmplayer(entity minigame_session, entity player)
  15 {
  16         entity e;
  17         entity p = minigame_session.minigame_players;
  18
  19         if ( p.minigame_players == player )
  20         {
  21                 if ( p.list_next == world )
  22                 {
  23                         end_minigame(minigame_session);
  24                         return;
  25                 }
  26                 minigame_session.minigame_event(minigame_session,"part",player);
  27                 GameLogEcho(strcat(":minigame:part:",minigame_session.netname,":",
  28                         ftos(num_for_edict(player)),":",player.netname));
  29                 minigame_session.minigame_players = p.list_next;
  30                 remove ( p );
  31                 player_clear_minigame(player);
  32         }
  33         else
  34         {
  35                 for ( e = p.list_next; e != world; e = e.list_next )
  36                 {
  37                         if ( e.minigame_players == player )
  38                         {
  39                                 minigame_session.minigame_event(minigame_session,"part",player);
  40                                 GameLogEcho(strcat(":minigame:part:",minigame_session.netname,":",
  41                                         ftos(num_for_edict(player)),":",player.netname));
  42                                 p.list_next = e.list_next;
  43                                 remove(e);
  44                                 player_clear_minigame(player);
  45                                 return;
  46                         }
  47                         p = e;
  48                 }
  49         }
  50 }
  51
  52
  53 #define FIELD(Flags, Type,Name) if ( sf & (Flags) ) Write##Type(MSG_ENTITY, self.Name);
  54 #define WriteVector(to,Name) WriteCoord(to,Name##_x); WriteCoord(to,Name##_y); WriteCoord(to,Name##_z)
  55 #define WriteVector2D(to,Name) WriteCoord(to,Name##_x); WriteCoord(to,Name##_y)
  56 #define MSLE(Name,Fields) \
  57         else if ( self.classname == #Name ) { \
  58                 if ( sf & MINIG_SF_CREATE ) WriteString(MSG_ENTITY,self.owner.netname); \
  59                 Fields }
  60
  61 // Send an entity to a client
  62 // only use on minigame entities or entities with a minigame owner
  63 bool minigame_SendEntity(entity this, entity to, int sf)
  64 {
  65         WriteByte(MSG_ENTITY, ENT_CLIENT_MINIGAME);
  66         WriteByte(MSG_ENTITY, sf);
  67
  68         if ( sf & MINIG_SF_CREATE )
  69         {
  70                 WriteShort(MSG_ENTITY,msle_id(self.classname));
  71                 WriteString(MSG_ENTITY,self.netname);
  72         }
  73
  74         entity minigame_ent = self.owner;
  75
  76         if ( self.classname == "minigame" )
  77         {
  78                 minigame_ent = self;
  79
  80                 if ( sf & MINIG_SF_CREATE )
  81                         WriteString(MSG_ENTITY,self.descriptor.netname);
  82
  83                 if ( sf & MINIG_SF_UPDATE )
  84                         WriteLong(MSG_ENTITY,self.minigame_flags);
  85         }
  86         else if ( self.classname == "minigame_player" )
  87         {
  88                 if ( sf & MINIG_SF_CREATE )
  89                 {
  90                         WriteString(MSG_ENTITY,self.owner.netname);
  91                         WriteLong(MSG_ENTITY,num_for_edict(self.minigame_players));
  92                 }
  93                 if ( sf & MINIG_SF_UPDATE )
  94                         WriteByte(MSG_ENTITY,self.team);
  95         }
  96         MINIGAME_SIMPLELINKED_ENTITIES
  97
  98         minigame_ent.minigame_event(minigame_ent,"network_send",self,sf);
  99
 100         return true;
 101
 102 }
 103 #undef FIELD
 104 #undef MSLE
 105
 106 // Force resend all minigame entities
 107 void minigame_resend(entity minigame)
 108 {
 109         minigame.SendFlags = MINIG_SF_ALL;
 110         entity e = world;
 111         while (( e = findentity(e,owner,minigame) ))
 112         {
 113                 e.SendFlags = MINIG_SF_ALL;
 114         }
 115 }
 116
 117 bool minigame_CheckSend()
 118 {SELFPARAM();
 119         entity e;
 120         for ( e = self.owner.minigame_players; e != world; e = e.list_next )
 121                 if ( e.minigame_players == other )
 122                         return true;
 123         return false;
 124 }
 125
 126 int minigame_addplayer(entity minigame_session, entity player)
 127 {SELFPARAM();
 128         if ( player.active_minigame )
 129         {
 130                 if ( player.active_minigame == minigame_session )
 131                         return 0;
 132                 minigame_rmplayer(player.active_minigame,player);
 133         }
 134         entity player_pointer = new(minigame_player);
 135         int mgteam = minigame_session.minigame_event(minigame_session,"join",player,player_pointer);
 136
 137         if ( mgteam )
 138         {
 139                 player_pointer.owner = minigame_session;
 140                 player_pointer.minigame_players = player;
 141                 player_pointer.team = mgteam;
 142                 player_pointer.list_next = minigame_session.minigame_players;
 143                 minigame_session.minigame_players = player_pointer;
 144                 player.active_minigame = minigame_session;
 145                 player.minigame_players = player_pointer;
 146                 player_pointer.customizeentityforclient = minigame_CheckSend;
 147                 Net_LinkEntity(player_pointer, false, 0, minigame_SendEntity);
 148
 149                 if ( !IS_OBSERVER(player) && autocvar_sv_minigames_observer )
 150                 {
 151                         WITH(entity, self, player, PutObserverInServer());
 152                 }
 153                 if ( autocvar_sv_minigames_observer == 2 )
 154                         player.team_forced = -1;
 155
 156                 minigame_resend(minigame_session);
 157         }
 158         else { remove(player_pointer); }
 159         GameLogEcho(strcat(":minigame:join",(mgteam?"":"fail"),":",minigame_session.netname,":",
 160                 ftos(num_for_edict(player)),":",player.netname));
 161
 162         return mgteam;
 163 }
 164
 165 entity start_minigame(entity player, string minigame )
 166 {
 167         if ( !autocvar_sv_minigames || !IS_REAL_CLIENT(player) )
 168                 return world;
 169
 170         entity e = minigame_get_descriptor(minigame);
 171         if ( e )
 172         {
 173                 entity minig = new(minigame);
 174                 minig.netname = strzone(strcat(e.netname,"_",ftos(num_for_edict(minig))));
 175                 minig.descriptor = e;
 176                 minig.minigame_event = e.minigame_event;
 177                 minig.minigame_event(minig,"start");
 178                 GameLogEcho(strcat(":minigame:start:",minig.netname));
 179                 if ( ! minigame_addplayer(minig,player) )
 180                 {
 181                         LOG_TRACE("Minigame ",minig.netname," rejected the first player join!\n");
 182                         end_minigame(minig);
 183                         return world;
 184                 }
 185                 Net_LinkEntity(minig, false, 0, minigame_SendEntity);
 186
 187                 if ( !minigame_sessions )
 188                         minigame_sessions = minig;
 189                 else
 190                 {
 191                         minigame_sessions.owner = minig;
 192                         minig.list_next = minigame_sessions;
 193                         minigame_sessions = minig;
 194                 }
 195                 return minig;
 196         }
 197
 198         return world;
 199 }
 200
 201 entity join_minigame(entity player, string game_id )
 202 {
 203         if ( !autocvar_sv_minigames || !IS_REAL_CLIENT(player) )
 204                 return world;
 205
 206         entity minig;
 207         for ( minig = minigame_sessions; minig != world; minig = minig.list_next )
 208         {
 209                 if ( minig.netname == game_id )
 210                 if ( minigame_addplayer(minig,player) )
 211                         return minig;
 212         }
 213
 214         return world;
 215 }
 216
 217 void part_minigame(entity player )
 218 {
 219         entity minig = player.active_minigame;
 220
 221         if ( minig && minig.classname == "minigame" )
 222                 minigame_rmplayer(minig,player);
 223 }
 224
 225 void end_minigame(entity minigame_session)
 226 {
 227         if ( minigame_session.owner )
 228                 minigame_session.owner.list_next = minigame_session.list_next;
 229         else
 230                 minigame_sessions = minigame_session.list_next;
 231
 232         minigame_session.minigame_event(minigame_session,"end");
 233         GameLogEcho(strcat(":minigame:end:",minigame_session.netname));
 234
 235
 236         entity e = world;
 237         while( (e = findentity(e, owner, minigame_session)) )
 238                 if ( e.minigame_autoclean )
 239                 {
 240                         LOG_TRACE("SV Auto-cleaned: ",ftos(num_for_edict(e)), " (",e.classname,")\n");
 241                         remove(e);
 242                 }
 243
 244         entity p;
 245         for ( e = minigame_session.minigame_players; e != world; e = p )
 246         {
 247                 p = e.list_next;
 248                 player_clear_minigame(e.minigame_players);
 249                 remove(e);
 250         }
 251
 252         strunzone(minigame_session.netname);
 253         remove(minigame_session);
 254 }
 255
 256 void end_minigames()
 257 {
 258         while ( minigame_sessions )
 259         {
 260                 end_minigame(minigame_sessions);
 261         }
 262 }
 263
 264 string invite_minigame(entity inviter, entity player)
 265 {
 266         if ( !inviter || !inviter.active_minigame )
 267                 return "Invalid minigame";
 268         if ( !VerifyClientEntity(player, true, false) )
 269                 return "Invalid player";
 270         if ( inviter == player )
 271                 return "You can't invite yourself";
 272         if ( player.active_minigame == inviter.active_minigame )
 273                 return strcat(player.netname," is already playing");
 274
 275         Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_MINIGAME_INVITE,
 276                 inviter.active_minigame.netname, inviter.netname );
 277
 278         GameLogEcho(strcat(":minigame:invite:",inviter.active_minigame.netname,":",
 279                 ftos(num_for_edict(player)),":",player.netname));
 280
 281         return "";
 282 }
 283
 284 entity minigame_find_player(entity client)
 285 {
 286         if ( ! client.active_minigame )
 287                 return world;
 288         entity e;
 289         for ( e = client.active_minigame.minigame_players; e; e = e.list_next )
 290                 if ( e.minigame_players == client )
 291                         return e;
 292         return world;
 293 }
 294
 295 bool MinigameImpulse(int imp)
 296 {SELFPARAM();
 297         entity e = minigame_find_player(self);
 298         if ( imp && self.active_minigame && e )
 299         {
 300                 return self.active_minigame.minigame_event(self.active_minigame,"impulse",e,imp);
 301         }
 302         return false;
 303 }
 304
 305
 306
 307 void ClientCommand_minigame(int request, int argc, string command)
 308 {SELFPARAM();
 309         if ( !autocvar_sv_minigames )
 310         {
 311                 sprint(self,"Minigames are not enabled!\n");
 312                 return;
 313         }
 314
 315         if (request == CMD_REQUEST_COMMAND )
 316         {
 317                 string minig_cmd = argv(1);
 318                 if ( minig_cmd == "create" && argc > 2 )
 319                 {
 320                         entity minig = start_minigame(self, argv(2));
 321                         if ( minig )
 322                                 sprint(self,"Created minigame session: ",minig.netname,"\n");
 323                         else
 324                                 sprint(self,"Cannot start minigame session!\n");
 325                         return;
 326                 }
 327                 else if ( minig_cmd == "join" && argc > 2 )
 328                 {
 329                         entity minig = join_minigame(self, argv(2));
 330                         if ( minig )
 331                                 sprint(self,"Joined: ",minig.netname,"\n");
 332                         else
 333                         {
 334                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_JOIN_PREVENT_MINIGAME);
 335                                 sprint(self,"Cannot join given minigame session!\n");
 336                         }
 337                         return;
 338                 }
 339                 else if ( minig_cmd == "list" )
 340                 {
 341                         FOREACH(Minigames, true, LAMBDA(
 342                         {
 343                                 sprint(self,it.netname," (",it.message,") ","\n");
 344                         }));
 345                         return;
 346                 }
 347                 else if ( minig_cmd == "list-sessions" )
 348                 {
 349                         entity e;
 350                         for ( e = minigame_sessions; e != world; e = e.list_next )
 351                                 sprint(self,e.netname,"\n");
 352                         return;
 353                 }
 354                 else if ( minig_cmd == "end" || minig_cmd == "part" )
 355                 {
 356                         if ( self.active_minigame )
 357                         {
 358                                 part_minigame(self);
 359                                 sprint(self,"Left minigame session\n");
 360                         }
 361                         else
 362                                 sprint(self,"You aren't playing any minigame...\n");
 363                         return;
 364                 }
 365                 else if ( minig_cmd == "invite" && argc > 2 )
 366                 {
 367                         if ( self.active_minigame )
 368                         {
 369                                 entity client = GetIndexedEntity(argc, 2);
 370                                 string error = invite_minigame(self,client);
 371                                 if ( error == "" )
 372                                 {
 373                                         sprint(self,"You have invited ",client.netname,
 374                                                 " to join your game of ", self.active_minigame.descriptor.message, "\n");
 375                                 }
 376                                 else
 377                                         sprint(self,"Could not invite: ", error, ".\n");
 378                         }
 379                         else
 380                                 sprint(self,"You aren't playing any minigame...\n");
 381                         return;
 382                 }
 383                 else if ( self.active_minigame )
 384                 {
 385                         entity e = minigame_find_player(self);
 386                         string subcommand = substring(command,argv_end_index(0),-1);
 387                         int arg_c = tokenize_console(subcommand);
 388                         if ( self.active_minigame.minigame_event(self.active_minigame,"cmd",e,arg_c,subcommand) )
 389                                 return;
 390
 391                 }
 392                 else sprint(self,strcat("Wrong command:^1 ",command,"\n"));
 393         }
 394
 395         sprint(self, "\nUsage:^3 cmd minigame create <minigame>\n");
 396         sprint(self, "  Start a new minigame session\n");
 397         sprint(self, "Usage:^3 cmd minigame join <session>\n");
 398         sprint(self, "  Join an exising minigame session\n");
 399         sprint(self, "Usage:^3 cmd minigame list\n");
 400         sprint(self, "  List available minigames\n");
 401         sprint(self, "Usage:^3 cmd minigame list-sessions\n");
 402         sprint(self, "  List available minigames sessions\n");
 403         sprint(self, "Usage:^3 cmd minigame part|end\n");
 404         sprint(self, "  Leave the current minigame\n");
 405         sprint(self, "Usage:^3 cmd minigame invite <player>\n");
 406         sprint(self, "  Invite the given player to join you in a minigame\n");
 407 }