qcsrc/common/mutators/mutator/overkill/sv_overkill.qc

   1 #include "sv_overkill.qh"
   2
   3 #include "hmg.qh"
   4 #include "rpc.qh"
   5
   6 string autocvar_g_overkill;
   7
   8 bool autocvar_g_overkill_powerups_replace;
   9
  10 bool autocvar_g_overkill_itemwaypoints = true;
  11
  12 .Weapon ok_lastwep[MAX_WEAPONSLOTS];
  13
  14 REGISTER_MUTATOR(ok, expr_evaluate(autocvar_g_overkill) && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  15 {
  16         MUTATOR_ONADD
  17         {
  18                 precache_all_playermodels("models/ok_player/*.dpm");
  19
  20                 WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
  21                 WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
  22
  23                 WEP_SHOTGUN.mdl = "ok_shotgun";
  24                 WEP_MACHINEGUN.mdl = "ok_mg";
  25                 WEP_VORTEX.mdl = "ok_sniper";
  26         }
  27
  28         MUTATOR_ONREMOVE
  29         {
  30                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  31                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  32         }
  33 }
  34
  35 void W_Blaster_Attack(entity, .entity, float, float, float, float, float, float, float, float, float, float);
  36
  37 MUTATOR_HOOKFUNCTION(ok, Damage_Calculate, CBC_ORDER_LAST)
  38 {
  39         entity frag_attacker = M_ARGV(1, entity);
  40         entity frag_target = M_ARGV(2, entity);
  41         float frag_deathtype = M_ARGV(3, float);
  42
  43         if(IS_PLAYER(frag_attacker) && (IS_PLAYER(frag_target) || IS_VEHICLE(frag_target) || IS_TURRET(frag_target)))
  44         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
  45         {
  46                 if(frag_attacker != frag_target)
  47                 if(!STAT(FROZEN, frag_target))
  48                 if(!IS_DEAD(frag_target))
  49                 {
  50                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  51                         M_ARGV(6, vector) = '0 0 0'; // force
  52                 }
  53
  54                 M_ARGV(4, float) = 0; // damage
  55         }
  56 }
  57
  58 void ok_DropItem(entity this, entity targ)
  59 {
  60         entity e = spawn();
  61         e.ok_item = true;
  62         Item_InitializeLoot(e, "item_armor_small", this.origin + '0 0 32',
  63                 '0 0 200' + normalize(targ.origin - this.origin) * 500, 5);
  64 }
  65
  66 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
  67 {
  68         entity frag_attacker = M_ARGV(1, entity);
  69         entity frag_target = M_ARGV(2, entity);
  70
  71         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
  72
  73         ok_DropItem(frag_target, targ);
  74
  75         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  76         {
  77                 .entity weaponentity = weaponentities[slot];
  78
  79                 frag_target.ok_lastwep[slot] = frag_target.(weaponentity).m_switchweapon;
  80         }
  81 }
  82
  83 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem)
  84 {
  85         entity mon = M_ARGV(0, entity);
  86         entity olditem = M_ARGV(1, entity);
  87         entity frag_attacker = M_ARGV(2, entity);
  88
  89         delete(olditem);
  90
  91         M_ARGV(1, entity) = NULL;
  92
  93         ok_DropItem(mon, frag_attacker);
  94 }
  95
  96 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
  97 {
  98         return true;
  99 }
 100
 101 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 102 {
 103         if(game_stopped)
 104                 return;
 105
 106         entity player = M_ARGV(0, entity);
 107
 108         if(IS_DEAD(player) || !IS_PLAYER(player) || STAT(FROZEN, player))
 109                 return;
 110
 111         if(PHYS_INPUT_BUTTON_ATCK2(player) && time >= player.jump_interval)
 112         if( !forbidWeaponUse(player)
 113                 || (round_handler_IsActive() && !round_handler_IsRoundStarted()) )
 114         {
 115                 player.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor(player);
 116                 makevectors(player.v_angle);
 117
 118                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 119                 {
 120                         .entity weaponentity = weaponentities[slot];
 121
 122                         if(player.(weaponentity).m_weapon == WEP_Null && slot != 0)
 123                                 continue;
 124
 125                         Weapon oldwep = player.(weaponentity).m_weapon;
 126                         player.(weaponentity).m_weapon = WEP_BLASTER;
 127                         W_Blaster_Attack(
 128                                 player,
 129                                 weaponentity,
 130                                 WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 131                                 WEP_CVAR_SEC(vaporizer, shotangle),
 132                                 WEP_CVAR_SEC(vaporizer, damage),
 133                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 134                                 WEP_CVAR_SEC(vaporizer, radius),
 135                                 WEP_CVAR_SEC(vaporizer, force),
 136                                 WEP_CVAR_SEC(vaporizer, speed),
 137                                 WEP_CVAR_SEC(vaporizer, spread),
 138                                 WEP_CVAR_SEC(vaporizer, delay),
 139                                 WEP_CVAR_SEC(vaporizer, lifetime)
 140                         );
 141                         player.(weaponentity).m_weapon = oldwep;
 142                 }
 143         }
 144
 145         PHYS_INPUT_BUTTON_ATCK2(player) = false;
 146 }
 147
 148 MUTATOR_HOOKFUNCTION(ok, PlayerWeaponSelect)
 149 {
 150         entity player = M_ARGV(0, entity);
 151
 152         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 153         {
 154                 .entity weaponentity = weaponentities[slot];
 155                 entity thiswep = player.(weaponentity);
 156
 157                 if(player.ok_lastwep[slot] && player.ok_lastwep[slot] != WEP_Null)
 158                 {
 159                         Weapon newwep = player.ok_lastwep[slot];
 160                         if(player.ok_lastwep[slot] == WEP_HMG)
 161                                 newwep = WEP_MACHINEGUN;
 162                         if(player.ok_lastwep[slot] == WEP_RPC)
 163                                 newwep = WEP_VORTEX;
 164                         thiswep.m_switchweapon = newwep;
 165                         player.ok_lastwep[slot] = WEP_Null;
 166                 }
 167         }
 168 }
 169
 170 void self_spawnfunc_weapon_hmg(entity this) { spawnfunc_weapon_hmg(this); }
 171 void self_spawnfunc_weapon_rpc(entity this) { spawnfunc_weapon_rpc(this); }
 172
 173 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 174 {
 175         entity ent = M_ARGV(0, entity);
 176
 177         if(autocvar_g_powerups)
 178         if(autocvar_g_overkill_powerups_replace)
 179         {
 180                 if(ent.classname == "item_strength")
 181                 {
 182                         entity wep = new(weapon_hmg);
 183                         setorigin(wep, ent.origin);
 184                         setmodel(wep, MDL_OK_HMG);
 185                         wep.ok_item = true;
 186                         wep.noalign = ent.noalign;
 187                         wep.cnt = ent.cnt;
 188                         wep.team = ent.team;
 189                         wep.respawntime = g_pickup_respawntime_superweapon;
 190                         wep.pickup_anyway = true;
 191                         wep.spawnfunc_checked = true;
 192                         setthink(wep, self_spawnfunc_weapon_hmg);
 193                         wep.nextthink = time + 0.1;
 194                         return true;
 195                 }
 196                 else if(ent.classname == "item_invincible")
 197                 {
 198                         entity wep = new(weapon_rpc);
 199                         setorigin(wep, ent.origin);
 200                         setmodel(wep, MDL_OK_RPC);
 201                         wep.ok_item = true;
 202                         wep.noalign = ent.noalign;
 203                         wep.cnt = ent.cnt;
 204                         wep.team = ent.team;
 205                         wep.respawntime = g_pickup_respawntime_superweapon;
 206                         wep.pickup_anyway = true;
 207                         wep.spawnfunc_checked = true;
 208                         setthink(wep, self_spawnfunc_weapon_rpc);
 209                         wep.nextthink = time + 0.1;
 210                         return true;
 211                 }
 212         }
 213 }
 214
 215 bool ok_HandleItemWaypoints(entity e)
 216 {
 217         if(!autocvar_g_overkill_itemwaypoints)
 218                 return false; // don't handle it
 219
 220         switch(e.itemdef)
 221         {
 222                 case ITEM_HealthMega: return true;
 223                 case ITEM_ArmorMedium: return true;
 224                 case ITEM_ArmorBig: return true;
 225                 case ITEM_ArmorMega: return true;
 226         }
 227
 228         return false;
 229 }
 230
 231 MUTATOR_HOOKFUNCTION(ok, Item_RespawnCountdown)
 232 {
 233         entity item = M_ARGV(0, entity);
 234         return ok_HandleItemWaypoints(item);
 235 }
 236
 237 MUTATOR_HOOKFUNCTION(ok, Item_ScheduleRespawn)
 238 {
 239         entity item = M_ARGV(0, entity);
 240         return ok_HandleItemWaypoints(item);
 241 }
 242
 243 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 244 {
 245         entity item = M_ARGV(0, entity);
 246
 247         if(item.ok_item)
 248                 return false;
 249
 250         switch(item.itemdef)
 251         {
 252                 case ITEM_HealthMega: return autocvar_g_overkill_filter_healthmega;
 253                 case ITEM_ArmorMedium: return autocvar_g_overkill_filter_armormedium;
 254                 case ITEM_ArmorBig: return autocvar_g_overkill_filter_armorbig;
 255                 case ITEM_ArmorMega: return autocvar_g_overkill_filter_armormega;
 256         }
 257
 258         return true;
 259 }
 260
 261 MUTATOR_HOOKFUNCTION(ok, SetStartItems, CBC_ORDER_LAST)
 262 {
 263         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 264
 265         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 266         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 267
 268         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 269         start_weapons = warmup_start_weapons = ok_start_items;
 270 }
 271
 272 MUTATOR_HOOKFUNCTION(ok, SetWeaponArena)
 273 {
 274         // turn weapon arena off
 275         M_ARGV(0, string) = "off";
 276 }
 277
 278 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 279 {
 280         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":OK");
 281 }
 282
 283 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 284 {
 285         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Overkill");
 286 }
 287
 288 MUTATOR_HOOKFUNCTION(ok, SetModname)
 289 {
 290         M_ARGV(0, string) = "Overkill";
 291         return true;
 292 }