qcsrc/common/mutators/mutator/campcheck/campcheck.qc

   1 #ifdef IMPLEMENTATION
   2 float autocvar_g_campcheck_damage;
   3 float autocvar_g_campcheck_distance;
   4 float autocvar_g_campcheck_interval;
   5
   6 REGISTER_MUTATOR(campcheck, cvar("g_campcheck"));
   7
   8 .float campcheck_nextcheck;
   9 .float campcheck_traveled_distance;
  10
  11 MUTATOR_HOOKFUNCTION(campcheck, PlayerDies)
  12 {
  13         entity frag_target = M_ARGV(2, entity);
  14
  15         Kill_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CPID_CAMPCHECK);
  16         return false;
  17 }
  18
  19 MUTATOR_HOOKFUNCTION(campcheck, PlayerDamage_Calculate)
  20 {
  21         entity frag_attacker = M_ARGV(1, entity);
  22         entity frag_target = M_ARGV(2, entity);
  23
  24         if(IS_PLAYER(frag_target))
  25         if(IS_PLAYER(frag_attacker))
  26         if(frag_attacker != frag_target)
  27         {
  28                 frag_target.campcheck_traveled_distance = autocvar_g_campcheck_distance;
  29                 frag_attacker.campcheck_traveled_distance = autocvar_g_campcheck_distance;
  30         }
  31
  32         return false;
  33 }
  34
  35 MUTATOR_HOOKFUNCTION(campcheck, PlayerPreThink)
  36 {SELFPARAM();
  37         if(!gameover)
  38         if(!warmup_stage) // don't consider it camping during warmup?
  39         if(time >= game_starttime)
  40         if(IS_PLAYER(self))
  41         if(IS_REAL_CLIENT(self)) // bots may camp, but that's no reason to constantly kill them
  42         if(!IS_DEAD(self))
  43         if(!STAT(FROZEN, self))
  44         if(!PHYS_INPUT_BUTTON_CHAT(self))
  45         if(autocvar_g_campcheck_interval)
  46         {
  47                 vector dist;
  48
  49                 // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
  50                 dist = self.prevorigin - self.origin;
  51                 dist.z = 0;
  52                 self.campcheck_traveled_distance += fabs(vlen(dist));
  53
  54                 if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime) || (round_handler_IsActive() && !round_handler_IsRoundStarted()))
  55                 {
  56                         self.campcheck_nextcheck = time + autocvar_g_campcheck_interval * 2;
  57                         self.campcheck_traveled_distance = 0;
  58                 }
  59
  60                 if(time > self.campcheck_nextcheck)
  61                 {
  62                         if(self.campcheck_traveled_distance < autocvar_g_campcheck_distance)
  63                         {
  64                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_CAMPCHECK);
  65                                 if(self.vehicle)
  66                                         Damage(self.vehicle, world, world, autocvar_g_campcheck_damage * 2, DEATH_CAMP.m_id, self.vehicle.origin, '0 0 0');
  67                                 else
  68                                         Damage(self, world, world, bound(0, autocvar_g_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP.m_id, self.origin, '0 0 0');
  69                         }
  70                         self.campcheck_nextcheck = time + autocvar_g_campcheck_interval;
  71                         self.campcheck_traveled_distance = 0;
  72                 }
  73
  74                 return false;
  75         }
  76
  77         self.campcheck_nextcheck = time + autocvar_g_campcheck_interval; // one of the above checks failed, so keep the timer up to date
  78         return false;
  79 }
  80
  81 MUTATOR_HOOKFUNCTION(campcheck, PlayerSpawn)
  82 {
  83         entity player = M_ARGV(0, entity);
  84
  85         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval * 2;
  86         player.campcheck_traveled_distance = 0;
  87 }
  88
  89 MUTATOR_HOOKFUNCTION(campcheck, BuildMutatorsString)
  90 {
  91         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":CampCheck");;
  92 }
  93 #endif