qcsrc/common/mutators/mutator/nix/nix.qc

   1 #ifdef IMPLEMENTATION
   2 int autocvar_g_balance_nix_ammo_cells;
   3 int autocvar_g_balance_nix_ammo_plasma;
   4 int autocvar_g_balance_nix_ammo_fuel;
   5 int autocvar_g_balance_nix_ammo_nails;
   6 int autocvar_g_balance_nix_ammo_rockets;
   7 int autocvar_g_balance_nix_ammo_shells;
   8 int autocvar_g_balance_nix_ammoincr_cells;
   9 int autocvar_g_balance_nix_ammoincr_plasma;
  10 int autocvar_g_balance_nix_ammoincr_fuel;
  11 int autocvar_g_balance_nix_ammoincr_nails;
  12 int autocvar_g_balance_nix_ammoincr_rockets;
  13 int autocvar_g_balance_nix_ammoincr_shells;
  14 float autocvar_g_balance_nix_incrtime;
  15 float autocvar_g_balance_nix_roundtime;
  16 bool autocvar_g_nix_with_healtharmor;
  17 bool autocvar_g_nix_with_blaster;
  18 bool autocvar_g_nix_with_powerups;
  19 int autocvar_g_pickup_cells_max;
  20 int autocvar_g_pickup_plasma_max;
  21 int autocvar_g_pickup_fuel_max;
  22 int autocvar_g_pickup_nails_max;
  23 int autocvar_g_pickup_rockets_max;
  24 int autocvar_g_pickup_shells_max;
  25
  26 float g_nix_with_blaster;
  27 // WEAPONTODO
  28 int nix_weapon;
  29 float nix_nextchange;
  30 float nix_nextweapon;
  31 .float nix_lastchange_id;
  32 .float nix_lastinfotime;
  33 .float nix_nextincr;
  34
  35 bool NIX_CanChooseWeapon(int wpn);
  36
  37 REGISTER_MUTATOR(nix, cvar("g_nix") && !cvar("g_instagib") && !cvar("g_overkill"))
  38 {
  39         MUTATOR_ONADD
  40         {
  41                 g_nix_with_blaster = autocvar_g_nix_with_blaster;
  42
  43                 nix_nextchange = 0;
  44                 nix_nextweapon = 0;
  45
  46                 for (int i = WEP_FIRST; i <= WEP_LAST; ++i)
  47                         if (NIX_CanChooseWeapon(i)) {
  48                                 Weapon w = Weapons_from(i);
  49                                 w.wr_init(w);
  50                         }
  51         }
  52
  53         MUTATOR_ONROLLBACK_OR_REMOVE
  54         {
  55                 // nothing to roll back
  56         }
  57
  58         MUTATOR_ONREMOVE
  59         {
  60                 // as the PlayerSpawn hook will no longer run, NIX is turned off by this!
  61                 entity e;
  62                 FOR_EACH_PLAYER(e) if(e.deadflag == DEAD_NO)
  63                 {
  64                         e.ammo_cells = start_ammo_cells;
  65                         e.ammo_plasma = start_ammo_plasma;
  66                         e.ammo_shells = start_ammo_shells;
  67                         e.ammo_nails = start_ammo_nails;
  68                         e.ammo_rockets = start_ammo_rockets;
  69                         e.ammo_fuel = start_ammo_fuel;
  70                         e.weapons = start_weapons;
  71                         if(!client_hasweapon(e, Weapons_from(e.weapon), true, false))
  72                                 PS(e).m_switchweapon = w_getbestweapon(self);
  73                 }
  74         }
  75
  76         return 0;
  77 }
  78
  79 bool NIX_CanChooseWeapon(int wpn)
  80 {
  81         entity e = Weapons_from(wpn);
  82         if(!e.weapon) // skip dummies
  83                 return false;
  84         if(g_weaponarena)
  85         {
  86                 if(!(g_weaponarena_weapons & e.m_wepset))
  87                         return false;
  88         }
  89         else
  90         {
  91                 if(wpn == WEP_BLASTER.m_id && g_nix_with_blaster)
  92                         return false;
  93                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
  94                         return false;
  95                 if (!(e.spawnflags & WEP_FLAG_NORMAL))
  96                         return false;
  97         }
  98         return true;
  99 }
 100 void NIX_ChooseNextWeapon()
 101 {
 102         float j;
 103         RandomSelection_Init();
 104         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 105                 if(NIX_CanChooseWeapon(j))
 106                         RandomSelection_Add(world, j, string_null, 1, (j != nix_weapon));
 107         nix_nextweapon = RandomSelection_chosen_float;
 108 }
 109
 110 void NIX_GiveCurrentWeapon()
 111 {SELFPARAM();
 112         float dt;
 113
 114         if(!nix_nextweapon)
 115                 NIX_ChooseNextWeapon();
 116
 117         dt = ceil(nix_nextchange - time);
 118
 119         if(dt <= 0)
 120         {
 121                 nix_weapon = nix_nextweapon;
 122                 nix_nextweapon = 0;
 123                 if (!nix_nextchange) // no round played yet?
 124                         nix_nextchange = time; // start the first round now!
 125                 else
 126                         nix_nextchange = time + autocvar_g_balance_nix_roundtime;
 127                 // Weapon w = Weapons_from(nix_weapon);
 128                 // w.wr_init(w); // forget it, too slow
 129         }
 130
 131         // get weapon info
 132         entity e = Weapons_from(nix_weapon);
 133
 134         if(nix_nextchange != self.nix_lastchange_id) // this shall only be called once per round!
 135         {
 136                 self.ammo_shells = self.ammo_nails = self.ammo_rockets = self.ammo_cells = self.ammo_plasma = self.ammo_fuel = 0;
 137
 138                 if(self.items & IT_UNLIMITED_WEAPON_AMMO)
 139                 {
 140                         switch(e.ammo_field)
 141                         {
 142                                 case ammo_shells:  self.ammo_shells  = autocvar_g_pickup_shells_max;  break;
 143                                 case ammo_nails:   self.ammo_nails   = autocvar_g_pickup_nails_max;   break;
 144                                 case ammo_rockets: self.ammo_rockets = autocvar_g_pickup_rockets_max; break;
 145                                 case ammo_cells:   self.ammo_cells   = autocvar_g_pickup_cells_max;   break;
 146                                 case ammo_plasma:  self.ammo_plasma  = autocvar_g_pickup_plasma_max;   break;
 147                                 case ammo_fuel:    self.ammo_fuel    = autocvar_g_pickup_fuel_max;    break;
 148                         }
 149                 }
 150                 else
 151                 {
 152                         switch(e.ammo_field)
 153                         {
 154                                 case ammo_shells:  self.ammo_shells  = autocvar_g_balance_nix_ammo_shells;  break;
 155                                 case ammo_nails:   self.ammo_nails   = autocvar_g_balance_nix_ammo_nails;   break;
 156                                 case ammo_rockets: self.ammo_rockets = autocvar_g_balance_nix_ammo_rockets; break;
 157                                 case ammo_cells:   self.ammo_cells   = autocvar_g_balance_nix_ammo_cells;   break;
 158                                 case ammo_plasma:  self.ammo_plasma  = autocvar_g_balance_nix_ammo_plasma;   break;
 159                                 case ammo_fuel:    self.ammo_fuel    = autocvar_g_balance_nix_ammo_fuel;    break;
 160                         }
 161                 }
 162
 163                 self.nix_nextincr = time + autocvar_g_balance_nix_incrtime;
 164                 if(dt >= 1 && dt <= 5)
 165                         self.nix_lastinfotime = -42;
 166                 else
 167                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_NIX_NEWWEAPON, nix_weapon);
 168
 169                 e.wr_resetplayer(e);
 170
 171                 // all weapons must be fully loaded when we spawn
 172                 if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 173                         self.(weapon_load[nix_weapon]) = e.reloading_ammo;
 174
 175                 // vortex too
 176                 if(WEP_CVAR(vortex, charge))
 177                 {
 178                         if(WEP_CVAR_SEC(vortex, chargepool))
 179                                 self.vortex_chargepool_ammo = 1;
 180                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 181                 }
 182
 183                 // set last change info
 184                 self.nix_lastchange_id = nix_nextchange;
 185         }
 186         if(self.nix_lastinfotime != dt)
 187         {
 188                 self.nix_lastinfotime = dt; // initial value 0 should count as "not seen"
 189                 if(dt >= 1 && dt <= 5)
 190                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_NIX_COUNTDOWN, nix_nextweapon, dt);
 191         }
 192
 193         if(!(self.items & IT_UNLIMITED_WEAPON_AMMO) && time > self.nix_nextincr)
 194         {
 195                 switch(e.ammo_field)
 196                 {
 197                         case ammo_shells:  self.ammo_shells  += autocvar_g_balance_nix_ammoincr_shells;  break;
 198                         case ammo_nails:   self.ammo_nails   += autocvar_g_balance_nix_ammoincr_nails;   break;
 199                         case ammo_rockets: self.ammo_rockets += autocvar_g_balance_nix_ammoincr_rockets; break;
 200                         case ammo_cells:   self.ammo_cells   += autocvar_g_balance_nix_ammoincr_cells;   break;
 201                         case ammo_plasma:  self.ammo_plasma  += autocvar_g_balance_nix_ammoincr_plasma;   break;
 202                         case ammo_fuel:    self.ammo_fuel    += autocvar_g_balance_nix_ammoincr_fuel;    break;
 203                 }
 204
 205                 self.nix_nextincr = time + autocvar_g_balance_nix_incrtime;
 206         }
 207
 208         self.weapons = '0 0 0';
 209         if(g_nix_with_blaster)
 210                 self.weapons |= WEPSET(BLASTER);
 211         self.weapons |= e.m_wepset;
 212
 213     Weapon w = Weapons_from(nix_weapon);
 214         if(PS(self).m_switchweapon != w)
 215                 if(!client_hasweapon(self, PS(self).m_switchweapon, true, false))
 216                 {
 217                         if(client_hasweapon(self, w, true, false))
 218                                 W_SwitchWeapon(w);
 219                 }
 220 }
 221
 222 MUTATOR_HOOKFUNCTION(nix, ForbidThrowCurrentWeapon)
 223 {
 224         return 1; // no throwing in NIX
 225 }
 226
 227 MUTATOR_HOOKFUNCTION(nix, BuildMutatorsString)
 228 {
 229         ret_string = strcat(ret_string, ":NIX");
 230         return 0;
 231 }
 232
 233 MUTATOR_HOOKFUNCTION(nix, BuildMutatorsPrettyString)
 234 {
 235         ret_string = strcat(ret_string, ", NIX");
 236         return 0;
 237 }
 238
 239 MUTATOR_HOOKFUNCTION(nix, FilterItem)
 240 {SELFPARAM();
 241         switch (self.items)
 242         {
 243                 case ITEM_HealthSmall.m_itemid:
 244                 case ITEM_HealthMedium.m_itemid:
 245                 case ITEM_HealthLarge.m_itemid:
 246                 case ITEM_HealthMega.m_itemid:
 247                 case ITEM_ArmorSmall.m_itemid:
 248                 case ITEM_ArmorMedium.m_itemid:
 249                 case ITEM_ArmorLarge.m_itemid:
 250                 case ITEM_ArmorMega.m_itemid:
 251                         if (autocvar_g_nix_with_healtharmor)
 252                                 return 0;
 253                         break;
 254                 case ITEM_Strength.m_itemid:
 255                 case ITEM_Shield.m_itemid:
 256                         if (autocvar_g_nix_with_powerups)
 257                                 return 0;
 258                         break;
 259         }
 260
 261         return 1; // delete all other items
 262 }
 263
 264 MUTATOR_HOOKFUNCTION(nix, OnEntityPreSpawn)
 265 {SELFPARAM();
 266         if(self.classname == "target_items") // items triggers cannot work in nix (as they change weapons/ammo)
 267                 return 1;
 268         return 0;
 269 }
 270
 271 MUTATOR_HOOKFUNCTION(nix, PlayerPreThink)
 272 {SELFPARAM();
 273         if(!intermission_running)
 274         if(self.deadflag == DEAD_NO)
 275         if(IS_PLAYER(self))
 276                 NIX_GiveCurrentWeapon();
 277         return 0;
 278 }
 279
 280 MUTATOR_HOOKFUNCTION(nix, PlayerSpawn)
 281 {SELFPARAM();
 282         self.nix_lastchange_id = -1;
 283         NIX_GiveCurrentWeapon(); // overrides the weapons you got when spawning
 284         self.items |= IT_UNLIMITED_SUPERWEAPONS;
 285         return 0;
 286 }
 287
 288 MUTATOR_HOOKFUNCTION(nix, SetModname, CBC_ORDER_LAST)
 289 {
 290         modname = "NIX";
 291         return 0;
 292 }
 293 #endif