qcsrc/common/mutators/mutator/spawn_near_teammate/spawn_near_teammate.qc

   1 #ifdef IMPLEMENTATION
   2
   3 float autocvar_g_spawn_near_teammate_distance;
   4 int autocvar_g_spawn_near_teammate_ignore_spawnpoint;
   5 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
   6 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
   7 int autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health;
   8 bool autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath;
   9
  10 REGISTER_MUTATOR(spawn_near_teammate, cvar("g_spawn_near_teammate") && teamplay);
  11
  12 .entity msnt_lookat;
  13
  14 .float msnt_timer;
  15 .vector msnt_deathloc;
  16
  17 .float cvar_cl_spawn_near_teammate;
  18
  19 MUTATOR_HOOKFUNCTION(spawn_near_teammate, Spawn_Score)
  20 {SELFPARAM();
  21         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && self.cvar_cl_spawn_near_teammate))
  22                 return 0;
  23
  24         entity p;
  25
  26         spawn_spot.msnt_lookat = world;
  27
  28         if(!teamplay)
  29                 return 0;
  30
  31         RandomSelection_Init();
  32         FOR_EACH_PLAYER(p) if(p != self) if(p.team == self.team) if(!p.deadflag)
  33         {
  34                 float l = vlen(spawn_spot.origin - p.origin);
  35                 if(l > autocvar_g_spawn_near_teammate_distance)
  36                         continue;
  37                 if(l < 48)
  38                         continue;
  39                 if(!checkpvs(spawn_spot.origin, p))
  40                         continue;
  41                 RandomSelection_Add(p, 0, string_null, 1, 1);
  42         }
  43
  44         if(RandomSelection_chosen_ent)
  45         {
  46                 spawn_spot.msnt_lookat = RandomSelection_chosen_ent;
  47                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_FOUND;
  48         }
  49         else if(self.team == spawn_spot.team)
  50                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_SAMETEAM; // prefer same team, if we can't find a spawn near teammate
  51
  52         return 0;
  53 }
  54
  55 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerSpawn)
  56 {SELFPARAM();
  57         // Note: when entering this, fixangle is already set.
  58         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && self.cvar_cl_spawn_near_teammate))
  59         {
  60                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death)
  61                         self.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
  62
  63                 entity team_mate, best_mate = world;
  64                 vector best_spot = '0 0 0';
  65                 float pc = 0, best_dist = 0, dist = 0;
  66                 FOR_EACH_PLAYER(team_mate)
  67                 {
  68                         if((autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health >= 0 && team_mate.health >= autocvar_g_balance_health_regenstable) || autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health == 0)
  69                         if(team_mate.deadflag == DEAD_NO)
  70                         if(team_mate.msnt_timer < time)
  71                         if(SAME_TEAM(self, team_mate))
  72                         if(time > team_mate.spawnshieldtime) // spawn shielding
  73                         if(team_mate.frozen == 0)
  74                         if(team_mate != self)
  75                         {
  76                                 tracebox(team_mate.origin, PL_MIN, PL_MAX, team_mate.origin - '0 0 100', MOVE_WORLDONLY, team_mate);
  77                                 if(trace_fraction != 1.0)
  78                                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
  79                                 {
  80                                         pc = pointcontents(trace_endpos + '0 0 1');
  81                                         if(pc == CONTENT_EMPTY)
  82                                         {
  83                                                 if(vlen(team_mate.velocity) > 5)
  84                                                         fixedmakevectors(vectoangles(team_mate.velocity));
  85                                                 else
  86                                                         fixedmakevectors(team_mate.angles);
  87
  88                                                 for(pc = 0; pc != 5; ++pc) // test 5 diffrent spots close to mate
  89                                                 {
  90                                                         switch(pc)
  91                                                         {
  92                                                                 case 0:
  93                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin + v_right * 128, MOVE_NORMAL, team_mate);
  94                                                                         break;
  95                                                                 case 1:
  96                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_right * 128 , MOVE_NORMAL, team_mate);
  97                                                                         break;
  98                                                                 case 2:
  99                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin + v_right * 64 - v_forward * 64, MOVE_NORMAL, team_mate);
 100                                                                         break;
 101                                                                 case 3:
 102                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_right * 64 - v_forward * 64, MOVE_NORMAL, team_mate);
 103                                                                         break;
 104                                                                 case 4:
 105                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_forward * 128, MOVE_NORMAL, team_mate);
 106                                                                         break;
 107                                                         }
 108
 109                                                         if(trace_fraction == 1.0)
 110                                                         {
 111                                                                 traceline(trace_endpos + '0 0 4', trace_endpos - '0 0 100', MOVE_NORMAL, team_mate);
 112                                                                 if(trace_fraction != 1.0)
 113                                                                 {
 114                                                                         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 115                                                                         {
 116                                                                                 dist = vlen(trace_endpos - self.msnt_deathloc);
 117                                                                                 if(dist < best_dist || best_dist == 0)
 118                                                                                 {
 119                                                                                         best_dist = dist;
 120                                                                                         best_spot = trace_endpos;
 121                                                                                         best_mate = team_mate;
 122                                                                                 }
 123                                                                         }
 124                                                                         else
 125                                                                         {
 126                                                                                 setorigin(self, trace_endpos);
 127                                                                                 self.angles = team_mate.angles;
 128                                                                                 self.angles_z = 0; // never spawn tilted even if the spot says to
 129                                                                                 team_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 130                                                                                 return 0;
 131                                                                         }
 132                                                                 }
 133                                                         }
 134                                                 }
 135                                         }
 136                                 }
 137                         }
 138                 }
 139
 140                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 141                 if(best_dist)
 142                 {
 143                         setorigin(self, best_spot);
 144                         self.angles = best_mate.angles;
 145                         self.angles_z = 0; // never spawn tilted even if the spot says to
 146                         best_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 147                 }
 148         }
 149         else if(spawn_spot.msnt_lookat)
 150         {
 151                 self.angles = vectoangles(spawn_spot.msnt_lookat.origin - self.origin);
 152                 self.angles_x = -self.angles.x;
 153                 self.angles_z = 0; // never spawn tilted even if the spot says to
 154                 /*
 155                 sprint(self, "You should be looking at ", spawn_spot.msnt_lookat.netname, "^7.\n");
 156                 sprint(self, "distance: ", vtos(spawn_spot.msnt_lookat.origin - self.origin), "\n");
 157                 sprint(self, "angles: ", vtos(self.angles), "\n");
 158                 */
 159         }
 160
 161         return 0;
 162 }
 163
 164 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerDies)
 165 {SELFPARAM();
 166         self.msnt_deathloc = self.origin;
 167         return 0;
 168 }
 169
 170 MUTATOR_HOOKFUNCTION(spawn_near_teammate, GetCvars)
 171 {
 172         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_spawn_near_teammate, "cl_spawn_near_teammate");
 173         return false;
 174 }
 175 #endif