qcsrc/common/mutators/mutator/buffs/buffs.qc

   1 #ifndef MUTATOR_BUFFS_H
   2 #define MUTATOR_BUFFS_H
   3
   4 #include "../instagib/module.inc"
   5
   6 bool  autocvar_g_buffs_effects;
   7 float autocvar_g_buffs_waypoint_distance;
   8 bool autocvar_g_buffs_randomize;
   9 float autocvar_g_buffs_random_lifetime;
  10 bool autocvar_g_buffs_random_location;
  11 int autocvar_g_buffs_random_location_attempts;
  12 int autocvar_g_buffs_spawn_count;
  13 bool autocvar_g_buffs_replace_powerups;
  14 float autocvar_g_buffs_cooldown_activate;
  15 float autocvar_g_buffs_cooldown_respawn;
  16 float autocvar_g_buffs_resistance_blockpercent;
  17 float autocvar_g_buffs_medic_survive_chance;
  18 float autocvar_g_buffs_medic_survive_health;
  19 float autocvar_g_buffs_medic_rot;
  20 float autocvar_g_buffs_medic_max;
  21 float autocvar_g_buffs_medic_regen;
  22 float autocvar_g_buffs_vengeance_damage_multiplier;
  23 float autocvar_g_buffs_bash_force;
  24 float autocvar_g_buffs_bash_force_self;
  25 float autocvar_g_buffs_disability_slowtime;
  26 float autocvar_g_buffs_disability_speed;
  27 float autocvar_g_buffs_disability_rate;
  28 float autocvar_g_buffs_disability_weaponspeed;
  29 float autocvar_g_buffs_speed_speed;
  30 float autocvar_g_buffs_speed_rate;
  31 float autocvar_g_buffs_speed_weaponspeed;
  32 float autocvar_g_buffs_speed_damage_take;
  33 float autocvar_g_buffs_speed_regen;
  34 float autocvar_g_buffs_vampire_damage_steal;
  35 float autocvar_g_buffs_invisible_alpha;
  36 float autocvar_g_buffs_flight_gravity;
  37 float autocvar_g_buffs_jump_height;
  38 float autocvar_g_buffs_inferno_burntime_factor;
  39 float autocvar_g_buffs_inferno_burntime_min_time;
  40 float autocvar_g_buffs_inferno_burntime_target_damage;
  41 float autocvar_g_buffs_inferno_burntime_target_time;
  42 float autocvar_g_buffs_inferno_damagemultiplier;
  43 float autocvar_g_buffs_swapper_range;
  44 float autocvar_g_buffs_magnet_range_item;
  45
  46 // ammo
  47 .float buff_ammo_prev_infitems;
  48 .int buff_ammo_prev_clipload;
  49 // invisible
  50 .float buff_invisible_prev_alpha;
  51 // flight
  52 .float buff_flight_prev_gravity;
  53 // disability
  54 .float buff_disability_time;
  55 .float buff_disability_effect_time;
  56 // common buff variables
  57 .float buff_effect_delay;
  58
  59 // buff definitions
  60 .float buff_active;
  61 .float buff_activetime;
  62 .float buff_activetime_updated;
  63 .entity buff_waypoint;
  64 .int oldbuffs; // for updating effects
  65 .entity buff_model; // controls effects (TODO: make csqc)
  66
  67 const vector BUFF_MIN = ('-16 -16 -20');
  68 const vector BUFF_MAX = ('16 16 20');
  69
  70 // client side options
  71 .float cvar_cl_buffs_autoreplace;
  72 #endif
  73
  74 #ifdef IMPLEMENTATION
  75
  76 #include "../../../triggers/target/music.qh"
  77 #include "../../../gamemodes/all.qh"
  78 #include "../../../buffs/all.qh"
  79
  80 .float buff_time;
  81 void buffs_DelayedInit();
  82
  83 REGISTER_MUTATOR(buffs, cvar("g_buffs"))
  84 {
  85         MUTATOR_ONADD
  86         {
  87                 addstat(STAT_BUFF_TIME, AS_FLOAT, buff_time);
  88
  89                 InitializeEntity(world, buffs_DelayedInit, INITPRIO_FINDTARGET);
  90         }
  91 }
  92
  93 entity buff_FirstFromFlags(int _buffs)
  94 {
  95         if (flags)
  96         {
  97                 FOREACH(Buffs, it.m_itemid & _buffs, LAMBDA(return it));
  98         }
  99         return BUFF_Null;
 100 }
 101
 102 bool buffs_BuffModel_Customize()
 103 {SELFPARAM();
 104         entity player, myowner;
 105         bool same_team;
 106
 107         player = WaypointSprite_getviewentity(other);
 108         myowner = self.owner;
 109         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
 110
 111         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
 112                 return false;
 113
 114         if(MUTATOR_CALLHOOK(BuffModel_Customize, self, player))
 115                 return false;
 116
 117         if(player == myowner || (IS_SPEC(other) && other.enemy == myowner))
 118         {
 119                 // somewhat hide the model, but keep the glow
 120                 self.effects = 0;
 121                 self.alpha = -1;
 122         }
 123         else
 124         {
 125                 self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 126                 self.alpha = 1;
 127         }
 128         return true;
 129 }
 130
 131 void buffs_BuffModel_Spawn(entity player)
 132 {
 133         player.buff_model = spawn();
 134         setmodel(player.buff_model, MDL_BUFF);
 135         setsize(player.buff_model, '0 0 -40', '0 0 40');
 136         setattachment(player.buff_model, player, "");
 137         setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
 138         player.buff_model.owner = player;
 139         player.buff_model.scale = 0.7;
 140         player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
 141         player.buff_model.light_lev = 200;
 142         player.buff_model.customizeentityforclient = buffs_BuffModel_Customize;
 143 }
 144
 145 vector buff_GlowColor(entity buff)
 146 {
 147         //if(buff.team) { return Team_ColorRGB(buff.team); }
 148         return buff.m_color;
 149 }
 150
 151 void buff_Effect(entity player, string eff)
 152 {SELFPARAM();
 153         if(!autocvar_g_buffs_effects) { return; }
 154
 155         if(time >= self.buff_effect_delay)
 156         {
 157                 Send_Effect_(eff, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
 158                 self.buff_effect_delay = time + 0.05; // prevent spam
 159         }
 160 }
 161
 162 // buff item
 163 float buff_Waypoint_visible_for_player(entity plr)
 164 {SELFPARAM();
 165         if(!self.owner.buff_active && !self.owner.buff_activetime)
 166                 return false;
 167
 168         if (plr.buffs)
 169         {
 170                 return plr.cvar_cl_buffs_autoreplace == false || plr.buffs != self.owner.buffs;
 171         }
 172
 173         return WaypointSprite_visible_for_player(plr);
 174 }
 175
 176 void buff_Waypoint_Spawn(entity e)
 177 {
 178         entity buff = buff_FirstFromFlags(e.buffs);
 179         entity wp = WaypointSprite_Spawn(WP_Buff, 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, world, e.team, e, buff_waypoint, true, RADARICON_Buff);
 180         wp.wp_extra = buff.m_id;
 181         WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_Buff, e.glowmod);
 182         e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
 183 }
 184
 185 void buff_SetCooldown(float cd)
 186 {SELFPARAM();
 187         cd = max(0, cd);
 188
 189         if(!self.buff_waypoint)
 190                 buff_Waypoint_Spawn(self);
 191
 192         WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + cd);
 193         self.buff_activetime = cd;
 194         self.buff_active = !cd;
 195 }
 196
 197 void buff_Respawn(entity ent)
 198 {SELFPARAM();
 199         if(gameover) { return; }
 200
 201         vector oldbufforigin = ent.origin;
 202
 203         if(!MoveToRandomMapLocation(ent, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
 204         {
 205                 entity spot = SelectSpawnPoint(true);
 206                 setorigin(ent, spot.origin + '0 0 200');
 207                 ent.angles = spot.angles;
 208         }
 209
 210         tracebox(ent.origin, ent.mins * 1.5, self.maxs * 1.5, ent.origin, MOVE_NOMONSTERS, ent);
 211
 212         setorigin(ent, trace_endpos); // attempt to unstick
 213
 214         ent.movetype = MOVETYPE_TOSS;
 215
 216         makevectors(ent.angles);
 217         ent.velocity = '0 0 200';
 218         ent.angles = '0 0 0';
 219         if(autocvar_g_buffs_random_lifetime > 0)
 220                 ent.lifetime = time + autocvar_g_buffs_random_lifetime;
 221
 222         Send_Effect(EFFECT_ELECTRO_COMBO, oldbufforigin + ((ent.mins + ent.maxs) * 0.5), '0 0 0', 1);
 223         Send_Effect(EFFECT_ELECTRO_COMBO, CENTER_OR_VIEWOFS(ent), '0 0 0', 1);
 224
 225         WaypointSprite_Ping(ent.buff_waypoint);
 226
 227         sound(ent, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 228 }
 229
 230 void buff_Touch()
 231 {SELFPARAM();
 232         if(gameover) { return; }
 233
 234         if(ITEM_TOUCH_NEEDKILL())
 235         {
 236                 buff_Respawn(self);
 237                 return;
 238         }
 239
 240         if((self.team && DIFF_TEAM(other, self))
 241         || (other.frozen)
 242         || (other.vehicle)
 243         || (!self.buff_active)
 244         )
 245         {
 246                 // can't touch this
 247                 return;
 248         }
 249
 250         if(MUTATOR_CALLHOOK(BuffTouch, self, other))
 251                 return;
 252
 253         if(!IS_PLAYER(other))
 254                 return; // incase mutator changed other
 255
 256         if (other.buffs)
 257         {
 258                 if (other.cvar_cl_buffs_autoreplace && other.buffs != self.buffs)
 259                 {
 260                         int buffid = buff_FirstFromFlags(other.buffs).m_id;
 261                         //Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_DROP, other.buffs);
 262                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ITEM_BUFF_LOST, other.netname, buffid);
 263
 264                         other.buffs = 0;
 265                         //sound(other, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 266                 }
 267                 else { return; } // do nothing
 268         }
 269
 270         self.owner = other;
 271         self.buff_active = false;
 272         self.lifetime = 0;
 273         int buffid = buff_FirstFromFlags(self.buffs).m_id;
 274         Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_GOT, buffid);
 275         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_INFO, INFO_ITEM_BUFF, other.netname, buffid);
 276
 277         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 278         sound(other, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTN_NORM);
 279         other.buffs |= (self.buffs);
 280 }
 281
 282 float buff_Available(entity buff)
 283 {
 284         if (buff == BUFF_Null)
 285                 return false;
 286         if (buff == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 287                 return false;
 288         if (buff == BUFF_VAMPIRE && cvar("g_vampire"))
 289                 return false;
 290         return cvar(strcat("g_buffs_", buff.m_name));
 291 }
 292
 293 .int buff_seencount;
 294
 295 void buff_NewType(entity ent, float cb)
 296 {
 297         RandomSelection_Init();
 298         FOREACH(Buffs, buff_Available(it), LAMBDA(
 299                 it.buff_seencount += 1;
 300                 // if it's already been chosen, give it a lower priority
 301                 RandomSelection_Add(world, it.m_itemid, string_null, 1, max(0.2, 1 / it.buff_seencount));
 302         ));
 303         ent.buffs = RandomSelection_chosen_float;
 304 }
 305
 306 void buff_Think()
 307 {SELFPARAM();
 308         if(self.buffs != self.oldbuffs)
 309         {
 310                 entity buff = buff_FirstFromFlags(self.buffs);
 311                 self.color = buff.m_color;
 312                 self.glowmod = buff_GlowColor(buff);
 313                 self.skin = buff.m_skin;
 314
 315                 setmodel(self, MDL_BUFF);
 316
 317                 if(self.buff_waypoint)
 318                 {
 319                         //WaypointSprite_Disown(self.buff_waypoint, 1);
 320                         WaypointSprite_Kill(self.buff_waypoint);
 321                         buff_Waypoint_Spawn(self);
 322                         if(self.buff_activetime)
 323                                 WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + self.buff_activetime - frametime);
 324                 }
 325
 326                 self.oldbuffs = self.buffs;
 327         }
 328
 329         if(!gameover)
 330         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 331         if(!self.buff_activetime_updated)
 332         {
 333                 buff_SetCooldown(self.buff_activetime);
 334                 self.buff_activetime_updated = true;
 335         }
 336
 337         if(!self.buff_active && !self.buff_activetime)
 338         if(!self.owner || self.owner.frozen || self.owner.deadflag != DEAD_NO || !self.owner.iscreature || !(self.owner.buffs & self.buffs))
 339         {
 340                 buff_SetCooldown(autocvar_g_buffs_cooldown_respawn + frametime);
 341                 self.owner = world;
 342                 if(autocvar_g_buffs_randomize)
 343                         buff_NewType(self, self.buffs);
 344
 345                 if(autocvar_g_buffs_random_location || (self.spawnflags & 64))
 346                         buff_Respawn(self);
 347         }
 348
 349         if(self.buff_activetime)
 350         if(!gameover)
 351         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 352         {
 353                 self.buff_activetime = max(0, self.buff_activetime - frametime);
 354
 355                 if(!self.buff_activetime)
 356                 {
 357                         self.buff_active = true;
 358                         sound(self, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTN_NORM);
 359                         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 360                 }
 361         }
 362
 363         if(self.buff_active)
 364         {
 365                 if(self.team && !self.buff_waypoint)
 366                         buff_Waypoint_Spawn(self);
 367
 368                 if(self.lifetime)
 369                 if(time >= self.lifetime)
 370                         buff_Respawn(self);
 371         }
 372
 373         self.nextthink = time;
 374         //self.angles_y = time * 110.1;
 375 }
 376
 377 void buff_Waypoint_Reset()
 378 {SELFPARAM();
 379         WaypointSprite_Kill(self.buff_waypoint);
 380
 381         if(self.buff_activetime) { buff_Waypoint_Spawn(self); }
 382 }
 383
 384 void buff_Reset()
 385 {SELFPARAM();
 386         if(autocvar_g_buffs_randomize)
 387                 buff_NewType(self, self.buffs);
 388         self.owner = world;
 389         buff_SetCooldown(autocvar_g_buffs_cooldown_activate);
 390         buff_Waypoint_Reset();
 391         self.buff_activetime_updated = false;
 392
 393         if(autocvar_g_buffs_random_location || (self.spawnflags & 64))
 394                 buff_Respawn(self);
 395 }
 396
 397 float buff_Customize()
 398 {SELFPARAM();
 399         entity player = WaypointSprite_getviewentity(other);
 400         if(!self.buff_active || (self.team && DIFF_TEAM(player, self)))
 401         {
 402                 self.alpha = 0.3;
 403                 if(self.effects & EF_FULLBRIGHT) { self.effects &= ~(EF_FULLBRIGHT); }
 404                 self.pflags = 0;
 405         }
 406         else
 407         {
 408                 self.alpha = 1;
 409                 if(!(self.effects & EF_FULLBRIGHT)) { self.effects |= EF_FULLBRIGHT; }
 410                 self.light_lev = 220 + 36 * sin(time);
 411                 self.pflags = PFLAGS_FULLDYNAMIC;
 412         }
 413         return true;
 414 }
 415
 416 void buff_Init(entity ent)
 417 {SELFPARAM();
 418         if(!cvar("g_buffs")) { remove(ent); return; }
 419
 420         if(!teamplay && ent.team) { ent.team = 0; }
 421
 422         entity buff = buff_FirstFromFlags(self.buffs);
 423
 424         setself(ent);
 425         if(!self.buffs || buff_Available(buff))
 426                 buff_NewType(self, 0);
 427
 428         self.classname = "item_buff";
 429         self.solid = SOLID_TRIGGER;
 430         self.flags = FL_ITEM;
 431         self.think = buff_Think;
 432         self.touch = buff_Touch;
 433         self.reset = buff_Reset;
 434         self.nextthink = time + 0.1;
 435         self.gravity = 1;
 436         self.movetype = MOVETYPE_TOSS;
 437         self.scale = 1;
 438         self.skin = buff.m_skin;
 439         self.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 440         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 441         self.customizeentityforclient = buff_Customize;
 442         //self.gravity = 100;
 443         self.color = buff.m_color;
 444         self.glowmod = buff_GlowColor(self);
 445         buff_SetCooldown(autocvar_g_buffs_cooldown_activate + game_starttime);
 446         self.buff_active = !self.buff_activetime;
 447         self.pflags = PFLAGS_FULLDYNAMIC;
 448
 449         if(self.spawnflags & 1)
 450                 self.noalign = true;
 451
 452         if(self.noalign)
 453                 self.movetype = MOVETYPE_NONE; // reset by random location
 454
 455         setmodel(self, MDL_BUFF);
 456         setsize(self, BUFF_MIN, BUFF_MAX);
 457
 458         if(cvar("g_buffs_random_location") || (self.spawnflags & 64))
 459                 buff_Respawn(self);
 460
 461         setself(this);
 462 }
 463
 464 void buff_Init_Compat(entity ent, entity replacement)
 465 {
 466         if (ent.spawnflags & 2)
 467                 ent.team = NUM_TEAM_1;
 468         else if (ent.spawnflags & 4)
 469                 ent.team = NUM_TEAM_2;
 470
 471         ent.buffs = replacement.m_itemid;
 472
 473         buff_Init(ent);
 474 }
 475
 476 void buff_SpawnReplacement(entity ent, entity old)
 477 {
 478         setorigin(ent, old.origin);
 479         ent.angles = old.angles;
 480         ent.noalign = (old.noalign || (old.spawnflags & 1));
 481
 482         buff_Init(ent);
 483 }
 484
 485 void buff_Vengeance_DelayedDamage()
 486 {SELFPARAM();
 487         if(self.enemy)
 488                 Damage(self.enemy, self.owner, self.owner, self.dmg, DEATH_BUFF.m_id, self.enemy.origin, '0 0 0');
 489
 490         remove(self);
 491         return;
 492 }
 493
 494 float buff_Inferno_CalculateTime(float x, float offset_x, float offset_y, float intersect_x, float intersect_y, float base)
 495 {
 496         return offset_y + (intersect_y - offset_y) * logn(((x - offset_x) * ((base - 1) / intersect_x)) + 1, base);
 497 }
 498
 499 // mutator hooks
 500 MUTATOR_HOOKFUNCTION(buffs, PlayerDamage_SplitHealthArmor)
 501 {
 502         if(frag_deathtype == DEATH_BUFF.m_id) { return false; }
 503
 504         if(frag_target.buffs & BUFF_RESISTANCE.m_itemid)
 505         {
 506                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 507                 damage_take = v.x;
 508                 damage_save = v.y;
 509         }
 510
 511         return false;
 512 }
 513
 514 MUTATOR_HOOKFUNCTION(buffs, PlayerDamage_Calculate)
 515 {
 516         if(frag_deathtype == DEATH_BUFF.m_id) { return false; }
 517
 518         if(frag_target.buffs & BUFF_SPEED.m_itemid)
 519         if(frag_target != frag_attacker)
 520                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 521
 522         if(frag_target.buffs & BUFF_MEDIC.m_itemid)
 523         if((frag_target.health - frag_damage) <= 0)
 524         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 525         if(frag_attacker)
 526         if(random() <= autocvar_g_buffs_medic_survive_chance)
 527                 frag_damage = max(5, frag_target.health - autocvar_g_buffs_medic_survive_health);
 528
 529         if(frag_target.buffs & BUFF_JUMP.m_itemid)
 530         if(frag_deathtype == DEATH_FALL.m_id)
 531                 frag_damage = 0;
 532
 533         if(frag_target.buffs & BUFF_VENGEANCE.m_itemid)
 534         if(frag_attacker)
 535         if(frag_attacker != frag_target)
 536         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 537         {
 538                 entity dmgent = spawn();
 539
 540                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 541                 dmgent.enemy = frag_attacker;
 542                 dmgent.owner = frag_target;
 543                 dmgent.think = buff_Vengeance_DelayedDamage;
 544                 dmgent.nextthink = time + 0.1;
 545         }
 546
 547         if(frag_target.buffs & BUFF_BASH.m_itemid)
 548         if(frag_attacker != frag_target)
 549         if(vlen(frag_force))
 550                 frag_force = '0 0 0';
 551
 552         if(frag_attacker.buffs & BUFF_BASH.m_itemid)
 553         if(vlen(frag_force))
 554         if(frag_attacker == frag_target)
 555                 frag_force *= autocvar_g_buffs_bash_force_self;
 556         else
 557                 frag_force *= autocvar_g_buffs_bash_force;
 558
 559         if(frag_attacker.buffs & BUFF_DISABILITY.m_itemid)
 560         if(frag_target != frag_attacker)
 561                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_slowtime;
 562
 563         if(frag_attacker.buffs & BUFF_MEDIC.m_itemid)
 564         if(DEATH_WEAPONOF(frag_deathtype) != WEP_ARC)
 565         if(SAME_TEAM(frag_attacker, frag_target))
 566         if(frag_attacker != frag_target)
 567         {
 568                 frag_target.health = min(g_pickup_healthmega_max, frag_target.health + frag_damage);
 569                 frag_damage = 0;
 570         }
 571
 572         if(frag_attacker.buffs & BUFF_INFERNO.m_itemid)
 573         if(frag_target != frag_attacker) {
 574                 float time = buff_Inferno_CalculateTime(
 575                         frag_damage,
 576                         0,
 577                         autocvar_g_buffs_inferno_burntime_min_time,
 578                         autocvar_g_buffs_inferno_burntime_target_damage,
 579                         autocvar_g_buffs_inferno_burntime_target_time,
 580                         autocvar_g_buffs_inferno_burntime_factor
 581                 );
 582                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier) * time, time, DEATH_BUFF.m_id);
 583         }
 584
 585         // this... is ridiculous (TODO: fix!)
 586         if(frag_attacker.buffs & BUFF_VAMPIRE.m_itemid)
 587         if(!frag_target.vehicle)
 588         if(DEATH_WEAPONOF(frag_deathtype) != WEP_ARC)
 589         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 590         if(frag_target.deadflag == DEAD_NO)
 591         if(IS_PLAYER(frag_target) || IS_MONSTER(frag_target))
 592         if(frag_attacker != frag_target)
 593         if(!frag_target.frozen)
 594         if(frag_target.takedamage)
 595         if(DIFF_TEAM(frag_attacker, frag_target))
 596         {
 597                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 598                 if(frag_target.armorvalue)
 599                         frag_attacker.armorvalue = bound(0, frag_attacker.armorvalue + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.armorvalue), g_pickup_armorsmall_max);
 600         }
 601
 602         return false;
 603 }
 604
 605 MUTATOR_HOOKFUNCTION(buffs,PlayerSpawn)
 606 {SELFPARAM();
 607         self.buffs = 0;
 608         // reset timers here to prevent them continuing after re-spawn
 609         self.buff_disability_time = 0;
 610         self.buff_disability_effect_time = 0;
 611         return false;
 612 }
 613
 614 .float stat_sv_maxspeed;
 615 .float stat_sv_airspeedlimit_nonqw;
 616 .float stat_sv_jumpvelocity;
 617
 618 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics)
 619 {SELFPARAM();
 620         if(self.buffs & BUFF_SPEED.m_itemid)
 621         {
 622                 self.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 623                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 624         }
 625
 626         if(time < self.buff_disability_time)
 627         {
 628                 self.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 629                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 630         }
 631
 632         if(self.buffs & BUFF_JUMP.m_itemid)
 633         {
 634                 // automatically reset, no need to worry
 635                 self.stat_sv_jumpvelocity = autocvar_g_buffs_jump_height;
 636         }
 637
 638         return false;
 639 }
 640
 641 MUTATOR_HOOKFUNCTION(buffs, PlayerJump)
 642 {SELFPARAM();
 643         if(self.buffs & BUFF_JUMP.m_itemid)
 644                 player_jumpheight = autocvar_g_buffs_jump_height;
 645
 646         return false;
 647 }
 648
 649 MUTATOR_HOOKFUNCTION(buffs, MonsterMove)
 650 {SELFPARAM();
 651         if(time < self.buff_disability_time)
 652         {
 653                 monster_speed_walk *= autocvar_g_buffs_disability_speed;
 654                 monster_speed_run *= autocvar_g_buffs_disability_speed;
 655         }
 656
 657         return false;
 658 }
 659
 660 MUTATOR_HOOKFUNCTION(buffs, PlayerDies)
 661 {SELFPARAM();
 662         if(self.buffs)
 663         {
 664                 int buffid = buff_FirstFromFlags(self.buffs).m_id;
 665                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 666                 self.buffs = 0;
 667
 668                 if(self.buff_model)
 669                 {
 670                         remove(self.buff_model);
 671                         self.buff_model = world;
 672                 }
 673         }
 674         return false;
 675 }
 676
 677 MUTATOR_HOOKFUNCTION(buffs, PlayerUseKey, CBC_ORDER_FIRST)
 678 {SELFPARAM();
 679         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 680         if(self.buffs)
 681         {
 682                 int buffid = buff_FirstFromFlags(self.buffs).m_id;
 683                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, buffid);
 684                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 685
 686                 self.buffs = 0;
 687                 sound(self, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 688                 return true;
 689         }
 690         return false;
 691 }
 692
 693 MUTATOR_HOOKFUNCTION(buffs, ForbidThrowCurrentWeapon)
 694 {SELFPARAM();
 695         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 696
 697         if(self.buffs & BUFF_SWAPPER.m_itemid)
 698         {
 699                 float best_distance = autocvar_g_buffs_swapper_range;
 700                 entity closest = world;
 701                 entity player;
 702                 FOR_EACH_PLAYER(player)
 703                 if(DIFF_TEAM(self, player))
 704                 if(player.deadflag == DEAD_NO && !player.frozen && !player.vehicle)
 705                 if(vlen(self.origin - player.origin) <= best_distance)
 706                 {
 707                         best_distance = vlen(self.origin - player.origin);
 708                         closest = player;
 709                 }
 710
 711                 if(closest)
 712                 {
 713                         vector my_org, my_vel, my_ang, their_org, their_vel, their_ang;
 714
 715                         my_org = self.origin;
 716                         my_vel = self.velocity;
 717                         my_ang = self.angles;
 718                         their_org = closest.origin;
 719                         their_vel = closest.velocity;
 720                         their_ang = closest.angles;
 721
 722                         Drop_Special_Items(closest);
 723
 724                         MUTATOR_CALLHOOK(PortalTeleport, self); // initiate flag dropper
 725
 726                         setorigin(self, their_org);
 727                         setorigin(closest, my_org);
 728
 729                         closest.velocity = my_vel;
 730                         closest.angles = my_ang;
 731                         closest.fixangle = true;
 732                         closest.oldorigin = my_org;
 733                         closest.oldvelocity = my_vel;
 734                         self.velocity = their_vel;
 735                         self.angles = their_ang;
 736                         self.fixangle = true;
 737                         self.oldorigin = their_org;
 738                         self.oldvelocity = their_vel;
 739
 740                         // set pusher so self gets the kill if they fall into void
 741                         closest.pusher = self;
 742                         closest.pushltime = time + autocvar_g_maxpushtime;
 743                         closest.istypefrag = closest.BUTTON_CHAT;
 744
 745                         Send_Effect(EFFECT_ELECTRO_COMBO, their_org, '0 0 0', 1);
 746                         Send_Effect(EFFECT_ELECTRO_COMBO, my_org, '0 0 0', 1);
 747
 748                         sound(self, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 749                         sound(closest, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 750
 751                         // TODO: add a counter to handle how many times one can teleport, and a delay to prevent spam
 752                         self.buffs = 0;
 753                         return true;
 754                 }
 755         }
 756         return false;
 757 }
 758
 759 bool buffs_RemovePlayer(entity player)
 760 {
 761         if(player.buff_model)
 762         {
 763                 remove(player.buff_model);
 764                 player.buff_model = world;
 765         }
 766
 767         // also reset timers here to prevent them continuing after spectating
 768         player.buff_disability_time = 0;
 769         player.buff_disability_effect_time = 0;
 770
 771         return false;
 772 }
 773 MUTATOR_HOOKFUNCTION(buffs, MakePlayerObserver) { return buffs_RemovePlayer(self); }
 774 MUTATOR_HOOKFUNCTION(buffs, ClientDisconnect) { return buffs_RemovePlayer(self); }
 775
 776 MUTATOR_HOOKFUNCTION(buffs, CustomizeWaypoint)
 777 {SELFPARAM();
 778         entity e = WaypointSprite_getviewentity(other);
 779
 780         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 781         // but only apply this to real players, not to spectators
 782         if((self.owner.flags & FL_CLIENT) && (self.owner.buffs & BUFF_INVISIBLE.m_itemid) && (e == other))
 783         if(DIFF_TEAM(self.owner, e))
 784                 return true;
 785
 786         return false;
 787 }
 788
 789 MUTATOR_HOOKFUNCTION(buffs, OnEntityPreSpawn, CBC_ORDER_LAST)
 790 {SELFPARAM();
 791         if(autocvar_g_buffs_replace_powerups)
 792         switch(self.classname)
 793         {
 794                 case "item_strength":
 795                 case "item_invincible":
 796                 {
 797                         entity e = spawn();
 798                         buff_SpawnReplacement(e, self);
 799                         return true;
 800                 }
 801         }
 802         return false;
 803 }
 804
 805 MUTATOR_HOOKFUNCTION(buffs, WeaponRateFactor)
 806 {SELFPARAM();
 807         if(self.buffs & BUFF_SPEED.m_itemid)
 808                 weapon_rate *= autocvar_g_buffs_speed_rate;
 809
 810         if(time < self.buff_disability_time)
 811                 weapon_rate *= autocvar_g_buffs_disability_rate;
 812
 813         return false;
 814 }
 815
 816 MUTATOR_HOOKFUNCTION(buffs, WeaponSpeedFactor)
 817 {SELFPARAM();
 818         if(self.buffs & BUFF_SPEED.m_itemid)
 819                 ret_float *= autocvar_g_buffs_speed_weaponspeed;
 820
 821         if(time < self.buff_disability_time)
 822                 ret_float *= autocvar_g_buffs_disability_weaponspeed;
 823
 824         return false;
 825 }
 826
 827 MUTATOR_HOOKFUNCTION(buffs, PlayerPreThink)
 828 {SELFPARAM();
 829         if(gameover || self.deadflag != DEAD_NO) { return false; }
 830
 831         if(time < self.buff_disability_time)
 832         if(time >= self.buff_disability_effect_time)
 833         {
 834                 Send_Effect(EFFECT_SMOKING, self.origin + ((self.mins + self.maxs) * 0.5), '0 0 0', 1);
 835                 self.buff_disability_effect_time = time + 0.5;
 836         }
 837
 838         // handle buff lost status
 839         // 1: notify everyone else
 840         // 2: notify carrier as well
 841         int buff_lost = 0;
 842
 843         if(self.buff_time)
 844         if(time >= self.buff_time)
 845                 buff_lost = 2;
 846
 847         if(self.frozen) { buff_lost = 1; }
 848
 849         if(buff_lost)
 850         {
 851                 if(self.buffs)
 852                 {
 853                         int buffid = buff_FirstFromFlags(self.buffs).m_id;
 854                         Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 855                         if(buff_lost >= 2)
 856                         {
 857                                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, buffid); // TODO: special timeout message?
 858                                 sound(self, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 859                         }
 860                         self.buffs = 0;
 861                 }
 862         }
 863
 864         if(self.buffs & BUFF_MAGNET.m_itemid)
 865         {
 866                 vector pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_item;
 867                 for(other = world; (other = findflags(other, flags, FL_ITEM)); )
 868                 if(boxesoverlap(self.absmin - pickup_size, self.absmax + pickup_size, other.absmin, other.absmax))
 869                 {
 870                         setself(other);
 871                         other = this;
 872                         if(self.touch)
 873                                 self.touch();
 874                         other = self;
 875                         setself(this);
 876                 }
 877         }
 878
 879         if(self.buffs & BUFF_AMMO.m_itemid)
 880         if(self.clip_size)
 881                 self.clip_load = self.(weapon_load[self.switchweapon]) = self.clip_size;
 882
 883         if((self.buffs & BUFF_INVISIBLE.m_itemid) && (self.oldbuffs & BUFF_INVISIBLE.m_itemid))
 884         if(self.alpha != autocvar_g_buffs_invisible_alpha)
 885                 self.alpha = autocvar_g_buffs_invisible_alpha; // powerups reset alpha, so we must enforce this (TODO)
 886
 887 #define BUFF_ONADD(b) if ( (self.buffs & (b).m_itemid) && !(self.oldbuffs & (b).m_itemid))
 888 #define BUFF_ONREM(b) if (!(self.buffs & (b).m_itemid) &&  (self.oldbuffs & (b).m_itemid))
 889
 890         if(self.buffs != self.oldbuffs)
 891         {
 892                 entity buff = buff_FirstFromFlags(self.buffs);
 893                 float bufftime = buff != BUFF_Null ? buff.m_time(buff) : 0;
 894                 self.buff_time = (bufftime) ? time + bufftime : 0;
 895
 896                 BUFF_ONADD(BUFF_AMMO)
 897                 {
 898                         self.buff_ammo_prev_infitems = (self.items & IT_UNLIMITED_WEAPON_AMMO);
 899                         self.items |= IT_UNLIMITED_WEAPON_AMMO;
 900
 901                         if(self.clip_load)
 902                                 self.buff_ammo_prev_clipload = self.clip_load;
 903                         self.clip_load = self.(weapon_load[self.switchweapon]) = self.clip_size;
 904                 }
 905
 906                 BUFF_ONREM(BUFF_AMMO)
 907                 {
 908                         if(self.buff_ammo_prev_infitems)
 909                                 self.items |= IT_UNLIMITED_WEAPON_AMMO;
 910                         else
 911                                 self.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 912
 913                         if(self.buff_ammo_prev_clipload)
 914                                 self.clip_load = self.buff_ammo_prev_clipload;
 915                 }
 916
 917                 BUFF_ONADD(BUFF_INVISIBLE)
 918                 {
 919                         if(time < self.strength_finished && g_instagib)
 920                                 self.alpha = autocvar_g_instagib_invis_alpha;
 921                         else
 922                                 self.alpha = self.buff_invisible_prev_alpha;
 923                         self.alpha = autocvar_g_buffs_invisible_alpha;
 924                 }
 925
 926                 BUFF_ONREM(BUFF_INVISIBLE)
 927                         self.alpha = self.buff_invisible_prev_alpha;
 928
 929                 BUFF_ONADD(BUFF_FLIGHT)
 930                 {
 931                         self.buff_flight_prev_gravity = self.gravity;
 932                         self.gravity = autocvar_g_buffs_flight_gravity;
 933                 }
 934
 935                 BUFF_ONREM(BUFF_FLIGHT)
 936                         self.gravity = self.buff_flight_prev_gravity;
 937
 938                 self.oldbuffs = self.buffs;
 939                 if(self.buffs)
 940                 {
 941                         if(!self.buff_model)
 942                                 buffs_BuffModel_Spawn(self);
 943
 944                         self.buff_model.color = buff.m_color;
 945                         self.buff_model.glowmod = buff_GlowColor(self.buff_model);
 946                         self.buff_model.skin = buff.m_skin;
 947
 948                         self.effects |= EF_NOSHADOW;
 949                 }
 950                 else
 951                 {
 952                         remove(self.buff_model);
 953                         self.buff_model = world;
 954
 955                         self.effects &= ~(EF_NOSHADOW);
 956                 }
 957         }
 958
 959         if(self.buff_model)
 960         {
 961                 self.buff_model.effects = self.effects;
 962                 self.buff_model.effects |= EF_LOWPRECISION;
 963                 self.buff_model.effects = self.buff_model.effects & EFMASK_CHEAP; // eat performance
 964
 965                 self.buff_model.alpha = self.alpha;
 966         }
 967
 968 #undef BUFF_ONADD
 969 #undef BUFF_ONREM
 970         return false;
 971 }
 972
 973 MUTATOR_HOOKFUNCTION(buffs, SpectateCopy)
 974 {SELFPARAM();
 975         self.buffs = other.buffs;
 976         return false;
 977 }
 978
 979 MUTATOR_HOOKFUNCTION(buffs, VehicleEnter)
 980 {
 981         vh_vehicle.buffs = vh_player.buffs;
 982         vh_player.buffs = 0;
 983         vh_vehicle.buff_time = vh_player.buff_time - time;
 984         vh_player.buff_time = 0;
 985         return false;
 986 }
 987
 988 MUTATOR_HOOKFUNCTION(buffs, VehicleExit)
 989 {
 990         vh_player.buffs = vh_player.oldbuffs = vh_vehicle.buffs;
 991         vh_vehicle.buffs = 0;
 992         vh_player.buff_time = time + vh_vehicle.buff_time;
 993         vh_vehicle.buff_time = 0;
 994         return false;
 995 }
 996
 997 MUTATOR_HOOKFUNCTION(buffs, PlayerRegen)
 998 {SELFPARAM();
 999         if(self.buffs & BUFF_MEDIC.m_itemid)
1000         {
1001                 regen_mod_rot = autocvar_g_buffs_medic_rot;
1002                 regen_mod_limit = regen_mod_max = autocvar_g_buffs_medic_max;
1003                 regen_mod_regen = autocvar_g_buffs_medic_regen;
1004         }
1005
1006         if(self.buffs & BUFF_SPEED.m_itemid)
1007                 regen_mod_regen = autocvar_g_buffs_speed_regen;
1008
1009         return false;
1010 }
1011
1012 MUTATOR_HOOKFUNCTION(buffs, GetCvars)
1013 {
1014         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_buffs_autoreplace, "cl_buffs_autoreplace");
1015         return false;
1016 }
1017
1018 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsString)
1019 {
1020         ret_string = strcat(ret_string, ":Buffs");
1021         return false;
1022 }
1023
1024 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsPrettyString)
1025 {
1026         ret_string = strcat(ret_string, ", Buffs");
1027         return false;
1028 }
1029
1030 void buffs_DelayedInit()
1031 {
1032         if(autocvar_g_buffs_spawn_count > 0)
1033         if(find(world, classname, "item_buff") == world)
1034         {
1035                 float i;
1036                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
1037                 {
1038                         entity e = spawn();
1039                         e.spawnflags |= 64; // always randomize
1040                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
1041                         buff_Init(e);
1042                 }
1043         }
1044 }
1045 #endif