qcsrc/common/mutators/mutator/overkill/overkill.qc

   1 #ifdef IMPLEMENTATION
   2 bool autocvar_g_overkill_powerups_replace;
   3 float autocvar_g_overkill_superguns_respawn_time;
   4 bool autocvar_g_overkill_100h_anyway;
   5 bool autocvar_g_overkill_100a_anyway;
   6 bool autocvar_g_overkill_ammo_charge;
   7 float autocvar_g_overkill_ammo_charge_notice;
   8 float autocvar_g_overkill_ammo_charge_limit;
   9
  10 .vector ok_deathloc;
  11 .float ok_spawnsys_timer;
  12 .float ok_lastwep;
  13 .float ok_item;
  14
  15 .float ok_notice_time;
  16 .float ammo_charge[Weapons_MAX];
  17 .float ok_use_ammocharge = _STAT(OK_AMMO_CHARGE);
  18 .float ok_ammo_charge = _STAT(OK_AMMO_CHARGEPOOL);
  19
  20 .float ok_pauseregen_finished;
  21
  22 void(entity ent, float wep) ok_DecreaseCharge;
  23
  24 void ok_Initialize();
  25
  26 REGISTER_MUTATOR(ok, cvar("g_overkill") && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  27 {
  28         MUTATOR_ONADD
  29         {
  30                 ok_Initialize();
  31         }
  32
  33         MUTATOR_ONREMOVE
  34         {
  35                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  36                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  37         }
  38
  39         return false;
  40 }
  41
  42 MUTATOR_HOOKFUNCTION(ok, W_DecreaseAmmo)
  43 {
  44         entity actor = MUTATOR_ARGV(0, entity);
  45         if (actor.ok_use_ammocharge)
  46         {
  47                 ok_DecreaseCharge(actor, actor.weapon);
  48                 return true;
  49         }
  50 }
  51
  52 MUTATOR_HOOKFUNCTION(ok, W_Reload)
  53 {
  54         entity actor = MUTATOR_ARGV(0, entity);
  55         return actor.ok_use_ammocharge;
  56 }
  57
  58 void W_Blaster_Attack(entity, float, float, float, float, float, float, float, float, float, float);
  59 spawnfunc(weapon_hmg);
  60 spawnfunc(weapon_rpc);
  61
  62 void ok_DecreaseCharge(entity ent, int wep)
  63 {
  64         if(!ent.ok_use_ammocharge) return;
  65
  66         entity wepent = Weapons_from(wep);
  67
  68         if(wepent.weapon == 0)
  69                 return; // dummy
  70
  71         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  72 }
  73
  74 void ok_IncreaseCharge(entity ent, int wep)
  75 {
  76         entity wepent = Weapons_from(wep);
  77
  78         if(wepent.weapon == 0)
  79                 return; // dummy
  80
  81         if(ent.ok_use_ammocharge)
  82         if(!ent.BUTTON_ATCK) // not while attacking?
  83                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  84 }
  85
  86 float ok_CheckWeaponCharge(entity ent, int wep)
  87 {
  88         if(!ent.ok_use_ammocharge) return true;
  89
  90         entity wepent = Weapons_from(wep);
  91
  92         if(wepent.weapon == 0)
  93                 return 0; // dummy
  94
  95         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  96 }
  97
  98 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_Calculate, CBC_ORDER_LAST)
  99 {
 100         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
 101         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
 102         {
 103                 frag_damage = 0;
 104
 105                 if(frag_attacker != frag_target)
 106                 if(frag_target.health > 0)
 107                 if(frag_target.frozen == 0)
 108                 if(frag_target.deadflag == DEAD_NO)
 109                 {
 110                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
 111                         frag_force = '0 0 0';
 112                 }
 113         }
 114
 115         return false;
 116 }
 117
 118 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_SplitHealthArmor)
 119 {SELFPARAM();
 120         if(damage_take)
 121                 self.ok_pauseregen_finished = max(self.ok_pauseregen_finished, time + 2);
 122         return false;
 123 }
 124
 125 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
 126 {
 127         SELFPARAM();
 128         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
 129
 130         if(IS_MONSTER(this))
 131         {
 132                 remove(other); // remove default item
 133                 other = NULL;
 134         }
 135
 136         entity e = new(droppedweapon); // hax
 137         e.ok_item = true;
 138         e.noalign = true;
 139         e.pickup_anyway = true;
 140         e.spawnfunc_checked = true;
 141         spawnfunc_item_armor_small(e);
 142         e.movetype = MOVETYPE_TOSS;
 143         e.gravity = 1;
 144         e.reset = SUB_Remove;
 145         setorigin(e, frag_target.origin + '0 0 32');
 146         e.velocity = '0 0 200' + normalize(targ.origin - self.origin) * 500;
 147         SUB_SetFade(e, time + 5, 1);
 148
 149         this.ok_lastwep = PS(this).m_switchweapon.m_id;
 150
 151         return false;
 152 }
 153 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem) { ok_PlayerDies(); }
 154
 155 MUTATOR_HOOKFUNCTION(ok, PlayerRegen)
 156 {SELFPARAM();
 157         // overkill's values are different, so use custom regen
 158         if(!self.frozen)
 159         {
 160                 self.armorvalue = CalcRotRegen(self.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 1 * frametime * (time > self.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > self.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 161                 self.health = CalcRotRegen(self.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > self.ok_pauseregen_finished), 200, 0, autocvar_g_balance_health_rotlinear, 1 * frametime * (time > self.pauserothealth_finished), autocvar_g_balance_health_limit);
 162
 163                 float minf, maxf, limitf;
 164
 165                 maxf = autocvar_g_balance_fuel_rotstable;
 166                 minf = autocvar_g_balance_fuel_regenstable;
 167                 limitf = autocvar_g_balance_fuel_limit;
 168
 169                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
 170         }
 171         return true; // return true anyway, as frozen uses no regen
 172 }
 173
 174 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 175 {
 176         return true;
 177 }
 178
 179 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 180 {SELFPARAM();
 181         if(intermission_running || gameover)
 182                 return false;
 183
 184         if(self.deadflag != DEAD_NO || !IS_PLAYER(self) || self.frozen)
 185                 return false;
 186
 187         if(self.ok_lastwep)
 188         {
 189                 PS(self).m_switchweapon = Weapons_from(self.ok_lastwep);
 190                 self.ok_lastwep = 0;
 191         }
 192
 193         ok_IncreaseCharge(self, self.weapon);
 194
 195         if(self.BUTTON_ATCK2)
 196         if(!forbidWeaponUse(self) || self.weapon_blocked) // allow if weapon is blocked
 197         if(time >= self.jump_interval)
 198         {
 199                 self.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor();
 200                 makevectors(self.v_angle);
 201
 202                 int oldwep = self.weapon;
 203                 self.weapon = WEP_BLASTER.m_id;
 204                 W_Blaster_Attack(
 205                         self,
 206                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 207                         WEP_CVAR_SEC(vaporizer, shotangle),
 208                         WEP_CVAR_SEC(vaporizer, damage),
 209                         WEP_CVAR_SEC(vaporizer, edgedamage),
 210                         WEP_CVAR_SEC(vaporizer, radius),
 211                         WEP_CVAR_SEC(vaporizer, force),
 212                         WEP_CVAR_SEC(vaporizer, speed),
 213                         WEP_CVAR_SEC(vaporizer, spread),
 214                         WEP_CVAR_SEC(vaporizer, delay),
 215                         WEP_CVAR_SEC(vaporizer, lifetime)
 216                 );
 217                 self.weapon = oldwep;
 218         }
 219
 220         self.weapon_blocked = false;
 221
 222         self.ok_ammo_charge = self.ammo_charge[self.weapon];
 223
 224         if(self.ok_use_ammocharge)
 225         if(!ok_CheckWeaponCharge(self, self.weapon))
 226         {
 227                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && self.BUTTON_ATCK && IS_REAL_CLIENT(self) && self.weapon == PS(self).m_switchweapon.m_id)
 228                 {
 229                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 230                         self.ok_notice_time = time + 2;
 231                         play2(self, SND(DRYFIRE));
 232                 }
 233                 Weapon wpn = Weapons_from(self.weapon);
 234                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 235                 if(self.(weaponentity).state != WS_CLEAR)
 236                         w_ready(wpn, self, weaponentity, (self.BUTTON_ATCK ? 1 : 0) | (self.BUTTON_ATCK2 ? 2 : 0));
 237
 238                 self.weapon_blocked = true;
 239         }
 240
 241         self.BUTTON_ATCK2 = 0;
 242
 243         return false;
 244 }
 245
 246 MUTATOR_HOOKFUNCTION(ok, PlayerSpawn)
 247 {SELFPARAM();
 248         if(autocvar_g_overkill_ammo_charge)
 249         {
 250                 for(int i = WEP_FIRST; i <= WEP_LAST; ++i)
 251                         self.ammo_charge[i] = autocvar_g_overkill_ammo_charge_limit;
 252
 253                 self.ok_use_ammocharge = 1;
 254                 self.ok_notice_time = time;
 255         }
 256         else
 257                 self.ok_use_ammocharge = 0;
 258
 259         self.ok_pauseregen_finished = time + 2;
 260
 261         return false;
 262 }
 263
 264 void self_spawnfunc_weapon_hmg() { SELFPARAM(); spawnfunc_weapon_hmg(this); }
 265 void self_spawnfunc_weapon_rpc() { SELFPARAM(); spawnfunc_weapon_rpc(this); }
 266
 267 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 268 {SELFPARAM();
 269         if(autocvar_g_powerups)
 270         if(autocvar_g_overkill_powerups_replace)
 271         {
 272                 if(self.classname == "item_strength")
 273                 {
 274                         entity wep = new(weapon_hmg);
 275                         setorigin(wep, self.origin);
 276                         setmodel(wep, MDL_OK_HMG);
 277                         wep.ok_item = true;
 278                         wep.noalign = self.noalign;
 279                         wep.cnt = self.cnt;
 280                         wep.team = self.team;
 281                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 282                         wep.pickup_anyway = true;
 283                         wep.spawnfunc_checked = true;
 284                         wep.think = self_spawnfunc_weapon_hmg;
 285                         wep.nextthink = time + 0.1;
 286                         return true;
 287                 }
 288
 289                 if(self.classname == "item_invincible")
 290                 {
 291                         entity wep = new(weapon_rpc);
 292                         setorigin(wep, self.origin);
 293                         setmodel(wep, MDL_OK_RPC);
 294                         wep.ok_item = true;
 295                         wep.noalign = self.noalign;
 296                         wep.cnt = self.cnt;
 297                         wep.team = self.team;
 298                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 299                         wep.pickup_anyway = true;
 300                         wep.spawnfunc_checked = true;
 301                         wep.think = self_spawnfunc_weapon_rpc;
 302                         wep.nextthink = time + 0.1;
 303                         return true;
 304                 }
 305         }
 306
 307         return false;
 308 }
 309
 310 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 311 {SELFPARAM();
 312         if(self.ok_item)
 313                 return false;
 314
 315         switch(self.items)
 316         {
 317                 case ITEM_HealthMega.m_itemid: return !(autocvar_g_overkill_100h_anyway);
 318                 case ITEM_ArmorMega.m_itemid: return !(autocvar_g_overkill_100a_anyway);
 319         }
 320
 321         return true;
 322 }
 323
 324 MUTATOR_HOOKFUNCTION(ok, SpectateCopy)
 325 {SELFPARAM();
 326         self.ammo_charge[self.weapon] = other.ammo_charge[other.weapon];
 327         self.ok_use_ammocharge = other.ok_use_ammocharge;
 328
 329         return false;
 330 }
 331
 332 MUTATOR_HOOKFUNCTION(ok, SetStartItems)
 333 {
 334         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 335
 336         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 337         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 338
 339         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 340         start_weapons = warmup_start_weapons = ok_start_items;
 341
 342         return false;
 343 }
 344
 345 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 346 {
 347         ret_string = strcat(ret_string, ":OK");
 348         return false;
 349 }
 350
 351 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 352 {
 353         ret_string = strcat(ret_string, ", Overkill");
 354         return false;
 355 }
 356
 357 MUTATOR_HOOKFUNCTION(ok, SetModname)
 358 {
 359         modname = "Overkill";
 360         return true;
 361 }
 362
 363 void ok_SetCvars()
 364 {
 365         // hack to force overkill playermodels
 366         cvar_settemp("sv_defaultcharacter", "1");
 367         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 368         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 369         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 370 }
 371
 372 void ok_Initialize()
 373 {
 374         ok_SetCvars();
 375
 376         precache_all_playermodels("models/ok_player/*.dpm");
 377
 378         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 379         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 380
 381         WEP_SHOTGUN.mdl = "ok_shotgun";
 382         WEP_MACHINEGUN.mdl = "ok_mg";
 383         WEP_VORTEX.mdl = "ok_sniper";
 384 }
 385 #endif