qcsrc/common/mutators/base.qh

   1 #ifndef MUTATORS_BASE_H
   2 #define MUTATORS_BASE_H
   3
   4 const int CBC_ORDER_FIRST = 1;
   5 const int CBC_ORDER_LAST = 2;
   6 const int CBC_ORDER_EXCLUSIVE = 3;
   7 const int CBC_ORDER_ANY = 4;
   8
   9 bool CallbackChain_ReturnValue; // read-only field of the current return value
  10
  11 /**
  12  * Callbacks may be added to zero or more callback chains.
  13  */
  14 CLASS(Callback, Object)
  15     /**
  16      * a callback function is like this:
  17      * bool mycallback()
  18      * {
  19      *     do something
  20      *     return false;
  21      * }
  22      */
  23     ATTRIB(Callback, cbc_func, bool(), func_null)
  24     CONSTRUCTOR(Callback, bool() func) {
  25         CONSTRUCT(Callback);
  26         this.cbc_func = func;
  27     }
  28 ENDCLASS(Callback)
  29
  30 /**
  31  * Callback chains contain zero or more callbacks.
  32  */
  33 CLASS(CallbackChain, Object)
  34     CLASS(CallbackNode, Object)
  35         ATTRIB(CallbackNode, cbc, Callback, NULL)
  36         ATTRIB(CallbackNode, cbc_next, CallbackNode, NULL)
  37         ATTRIB(CallbackNode, cbc_order, int, 0)
  38         CONSTRUCTOR(CallbackNode, Callback it, int order) {
  39             CONSTRUCT(CallbackNode);
  40             this.cbc = it;
  41             this.cbc_order = order;
  42         }
  43     ENDCLASS(CallbackNode)
  44
  45     ATTRIB(CallbackChain, cbc_next, CallbackNode, NULL)
  46     ATTRIB(CallbackChain, cbc_order, int, 0)
  47     CONSTRUCTOR(CallbackChain, string _name) {
  48         CONSTRUCT(CallbackChain);
  49         this.netname = _name;
  50     }
  51
  52     bool CallbackChain_Add(CallbackChain this, Callback cb, int order)
  53     {
  54         if (order & CBC_ORDER_FIRST) {
  55             if (order & CBC_ORDER_LAST)
  56                 if (this.cbc_order & CBC_ORDER_ANY)
  57                     return false;
  58             if (this.cbc_order & CBC_ORDER_FIRST)
  59                 return false;
  60         } else if (order & CBC_ORDER_LAST) {
  61             if (this.cbc_order & CBC_ORDER_LAST)
  62                 return false;
  63         }
  64         entity node = NEW(CallbackNode, cb, order);
  65         if (order & CBC_ORDER_FIRST) {
  66             node.cbc_next = this.cbc_next;
  67             this.cbc_next = node;
  68         } else if (order & CBC_ORDER_LAST) {
  69             CallbackNode prev = NULL, it = this.cbc_next;
  70             while (it) { prev = it, it = it.cbc_next; }
  71             if (prev) prev.cbc_next = node;
  72             else this.cbc_next = node;
  73         } else {
  74             // by default we execute last, but before a possible CBC_ORDER_LAST callback
  75             CallbackNode prev = NULL, it = this.cbc_next;
  76             while (it && !(it.cbc_order & CBC_ORDER_LAST)) { prev = it, it = it.cbc_next; }
  77             node.cbc_next = it;
  78             if (prev) prev.cbc_next = node;
  79             else this.cbc_next = node;
  80         }
  81         this.cbc_order |= (order | CBC_ORDER_ANY);
  82         return true;
  83     }
  84     int CallbackChain_Remove(CallbackChain this, Callback cb)
  85     {
  86         int n = 0, order = 0;
  87         for (Callback prev = NULL, it = this.cbc_next; it; prev = it, it = it.cbc_next) {
  88             if (it.cbc == cb) {
  89                 // remove it from the chain
  90                 Callback next = it.cbc_next;
  91                 if (prev) prev.cbc_next = next;
  92                 else this.cbc_next = next;
  93                 ++n;
  94             }
  95             // it is now something we want to keep
  96             order |= (it.cbc_order & CBC_ORDER_ANY);
  97         }
  98         this.cbc_order = order;
  99         return n;
 100     }
 101     bool CallbackChain_Call(CallbackChain this)
 102     {
 103         bool r = false;
 104         for (Callback it = this.cbc_next; it; it = it.cbc_next) {
 105             CallbackChain_ReturnValue = r;
 106             r |= it.cbc.cbc_func();
 107         }
 108         return r; // callbacks return an error status, so 0 is default return value
 109     }
 110 ENDCLASS(CallbackChain)
 111
 112 #define _MUTATOR_HANDLE_NOP(type, id)
 113 #define _MUTATOR_HANDLE_PARAMS(type, id) , type in_##id
 114 #define _MUTATOR_HANDLE_PREPARE(type, id) id = in_##id;
 115 #define _MUTATOR_HANDLE_PUSHTMP(type, id) type tmp_##id = id;
 116 #define _MUTATOR_HANDLE_PUSHOUT(type, id) type out_##id = id;
 117 #define _MUTATOR_HANDLE_POPTMP(type, id) id = tmp_##id;
 118 #define _MUTATOR_HANDLE_POPOUT(type, id) id = out_##id;
 119
 120 void RegisterHooks() {};
 121 void RegisterCallbacks() {};
 122
 123 #define _MUTATOR_HOOKABLE(id, ...) CallbackChain HOOK_##id; bool __Mutator_Send_##id(__VA_ARGS__)
 124 #define MUTATOR_HOOKABLE(id, params) \
 125     _MUTATOR_HOOKABLE(id, int params(_MUTATOR_HANDLE_PARAMS, _MUTATOR_HANDLE_NOP)) { \
 126         params(_MUTATOR_HANDLE_PUSHTMP, _MUTATOR_HANDLE_NOP) \
 127         params(_MUTATOR_HANDLE_PREPARE, _MUTATOR_HANDLE_NOP) \
 128         bool ret = CallbackChain_Call(HOOK_##id); \
 129         params(_MUTATOR_HANDLE_NOP,     _MUTATOR_HANDLE_PUSHOUT) \
 130         params(_MUTATOR_HANDLE_POPTMP,  _MUTATOR_HANDLE_NOP) \
 131         params(_MUTATOR_HANDLE_NOP,     _MUTATOR_HANDLE_POPOUT) \
 132         return ret; \
 133     } \
 134     [[accumulate]] void RegisterHooks() { HOOK_##id = NEW(CallbackChain, #id); }
 135 #define MUTATOR_CALLHOOK(id, ...) APPLY(__Mutator_Send_##id, 0, ##__VA_ARGS__)
 136
 137 enum {
 138     MUTATOR_REMOVING,
 139     MUTATOR_ADDING,
 140     MUTATOR_ROLLING_BACK
 141 };
 142
 143 typedef bool(int) mutatorfunc_t;
 144
 145 CLASS(Mutator, Object)
 146     ATTRIB(Mutator, m_id, int, 0)
 147     ATTRIB(Mutator, m_name, string, string_null)
 148     ATTRIB(Mutator, mutatorfunc, mutatorfunc_t, func_null)
 149     ATTRIB(Mutator, mutatorcheck, bool(), func_null)
 150     CONSTRUCTOR(Mutator, string _name, mutatorfunc_t func) {
 151         CONSTRUCT(Mutator);
 152         this.m_name = _name;
 153         this.mutatorfunc = func;
 154     }
 155 ENDCLASS(Mutator)
 156
 157 REGISTRY(Mutators, BITS(7))
 158 #define Mutators_from(i) _Mutators_from(i, NULL)
 159 Mutator loaded_mutators[Mutators_MAX];
 160 bool Mutator_Add(Mutator mut);
 161 void Mutator_Remove(Mutator mut);
 162 bool mutator_log = false;
 163
 164 #ifndef MENUQC
 165 REGISTER_NET_LINKED(Mutator)
 166
 167 #ifdef SVQC
 168 bool Mutator_SendEntity(entity this, entity to, int sf)
 169 {
 170     int chan = MSG_ENTITY;
 171     WriteHeader(chan, Mutator);
 172     WriteString(chan, this.registered_id);
 173     return true;
 174 }
 175 #endif
 176
 177 #ifdef CSQC
 178 void NET_Mutator_Remove()
 179 {
 180     SELFPARAM();
 181     string s = this.netname;
 182     WITH(bool, mutator_log, true, LAMBDA(
 183         FOREACH(Mutators, it.registered_id == s, LAMBDA(Mutator_Remove(it)));
 184     ));
 185 }
 186 NET_HANDLE(Mutator, bool isNew)
 187 {
 188     string s = this.netname = ReadString();
 189     return = true;
 190     if (isNew)
 191     {
 192         make_pure(this);
 193         this.entremove = NET_Mutator_Remove;
 194         int added = 0;
 195         WITH(bool, mutator_log, true, LAMBDA(
 196             FOREACH(Mutators, it.registered_id == s, LAMBDA(Mutator_Add(it); ++added));
 197         ));
 198         if (added > 1) LOG_WARNINGF("Added more than one mutator for %s\n", s);
 199     }
 200 }
 201 #endif
 202
 203 #endif
 204
 205 bool Mutator_Add(Mutator mut)
 206 {
 207     int j = -1;
 208     for (int i = 0; i < Mutators_MAX; ++i) {
 209         if (loaded_mutators[i] == mut)
 210             return true; // already added
 211         if (!(loaded_mutators[i]))
 212             j = i;
 213     }
 214     if (j < 0) {
 215         backtrace("WARNING: too many mutators, cannot add any more\n");
 216         return false;
 217     }
 218     loaded_mutators[j] = mut;
 219     mutatorfunc_t func = mut.mutatorfunc;
 220     if (!func(MUTATOR_ADDING)) {
 221         // good
 222         if (mutator_log) LOG_TRACEF("Mutator: added %s\n", mut.m_name);
 223 #ifdef SVQC
 224         Net_LinkEntity(mut, false, 0, Mutator_SendEntity);
 225 #endif
 226         return true;
 227     }
 228     backtrace("WARNING: when adding mutator: adding failed, rolling back\n");
 229     if (func(MUTATOR_ROLLING_BACK)) {
 230         // baaaaad
 231         error("WARNING: when adding mutator: rolling back failed");
 232     }
 233     return false;
 234 }
 235
 236 void Mutator_Remove(Mutator mut)
 237 {
 238     int i;
 239     for (i = 0; i < Mutators_MAX; ++i)
 240         if (loaded_mutators[i] == mut)
 241             break;
 242     if (i >= Mutators_MAX) {
 243         backtrace("WARNING: removing not-added mutator\n");
 244         return;
 245     }
 246     loaded_mutators[i] = NULL;
 247     mutatorfunc_t func = mut.mutatorfunc;
 248     if (func(MUTATOR_REMOVING)) {
 249         // baaaaad
 250         error("Mutator_Remove: removing mutator failed");
 251     }
 252     if (mutator_log) LOG_TRACEF("Mutator: removed %s\n", mut.m_name);
 253 #ifdef SVQC
 254     Net_UnlinkEntity(mut);
 255 #endif
 256 }
 257
 258 #define REGISTER_MUTATOR(id, dependence) \
 259     bool MUTATORFUNCTION_##id##_hooks(int mode) { return = false; } \
 260     bool MUTATORFUNCTION_##id(int mode) { \
 261         return = false; \
 262         bool ret = MUTATORFUNCTION_##id##_hooks(mode); if (ret) return ret; \
 263     } \
 264     bool MUTATOR_##id##_check() { return dependence; } \
 265     REGISTER(Mutators, MUTATOR, id, m_id, NEW(Mutator, #id, MUTATORFUNCTION_##id)) \
 266     { this.mutatorcheck = MUTATOR_##id##_check; } \
 267     [[accumulate]] bool MUTATORFUNCTION_##id(int mode)
 268
 269 STATIC_INIT(Mutators) {
 270     RegisterHooks();
 271     RegisterCallbacks();
 272     RegisterMutators();
 273 }
 274
 275 STATIC_INIT_LATE(Mutators) {
 276     FOREACH(Mutators, it.mutatorcheck(), LAMBDA(Mutator_Add(it)));
 277 }
 278
 279 #define MUTATOR_ONADD                   if (mode == MUTATOR_ADDING)
 280 #define MUTATOR_ONREMOVE                if (mode == MUTATOR_REMOVING)
 281 #define MUTATOR_ONROLLBACK_OR_REMOVE    if (mode == MUTATOR_REMOVING || mode == MUTATOR_ROLLING_BACK)
 282 #define MUTATOR_ADD(name)               Mutator_Add(MUTATOR_##name)
 283 #define MUTATOR_REMOVE(name)            Mutator_Remove(MUTATOR_##name)
 284 #define MUTATOR_RETURNVALUE             CallbackChain_ReturnValue
 285
 286 #define _MUTATOR_CALLBACK(name, func) \
 287     Callback CALLBACK_##name; \
 288     bool func(); \
 289     [[accumulate]] void RegisterCallbacks() { CALLBACK_##name = NEW(Callback, func); }
 290
 291 #define MUTATOR_HOOKFUNCTION(...) \
 292     EVAL(OVERLOAD(MUTATOR_HOOKFUNCTION, __VA_ARGS__))
 293
 294 #define MUTATOR_HOOKFUNCTION_2(mut, cb) \
 295     MUTATOR_HOOKFUNCTION_3(mut, cb, CBC_ORDER_ANY)
 296
 297 #define MUTATOR_HOOKFUNCTION_3(mut, cb, order) \
 298     _MUTATOR_CALLBACK(mut##_##cb, mut##_##cb) \
 299     [[accumulate]] bool MUTATORFUNCTION_##mut##_hooks(int mode) { MUTATOR_HOOK(cb, mut##_##cb, order); } \
 300     bool mut##_##cb() { return = false; } \
 301     [[accumulate]] bool mut##_##cb()
 302
 303 #define MUTATOR_HOOK(cb, func, order) do {                              \
 304     MUTATOR_ONADD {                                                     \
 305         if (!CallbackChain_Add(HOOK_##cb, CALLBACK_##func, order)) {    \
 306             LOG_INFO("HOOK FAILED: ", #cb, ":", #func, "\n");           \
 307             return true;                                                \
 308         }                                                               \
 309     }                                                                   \
 310     MUTATOR_ONROLLBACK_OR_REMOVE {                                      \
 311         CallbackChain_Remove(HOOK_##cb, CALLBACK_##func);               \
 312     }                                                                   \
 313 } while (0)
 314
 315 #include "events.qh"
 316
 317 #endif