qcsrc/common/mutators/mutator/powerups/sv_powerups.qc

   1 #include "sv_powerups.qh"
   2
   3 MUTATOR_HOOKFUNCTION(powerups, W_PlayStrengthSound)
   4 {
   5         entity player = M_ARGV(0, entity);
   6
   7         if(StatusEffects_active(STATUSEFFECT_Strength, player)
   8                 && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
   9                 || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
  10                 {
  11                         sound(player, CH_TRIGGER, SND_STRENGTH_FIRE, VOL_BASE, ATTEN_NORM);
  12                         player.prevstrengthsound = time;
  13                 }
  14         player.prevstrengthsoundattempt = time;
  15 }
  16
  17 MUTATOR_HOOKFUNCTION(powerups, LogDeath_AppendItemCodes)
  18 {
  19         entity player = M_ARGV(0, entity);
  20
  21         if(StatusEffects_active(STATUSEFFECT_Strength, player))
  22                 M_ARGV(1, string) = strcat(M_ARGV(1, string), "S");
  23
  24         if(StatusEffects_active(STATUSEFFECT_Shield, player))
  25                 M_ARGV(1, string) = strcat(M_ARGV(1, string), "I");
  26
  27         // TODO: item codes for other powerups?
  28 }
  29
  30 MUTATOR_HOOKFUNCTION(powerups, Damage_Calculate)
  31 {
  32         entity attacker = M_ARGV(1, entity);
  33         entity targ = M_ARGV(2, entity);
  34
  35         // apply strength multiplier
  36         if(StatusEffects_active(STATUSEFFECT_Strength, attacker))
  37         {
  38                 if(targ == attacker)
  39                 {
  40                         M_ARGV(4, float) = M_ARGV(4, float) * autocvar_g_balance_powerup_strength_selfdamage;
  41                         M_ARGV(6, vector) = M_ARGV(6, vector) * autocvar_g_balance_powerup_strength_selfforce;
  42                 }
  43                 else
  44                 {
  45                         M_ARGV(4, float) = M_ARGV(4, float) * autocvar_g_balance_powerup_strength_damage;
  46                         M_ARGV(6, vector) = M_ARGV(6, vector) * autocvar_g_balance_powerup_strength_force;
  47                 }
  48         }
  49
  50         // apply shield multiplier
  51         if(StatusEffects_active(STATUSEFFECT_Shield, targ))
  52         {
  53                 M_ARGV(4, float) = M_ARGV(4, float) * autocvar_g_balance_powerup_invincible_takedamage;
  54                 if (targ != attacker)
  55                 {
  56                         M_ARGV(6, vector) = M_ARGV(6, vector) * autocvar_g_balance_powerup_invincible_takeforce;
  57                 }
  58         }
  59 }
  60
  61 MUTATOR_HOOKFUNCTION(powerups, CustomizeWaypoint)
  62 {
  63         entity wp = M_ARGV(0, entity);
  64         entity player = M_ARGV(1, entity);
  65
  66         entity e = WaypointSprite_getviewentity(player);
  67
  68         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
  69         // but only apply this to real players, not to spectators
  70         if(IS_CLIENT(wp.owner) && (e == player) && DIFF_TEAM(wp.owner, e) && StatusEffects_active(STATUSEFFECT_Invisibility, wp.owner))
  71                 return true;
  72 }
  73
  74 MUTATOR_HOOKFUNCTION(powerups, MonsterValidTarget)
  75 {
  76         entity targ = M_ARGV(1, entity);
  77         return StatusEffects_active(STATUSEFFECT_Invisibility, targ);
  78 }
  79
  80 void powerups_DropItem_Think(entity this)
  81 {
  82         TakeResource(this, RES_HEALTH, 1);
  83
  84         if(GetResource(this, RES_HEALTH) < 1) {
  85                 WaypointSprite_Kill(this.waypointsprite_attached);
  86                 delete(this);
  87                 return;
  88         }
  89
  90         // Only needed to update if the timer of the powerup is running
  91         if(!GetResource(this, RES_ARMOR))
  92                 WaypointSprite_UpdateHealth(this.waypointsprite_attached, GetResource(this, RES_HEALTH));
  93
  94         this.nextthink = time + 1;
  95 }
  96
  97 void powerups_DropItem(entity this, StatusEffects effect, bool freezeTimer)
  98 {
  99         entity item = Item_DefinitionFromInternalName(effect.netname);
 100         float t = StatusEffects_gettime(effect, this);
 101         float timeleft = t - time;
 102         float maxtime = 0;
 103
 104         if(timeleft <= 1 || !item)
 105                 return;
 106         entity e = spawn();
 107
 108         // If we want the timer to keep running, we enable expiring then use the exact time the powerup will finish at.
 109         // If we want the timer to freeze, we disable expiring and we just use the time left of the powerup.
 110         // See Item_SetExpiring() below.
 111         float finished = (freezeTimer ? timeleft : t);
 112
 113         // If the timer is frozen, the item will stay on the floor for 20 secs (same as weapons),
 114         // otherwise it'll disappear after the timer runs out.
 115         float time_to_live = (freezeTimer ? autocvar_g_items_dropped_lifetime : timeleft);
 116
 117         // TODO: items cannot hold their "item field" yet, so we need to list all the powerups here!
 118         switch(item)
 119         {
 120                 case ITEM_Strength: e.strength_finished = finished; maxtime = autocvar_g_balance_powerup_strength_time; break;
 121                 case ITEM_Shield: e.invincible_finished = finished; maxtime = autocvar_g_balance_powerup_invincible_time; break;
 122                 case ITEM_Invisibility: e.invisibility_finished = finished; maxtime = autocvar_g_balance_powerup_invincible_time; break;
 123                 case ITEM_Speed: e.speed_finished = finished; maxtime = autocvar_g_balance_powerup_speed_time; break;
 124         }
 125         Item_InitializeLoot(e, item.m_canonical_spawnfunc, this.origin, W_CalculateProjectileVelocity(this, this.velocity, v_forward * 750, false), time_to_live);
 126         e.item_spawnshieldtime = time + 0.5;
 127
 128         if(!freezeTimer)
 129                 Item_SetExpiring(e, true);
 130
 131         // Use health as time left to live
 132         SetResourceExplicit(e, RES_HEALTH, time_to_live);
 133
 134         // Use armor as timer freezer
 135         if(freezeTimer)
 136                 SetResourceExplicit(e, RES_ARMOR, 1);
 137
 138         // Create waypoint displaying time left of the powerup
 139         entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, e, '0 0 1' * e.maxs.z, NULL, 0, e, waypointsprite_attached, true, RADARICON_Item);
 140         wp.wp_extra = item.m_id;
 141         WaypointSprite_UpdateMaxHealth(e.waypointsprite_attached, maxtime);
 142         WaypointSprite_UpdateHealth(e.waypointsprite_attached, timeleft);
 143
 144         // Start dropping its time to live
 145         setthink(e, powerups_DropItem_Think);
 146         e.nextthink = time + 1;
 147 }
 148
 149 MUTATOR_HOOKFUNCTION(powerups, ItemTouched)
 150 {
 151         entity e = M_ARGV(0, entity);
 152         if(e.waypointsprite_attached)
 153                 WaypointSprite_Kill(e.waypointsprite_attached);
 154 }
 155
 156 MUTATOR_HOOKFUNCTION(powerups, PlayerDies)
 157 {
 158         if(!autocvar_g_powerups_drop_ondeath)
 159                 return;
 160
 161         entity frag_target = M_ARGV(2, entity);
 162
 163         FOREACH(StatusEffect, it.instanceOfPowerups,
 164         {
 165                 if(StatusEffects_active(it, frag_target))
 166                         powerups_DropItem(frag_target, it, autocvar_g_powerups_drop_ondeath == 2);
 167         });
 168 }
 169
 170 MUTATOR_HOOKFUNCTION(powerups, PlayerUseKey)
 171 {
 172         if(!autocvar_g_powerups_drop)
 173                 return;
 174
 175         entity player = M_ARGV(0, entity);
 176
 177         FOREACH(StatusEffect, it.instanceOfPowerups,
 178         {
 179                 if(StatusEffects_active(it, player)) {
 180                         powerups_DropItem(player, it, autocvar_g_powerups_drop == 2);
 181                         StatusEffects_remove(it, player, STATUSEFFECT_REMOVE_NORMAL);
 182                         return true;
 183                 }
 184         });
 185 }
 186
 187 MUTATOR_HOOKFUNCTION(powerups, PlayerPhysics_UpdateStats)
 188 {
 189         entity player = M_ARGV(0, entity);
 190         // these automatically reset, no need to worry
 191
 192         if(StatusEffects_active(STATUSEFFECT_Speed, player))
 193                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_balance_powerup_speed_highspeed;
 194 }
 195
 196 MUTATOR_HOOKFUNCTION(powerups, WeaponRateFactor)
 197 {
 198         entity player = M_ARGV(1, entity);
 199
 200         if(StatusEffects_active(STATUSEFFECT_Speed, player))
 201                 M_ARGV(0, float) *= autocvar_g_balance_powerup_speed_attackrate;
 202 }
 203
 204 MUTATOR_HOOKFUNCTION(powerups, BuildMutatorsPrettyString)
 205 {
 206         if(autocvar_g_powerups == 0)
 207                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ", No powerups");
 208         if(autocvar_g_powerups > 0)
 209                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Powerups");
 210 }
 211
 212 MUTATOR_HOOKFUNCTION(powerups, BotShouldAttack)
 213 {
 214         entity targ = M_ARGV(1, entity);
 215
 216         if(StatusEffects_active(STATUSEFFECT_Invisibility, targ))
 217                 return true;
 218 }
 219
 220 MUTATOR_HOOKFUNCTION(powerups, BuildMutatorsString)
 221 {
 222         if(autocvar_g_powerups == 0)
 223                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ":no_powerups");
 224         if(autocvar_g_powerups > 0)
 225                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ":powerups");
 226 }