qcsrc/common/notifications/all.qc

   1 #include "all.qh"
   2
   3 #if defined(CSQC)
   4         #include <client/announcer.qh>
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7         #include <common/constants.qh>
   8         #include <common/net_linked.qh>
   9         #include <common/teams.qh>
  10         #include <server/command/getreplies.qh>
  11         #include <server/mutators/_mod.qh>
  12         #include <server/world.qh>
  13 #endif
  14
  15 // ================================================
  16 //  Unified notification system, written by Samual
  17 //  Last updated: August, 2013
  18 // ================================================
  19
  20 #ifdef SVQC
  21 string Notification_CheckArgs(
  22         NOTIF broadcast, entity client)
  23 {
  24         // check supplied broadcast and target for errors
  25         switch (broadcast)
  26         {
  27                 case NOTIF_ONE:
  28                 case NOTIF_ONE_ONLY:
  29                 {
  30                         if (IS_NOT_A_CLIENT(client)) {
  31                                 return "No client provided!";
  32                         }
  33                         break;
  34                 }
  35
  36                 case NOTIF_ALL_EXCEPT:
  37                 {
  38                         if (IS_NOT_A_CLIENT(client)) {
  39                                 return "Exception can't be a non-client!";
  40                         }
  41                         break;
  42                 }
  43
  44                 case NOTIF_ALL:
  45                 {
  46                         if (client) {
  47                                 return "Entity provided when NULL was required!";
  48                         }
  49                         break;
  50                 }
  51
  52                 case NOTIF_TEAM:
  53                 {
  54                         if (!teamplay) {
  55                                 return "Teamplay not active!";
  56                         } else if (!client.team) {
  57                                 // checkargs = sprintf("%sNo team provided!", checkargs);
  58                         }
  59                         break;
  60                 }
  61
  62                 case NOTIF_TEAM_EXCEPT:
  63                 {
  64                         if (!teamplay) {
  65                                 return "Teamplay not active!";
  66                         } else if (IS_NOT_A_CLIENT(client)) {
  67                                 return "Exception can't be a non-client!";
  68                         }
  69                         break;
  70                 }
  71
  72                 default:
  73                 {
  74                         return sprintf("Improper broadcast: %d!", broadcast);
  75                 }
  76         }
  77         return "";
  78 }
  79
  80 bool Notification_ShouldSend(NOTIF broadcast, entity to_client, entity other_client)
  81 {
  82         if(!IS_REAL_CLIENT(to_client))
  83                 return false;
  84
  85         switch (broadcast)
  86         {
  87                 case NOTIF_ONE:
  88                         return (
  89                                 (to_client == other_client)
  90                                 ||
  91                                 (IS_SPEC(to_client) && (to_client.enemy == other_client))
  92                         );
  93                 case NOTIF_ONE_ONLY:
  94                         return (to_client == other_client);
  95                 case NOTIF_TEAM:
  96                         return (
  97                                 (to_client.team == other_client.team)
  98                                 ||
  99                                 (
 100                                         IS_SPEC(to_client)
 101                                         &&
 102                                         (to_client.enemy.team == other_client.team)
 103                                 )
 104                         );
 105                 case NOTIF_TEAM_EXCEPT:
 106                         return (
 107                                 (to_client != other_client)
 108                                 &&
 109                                 (
 110                                         (to_client.team == other_client.team)
 111                                         ||
 112                                         (
 113                                                 IS_SPEC(to_client)
 114                                                 &&
 115                                                 (
 116                                                         (to_client.enemy != other_client)
 117                                                         &&
 118                                                         (to_client.enemy.team == other_client.team)
 119                                                 )
 120                                         )
 121                                 )
 122                         );
 123                 case NOTIF_ALL:
 124                         return true;
 125                 case NOTIF_ALL_EXCEPT:
 126                         return (
 127                                 (to_client != other_client)
 128                                 &&
 129                                 !(
 130                                         IS_SPEC(to_client)
 131                                         &&
 132                                         (to_client.enemy == other_client)
 133                                 )
 134                         );
 135                 default:
 136                         return false;
 137         }
 138 }
 139
 140 #endif
 141
 142 // ===============================
 143 //  Initialization Core Functions
 144 // ===============================
 145
 146 // used by restartnotifs command to initialize notifications
 147 void Destroy_Notification_Entity(entity notif)
 148 {
 149         if (notif.nent_name != "") strunzone(notif.nent_name);
 150         if (notif.nent_snd != "") strunzone(notif.nent_snd);
 151         if (notif.nent_args != "") strunzone(notif.nent_args);
 152         if (notif.nent_hudargs != "") strunzone(notif.nent_hudargs);
 153         if (notif.nent_icon != "") strunzone(notif.nent_icon);
 154         if (notif.nent_durcnt != "") strunzone(notif.nent_durcnt);
 155         if (notif.nent_string != "") strunzone(notif.nent_string);
 156         delete(notif);
 157 }
 158
 159 void Destroy_All_Notifications()
 160 {
 161         // kill all networked notifications and centerprints
 162         #ifdef SVQC
 163         Kill_Notification(NOTIF_ALL, NULL, MSG_Null, CPID_Null);
 164         #else
 165         centerprint_KillAll();
 166         #endif
 167
 168         // kill all real notification entities
 169         FOREACH(Notifications, true, { Destroy_Notification_Entity(it); });
 170 }
 171
 172 string Process_Notif_Line(
 173         MSG typeId,
 174         bool chat,
 175         string input,
 176         string notiftype,
 177         string notifname,
 178         string stringtype)
 179 {
 180         #ifdef CSQC
 181         if(typeId == MSG_INFO)
 182         {
 183                 if((chat && autocvar_notification_allow_chatboxprint)
 184                         || (autocvar_notification_allow_chatboxprint == 2))
 185                 {
 186                         // pass 1: add ETX char at beginning of line
 187                         input = strcat("\{3}", input);
 188
 189                         // pass 2: add ETX char at end of each new line (so that
 190                         // messages with multiple lines are put through chatbox too)
 191                         input = strreplace("\n", "\n\{3}", input);
 192
 193                         // pass 3: strip trailing ETX char
 194                         if(substring(input, (strlen(input) - 1), 1) == "\{3}")
 195                                 { input = substring(input, 0, (strlen(input) - 1)); }
 196                 }
 197         }
 198         #endif
 199
 200         // done to both MSG_INFO and MSG_CENTER
 201         if(substring(input, (strlen(input) - 1), 1) == "\n")
 202         {
 203                 LOG_INFOF(
 204                         (
 205                                 "^1TRAILING NEW LINE AT END OF NOTIFICATION: "
 206                                 "^7net_type = %s, net_name = %s, string = %s."
 207                         ),
 208                         notiftype,
 209                         notifname,
 210                         stringtype
 211                 );
 212                 notif_error = true;
 213                 input = substring(input, 1, (strlen(input) - 1));
 214         }
 215
 216         return input;
 217 }
 218
 219 string Process_Notif_Args(
 220         float arg_type,
 221         string args,
 222         string notiftype,
 223         string notifname)
 224 {
 225         string selected, remaining = args;
 226         float sel_num = 0;
 227
 228         for (;(remaining != "");)
 229         {
 230                 selected = car(remaining); remaining = cdr(remaining);
 231
 232                 switch(arg_type)
 233                 {
 234                         case 1: // normal args
 235                         {
 236                                 if(sel_num == NOTIF_MAX_ARGS)
 237                                 {
 238                                         LOG_INFOF(
 239                                                 (
 240                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: "
 241                                                         "^7net_type = %s, net_name = %s, max args = %d."
 242                                                 ),
 243                                                 notiftype,
 244                                                 notifname,
 245                                                 NOTIF_MAX_ARGS
 246                                         );
 247                                         notif_error = true;
 248                                         break;
 249                                 }
 250
 251                                 switch(strtolower(selected))
 252                                 {
 253                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: ++sel_num; break;
 254                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: ++sel_num; break;
 255                                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: ++sel_num; break;
 256                                         #define ARG_CASE_ARG_CS(selected,result)       case selected: ++sel_num; break;
 257                                         #define ARG_CASE_ARG_SV(selected,result)       case selected: ++sel_num; break;
 258                                         #define ARG_CASE_ARG_DC(selected,result)
 259                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 260                                         NOTIF_ARGUMENT_LIST
 261                                         #undef ARG_CASE
 262                                         #undef ARG_CASE_ARG_DC
 263                                         #undef ARG_CASE_ARG_SV
 264                                         #undef ARG_CASE_ARG_CS
 265                                         #undef ARG_CASE_ARG_CS_SV
 266                                         #undef ARG_CASE_ARG_CS_SV_DC
 267                                         #undef ARG_CASE_ARG_CS_SV_HA
 268                                         default:
 269                                         {
 270                                                 LOG_INFOF(
 271                                                         (
 272                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: "
 273                                                                 "^7net_type = %s, net_name = %s, args arg = '%s'."
 274                                                         ),
 275                                                         notiftype,
 276                                                         notifname,
 277                                                         selected
 278                                                 );
 279                                                 notif_error = true;
 280                                                 break;
 281                                         }
 282                                 }
 283                                 break;
 284                         }
 285                         case 2: // hudargs
 286                         {
 287                                 if(sel_num == NOTIF_MAX_HUDARGS)
 288                                 {
 289                                         LOG_INFOF(
 290                                                 (
 291                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: "
 292                                                         "^7net_type = %s, net_name = %s, max hudargs = %d."
 293                                                 ),
 294                                                 notiftype,
 295                                                 notifname,
 296                                                 NOTIF_MAX_HUDARGS
 297                                         );
 298                                         notif_error = true;
 299                                         break;
 300                                 }
 301
 302                                 switch(strtolower(selected))
 303                                 {
 304                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: ++sel_num; break;
 305                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result)
 306                                         #define ARG_CASE_ARG_CS_SV(selected,result)
 307                                         #define ARG_CASE_ARG_CS(selected,result)
 308                                         #define ARG_CASE_ARG_SV(selected,result)
 309                                         #define ARG_CASE_ARG_DC(selected,result)
 310                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 311                                         NOTIF_ARGUMENT_LIST
 312                                         #undef ARG_CASE
 313                                         #undef ARG_CASE_ARG_DC
 314                                         #undef ARG_CASE_ARG_SV
 315                                         #undef ARG_CASE_ARG_CS
 316                                         #undef ARG_CASE_ARG_CS_SV
 317                                         #undef ARG_CASE_ARG_CS_SV_DC
 318                                         #undef ARG_CASE_ARG_CS_SV_HA
 319                                         default:
 320                                         {
 321                                                 LOG_INFOF(
 322                                                         (
 323                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: "
 324                                                                 "^7net_type = %s, net_name = %s, hudargs arg = '%s'."
 325                                                         ),
 326                                                         notiftype,
 327                                                         notifname,
 328                                                         selected
 329                                                 );
 330                                                 notif_error = true;
 331                                                 break;
 332                                         }
 333                                 }
 334                                 break;
 335                         }
 336                         case 3: // durcnt
 337                         {
 338                                 if(sel_num == NOTIF_MAX_DURCNT)
 339                                 {
 340                                         LOG_INFOF(
 341                                                 (
 342                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: "
 343                                                         "^7net_type = %s, net_name = %s, max durcnt = %d."
 344                                                 ),
 345                                                 notiftype,
 346                                                 notifname,
 347                                                 NOTIF_MAX_DURCNT
 348                                         );
 349                                         notif_error = true;
 350                                         break;
 351                                 }
 352
 353                                 switch(strtolower(selected))
 354                                 {
 355                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result)
 356                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: ++sel_num; break;
 357                                         #define ARG_CASE_ARG_CS_SV(selected,result)
 358                                         #define ARG_CASE_ARG_CS(selected,result)
 359                                         #define ARG_CASE_ARG_SV(selected,result)
 360                                         #define ARG_CASE_ARG_DC(selected,result)       case selected: ++sel_num; break;
 361                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 362                                         NOTIF_ARGUMENT_LIST
 363                                         #undef ARG_CASE
 364                                         #undef ARG_CASE_ARG_DC
 365                                         #undef ARG_CASE_ARG_SV
 366                                         #undef ARG_CASE_ARG_CS
 367                                         #undef ARG_CASE_ARG_CS_SV
 368                                         #undef ARG_CASE_ARG_CS_SV_DC
 369                                         #undef ARG_CASE_ARG_CS_SV_HA
 370                                         default:
 371                                         {
 372                                                 if(ftos(stof(selected)) != "") { ++sel_num; }
 373                                                 else
 374                                                 {
 375                                                         LOG_INFOF(
 376                                                                 (
 377                                                                         "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: "
 378                                                                         "^7net_type = %s, net_name = %s, durcnt arg = '%s'."
 379                                                                 ),
 380                                                                 notiftype,
 381                                                                 notifname,
 382                                                                 selected
 383                                                         );
 384                                                         notif_error = true;
 385                                                 }
 386                                                 break;
 387                                         }
 388                                 }
 389                                 break;
 390                         }
 391                 }
 392         }
 393         return args;
 394 }
 395
 396 void Create_Notification_Entity(entity notif,
 397         float var_default,
 398         float var_cvar,
 399         MSG typeId,
 400         string namestring,
 401         int teamnum)
 402 {
 403         // =====================
 404         //  Global Entity Setup
 405         // =====================
 406         notif.nent_default = var_default;
 407         notif.nent_enabled = (var_cvar >= 1);
 408         notif.nent_type = typeId;
 409         notif.nent_name = strzone(namestring);
 410         notif.nent_teamnum = teamnum;
 411
 412         // Other pre-notif-setup requisites
 413         notif_error = false;
 414
 415         switch (typeId)
 416         {
 417                 case MSG_ANNCE:
 418                 case MSG_INFO:
 419                 case MSG_CENTER:
 420                 case MSG_MULTI:
 421                 case MSG_CHOICE:
 422                         break;
 423                 default:
 424                         LOG_INFOF(
 425                                 (
 426                                         "^1NOTIFICATION WITH IMPROPER TYPE: "
 427                                         "^7net_type = %d, net_name = %s."
 428                                 ),
 429                                 typeId,
 430                                 namestring
 431                         );
 432                         notif_error = true;
 433                         break;
 434         }
 435
 436         // now check to see if any errors happened
 437         if (notif_error)
 438         {
 439                 notif.nent_enabled = false; // disable the notification so it can't cause trouble
 440                 notif_global_error = true; // throw the red flag that an error happened on init
 441         }
 442 }
 443
 444 #define AnnouncerFilename(snd) sprintf("announcer/%s/%s.wav", AnnouncerOption(), snd)
 445
 446 void Create_Notification_Entity_Annce(entity notif,
 447                                                                                 float var_cvar,
 448                                                                                 string namestring,
 449                                                                                 /* MSG_ANNCE */
 450                                                                                 float channel,
 451                                                                                 string snd,
 452                                                                                 float vol,
 453                                                                                 float position)
 454                 {
 455                         // Set MSG_ANNCE information and handle precaching
 456                         #ifdef CSQC
 457                         MSG typeId = MSG_ANNCE;
 458                         if (!(GENTLE && (var_cvar == 1)))
 459                         {
 460                                 if(snd != "")
 461                                 {
 462                                         if(notif.nent_enabled)
 463                                         {
 464                                                 precache_sound(AnnouncerFilename(snd));
 465                                                 notif.nent_channel = channel;
 466                                                 notif.nent_snd = strzone(snd);
 467                                                 notif.nent_vol = vol;
 468                                                 notif.nent_position = position;
 469                                         }
 470                                 }
 471                                 else
 472                                 {
 473                                         string typestring = Get_Notif_TypeName(typeId);
 474                                         LOG_INFOF(
 475                                                 (
 476                                                         "^1NOTIFICATION WITH NO SOUND: "
 477                                                         "^7net_type = %s, net_name = %s."
 478                                                 ),
 479                                                 typestring,
 480                                                 namestring
 481                                         );
 482                                         notif_error = true;
 483                                 }
 484                         }
 485                         else { notif.nent_enabled = false; }
 486                         #else
 487                         notif.nent_enabled = false;
 488                         #endif
 489
 490                 }
 491
 492 void Create_Notification_Entity_InfoCenter(entity notif,
 493                                                                                         float var_cvar,
 494                                                                                         string namestring,
 495                                                                                         int strnum,
 496                                                                                         int flnum,
 497                                                                                         /* MSG_INFO & MSG_CENTER */
 498                                                                                         string args,
 499                                                                                         string hudargs,
 500                                                                                         string icon,
 501                                                                                         CPID cpid,
 502                                                                                         string durcnt,
 503                                                                                         string normal,
 504                                                                                         string gentle)
 505                 {
 506                         MSG typeId = notif.nent_type;
 507                         // Set MSG_INFO and MSG_CENTER string/float counts
 508                         notif.nent_stringcount = strnum;
 509                         notif.nent_floatcount = flnum;
 510
 511                         // Only initialize arguments if we're either a client or on a dedicated server
 512                         #ifdef SVQC
 513                         float should_process_args = server_is_dedicated;
 514                         #else
 515                         float should_process_args = true;
 516                         #endif
 517                         string typestring = Get_Notif_TypeName(typeId);
 518                         if(should_process_args)
 519                         {
 520                                 // ========================
 521                                 //  Process Main Arguments
 522                                 // ========================
 523                                 if(strnum + flnum)
 524                                 {
 525                                         if(args != "")
 526                                         {
 527                                                 notif.nent_args = strzone(
 528                                                         Process_Notif_Args(1, args, typestring, namestring));
 529                                         }
 530                                         else if((hudargs == "") && (durcnt ==""))
 531                                         {
 532                                                 LOG_INFOF(
 533                                                         (
 534                                                                 "^1NOTIFICATION HAS ARG COUNTS BUT NO ARGS OR HUDARGS OR DURCNT: "
 535                                                                 "^7net_type = %s, net_name = %s, strnum = %d, flnum = %d"
 536                                                         ),
 537                                                         typestring,
 538                                                         namestring,
 539                                                         strnum,
 540                                                         flnum
 541                                                 );
 542                                                 notif_error = true;
 543                                         }
 544                                 }
 545                                 else if(args != "")
 546                                 {
 547                                         notif.nent_args = strzone(
 548                                                 Process_Notif_Args(1, args, typestring, namestring));
 549                                 }
 550
 551
 552                                 // =======================================
 553                                 //  Process HUD and Centerprint Arguments
 554                                 //    Only processed on CSQC, as these
 555                                 //    args are only for HUD features.
 556                                 // =======================================
 557                                 #ifdef CSQC
 558                                 if(hudargs != "")
 559                                 {
 560                                         notif.nent_hudargs = strzone(
 561                                                 Process_Notif_Args(2, hudargs, typestring, namestring));
 562
 563                                         if(icon != "") { notif.nent_icon = strzone(icon); }
 564                                         else
 565                                         {
 566                                                 LOG_INFOF(
 567                                                         (
 568                                                                 "^1NOTIFICATION HAS HUDARGS BUT NO ICON: "
 569                                                                 "^7net_type = %s, net_name = %s."
 570                                                         ),
 571                                                         typestring,
 572                                                         namestring
 573                                                 );
 574                                                 notif_error = true;
 575                                         }
 576                                 }
 577                                 else if(icon != "")
 578                                 {
 579                                         LOG_WARNF(
 580                                                 (
 581                                                         "^1NOTIFICATION HAS ICON BUT NO HUDARGS: "
 582                                                         "^7net_type = %s, net_name = %s.\n"
 583                                                 ),
 584                                                 typestring,
 585                                                 namestring
 586                                         );
 587                                         notif_error = true;
 588                                 }
 589
 590                                 if (durcnt != "")
 591                                 {
 592                                         notif.nent_durcnt = strzone(Process_Notif_Args(3, durcnt, typestring, namestring));
 593
 594                                         if (cpid == CPID_Null && durcnt != "0 0")
 595                                         {
 596                                                 LOG_WARNF(
 597                                                         (
 598                                                                 "Notification has durcnt but no cpid: "
 599                                                                 "net_type = %s, net_name = %s."
 600                                                         ),
 601                                                         typestring,
 602                                                         namestring
 603                                                 );
 604                                                 notif_error = true;
 605                                         }
 606                                 }
 607                                 notif.nent_cpid = cpid;
 608                                 #endif
 609
 610
 611                                 // ======================
 612                                 //  Process Notif String
 613                                 // ======================
 614                                 #define SET_NOTIF_STRING(string,stringname) MACRO_BEGIN \
 615                                         notif.nent_string = strzone(CCR( \
 616                                                 Process_Notif_Line( \
 617                                                         typeId, \
 618                                                         (var_cvar > 1), \
 619                                                         string, \
 620                                                         typestring, \
 621                                                         namestring, \
 622                                                         stringname \
 623                                                 )) \
 624                                         ); \
 625                                 MACRO_END
 626
 627                                 if(GENTLE)
 628                                 {
 629                                         if(gentle != "") { SET_NOTIF_STRING(gentle, "GENTLE"); }
 630                                         else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL"); }
 631                                 }
 632                                 else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL"); }
 633                                 #undef SET_NOTIF_STRING
 634
 635                                 // Check to make sure a string was chosen
 636                                 if(notif.nent_string == "")
 637                                 {
 638                                         LOG_INFOF(
 639                                                 (
 640                                                         "^1EMPTY NOTIFICATION: "
 641                                                         "^7net_type = %s, net_name = %s."
 642                                                 ),
 643                                                 typestring,
 644                                                 namestring
 645                                         );
 646                                         notif_error = true;
 647                                 }
 648                         }
 649                 }
 650
 651 void Create_Notification_Entity_Multi(entity notif,
 652                                                                                 float var_cvar,
 653                                                                                 string namestring,
 654                                                                                 /* MSG_MULTI */
 655                                                                                 Notification anncename,
 656                                                                                 Notification infoname,
 657                                                                                 Notification centername)
 658                 {
 659                         MSG typeId = MSG_MULTI;
 660                         // Set MSG_MULTI string/float counts
 661                         if (!anncename && !infoname && !centername)
 662                         {
 663                                 string typestring = Get_Notif_TypeName(typeId);
 664                                 LOG_INFOF(
 665                                         (
 666                                                 "^1NOTIFICATION WITH NO SUBCALLS: "
 667                                                 "^7net_type = %s, net_name = %s."
 668                                         ),
 669                                         typestring,
 670                                         namestring
 671                                 );
 672                                 notif_error = true;
 673                         }
 674                         else
 675                         {
 676                                 // announcements don't actually need any arguments, so lets not even count them.
 677                                 if (anncename) { notif.nent_msgannce = anncename; }
 678
 679                                 float infoname_stringcount = 0, infoname_floatcount = 0;
 680                                 float centername_stringcount = 0, centername_floatcount = 0;
 681
 682                                 if (infoname)
 683                                 {
 684                                         notif.nent_msginfo = infoname;
 685                                         infoname_stringcount = notif.nent_msginfo.nent_stringcount;
 686                                         infoname_floatcount = notif.nent_msginfo.nent_floatcount;
 687                                 }
 688
 689                                 if (centername)
 690                                 {
 691                                         notif.nent_msgcenter = centername;
 692                                         centername_stringcount = notif.nent_msgcenter.nent_stringcount;
 693                                         centername_floatcount = notif.nent_msgcenter.nent_floatcount;
 694                                 }
 695
 696                                 // set the requirements of THIS notification to the totals of its subcalls
 697                                 notif.nent_stringcount = max(infoname_stringcount, centername_stringcount);
 698                                 notif.nent_floatcount = max(infoname_floatcount, centername_floatcount);
 699                         }
 700                 }
 701
 702 void Create_Notification_Entity_Choice(entity notif,
 703                                                                                 float var_cvar,
 704                                                                                 string namestring,
 705                                                                                 /* MSG_CHOICE */
 706                                                                                 float challow_def,
 707                                                                                 float challow_var,
 708                                                                                 MSG chtype,
 709                                                                                 Notification optiona,
 710                                                                                 Notification optionb)
 711                 {
 712                         MSG typeId = MSG_CHOICE;
 713                         if (chtype == MSG_Null || !optiona || !optionb)
 714                         {
 715                                 string typestring = Get_Notif_TypeName(typeId);
 716                                 LOG_INFOF(
 717                                         (
 718                                                 "^1NOTIFICATION IS MISSING CHOICE PARAMS: "
 719                                                 "^7net_type = %s, net_name = %s."
 720                                         ),
 721                                         typestring,
 722                                         namestring
 723                                 );
 724                                 notif_error = true;
 725                         }
 726                         else
 727                         {
 728                                 notif.nent_optiona = optiona;
 729                                 notif.nent_optionb = optionb;
 730                                 notif.nent_challow_def = challow_def; // 0: never allowed, 1: allowed in warmup, 2: always allowed
 731                                 notif.nent_challow_var = challow_var; // 0: never allowed, 1: allowed in warmup, 2: always allowed
 732                                 notif.nent_stringcount = max(notif.nent_optiona.nent_stringcount, notif.nent_optionb.nent_stringcount);
 733                                 notif.nent_floatcount = max(notif.nent_optiona.nent_floatcount, notif.nent_optionb.nent_floatcount);
 734
 735                                 /*#ifdef NOTIFICATIONS_DEBUG
 736                                 Debug_Notification(sprintf(
 737                                         "Create_Notification_Entity(...): MSG_CHOICE: %s\n%s\n%s\n",
 738                                         notif.nent_name,
 739                                         sprintf(
 740                                                 "^ optiona: %s %s : %d %d",
 741                                                 Get_Notif_TypeName(notif.nent_optiona.nent_type),
 742                                                 notif.nent_optiona.nent_name,
 743                                                 notif.nent_optiona.nent_stringcount,
 744                                                 notif.nent_optiona.nent_floatcount
 745                                         ),
 746                                         sprintf(
 747                                                 "^ optionb: %s %s : %d %d",
 748                                                 Get_Notif_TypeName(notif.nent_optionb.nent_type),
 749                                                 notif.nent_optionb.nent_name,
 750                                                 notif.nent_optionb.nent_stringcount,
 751                                                 notif.nent_optionb.nent_floatcount
 752                                         )
 753                                 ));
 754                                 #endif*/
 755                         }
 756                 }
 757
 758
 759 // ===============
 760 //  Cvar Handling
 761 // ===============
 762
 763 // used by MSG_CHOICE to build list of choices
 764 #ifdef SVQC
 765 void Notification_GetCvars(entity this, entity store)
 766 {
 767         FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 768                 GetCvars_handleFloat(
 769                         this,
 770                         store,
 771                         get_cvars_s,
 772                         get_cvars_f,
 773                         msg_choice_choices[it.nent_choice_idx],
 774                         sprintf("notification_%s", Get_Notif_CvarName(it))
 775                 );
 776         });
 777 }
 778 #endif
 779
 780 /** used to output notifications.cfg file */
 781 void Dump_Notifications(int fh, bool alsoprint)
 782 {
 783         #define NOTIF_WRITE(str) write_String_To_File(fh, str, alsoprint)
 784
 785         #define NOTIF_WRITE_ENTITY(e, description) \
 786                 NOTIF_WRITE(sprintf( \
 787                         "seta notification_%s \"%d\" \"%s\"\n", \
 788                         Get_Notif_CvarName(e), e.nent_default, description \
 789                 ))
 790
 791         #define NOTIF_WRITE_ENTITY_CHOICE(e, descriptiona, descriptionb) \
 792                 NOTIF_WRITE(sprintf( \
 793                         "seta notification_%s \"%d\" \"%s\"\n" \
 794                         "seta notification_%s_ALLOWED \"%d\" \"%s\"\n", \
 795                         Get_Notif_CvarName(e), e.nent_default, descriptiona, \
 796                         Get_Notif_CvarName(e), e.nent_challow_def, descriptionb \
 797                 ))
 798
 799         #define NOTIF_WRITE_HARDCODED(cvar, default, description) \
 800                 NOTIF_WRITE("seta notification_" cvar " \"" default "\" \"" description "\"\n")
 801
 802         // Note: This warning only applies to the notifications.cfg file that is output...
 803         // You ARE supposed to manually edit this function to add i.e. hard coded
 804         // notification variables for mutators or game modes or such and then
 805         // regenerate the notifications.cfg file from the new code.
 806
 807         NOTIF_WRITE(
 808                 "// ********************************************** //\n"
 809                 "// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n"
 810                 "// **                                          ** //\n"
 811                 "// **  This file is automatically generated    ** //\n"
 812                 "// **  by code with the command 'dumpnotifs'.  ** //\n"
 813                 "// **                                          ** //\n"
 814                 "// **  If you add a new notification, please   ** //\n"
 815                 "// **  regenerate this file with that command  ** //\n"
 816                 "// **  making sure that the output matches     ** //\n"
 817                 "// **  with the lists and defaults in code.    ** //\n"
 818                 "// **                                          ** //\n"
 819                 "// ********************************************** //\n");
 820
 821         // These notifications will also append their string as a comment...
 822         // This is not necessary, and does not matter if they vary between config versions,
 823         // it is just a semi-helpful tool for those who want to manually change their user settings.
 824
 825         int NOTIF_ANNCE_COUNT = 0;
 826         int NOTIF_INFO_COUNT = 0;
 827         int NOTIF_CENTER_COUNT = 0;
 828         int NOTIF_MULTI_COUNT = 0;
 829         int NOTIF_CHOICE_COUNT = 0;
 830         FOREACH(Notifications, true, {
 831                 switch (it.nent_type)
 832                 {
 833                         case MSG_ANNCE: ++NOTIF_ANNCE_COUNT; break;
 834                         case MSG_INFO: ++NOTIF_INFO_COUNT; break;
 835                         case MSG_CENTER: ++NOTIF_CENTER_COUNT; break;
 836                         case MSG_MULTI: ++NOTIF_MULTI_COUNT; break;
 837                         case MSG_CHOICE: ++NOTIF_CHOICE_COUNT; break;
 838                 }
 839         });
 840
 841         NOTIF_WRITE(sprintf("\n// MSG_ANNCE notifications:\n"));
 842         FOREACH(Notifications, it.nent_type == MSG_ANNCE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 843                 NOTIF_WRITE_ENTITY(it,
 844                         "0 = disabled, 1 = enabled if gentle mode is off, 2 = always enabled"
 845                 );
 846         });
 847
 848         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications:\n"));
 849         FOREACH(Notifications, it.nent_type == MSG_INFO && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 850                 NOTIF_WRITE_ENTITY(it,
 851                         "0 = off, 1 = print to console, "
 852                         "2 = print to console and chatbox (if notification_allow_chatboxprint is enabled)"
 853                 );
 854         });
 855
 856         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications:\n"));
 857         FOREACH(Notifications, it.nent_type == MSG_CENTER && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 858                 NOTIF_WRITE_ENTITY(it,
 859                         "0 = off, 1 = centerprint"
 860                 );
 861         });
 862
 863         NOTIF_WRITE(sprintf("\n// MSG_MULTI notifications:\n"));
 864         FOREACH(Notifications, it.nent_type == MSG_MULTI && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 865                 NOTIF_WRITE_ENTITY(it,
 866                         "Enable this multiple notification"
 867                 );
 868         });
 869
 870         NOTIF_WRITE(sprintf("\n// MSG_CHOICE notifications:\n"));
 871         FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 872                 NOTIF_WRITE_ENTITY_CHOICE(it,
 873                         "Choice for this notification 0 = off, 1 = default message, 2 = verbose message",
 874                         "Allow choice for this notification 0 = off, 1 = only in warmup mode, 2 = always"
 875                 );
 876         });
 877
 878         // edit these to match whichever cvars are used for specific notification options
 879         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
 880
 881         NOTIF_WRITE_HARDCODED(
 882                 "allow_chatboxprint", "1",
 883                 "Allow INFO notifications to be printed to chat box "
 884                 "0 = do not allow, "
 885                 "1 = allow only if allowed by individual notification_INFO* cvars, "
 886                 "2 = force all INFO notifications to be printed to the chatbox"
 887         );
 888
 889         NOTIF_WRITE_HARDCODED(
 890                 "debug", "0",
 891                 "Print extra debug information on all notification function calls "
 892                 "(Requires -DNOTIFICATIONS_DEBUG flag to be enabled on QCSRC compilation)... "
 893                 "0 = disabled, 1 = dprint, 2 = print"
 894         );
 895
 896         NOTIF_WRITE_HARDCODED(
 897                 "errors_are_fatal", "1",
 898                 "If a notification fails upon initialization, cause a Host_Error to stop the program"
 899         );
 900
 901         NOTIF_WRITE_HARDCODED(
 902                 "item_centerprinttime", "1.5",
 903                 "How long to show item information centerprint messages (like 'You got the Electro' or such)"
 904         );
 905
 906         NOTIF_WRITE_HARDCODED(
 907                 "lifetime_mapload", "10",
 908                 "Amount of time that notification entities last immediately at mapload (in seconds) "
 909                 "to help prevent notifications from being lost on early init (like gamestart countdown)"
 910         );
 911
 912         NOTIF_WRITE_HARDCODED(
 913                 "lifetime_runtime", "0.5",
 914                 "Amount of time that notification entities last on the server during runtime (In seconds)"
 915         );
 916
 917         NOTIF_WRITE_HARDCODED(
 918                 "server_allows_location", "1",
 919                 "Server side cvar for allowing death messages to show location information too"
 920         );
 921
 922         NOTIF_WRITE_HARDCODED(
 923                 "show_location", "0",
 924                 "Append location information to MSG_INFO death/kill messages"
 925         );
 926
 927         NOTIF_WRITE_HARDCODED(
 928                 "show_location_string", "",
 929                 "Replacement string piped into sprintf, "
 930                 "so you can do different messages like this: ' at the %s' or ' (near %s)'"
 931         );
 932
 933         NOTIF_WRITE_HARDCODED(
 934                 "show_sprees", "1",
 935                 "Print information about sprees in death/kill messages"
 936         );
 937
 938         NOTIF_WRITE_HARDCODED(
 939                 "show_sprees_center", "1",
 940                 "Show spree information in MSG_CENTER messages... "
 941                 "0 = off, 1 = target (but only for first victim) and attacker"
 942         );
 943
 944         NOTIF_WRITE_HARDCODED(
 945                 "show_sprees_center_specialonly", "1",
 946                 "Don't show spree information in MSG_CENTER messages if it isn't an achievement"
 947         );
 948
 949         NOTIF_WRITE_HARDCODED(
 950                 "show_sprees_info", "3",
 951                 "Show spree information in MSG_INFO messages... "
 952                 "0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker"
 953         );
 954
 955         NOTIF_WRITE_HARDCODED(
 956                 "show_sprees_info_newline", "1",
 957                 "Show attacker spree information for MSG_INFO messages on a separate line than the death notification itself"
 958         );
 959
 960         NOTIF_WRITE_HARDCODED(
 961                 "show_sprees_info_specialonly", "1",
 962                 "Don't show attacker spree information in MSG_INFO messages if it isn't an achievement"
 963         );
 964
 965         LOG_INFOF("Notification counts (total = %d): "
 966                 "MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d, MSG_CHOICE = %d\n",
 967                 (
 968                         NOTIF_ANNCE_COUNT +
 969                         NOTIF_INFO_COUNT +
 970                         NOTIF_CENTER_COUNT +
 971                         NOTIF_MULTI_COUNT +
 972                         NOTIF_CHOICE_COUNT
 973                 ),
 974                 NOTIF_ANNCE_COUNT,
 975                 NOTIF_INFO_COUNT,
 976                 NOTIF_CENTER_COUNT,
 977                 NOTIF_MULTI_COUNT,
 978                 NOTIF_CHOICE_COUNT
 979         );
 980         #undef NOTIF_WRITE_HARDCODED
 981         #undef NOTIF_WRITE_ENTITY
 982         #undef NOTIF_WRITE
 983 }
 984
 985
 986 // ===============================
 987 //  Frontend Notification Pushing
 988 // ===============================
 989
 990 string Local_Notification_sprintf(
 991         string input, string args,
 992         string s1, string s2, string s3, string s4,
 993         int f1, float f2, float f3, float f4)
 994 {
 995         #ifdef NOTIFICATIONS_DEBUG
 996         Debug_Notification(sprintf(
 997                 "Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
 998                 MakeConsoleSafe(input),
 999                 args,
1000                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1001                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1002         ));
1003         #endif
1004
1005         for (int sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
1006
1007         for (int sel_num = 0; (args != ""); )
1008         {
1009                 string selected = car(args); args = cdr(args);
1010                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf");
1011                 string tmp_s; // used by NOTIF_ARGUMENT_LIST
1012                 switch (strtolower(selected))
1013                 {
1014                         #define ARG_CASE_ARG_CS_SV_HA(selected, result) case selected: arg_slot[sel_num++] = result; break;
1015                         #define ARG_CASE_ARG_CS_SV_DC(selected, result) case selected: arg_slot[sel_num++] = result; break;
1016                         #define ARG_CASE_ARG_CS_SV(selected, result)    case selected: arg_slot[sel_num++] = result; break;
1017 #ifdef CSQC
1018                         #define ARG_CASE_ARG_CS(selected, result)       case selected: arg_slot[sel_num++] = result; break;
1019                         #define ARG_CASE_ARG_SV(selected, result)
1020 #else
1021                         #define ARG_CASE_ARG_CS(selected, result)
1022                         #define ARG_CASE_ARG_SV(selected, result)       case selected: arg_slot[sel_num++] = result; break;
1023 #endif
1024                         #define ARG_CASE_ARG_DC(selected, result)
1025                         #define ARG_CASE(prog, selected, result)        ARG_CASE_##prog(selected, result)
1026                         NOTIF_ARGUMENT_LIST
1027                         #undef ARG_CASE
1028                         #undef ARG_CASE_ARG_DC
1029                         #undef ARG_CASE_ARG_SV
1030                         #undef ARG_CASE_ARG_CS
1031                         #undef ARG_CASE_ARG_CS_SV
1032                         #undef ARG_CASE_ARG_CS_SV_DC
1033                         #undef ARG_CASE_ARG_CS_SV_HA
1034                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
1035                 }
1036         }
1037         return sprintf(
1038                 strcat(input, "\n"),
1039                 arg_slot[0],
1040                 arg_slot[1],
1041                 arg_slot[2],
1042                 arg_slot[3],
1043                 arg_slot[4],
1044                 arg_slot[5],
1045                 arg_slot[6]
1046         );
1047 }
1048
1049 #ifdef CSQC
1050 void Local_Notification_sound(int soundchannel, string soundfile, float soundvolume, float soundposition)
1051 {
1052         if ((soundfile != prev_soundfile) || (time >= (prev_soundtime + autocvar_cl_announcer_antispam)))
1053         {
1054                 #ifdef NOTIFICATIONS_DEBUG
1055                 Debug_Notification(sprintf(
1056                         "Local_Notification_sound(%f, '%s', %f, %f);\n",
1057                         soundchannel,
1058                         AnnouncerFilename(soundfile),
1059                         soundvolume,
1060                         soundposition
1061                 ));
1062                 #endif
1063
1064                 _sound(NULL, soundchannel, AnnouncerFilename(soundfile), soundvolume, soundposition);
1065
1066                 strcpy(prev_soundfile, soundfile);
1067                 prev_soundtime = time;
1068         }
1069         else
1070         {
1071                 #ifdef NOTIFICATIONS_DEBUG
1072                 Debug_Notification(sprintf(
1073                         (
1074                                 "Local_Notification_sound(%f, '%s', %f, %f) "
1075                                 "^1BLOCKED BY ANTISPAM:^7 prevsnd: '%s', timediff: %f, limit: %f\n"
1076                         ),
1077                         soundchannel,
1078                         AnnouncerFilename(soundfile),
1079                         soundvolume,
1080                         soundposition,
1081                         prev_soundfile,
1082                         (time - prev_soundtime),
1083                         autocvar_cl_announcer_antispam
1084                 ));
1085                 #endif
1086         }
1087 }
1088
1089 void Local_Notification_HUD_Notify_Push(
1090         string icon, string hudargs,
1091         string s1, string s2, string s3, string s4,
1092         float f1, float f2, float f3, float f4)
1093 {
1094         arg_slot[0] = ""; arg_slot[1] = "";
1095
1096         for (int sel_num = 0; (hudargs != ""); )
1097         {
1098                 string selected = car(hudargs); hudargs = cdr(hudargs);
1099                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push");
1100                 switch (strtolower(selected))
1101                 {
1102                         #define ARG_CASE_ARG_CS_SV_HA(selected, result) case selected: arg_slot[sel_num++] = result; break;
1103                         #define ARG_CASE_ARG_CS_SV_DC(selected, result)
1104                         #define ARG_CASE_ARG_CS_SV(selected, result)
1105                         #define ARG_CASE_ARG_CS(selected, result)
1106                         #define ARG_CASE_ARG_SV(selected, result)
1107                         #define ARG_CASE_ARG_DC(selected, result)
1108                         #define ARG_CASE(prog, selected, result)        ARG_CASE_##prog(selected, result)
1109                         NOTIF_ARGUMENT_LIST
1110                         #undef ARG_CASE
1111                         #undef ARG_CASE_ARG_DC
1112                         #undef ARG_CASE_ARG_SV
1113                         #undef ARG_CASE_ARG_CS
1114                         #undef ARG_CASE_ARG_CS_SV
1115                         #undef ARG_CASE_ARG_CS_SV_DC
1116                         #undef ARG_CASE_ARG_CS_SV_HA
1117                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
1118                 }
1119         }
1120         #ifdef NOTIFICATIONS_DEBUG
1121         Debug_Notification(sprintf(
1122                 "Local_Notification_HUD_Notify_Push('%s^7', '%s', %s, %s, %s);\n",
1123                 icon,
1124                 hudargs,
1125                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1126                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4),
1127                 MakeConsoleSafe(sprintf("'%s^7', '%s^7'", stof(arg_slot[0]), stof(arg_slot[1])))
1128         ));
1129         #endif
1130         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
1131 }
1132
1133 void Local_Notification_centerprint_Add(
1134         string input, string durcnt,
1135         CPID cpid, float f1, float f2)
1136 {
1137         arg_slot[0] = ""; arg_slot[1] = "";
1138
1139         for (int sel_num = 0; (durcnt != ""); )
1140         {
1141                 string selected = car(durcnt); durcnt = cdr(durcnt);
1142                 NOTIF_HIT_MAX(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_Add");
1143                 switch (strtolower(selected))
1144                 {
1145                         #define ARG_CASE_ARG_CS_SV_HA(selected, result)
1146                         #define ARG_CASE_ARG_CS_SV_DC(selected, result) case selected: arg_slot[sel_num++] = result; break;
1147                         #define ARG_CASE_ARG_CS_SV(selected, result)
1148                         #define ARG_CASE_ARG_CS(selected, result)
1149                         #define ARG_CASE_ARG_SV(selected, result)
1150                         #define ARG_CASE_ARG_DC(selected, result)       case selected: arg_slot[sel_num++] = result; break;
1151                         #define ARG_CASE(prog, selected, result)        ARG_CASE_##prog(selected,result)
1152                         NOTIF_ARGUMENT_LIST
1153                         #undef ARG_CASE
1154                         #undef ARG_CASE_ARG_DC
1155                         #undef ARG_CASE_ARG_SV
1156                         #undef ARG_CASE_ARG_CS
1157                         #undef ARG_CASE_ARG_CS_SV
1158                         #undef ARG_CASE_ARG_CS_SV_DC
1159                         #undef ARG_CASE_ARG_CS_SV_HA
1160                         default:
1161                         {
1162                                 if (/* wtf */ ftos(stof(selected)) != "") { arg_slot[sel_num++] = selected; }
1163                                 else { NOTIF_HIT_UNKNOWN(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_Add") }
1164                                 break;
1165                         }
1166                 }
1167         }
1168         #ifdef NOTIFICATIONS_DEBUG
1169         Debug_Notification(sprintf(
1170                 "Local_Notification_centerprint_Add('%s^7', '%s', %d, %d, %d, %d);\n",
1171                 MakeConsoleSafe(input),
1172                 durcnt,
1173                 f1, f2,
1174                 stof(arg_slot[0]),
1175                 stof(arg_slot[1])
1176         ));
1177         #endif
1178         centerprint_Add(ORDINAL(cpid), input, stof(arg_slot[0]), stof(arg_slot[1]));
1179 }
1180 #endif
1181
1182 void Local_Notification(MSG net_type, Notification net_name, ...count)
1183 {
1184         // retreive entity of this notification
1185         entity notif = net_name;
1186         if (!notif)
1187         {
1188                 #ifdef NOTIFICATIONS_DEBUG
1189                 Debug_Notification(sprintf(
1190                         "Local_Notification(%s, NULL, ...);\n",
1191                         Get_Notif_TypeName(net_type)
1192                 ));
1193                 #endif
1194                 LOG_WARNF("Incorrect usage of Local_Notification: %s", "Null notification");
1195                 return;
1196         }
1197
1198         // check if the notification is enabled
1199         if (!notif.nent_enabled)
1200         {
1201                 #ifdef NOTIFICATIONS_DEBUG
1202                 Debug_Notification(sprintf(
1203                         "Local_Notification(%s, %s, ...): Entity was disabled...\n",
1204                         Get_Notif_TypeName(net_type),
1205                         notif.nent_name
1206                 ));
1207                 #endif
1208                 return;
1209         }
1210
1211         string s1 = CCR((notif.nent_stringcount > 0) ? ...(0, string) : "");
1212         string s2 = CCR((notif.nent_stringcount > 1) ? ...(1, string) : "");
1213         string s3 = CCR((notif.nent_stringcount > 2) ? ...(2, string) : "");
1214         string s4 = CCR((notif.nent_stringcount > 3) ? ...(3, string) : "");
1215         float f1 =  ((notif.nent_floatcount  > 0) ? ...((notif.nent_stringcount + 0), float) : 0);
1216         float f2 =  ((notif.nent_floatcount  > 1) ? ...((notif.nent_stringcount + 1), float) : 0);
1217         float f3 =  ((notif.nent_floatcount  > 2) ? ...((notif.nent_stringcount + 2), float) : 0);
1218         float f4 =  ((notif.nent_floatcount  > 3) ? ...((notif.nent_stringcount + 3), float) : 0);
1219
1220         #ifdef NOTIFICATIONS_DEBUG
1221         Debug_Notification(sprintf(
1222                 "Local_Notification(%s, %s, %s, %s);\n",
1223                 Get_Notif_TypeName(net_type),
1224                 notif.nent_name,
1225                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1226                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1227         ));
1228         #endif
1229
1230         if ((notif.nent_stringcount + notif.nent_floatcount) != count)
1231         {
1232                 backtrace(sprintf(
1233                         (
1234                                 "Arguments mismatch for Local_Notification(%s, %s, ...)! "
1235                                 "stringcount(%d) + floatcount(%d) != count(%d)\n"
1236                                 "Check the definition and function call for accuracy...?\n"
1237                         ),
1238                         Get_Notif_TypeName(net_type),
1239                         notif.nent_name,
1240                         notif.nent_stringcount,
1241                         notif.nent_floatcount,
1242                         count
1243                 ));
1244                 return;
1245         }
1246
1247         switch (net_type)
1248         {
1249                 case MSG_ANNCE:
1250                 {
1251                         #ifdef CSQC
1252                         Local_Notification_sound(notif.nent_channel, notif.nent_snd, notif.nent_vol, notif.nent_position);
1253                         #else
1254                         backtrace("MSG_ANNCE on server?... Please notify Samual immediately!\n");
1255                         #endif
1256                         break;
1257                 }
1258
1259                 case MSG_INFO:
1260                 {
1261                         print(
1262                                 Local_Notification_sprintf(
1263                                         notif.nent_string,
1264                                         notif.nent_args,
1265                                         s1, s2, s3, s4,
1266                                         f1, f2, f3, f4)
1267                         );
1268                         #ifdef CSQC
1269                         if (notif.nent_icon != "")
1270                         {
1271                                 if (notif.nent_iconargs != "")
1272                                 {
1273                                         string s = Local_Notification_sprintf(
1274                                                 notif.nent_icon,notif.nent_iconargs,
1275                                                 s1, s2, s3, s4, f1, f2, f3, f4);
1276                                         // remove the trailing newline
1277                                         notif.nent_icon = strzone(substring(s, 0, -1));
1278                                 }
1279                                 Local_Notification_HUD_Notify_Push(
1280                                         notif.nent_icon,
1281                                         notif.nent_hudargs,
1282                                         s1, s2, s3, s4,
1283                                         f1, f2, f3, f4);
1284                         }
1285                         #endif
1286                         break;
1287                 }
1288
1289                 #ifdef CSQC
1290                 case MSG_CENTER:
1291                 {
1292                         Local_Notification_centerprint_Add(
1293                                 Local_Notification_sprintf(
1294                                         notif.nent_string,
1295                                         notif.nent_args,
1296                                         s1, s2, s3, s4,
1297                                         f1, f2, f3, f4),
1298                                 notif.nent_durcnt,
1299                                 notif.nent_cpid,
1300                                 f1, f2);
1301                         break;
1302                 }
1303                 #endif
1304
1305                 case MSG_MULTI:
1306                 {
1307                         if (notif.nent_msginfo && notif.nent_msginfo.nent_enabled)
1308                         {
1309                                 Local_Notification_WOVA(
1310                                         MSG_INFO,
1311                                         notif.nent_msginfo,
1312                                         notif.nent_msginfo.nent_stringcount,
1313                                         notif.nent_msginfo.nent_floatcount,
1314                                         s1, s2, s3, s4,
1315                                         f1, f2, f3, f4);
1316                         }
1317                         #ifdef CSQC
1318                         if (notif.nent_msgannce && notif.nent_msgannce.nent_enabled)
1319                         {
1320                                 Local_Notification_WOVA(
1321                                         MSG_ANNCE,
1322                                         notif.nent_msgannce,
1323                                         0, 0,
1324                                         "", "", "", "",
1325                                         0, 0, 0, 0);
1326                         }
1327                         if (notif.nent_msgcenter && notif.nent_msgcenter.nent_enabled)
1328                         {
1329                                 Local_Notification_WOVA(
1330                                         MSG_CENTER,
1331                                         notif.nent_msgcenter,
1332                                         notif.nent_msgcenter.nent_stringcount,
1333                                         notif.nent_msgcenter.nent_floatcount,
1334                                         s1, s2, s3, s4,
1335                                         f1, f2, f3, f4);
1336                         }
1337                         #endif
1338                         break;
1339                 }
1340
1341                 case MSG_CHOICE:
1342                 {
1343                         entity found_choice = notif.nent_optiona;
1344                         if (notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2))) {
1345                                 switch (cvar(sprintf("notification_%s", Get_Notif_CvarName(notif))))
1346                                 {
1347                                         case 1: break;
1348                                         case 2: found_choice = notif.nent_optionb; break;
1349                                         default: return; // not enabled anyway
1350                                 }
1351                         }
1352
1353                         Local_Notification_WOVA(
1354                                 found_choice.nent_type,
1355                                 found_choice,
1356                                 found_choice.nent_stringcount,
1357                                 found_choice.nent_floatcount,
1358                                 s1, s2, s3, s4,
1359                                 f1, f2, f3, f4);
1360                 }
1361         }
1362 }
1363
1364 // WOVA = Without Variable Arguments
1365 void Local_Notification_WOVA(
1366         MSG net_type, Notification net_name,
1367         float stringcount, float floatcount,
1368         string s1, string s2, string s3, string s4,
1369         float f1, float f2, float f3, float f4)
1370 {
1371         #define VARITEM(stringc, floatc, args) \
1372                 if ((stringcount == stringc) && (floatcount == floatc)) \
1373                 { Local_Notification(net_type, net_name, args); return; }
1374         EIGHT_VARS_TO_VARARGS_VARLIST
1375         #undef VARITEM
1376         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
1377 }
1378
1379
1380 // =========================
1381 //  Notification Networking
1382 // =========================
1383
1384 /** networked as a linked entity to give newly connecting clients some notification context */
1385 REGISTER_NET_LINKED(ENT_CLIENT_NOTIFICATION)
1386
1387 #ifdef CSQC
1388 NET_HANDLE(ENT_CLIENT_NOTIFICATION, bool is_new)
1389 {
1390         make_pure(this);
1391         MSG net_type = ENUMCAST(MSG, ReadByte());
1392         int net_name = ReadShort();
1393     return = true;
1394
1395         if (net_type == MSG_CENTER_KILL)
1396     {
1397         if (!is_new) return;
1398         // killing
1399         #ifdef NOTIFICATIONS_DEBUG
1400         Debug_Notification(sprintf(
1401             "Read_Notification(%d) at %f: net_type = %s, cpid = %d\n",
1402             is_new,
1403             time,
1404             Get_Notif_TypeName(net_type),
1405             net_name
1406         ));
1407         #endif
1408         int _net_name = net_name;
1409         CPID net_name = ENUMCAST(CPID, _net_name);
1410         if (net_name == CPID_Null) {
1411             centerprint_KillAll();
1412         } else {
1413             centerprint_Kill(ORDINAL(net_name));// kill group
1414         }
1415         return;
1416     }
1417
1418         Notification notif = Get_Notif_Ent(net_type, net_name);
1419
1420         #ifdef NOTIFICATIONS_DEBUG
1421         Debug_Notification(sprintf(
1422                 "Read_Notification(%d) at %f: net_type = %s, net_name = %s (%d)\n",
1423                 is_new,
1424                 time,
1425                 Get_Notif_TypeName(net_type),
1426                 notif.registered_id,
1427                 net_name
1428         ));
1429         #endif
1430
1431     if (!notif) {
1432         backtrace("Read_Notification: Could not find notification entity!\n");
1433         return false;
1434     }
1435
1436     string s1 = ((notif.nent_stringcount > 0) ? ReadString() : "");
1437     string s2 = ((notif.nent_stringcount > 1) ? ReadString() : "");
1438     string s3 = ((notif.nent_stringcount > 2) ? ReadString() : "");
1439     string s4 = ((notif.nent_stringcount > 3) ? ReadString() : "");
1440     float f1 = ((notif.nent_floatcount > 0) ? ReadLong() : 0);
1441     float f2 = ((notif.nent_floatcount > 1) ? ReadLong() : 0);
1442     float f3 = ((notif.nent_floatcount > 2) ? ReadLong() : 0);
1443     float f4 = ((notif.nent_floatcount > 3) ? ReadLong() : 0);
1444
1445     if (!is_new) return;
1446     Local_Notification_WOVA(
1447         net_type, notif,
1448         notif.nent_stringcount,
1449         notif.nent_floatcount,
1450         s1, s2, s3, s4,
1451         f1, f2, f3, f4);
1452 }
1453 #endif
1454
1455 #ifdef SVQC
1456 void Net_Notification_Remove(entity this)
1457 {
1458         #ifdef NOTIFICATIONS_DEBUG
1459         Debug_Notification(sprintf(
1460                 "Net_Notification_Remove() at %f: %s '%s - %s' notification\n",
1461                 time,
1462                 ((this.nent_net_name == -1) ? "Killed" : "Removed"),
1463                 Get_Notif_TypeName(this.nent_net_type),
1464                 this.owner.nent_name
1465         ));
1466         #endif
1467         for (int i = 0; i < this.nent_stringcount; ++i) { strfree(this.nent_strings[i]); }
1468         delete(this);
1469 }
1470
1471 bool Net_Write_Notification(entity this, entity client, int sf)
1472 {
1473         if (!Notification_ShouldSend(this.nent_broadcast, client, this.nent_client)) return false;
1474         WriteHeader(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
1475         WriteByte(MSG_ENTITY, ORDINAL(this.nent_net_type));
1476         WriteShort(MSG_ENTITY, this.nent_net_name);
1477         for (int i = 0; i < this.nent_stringcount; ++i) { WriteString(MSG_ENTITY, this.nent_strings[i]); }
1478         for (int i = 0; i < this.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, this.nent_floats[i]); }
1479         return true;
1480 }
1481
1482 void Kill_Notification(
1483         NOTIF broadcast, entity client,
1484         /** message group, MSG_Null for all */
1485         MSG net_type,
1486         /** cpid group, CPID_Null for all */
1487         CPID net_cpid)
1488 {
1489         #ifdef NOTIFICATIONS_DEBUG
1490         Debug_Notification(sprintf(
1491                 "Kill_Notification(%s, '%s', %s, %d);\n",
1492                 Get_Notif_BroadcastName(broadcast),
1493                 client.netname,
1494                 (net_type ? Get_Notif_TypeName(net_type) : "0"),
1495                 net_cpid
1496         ));
1497         #endif
1498
1499         string checkargs = Notification_CheckArgs(broadcast, client);
1500         if (checkargs != "") { LOG_WARNF("Incorrect usage of Kill_Notification: %s", checkargs); return; }
1501
1502         entity net_notif = new_pure(net_kill_notification);
1503         net_notif.nent_broadcast = broadcast;
1504         net_notif.nent_client = client;
1505         net_notif.nent_net_type = MSG_CENTER_KILL;
1506         net_notif.nent_net_name = ORDINAL(net_cpid);
1507         Net_LinkEntity(net_notif, false, autocvar_notification_lifetime_runtime, Net_Write_Notification);
1508
1509         IL_EACH(g_notifications,
1510                 (it.owner.nent_type == net_type || net_type == MSG_Null) && (it.owner.nent_cpid == net_cpid || net_cpid == CPID_Null),
1511                 {
1512                         it.nent_net_name = -1;
1513                         it.nextthink = time;
1514                 }
1515         );
1516 }
1517
1518 void Send_Notification(
1519         NOTIF broadcast, entity client,
1520         MSG net_type, Notification net_name,
1521         ...count)
1522 {
1523     if (broadcast == NOTIF_ONE_ONLY && !IS_REAL_CLIENT(client)) return;
1524         entity notif = net_name;
1525         string parms = sprintf("%s, '%s', %s, %s",
1526                 Get_Notif_BroadcastName(broadcast),
1527                 client.classname,
1528                 Get_Notif_TypeName(net_type),
1529                 net_name.registered_id
1530         );
1531         #ifdef NOTIFICATIONS_DEBUG
1532         Debug_Notification(sprintf("Send_Notification(%s, ...%d);\n", parms, count));
1533         #endif
1534
1535         if (!notif)
1536         {
1537                 LOG_WARN("Send_Notification: Could not find notification entity!");
1538                 return;
1539         }
1540
1541         // check supplied broadcast, target, type, and name for errors
1542         string checkargs = Notification_CheckArgs(broadcast, client);
1543     if (!net_name) { checkargs = sprintf("No notification provided! %s", checkargs); }
1544         if (checkargs != "")
1545         {
1546                 LOG_WARNF("Incorrect usage of Send_Notification: %s", checkargs);
1547                 return;
1548         }
1549
1550         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1551         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1552         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1553         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1554         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1555         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1556         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1557         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1558
1559         #ifdef NOTIFICATIONS_DEBUG
1560         Debug_Notification(sprintf(
1561                 "Send_Notification(%s, %s, %s);\n",
1562                 parms,
1563                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1564                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1565         ));
1566         #endif
1567
1568         if ((notif.nent_stringcount + notif.nent_floatcount) != count)
1569         {
1570                 LOG_WARNF(
1571                         "Argument mismatch for Send_Notification(%s, ...)! "
1572                         "stringcount(%d) + floatcount(%d) != count(%d)\n"
1573                         "Check the definition and function call for accuracy...?\n",
1574                         parms,
1575                         notif.nent_stringcount,
1576                         notif.nent_floatcount,
1577                         count
1578                 );
1579                 return;
1580         }
1581
1582         if (server_is_dedicated
1583                 && (broadcast == NOTIF_ALL || broadcast == NOTIF_ALL_EXCEPT)
1584                 && !(net_type == MSG_ANNCE || net_type == MSG_CENTER)
1585         )
1586         {
1587                 Local_Notification_WOVA(
1588                         net_type, net_name,
1589                         notif.nent_stringcount,
1590                         notif.nent_floatcount,
1591                         s1, s2, s3, s4,
1592                         f1, f2, f3, f4);
1593         }
1594
1595         if (net_type == MSG_CHOICE)
1596         {
1597                 // THIS GETS TRICKY... now we have to cycle through each possible player (checking broadcast)
1598                 // and then do an individual NOTIF_ONE_ONLY recursive call for each one depending on their option...
1599                 // It's slow, but it's better than the alternatives:
1600                 //   1. Constantly networking all info and letting client decide
1601                 //   2. Manually handling each separate call on per-usage basis (See old CTF usage of verbose)
1602                 entity found_choice;
1603
1604                 #define RECURSE_FROM_CHOICE(ent,action) MACRO_BEGIN \
1605                         if (notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2))) { \
1606                                 switch (CS_CVAR(ent).msg_choice_choices[net_name.nent_choice_idx]) \
1607                                 { \
1608                                         case 1: found_choice = notif.nent_optiona; break; \
1609                                         case 2: found_choice = notif.nent_optionb; break; \
1610                                         default: action; \
1611                                 } \
1612                         } else { \
1613                                 found_choice = notif.nent_optiona; \
1614                         } \
1615                         Send_Notification_WOVA( \
1616                                 NOTIF_ONE_ONLY, \
1617                                 ent, \
1618                                 found_choice.nent_type, \
1619                                 found_choice, \
1620                                 found_choice.nent_stringcount, \
1621                                 found_choice.nent_floatcount, \
1622                                 s1, s2, s3, s4, \
1623                                 f1, f2, f3, f4); \
1624                 MACRO_END
1625
1626                 switch (broadcast)
1627                 {
1628                         case NOTIF_ONE_ONLY: // we can potentially save processing power with this broadcast method
1629                         {
1630                                 if (IS_REAL_CLIENT(client)) {
1631                                         RECURSE_FROM_CHOICE(client, return);
1632                                 }
1633                                 break;
1634                         }
1635                         default:
1636                         {
1637                                 FOREACH_CLIENT(Notification_ShouldSend(broadcast, it, client), {
1638                                         RECURSE_FROM_CHOICE(it, continue);
1639                                 });
1640                                 break;
1641                         }
1642                 }
1643         }
1644         else
1645         {
1646                 entity net_notif = new_pure(net_notification);
1647                 IL_PUSH(g_notifications, net_notif);
1648                 net_notif.owner = notif;
1649                 net_notif.nent_broadcast = broadcast;
1650                 net_notif.nent_client = client;
1651                 net_notif.nent_net_type = net_type;
1652                 net_notif.nent_net_name = notif.m_id;
1653                 net_notif.nent_stringcount = notif.nent_stringcount;
1654                 net_notif.nent_floatcount = notif.nent_floatcount;
1655
1656                 for (int i = 0; i < net_notif.nent_stringcount; ++i) {
1657                         net_notif.nent_strings[i] = strzone(...(i, string));
1658                 }
1659                 for (int i = 0; i < net_notif.nent_floatcount; ++i) {
1660                         net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float);
1661                 }
1662
1663                 setthink(net_notif, Net_Notification_Remove);
1664                 net_notif.nextthink = (time > autocvar_notification_lifetime_mapload)
1665                         ? (time + autocvar_notification_lifetime_runtime)
1666                         : autocvar_notification_lifetime_mapload;
1667
1668                 Net_LinkEntity(net_notif, false, 0, Net_Write_Notification);
1669         }
1670 }
1671
1672 // WOVA = Without Variable Arguments
1673 void Send_Notification_WOVA(
1674         NOTIF broadcast, entity client,
1675         MSG net_type, Notification net_name,
1676         float stringcount, float floatcount,
1677         string s1, string s2, string s3, string s4,
1678         float f1, float f2, float f3, float f4)
1679 {
1680         #ifdef NOTIFICATIONS_DEBUG
1681         entity notif = net_name;
1682         Debug_Notification(sprintf(
1683                 "Send_Notification_WOVA(%s, %d, %d, %s, %s);\n",
1684                 sprintf(
1685                         "%s, '%s', %s, %s",
1686                         Get_Notif_BroadcastName(broadcast),
1687                         client.classname,
1688                         Get_Notif_TypeName(net_type),
1689                         notif.nent_name
1690                 ),
1691                 stringcount,
1692                 floatcount,
1693                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1694                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1695         ));
1696         #endif
1697
1698         #define VARITEM(stringc, floatc, args) \
1699                 if ((stringcount == stringc) && (floatcount == floatc)) \
1700                 { Send_Notification(broadcast, client, net_type, net_name, args); return; }
1701         EIGHT_VARS_TO_VARARGS_VARLIST
1702         #undef VARITEM
1703         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
1704 }
1705
1706 // WOCOVA = Without Counts Or Variable Arguments
1707 void Send_Notification_WOCOVA(
1708         NOTIF broadcast, entity client,
1709         MSG net_type, Notification net_name,
1710         string s1, string s2, string s3, string s4,
1711         float f1, float f2, float f3, float f4)
1712 {
1713         entity notif = net_name;
1714
1715         #ifdef NOTIFICATIONS_DEBUG
1716         Debug_Notification(sprintf(
1717                 "Send_Notification_WOCOVA(%s, %s, %s);\n",
1718                 sprintf(
1719                         "%s, '%s', %s, %s",
1720                         Get_Notif_BroadcastName(broadcast),
1721                         client.classname,
1722                         Get_Notif_TypeName(net_type),
1723                         notif.nent_name
1724                 ),
1725                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1726                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1727         ));
1728         #endif
1729
1730         #define VARITEM(stringc, floatc, args) \
1731                 if ((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
1732                 { Send_Notification(broadcast, client, net_type, net_name, args); return; }
1733         EIGHT_VARS_TO_VARARGS_VARLIST
1734         #undef VARITEM
1735         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
1736 }
1737 #endif // ifdef SVQC