qcsrc/common/mutators/mutator/itemstime.qc

   1 #ifdef IMPLEMENTATION
   2 REGISTER_MUTATOR(itemstime, true);
   3
   4 REGISTER_NET_TEMP(itemstime)
   5
   6 #ifdef SVQC
   7 void IT_Write(entity e, int i, float f) {
   8     if (!IS_REAL_CLIENT(e)) return;
   9     msg_entity = e;
  10     WriteHeader(MSG_ONE, itemstime);
  11     WriteByte(MSG_ONE, i);
  12     WriteFloat(MSG_ONE, f);
  13 }
  14 #endif
  15
  16 #ifdef CSQC
  17 // reserve one more spot for superweapons time
  18 float ItemsTime_time[Items_MAX + 1];
  19 float ItemsTime_availableTime[Items_MAX + 1];
  20 NET_HANDLE(itemstime, bool isNew)
  21 {
  22     int i = ReadByte();
  23     float f = ReadFloat();
  24     return = true;
  25     ItemsTime_time[i] = f;
  26 }
  27 #endif
  28
  29 #ifdef CSQC
  30 void Item_ItemsTime_Init()
  31 {
  32     FOREACH(Items, true, LAMBDA(
  33         ItemsTime_time[it.m_id] = -1;
  34     ));
  35     ItemsTime_time[Items_MAX] = -1;
  36 }
  37
  38 STATIC_INIT(ItemsTime_Init) {
  39     Item_ItemsTime_Init();
  40 }
  41
  42 int autocvar_hud_panel_itemstime = 2;
  43 float autocvar_hud_panel_itemstime_dynamicsize = 1;
  44 float autocvar_hud_panel_itemstime_ratio = 2;
  45 int autocvar_hud_panel_itemstime_iconalign;
  46 bool autocvar_hud_panel_itemstime_progressbar = 0;
  47 float autocvar_hud_panel_itemstime_progressbar_maxtime = 30;
  48 string autocvar_hud_panel_itemstime_progressbar_name = "progressbar";
  49 float autocvar_hud_panel_itemstime_progressbar_reduced;
  50 bool autocvar_hud_panel_itemstime_hidespawned = 1;
  51 bool autocvar_hud_panel_itemstime_hidelarge = false;
  52 int autocvar_hud_panel_itemstime_text = 1;
  53 #define hud_panel_itemstime_hidelarge autocvar_hud_panel_itemstime_hidelarge
  54 #else
  55 #define hud_panel_itemstime_hidelarge false
  56 #endif
  57
  58 bool Item_ItemsTime_SpectatorOnly(GameItem it)
  59 {
  60     return (false
  61     || it == ITEM_ArmorMega     || (it == ITEM_ArmorLarge && !hud_panel_itemstime_hidelarge)
  62     || it == ITEM_HealthMega    || (it == ITEM_HealthLarge && !hud_panel_itemstime_hidelarge)
  63     );
  64 }
  65
  66 bool Item_ItemsTime_Allow(GameItem it)
  67 {
  68     return (false
  69     || it.instanceOfPowerup
  70     || Item_ItemsTime_SpectatorOnly(it)
  71     );
  72 }
  73
  74 #ifdef SVQC
  75
  76 // reserve one more spot for superweapons time
  77 float it_times[Items_MAX + 1];
  78
  79 void Item_ItemsTime_Init()
  80 {
  81     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
  82         it_times[it.m_id] = -1;
  83     ));
  84     it_times[Items_MAX] = -1;
  85 }
  86
  87 STATIC_INIT(ItemsTime_Init) {
  88     // items time
  89     Item_ItemsTime_Init();
  90 }
  91
  92 void Item_ItemsTime_ResetTimes()
  93 {
  94     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
  95         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
  96     ));
  97     it_times[Items_MAX] = (it_times[Items_MAX] == -1) ? -1 : 0;
  98 }
  99
 100 void Item_ItemsTime_ResetTimesForPlayer(entity e)
 101 {
 102     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 103         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
 104     ));
 105     IT_Write(e, Items_MAX, (it_times[Items_MAX] == -1) ? -1 : 0);
 106 }
 107
 108 void Item_ItemsTime_SetTimesForPlayer(entity e)
 109 {
 110     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 111         IT_Write(e, it.m_id, it_times[it.m_id]);
 112     ));
 113     IT_Write(e, Items_MAX, it_times[Items_MAX]);
 114 }
 115
 116 void Item_ItemsTime_SetTime(entity e, float t)
 117 {
 118     if (!autocvar_sv_itemstime)
 119         return;
 120
 121     GameItem item = e.itemdef;
 122     if (item.instanceOfGameItem)
 123     {
 124                 if (!item.instanceOfWeaponPickup)
 125                         it_times[item.m_id] = t;
 126                 else if (e.weapons & WEPSET_SUPERWEAPONS)
 127                         it_times[Items_MAX] = t;
 128     }
 129 }
 130
 131 void Item_ItemsTime_SetTimesForAllPlayers()
 132 {
 133     FOREACH_CLIENT(IS_REAL_CLIENT(it) && (warmup_stage || !IS_PLAYER(it)), LAMBDA(Item_ItemsTime_SetTimesForPlayer(it)));
 134 }
 135
 136 float Item_ItemsTime_UpdateTime(entity e, float t)
 137 {
 138     bool isavailable = (t == 0);
 139     FOREACH_ENTITY(it.itemdef == e.itemdef || ((e.weapons & WEPSET_SUPERWEAPONS) && (it.weapons & WEPSET_SUPERWEAPONS) && clienttype(it) == CLIENTTYPE_NOTACLIENT), LAMBDA(
 140         if (e == it) continue;
 141         if (it.scheduledrespawntime <= time)
 142             isavailable = true;
 143         else if (t == 0 || it.scheduledrespawntime < t)
 144             t = it.scheduledrespawntime;
 145     ));
 146     if (isavailable)
 147         t = -t; // let know the client there's another available item
 148     return t;
 149 }
 150
 151 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global)
 152 {
 153     Item_ItemsTime_ResetTimes();
 154     // ALL the times need to be reset before .reset()ing each item
 155     // since Item_Reset schedules respawn of superweapons and powerups
 156     FOREACH_ENTITY(IS_NOT_A_CLIENT(it), LAMBDA(
 157         if (it.reset) Item_ItemsTime_SetTime(it, 0);
 158     ));
 159     Item_ItemsTime_SetTimesForAllPlayers();
 160 }
 161
 162 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver)
 163 {
 164     entity player = M_ARGV(0, entity);
 165
 166     Item_ItemsTime_SetTimesForPlayer(player);
 167 }
 168
 169 MUTATOR_HOOKFUNCTION(itemstime, ClientConnect, CBC_ORDER_LAST)
 170 {
 171     entity player = M_ARGV(0, entity);
 172
 173         if(IS_PLAYER(player))
 174         {
 175                 // client became player on connection skipping putObserverInServer step
 176                 if (IS_REAL_CLIENT(player))
 177                 if (warmup_stage)
 178                         Item_ItemsTime_SetTimesForPlayer(player);
 179         }
 180 }
 181
 182 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn)
 183 {
 184     if (warmup_stage) return;
 185     entity player = M_ARGV(0, entity);
 186
 187     Item_ItemsTime_ResetTimesForPlayer(player);
 188 }
 189
 190 #endif
 191
 192 #ifdef CSQC
 193
 194 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, string item_icon, float item_time, bool item_available, float item_availableTime)
 195 {
 196     float t = 0;
 197     vector color = '0 0 0';
 198     float picalpha;
 199
 200     if (autocvar_hud_panel_itemstime_hidespawned == 2)
 201         picalpha = 1;
 202     else if (item_available)
 203     {
 204         float BLINK_FACTOR = 0.15;
 205         float BLINK_BASE = 0.85;
 206         float BLINK_FREQ = 5;
 207         picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 208     }
 209     else
 210         picalpha = 0.5;
 211     t = floor(item_time - time + 0.999);
 212     if (t < 5)
 213         color = '0.7 0 0';
 214     else if (t < 10)
 215         color = '0.7 0.7 0';
 216     else
 217         color = '1 1 1';
 218
 219     vector picpos, numpos;
 220     if (autocvar_hud_panel_itemstime_iconalign)
 221     {
 222         numpos = myPos;
 223         picpos = myPos + eX * (ar - 1) * mySize_y;
 224     }
 225     else
 226     {
 227         numpos = myPos + eX * mySize_y;
 228         picpos = myPos;
 229     }
 230
 231     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
 232     {
 233         vector p_pos, p_size;
 234         if (autocvar_hud_panel_itemstime_progressbar_reduced)
 235         {
 236             p_pos = numpos;
 237             p_size = eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y;
 238         }
 239         else
 240         {
 241             p_pos = myPos;
 242             p_size = mySize;
 243         }
 244         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 245     }
 246
 247     if(autocvar_hud_panel_itemstime_text)
 248     {
 249         if(t > 0)
 250             drawstring_aspect(numpos, ftos(t), eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 251         else if(precache_pic("gfx/hud/default/checkmark")) // COMPAT: check if this image exists, as 0.8.1 clients lack it
 252             drawpic_aspect_skin(numpos, "checkmark", eX * (ar - 1) * mySize_y + eY * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 253         else // legacy code, if the image is missing just center the icon
 254             picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
 255     }
 256     if (item_availableTime)
 257         drawpic_aspect_skin_expanding(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
 258     drawpic_aspect_skin(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 259 }
 260
 261 void HUD_ItemsTime()
 262 {
 263     if (!autocvar__hud_configure)
 264     {
 265         if (!(
 266             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
 267         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage))
 268             )) { return; }
 269     }
 270     else
 271     {
 272         ItemsTime_time[ITEM_ArmorMega.m_id] = time + 0;
 273         ItemsTime_time[ITEM_HealthMega.m_id] = time + 8;
 274         ItemsTime_time[ITEM_Strength.m_id] = time + 0;
 275         ItemsTime_time[ITEM_Shield.m_id] = time + 4;
 276     }
 277
 278     int count = 0;
 279     if (autocvar_hud_panel_itemstime_hidespawned == 1)
 280     {
 281         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 282             count += (ItemsTime_time[it.m_id] > time || -ItemsTime_time[it.m_id] > time);
 283         ));
 284         count += (ItemsTime_time[Items_MAX] > time || -ItemsTime_time[Items_MAX] > time);
 285     }
 286     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
 287     {
 288         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 289             count += (ItemsTime_time[it.m_id] > time);
 290         ));
 291         count += (ItemsTime_time[Items_MAX] > time);
 292     }
 293     else
 294     {
 295         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 296             count += (ItemsTime_time[it.m_id] != -1);
 297         ));
 298         count += (ItemsTime_time[Items_MAX] != -1);
 299     }
 300     if (count == 0)
 301         return;
 302
 303     HUD_Panel_UpdateCvars();
 304
 305     vector pos, mySize;
 306     pos = panel_pos;
 307     mySize = panel_size;
 308
 309     if (panel_bg_padding)
 310     {
 311         pos += '1 1 0' * panel_bg_padding;
 312         mySize -= '2 2 0' * panel_bg_padding;
 313     }
 314
 315     float rows, columns;
 316     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
 317     rows = HUD_GetRowCount(count, mySize, ar);
 318     columns = ceil(count/rows);
 319
 320     vector itemstime_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
 321
 322     vector offset = '0 0 0';
 323     float newSize;
 324     if (autocvar_hud_panel_itemstime_dynamicsize)
 325     {
 326         if (autocvar__hud_configure)
 327         if (menu_enabled != 2)
 328             HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 329
 330         // reduce panel to avoid spacing items
 331         if (itemstime_size.x / itemstime_size.y < ar)
 332         {
 333             newSize = rows * itemstime_size.x / ar;
 334             pos.y += (mySize.y - newSize) / 2;
 335             mySize.y = newSize;
 336             itemstime_size.y = mySize.y / rows;
 337         }
 338         else
 339         {
 340             newSize = columns * itemstime_size.y * ar;
 341             pos.x += (mySize.x - newSize) / 2;
 342             mySize.x = newSize;
 343             itemstime_size.x = mySize.x / columns;
 344         }
 345         panel_pos = pos - '1 1 0' * panel_bg_padding;
 346         panel_size = mySize + '2 2 0' * panel_bg_padding;
 347     }
 348     else
 349     {
 350         if (itemstime_size.x/itemstime_size.y > ar)
 351         {
 352             newSize = ar * itemstime_size.y;
 353             offset.x = itemstime_size.x - newSize;
 354             pos.x += offset.x/2;
 355             itemstime_size.x = newSize;
 356         }
 357         else
 358         {
 359             newSize = 1/ar * itemstime_size.x;
 360             offset.y = itemstime_size.y - newSize;
 361             pos.y += offset.y/2;
 362             itemstime_size.y = newSize;
 363         }
 364     }
 365
 366     HUD_Scale_Enable();
 367     HUD_Panel_DrawBg(1);
 368
 369     float row = 0, column = 0;
 370     bool item_available;
 371     int id = 0;
 372     string icon = "";
 373     FOREACH(Items, Item_ItemsTime_Allow(it) && ItemsTime_time[it.m_id] != -1, LAMBDA(
 374         id = it.m_id;
 375         icon = it.m_icon;
 376
 377 LABEL(iteration)
 378         float item_time = ItemsTime_time[id];
 379         if (item_time < -1)
 380         {
 381             item_available = true;
 382             item_time = -item_time;
 383         }
 384         else
 385             item_available = (item_time <= time);
 386
 387         if (ItemsTime_time[id] >= 0)
 388         {
 389             if (time <= ItemsTime_time[id])
 390                 ItemsTime_availableTime[id] = 0;
 391             else if (ItemsTime_availableTime[id] == 0)
 392                 ItemsTime_availableTime[id] = time;
 393         }
 394         else if (ItemsTime_availableTime[id] == 0)
 395             ItemsTime_availableTime[id] = time;
 396
 397         float f = (time - ItemsTime_availableTime[id]) * 2;
 398         f = (f > 1) ? 0 : bound(0, f, 1);
 399
 400         if (autocvar_hud_panel_itemstime_hidespawned == 1)
 401             if (!(ItemsTime_time[id] > time || -ItemsTime_time[id] > time))
 402                 continue;
 403
 404         if (autocvar_hud_panel_itemstime_hidespawned == 2)
 405             if (!(ItemsTime_time[id] > time))
 406                 continue;
 407
 408         DrawItemsTimeItem(pos + eX * column * (itemstime_size.x + offset.x) + eY * row * (itemstime_size.y + offset.y), itemstime_size, ar, icon, item_time, item_available, f);
 409         ++row;
 410         if (row >= rows)
 411         {
 412             row = 0;
 413             column = column + 1;
 414         }
 415         if(id == Items_MAX) // can happen only in the last fake iteration
 416                 break;
 417     ));
 418     // add another fake iteration for superweapons time
 419     if(id < Items_MAX && ItemsTime_time[Items_MAX] != -1)
 420     {
 421                 id = Items_MAX;
 422                 icon = "superweapons";
 423                 goto iteration;
 424     }
 425 }
 426
 427 #endif
 428 #endif