qcsrc/common/mutators/mutator/sandbox/sv_sandbox.qc

   1 #include "sv_sandbox.qh"
   2
   3 string autocvar_g_sandbox;
   4 int autocvar_g_sandbox_info;
   5 bool autocvar_g_sandbox_readonly;
   6 string autocvar_g_sandbox_storage_name;
   7 float autocvar_g_sandbox_storage_autosave;
   8 bool autocvar_g_sandbox_storage_autoload;
   9 float autocvar_g_sandbox_editor_flood;
  10 int autocvar_g_sandbox_editor_maxobjects;
  11 int autocvar_g_sandbox_editor_free;
  12 float autocvar_g_sandbox_editor_distance_spawn;
  13 float autocvar_g_sandbox_editor_distance_edit;
  14 float autocvar_g_sandbox_object_scale_min;
  15 float autocvar_g_sandbox_object_scale_max;
  16 float autocvar_g_sandbox_object_material_velocity_min;
  17 float autocvar_g_sandbox_object_material_velocity_factor;
  18
  19 float autosave_time;
  20 void sandbox_Database_Load();
  21
  22 REGISTER_MUTATOR(sandbox, expr_evaluate(autocvar_g_sandbox))
  23 {
  24         MUTATOR_ONADD
  25         {
  26                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
  27                 if(autocvar_g_sandbox_storage_autoload)
  28                         sandbox_Database_Load();
  29         }
  30 }
  31
  32 const float MAX_STORAGE_ATTACHMENTS = 16;
  33 float object_count;
  34 .float object_flood;
  35 .entity object_attach;
  36 .string material;
  37
  38 .float touch_timer;
  39 void sandbox_ObjectFunction_Touch(entity this, entity toucher)
  40 {
  41         // apply material impact effects
  42
  43         if(!this.material)
  44                 return;
  45         if(this.touch_timer > time)
  46                 return; // don't execute each frame
  47         this.touch_timer = time + 0.1;
  48
  49         // make particle count and sound volume depend on impact speed
  50         float intensity;
  51         intensity = vlen(this.velocity) + vlen(toucher.velocity);
  52         if(intensity) // avoid divisions by 0
  53                 intensity /= 2; // average the two velocities
  54         if (!(intensity >= autocvar_g_sandbox_object_material_velocity_min))
  55                 return; // impact not strong enough to do anything
  56         // now offset intensity and apply it to the effects
  57         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  58         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  59
  60         _sound(this, CH_TRIGGER, strcat("object/impact_", this.material, "_", ftos(ceil(random() * 5)) , ".wav"), VOL_BASE * intensity, ATTEN_NORM);
  61         Send_Effect_(strcat("impact_", this.material), this.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  62 }
  63
  64 void sandbox_ObjectFunction_Think(entity this)
  65 {
  66         // decide if and how this object can be grabbed
  67         if(autocvar_g_sandbox_readonly)
  68                 this.grab = 0; // no grabbing
  69         else if(autocvar_g_sandbox_editor_free < 2 && this.crypto_idfp)
  70                 this.grab = 1; // owner only
  71         else
  72                 this.grab = 3; // anyone
  73
  74         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  75         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  76         // since if the owning player disconnects, the object's owner should also be reset.
  77
  78         // bots can't have objects
  79         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
  80                 if(this.crypto_idfp == it.crypto_idfp)
  81                 {
  82                         this.realowner = it;
  83                         break;
  84                 }
  85                 this.realowner = NULL;
  86         });
  87
  88         this.nextthink = time;
  89
  90         CSQCMODEL_AUTOUPDATE(this);
  91 }
  92
  93 .float old_solid, old_movetype;
  94 entity sandbox_ObjectEdit_Get(entity this, float permissions)
  95 {
  96         // Returns the traced entity if the player can edit it, and NULL if not.
  97         // If permissions if false, the object is returned regardless of editing rights.
  98         // Attached objects are SOLID_NOT and do not get traced.
  99
 100         crosshair_trace_plusvisibletriggers(this);
 101         if(vdist(this.origin - trace_ent.origin, >, autocvar_g_sandbox_editor_distance_edit))
 102                 return NULL; // out of trace range
 103         if(trace_ent.classname != "object")
 104                 return NULL; // entity is not an object
 105         if(!permissions)
 106                 return trace_ent; // don't check permissions, anyone can edit this object
 107         if(trace_ent.crypto_idfp == "")
 108                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
 109         if (!(trace_ent.realowner != this && autocvar_g_sandbox_editor_free < 2))
 110                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
 111         return NULL;
 112 }
 113
 114 void sandbox_ObjectEdit_Scale(entity e, float f)
 115 {
 116         e.scale = f;
 117         if(e.scale)
 118         {
 119                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
 120                 _setmodel(e, e.model); // reset mins and maxs based on mesh
 121                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
 122         }
 123 }
 124
 125 void sandbox_ObjectAttach_Remove(entity e);
 126 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
 127 {
 128         // attaches e to parent on string s
 129
 130         // we can't attach to an attachment, for obvious reasons
 131         sandbox_ObjectAttach_Remove(e);
 132
 133         e.old_solid = e.solid; // persist solidity
 134         e.old_movetype = e.move_movetype; // persist physics
 135         set_movetype(e, MOVETYPE_FOLLOW);
 136         e.solid = SOLID_NOT;
 137         e.takedamage = DAMAGE_NO;
 138
 139         setattachment(e, parent, s);
 140         e.owner = parent;
 141 }
 142
 143 void sandbox_ObjectAttach_Remove(entity e)
 144 {
 145         // detaches any object attached to e
 146
 147         IL_EACH(g_sandbox_objects, it.owner == e,
 148         {
 149                 vector org = gettaginfo(it, 0);
 150                 setattachment(it, NULL, "");
 151                 it.owner = NULL;
 152
 153                 // objects change origin and angles when detached, so apply previous position
 154                 setorigin(it, org);
 155                 it.angles = e.angles; // don't allow detached objects to spin or roll
 156
 157                 it.solid = it.old_solid; // restore persisted solidity
 158                 set_movetype(it, it.old_movetype); // restore persisted physics
 159                 it.takedamage = DAMAGE_AIM;
 160         });
 161 }
 162
 163 entity sandbox_ObjectSpawn(entity this, float database)
 164 {
 165         // spawn a new object with default properties
 166
 167         entity e = new(object);
 168         IL_PUSH(g_sandbox_objects, e);
 169         e.takedamage = DAMAGE_AIM;
 170         e.damageforcescale = 1;
 171         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 172         set_movetype(e, MOVETYPE_TOSS);
 173         e.frame = 0;
 174         e.skin = 0;
 175         e.material = string_null;
 176         settouch(e, sandbox_ObjectFunction_Touch);
 177         setthink(e, sandbox_ObjectFunction_Think);
 178         e.nextthink = time;
 179         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 180
 181         if(!database)
 182         {
 183                 // set the object's owner via player UID
 184                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 185                 if(this.crypto_idfp != "")
 186                         e.crypto_idfp = strzone(this.crypto_idfp);
 187                 else
 188                         print_to(this, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 189
 190                 // set public object information
 191                 e.netname = strzone(this.netname); // name of the owner
 192                 e.message = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // creation time
 193                 e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // last editing time
 194
 195                 // set origin and direction based on player position and view angle
 196                 makevectors(this.v_angle);
 197                 WarpZone_TraceLine(this.origin + this.view_ofs, this.origin + this.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, this);
 198                 setorigin(e, trace_endpos);
 199                 e.angles_y = this.v_angle.y;
 200         }
 201
 202         CSQCMODEL_AUTOINIT(e);
 203
 204         object_count += 1;
 205         return e;
 206 }
 207
 208 void sandbox_ObjectRemove(entity e)
 209 {
 210         sandbox_ObjectAttach_Remove(e); // detach child objects
 211
 212         // if the object being removed has been selected for attachment by a player, unset it
 213         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it.object_attach == e, { it.object_attach = NULL; });
 214
 215         strfree(e.material);
 216         strfree(e.crypto_idfp);
 217         strfree(e.netname);
 218         strfree(e.message);
 219         strfree(e.message2);
 220         delete(e);
 221         e = NULL;
 222
 223         object_count -= 1;
 224 }
 225
 226 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 227
 228 string sandbox_ObjectPort_Save(entity e, bool database)
 229 {
 230         // save object properties, and return them as a string
 231         int o = 0;
 232
 233         // order doesn't really matter, as we're writing the file fresh
 234         IL_EACH(g_sandbox_objects, it == e || it.owner == e, LAMBDA(
 235                 // the main object needs to be first in the array [0] with attached objects following
 236                 int slot, physics, solidity;
 237                 if(it == e) // this is the main object, place it first
 238                 {
 239                         slot = 0;
 240                         solidity = it.solid; // applied solidity is normal solidity for children
 241                         physics = it.move_movetype; // applied physics are normal physics for parents
 242                 }
 243                 else if(it.owner == e) // child object, list them in order
 244                 {
 245                         o += 1; // children start from 1
 246                         slot = o;
 247                         solidity = it.old_solid; // persisted solidity is normal solidity for children
 248                         physics = it.old_movetype; // persisted physics are normal physics for children
 249                         gettaginfo(it.owner, it.tag_index); // get the name of the tag our object is attached to, used further below
 250                 }
 251                 else
 252                         continue;
 253
 254                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 255                 if(slot)
 256                 {
 257                         // properties stored only for child objects
 258                         if(gettaginfo_name)
 259                                 port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");
 260                         else
 261                                 port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 262                 }
 263                 else
 264                 {
 265                         // properties stored only for parent objects
 266                         if(database)
 267                         {
 268                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", it.origin), " ");
 269                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", it.angles), " ");
 270                         }
 271                 }
 272                 // properties stored for all objects
 273                 port_string[slot] = strcat(port_string[slot], "\"", it.model, "\" ");
 274                 port_string[slot] = strcat(port_string[slot], ftos(it.skin), " ");
 275                 port_string[slot] = strcat(port_string[slot], ftos(it.alpha), " ");
 276                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", it.colormod), " ");
 277                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", it.glowmod), " ");
 278                 port_string[slot] = strcat(port_string[slot], ftos(it.frame), " ");
 279                 port_string[slot] = strcat(port_string[slot], ftos(it.scale), " ");
 280                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
 281                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 282                 port_string[slot] = strcat(port_string[slot], ftos(it.damageforcescale), " ");
 283                 if(it.material)
 284                         port_string[slot] = strcat(port_string[slot], "\"", it.material, "\" ");
 285                 else
 286                         port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 287                 if(database)
 288                 {
 289                         // properties stored only for the database
 290                         if(it.crypto_idfp)
 291                                 port_string[slot] = strcat(port_string[slot], "\"", it.crypto_idfp, "\" ");
 292                         else
 293                                 port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 294                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 295                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 296                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 297                 }
 298         ));
 299
 300         // now apply the array to a simple string, with the ; symbol separating objects
 301         string s = "";
 302         for(int j = 0; j <= MAX_STORAGE_ATTACHMENTS; ++j)
 303         {
 304                 if(port_string[j])
 305                         s = strcat(s, port_string[j], "; ");
 306                 port_string[j] = string_null; // fully clear the string
 307         }
 308
 309         return s;
 310 }
 311
 312 entity sandbox_ObjectPort_Load(entity this, string s, float database)
 313 {
 314         // load object properties, and spawn a new object with them
 315         int n, i;
 316         entity e = NULL, parent = NULL;
 317         string arg = string_null;
 318
 319         // separate objects between the ; symbols
 320         n = tokenizebyseparator(s, "; ");
 321         for(i = 0; i < n; ++i)
 322                 port_string[i] = argv(i);
 323
 324         // now separate and apply the properties of each object
 325         for(i = 0; i < n; ++i)
 326         {
 327                 #define SANDBOX_GETARG arg = argv(++argv_num);
 328                 int argv_num = -1; // starts at -1 so I don't need postincrement
 329
 330                 string tagname = string_null;
 331                 tokenize_console(port_string[i]);
 332                 e = sandbox_ObjectSpawn(this, database);
 333
 334                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 335                 if(i)
 336                 {
 337                         // properties stored only for child objects
 338                         SANDBOX_GETARG; tagname = (arg != "") ? arg : string_null;
 339                 }
 340                 else
 341                 {
 342                         // properties stored only for parent objects
 343                         if(database)
 344                         {
 345                                 SANDBOX_GETARG; setorigin(e, stov(arg));
 346                                 SANDBOX_GETARG; e.angles = stov(arg);
 347                         }
 348                         parent = e; // mark parent objects as such
 349                 }
 350                 // properties stored for all objects
 351                 SANDBOX_GETARG; _setmodel(e, arg);
 352                 SANDBOX_GETARG; e.skin = stof(arg);
 353                 SANDBOX_GETARG; e.alpha = stof(arg);
 354                 SANDBOX_GETARG; e.colormod = stov(arg);
 355                 SANDBOX_GETARG; e.glowmod = stov(arg);
 356                 SANDBOX_GETARG; e.frame = stof(arg);
 357                 SANDBOX_GETARG; sandbox_ObjectEdit_Scale(e, stof(arg));
 358                 SANDBOX_GETARG; e.solid = e.old_solid = stof(arg);
 359                 SANDBOX_GETARG; e.old_movetype = stof(arg);
 360                 set_movetype(e, e.old_movetype);
 361                 SANDBOX_GETARG; e.damageforcescale = stof(arg);
 362                 strfree(e.material);
 363                 SANDBOX_GETARG; e.material = (arg != "") ? strzone(arg) : string_null;
 364                 if(database)
 365                 {
 366                         // properties stored only for the database
 367                         strfree(e.crypto_idfp);
 368                         SANDBOX_GETARG; e.crypto_idfp = (arg != "") ? strzone(arg) : string_null;
 369                         SANDBOX_GETARG; strcpy(e.netname, arg);
 370                         SANDBOX_GETARG; strcpy(e.message, arg);
 371                         SANDBOX_GETARG; strcpy(e.message2, arg);
 372                 }
 373
 374                 // attach last
 375                 if(i)
 376                         sandbox_ObjectAttach_Set(e, parent, tagname);
 377         }
 378
 379         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 380                 port_string[i] = string_null; // fully clear the string
 381
 382         return e;
 383 }
 384
 385 void sandbox_Database_Save()
 386 {
 387         // saves all objects to the database file
 388         string file_name;
 389         float file_get;
 390
 391         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 392         file_get = fopen(file_name, FILE_WRITE);
 393         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S")));
 394         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 395
 396         IL_EACH(g_sandbox_objects, !it.owner, // attached objects are persisted separately, ignore them here
 397         {
 398                 // use a line of text for each object, listing all properties
 399                 fputs(file_get, strcat(sandbox_ObjectPort_Save(it, true), "\n"));
 400         });
 401         fclose(file_get);
 402 }
 403
 404 void sandbox_Database_Load()
 405 {
 406         // loads all objects from the database file
 407         string file_read, file_name;
 408         float file_get, i;
 409
 410         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 411         file_get = fopen(file_name, FILE_READ);
 412         if(file_get < 0)
 413         {
 414                 if(autocvar_g_sandbox_info > 0)
 415                         LOG_INFO("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded");
 416         }
 417         else
 418         {
 419                 for (;;)
 420                 {
 421                         file_read = fgets(file_get);
 422                         if(file_read == "")
 423                                 break;
 424                         if(substring(file_read, 0, 2) == "//")
 425                                 continue;
 426                         if(substring(file_read, 0, 1) == "#")
 427                                 continue;
 428
 429                         entity e;
 430                         e = sandbox_ObjectPort_Load(NULL, file_read, true);
 431
 432                         if(e.material)
 433                         {
 434                                 // since objects are being loaded for the first time, precache material sounds for each
 435                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 436                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".wav"));
 437                         }
 438                 }
 439                 if(autocvar_g_sandbox_info > 0)
 440                         LOG_INFO("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name);
 441         }
 442         fclose(file_get);
 443 }
 444
 445 MUTATOR_HOOKFUNCTION(sandbox, SV_ParseClientCommand)
 446 {
 447         if(MUTATOR_RETURNVALUE) // command was already handled?
 448                 return;
 449
 450         entity player = M_ARGV(0, entity);
 451         string cmd_name = M_ARGV(1, string);
 452         int cmd_argc = M_ARGV(2, int);
 453
 454         if(cmd_name == "g_sandbox")
 455         {
 456                 if(autocvar_g_sandbox_readonly)
 457                 {
 458                         print_to(player, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 459                         return true;
 460                 }
 461                 if(cmd_argc < 2)
 462                 {
 463                         print_to(player, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 464                         return true;
 465                 }
 466
 467                 switch(argv(1))
 468                 {
 469                         entity e;
 470                         int j;
 471                         string s;
 472
 473                         // ---------------- COMMAND: HELP ----------------
 474                         case "help":
 475                                 print_to(player, "You can use the following sandbox commands:");
 476                                 print_to(player, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 477                                 print_to(player, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 478                                 print_to(player, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 479                                 print_to(player, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 480                                 print_to(player, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 481                                 print_to(player, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 482                                 print_to(player, "^3get ^7- selects the object you are facing as the object to be attached");
 483                                 print_to(player, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 484                                 print_to(player, "^3remove ^7- detaches all objects from the object you are facing");
 485                                 print_to(player, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 486                                 print_to(player, "^3skin value ^7- changes the skin of the object");
 487                                 print_to(player, "^3alpha value ^7- sets object transparency");
 488                                 print_to(player, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 489                                 print_to(player, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 490                                 print_to(player, "^3frame value ^7- object animation frame, for self-animated models");
 491                                 print_to(player, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 492                                 print_to(player, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
 493                                 print_to(player, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 494                                 print_to(player, "^3force value ^7- amount of force applied to objects that are shot");
 495                                 print_to(player, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 496                                 print_to(player, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 497                                 print_to(player, "^7\"^2object_info ^3value^7\" shows public information about the object");
 498                                 print_to(player, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 499                                 print_to(player, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 500                                 print_to(player, "^3attachments ^7- prints information about the object's attachments");
 501                                 print_to(player, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 502                                 return true;
 503
 504                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 505                         case "object_spawn":
 506                                 if(time < player.object_flood)
 507                                 {
 508                                         print_to(player, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(player.object_flood - time), " ^7seconds beofore spawning another object"));
 509                                         return true;
 510                                 }
 511                                 player.object_flood = time + autocvar_g_sandbox_editor_flood;
 512                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 513                                 {
 514                                         print_to(player, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 515                                         return true;
 516                                 }
 517                                 if(cmd_argc < 3)
 518                                 {
 519                                         print_to(player, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 520                                         return true;
 521                                 }
 522                                 if (!(fexists(argv(2))))
 523                                 {
 524                                         print_to(player, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 525                                         return true;
 526                                 }
 527
 528                                 e = sandbox_ObjectSpawn(player, false);
 529                                 _setmodel(e, argv(2));
 530
 531                                 if(autocvar_g_sandbox_info > 0)
 532                                         LOG_INFO("^3SANDBOX - SERVER: ^7", player.netname, " spawned an object at origin ^3", vtos(e.origin));
 533                                 return true;
 534
 535                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 536                         case "object_remove":
 537                                 e = sandbox_ObjectEdit_Get(player, true);
 538                                 if(e != NULL)
 539                                 {
 540                                         if(autocvar_g_sandbox_info > 0)
 541                                                 LOG_INFO("^3SANDBOX - SERVER: ^7", player.netname, " removed an object at origin ^3", vtos(e.origin));
 542                                         sandbox_ObjectRemove(e);
 543                                         return true;
 544                                 }
 545
 546                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 547                                 return true;
 548
 549                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 550                         case "object_duplicate":
 551                                 switch(argv(2))
 552                                 {
 553                                         case "copy":
 554                                                 // copies customizable properties of the selected object to the clipboard cvar
 555                                                 e = sandbox_ObjectEdit_Get(player, autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 556                                                 if(e != NULL)
 557                                                 {
 558                                                         s = sandbox_ObjectPort_Save(e, false);
 559                                                         s = strreplace("\"", "\\\"", s);
 560                                                         stuffcmd(player, strcat("set ", argv(3), " \"", s, "\""));
 561
 562                                                         print_to(player, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 563                                                         return true;
 564                                                 }
 565                                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 566                                                 return true;
 567
 568                                         case "paste":
 569                                                 // spawns a new object using the properties in the player's clipboard cvar
 570                                                 if(time < player.object_flood)
 571                                                 {
 572                                                         print_to(player, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(player.object_flood - time), " ^7seconds beofore spawning another object"));
 573                                                         return true;
 574                                                 }
 575                                                 player.object_flood = time + autocvar_g_sandbox_editor_flood;
 576                                                 if(argv(3) == "") // no object in clipboard
 577                                                 {
 578                                                         print_to(player, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 579                                                         return true;
 580                                                 }
 581                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 582                                                 {
 583                                                         print_to(player, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 584                                                         return true;
 585                                                 }
 586                                                 e = sandbox_ObjectPort_Load(player, argv(3), false);
 587
 588                                                 print_to(player, "^2SANDBOX - INFO: ^7Object pasted successfully");
 589                                                 if(autocvar_g_sandbox_info > 0)
 590                                                         LOG_INFO("^3SANDBOX - SERVER: ^7", player.netname, " pasted an object at origin ^3", vtos(e.origin));
 591                                                 return true;
 592                                 }
 593                                 return true;
 594
 595                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 596                         case "object_attach":
 597                                 switch(argv(2))
 598                                 {
 599                                         case "get":
 600                                                 // select e as the object as meant to be attached
 601                                                 e = sandbox_ObjectEdit_Get(player, true);
 602                                                 if(e != NULL)
 603                                                 {
 604                                                         player.object_attach = e;
 605                                                         print_to(player, "^2SANDBOX - INFO: ^7Object selected for attachment");
 606                                                         return true;
 607                                                 }
 608                                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 609                                                 return true;
 610                                         case "set":
 611                                                 if(player.object_attach == NULL)
 612                                                 {
 613                                                         print_to(player, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 614                                                         return true;
 615                                                 }
 616
 617                                                 // attaches the previously selected object to e
 618                                                 e = sandbox_ObjectEdit_Get(player, true);
 619                                                 if(e != NULL)
 620                                                 {
 621                                                         sandbox_ObjectAttach_Set(player.object_attach, e, argv(3));
 622                                                         player.object_attach = NULL; // object was attached, no longer keep it scheduled for attachment
 623                                                         print_to(player, "^2SANDBOX - INFO: ^7Object attached successfully");
 624                                                         if(autocvar_g_sandbox_info > 1)
 625                                                                 LOG_INFO("^3SANDBOX - SERVER: ^7", player.netname, " attached objects at origin ^3", vtos(e.origin));
 626                                                         return true;
 627                                                 }
 628                                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 629                                                 return true;
 630                                         case "remove":
 631                                                 // removes e if it was attached
 632                                                 e = sandbox_ObjectEdit_Get(player, true);
 633                                                 if(e != NULL)
 634                                                 {
 635                                                         sandbox_ObjectAttach_Remove(e);
 636                                                         print_to(player, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 637                                                         if(autocvar_g_sandbox_info > 1)
 638                                                                 LOG_INFO("^3SANDBOX - SERVER: ^7", player.netname, " detached objects at origin ^3", vtos(e.origin));
 639                                                         return true;
 640                                                 }
 641                                                 print_to(player, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 642                                                 return true;
 643                                 }
 644                                 return true;
 645
 646                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 647                         case "object_edit":
 648                                 if(argv(2) == "")
 649                                 {
 650                                         print_to(player, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 651                                         return true;
 652                                 }
 653
 654                                 e = sandbox_ObjectEdit_Get(player, true);
 655                                 if(e != NULL)
 656                                 {
 657                                         switch(argv(2))
 658                                         {
 659                                                 case "skin":
 660                                                         e.skin = stof(argv(3));
 661                                                         break;
 662                                                 case "alpha":
 663                                                         e.alpha = stof(argv(3));
 664                                                         break;
 665                                                 case "color_main":
 666                                                         e.colormod = stov(argv(3));
 667                                                         break;
 668                                                 case "color_glow":
 669                                                         e.glowmod = stov(argv(3));
 670                                                         break;
 671                                                 case "frame":
 672                                                         e.frame = stof(argv(3));
 673                                                         break;
 674                                                 case "scale":
 675                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 676                                                         break;
 677                                                 case "solidity":
 678                                                         switch(argv(3))
 679                                                         {
 680                                                                 case "0": // non-solid
 681                                                                         e.solid = SOLID_TRIGGER;
 682                                                                         break;
 683                                                                 case "1": // solid
 684                                                                         e.solid = SOLID_BBOX;
 685                                                                         break;
 686                                                                 default:
 687                                                                         break;
 688                                                         }
 689                                                 case "physics":
 690                                                         switch(argv(3))
 691                                                         {
 692                                                                 case "0": // static
 693                                                                         set_movetype(e, MOVETYPE_NONE);
 694                                                                         break;
 695                                                                 case "1": // movable
 696                                                                         set_movetype(e, MOVETYPE_TOSS);
 697                                                                         break;
 698                                                                 case "2": // physical
 699                                                                         set_movetype(e, MOVETYPE_PHYSICS);
 700                                                                         break;
 701                                                                 default:
 702                                                                         break;
 703                                                         }
 704                                                         break;
 705                                                 case "force":
 706                                                         e.damageforcescale = stof(argv(3));
 707                                                         break;
 708                                                 case "material":
 709                                                         strfree(e.material);
 710                                                         if(argv(3))
 711                                                         {
 712                                                                 for (j = 1; j <= 5; j++) // precache material sounds, 5 in total
 713                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(j), ".wav"));
 714                                                                 e.material = strzone(argv(3));
 715                                                         }
 716                                                         else
 717                                                                 e.material = string_null; // no material
 718                                                         break;
 719                                                 default:
 720                                                         print_to(player, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 721                                                         return true;
 722                                         }
 723
 724                                         // update last editing time
 725                                         strcpy(e.message2, strftime(true, "%d-%m-%Y %H:%M:%S"));
 726
 727                                         if(autocvar_g_sandbox_info > 1)
 728                                                 LOG_INFO("^3SANDBOX - SERVER: ^7", player.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin));
 729                                         return true;
 730                                 }
 731
 732                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 733                                 return true;
 734
 735                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 736                         case "object_claim":
 737                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 738                                 if(player.crypto_idfp == "")
 739                                 {
 740                                         print_to(player, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 741                                         return true;
 742                                 }
 743                                 e = sandbox_ObjectEdit_Get(player, true);
 744                                 if(e != NULL)
 745                                 {
 746                                         // update the owner's name
 747                                         // Do this before checking if you're already the owner and skipping if such, so we
 748                                         // also update the player's nickname if he changed it (but has the same player UID)
 749                                         if(e.netname != player.netname)
 750                                         {
 751                                                 strcpy(e.netname, player.netname);
 752                                                 print_to(player, "^2SANDBOX - INFO: ^7Object owner name updated");
 753                                         }
 754
 755                                         if(e.crypto_idfp == player.crypto_idfp)
 756                                         {
 757                                                 print_to(player, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 758                                                 return true;
 759                                         }
 760
 761                                         strcpy(e.crypto_idfp, player.crypto_idfp);
 762
 763                                         print_to(player, "^2SANDBOX - INFO: ^7Object claimed successfully");
 764                                 }
 765                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 766                                 return true;
 767
 768                         // ---------------- COMMAND: OBJECT, INFO ----------------
 769                         case "object_info":
 770                                 // prints public information about the object to the player
 771                                 e = sandbox_ObjectEdit_Get(player, false);
 772                                 if(e != NULL)
 773                                 {
 774                                         switch(argv(2))
 775                                         {
 776                                                 case "object":
 777                                                         print_to(player, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 778                                                         return true;
 779                                                 case "mesh":
 780                                                         s = "";
 781                                                         FOR_EACH_TAG(e)
 782                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 783                                                         print_to(player, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 784                                                         return true;
 785                                                 case "attachments":
 786                                                         // this should show the same info as 'mesh' but for attachments
 787                                                         s = "";
 788                                                         j = 0;
 789                                                         IL_EACH(g_sandbox_objects, it.owner == e,
 790                                                         {
 791                                                                 ++j; // start from 1
 792                                                                 gettaginfo(e, it.tag_index);
 793                                                                 s = strcat(s, "^1attachment ", ftos(j), "^7 has mesh \"^3", it.model, "^7\" at animation frame ^3", ftos(it.frame));
 794                                                                 s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 795                                                         });
 796                                                         if(j) // object contains attachments
 797                                                                 print_to(player, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(j), "^7 attachment(s): ", s));
 798                                                         else
 799                                                                 print_to(player, "^2SANDBOX - INFO: ^7Object contains no attachments");
 800                                                         return true;
 801                                         }
 802                                 }
 803                                 print_to(player, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 804                                 return true;
 805
 806                         // ---------------- COMMAND: DEFAULT ----------------
 807                         default:
 808                                 print_to(player, "Invalid command. For usage information, type 'sandbox help'");
 809                                 return true;
 810                 }
 811         }
 812 }
 813
 814 MUTATOR_HOOKFUNCTION(sandbox, SV_StartFrame)
 815 {
 816         if(!autocvar_g_sandbox_storage_autosave)
 817                 return;
 818         if(time < autosave_time)
 819                 return;
 820         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 821
 822         sandbox_Database_Save();
 823
 824         return true;
 825 }