qcsrc/common/mutators/mutator/overkill/sv_overkill.qc

   1 #include "sv_overkill.qh"
   2
   3 #include "hmg.qh"
   4 #include "rpc.qh"
   5
   6 bool autocvar_g_overkill_powerups_replace;
   7 float autocvar_g_overkill_superguns_respawn_time;
   8 bool autocvar_g_overkill_100h_anyway;
   9 bool autocvar_g_overkill_100a_anyway;
  10 bool autocvar_g_overkill_ammo_charge;
  11 float autocvar_g_overkill_ammo_charge_notice;
  12 float autocvar_g_overkill_ammo_charge_limit;
  13
  14 .vector ok_deathloc;
  15 .float ok_spawnsys_timer;
  16 .float ok_lastwep;
  17 .float ok_item;
  18
  19 .float ok_notice_time;
  20 .float ammo_charge[Weapons_MAX];
  21 .float ok_use_ammocharge = _STAT(OK_AMMO_CHARGE);
  22 .float ok_ammo_charge = _STAT(OK_AMMO_CHARGEPOOL);
  23
  24 .float pauseregen_finished;
  25
  26 void(entity ent, float wep) ok_DecreaseCharge;
  27
  28 void ok_Initialize();
  29
  30 REGISTER_MUTATOR(ok, cvar("g_overkill") && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  31 {
  32         MUTATOR_ONADD
  33         {
  34                 ok_Initialize();
  35         }
  36
  37         MUTATOR_ONREMOVE
  38         {
  39                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  40                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  41         }
  42 }
  43
  44 MUTATOR_HOOKFUNCTION(ok, W_DecreaseAmmo)
  45 {
  46         entity actor = M_ARGV(0, entity);
  47         if (actor.ok_use_ammocharge)
  48         {
  49                 ok_DecreaseCharge(actor, PS(actor).m_weapon.m_id);
  50                 return true;
  51         }
  52 }
  53
  54 MUTATOR_HOOKFUNCTION(ok, W_Reload)
  55 {
  56         entity actor = M_ARGV(0, entity);
  57         return actor.ok_use_ammocharge;
  58 }
  59
  60 void W_Blaster_Attack(entity, .entity, float, float, float, float, float, float, float, float, float, float);
  61 spawnfunc(weapon_hmg);
  62 spawnfunc(weapon_rpc);
  63
  64 void ok_DecreaseCharge(entity ent, int wep)
  65 {
  66         if(!ent.ok_use_ammocharge) return;
  67
  68         entity wepent = Weapons_from(wep);
  69
  70         if (wepent == WEP_Null) return;  // dummy
  71
  72         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  73 }
  74
  75 void ok_IncreaseCharge(entity ent, int wep)
  76 {
  77         entity wepent = Weapons_from(wep);
  78
  79         if (wepent == WEP_Null) return;  // dummy
  80
  81         if(ent.ok_use_ammocharge)
  82         if(!PHYS_INPUT_BUTTON_ATCK(ent)) // not while attacking?
  83                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  84 }
  85
  86 float ok_CheckWeaponCharge(entity ent, int wep)
  87 {
  88         if(!ent.ok_use_ammocharge) return true;
  89
  90         entity wepent = Weapons_from(wep);
  91
  92         if(wepent == WEP_Null) return false;  // dummy
  93
  94         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  95 }
  96
  97 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_Calculate, CBC_ORDER_LAST)
  98 {
  99         entity frag_attacker = M_ARGV(1, entity);
 100         entity frag_target = M_ARGV(2, entity);
 101         float frag_deathtype = M_ARGV(3, float);
 102
 103         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
 104         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
 105         {
 106                 if(frag_attacker != frag_target)
 107                 if(frag_target.health > 0)
 108                 if(STAT(FROZEN, frag_target) == 0)
 109                 if(!IS_DEAD(frag_target))
 110                 {
 111                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
 112                         M_ARGV(6, vector) = '0 0 0';
 113                 }
 114
 115                 M_ARGV(4, float) = 0;
 116         }
 117 }
 118
 119 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_SplitHealthArmor)
 120 {
 121         entity frag_target = M_ARGV(2, entity);
 122         float damage_take = M_ARGV(4, float);
 123
 124         if(damage_take)
 125                 frag_target.pauseregen_finished = max(frag_target.pauseregen_finished, time + 2);
 126 }
 127
 128 void ok_DropItem(entity this, entity targ)
 129 {
 130         entity e = new(droppedweapon); // hax
 131         e.ok_item = true;
 132         e.noalign = true;
 133         e.pickup_anyway = true;
 134         e.spawnfunc_checked = true;
 135         spawnfunc_item_armor_small(e);
 136         if (!wasfreed(e)) { // might have been blocked by a mutator
 137         set_movetype(e, MOVETYPE_TOSS);
 138         e.gravity = 1;
 139         e.reset = SUB_Remove;
 140         setorigin(e, this.origin + '0 0 32');
 141         e.velocity = '0 0 200' + normalize(targ.origin - this.origin) * 500;
 142         SUB_SetFade(e, time + 5, 1);
 143         }
 144 }
 145
 146 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
 147 {
 148         entity frag_attacker = M_ARGV(1, entity);
 149         entity frag_target = M_ARGV(2, entity);
 150
 151         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
 152
 153         ok_DropItem(frag_target, targ);
 154
 155         frag_target.ok_lastwep = PS(frag_target).m_switchweapon.m_id;
 156 }
 157
 158 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem)
 159 {
 160         entity mon = M_ARGV(0, entity);
 161         entity olditem = M_ARGV(1, entity);
 162         entity frag_attacker = M_ARGV(2, entity);
 163
 164         delete(olditem);
 165
 166         M_ARGV(1, entity) = NULL;
 167
 168         ok_DropItem(mon, frag_attacker);
 169 }
 170
 171 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 172 {
 173         return true;
 174 }
 175
 176 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 177 {
 178         if(intermission_running || gameover)
 179                 return;
 180
 181         entity player = M_ARGV(0, entity);
 182
 183         if(IS_DEAD(player) || !IS_PLAYER(player) || STAT(FROZEN, player))
 184                 return;
 185
 186         if(player.ok_lastwep)
 187         {
 188                 Weapon newwep = Weapons_from(player.ok_lastwep);
 189                 if(player.ok_lastwep == WEP_HMG.m_id)
 190                         newwep = WEP_MACHINEGUN;
 191                 if(player.ok_lastwep == WEP_RPC.m_id)
 192                         newwep = WEP_VORTEX;
 193                 PS(player).m_switchweapon = newwep;
 194                 player.ok_lastwep = 0;
 195         }
 196
 197         ok_IncreaseCharge(player, PS(player).m_weapon.m_id);
 198
 199         if(PHYS_INPUT_BUTTON_ATCK2(player))
 200         if(!forbidWeaponUse(player) || player.weapon_blocked) // allow if weapon is blocked
 201         if(time >= player.jump_interval)
 202         {
 203                 player.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor(player);
 204                 makevectors(player.v_angle);
 205
 206                 Weapon oldwep = PS(player).m_weapon;
 207                 PS(player).m_weapon = WEP_BLASTER;
 208                 W_Blaster_Attack(
 209                         player,
 210                         weaponentities[0], // TODO: unhardcode
 211                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 212                         WEP_CVAR_SEC(vaporizer, shotangle),
 213                         WEP_CVAR_SEC(vaporizer, damage),
 214                         WEP_CVAR_SEC(vaporizer, edgedamage),
 215                         WEP_CVAR_SEC(vaporizer, radius),
 216                         WEP_CVAR_SEC(vaporizer, force),
 217                         WEP_CVAR_SEC(vaporizer, speed),
 218                         WEP_CVAR_SEC(vaporizer, spread),
 219                         WEP_CVAR_SEC(vaporizer, delay),
 220                         WEP_CVAR_SEC(vaporizer, lifetime)
 221                 );
 222                 PS(player).m_weapon = oldwep;
 223         }
 224
 225         player.weapon_blocked = false;
 226
 227         player.ok_ammo_charge = player.ammo_charge[PS(player).m_weapon.m_id];
 228
 229         if(player.ok_use_ammocharge)
 230         if(!ok_CheckWeaponCharge(player, PS(player).m_weapon.m_id))
 231         {
 232                 if(autocvar_g_overkill_ammo_charge_notice && time > player.ok_notice_time && PHYS_INPUT_BUTTON_ATCK(player) && IS_REAL_CLIENT(player) && PS(player).m_weapon == PS(player).m_switchweapon)
 233                 {
 234                         //Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 235                         player.ok_notice_time = time + 2;
 236                         play2(player, SND(DRYFIRE));
 237                 }
 238                 Weapon wpn = PS(player).m_weapon;
 239                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 240                 if(player.(weaponentity).state != WS_CLEAR)
 241                         w_ready(wpn, player, weaponentity, PHYS_INPUT_BUTTON_ATCK(player) | (PHYS_INPUT_BUTTON_ATCK2(player) << 1));
 242
 243                 player.weapon_blocked = true;
 244         }
 245
 246         PHYS_INPUT_BUTTON_ATCK2(player) = false;
 247 }
 248
 249 MUTATOR_HOOKFUNCTION(ok, PlayerSpawn)
 250 {
 251         entity player = M_ARGV(0, entity);
 252
 253         if(autocvar_g_overkill_ammo_charge)
 254         {
 255                 FOREACH(Weapons, it != WEP_Null, LAMBDA(player.ammo_charge[it.m_id] = autocvar_g_overkill_ammo_charge_limit));
 256
 257                 player.ok_use_ammocharge = 1;
 258                 player.ok_notice_time = time;
 259         }
 260         else
 261                 player.ok_use_ammocharge = 0;
 262
 263         // if player changed their weapon while dead, don't switch to their death weapon
 264         if(player.impulse)
 265                 player.ok_lastwep = 0;
 266
 267         player.pauseregen_finished = time + 2;
 268 }
 269
 270 void self_spawnfunc_weapon_hmg(entity this) { spawnfunc_weapon_hmg(this); }
 271 void self_spawnfunc_weapon_rpc(entity this) { spawnfunc_weapon_rpc(this); }
 272
 273 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 274 {
 275         entity ent = M_ARGV(0, entity);
 276
 277         if(autocvar_g_powerups)
 278         if(autocvar_g_overkill_powerups_replace)
 279         {
 280                 if(ent.classname == "item_strength")
 281                 {
 282                         entity wep = new(weapon_hmg);
 283                         setorigin(wep, ent.origin);
 284                         setmodel(wep, MDL_OK_HMG);
 285                         wep.ok_item = true;
 286                         wep.noalign = ent.noalign;
 287                         wep.cnt = ent.cnt;
 288                         wep.team = ent.team;
 289                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 290                         wep.pickup_anyway = true;
 291                         wep.spawnfunc_checked = true;
 292                         setthink(wep, self_spawnfunc_weapon_hmg);
 293                         wep.nextthink = time + 0.1;
 294                         return true;
 295                 }
 296
 297                 if(ent.classname == "item_invincible")
 298                 {
 299                         entity wep = new(weapon_rpc);
 300                         setorigin(wep, ent.origin);
 301                         setmodel(wep, MDL_OK_RPC);
 302                         wep.ok_item = true;
 303                         wep.noalign = ent.noalign;
 304                         wep.cnt = ent.cnt;
 305                         wep.team = ent.team;
 306                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 307                         wep.pickup_anyway = true;
 308                         wep.spawnfunc_checked = true;
 309                         setthink(wep, self_spawnfunc_weapon_rpc);
 310                         wep.nextthink = time + 0.1;
 311                         return true;
 312                 }
 313         }
 314 }
 315
 316 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 317 {
 318         entity item = M_ARGV(0, entity);
 319
 320         if(item.ok_item)
 321                 return;
 322
 323         switch(item.items)
 324         {
 325                 case ITEM_HealthMega.m_itemid: return !(autocvar_g_overkill_100h_anyway);
 326                 case ITEM_ArmorMega.m_itemid: return !(autocvar_g_overkill_100a_anyway);
 327         }
 328
 329         return true;
 330 }
 331
 332 MUTATOR_HOOKFUNCTION(ok, SpectateCopy)
 333 {
 334         entity spectatee = M_ARGV(0, entity);
 335         entity client = M_ARGV(1, entity);
 336
 337         client.ammo_charge[PS(client).m_weapon.m_id] = spectatee.ammo_charge[PS(spectatee).m_weapon.m_id];
 338         client.ok_use_ammocharge = spectatee.ok_use_ammocharge;
 339 }
 340
 341 MUTATOR_HOOKFUNCTION(ok, SetStartItems, CBC_ORDER_LAST)
 342 {
 343         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 344
 345         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 346         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 347
 348         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 349         start_weapons = warmup_start_weapons = ok_start_items;
 350 }
 351
 352 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 353 {
 354         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":OK");
 355 }
 356
 357 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 358 {
 359         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Overkill");
 360 }
 361
 362 MUTATOR_HOOKFUNCTION(ok, SetModname)
 363 {
 364         M_ARGV(0, string) = "Overkill";
 365         return true;
 366 }
 367
 368 void ok_SetCvars()
 369 {
 370         // hack to force overkill playermodels
 371         cvar_settemp("sv_defaultcharacter", "1");
 372         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 373         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 374         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 375 }
 376
 377 void ok_Initialize()
 378 {
 379         ok_SetCvars();
 380
 381         precache_all_playermodels("models/ok_player/*.dpm");
 382
 383         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 384         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 385
 386         WEP_SHOTGUN.mdl = "ok_shotgun";
 387         WEP_MACHINEGUN.mdl = "ok_mg";
 388         WEP_VORTEX.mdl = "ok_sniper";
 389 }