qcsrc/common/mutators/mutator/spawn_near_teammate/sv_spawn_near_teammate.qc

   1 #include "sv_spawn_near_teammate.qh"
   2
   3 float autocvar_g_spawn_near_teammate_distance;
   4 int autocvar_g_spawn_near_teammate_ignore_spawnpoint;
   5 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
   6 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
   7 int autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health;
   8 bool autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath;
   9
  10 REGISTER_MUTATOR(spawn_near_teammate, cvar("g_spawn_near_teammate"));
  11
  12 .entity msnt_lookat;
  13
  14 .float msnt_timer;
  15 .vector msnt_deathloc;
  16
  17 .float cvar_cl_spawn_near_teammate;
  18
  19 MUTATOR_HOOKFUNCTION(spawn_near_teammate, Spawn_Score)
  20 {
  21         entity player = M_ARGV(0, entity);
  22         entity spawn_spot = M_ARGV(1, entity);
  23         vector spawn_score = M_ARGV(2, vector);
  24
  25         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && player.cvar_cl_spawn_near_teammate))
  26                 return;
  27
  28         spawn_spot.msnt_lookat = NULL;
  29
  30         if(!teamplay)
  31                 return;
  32
  33         RandomSelection_Init();
  34         FOREACH_CLIENT(IS_PLAYER(it) && it != player && SAME_TEAM(it, player) && !IS_DEAD(it), LAMBDA(
  35                 if(vdist(spawn_spot.origin - it.origin, >, autocvar_g_spawn_near_teammate_distance))
  36                         continue;
  37                 if(vdist(spawn_spot.origin - it.origin, <, 48))
  38                         continue;
  39                 if(!checkpvs(spawn_spot.origin, it))
  40                         continue;
  41                 RandomSelection_AddEnt(it, 1, 1);
  42         ));
  43
  44         if(RandomSelection_chosen_ent)
  45         {
  46                 spawn_spot.msnt_lookat = RandomSelection_chosen_ent;
  47                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_FOUND;
  48         }
  49         else if(player.team == spawn_spot.team)
  50                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_SAMETEAM; // prefer same team, if we can't find a spawn near teammate
  51
  52         M_ARGV(2, vector) = spawn_score;
  53 }
  54
  55 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerSpawn)
  56 {
  57         if(!teamplay) { return; }
  58         entity player = M_ARGV(0, entity);
  59         entity spawn_spot = M_ARGV(1, entity);
  60
  61         //LOG_INFOF("PlayerSpawn for player: %s %v spawn_spot: %v\n", player.netname, player.origin, spawn_spot.origin);
  62
  63         int num_red = 0, num_blue = 0, num_yellow = 0, num_pink = 0;
  64         FOREACH_CLIENT(IS_PLAYER(it),
  65         {
  66                 switch(it.team)
  67                 {
  68                         case NUM_TEAM_1: ++num_red; break;
  69                         case NUM_TEAM_2: ++num_blue; break;
  70                         case NUM_TEAM_3: ++num_yellow; break;
  71                         case NUM_TEAM_4: ++num_pink; break;
  72                 }
  73         });
  74
  75         if(num_red == 1 || num_blue == 1 || num_yellow == 1 || num_pink == 1)
  76                 return; // at least 1 team has only 1 player, let's not give the bigger team too much of an advantage!
  77
  78         // Note: when entering this, fixangle is already set.
  79         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && player.cvar_cl_spawn_near_teammate))
  80         {
  81                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death)
  82                         player.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
  83
  84                 entity best_mate = NULL;
  85                 vector best_pos = '0 0 0';
  86                 float best_dist = 0;
  87                 FOREACH_CLIENT_RANDOM(IS_PLAYER(it), LAMBDA(
  88                         //LOG_INFOF("  for client: %s %v\n", it.netname, it.origin);
  89                         if (!SAME_TEAM(player, it)) continue;
  90                         if (autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health >= 0 && it.health < autocvar_g_balance_health_regenstable) continue;
  91                         if (IS_DEAD(it)) continue;
  92                         if (time < it.msnt_timer) continue;
  93                         if (time < it.spawnshieldtime) continue;
  94                         if (forbidWeaponUse(it)) continue;
  95                         if (it == player) continue;
  96
  97                         vector horiz_vel = vec2(it.velocity);
  98                         if (vdist(horiz_vel, >, 450))
  99                                 fixedmakevectors(vectoangles(horiz_vel));
 100                         else
 101                                 fixedmakevectors(it.angles); // .angles is the angle of the model - usually/always 0 pitch
 102
 103                         // test different spots close to mate - trace upwards so it works on uneven surfaces
 104                         // don't spawn in front of player or directly behind to avoid players shooting each other
 105                         for(int i = 0; i < 6; ++i)
 106                         {
 107                                 switch(i)
 108                                 {
 109                                         case 0:
 110                                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_forward * 64 + v_right * 128 + v_up * 64, MOVE_NOMONSTERS, it);
 111                                                 break;
 112                                         case 1:
 113                                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_forward * 64 - v_right * 128 + v_up * 64, MOVE_NOMONSTERS, it);
 114                                                 break;
 115                                         case 2:
 116                                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin + v_right * 192 + v_up * 64, MOVE_NOMONSTERS, it);
 117                                                 break;
 118                                         case 3:
 119                                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_right * 192 + v_up * 64, MOVE_NOMONSTERS, it);
 120                                                 break;
 121                                         case 4:
 122                                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_forward * 128 + v_right * 64 + v_up * 64, MOVE_NOMONSTERS, it);
 123                                                 break;
 124                                         case 5:
 125                                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_forward * 128 - v_right * 64 + v_up * 64, MOVE_NOMONSTERS, it);
 126                                                 break;
 127                                 }
 128                                 vector horizontal_trace_endpos = trace_endpos;
 129                                 //te_lightning1(NULL, it.origin, horizontal_trace_endpos);
 130                                 if(trace_fraction != 1.0) continue;
 131
 132                                 // 400 is about the height of a typical laser jump (in overkill)
 133                                 // not traceline because we need space for the whole player, not just his origin
 134                                 tracebox(horizontal_trace_endpos, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), horizontal_trace_endpos - '0 0 400', MOVE_NORMAL, it);
 135                                 vector vectical_trace_endpos = trace_endpos;
 136                                 //te_lightning1(NULL, horizontal_trace_endpos, vectical_trace_endpos);
 137                                 if (trace_startsolid) continue; // inside another player
 138                                 if (trace_fraction == 1.0) continue; // above void or too high
 139                                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY) continue;
 140                                 if (pointcontents(vectical_trace_endpos) != CONTENT_EMPTY) continue; // no lava or slime (this also prevents spawning in water which i assume would be annoying)
 141                                 if (tracebox_hits_trigger_hurt(horizontal_trace_endpos, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), vectical_trace_endpos)) continue;
 142
 143                                 // make sure the spawned player will have floor ahead (or at least a wall - he shouldn't fall as soon as he starts moving)
 144                                 vector floor_test_start = vectical_trace_endpos + v_up * STAT(PL_MAX, NULL).z + v_forward * STAT(PL_MAX, NULL).x; // top front of player's bbox - highest point we know is not inside solid
 145                                 traceline(floor_test_start, floor_test_start + v_forward * 100 - v_up * 128, MOVE_NOMONSTERS, it);
 146                                 //te_beam(NULL, floor_test_start, trace_endpos);
 147                                 if (trace_fraction == 1.0) continue;
 148
 149                                 if (autocvar_g_nades) {
 150                                         bool nade_in_range = false;
 151                                         IL_EACH(g_projectiles, it.classname == "nade",
 152                                         {
 153                                                 if (vdist(it.origin - vectical_trace_endpos, <, autocvar_g_nades_nade_radius)) {
 154                                                         nade_in_range = true;
 155                                                         break;
 156                                                 }
 157                                         });
 158                                         if (nade_in_range) continue;
 159                                 }
 160
 161                                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 162                                 {
 163                                         float dist = vlen(vectical_trace_endpos - player.msnt_deathloc);
 164                                         //LOG_INFOF("      dist: %f, best_dist %f\n", dist, best_dist);
 165                                         if(dist < best_dist || best_dist == 0)
 166                                         {
 167                                                 //LOG_INFOF("      new best dist - pos: %v\n", vectical_trace_endpos);
 168                                                 best_dist = dist;
 169                                                 best_pos = vectical_trace_endpos;
 170                                                 best_mate = it;
 171                                         }
 172                                 }
 173                                 else
 174                                 {
 175                                         setorigin(player, vectical_trace_endpos);
 176                                         player.angles = it.angles;
 177                                         player.angles_z = 0; // never spawn tilted even if the spot says to
 178                                         it.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 179                                         //LOG_INFOF("      PlayerSpawn return %v\n", player.origin);
 180                                         return;
 181                                 }
 182                         }
 183                 ));
 184
 185                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 186                 if(best_dist)
 187                 {
 188                         setorigin(player, best_pos);
 189                         player.angles = best_mate.angles;
 190                         player.angles_z = 0; // never spawn tilted even if the spot says to
 191                         best_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 192                 }
 193         }
 194         else if(spawn_spot.msnt_lookat)
 195         {
 196                 player.angles = vectoangles(spawn_spot.msnt_lookat.origin - player.origin);
 197                 player.angles_x = -player.angles.x;
 198                 player.angles_z = 0; // never spawn tilted even if the spot says to
 199                 /*
 200                 sprint(player, "You should be looking at ", spawn_spot.msnt_lookat.netname, "^7.\n");
 201                 sprint(player, "distance: ", vtos(spawn_spot.msnt_lookat.origin - player.origin), "\n");
 202                 sprint(player, "angles: ", vtos(player.angles), "\n");
 203                 */
 204         }
 205 }
 206
 207 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerDies)
 208 {
 209         entity frag_target = M_ARGV(0, entity);
 210
 211         frag_target.msnt_deathloc = frag_target.origin;
 212 }
 213
 214 REPLICATE(cvar_cl_spawn_near_teammate, bool, "cl_spawn_near_teammate");