qcsrc/common/mutators/mutator/sandbox/sv_sandbox.qc

   1 #include "sv_sandbox.qh"
   2
   3 string autocvar_g_sandbox;
   4 int autocvar_g_sandbox_info;
   5 bool autocvar_g_sandbox_readonly;
   6 string autocvar_g_sandbox_storage_name;
   7 float autocvar_g_sandbox_storage_autosave;
   8 bool autocvar_g_sandbox_storage_autoload;
   9 float autocvar_g_sandbox_editor_flood;
  10 int autocvar_g_sandbox_editor_maxobjects;
  11 int autocvar_g_sandbox_editor_free;
  12 float autocvar_g_sandbox_editor_distance_spawn;
  13 float autocvar_g_sandbox_editor_distance_edit;
  14 float autocvar_g_sandbox_object_scale_min;
  15 float autocvar_g_sandbox_object_scale_max;
  16 float autocvar_g_sandbox_object_material_velocity_min;
  17 float autocvar_g_sandbox_object_material_velocity_factor;
  18
  19 float autosave_time;
  20 void sandbox_Database_Load();
  21
  22 REGISTER_MUTATOR(sandbox, expr_evaluate(autocvar_g_sandbox))
  23 {
  24         MUTATOR_ONADD
  25         {
  26                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
  27                 if(autocvar_g_sandbox_storage_autoload)
  28                         sandbox_Database_Load();
  29         }
  30 }
  31
  32 const float MAX_STORAGE_ATTACHMENTS = 16;
  33 float object_count;
  34 .float object_flood;
  35 .entity object_attach;
  36 .string material;
  37
  38 .float touch_timer;
  39 void sandbox_ObjectFunction_Touch(entity this, entity toucher)
  40 {
  41         // apply material impact effects
  42
  43         if(!this.material)
  44                 return;
  45         if(this.touch_timer > time)
  46                 return; // don't execute each frame
  47         this.touch_timer = time + 0.1;
  48
  49         // make particle count and sound volume depend on impact speed
  50         float intensity;
  51         intensity = vlen(this.velocity) + vlen(toucher.velocity);
  52         if(intensity) // avoid divisions by 0
  53                 intensity /= 2; // average the two velocities
  54         if (!(intensity >= autocvar_g_sandbox_object_material_velocity_min))
  55                 return; // impact not strong enough to do anything
  56         // now offset intensity and apply it to the effects
  57         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  58         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  59
  60         _sound(this, CH_TRIGGER, strcat("object/impact_", this.material, "_", ftos(ceil(random() * 5)) , ".wav"), VOL_BASE * intensity, ATTEN_NORM);
  61         Send_Effect_(strcat("impact_", this.material), this.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  62 }
  63
  64 void sandbox_ObjectFunction_Think(entity this)
  65 {
  66         // decide if and how this object can be grabbed
  67         if(autocvar_g_sandbox_readonly)
  68                 this.grab = 0; // no grabbing
  69         else if(autocvar_g_sandbox_editor_free < 2 && this.crypto_idfp)
  70                 this.grab = 1; // owner only
  71         else
  72                 this.grab = 3; // anyone
  73
  74         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  75         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  76         // since if the owning player disconnects, the object's owner should also be reset.
  77
  78         // bots can't have objects
  79         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
  80                 if(this.crypto_idfp == it.crypto_idfp)
  81                 {
  82                         this.realowner = it;
  83                         break;
  84                 }
  85                 this.realowner = NULL;
  86         });
  87
  88         this.nextthink = time;
  89
  90         CSQCMODEL_AUTOUPDATE(this);
  91 }
  92
  93 .float old_solid, old_movetype;
  94 entity sandbox_ObjectEdit_Get(entity this, float permissions)
  95 {
  96         // Returns the traced entity if the player can edit it, and NULL if not.
  97         // If permissions if false, the object is returned regardless of editing rights.
  98         // Attached objects are SOLID_NOT and do not get traced.
  99
 100         crosshair_trace_plusvisibletriggers(this);
 101         if(vdist(this.origin - trace_ent.origin, >, autocvar_g_sandbox_editor_distance_edit))
 102                 return NULL; // out of trace range
 103         if(trace_ent.classname != "object")
 104                 return NULL; // entity is not an object
 105         if(!permissions)
 106                 return trace_ent; // don't check permissions, anyone can edit this object
 107         if(trace_ent.crypto_idfp == "")
 108                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
 109         if (!(trace_ent.realowner != this && autocvar_g_sandbox_editor_free < 2))
 110                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
 111         return NULL;
 112 }
 113
 114 void sandbox_ObjectEdit_Scale(entity e, float f)
 115 {
 116         e.scale = f;
 117         if(e.scale)
 118         {
 119                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
 120                 _setmodel(e, e.model); // reset mins and maxs based on mesh
 121                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
 122         }
 123 }
 124
 125 void sandbox_ObjectAttach_Remove(entity e);
 126 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
 127 {
 128         // attaches e to parent on string s
 129
 130         // we can't attach to an attachment, for obvious reasons
 131         sandbox_ObjectAttach_Remove(e);
 132
 133         e.old_solid = e.solid; // persist solidity
 134         e.old_movetype = e.move_movetype; // persist physics
 135         set_movetype(e, MOVETYPE_FOLLOW);
 136         e.solid = SOLID_NOT;
 137         e.takedamage = DAMAGE_NO;
 138
 139         setattachment(e, parent, s);
 140         e.owner = parent;
 141 }
 142
 143 void sandbox_ObjectAttach_Remove(entity e)
 144 {
 145         // detaches any object attached to e
 146
 147         IL_EACH(g_sandbox_objects, it.owner == e,
 148         {
 149                 vector org = gettaginfo(it, 0);
 150                 setattachment(it, NULL, "");
 151                 it.owner = NULL;
 152
 153                 // objects change origin and angles when detached, so apply previous position
 154                 setorigin(it, org);
 155                 it.angles = e.angles; // don't allow detached objects to spin or roll
 156
 157                 it.solid = it.old_solid; // restore persisted solidity
 158                 set_movetype(it, it.old_movetype); // restore persisted physics
 159                 it.takedamage = DAMAGE_AIM;
 160         });
 161 }
 162
 163 entity sandbox_ObjectSpawn(entity this, float database)
 164 {
 165         // spawn a new object with default properties
 166
 167         entity e = new(object);
 168         IL_PUSH(g_sandbox_objects, e);
 169         e.takedamage = DAMAGE_AIM;
 170         e.damageforcescale = 1;
 171         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 172         set_movetype(e, MOVETYPE_TOSS);
 173         e.frame = 0;
 174         e.skin = 0;
 175         e.material = string_null;
 176         settouch(e, sandbox_ObjectFunction_Touch);
 177         setthink(e, sandbox_ObjectFunction_Think);
 178         e.nextthink = time;
 179         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 180
 181         if(!database)
 182         {
 183                 // set the object's owner via player UID
 184                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 185                 if(this.crypto_idfp != "")
 186                         e.crypto_idfp = strzone(this.crypto_idfp);
 187                 else
 188                         print_to(this, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 189
 190                 // set public object information
 191                 e.netname = strzone(this.netname); // name of the owner
 192                 e.message = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // creation time
 193                 e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // last editing time
 194
 195                 // set origin and direction based on player position and view angle
 196                 makevectors(this.v_angle);
 197                 WarpZone_TraceLine(this.origin + this.view_ofs, this.origin + this.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, this);
 198                 setorigin(e, trace_endpos);
 199                 e.angles_y = this.v_angle.y;
 200         }
 201
 202         CSQCMODEL_AUTOINIT(e);
 203
 204         object_count += 1;
 205         return e;
 206 }
 207
 208 void sandbox_ObjectRemove(entity e)
 209 {
 210         sandbox_ObjectAttach_Remove(e); // detach child objects
 211
 212         // if the object being removed has been selected for attachment by a player, unset it
 213         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it.object_attach == e, { it.object_attach = NULL; });
 214
 215         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 216         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 217         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 218         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 219         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 220         delete(e);
 221         e = NULL;
 222
 223         object_count -= 1;
 224 }
 225
 226 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 227
 228 string sandbox_ObjectPort_Save(entity e, bool database)
 229 {
 230         // save object properties, and return them as a string
 231         int o = 0;
 232
 233         // order doesn't really matter, as we're writing the file fresh
 234         IL_EACH(g_sandbox_objects, it == e || it.owner == e, LAMBDA(
 235                 // the main object needs to be first in the array [0] with attached objects following
 236                 int slot, physics, solidity;
 237                 if(it == e) // this is the main object, place it first
 238                 {
 239                         slot = 0;
 240                         solidity = it.solid; // applied solidity is normal solidity for children
 241                         physics = it.move_movetype; // applied physics are normal physics for parents
 242                 }
 243                 else if(it.owner == e) // child object, list them in order
 244                 {
 245                         o += 1; // children start from 1
 246                         slot = o;
 247                         solidity = it.old_solid; // persisted solidity is normal solidity for children
 248                         physics = it.old_movetype; // persisted physics are normal physics for children
 249                         gettaginfo(it.owner, it.tag_index); // get the name of the tag our object is attached to, used further below
 250                 }
 251                 else
 252                         continue;
 253
 254                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 255                 if(slot)
 256                 {
 257                         // properties stored only for child objects
 258                         if(gettaginfo_name)
 259                                 port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");
 260                         else
 261                                 port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 262                 }
 263                 else
 264                 {
 265                         // properties stored only for parent objects
 266                         if(database)
 267                         {
 268                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", it.origin), " ");
 269                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", it.angles), " ");
 270                         }
 271                 }
 272                 // properties stored for all objects
 273                 port_string[slot] = strcat(port_string[slot], "\"", it.model, "\" ");
 274                 port_string[slot] = strcat(port_string[slot], ftos(it.skin), " ");
 275                 port_string[slot] = strcat(port_string[slot], ftos(it.alpha), " ");
 276                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", it.colormod), " ");
 277                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", it.glowmod), " ");
 278                 port_string[slot] = strcat(port_string[slot], ftos(it.frame), " ");
 279                 port_string[slot] = strcat(port_string[slot], ftos(it.scale), " ");
 280                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
 281                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 282                 port_string[slot] = strcat(port_string[slot], ftos(it.damageforcescale), " ");
 283                 if(it.material)
 284                         port_string[slot] = strcat(port_string[slot], "\"", it.material, "\" ");
 285                 else
 286                         port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 287                 if(database)
 288                 {
 289                         // properties stored only for the database
 290                         if(it.crypto_idfp)
 291                                 port_string[slot] = strcat(port_string[slot], "\"", it.crypto_idfp, "\" ");
 292                         else
 293                                 port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 294                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 295                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 296                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 297                 }
 298         ));
 299
 300         // now apply the array to a simple string, with the ; symbol separating objects
 301         string s = "";
 302         for(int j = 0; j <= MAX_STORAGE_ATTACHMENTS; ++j)
 303         {
 304                 if(port_string[j])
 305                         s = strcat(s, port_string[j], "; ");
 306                 port_string[j] = string_null; // fully clear the string
 307         }
 308
 309         return s;
 310 }
 311
 312 entity sandbox_ObjectPort_Load(entity this, string s, float database)
 313 {
 314         // load object properties, and spawn a new object with them
 315         float n, i;
 316         entity e = NULL, parent = NULL;
 317
 318         // separate objects between the ; symbols
 319         n = tokenizebyseparator(s, "; ");
 320         for(i = 0; i < n; ++i)
 321                 port_string[i] = argv(i);
 322
 323         // now separate and apply the properties of each object
 324         for(i = 0; i < n; ++i)
 325         {
 326                 float argv_num;
 327                 string tagname = string_null;
 328                 argv_num = 0;
 329                 tokenize_console(port_string[i]);
 330                 e = sandbox_ObjectSpawn(this, database);
 331
 332                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 333                 if(i)
 334                 {
 335                         // properties stored only for child objects
 336                         if(argv(argv_num) != "")        tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 337                 }
 338                 else
 339                 {
 340                         // properties stored only for parent objects
 341                         if(database)
 342                         {
 343                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 344                                 e.angles = stov(argv(argv_num));        ++argv_num;
 345                         }
 346                         parent = e; // mark parent objects as such
 347                 }
 348                 // properties stored for all objects
 349                 _setmodel(e, argv(argv_num));   ++argv_num;
 350                 e.skin = stof(argv(argv_num));  ++argv_num;
 351                 e.alpha = stof(argv(argv_num)); ++argv_num;
 352                 e.colormod = stov(argv(argv_num));      ++argv_num;
 353                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 354                 e.frame = stof(argv(argv_num)); ++argv_num;
 355                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 356                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
 357                 e.old_movetype = stof(argv(argv_num));  ++argv_num;
 358                 set_movetype(e, e.old_movetype);
 359                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 360                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "")        e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 361                 if(database)
 362                 {
 363                         // properties stored only for the database
 364                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "")        e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 365                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 366                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 367                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 368                 }
 369
 370                 // attach last
 371                 if(i)
 372                         sandbox_ObjectAttach_Set(e, parent, tagname);
 373         }
 374
 375         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 376                 port_string[i] = string_null; // fully clear the string
 377
 378         return e;
 379 }
 380
 381 void sandbox_Database_Save()
 382 {
 383         // saves all objects to the database file
 384         string file_name;
 385         float file_get;
 386
 387         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 388         file_get = fopen(file_name, FILE_WRITE);
 389         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S")));
 390         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 391
 392         IL_EACH(g_sandbox_objects, !it.owner, // attached objects are persisted separately, ignore them here
 393         {
 394                 // use a line of text for each object, listing all properties
 395                 fputs(file_get, strcat(sandbox_ObjectPort_Save(it, true), "\n"));
 396         });
 397         fclose(file_get);
 398 }
 399
 400 void sandbox_Database_Load()
 401 {
 402         // loads all objects from the database file
 403         string file_read, file_name;
 404         float file_get, i;
 405
 406         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 407         file_get = fopen(file_name, FILE_READ);
 408         if(file_get < 0)
 409         {
 410                 if(autocvar_g_sandbox_info > 0)
 411                         LOG_INFO("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded");
 412         }
 413         else
 414         {
 415                 for (;;)
 416                 {
 417                         file_read = fgets(file_get);
 418                         if(file_read == "")
 419                                 break;
 420                         if(substring(file_read, 0, 2) == "//")
 421                                 continue;
 422                         if(substring(file_read, 0, 1) == "#")
 423                                 continue;
 424
 425                         entity e;
 426                         e = sandbox_ObjectPort_Load(NULL, file_read, true);
 427
 428                         if(e.material)
 429                         {
 430                                 // since objects are being loaded for the first time, precache material sounds for each
 431                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 432                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".wav"));
 433                         }
 434                 }
 435                 if(autocvar_g_sandbox_info > 0)
 436                         LOG_INFO("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name);
 437         }
 438         fclose(file_get);
 439 }
 440
 441 MUTATOR_HOOKFUNCTION(sandbox, SV_ParseClientCommand)
 442 {
 443         if(MUTATOR_RETURNVALUE) // command was already handled?
 444                 return;
 445
 446         entity player = M_ARGV(0, entity);
 447         string cmd_name = M_ARGV(1, string);
 448         int cmd_argc = M_ARGV(2, int);
 449
 450         if(cmd_name == "g_sandbox")
 451         {
 452                 if(autocvar_g_sandbox_readonly)
 453                 {
 454                         print_to(player, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 455                         return true;
 456                 }
 457                 if(cmd_argc < 2)
 458                 {
 459                         print_to(player, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 460                         return true;
 461                 }
 462
 463                 switch(argv(1))
 464                 {
 465                         entity e;
 466                         int j;
 467                         string s;
 468
 469                         // ---------------- COMMAND: HELP ----------------
 470                         case "help":
 471                                 print_to(player, "You can use the following sandbox commands:");
 472                                 print_to(player, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 473                                 print_to(player, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 474                                 print_to(player, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 475                                 print_to(player, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 476                                 print_to(player, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 477                                 print_to(player, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 478                                 print_to(player, "^3get ^7- selects the object you are facing as the object to be attached");
 479                                 print_to(player, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 480                                 print_to(player, "^3remove ^7- detaches all objects from the object you are facing");
 481                                 print_to(player, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 482                                 print_to(player, "^3skin value ^7- changes the skin of the object");
 483                                 print_to(player, "^3alpha value ^7- sets object transparency");
 484                                 print_to(player, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 485                                 print_to(player, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 486                                 print_to(player, "^3frame value ^7- object animation frame, for self-animated models");
 487                                 print_to(player, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 488                                 print_to(player, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
 489                                 print_to(player, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 490                                 print_to(player, "^3force value ^7- amount of force applied to objects that are shot");
 491                                 print_to(player, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 492                                 print_to(player, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 493                                 print_to(player, "^7\"^2object_info ^3value^7\" shows public information about the object");
 494                                 print_to(player, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 495                                 print_to(player, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 496                                 print_to(player, "^3attachments ^7- prints information about the object's attachments");
 497                                 print_to(player, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 498                                 return true;
 499
 500                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 501                         case "object_spawn":
 502                                 if(time < player.object_flood)
 503                                 {
 504                                         print_to(player, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(player.object_flood - time), " ^7seconds beofore spawning another object"));
 505                                         return true;
 506                                 }
 507                                 player.object_flood = time + autocvar_g_sandbox_editor_flood;
 508                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 509                                 {
 510                                         print_to(player, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 511                                         return true;
 512                                 }
 513                                 if(cmd_argc < 3)
 514                                 {
 515                                         print_to(player, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 516                                         return true;
 517                                 }
 518                                 if (!(fexists(argv(2))))
 519                                 {
 520                                         print_to(player, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 521                                         return true;
 522                                 }
 523
 524                                 e = sandbox_ObjectSpawn(player, false);
 525                                 _setmodel(e, argv(2));
 526
 527                                 if(autocvar_g_sandbox_info > 0)
 528                                         LOG_INFO("^3SANDBOX - SERVER: ^7", player.netname, " spawned an object at origin ^3", vtos(e.origin));
 529                                 return true;
 530
 531                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 532                         case "object_remove":
 533                                 e = sandbox_ObjectEdit_Get(player, true);
 534                                 if(e != NULL)
 535                                 {
 536                                         if(autocvar_g_sandbox_info > 0)
 537                                                 LOG_INFO("^3SANDBOX - SERVER: ^7", player.netname, " removed an object at origin ^3", vtos(e.origin));
 538                                         sandbox_ObjectRemove(e);
 539                                         return true;
 540                                 }
 541
 542                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 543                                 return true;
 544
 545                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 546                         case "object_duplicate":
 547                                 switch(argv(2))
 548                                 {
 549                                         case "copy":
 550                                                 // copies customizable properties of the selected object to the clipboard cvar
 551                                                 e = sandbox_ObjectEdit_Get(player, autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 552                                                 if(e != NULL)
 553                                                 {
 554                                                         s = sandbox_ObjectPort_Save(e, false);
 555                                                         s = strreplace("\"", "\\\"", s);
 556                                                         stuffcmd(player, strcat("set ", argv(3), " \"", s, "\""));
 557
 558                                                         print_to(player, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 559                                                         return true;
 560                                                 }
 561                                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 562                                                 return true;
 563
 564                                         case "paste":
 565                                                 // spawns a new object using the properties in the player's clipboard cvar
 566                                                 if(time < player.object_flood)
 567                                                 {
 568                                                         print_to(player, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(player.object_flood - time), " ^7seconds beofore spawning another object"));
 569                                                         return true;
 570                                                 }
 571                                                 player.object_flood = time + autocvar_g_sandbox_editor_flood;
 572                                                 if(argv(3) == "") // no object in clipboard
 573                                                 {
 574                                                         print_to(player, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 575                                                         return true;
 576                                                 }
 577                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 578                                                 {
 579                                                         print_to(player, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 580                                                         return true;
 581                                                 }
 582                                                 e = sandbox_ObjectPort_Load(player, argv(3), false);
 583
 584                                                 print_to(player, "^2SANDBOX - INFO: ^7Object pasted successfully");
 585                                                 if(autocvar_g_sandbox_info > 0)
 586                                                         LOG_INFO("^3SANDBOX - SERVER: ^7", player.netname, " pasted an object at origin ^3", vtos(e.origin));
 587                                                 return true;
 588                                 }
 589                                 return true;
 590
 591                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 592                         case "object_attach":
 593                                 switch(argv(2))
 594                                 {
 595                                         case "get":
 596                                                 // select e as the object as meant to be attached
 597                                                 e = sandbox_ObjectEdit_Get(player, true);
 598                                                 if(e != NULL)
 599                                                 {
 600                                                         player.object_attach = e;
 601                                                         print_to(player, "^2SANDBOX - INFO: ^7Object selected for attachment");
 602                                                         return true;
 603                                                 }
 604                                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 605                                                 return true;
 606                                         case "set":
 607                                                 if(player.object_attach == NULL)
 608                                                 {
 609                                                         print_to(player, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 610                                                         return true;
 611                                                 }
 612
 613                                                 // attaches the previously selected object to e
 614                                                 e = sandbox_ObjectEdit_Get(player, true);
 615                                                 if(e != NULL)
 616                                                 {
 617                                                         sandbox_ObjectAttach_Set(player.object_attach, e, argv(3));
 618                                                         player.object_attach = NULL; // object was attached, no longer keep it scheduled for attachment
 619                                                         print_to(player, "^2SANDBOX - INFO: ^7Object attached successfully");
 620                                                         if(autocvar_g_sandbox_info > 1)
 621                                                                 LOG_INFO("^3SANDBOX - SERVER: ^7", player.netname, " attached objects at origin ^3", vtos(e.origin));
 622                                                         return true;
 623                                                 }
 624                                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 625                                                 return true;
 626                                         case "remove":
 627                                                 // removes e if it was attached
 628                                                 e = sandbox_ObjectEdit_Get(player, true);
 629                                                 if(e != NULL)
 630                                                 {
 631                                                         sandbox_ObjectAttach_Remove(e);
 632                                                         print_to(player, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 633                                                         if(autocvar_g_sandbox_info > 1)
 634                                                                 LOG_INFO("^3SANDBOX - SERVER: ^7", player.netname, " detached objects at origin ^3", vtos(e.origin));
 635                                                         return true;
 636                                                 }
 637                                                 print_to(player, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 638                                                 return true;
 639                                 }
 640                                 return true;
 641
 642                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 643                         case "object_edit":
 644                                 if(argv(2) == "")
 645                                 {
 646                                         print_to(player, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 647                                         return true;
 648                                 }
 649
 650                                 e = sandbox_ObjectEdit_Get(player, true);
 651                                 if(e != NULL)
 652                                 {
 653                                         switch(argv(2))
 654                                         {
 655                                                 case "skin":
 656                                                         e.skin = stof(argv(3));
 657                                                         break;
 658                                                 case "alpha":
 659                                                         e.alpha = stof(argv(3));
 660                                                         break;
 661                                                 case "color_main":
 662                                                         e.colormod = stov(argv(3));
 663                                                         break;
 664                                                 case "color_glow":
 665                                                         e.glowmod = stov(argv(3));
 666                                                         break;
 667                                                 case "frame":
 668                                                         e.frame = stof(argv(3));
 669                                                         break;
 670                                                 case "scale":
 671                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 672                                                         break;
 673                                                 case "solidity":
 674                                                         switch(argv(3))
 675                                                         {
 676                                                                 case "0": // non-solid
 677                                                                         e.solid = SOLID_TRIGGER;
 678                                                                         break;
 679                                                                 case "1": // solid
 680                                                                         e.solid = SOLID_BBOX;
 681                                                                         break;
 682                                                                 default:
 683                                                                         break;
 684                                                         }
 685                                                 case "physics":
 686                                                         switch(argv(3))
 687                                                         {
 688                                                                 case "0": // static
 689                                                                         set_movetype(e, MOVETYPE_NONE);
 690                                                                         break;
 691                                                                 case "1": // movable
 692                                                                         set_movetype(e, MOVETYPE_TOSS);
 693                                                                         break;
 694                                                                 case "2": // physical
 695                                                                         set_movetype(e, MOVETYPE_PHYSICS);
 696                                                                         break;
 697                                                                 default:
 698                                                                         break;
 699                                                         }
 700                                                         break;
 701                                                 case "force":
 702                                                         e.damageforcescale = stof(argv(3));
 703                                                         break;
 704                                                 case "material":
 705                                                         if(e.material)  strunzone(e.material);
 706                                                         if(argv(3))
 707                                                         {
 708                                                                 for (j = 1; j <= 5; j++) // precache material sounds, 5 in total
 709                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(j), ".wav"));
 710                                                                 e.material = strzone(argv(3));
 711                                                         }
 712                                                         else
 713                                                                 e.material = string_null; // no material
 714                                                         break;
 715                                                 default:
 716                                                         print_to(player, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 717                                                         return true;
 718                                         }
 719
 720                                         // update last editing time
 721                                         if(e.message2)  strunzone(e.message2);
 722                                         e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S"));
 723
 724                                         if(autocvar_g_sandbox_info > 1)
 725                                                 LOG_INFO("^3SANDBOX - SERVER: ^7", player.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin));
 726                                         return true;
 727                                 }
 728
 729                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 730                                 return true;
 731
 732                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 733                         case "object_claim":
 734                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 735                                 if(player.crypto_idfp == "")
 736                                 {
 737                                         print_to(player, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 738                                         return true;
 739                                 }
 740                                 e = sandbox_ObjectEdit_Get(player, true);
 741                                 if(e != NULL)
 742                                 {
 743                                         // update the owner's name
 744                                         // Do this before checking if you're already the owner and skipping if such, so we
 745                                         // also update the player's nickname if he changed it (but has the same player UID)
 746                                         if(e.netname != player.netname)
 747                                         {
 748                                                 if(e.netname)   strunzone(e.netname);
 749                                                 e.netname = strzone(player.netname);
 750                                                 print_to(player, "^2SANDBOX - INFO: ^7Object owner name updated");
 751                                         }
 752
 753                                         if(e.crypto_idfp == player.crypto_idfp)
 754                                         {
 755                                                 print_to(player, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 756                                                 return true;
 757                                         }
 758
 759                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 760                                         e.crypto_idfp = strzone(player.crypto_idfp);
 761
 762                                         print_to(player, "^2SANDBOX - INFO: ^7Object claimed successfully");
 763                                 }
 764                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 765                                 return true;
 766
 767                         // ---------------- COMMAND: OBJECT, INFO ----------------
 768                         case "object_info":
 769                                 // prints public information about the object to the player
 770                                 e = sandbox_ObjectEdit_Get(player, false);
 771                                 if(e != NULL)
 772                                 {
 773                                         switch(argv(2))
 774                                         {
 775                                                 case "object":
 776                                                         print_to(player, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 777                                                         return true;
 778                                                 case "mesh":
 779                                                         s = "";
 780                                                         FOR_EACH_TAG(e)
 781                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 782                                                         print_to(player, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 783                                                         return true;
 784                                                 case "attachments":
 785                                                         // this should show the same info as 'mesh' but for attachments
 786                                                         s = "";
 787                                                         j = 0;
 788                                                         IL_EACH(g_sandbox_objects, it.owner == e,
 789                                                         {
 790                                                                 ++j; // start from 1
 791                                                                 gettaginfo(e, it.tag_index);
 792                                                                 s = strcat(s, "^1attachment ", ftos(j), "^7 has mesh \"^3", it.model, "^7\" at animation frame ^3", ftos(it.frame));
 793                                                                 s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 794                                                         });
 795                                                         if(j) // object contains attachments
 796                                                                 print_to(player, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(j), "^7 attachment(s): ", s));
 797                                                         else
 798                                                                 print_to(player, "^2SANDBOX - INFO: ^7Object contains no attachments");
 799                                                         return true;
 800                                         }
 801                                 }
 802                                 print_to(player, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 803                                 return true;
 804
 805                         // ---------------- COMMAND: DEFAULT ----------------
 806                         default:
 807                                 print_to(player, "Invalid command. For usage information, type 'sandbox help'");
 808                                 return true;
 809                 }
 810         }
 811 }
 812
 813 MUTATOR_HOOKFUNCTION(sandbox, SV_StartFrame)
 814 {
 815         if(!autocvar_g_sandbox_storage_autosave)
 816                 return;
 817         if(time < autosave_time)
 818                 return;
 819         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 820
 821         sandbox_Database_Save();
 822
 823         return true;
 824 }