qcsrc/common/mutators/mutator/overkill/sv_overkill.qc

   1 #include "sv_overkill.qh"
   2
   3 #include "okshotgun.qh"
   4 #include "okhmg.qh"
   5 #include "okrpc.qh"
   6
   7 string autocvar_g_overkill;
   8
   9 bool autocvar_g_overkill_powerups_replace;
  10
  11 bool autocvar_g_overkill_itemwaypoints = true;
  12
  13 .Weapon ok_lastwep[MAX_WEAPONSLOTS];
  14
  15 REGISTER_MUTATOR(ok, expr_evaluate(autocvar_g_overkill) && !autocvar_g_instagib && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  16 {
  17         MUTATOR_ONADD
  18         {
  19                 precache_all_playermodels("models/ok_player/*.dpm");
  20
  21                 if (autocvar_g_overkill_filter_healthmega)
  22                 {
  23                         ITEM_HealthMega.spawnflags |= ITEM_FLAG_MUTATORBLOCKED;
  24                 }
  25                 if (autocvar_g_overkill_filter_armormedium)
  26                 {
  27                         ITEM_ArmorMedium.spawnflags |= ITEM_FLAG_MUTATORBLOCKED;
  28                 }
  29                 if (autocvar_g_overkill_filter_armorbig)
  30                 {
  31                         ITEM_ArmorBig.spawnflags |= ITEM_FLAG_MUTATORBLOCKED;
  32                 }
  33                 if (autocvar_g_overkill_filter_armormega)
  34                 {
  35                         ITEM_ArmorMega.spawnflags |= ITEM_FLAG_MUTATORBLOCKED;
  36                 }
  37
  38                 WEP_OVERKILL_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
  39                 WEP_OVERKILL_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
  40
  41                 WEP_OVERKILL_SHOTGUN.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
  42                 WEP_OVERKILL_MACHINEGUN.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
  43                 WEP_OVERKILL_NEX.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
  44
  45                 //WEP_SHOTGUN.mdl = "ok_shotgun";
  46                 //WEP_MACHINEGUN.mdl = "ok_mg";
  47                 //WEP_VORTEX.mdl = "ok_sniper";
  48         }
  49
  50         MUTATOR_ONREMOVE
  51         {
  52                 ITEM_HealthMega.spawnflags &= ~ITEM_FLAG_MUTATORBLOCKED;
  53                 ITEM_ArmorMedium.spawnflags &= ~ITEM_FLAG_MUTATORBLOCKED;
  54                 ITEM_ArmorBig.spawnflags &= ~ITEM_FLAG_MUTATORBLOCKED;
  55                 ITEM_ArmorMega.spawnflags &= ~ITEM_FLAG_MUTATORBLOCKED;
  56
  57                 WEP_OVERKILL_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  58                 WEP_OVERKILL_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  59
  60                 WEP_OVERKILL_SHOTGUN.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  61                 WEP_OVERKILL_MACHINEGUN.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  62                 WEP_OVERKILL_NEX.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  63         }
  64 }
  65
  66 void W_Blaster_Attack(entity, .entity, float, float, float, float, float, float, float, float, float, float);
  67
  68 MUTATOR_HOOKFUNCTION(ok, Damage_Calculate, CBC_ORDER_LAST)
  69 {
  70         entity frag_attacker = M_ARGV(1, entity);
  71         entity frag_target = M_ARGV(2, entity);
  72         float frag_deathtype = M_ARGV(3, float);
  73
  74         if(IS_PLAYER(frag_attacker) && (IS_PLAYER(frag_target) || IS_VEHICLE(frag_target) || IS_TURRET(frag_target)))
  75         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
  76         {
  77                 if(frag_attacker != frag_target)
  78                 if(!STAT(FROZEN, frag_target))
  79                 if(!IS_DEAD(frag_target))
  80                 {
  81                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  82                         M_ARGV(6, vector) = '0 0 0'; // force
  83                 }
  84
  85                 M_ARGV(4, float) = 0; // damage
  86         }
  87 }
  88
  89 void ok_DropItem(entity this, entity targ)
  90 {
  91         entity e = spawn();
  92         e.ok_item = true;
  93         Item_InitializeLoot(e, "item_armor_small", this.origin + '0 0 32',
  94                 '0 0 200' + normalize(targ.origin - this.origin) * 500, 5);
  95 }
  96
  97 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
  98 {
  99         entity frag_attacker = M_ARGV(1, entity);
 100         entity frag_target = M_ARGV(2, entity);
 101
 102         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
 103
 104         ok_DropItem(frag_target, targ);
 105
 106         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 107         {
 108                 .entity weaponentity = weaponentities[slot];
 109
 110                 frag_target.ok_lastwep[slot] = frag_target.(weaponentity).m_switchweapon;
 111         }
 112 }
 113
 114 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem)
 115 {
 116         entity mon = M_ARGV(0, entity);
 117         entity olditem = M_ARGV(1, entity);
 118         entity frag_attacker = M_ARGV(2, entity);
 119
 120         delete(olditem);
 121
 122         M_ARGV(1, entity) = NULL;
 123
 124         ok_DropItem(mon, frag_attacker);
 125 }
 126
 127 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 128 {
 129         return true;
 130 }
 131
 132 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 133 {
 134         if (game_stopped)
 135         {
 136                 return;
 137         }
 138         entity player = M_ARGV(0, entity);
 139         if (!IS_PLAYER(player) || IS_DEAD(player) || STAT(FROZEN, player))
 140         {
 141                 return;
 142         }
 143         if (!PHYS_INPUT_BUTTON_ATCK2(player) || forbidWeaponUse(player) ||
 144                 !(round_handler_IsActive() && !round_handler_IsRoundStarted()))
 145         {
 146                 return;
 147         }
 148         // Allow secondary blaster during countdown.
 149         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 150         {
 151                 .entity weaponentity = weaponentities[slot];
 152                 Weapon weapon = player.(weaponentity).m_weapon;
 153                 if (weapon == WEP_Null && slot != 0)
 154                 {
 155                         continue;
 156                 }
 157                 weapon.wr_think(weapon, player, weaponentity, 2);
 158         }
 159         PHYS_INPUT_BUTTON_ATCK2(player) = false;
 160 }
 161
 162 MUTATOR_HOOKFUNCTION(ok, ForbidRandomStartWeapons)
 163 {
 164         return true;
 165 }
 166
 167 MUTATOR_HOOKFUNCTION(ok, PlayerWeaponSelect)
 168 {
 169         entity player = M_ARGV(0, entity);
 170
 171         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 172         {
 173                 .entity weaponentity = weaponentities[slot];
 174                 entity thiswep = player.(weaponentity);
 175
 176                 if(player.ok_lastwep[slot] && player.ok_lastwep[slot] != WEP_Null)
 177                 {
 178                         Weapon newwep = player.ok_lastwep[slot];
 179                         if(player.ok_lastwep[slot] == WEP_OVERKILL_HMG)
 180                                 newwep = WEP_OVERKILL_MACHINEGUN;
 181                         if(player.ok_lastwep[slot] == WEP_OVERKILL_RPC)
 182                                 newwep = WEP_OVERKILL_NEX;
 183                         thiswep.m_switchweapon = newwep;
 184                         player.ok_lastwep[slot] = WEP_Null;
 185                 }
 186         }
 187 }
 188
 189 bool ok_HandleItemWaypoints(entity e)
 190 {
 191         if(!autocvar_g_overkill_itemwaypoints)
 192                 return false; // don't handle it
 193
 194         switch(e.itemdef)
 195         {
 196                 case ITEM_HealthMega: return true;
 197                 case ITEM_ArmorMedium: return true;
 198                 case ITEM_ArmorBig: return true;
 199                 case ITEM_ArmorMega: return true;
 200         }
 201
 202         return false;
 203 }
 204
 205 MUTATOR_HOOKFUNCTION(ok, Item_RespawnCountdown)
 206 {
 207         entity item = M_ARGV(0, entity);
 208         return ok_HandleItemWaypoints(item);
 209 }
 210
 211 MUTATOR_HOOKFUNCTION(ok, Item_ScheduleRespawn)
 212 {
 213         entity item = M_ARGV(0, entity);
 214         return ok_HandleItemWaypoints(item);
 215 }
 216
 217 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 218 {
 219         entity item = M_ARGV(0, entity);
 220
 221         if (item.ok_item)
 222         {
 223                 return false;
 224         }
 225         switch(item.itemdef)
 226         {
 227                 case ITEM_HealthMega: return autocvar_g_overkill_filter_healthmega;
 228                 case ITEM_ArmorMedium: return autocvar_g_overkill_filter_armormedium;
 229                 case ITEM_ArmorBig: return autocvar_g_overkill_filter_armorbig;
 230                 case ITEM_ArmorMega: return autocvar_g_overkill_filter_armormega;
 231         }
 232         if (!autocvar_g_powerups || !autocvar_g_overkill_powerups_replace)
 233         {
 234                 return true;
 235         }
 236         if (item.classname == "item_strength")
 237         {
 238                 entity wep = new(weapon_okhmg);
 239                 setorigin(wep, item.origin);
 240                 wep.ok_item = true;
 241                 wep.noalign = Item_ShouldKeepPosition(item);
 242                 wep.cnt = item.cnt;
 243                 wep.team = item.team;
 244                 wep.respawntime = g_pickup_respawntime_superweapon;
 245                 wep.pickup_anyway = true;
 246                 wep.spawnfunc_checked = true;
 247                 Item_Initialize(wep, "weapon_okhmg"); // doesn't actually use spawnfunc
 248                 return true;
 249         }
 250         else if (item.classname == "item_shield")
 251         {
 252                 entity wep = new(weapon_okrpc);
 253                 setorigin(wep, item.origin);
 254                 wep.ok_item = true;
 255                 wep.noalign = Item_ShouldKeepPosition(item);
 256                 wep.cnt = item.cnt;
 257                 wep.team = item.team;
 258                 wep.respawntime = g_pickup_respawntime_superweapon;
 259                 wep.pickup_anyway = true;
 260                 wep.spawnfunc_checked = true;
 261                 Item_Initialize(wep, "weapon_okrpc"); // doesn't actually use spawnfunc
 262                 return true;
 263         }
 264         return true;
 265 }
 266
 267 MUTATOR_HOOKFUNCTION(ok, SetStartItems, CBC_ORDER_LAST)
 268 {
 269         WepSet ok_start_items = (WEPSET(OVERKILL_MACHINEGUN) | WEPSET(OVERKILL_NEX) | WEPSET(OVERKILL_SHOTGUN));
 270
 271         if(WEP_OVERKILL_RPC.weaponstart > 0) { ok_start_items |= WEPSET(OVERKILL_RPC); }
 272         if(WEP_OVERKILL_HMG.weaponstart > 0) { ok_start_items |= WEPSET(OVERKILL_HMG); }
 273
 274         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 275         start_weapons = warmup_start_weapons = ok_start_items;
 276 }
 277
 278 MUTATOR_HOOKFUNCTION(ok, SetWeaponArena)
 279 {
 280         // turn weapon arena off
 281         M_ARGV(0, string) = "off";
 282 }
 283
 284 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 285 {
 286         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":OK");
 287 }
 288
 289 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 290 {
 291         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Overkill");
 292 }
 293
 294 MUTATOR_HOOKFUNCTION(ok, SetModname)
 295 {
 296         M_ARGV(0, string) = "Overkill";
 297         return true;
 298 }
 299