qcsrc/common/mutators/mutator/sandbox/sandbox.qc

   1 #ifdef IMPLEMENTATION
   2 int autocvar_g_sandbox_info;
   3 bool autocvar_g_sandbox_readonly;
   4 string autocvar_g_sandbox_storage_name;
   5 float autocvar_g_sandbox_storage_autosave;
   6 bool autocvar_g_sandbox_storage_autoload;
   7 float autocvar_g_sandbox_editor_flood;
   8 int autocvar_g_sandbox_editor_maxobjects;
   9 int autocvar_g_sandbox_editor_free;
  10 float autocvar_g_sandbox_editor_distance_spawn;
  11 float autocvar_g_sandbox_editor_distance_edit;
  12 float autocvar_g_sandbox_object_scale_min;
  13 float autocvar_g_sandbox_object_scale_max;
  14 float autocvar_g_sandbox_object_material_velocity_min;
  15 float autocvar_g_sandbox_object_material_velocity_factor;
  16
  17 float autosave_time;
  18 void sandbox_Database_Load();
  19
  20 REGISTER_MUTATOR(sandbox, cvar("g_sandbox"))
  21 {
  22         MUTATOR_ONADD
  23         {
  24                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
  25                 if(autocvar_g_sandbox_storage_autoload)
  26                         sandbox_Database_Load();
  27         }
  28
  29         MUTATOR_ONROLLBACK_OR_REMOVE
  30         {
  31                 // nothing to roll back
  32         }
  33
  34         MUTATOR_ONREMOVE
  35         {
  36                 // nothing to remove
  37         }
  38
  39         return false;
  40 }
  41
  42 const float MAX_STORAGE_ATTACHMENTS = 16;
  43 float object_count;
  44 .float object_flood;
  45 .entity object_attach;
  46 .string material;
  47
  48 .float touch_timer;
  49 void sandbox_ObjectFunction_Touch()
  50 {SELFPARAM();
  51         // apply material impact effects
  52
  53         if(!self.material)
  54                 return;
  55         if(self.touch_timer > time)
  56                 return; // don't execute each frame
  57         self.touch_timer = time + 0.1;
  58
  59         // make particle count and sound volume depend on impact speed
  60         float intensity;
  61         intensity = vlen(self.velocity) + vlen(other.velocity);
  62         if(intensity) // avoid divisions by 0
  63                 intensity /= 2; // average the two velocities
  64         if (!(intensity >= autocvar_g_sandbox_object_material_velocity_min))
  65                 return; // impact not strong enough to do anything
  66         // now offset intensity and apply it to the effects
  67         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  68         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  69
  70         _sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".wav"), VOL_BASE * intensity, ATTEN_NORM);
  71         Send_Effect_(strcat("impact_", self.material), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  72 }
  73
  74 void sandbox_ObjectFunction_Think()
  75 {SELFPARAM();
  76         entity e;
  77
  78         // decide if and how this object can be grabbed
  79         if(autocvar_g_sandbox_readonly)
  80                 self.grab = 0; // no grabbing
  81         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
  82                 self.grab = 1; // owner only
  83         else
  84                 self.grab = 3; // anyone
  85
  86         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  87         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  88         // since if the owning player disconnects, the object's owner should also be reset.
  89         FOR_EACH_REALPLAYER(e) // bots can't have objects
  90         {
  91                 if(self.crypto_idfp == e.crypto_idfp)
  92                 {
  93                         self.realowner = e;
  94                         break;
  95                 }
  96                 self.realowner = world;
  97         }
  98
  99         self.nextthink = time;
 100
 101         CSQCMODEL_AUTOUPDATE(self);
 102 }
 103
 104 .float old_solid, old_movetype;
 105 entity sandbox_ObjectEdit_Get(float permissions)
 106 {SELFPARAM();
 107         // Returns the traced entity if the player can edit it, and world if not.
 108         // If permissions if false, the object is returned regardless of editing rights.
 109         // Attached objects are SOLID_NOT and do not get traced.
 110
 111         crosshair_trace_plusvisibletriggers(self);
 112         if(vlen(self.origin - trace_ent.origin) > autocvar_g_sandbox_editor_distance_edit)
 113                 return world; // out of trace range
 114         if(trace_ent.classname != "object")
 115                 return world; // entity is not an object
 116         if(!permissions)
 117                 return trace_ent; // don't check permissions, anyone can edit this object
 118         if(trace_ent.crypto_idfp == "")
 119                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
 120         if (!(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2))
 121                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
 122         return world;
 123 }
 124
 125 void sandbox_ObjectEdit_Scale(entity e, float f)
 126 {
 127         e.scale = f;
 128         if(e.scale)
 129         {
 130                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
 131                 _setmodel(e, e.model); // reset mins and maxs based on mesh
 132                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
 133         }
 134 }
 135
 136 void sandbox_ObjectAttach_Remove(entity e);
 137 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
 138 {
 139         // attaches e to parent on string s
 140
 141         // we can't attach to an attachment, for obvious reasons
 142         sandbox_ObjectAttach_Remove(e);
 143
 144         e.old_solid = e.solid; // persist solidity
 145         e.old_movetype = e.movetype; // persist physics
 146         e.movetype = MOVETYPE_FOLLOW;
 147         e.solid = SOLID_NOT;
 148         e.takedamage = DAMAGE_NO;
 149
 150         setattachment(e, parent, s);
 151         e.owner = parent;
 152 }
 153
 154 void sandbox_ObjectAttach_Remove(entity e)
 155 {
 156         // detaches any object attached to e
 157
 158         entity head;
 159         for(head = world; (head = find(head, classname, "object")); )
 160         {
 161                 if(head.owner == e)
 162                 {
 163                         vector org;
 164                         org = gettaginfo(head, 0);
 165                         setattachment(head, world, "");
 166                         head.owner = world;
 167
 168                         // objects change origin and angles when detached, so apply previous position
 169                         setorigin(head, org);
 170                         head.angles = e.angles; // don't allow detached objects to spin or roll
 171
 172                         head.solid = head.old_solid; // restore persisted solidity
 173                         head.movetype = head.old_movetype; // restore persisted physics
 174                         head.takedamage = DAMAGE_AIM;
 175                 }
 176         }
 177 }
 178
 179 entity sandbox_ObjectSpawn(float database)
 180 {SELFPARAM();
 181         // spawn a new object with default properties
 182
 183         entity e = new(object);
 184         e.takedamage = DAMAGE_AIM;
 185         e.damageforcescale = 1;
 186         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 187         e.movetype = MOVETYPE_TOSS;
 188         e.frame = 0;
 189         e.skin = 0;
 190         e.material = string_null;
 191         e.touch = sandbox_ObjectFunction_Touch;
 192         e.think = sandbox_ObjectFunction_Think;
 193         e.nextthink = time;
 194         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 195
 196         if(!database)
 197         {
 198                 // set the object's owner via player UID
 199                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 200                 if(self.crypto_idfp != "")
 201                         e.crypto_idfp = strzone(self.crypto_idfp);
 202                 else
 203                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 204
 205                 // set public object information
 206                 e.netname = strzone(self.netname); // name of the owner
 207                 e.message = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // creation time
 208                 e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // last editing time
 209
 210                 // set origin and direction based on player position and view angle
 211                 makevectors(self.v_angle);
 212                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 213                 setorigin(e, trace_endpos);
 214                 e.angles_y = self.v_angle.y;
 215         }
 216
 217         WITH(entity, self, e, CSQCMODEL_AUTOINIT(e));
 218
 219         object_count += 1;
 220         return e;
 221 }
 222
 223 void sandbox_ObjectRemove(entity e)
 224 {
 225         sandbox_ObjectAttach_Remove(e); // detach child objects
 226
 227         // if the object being removed has been selected for attachment by a player, unset it
 228         entity head;
 229         FOR_EACH_REALPLAYER(head) // bots can't have objects
 230         {
 231                 if(head.object_attach == e)
 232                         head.object_attach = world;
 233         }
 234
 235         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 236         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 237         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 238         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 239         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 240         remove(e);
 241         e = world;
 242
 243         object_count -= 1;
 244 }
 245
 246 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 247
 248 string sandbox_ObjectPort_Save(entity e, float database)
 249 {
 250         // save object properties, and return them as a string
 251         float i = 0;
 252         string s;
 253         entity head;
 254
 255         for(head = world; (head = find(head, classname, "object")); )
 256         {
 257                 // the main object needs to be first in the array [0] with attached objects following
 258                 float slot, physics, solidity;
 259                 if(head == e) // this is the main object, place it first
 260                 {
 261                         slot = 0;
 262                         solidity = head.solid; // applied solidity is normal solidity for children
 263                         physics = head.movetype; // applied physics are normal physics for parents
 264                 }
 265                 else if(head.owner == e) // child object, list them in order
 266                 {
 267                         i += 1; // children start from 1
 268                         slot = i;
 269                         solidity = head.old_solid; // persisted solidity is normal solidity for children
 270                         physics = head.old_movetype; // persisted physics are normal physics for children
 271                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 272                 }
 273                 else
 274                         continue;
 275
 276                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 277                 if(slot)
 278                 {
 279                         // properties stored only for child objects
 280                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 281                 }
 282                 else
 283                 {
 284                         // properties stored only for parent objects
 285                         if(database)
 286                         {
 287                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 288                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 289                         }
 290                 }
 291                 // properties stored for all objects
 292                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 293                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 294                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 295                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 296                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 297                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 298                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 299                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
 300                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 301                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 302                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 303                 if(database)
 304                 {
 305                         // properties stored only for the database
 306                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 307                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 308                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 309                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 310                 }
 311         }
 312
 313         // now apply the array to a simple string, with the ; symbol separating objects
 314         s = "";
 315         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 316         {
 317                 if(port_string[i])
 318                         s = strcat(s, port_string[i], "; ");
 319                 port_string[i] = string_null; // fully clear the string
 320         }
 321
 322         return s;
 323 }
 324
 325 entity sandbox_ObjectPort_Load(string s, float database)
 326 {
 327         // load object properties, and spawn a new object with them
 328         float n, i;
 329         entity e = world, parent = world;
 330
 331         // separate objects between the ; symbols
 332         n = tokenizebyseparator(s, "; ");
 333         for(i = 0; i < n; ++i)
 334                 port_string[i] = argv(i);
 335
 336         // now separate and apply the properties of each object
 337         for(i = 0; i < n; ++i)
 338         {
 339                 float argv_num;
 340                 string tagname = string_null;
 341                 argv_num = 0;
 342                 tokenize_console(port_string[i]);
 343                 e = sandbox_ObjectSpawn(database);
 344
 345                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 346                 if(i)
 347                 {
 348                         // properties stored only for child objects
 349                         if(argv(argv_num) != "")        tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 350                 }
 351                 else
 352                 {
 353                         // properties stored only for parent objects
 354                         if(database)
 355                         {
 356                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 357                                 e.angles = stov(argv(argv_num));        ++argv_num;
 358                         }
 359                         parent = e; // mark parent objects as such
 360                 }
 361                 // properties stored for all objects
 362                 _setmodel(e, argv(argv_num));   ++argv_num;
 363                 e.skin = stof(argv(argv_num));  ++argv_num;
 364                 e.alpha = stof(argv(argv_num)); ++argv_num;
 365                 e.colormod = stov(argv(argv_num));      ++argv_num;
 366                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 367                 e.frame = stof(argv(argv_num)); ++argv_num;
 368                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 369                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
 370                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 371                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 372                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "")        e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 373                 if(database)
 374                 {
 375                         // properties stored only for the database
 376                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "")        e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 377                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 378                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 379                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 380                 }
 381
 382                 // attach last
 383                 if(i)
 384                         sandbox_ObjectAttach_Set(e, parent, tagname);
 385         }
 386
 387         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 388                 port_string[i] = string_null; // fully clear the string
 389
 390         return e;
 391 }
 392
 393 void sandbox_Database_Save()
 394 {
 395         // saves all objects to the database file
 396         entity head;
 397         string file_name;
 398         float file_get;
 399
 400         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 401         file_get = fopen(file_name, FILE_WRITE);
 402         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S")));
 403         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 404
 405         for(head = world; (head = find(head, classname, "object")); )
 406         {
 407                 // attached objects are persisted separately, ignore them here
 408                 if(head.owner != world)
 409                         continue;
 410
 411                 // use a line of text for each object, listing all properties
 412                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, true), "\n"));
 413         }
 414         fclose(file_get);
 415 }
 416
 417 void sandbox_Database_Load()
 418 {
 419         // loads all objects from the database file
 420         string file_read, file_name;
 421         float file_get, i;
 422
 423         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 424         file_get = fopen(file_name, FILE_READ);
 425         if(file_get < 0)
 426         {
 427                 if(autocvar_g_sandbox_info > 0)
 428                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 429         }
 430         else
 431         {
 432                 for (;;)
 433                 {
 434                         file_read = fgets(file_get);
 435                         if(file_read == "")
 436                                 break;
 437                         if(substring(file_read, 0, 2) == "//")
 438                                 continue;
 439                         if(substring(file_read, 0, 1) == "#")
 440                                 continue;
 441
 442                         entity e;
 443                         e = sandbox_ObjectPort_Load(file_read, true);
 444
 445                         if(e.material)
 446                         {
 447                                 // since objects are being loaded for the first time, precache material sounds for each
 448                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 449                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".wav"));
 450                         }
 451                 }
 452                 if(autocvar_g_sandbox_info > 0)
 453                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 454         }
 455         fclose(file_get);
 456 }
 457
 458 MUTATOR_HOOKFUNCTION(sandbox, SV_ParseClientCommand)
 459 {SELFPARAM();
 460         if(MUTATOR_RETURNVALUE) // command was already handled?
 461                 return false;
 462         if(cmd_name == "g_sandbox")
 463         {
 464                 if(autocvar_g_sandbox_readonly)
 465                 {
 466                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 467                         return true;
 468                 }
 469                 if(cmd_argc < 2)
 470                 {
 471                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 472                         return true;
 473                 }
 474
 475                 switch(argv(1))
 476                 {
 477                         entity e;
 478                         float i;
 479                         string s;
 480
 481                         // ---------------- COMMAND: HELP ----------------
 482                         case "help":
 483                                 print_to(self, "You can use the following sandbox commands:");
 484                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 485                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 486                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 487                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 488                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 489                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 490                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 491                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 492                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 493                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 494                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 495                                 print_to(self, "^3alpha value ^7- sets object transparency");
 496                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 497                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 498                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 499                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 500                                 print_to(self, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
 501                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 502                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 503                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 504                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 505                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 506                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 507                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 508                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 509                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 510                                 return true;
 511
 512                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 513                         case "object_spawn":
 514                                 if(time < self.object_flood)
 515                                 {
 516                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 517                                         return true;
 518                                 }
 519                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 520                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 521                                 {
 522                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 523                                         return true;
 524                                 }
 525                                 if(cmd_argc < 3)
 526                                 {
 527                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 528                                         return true;
 529                                 }
 530                                 if (!(fexists(argv(2))))
 531                                 {
 532                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 533                                         return true;
 534                                 }
 535
 536                                 e = sandbox_ObjectSpawn(false);
 537                                 _setmodel(e, argv(2));
 538
 539                                 if(autocvar_g_sandbox_info > 0)
 540                                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 541                                 return true;
 542
 543                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 544                         case "object_remove":
 545                                 e = sandbox_ObjectEdit_Get(true);
 546                                 if(e != world)
 547                                 {
 548                                         if(autocvar_g_sandbox_info > 0)
 549                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 550                                         sandbox_ObjectRemove(e);
 551                                         return true;
 552                                 }
 553
 554                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 555                                 return true;
 556
 557                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 558                         case "object_duplicate":
 559                                 switch(argv(2))
 560                                 {
 561                                         case "copy":
 562                                                 // copies customizable properties of the selected object to the clipboard cvar
 563                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 564                                                 if(e != world)
 565                                                 {
 566                                                         s = sandbox_ObjectPort_Save(e, false);
 567                                                         s = strreplace("\"", "\\\"", s);
 568                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 569
 570                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 571                                                         return true;
 572                                                 }
 573                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 574                                                 return true;
 575
 576                                         case "paste":
 577                                                 // spawns a new object using the properties in the player's clipboard cvar
 578                                                 if(time < self.object_flood)
 579                                                 {
 580                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 581                                                         return true;
 582                                                 }
 583                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 584                                                 if(argv(3) == "") // no object in clipboard
 585                                                 {
 586                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 587                                                         return true;
 588                                                 }
 589                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 590                                                 {
 591                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 592                                                         return true;
 593                                                 }
 594                                                 e = sandbox_ObjectPort_Load(argv(3), false);
 595
 596                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 597                                                 if(autocvar_g_sandbox_info > 0)
 598                                                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 599                                                 return true;
 600                                 }
 601                                 return true;
 602
 603                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 604                         case "object_attach":
 605                                 switch(argv(2))
 606                                 {
 607                                         case "get":
 608                                                 // select e as the object as meant to be attached
 609                                                 e = sandbox_ObjectEdit_Get(true);
 610                                                 if(e != world)
 611                                                 {
 612                                                         self.object_attach = e;
 613                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 614                                                         return true;
 615                                                 }
 616                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 617                                                 return true;
 618                                         case "set":
 619                                                 if(self.object_attach == world)
 620                                                 {
 621                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 622                                                         return true;
 623                                                 }
 624
 625                                                 // attaches the previously selected object to e
 626                                                 e = sandbox_ObjectEdit_Get(true);
 627                                                 if(e != world)
 628                                                 {
 629                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 630                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 631                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 632                                                         if(autocvar_g_sandbox_info > 1)
 633                                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 634                                                         return true;
 635                                                 }
 636                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 637                                                 return true;
 638                                         case "remove":
 639                                                 // removes e if it was attached
 640                                                 e = sandbox_ObjectEdit_Get(true);
 641                                                 if(e != world)
 642                                                 {
 643                                                         sandbox_ObjectAttach_Remove(e);
 644                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 645                                                         if(autocvar_g_sandbox_info > 1)
 646                                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 647                                                         return true;
 648                                                 }
 649                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 650                                                 return true;
 651                                 }
 652                                 return true;
 653
 654                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 655                         case "object_edit":
 656                                 if(argv(2) == "")
 657                                 {
 658                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 659                                         return true;
 660                                 }
 661
 662                                 e = sandbox_ObjectEdit_Get(true);
 663                                 if(e != world)
 664                                 {
 665                                         switch(argv(2))
 666                                         {
 667                                                 case "skin":
 668                                                         e.skin = stof(argv(3));
 669                                                         break;
 670                                                 case "alpha":
 671                                                         e.alpha = stof(argv(3));
 672                                                         break;
 673                                                 case "color_main":
 674                                                         e.colormod = stov(argv(3));
 675                                                         break;
 676                                                 case "color_glow":
 677                                                         e.glowmod = stov(argv(3));
 678                                                         break;
 679                                                 case "frame":
 680                                                         e.frame = stof(argv(3));
 681                                                         break;
 682                                                 case "scale":
 683                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 684                                                         break;
 685                                                 case "solidity":
 686                                                         switch(argv(3))
 687                                                         {
 688                                                                 case "0": // non-solid
 689                                                                         e.solid = SOLID_TRIGGER;
 690                                                                         break;
 691                                                                 case "1": // solid
 692                                                                         e.solid = SOLID_BBOX;
 693                                                                         break;
 694                                                                 default:
 695                                                                         break;
 696                                                         }
 697                                                 case "physics":
 698                                                         switch(argv(3))
 699                                                         {
 700                                                                 case "0": // static
 701                                                                         e.movetype = MOVETYPE_NONE;
 702                                                                         break;
 703                                                                 case "1": // movable
 704                                                                         e.movetype = MOVETYPE_TOSS;
 705                                                                         break;
 706                                                                 case "2": // physical
 707                                                                         e.movetype = MOVETYPE_PHYSICS;
 708                                                                         break;
 709                                                                 default:
 710                                                                         break;
 711                                                         }
 712                                                         break;
 713                                                 case "force":
 714                                                         e.damageforcescale = stof(argv(3));
 715                                                         break;
 716                                                 case "material":
 717                                                         if(e.material)  strunzone(e.material);
 718                                                         if(argv(3))
 719                                                         {
 720                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 721                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".wav"));
 722                                                                 e.material = strzone(argv(3));
 723                                                         }
 724                                                         else
 725                                                                 e.material = string_null; // no material
 726                                                         break;
 727                                                 default:
 728                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 729                                                         return true;
 730                                         }
 731
 732                                         // update last editing time
 733                                         if(e.message2)  strunzone(e.message2);
 734                                         e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S"));
 735
 736                                         if(autocvar_g_sandbox_info > 1)
 737                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 738                                         return true;
 739                                 }
 740
 741                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 742                                 return true;
 743
 744                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 745                         case "object_claim":
 746                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 747                                 if(self.crypto_idfp == "")
 748                                 {
 749                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 750                                         return true;
 751                                 }
 752                                 e = sandbox_ObjectEdit_Get(true);
 753                                 if(e != world)
 754                                 {
 755                                         // update the owner's name
 756                                         // Do this before checking if you're already the owner and skipping if such, so we
 757                                         // also update the player's nickname if he changed it (but has the same player UID)
 758                                         if(e.netname != self.netname)
 759                                         {
 760                                                 if(e.netname)   strunzone(e.netname);
 761                                                 e.netname = strzone(self.netname);
 762                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 763                                         }
 764
 765                                         if(e.crypto_idfp == self.crypto_idfp)
 766                                         {
 767                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 768                                                 return true;
 769                                         }
 770
 771                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 772                                         e.crypto_idfp = strzone(self.crypto_idfp);
 773
 774                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 775                                 }
 776                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 777                                 return true;
 778
 779                         // ---------------- COMMAND: OBJECT, INFO ----------------
 780                         case "object_info":
 781                                 // prints public information about the object to the player
 782                                 e = sandbox_ObjectEdit_Get(false);
 783                                 if(e != world)
 784                                 {
 785                                         switch(argv(2))
 786                                         {
 787                                                 case "object":
 788                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 789                                                         return true;
 790                                                 case "mesh":
 791                                                         s = "";
 792                                                         FOR_EACH_TAG(e)
 793                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 794                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 795                                                         return true;
 796                                                 case "attachments":
 797                                                         // this should show the same info as 'mesh' but for attachments
 798                                                         s = "";
 799                                                         entity head;
 800                                                         i = 0;
 801                                                         for(head = world; (head = find(head, classname, "object")); )
 802                                                         {
 803                                                                 if(head.owner == e)
 804                                                                 {
 805                                                                         ++i; // start from 1
 806                                                                         gettaginfo(e, head.tag_index);
 807                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 808                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 809                                                                 }
 810                                                         }
 811                                                         if(i) // object contains attachments
 812                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 813                                                         else
 814                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 815                                                         return true;
 816                                         }
 817                                 }
 818                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 819                                 return true;
 820
 821                         // ---------------- COMMAND: DEFAULT ----------------
 822                         default:
 823                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 824                                 return true;
 825                 }
 826         }
 827         return false;
 828 }
 829
 830 MUTATOR_HOOKFUNCTION(sandbox, SV_StartFrame)
 831 {
 832         if(!autocvar_g_sandbox_storage_autosave)
 833                 return false;
 834         if(time < autosave_time)
 835                 return false;
 836         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 837
 838         sandbox_Database_Save();
 839
 840         return true;
 841 }
 842 #endif