qcsrc/common/mutators/mutator/overkill/sv_overkill.qc

   1 #include "sv_overkill.qh"
   2
   3 #include "hmg.qh"
   4 #include "rpc.qh"
   5
   6 string autocvar_g_overkill;
   7
   8 bool autocvar_g_overkill_powerups_replace;
   9
  10 bool autocvar_g_overkill_itemwaypoints = true;
  11
  12 .Weapon ok_lastwep[MAX_WEAPONSLOTS];
  13
  14 REGISTER_MUTATOR(ok, expr_evaluate(autocvar_g_overkill) && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  15 {
  16         MUTATOR_ONADD
  17         {
  18                 precache_all_playermodels("models/ok_player/*.dpm");
  19
  20                 if (autocvar_g_overkill_filter_healthmega)
  21                 {
  22                         ITEM_HealthMega.spawnflags |= ITEM_FLAG_MUTATORBLOCKED;
  23                 }
  24                 if (autocvar_g_overkill_filter_armormedium)
  25                 {
  26                         ITEM_ArmorMedium.spawnflags |= ITEM_FLAG_MUTATORBLOCKED;
  27                 }
  28                 if (autocvar_g_overkill_filter_armorbig)
  29                 {
  30                         ITEM_ArmorBig.spawnflags |= ITEM_FLAG_MUTATORBLOCKED;
  31                 }
  32                 if (autocvar_g_overkill_filter_armormega)
  33                 {
  34                         ITEM_ArmorMega.spawnflags |= ITEM_FLAG_MUTATORBLOCKED;
  35                 }
  36
  37                 WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
  38                 WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
  39
  40                 //WEP_SHOTGUN.mdl = "ok_shotgun";
  41                 //WEP_MACHINEGUN.mdl = "ok_mg";
  42                 //WEP_VORTEX.mdl = "ok_sniper";
  43         }
  44
  45         MUTATOR_ONREMOVE
  46         {
  47                 ITEM_HealthMega.spawnflags &= ~ITEM_FLAG_MUTATORBLOCKED;
  48                 ITEM_ArmorMedium.spawnflags &= ~ITEM_FLAG_MUTATORBLOCKED;
  49                 ITEM_ArmorBig.spawnflags &= ~ITEM_FLAG_MUTATORBLOCKED;
  50                 ITEM_ArmorMega.spawnflags &= ~ITEM_FLAG_MUTATORBLOCKED;
  51
  52                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  53                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  54         }
  55 }
  56
  57 void W_Blaster_Attack(entity, .entity, float, float, float, float, float, float, float, float, float, float);
  58
  59 MUTATOR_HOOKFUNCTION(ok, Damage_Calculate, CBC_ORDER_LAST)
  60 {
  61         entity frag_attacker = M_ARGV(1, entity);
  62         entity frag_target = M_ARGV(2, entity);
  63         float frag_deathtype = M_ARGV(3, float);
  64
  65         if(IS_PLAYER(frag_attacker) && (IS_PLAYER(frag_target) || IS_VEHICLE(frag_target) || IS_TURRET(frag_target)))
  66         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
  67         {
  68                 if(frag_attacker != frag_target)
  69                 if(!STAT(FROZEN, frag_target))
  70                 if(!IS_DEAD(frag_target))
  71                 {
  72                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  73                         M_ARGV(6, vector) = '0 0 0'; // force
  74                 }
  75
  76                 M_ARGV(4, float) = 0; // damage
  77         }
  78 }
  79
  80 void ok_DropItem(entity this, entity targ)
  81 {
  82         entity e = spawn();
  83         e.ok_item = true;
  84         Item_InitializeLoot(e, "item_armor_small", this.origin + '0 0 32',
  85                 '0 0 200' + normalize(targ.origin - this.origin) * 500, 5);
  86 }
  87
  88 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
  89 {
  90         entity frag_attacker = M_ARGV(1, entity);
  91         entity frag_target = M_ARGV(2, entity);
  92
  93         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
  94
  95         ok_DropItem(frag_target, targ);
  96
  97         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  98         {
  99                 .entity weaponentity = weaponentities[slot];
 100
 101                 frag_target.ok_lastwep[slot] = frag_target.(weaponentity).m_switchweapon;
 102         }
 103 }
 104
 105 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem)
 106 {
 107         entity mon = M_ARGV(0, entity);
 108         entity olditem = M_ARGV(1, entity);
 109         entity frag_attacker = M_ARGV(2, entity);
 110
 111         delete(olditem);
 112
 113         M_ARGV(1, entity) = NULL;
 114
 115         ok_DropItem(mon, frag_attacker);
 116 }
 117
 118 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 119 {
 120         return true;
 121 }
 122
 123 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 124 {
 125         if (game_stopped)
 126         {
 127                 return;
 128         }
 129         entity player = M_ARGV(0, entity);
 130         if (!IS_PLAYER(player) || IS_DEAD(player) || STAT(FROZEN, player))
 131         {
 132                 return;
 133         }
 134         if (!PHYS_INPUT_BUTTON_ATCK2(player) || forbidWeaponUse(player) ||
 135                 !(round_handler_IsActive() && !round_handler_IsRoundStarted()))
 136         {
 137                 return;
 138         }
 139         // Allow secondary blaster during countdown.
 140         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 141         {
 142                 .entity weaponentity = weaponentities[slot];
 143                 Weapon weapon = player.(weaponentity).m_weapon;
 144                 if (weapon == WEP_Null && slot != 0)
 145                 {
 146                         continue;
 147                 }
 148                 weapon.wr_think(weapon, player, weaponentity, 2);
 149         }
 150         PHYS_INPUT_BUTTON_ATCK2(player) = false;
 151 }
 152
 153 MUTATOR_HOOKFUNCTION(ok, PlayerWeaponSelect)
 154 {
 155         entity player = M_ARGV(0, entity);
 156
 157         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 158         {
 159                 .entity weaponentity = weaponentities[slot];
 160                 entity thiswep = player.(weaponentity);
 161
 162                 if(player.ok_lastwep[slot] && player.ok_lastwep[slot] != WEP_Null)
 163                 {
 164                         Weapon newwep = player.ok_lastwep[slot];
 165                         if(player.ok_lastwep[slot] == WEP_HMG)
 166                                 newwep = WEP_MACHINEGUN;
 167                         if(player.ok_lastwep[slot] == WEP_RPC)
 168                                 newwep = WEP_VORTEX;
 169                         thiswep.m_switchweapon = newwep;
 170                         player.ok_lastwep[slot] = WEP_Null;
 171                 }
 172         }
 173 }
 174
 175 void self_spawnfunc_weapon_hmg(entity this) { spawnfunc_weapon_hmg(this); }
 176 void self_spawnfunc_weapon_rpc(entity this) { spawnfunc_weapon_rpc(this); }
 177
 178 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 179 {
 180         entity ent = M_ARGV(0, entity);
 181
 182         if(autocvar_g_powerups)
 183         if(autocvar_g_overkill_powerups_replace)
 184         {
 185                 if(ent.classname == "item_strength")
 186                 {
 187                         entity wep = new(weapon_hmg);
 188                         setorigin(wep, ent.origin);
 189                         setmodel(wep, MDL_OK_HMG);
 190                         wep.ok_item = true;
 191                         wep.noalign = Item_ShouldKeepPosition(ent);
 192                         wep.cnt = ent.cnt;
 193                         wep.team = ent.team;
 194                         wep.respawntime = g_pickup_respawntime_superweapon;
 195                         wep.pickup_anyway = true;
 196                         wep.spawnfunc_checked = true;
 197                         setthink(wep, self_spawnfunc_weapon_hmg);
 198                         wep.nextthink = time + 0.1;
 199                         return true;
 200                 }
 201                 else if(ent.classname == "item_shield")
 202                 {
 203                         entity wep = new(weapon_rpc);
 204                         setorigin(wep, ent.origin);
 205                         setmodel(wep, MDL_OK_RPC);
 206                         wep.ok_item = true;
 207                         wep.noalign = Item_ShouldKeepPosition(ent);
 208                         wep.cnt = ent.cnt;
 209                         wep.team = ent.team;
 210                         wep.respawntime = g_pickup_respawntime_superweapon;
 211                         wep.pickup_anyway = true;
 212                         wep.spawnfunc_checked = true;
 213                         setthink(wep, self_spawnfunc_weapon_rpc);
 214                         wep.nextthink = time + 0.1;
 215                         return true;
 216                 }
 217         }
 218 }
 219
 220 bool ok_HandleItemWaypoints(entity e)
 221 {
 222         if(!autocvar_g_overkill_itemwaypoints)
 223                 return false; // don't handle it
 224
 225         switch(e.itemdef)
 226         {
 227                 case ITEM_HealthMega: return true;
 228                 case ITEM_ArmorMedium: return true;
 229                 case ITEM_ArmorBig: return true;
 230                 case ITEM_ArmorMega: return true;
 231         }
 232
 233         return false;
 234 }
 235
 236 MUTATOR_HOOKFUNCTION(ok, Item_RespawnCountdown)
 237 {
 238         entity item = M_ARGV(0, entity);
 239         return ok_HandleItemWaypoints(item);
 240 }
 241
 242 MUTATOR_HOOKFUNCTION(ok, Item_ScheduleRespawn)
 243 {
 244         entity item = M_ARGV(0, entity);
 245         return ok_HandleItemWaypoints(item);
 246 }
 247
 248 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 249 {
 250         entity item = M_ARGV(0, entity);
 251
 252         if(item.ok_item)
 253                 return false;
 254
 255         return true;
 256 }
 257
 258 MUTATOR_HOOKFUNCTION(ok, SetStartItems, CBC_ORDER_LAST)
 259 {
 260         WepSet ok_start_items = (WEPSET(OVERKILL_MACHINEGUN) | WEPSET(OVERKILL_VORTEX) | WEPSET(OVERKILL_SHOTGUN));
 261
 262         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 263         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 264
 265         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 266         start_weapons = warmup_start_weapons = ok_start_items;
 267 }
 268
 269 MUTATOR_HOOKFUNCTION(ok, SetWeaponArena)
 270 {
 271         // turn weapon arena off
 272         M_ARGV(0, string) = "off";
 273 }
 274
 275 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 276 {
 277         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":OK");
 278 }
 279
 280 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 281 {
 282         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Overkill");
 283 }
 284
 285 MUTATOR_HOOKFUNCTION(ok, SetModname)
 286 {
 287         M_ARGV(0, string) = "Overkill";
 288         return true;
 289 }
 290