qcsrc/common/mutators/mutator/buffs/sv_buffs.qc

   1 #include "sv_buffs.qh"
   2
   3 #include <common/triggers/target/music.qh>
   4 #include <common/gamemodes/_mod.qh>
   5
   6 .float buff_time = _STAT(BUFF_TIME);
   7 void buffs_DelayedInit(entity this);
   8
   9 AUTOCVAR(g_buffs, int, -1, "Enable buffs, -1: enabled but no auto location or replacing powerups, 1: enabled and can replace them");
  10
  11 REGISTER_MUTATOR(buffs, autocvar_g_buffs)
  12 {
  13         MUTATOR_ONADD
  14         {
  15                 if(autocvar_g_buffs > 0)
  16                         InitializeEntity(NULL, buffs_DelayedInit, INITPRIO_FINDTARGET);
  17         }
  18 }
  19
  20 bool buffs_BuffModel_Customize(entity this, entity client)
  21 {
  22         entity player, myowner;
  23         bool same_team;
  24
  25         player = WaypointSprite_getviewentity(client);
  26         myowner = this.owner;
  27         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
  28
  29         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
  30                 return false;
  31
  32         if(MUTATOR_CALLHOOK(BuffModel_Customize, this, player))
  33                 return false;
  34
  35         if(player == myowner || (IS_SPEC(client) && client.enemy == myowner))
  36         {
  37                 // somewhat hide the model, but keep the glow
  38                 this.effects = 0;
  39                 this.alpha = -1;
  40         }
  41         else
  42         {
  43                 this.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
  44                 this.alpha = 1;
  45         }
  46         return true;
  47 }
  48
  49 void buffs_BuffModel_Spawn(entity player)
  50 {
  51         player.buff_model = spawn();
  52         setmodel(player.buff_model, MDL_BUFF);
  53         setsize(player.buff_model, '0 0 -40', '0 0 40');
  54         setattachment(player.buff_model, player, "");
  55         setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
  56         player.buff_model.owner = player;
  57         player.buff_model.scale = 0.7;
  58         player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
  59         player.buff_model.light_lev = 200;
  60         setcefc(player.buff_model, buffs_BuffModel_Customize);
  61 }
  62
  63 vector buff_GlowColor(entity buff)
  64 {
  65         //if(buff.team) { return Team_ColorRGB(buff.team); }
  66         return buff.m_color;
  67 }
  68
  69 void buff_Effect(entity player, string eff)
  70 {
  71         if(!autocvar_g_buffs_effects) { return; }
  72
  73         if(time >= player.buff_effect_delay)
  74         {
  75                 Send_Effect_(eff, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
  76                 player.buff_effect_delay = time + 0.05; // prevent spam
  77         }
  78 }
  79
  80 // buff item
  81 bool buff_Waypoint_visible_for_player(entity this, entity player, entity view)
  82 {
  83         if(!this.owner.buff_active && !this.owner.buff_activetime)
  84                 return false;
  85
  86         if (view.buffs)
  87         {
  88                 return view.cvar_cl_buffs_autoreplace == false || view.buffs != this.owner.buffs;
  89         }
  90
  91         return WaypointSprite_visible_for_player(this, player, view);
  92 }
  93
  94 void buff_Waypoint_Spawn(entity e)
  95 {
  96         entity buff = buff_FirstFromFlags(e.buffs);
  97         entity wp = WaypointSprite_Spawn(WP_Buff, 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, NULL, e.team, e, buff_waypoint, true, RADARICON_Buff);
  98         wp.wp_extra = buff.m_id;
  99         WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_Buff, e.glowmod);
 100         e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
 101 }
 102
 103 void buff_SetCooldown(entity this, float cd)
 104 {
 105         cd = max(0, cd);
 106
 107         if(!this.buff_waypoint)
 108                 buff_Waypoint_Spawn(this);
 109
 110         WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + cd);
 111         this.buff_activetime = cd;
 112         this.buff_active = !cd;
 113 }
 114
 115 void buff_Respawn(entity this)
 116 {
 117         if(game_stopped) return;
 118
 119         vector oldbufforigin = this.origin;
 120         this.velocity = '0 0 200';
 121
 122         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY,
 123                 ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
 124         {
 125                 entity spot = SelectSpawnPoint(this, true);
 126                 setorigin(this, spot.origin);
 127                 this.velocity = ((randomvec() * 100) + '0 0 200');
 128                 this.angles = spot.angles;
 129         }
 130
 131         tracebox(this.origin, this.mins * 1.5, this.maxs * 1.5, this.origin, MOVE_NOMONSTERS, this);
 132
 133         setorigin(this, trace_endpos); // attempt to unstick
 134
 135         set_movetype(this, MOVETYPE_TOSS);
 136
 137         makevectors(this.angles);
 138         this.angles = '0 0 0';
 139         if(autocvar_g_buffs_random_lifetime > 0)
 140                 this.lifetime = time + autocvar_g_buffs_random_lifetime;
 141
 142         Send_Effect(EFFECT_ELECTRO_COMBO, oldbufforigin + ((this.mins + this.maxs) * 0.5), '0 0 0', 1);
 143         Send_Effect(EFFECT_ELECTRO_COMBO, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 144
 145         WaypointSprite_Ping(this.buff_waypoint);
 146
 147         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 148 }
 149
 150 void buff_Touch(entity this, entity toucher)
 151 {
 152         if(game_stopped) return;
 153
 154         if(ITEM_TOUCH_NEEDKILL())
 155         {
 156                 buff_Respawn(this);
 157                 return;
 158         }
 159
 160         if((this.team && DIFF_TEAM(toucher, this))
 161         || (STAT(FROZEN, toucher))
 162         || (toucher.vehicle)
 163         || (time < toucher.buff_shield)
 164         || (!this.buff_active)
 165         )
 166         {
 167                 // can't touch this
 168                 return;
 169         }
 170
 171         if(MUTATOR_CALLHOOK(BuffTouch, this, toucher))
 172                 return;
 173         toucher = M_ARGV(1, entity);
 174
 175         if(!IS_PLAYER(toucher))
 176                 return; // incase mutator changed toucher
 177
 178         if (toucher.buffs)
 179         {
 180                 if (toucher.cvar_cl_buffs_autoreplace && toucher.buffs != this.buffs)
 181                 {
 182                         int buffid = buff_FirstFromFlags(toucher.buffs).m_id;
 183                         //Send_Notification(NOTIF_ONE, toucher, MSG_MULTI, ITEM_BUFF_DROP, toucher.buffs);
 184                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ITEM_BUFF_LOST, toucher.netname, buffid);
 185
 186                         toucher.buffs = 0;
 187                         //sound(toucher, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 188                 }
 189                 else { return; } // do nothing
 190         }
 191
 192         this.owner = toucher;
 193         this.buff_active = false;
 194         this.lifetime = 0;
 195         int buffid = buff_FirstFromFlags(this.buffs).m_id;
 196         Send_Notification(NOTIF_ONE, toucher, MSG_MULTI, ITEM_BUFF_GOT, buffid);
 197         Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_INFO, INFO_ITEM_BUFF, toucher.netname, buffid);
 198
 199         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 200         sound(toucher, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTN_NORM);
 201         toucher.buffs |= (this.buffs);
 202 }
 203
 204 float buff_Available(entity buff)
 205 {
 206         if (buff == BUFF_Null)
 207                 return false;
 208         if (buff == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 209                 return false;
 210         if (buff == BUFF_VAMPIRE && cvar("g_vampire"))
 211                 return false;
 212         return cvar(strcat("g_buffs_", buff.m_name));
 213 }
 214
 215 .int buff_seencount;
 216
 217 void buff_NewType(entity ent)
 218 {
 219         RandomSelection_Init();
 220         FOREACH(Buffs, buff_Available(it),
 221         {
 222                 // if it's already been chosen, give it a lower priority
 223                 RandomSelection_AddEnt(it, max(0.2, 1 / it.buff_seencount), 1);
 224         });
 225         entity newbuff = RandomSelection_chosen_ent;
 226         newbuff.buff_seencount += 1; // lower chances of seeing this buff again soon
 227         ent.buffs = newbuff.m_itemid;
 228 }
 229
 230 void buff_Think(entity this)
 231 {
 232         if(this.buffs != this.oldbuffs)
 233         {
 234                 entity buff = buff_FirstFromFlags(this.buffs);
 235                 this.color = buff.m_color;
 236                 this.glowmod = buff_GlowColor(buff);
 237                 this.skin = buff.m_skin;
 238
 239                 setmodel(this, MDL_BUFF);
 240                 setsize(this, BUFF_MIN, BUFF_MAX);
 241
 242                 if(this.buff_waypoint)
 243                 {
 244                         //WaypointSprite_Disown(this.buff_waypoint, 1);
 245                         WaypointSprite_Kill(this.buff_waypoint);
 246                         buff_Waypoint_Spawn(this);
 247                         if(this.buff_activetime)
 248                                 WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + this.buff_activetime - frametime);
 249                 }
 250
 251                 this.oldbuffs = this.buffs;
 252         }
 253
 254         if(!game_stopped)
 255         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 256         if(!this.buff_activetime_updated)
 257         {
 258                 buff_SetCooldown(this, this.buff_activetime);
 259                 this.buff_activetime_updated = true;
 260         }
 261
 262         if(!this.buff_active && !this.buff_activetime)
 263         if(!this.owner || STAT(FROZEN, this.owner) || IS_DEAD(this.owner) || !this.owner.iscreature || this.owner.vehicle || !(this.owner.buffs & this.buffs) || this.pickup_anyway > 0 || (this.pickup_anyway >= 0 && autocvar_g_buffs_pickup_anyway))
 264         {
 265                 buff_SetCooldown(this, autocvar_g_buffs_cooldown_respawn + frametime);
 266                 this.owner = NULL;
 267                 if(autocvar_g_buffs_randomize)
 268                         buff_NewType(this);
 269
 270                 if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 271                         buff_Respawn(this);
 272         }
 273
 274         if(this.buff_activetime)
 275         if(!game_stopped)
 276         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 277         {
 278                 this.buff_activetime = max(0, this.buff_activetime - frametime);
 279
 280                 if(!this.buff_activetime)
 281                 {
 282                         this.buff_active = true;
 283                         sound(this, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTN_NORM);
 284                         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 285                 }
 286         }
 287
 288         if(this.buff_active)
 289         {
 290                 if(this.team && !this.buff_waypoint)
 291                         buff_Waypoint_Spawn(this);
 292
 293                 if(this.lifetime)
 294                 if(time >= this.lifetime)
 295                         buff_Respawn(this);
 296         }
 297
 298         this.nextthink = time;
 299         //this.angles_y = time * 110.1;
 300 }
 301
 302 void buff_Waypoint_Reset(entity this)
 303 {
 304         WaypointSprite_Kill(this.buff_waypoint);
 305
 306         if(this.buff_activetime) { buff_Waypoint_Spawn(this); }
 307 }
 308
 309 void buff_Reset(entity this)
 310 {
 311         if(autocvar_g_buffs_randomize)
 312                 buff_NewType(this);
 313         this.owner = NULL;
 314         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate);
 315         buff_Waypoint_Reset(this);
 316         this.buff_activetime_updated = false;
 317
 318         if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 319                 buff_Respawn(this);
 320 }
 321
 322 bool buff_Customize(entity this, entity client)
 323 {
 324         entity player = WaypointSprite_getviewentity(client);
 325         if(!this.buff_active || (this.team && DIFF_TEAM(player, this)))
 326         {
 327                 this.alpha = 0.3;
 328                 if(this.effects & EF_FULLBRIGHT) { this.effects &= ~(EF_FULLBRIGHT); }
 329                 this.pflags = 0;
 330         }
 331         else
 332         {
 333                 this.alpha = 1;
 334                 if(!(this.effects & EF_FULLBRIGHT)) { this.effects |= EF_FULLBRIGHT; }
 335                 this.light_lev = 220 + 36 * sin(time);
 336                 this.pflags = PFLAGS_FULLDYNAMIC;
 337         }
 338         return true;
 339 }
 340
 341 void buff_Init(entity this)
 342 {
 343         if(!cvar("g_buffs")) { delete(this); return; }
 344
 345         if(!teamplay && this.team) { this.team = 0; }
 346
 347         entity buff = buff_FirstFromFlags(this.buffs);
 348
 349         if(!this.buffs || !buff_Available(buff))
 350                 buff_NewType(this);
 351
 352         this.classname = "item_buff";
 353         this.solid = SOLID_TRIGGER;
 354         this.flags = FL_ITEM;
 355         this.bot_pickup = true;
 356         this.bot_pickupevalfunc = generic_pickupevalfunc;
 357         this.bot_pickupbasevalue = 1000;
 358         IL_PUSH(g_items, this);
 359         setthink(this, buff_Think);
 360         settouch(this, buff_Touch);
 361         this.reset = buff_Reset;
 362         this.nextthink = time + 0.1;
 363         this.gravity = 1;
 364         set_movetype(this, MOVETYPE_TOSS);
 365         this.scale = 1;
 366         this.skin = buff.m_skin;
 367         this.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 368         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 369         setcefc(this, buff_Customize);
 370         //this.gravity = 100;
 371         this.color = buff.m_color;
 372         this.glowmod = buff_GlowColor(this);
 373         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate + max(0, game_starttime - time));
 374         this.buff_active = !this.buff_activetime;
 375         this.pflags = PFLAGS_FULLDYNAMIC;
 376
 377         if(this.spawnflags & 1)
 378                 this.noalign = true;
 379
 380         if(this.noalign)
 381                 set_movetype(this, MOVETYPE_NONE); // reset by random location
 382
 383         setmodel(this, MDL_BUFF);
 384         setsize(this, BUFF_MIN, BUFF_MAX);
 385
 386         if(cvar("g_buffs_random_location") || (this.spawnflags & 64))
 387                 buff_Respawn(this);
 388 }
 389
 390 void buff_Init_Compat(entity ent, entity replacement)
 391 {
 392         if (ent.spawnflags & 2)
 393                 ent.team = NUM_TEAM_1;
 394         else if (ent.spawnflags & 4)
 395                 ent.team = NUM_TEAM_2;
 396
 397         ent.buffs = replacement.m_itemid;
 398
 399         buff_Init(ent);
 400 }
 401
 402 void buff_SpawnReplacement(entity ent, entity old)
 403 {
 404         setorigin(ent, old.origin);
 405         ent.angles = old.angles;
 406         ent.noalign = (old.noalign || (old.spawnflags & 1));
 407
 408         buff_Init(ent);
 409 }
 410
 411 void buff_Vengeance_DelayedDamage(entity this)
 412 {
 413         if(this.enemy)
 414                 Damage(this.enemy, this.owner, this.owner, this.dmg, DEATH_BUFF.m_id, this.enemy.origin, '0 0 0');
 415
 416         delete(this);
 417         return;
 418 }
 419
 420 // note: only really useful in teamplay
 421 void buff_Medic_Heal(entity this)
 422 {
 423         FOREACH_CLIENT(IS_PLAYER(it) && it != this && vdist(it.origin - this.origin, <=, autocvar_g_buffs_medic_heal_range),
 424         {
 425                 if(SAME_TEAM(it, this))
 426                 if(it.health < autocvar_g_balance_health_regenstable)
 427                 {
 428                         Send_Effect(EFFECT_HEALING, it.origin, '0 0 0', 1);
 429                         it.health = bound(0, it.health + autocvar_g_buffs_medic_heal_amount, autocvar_g_balance_health_regenstable);
 430                 }
 431         });
 432 }
 433
 434 float buff_Inferno_CalculateTime(float damg, float offset_x, float offset_y, float intersect_x, float intersect_y, float base)
 435 {
 436         return offset_y + (intersect_y - offset_y) * logn(((damg - offset_x) * ((base - 1) / intersect_x)) + 1, base);
 437 }
 438
 439 // mutator hooks
 440 MUTATOR_HOOKFUNCTION(buffs, Damage_Calculate)
 441 {
 442         entity frag_attacker = M_ARGV(1, entity);
 443         entity frag_target = M_ARGV(2, entity);
 444         float frag_deathtype = M_ARGV(3, float);
 445         float frag_damage = M_ARGV(4, float);
 446         vector frag_force = M_ARGV(6, vector);
 447
 448         if(frag_deathtype == DEATH_BUFF.m_id) { return; }
 449
 450         if(frag_target.buffs & BUFF_RESISTANCE.m_itemid)
 451         {
 452                 float reduced = frag_damage * autocvar_g_buffs_resistance_blockpercent;
 453                 frag_damage = bound(0, frag_damage - reduced, frag_damage);
 454         }
 455
 456         if(frag_target.buffs & BUFF_SPEED.m_itemid)
 457         if(frag_target != frag_attacker)
 458                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 459
 460         if(frag_target.buffs & BUFF_MEDIC.m_itemid)
 461         if((frag_target.health - frag_damage) <= 0)
 462         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 463         if(frag_attacker)
 464         if(random() <= autocvar_g_buffs_medic_survive_chance)
 465                 frag_damage = max(5, frag_target.health - autocvar_g_buffs_medic_survive_health);
 466
 467         if(frag_target.buffs & BUFF_JUMP.m_itemid)
 468         if(frag_deathtype == DEATH_FALL.m_id)
 469                 frag_damage = 0;
 470
 471         if(frag_target.buffs & BUFF_VENGEANCE.m_itemid)
 472         if(frag_attacker)
 473         if(frag_attacker != frag_target)
 474         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 475         {
 476                 entity dmgent = spawn();
 477
 478                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 479                 dmgent.enemy = frag_attacker;
 480                 dmgent.owner = frag_target;
 481                 setthink(dmgent, buff_Vengeance_DelayedDamage);
 482                 dmgent.nextthink = time + 0.1;
 483         }
 484
 485         if(frag_target.buffs & BUFF_BASH.m_itemid)
 486         if(frag_attacker != frag_target)
 487                 frag_force = '0 0 0';
 488
 489         if(frag_attacker.buffs & BUFF_BASH.m_itemid)
 490         if(frag_force)
 491         if(frag_attacker == frag_target)
 492                 frag_force *= autocvar_g_buffs_bash_force_self;
 493         else
 494                 frag_force *= autocvar_g_buffs_bash_force;
 495
 496         if(frag_attacker.buffs & BUFF_DISABILITY.m_itemid)
 497         if(frag_target != frag_attacker)
 498                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_slowtime;
 499
 500         if(frag_target.buffs & BUFF_INFERNO.m_itemid)
 501         {
 502                 if(frag_deathtype == DEATH_FIRE.m_id)
 503                         frag_damage = 0;
 504                 if(frag_deathtype == DEATH_LAVA.m_id)
 505                         frag_damage *= 0.5; // TODO: cvarize?
 506         }
 507
 508         if(frag_attacker.buffs & BUFF_LUCK.m_itemid)
 509         if(frag_attacker != frag_target)
 510         if(autocvar_g_buffs_luck_damagemultiplier > 0)
 511         if(random() <= autocvar_g_buffs_luck_chance)
 512                 frag_damage *= autocvar_g_buffs_luck_damagemultiplier;
 513
 514         if(frag_attacker.buffs & BUFF_INFERNO.m_itemid)
 515         if(frag_target != frag_attacker) {
 516                 float btime = buff_Inferno_CalculateTime(
 517                         frag_damage,
 518                         0,
 519                         autocvar_g_buffs_inferno_burntime_min_time,
 520                         autocvar_g_buffs_inferno_burntime_target_damage,
 521                         autocvar_g_buffs_inferno_burntime_target_time,
 522                         autocvar_g_buffs_inferno_burntime_factor
 523                 );
 524                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier), btime, DEATH_BUFF.m_id);
 525         }
 526
 527         // this... is ridiculous (TODO: fix!)
 528         if(frag_attacker.buffs & BUFF_VAMPIRE.m_itemid)
 529         if(!frag_target.vehicle)
 530         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 531         if(!IS_DEAD(frag_target))
 532         if(IS_PLAYER(frag_target) || IS_MONSTER(frag_target))
 533         if(frag_attacker != frag_target)
 534         if(!STAT(FROZEN, frag_target))
 535         if(frag_target.takedamage)
 536         if(DIFF_TEAM(frag_attacker, frag_target))
 537         {
 538                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 539                 if(frag_target.armorvalue)
 540                         frag_attacker.armorvalue = bound(0, frag_attacker.armorvalue + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.armorvalue), g_pickup_armorsmall_max);
 541         }
 542
 543         M_ARGV(4, float) = frag_damage;
 544         M_ARGV(6, vector) = frag_force;
 545 }
 546
 547 MUTATOR_HOOKFUNCTION(buffs, PlayerSpawn)
 548 {
 549         entity player = M_ARGV(0, entity);
 550
 551         player.buffs = 0;
 552         player.buff_time = 0;
 553         player.buff_shield = time + 0.5; // prevent picking up buffs immediately
 554         // reset timers here to prevent them continuing after re-spawn
 555         player.buff_disability_time = 0;
 556         player.buff_disability_effect_time = 0;
 557 }
 558
 559 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics_UpdateStats)
 560 {
 561         entity player = M_ARGV(0, entity);
 562         // these automatically reset, no need to worry
 563
 564         if(player.buffs & BUFF_SPEED.m_itemid)
 565                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_buffs_speed_speed;
 566
 567         if(time < player.buff_disability_time)
 568                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_buffs_disability_speed;
 569 }
 570
 571 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics)
 572 {
 573         entity player = M_ARGV(0, entity);
 574         // these automatically reset, no need to worry
 575
 576         if(player.buffs & BUFF_JUMP.m_itemid)
 577                 STAT(MOVEVARS_JUMPVELOCITY, player) = autocvar_g_buffs_jump_height;
 578 }
 579
 580 MUTATOR_HOOKFUNCTION(buffs, MonsterMove)
 581 {
 582         entity mon = M_ARGV(0, entity);
 583
 584         if(time < mon.buff_disability_time)
 585         {
 586                 M_ARGV(1, float) *= autocvar_g_buffs_disability_speed; // run speed
 587                 M_ARGV(2, float) *= autocvar_g_buffs_disability_speed; // walk speed
 588         }
 589 }
 590
 591 MUTATOR_HOOKFUNCTION(buffs, PlayerDies)
 592 {
 593         entity frag_target = M_ARGV(2, entity);
 594
 595         if(frag_target.buffs)
 596         {
 597                 int buffid = buff_FirstFromFlags(frag_target.buffs).m_id;
 598                 Send_Notification(NOTIF_ALL_EXCEPT, frag_target, MSG_INFO, INFO_ITEM_BUFF_LOST, frag_target.netname, buffid);
 599                 frag_target.buffs = 0;
 600
 601                 if(frag_target.buff_model)
 602                 {
 603                         delete(frag_target.buff_model);
 604                         frag_target.buff_model = NULL;
 605                 }
 606         }
 607 }
 608
 609 MUTATOR_HOOKFUNCTION(buffs, PlayerUseKey, CBC_ORDER_FIRST)
 610 {
 611         if(MUTATOR_RETURNVALUE || game_stopped || !autocvar_g_buffs_drop) return;
 612
 613         entity player = M_ARGV(0, entity);
 614
 615         if(player.buffs)
 616         {
 617                 int buffid = buff_FirstFromFlags(player.buffs).m_id;
 618                 Send_Notification(NOTIF_ONE, player, MSG_MULTI, ITEM_BUFF_DROP, buffid);
 619                 Send_Notification(NOTIF_ALL_EXCEPT, player, MSG_INFO, INFO_ITEM_BUFF_LOST, player.netname, buffid);
 620
 621                 player.buffs = 0;
 622                 player.buff_shield = time + max(0, autocvar_g_buffs_pickup_delay);
 623                 //player.buff_time = 0; // already notified
 624                 sound(player, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 625                 return true;
 626         }
 627 }
 628
 629 MUTATOR_HOOKFUNCTION(buffs, ForbidThrowCurrentWeapon)
 630 {
 631         if(MUTATOR_RETURNVALUE || game_stopped) return;
 632         entity player = M_ARGV(0, entity);
 633
 634         if(player.buffs & BUFF_SWAPPER.m_itemid)
 635         {
 636                 float best_distance = autocvar_g_buffs_swapper_range;
 637                 entity closest = NULL;
 638                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 639                         if(!IS_DEAD(it) && !STAT(FROZEN, it) && !it.vehicle)
 640                         if(DIFF_TEAM(it, player))
 641                         {
 642                                 float test = vlen2(player.origin - it.origin);
 643                                 if(test <= best_distance * best_distance)
 644                                 {
 645                                         best_distance = sqrt(test);
 646                                         closest = it;
 647                                 }
 648                         }
 649                 ));
 650
 651                 if(closest)
 652                 {
 653                         vector my_org, my_vel, my_ang, their_org, their_vel, their_ang;
 654
 655                         my_org = player.origin;
 656                         my_vel = player.velocity;
 657                         my_ang = player.angles;
 658                         their_org = closest.origin;
 659                         their_vel = closest.velocity;
 660                         their_ang = closest.angles;
 661
 662                         Drop_Special_Items(closest);
 663
 664                         MUTATOR_CALLHOOK(PortalTeleport, player); // initiate flag dropper
 665
 666                         setorigin(player, their_org);
 667                         setorigin(closest, my_org);
 668
 669                         closest.velocity = my_vel;
 670                         closest.angles = my_ang;
 671                         closest.fixangle = true;
 672                         closest.oldorigin = my_org;
 673                         closest.oldvelocity = my_vel;
 674                         player.velocity = their_vel;
 675                         player.angles = their_ang;
 676                         player.fixangle = true;
 677                         player.oldorigin = their_org;
 678                         player.oldvelocity = their_vel;
 679
 680                         // set pusher so player gets the kill if they fall into void
 681                         closest.pusher = player;
 682                         closest.pushltime = time + autocvar_g_maxpushtime;
 683                         closest.istypefrag = PHYS_INPUT_BUTTON_CHAT(closest);
 684
 685                         Send_Effect(EFFECT_ELECTRO_COMBO, their_org, '0 0 0', 1);
 686                         Send_Effect(EFFECT_ELECTRO_COMBO, my_org, '0 0 0', 1);
 687
 688                         sound(player, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 689                         sound(closest, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 690
 691                         // TODO: add a counter to handle how many times one can teleport, and a delay to prevent spam
 692                         player.buffs = 0;
 693                         return true;
 694                 }
 695         }
 696 }
 697
 698 bool buffs_RemovePlayer(entity player)
 699 {
 700         if(player.buff_model)
 701         {
 702                 delete(player.buff_model);
 703                 player.buff_model = NULL;
 704         }
 705
 706         // also reset timers here to prevent them continuing after spectating
 707         player.buff_disability_time = 0;
 708         player.buff_disability_effect_time = 0;
 709
 710         return false;
 711 }
 712 MUTATOR_HOOKFUNCTION(buffs, MakePlayerObserver) { entity player = M_ARGV(0, entity); return buffs_RemovePlayer(player); }
 713 MUTATOR_HOOKFUNCTION(buffs, ClientDisconnect) { entity player = M_ARGV(0, entity); return buffs_RemovePlayer(player); }
 714
 715 MUTATOR_HOOKFUNCTION(buffs, CustomizeWaypoint)
 716 {
 717         entity wp = M_ARGV(0, entity);
 718         entity player = M_ARGV(1, entity);
 719
 720         entity e = WaypointSprite_getviewentity(player);
 721
 722         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 723         // but only apply this to real players, not to spectators
 724         if((wp.owner.flags & FL_CLIENT) && (wp.owner.buffs & BUFF_INVISIBLE.m_itemid) && (e == player))
 725         if(DIFF_TEAM(wp.owner, e))
 726                 return true;
 727 }
 728
 729 MUTATOR_HOOKFUNCTION(buffs, OnEntityPreSpawn, CBC_ORDER_LAST)
 730 {
 731         if(autocvar_g_buffs < 0)
 732                 return; // no auto replacing of entities in this mode
 733
 734         entity ent = M_ARGV(0, entity);
 735
 736         if(autocvar_g_buffs_replace_powerups)
 737         switch(ent.classname)
 738         {
 739                 case "item_strength":
 740                 case "item_invincible":
 741                 {
 742                         entity e = spawn();
 743                         buff_SpawnReplacement(e, ent);
 744                         return true;
 745                 }
 746         }
 747 }
 748
 749 MUTATOR_HOOKFUNCTION(buffs, WeaponRateFactor)
 750 {
 751         entity player = M_ARGV(1, entity);
 752
 753         if(player.buffs & BUFF_SPEED.m_itemid)
 754                 M_ARGV(0, float) *= autocvar_g_buffs_speed_rate;
 755
 756         if(time < player.buff_disability_time)
 757                 M_ARGV(0, float) *= autocvar_g_buffs_disability_rate;
 758 }
 759
 760 MUTATOR_HOOKFUNCTION(buffs, WeaponSpeedFactor)
 761 {
 762         entity player = M_ARGV(1, entity);
 763
 764         if(player.buffs & BUFF_SPEED.m_itemid)
 765                 M_ARGV(0, float) *= autocvar_g_buffs_speed_weaponspeed;
 766
 767         if(time < player.buff_disability_time)
 768                 M_ARGV(0, float) *= autocvar_g_buffs_disability_weaponspeed;
 769 }
 770
 771 .bool buff_flight_crouchheld;
 772
 773 MUTATOR_HOOKFUNCTION(buffs, PlayerPreThink)
 774 {
 775         entity player = M_ARGV(0, entity);
 776
 777         if(game_stopped || IS_DEAD(player) || frametime || !IS_PLAYER(player)) return;
 778
 779         if(player.buffs & BUFF_FLIGHT.m_itemid)
 780         {
 781                 if(!PHYS_INPUT_BUTTON_CROUCH(player))
 782                         player.buff_flight_crouchheld = false;
 783                 else if(!player.buff_flight_crouchheld)
 784                 {
 785                         player.buff_flight_crouchheld = true;
 786                         player.gravity *= -1;
 787                 }
 788         }
 789
 790         if(time < player.buff_disability_time)
 791         if(time >= player.buff_disability_effect_time)
 792         {
 793                 Send_Effect(EFFECT_SMOKING, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
 794                 player.buff_disability_effect_time = time + 0.5;
 795         }
 796
 797         // handle buff lost status
 798         // 1: notify everyone else
 799         // 2: notify carrier as well
 800         int buff_lost = 0;
 801
 802         if(player.buff_time && player.buffs)
 803         if(time >= player.buff_time)
 804         {
 805                 player.buff_time = 0;
 806                 buff_lost = 2;
 807         }
 808
 809         if(STAT(FROZEN, player)) { buff_lost = 1; }
 810
 811         if(buff_lost)
 812         {
 813                 if(player.buffs)
 814                 {
 815                         int buffid = buff_FirstFromFlags(player.buffs).m_id;
 816                         if(buff_lost == 2)
 817                         {
 818                                 Send_Notification(NOTIF_ONE, player, MSG_MULTI, ITEM_BUFF_DROP, buffid); // TODO: special timeout message?
 819                                 sound(player, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 820                         }
 821                         else
 822                                 Send_Notification(NOTIF_ALL_EXCEPT, player, MSG_INFO, INFO_ITEM_BUFF_LOST, player.netname, buffid);
 823                         player.buffs = 0;
 824                         player.buff_shield = time + max(0, autocvar_g_buffs_pickup_delay); // always put in a delay, even if small
 825                 }
 826         }
 827
 828         if(player.buffs & BUFF_MAGNET.m_itemid)
 829         {
 830                 vector pickup_size;
 831                 IL_EACH(g_items, it.itemdef,
 832                 {
 833                         if(it.buffs)
 834                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_buff;
 835                         else
 836                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_item;
 837
 838                         if(boxesoverlap(player.absmin - pickup_size, player.absmax + pickup_size, it.absmin, it.absmax))
 839                         {
 840                                 if(gettouch(it))
 841                                         gettouch(it)(it, player);
 842                         }
 843                 });
 844         }
 845
 846         if(player.buffs & BUFF_AMMO.m_itemid)
 847         {
 848                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 849                 {
 850                         .entity weaponentity = weaponentities[slot];
 851                         if(player.(weaponentity).clip_size)
 852                                 player.(weaponentity).clip_load = player.(weaponentity).(weapon_load[player.(weaponentity).m_switchweapon.m_id]) = player.(weaponentity).clip_size;
 853                 }
 854         }
 855
 856         if((player.buffs & BUFF_INVISIBLE.m_itemid) && (player.oldbuffs & BUFF_INVISIBLE.m_itemid))
 857                 player.alpha = ((autocvar_g_buffs_invisible_alpha) ? autocvar_g_buffs_invisible_alpha : -1); // powerups reset alpha, so we must enforce this (TODO)
 858
 859         if(player.buffs & BUFF_MEDIC.m_itemid)
 860         if(time >= player.buff_medic_healtime)
 861         {
 862                 buff_Medic_Heal(player);
 863                 player.buff_medic_healtime = time + autocvar_g_buffs_medic_heal_delay;
 864         }
 865
 866 #define BUFF_ONADD(b) if ( (player.buffs & (b).m_itemid) && !(player.oldbuffs & (b).m_itemid))
 867 #define BUFF_ONREM(b) if (!(player.buffs & (b).m_itemid) &&  (player.oldbuffs & (b).m_itemid))
 868
 869         if(player.buffs != player.oldbuffs)
 870         {
 871                 entity buff = buff_FirstFromFlags(player.buffs);
 872                 float bufftime = buff != BUFF_Null ? buff.m_time(buff) : 0;
 873                 player.buff_time = (bufftime) ? time + bufftime : 0;
 874
 875                 BUFF_ONADD(BUFF_AMMO)
 876                 {
 877                         player.buff_ammo_prev_infitems = (player.items & IT_UNLIMITED_WEAPON_AMMO);
 878                         player.items |= IT_UNLIMITED_WEAPON_AMMO;
 879
 880                         if(player.buffs & BUFF_AMMO.m_itemid)
 881                         {
 882                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 883                                 {
 884                                         .entity weaponentity = weaponentities[slot];
 885                                         if(player.(weaponentity).clip_load)
 886                                                 player.(weaponentity).buff_ammo_prev_clipload = player.(weaponentity).clip_load;
 887                                         if(player.(weaponentity).clip_size)
 888                                                 player.(weaponentity).clip_load = player.(weaponentity).(weapon_load[player.(weaponentity).m_switchweapon.m_id]) = player.(weaponentity).clip_size;
 889                                 }
 890                         }
 891                 }
 892
 893                 BUFF_ONREM(BUFF_AMMO)
 894                 {
 895                         if(player.buff_ammo_prev_infitems)
 896                                 player.items |= IT_UNLIMITED_WEAPON_AMMO;
 897                         else
 898                                 player.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 899
 900                         if(player.buffs & BUFF_AMMO.m_itemid)
 901                         {
 902                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 903                                 {
 904                                         .entity weaponentity = weaponentities[slot];
 905                                         if(player.(weaponentity).buff_ammo_prev_clipload)
 906                                                 player.(weaponentity).clip_load = player.(weaponentity).buff_ammo_prev_clipload;
 907                                 }
 908                         }
 909                 }
 910
 911                 BUFF_ONADD(BUFF_INVISIBLE)
 912                 {
 913                         if(time < player.strength_finished && g_instagib)
 914                                 player.buff_invisible_prev_alpha = default_player_alpha; // we don't want to save the powerup's alpha, as player may lose the powerup while holding the buff
 915                         else
 916                                 player.buff_invisible_prev_alpha = player.alpha;
 917                         player.alpha = autocvar_g_buffs_invisible_alpha;
 918                 }
 919
 920                 BUFF_ONREM(BUFF_INVISIBLE)
 921                 {
 922                         if(time < player.strength_finished && g_instagib)
 923                                 player.alpha = autocvar_g_instagib_invis_alpha;
 924                         else
 925                                 player.alpha = player.buff_invisible_prev_alpha;
 926                 }
 927
 928                 BUFF_ONADD(BUFF_FLIGHT)
 929                 {
 930                         player.buff_flight_oldgravity = player.gravity;
 931                         if(!player.gravity)
 932                                 player.gravity = 1;
 933                 }
 934
 935                 BUFF_ONREM(BUFF_FLIGHT)
 936                         player.gravity = ((player.trigger_gravity_check) ? player.trigger_gravity_check.enemy.gravity : player.buff_flight_oldgravity);
 937
 938                 player.oldbuffs = player.buffs;
 939                 if(player.buffs)
 940                 {
 941                         if(!player.buff_model)
 942                                 buffs_BuffModel_Spawn(player);
 943
 944                         player.buff_model.color = buff.m_color;
 945                         player.buff_model.glowmod = buff_GlowColor(player.buff_model);
 946                         player.buff_model.skin = buff.m_skin;
 947
 948                         player.effects |= EF_NOSHADOW;
 949                 }
 950                 else
 951                 {
 952                         if(player.buff_model)
 953                                 delete(player.buff_model);
 954                         player.buff_model = NULL;
 955
 956                         player.effects &= ~(EF_NOSHADOW);
 957                 }
 958         }
 959
 960         if(player.buff_model)
 961         {
 962                 player.buff_model.effects = player.effects;
 963                 player.buff_model.effects |= EF_LOWPRECISION;
 964                 player.buff_model.effects = player.buff_model.effects & EFMASK_CHEAP; // eat performance
 965
 966                 player.buff_model.alpha = player.alpha;
 967         }
 968
 969 #undef BUFF_ONADD
 970 #undef BUFF_ONREM
 971 }
 972
 973 MUTATOR_HOOKFUNCTION(buffs, SpectateCopy)
 974 {
 975         entity spectatee = M_ARGV(0, entity);
 976         entity client = M_ARGV(1, entity);
 977
 978         client.buffs = spectatee.buffs;
 979         client.buff_time = spectatee.buff_time;
 980 }
 981
 982 MUTATOR_HOOKFUNCTION(buffs, PlayerRegen)
 983 {
 984         entity player = M_ARGV(0, entity);
 985
 986         if(player.buffs & BUFF_MEDIC.m_itemid)
 987         {
 988                 M_ARGV(2, float) = autocvar_g_buffs_medic_rot; // rot_mod
 989                 M_ARGV(4, float) = M_ARGV(1, float) = autocvar_g_buffs_medic_max; // limit_mod = max_mod
 990                 M_ARGV(2, float) = autocvar_g_buffs_medic_regen; // regen_mod
 991         }
 992
 993         if(player.buffs & BUFF_SPEED.m_itemid)
 994                 M_ARGV(2, float) = autocvar_g_buffs_speed_regen; // regen_mod
 995 }
 996
 997 REPLICATE(cvar_cl_buffs_autoreplace, bool, "cl_buffs_autoreplace");
 998
 999 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsString)
1000 {
1001         if(autocvar_g_buffs > 0) // only report as a mutator if they're enabled
1002                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ":Buffs");
1003 }
1004
1005 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsPrettyString)
1006 {
1007         if(autocvar_g_buffs > 0)
1008                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Buffs");
1009 }
1010
1011 void buffs_DelayedInit(entity this)
1012 {
1013         if(autocvar_g_buffs_spawn_count > 0)
1014         if(find(NULL, classname, "item_buff") == NULL)
1015         {
1016                 float i;
1017                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
1018                 {
1019                         entity e = spawn();
1020                         e.spawnflags |= 64; // always randomize
1021                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
1022                         buff_Init(e);
1023                 }
1024         }
1025 }