qcsrc/common/monsters/monster/mage.qc

   1 #ifndef MAGE_H
   2 #define MAGE_H
   3
   4 #ifndef MENUQC
   5 MODEL(MON_MAGE, M_Model("mage.dpm"));
   6 #endif
   7
   8 CLASS(Mage, Monster)
   9     ATTRIB(Mage, spawnflags, int, MON_FLAG_MELEE | MON_FLAG_RANGED);
  10     ATTRIB(Mage, mins, vector, '-36 -36 -24');
  11     ATTRIB(Mage, maxs, vector, '36 36 50');
  12 #ifndef MENUQC
  13     ATTRIB(Mage, m_model, Model, MDL_MON_MAGE);
  14 #endif
  15     ATTRIB(Mage, netname, string, "mage");
  16     ATTRIB(Mage, monster_name, string, _("Mage"));
  17 ENDCLASS(Mage)
  18
  19 REGISTER_MONSTER(MAGE, NEW(Mage)) {
  20 #ifndef MENUQC
  21     this.mr_precache(this);
  22 #endif
  23 }
  24
  25 #include <common/weapons/all.qh>
  26 #include <common/items/all.qc>
  27
  28 CLASS(MageSpike, PortoLaunch)
  29 /* flags     */ ATTRIB(MageSpike, spawnflags, int, WEP_TYPE_OTHER | WEP_FLAG_HIDDEN | WEP_FLAG_MUTATORBLOCKED);
  30 /* impulse   */ ATTRIB(MageSpike, impulse, int, 9);
  31 /* refname   */ ATTRIB(MageSpike, netname, string, "magespike");
  32 /* wepname   */ ATTRIB(MageSpike, m_name, string, _("Mage spike"));
  33 ENDCLASS(MageSpike)
  34 REGISTER_WEAPON(MAGE_SPIKE, NEW(MageSpike));
  35
  36 #endif
  37
  38 #ifdef IMPLEMENTATION
  39
  40 #ifdef SVQC
  41
  42 SOUND(MageSpike_FIRE, W_Sound("electro_fire"));
  43 void M_Mage_Attack_Spike(entity this, vector dir);
  44 void M_Mage_Attack_Push(entity this);
  45 METHOD(MageSpike, wr_think, void(MageSpike thiswep, entity actor, .entity weaponentity, int fire)) {
  46     if (fire & 1)
  47     if (!IS_PLAYER(actor) || weapon_prepareattack(thiswep, actor, weaponentity, false, 0.2)) {
  48         if (!actor.target_range) actor.target_range = autocvar_g_monsters_target_range;
  49         actor.enemy = Monster_FindTarget(actor);
  50         W_SetupShot_Dir(actor, v_forward, false, 0, SND(MageSpike_FIRE), CH_WEAPON_B, 0);
  51         if (!IS_PLAYER(actor)) w_shotdir = normalize((actor.enemy.origin + '0 0 10') - actor.origin);
  52         M_Mage_Attack_Spike(actor, w_shotdir);
  53         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, w_ready);
  54     }
  55     if (fire & 2)
  56     if (!IS_PLAYER(actor) || weapon_prepareattack(thiswep, actor, weaponentity, true, 0.5)) {
  57         M_Mage_Attack_Push(actor);
  58         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, 0, w_ready);
  59     }
  60 }
  61
  62 void M_Mage_Attack_Teleport(entity this, entity targ);
  63
  64 CLASS(OffhandMageTeleport, OffhandWeapon)
  65     .bool OffhandMageTeleport_key_pressed;
  66     METHOD(OffhandMageTeleport, offhand_think, void(OffhandMageTeleport this, entity player, bool key_pressed))
  67     {
  68         if (key_pressed && !player.OffhandMageTeleport_key_pressed)
  69                 M_Mage_Attack_Teleport(player, player.enemy);
  70         player.OffhandMageTeleport_key_pressed = key_pressed;
  71     }
  72 ENDCLASS(OffhandMageTeleport)
  73 OffhandMageTeleport OFFHAND_MAGE_TELEPORT; STATIC_INIT(OFFHAND_MAGE_TELEPORT) { OFFHAND_MAGE_TELEPORT = NEW(OffhandMageTeleport); }
  74
  75 float autocvar_g_monster_mage_health;
  76 float autocvar_g_monster_mage_damageforcescale = 0.5;
  77 float autocvar_g_monster_mage_attack_spike_damage;
  78 float autocvar_g_monster_mage_attack_spike_radius;
  79 float autocvar_g_monster_mage_attack_spike_delay;
  80 float autocvar_g_monster_mage_attack_spike_accel;
  81 float autocvar_g_monster_mage_attack_spike_decel;
  82 float autocvar_g_monster_mage_attack_spike_turnrate;
  83 float autocvar_g_monster_mage_attack_spike_speed_max;
  84 float autocvar_g_monster_mage_attack_spike_smart;
  85 float autocvar_g_monster_mage_attack_spike_smart_trace_min;
  86 float autocvar_g_monster_mage_attack_spike_smart_trace_max;
  87 float autocvar_g_monster_mage_attack_spike_smart_mindist;
  88 float autocvar_g_monster_mage_attack_push_damage;
  89 float autocvar_g_monster_mage_attack_push_radius;
  90 float autocvar_g_monster_mage_attack_push_delay;
  91 float autocvar_g_monster_mage_attack_push_force;
  92 float autocvar_g_monster_mage_heal_self;
  93 float autocvar_g_monster_mage_heal_allies;
  94 float autocvar_g_monster_mage_heal_minhealth;
  95 float autocvar_g_monster_mage_heal_range;
  96 float autocvar_g_monster_mage_heal_delay;
  97 float autocvar_g_monster_mage_shield_time;
  98 float autocvar_g_monster_mage_shield_delay;
  99 float autocvar_g_monster_mage_shield_blockpercent;
 100 float autocvar_g_monster_mage_speed_stop;
 101 float autocvar_g_monster_mage_speed_run;
 102 float autocvar_g_monster_mage_speed_walk;
 103
 104 /*
 105 const float mage_anim_idle              = 0;
 106 const float mage_anim_walk              = 1;
 107 const float mage_anim_attack    = 2;
 108 const float mage_anim_pain              = 3;
 109 const float mage_anim_death             = 4;
 110 const float mage_anim_run               = 5;
 111 */
 112
 113 void M_Mage_Defend_Heal(entity this);
 114 void M_Mage_Defend_Shield(entity this);
 115
 116 .entity mage_spike;
 117 .float mage_shield_delay;
 118 .float mage_shield_time;
 119
 120 bool M_Mage_Defend_Heal_Check(entity this, entity targ)
 121 {
 122         if(targ == world)
 123                 return false;
 124         if(targ.health <= 0)
 125                 return false;
 126         if(DIFF_TEAM(targ, this) && targ != this.monster_follow)
 127                 return false;
 128         if(STAT(FROZEN, targ))
 129                 return false;
 130         if(!IS_PLAYER(targ))
 131                 return (IS_MONSTER(targ) && targ.health < targ.max_health);
 132         if(targ.items & ITEM_Shield.m_itemid)
 133                 return false;
 134
 135         switch(this.skin)
 136         {
 137                 case 0: return (targ.health < autocvar_g_balance_health_regenstable);
 138                 case 1: return ((targ.ammo_cells && targ.ammo_cells < g_pickup_cells_max) || (targ.ammo_plasma && targ.ammo_plasma < g_pickup_plasma_max) || (targ.ammo_rockets && targ.ammo_rockets < g_pickup_rockets_max) || (targ.ammo_nails && targ.ammo_nails < g_pickup_nails_max) || (targ.ammo_shells && targ.ammo_shells < g_pickup_shells_max));
 139                 case 2: return (targ.armorvalue < autocvar_g_balance_armor_regenstable);
 140                 case 3: return (targ.health > 0);
 141         }
 142
 143         return false;
 144 }
 145
 146 void M_Mage_Attack_Spike_Explode(entity this)
 147 {
 148         this.event_damage = func_null;
 149
 150         sound(this, CH_SHOTS, SND_GRENADE_IMPACT, VOL_BASE, ATTEN_NORM);
 151
 152         this.realowner.mage_spike = world;
 153
 154         Send_Effect(EFFECT_EXPLOSION_SMALL, this.origin, '0 0 0', 1);
 155         RadiusDamage (this, this.realowner, (autocvar_g_monster_mage_attack_spike_damage), (autocvar_g_monster_mage_attack_spike_damage) * 0.5, (autocvar_g_monster_mage_attack_spike_radius), world, world, 0, DEATH_MONSTER_MAGE.m_id, other);
 156
 157         remove (this);
 158 }
 159
 160 void M_Mage_Attack_Spike_Touch()
 161 {
 162         PROJECTILE_TOUCH;
 163
 164         M_Mage_Attack_Spike_Explode(self);
 165 }
 166
 167 .float wait;
 168
 169 // copied from W_Seeker_Think
 170 void M_Mage_Attack_Spike_Think()
 171 {SELFPARAM();
 172         if (time > self.ltime || (self.enemy && self.enemy.health <= 0) || self.owner.health <= 0) {
 173                 self.projectiledeathtype |= HITTYPE_SPLASH;
 174                 M_Mage_Attack_Spike_Explode(self);
 175         }
 176
 177         float spd = vlen(self.velocity);
 178         spd = bound(
 179                 spd - (autocvar_g_monster_mage_attack_spike_decel) * frametime,
 180                 (autocvar_g_monster_mage_attack_spike_speed_max),
 181                 spd + (autocvar_g_monster_mage_attack_spike_accel) * frametime
 182         );
 183
 184         if (self.enemy != world)
 185                 if (self.enemy.takedamage != DAMAGE_AIM || IS_DEAD(self.enemy))
 186                         self.enemy = world;
 187
 188         if (self.enemy != world)
 189         {
 190                 entity e = self.enemy;
 191                 vector eorg = 0.5 * (e.absmin + e.absmax);
 192                 float turnrate = (autocvar_g_monster_mage_attack_spike_turnrate); // how fast to turn
 193                 vector desireddir = normalize(eorg - self.origin);
 194                 vector olddir = normalize(self.velocity); // get my current direction
 195                 float dist = vlen(eorg - self.origin);
 196
 197                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 198                 if ((autocvar_g_monster_mage_attack_spike_smart) && (dist > (autocvar_g_monster_mage_attack_spike_smart_mindist)))
 199                 {
 200                         // Is it a better idea (shorter distance) to trace to the target itself?
 201                         if ( vlen(self.origin + olddir * self.wait) < dist)
 202                                 traceline(self.origin, self.origin + olddir * self.wait, false, self);
 203                         else
 204                                 traceline(self.origin, eorg, false, self);
 205
 206                         // Setup adaptive tracelength
 207                         self.wait = bound((autocvar_g_monster_mage_attack_spike_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = (autocvar_g_monster_mage_attack_spike_smart_trace_max));
 208
 209                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 210                         desireddir = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 211                 }
 212
 213                 vector newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 214                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 215         }
 216
 217         ///////////////
 218
 219         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 220         self.nextthink = time;// + 0.05; // csqc projectiles
 221         UpdateCSQCProjectile(self);
 222 }
 223
 224 void M_Mage_Attack_Spike(entity this, vector dir)
 225 {
 226         makevectors(this.angles);
 227
 228         entity missile = spawn();
 229         missile.owner = missile.realowner = this;
 230         missile.think = M_Mage_Attack_Spike_Think;
 231         missile.ltime = time + 7;
 232         missile.nextthink = time;
 233         missile.solid = SOLID_BBOX;
 234         missile.movetype = MOVETYPE_FLYMISSILE;
 235         missile.flags = FL_PROJECTILE;
 236         setorigin(missile, this.origin + v_forward * 14 + '0 0 30' + v_right * -14);
 237         setsize(missile, '0 0 0', '0 0 0');
 238         missile.velocity = dir * 400;
 239         missile.avelocity = '300 300 300';
 240         missile.enemy = this.enemy;
 241         missile.touch = M_Mage_Attack_Spike_Touch;
 242
 243         this.mage_spike = missile;
 244
 245         CSQCProjectile(missile, true, PROJECTILE_MAGE_SPIKE, true);
 246 }
 247
 248 void M_Mage_Defend_Heal(entity this)
 249 {
 250         entity head;
 251         float washealed = false;
 252
 253         for(head = findradius(this.origin, (autocvar_g_monster_mage_heal_range)); head; head = head.chain) if(M_Mage_Defend_Heal_Check(this, head))
 254         {
 255                 washealed = true;
 256                 string fx = "";
 257                 if(IS_PLAYER(head))
 258                 {
 259                         switch(this.skin)
 260                         {
 261                                 case 0:
 262                                         if(head.health < autocvar_g_balance_health_regenstable) head.health = bound(0, head.health + (autocvar_g_monster_mage_heal_allies), autocvar_g_balance_health_regenstable);
 263                                         fx = EFFECT_HEALING.eent_eff_name;
 264                                         break;
 265                                 case 1:
 266                                         if(head.ammo_cells) head.ammo_cells = bound(head.ammo_cells, head.ammo_cells + 1, g_pickup_cells_max);
 267                                         if(head.ammo_plasma) head.ammo_plasma = bound(head.ammo_plasma, head.ammo_plasma + 1, g_pickup_plasma_max);
 268                                         if(head.ammo_rockets) head.ammo_rockets = bound(head.ammo_rockets, head.ammo_rockets + 1, g_pickup_rockets_max);
 269                                         if(head.ammo_shells) head.ammo_shells = bound(head.ammo_shells, head.ammo_shells + 2, g_pickup_shells_max);
 270                                         if(head.ammo_nails) head.ammo_nails = bound(head.ammo_nails, head.ammo_nails + 5, g_pickup_nails_max);
 271                                         fx = "ammoregen_fx";
 272                                         break;
 273                                 case 2:
 274                                         if(head.armorvalue < autocvar_g_balance_armor_regenstable)
 275                                         {
 276                                                 head.armorvalue = bound(0, head.armorvalue + (autocvar_g_monster_mage_heal_allies), autocvar_g_balance_armor_regenstable);
 277                                                 fx = "armorrepair_fx";
 278                                         }
 279                                         break;
 280                                 case 3:
 281                                         head.health = bound(0, head.health - ((head == this)  ? (autocvar_g_monster_mage_heal_self) : (autocvar_g_monster_mage_heal_allies)), autocvar_g_balance_health_regenstable);
 282                                         fx = EFFECT_RAGE.eent_eff_name;
 283                                         break;
 284                         }
 285
 286                         Send_Effect_(fx, head.origin, '0 0 0', 1);
 287                 }
 288                 else
 289                 {
 290                         Send_Effect(EFFECT_HEALING, head.origin, '0 0 0', 1);
 291                         head.health = bound(0, head.health + (autocvar_g_monster_mage_heal_allies), head.max_health);
 292                         if(!(head.spawnflags & MONSTERFLAG_INVINCIBLE) && head.sprite)
 293                                 WaypointSprite_UpdateHealth(head.sprite, head.health);
 294                 }
 295         }
 296
 297         if(washealed)
 298         {
 299                 setanim(this, this.anim_shoot, true, true, true);
 300                 this.attack_finished_single[0] = time + (autocvar_g_monster_mage_heal_delay);
 301                 this.anim_finished = time + 1.5;
 302         }
 303 }
 304
 305 void M_Mage_Attack_Push(entity this)
 306 {
 307         sound(this, CH_SHOTS, SND_TAGEXP1, 1, ATTEN_NORM);
 308         RadiusDamage (this, this, (autocvar_g_monster_mage_attack_push_damage), (autocvar_g_monster_mage_attack_push_damage), (autocvar_g_monster_mage_attack_push_radius), world, world, (autocvar_g_monster_mage_attack_push_force), DEATH_MONSTER_MAGE.m_id, this.enemy);
 309         Send_Effect(EFFECT_TE_EXPLOSION, this.origin, '0 0 0', 1);
 310
 311         setanim(this, this.anim_shoot, true, true, true);
 312         this.attack_finished_single[0] = time + (autocvar_g_monster_mage_attack_push_delay);
 313 }
 314
 315 void M_Mage_Attack_Teleport(entity this, entity targ)
 316 {
 317         if(!targ) return;
 318         if(vdist(targ.origin - this.origin, >, 1500)) return;
 319
 320         makevectors(targ.angles);
 321         tracebox(targ.origin + ((v_forward * -1) * 200), this.mins, this.maxs, this.origin, MOVE_NOMONSTERS, this);
 322
 323         if(trace_fraction < 1)
 324                 return;
 325
 326         vector newpos = targ.origin + ((v_forward * -1) * 200);
 327
 328         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 329         Send_Effect(EFFECT_SPAWN_NEUTRAL, newpos, '0 0 0', 1);
 330
 331         setorigin(this, newpos);
 332
 333         vector a = vectoangles(targ.origin - this.origin);
 334         a.x = -a.x;
 335         this.angles_x = a.x;
 336         this.angles_y = a.y;
 337         this.fixangle = true;
 338         this.velocity *= 0.5;
 339
 340         this.attack_finished_single[0] = time + 0.2;
 341 }
 342
 343 void M_Mage_Defend_Shield_Remove(entity this)
 344 {
 345         this.effects &= ~(EF_ADDITIVE | EF_BLUE);
 346         this.armorvalue = autocvar_g_monsters_armor_blockpercent;
 347 }
 348
 349 void M_Mage_Defend_Shield(entity this)
 350 {
 351         this.effects |= (EF_ADDITIVE | EF_BLUE);
 352         this.mage_shield_delay = time + (autocvar_g_monster_mage_shield_delay);
 353         this.armorvalue = (autocvar_g_monster_mage_shield_blockpercent);
 354         this.mage_shield_time = time + (autocvar_g_monster_mage_shield_time);
 355         setanim(this, this.anim_shoot, true, true, true);
 356         this.attack_finished_single[0] = time + 1;
 357         this.anim_finished = time + 1;
 358 }
 359
 360 bool M_Mage_Attack(int attack_type, entity actor, entity targ)
 361 {
 362     .entity weaponentity = weaponentities[0];
 363         switch(attack_type)
 364         {
 365                 case MONSTER_ATTACK_MELEE:
 366                 {
 367                         if(random() <= 0.7)
 368                         {
 369                                 Weapon wep = WEP_MAGE_SPIKE;
 370
 371                                 wep.wr_think(wep, actor, weaponentity, 2);
 372                                 return true;
 373                         }
 374
 375                         return false;
 376                 }
 377                 case MONSTER_ATTACK_RANGED:
 378                 {
 379                         if(!actor.mage_spike)
 380                         {
 381                                 if(random() <= 0.4)
 382                                 {
 383                                         OffhandWeapon off = OFFHAND_MAGE_TELEPORT;
 384                                         off.offhand_think(off, actor, true);
 385                                         return true;
 386                                 }
 387                                 else
 388                                 {
 389                                         setanim(actor, actor.anim_shoot, true, true, true);
 390                                         actor.attack_finished_single[0] = time + (autocvar_g_monster_mage_attack_spike_delay);
 391                                         actor.anim_finished = time + 1;
 392                                         Weapon wep = WEP_MAGE_SPIKE;
 393                                         wep.wr_think(wep, actor, weaponentity, 1);
 394                                         return true;
 395                                 }
 396                         }
 397
 398                         if(actor.mage_spike)
 399                                 return true;
 400                         else
 401                                 return false;
 402                 }
 403         }
 404
 405         return false;
 406 }
 407
 408 spawnfunc(monster_mage) { Monster_Spawn(this, MON_MAGE.monsterid); }
 409
 410 #endif // SVQC
 411
 412                 #ifdef SVQC
 413                 METHOD(Mage, mr_think, bool(Mage thismon, entity actor))
 414                 {
 415                         bool need_help = false;
 416
 417                         FOREACH_ENTITY_FLOAT(iscreature, true,
 418                         {
 419                                 if(it != actor)
 420                                 if(vdist(it.origin - actor.origin, <=, autocvar_g_monster_mage_heal_range))
 421                                 if(M_Mage_Defend_Heal_Check(actor, it))
 422                                 {
 423                                         need_help = true;
 424                                         break;
 425                                 }
 426                         });
 427
 428                         if(actor.health < (autocvar_g_monster_mage_heal_minhealth) || need_help)
 429                         if(time >= actor.attack_finished_single[0])
 430                         if(random() < 0.5)
 431                                 M_Mage_Defend_Heal(actor);
 432
 433                         if(time >= actor.mage_shield_time && actor.armorvalue)
 434                                 M_Mage_Defend_Shield_Remove(actor);
 435
 436                         if(actor.enemy)
 437                         if(actor.health < actor.max_health)
 438                         if(time >= actor.mage_shield_delay)
 439                         if(random() < 0.5)
 440                                 M_Mage_Defend_Shield(actor);
 441
 442                         return true;
 443                 }
 444                 METHOD(Mage, mr_pain, bool(Mage thismon, entity actor))
 445                 {
 446                         return true;
 447                 }
 448                 METHOD(Mage, mr_death, bool(Mage thismon, entity actor))
 449                 {
 450                         setanim(actor, actor.anim_die1, false, true, true);
 451                         return true;
 452                 }
 453                 #endif
 454                 #ifndef MENUQC
 455                 METHOD(Mage, mr_anim, bool(Mage thismon, entity actor))
 456                 {
 457                         vector none = '0 0 0';
 458                         actor.anim_die1 = animfixfps(actor, '4 1 0.5', none); // 2 seconds
 459                         actor.anim_walk = animfixfps(actor, '1 1 1', none);
 460                         actor.anim_idle = animfixfps(actor, '0 1 1', none);
 461                         actor.anim_pain1 = animfixfps(actor, '3 1 2', none); // 0.5 seconds
 462                         actor.anim_shoot = animfixfps(actor, '2 1 5', none); // analyze models and set framerate
 463                         actor.anim_run = animfixfps(actor, '5 1 1', none);
 464                         return true;
 465                 }
 466                 #endif
 467                 #ifdef SVQC
 468                 .float speed;
 469                 spawnfunc(item_health_large);
 470                 METHOD(Mage, mr_setup, bool(Mage thismon, entity actor))
 471                 {
 472                         if(!actor.health) actor.health = (autocvar_g_monster_mage_health);
 473                         if(!actor.speed) { actor.speed = (autocvar_g_monster_mage_speed_walk); }
 474                         if(!actor.speed2) { actor.speed2 = (autocvar_g_monster_mage_speed_run); }
 475                         if(!actor.stopspeed) { actor.stopspeed = (autocvar_g_monster_mage_speed_stop); }
 476                         if(!actor.damageforcescale) { actor.damageforcescale = (autocvar_g_monster_mage_damageforcescale); }
 477
 478                         actor.monster_loot = spawnfunc_item_health_large;
 479                         actor.monster_attackfunc = M_Mage_Attack;
 480
 481                         return true;
 482                 }
 483                 METHOD(Mage, mr_precache, bool(Mage thismon))
 484                 {
 485                         return true;
 486                 }
 487                 #endif
 488
 489 #endif