qcsrc/common/playerstats.qc

   1 #include "playerstats.qh"
   2
   3 #if defined(CSQC)
   4 #elif defined(MENUQC)
   5 #elif defined(SVQC)
   6         #include <common/constants.qh>
   7         #include <common/stats.qh>
   8         #include <common/util.qh>
   9         #include <common/weapons/_all.qh>
  10         #include <server/anticheat.qh>
  11         #include <server/client.qh>
  12         #include <server/intermission.qh>
  13         #include <server/scores.qh>
  14         #include <server/weapons/accuracy.qh>
  15         #include <server/world.qh>
  16 #endif
  17
  18
  19 #ifdef GAMEQC
  20 REPLICATE(cvar_cl_allow_uid2name, int, "cl_allow_uid2name");
  21 REPLICATE(cvar_cl_allow_uidranking, bool, "cl_allow_uidranking");
  22 REPLICATE(cvar_cl_allow_uidtracking, int, "cl_allow_uidtracking");
  23 #endif
  24
  25 #ifdef SVQC
  26 REPLICATE_APPLYCHANGE("cl_allow_uidtracking", { PlayerStats_GameReport_AddPlayer(this); });
  27 #endif
  28
  29 #ifdef SVQC
  30 void PlayerStats_Prematch()
  31 {
  32         //foobar
  33 }
  34
  35 // Deletes current playerstats DB, creates a new one and fully initializes it
  36 void PlayerStats_GameReport_Reset_All()
  37 {
  38         strfree(PS_GR_OUT_TL);
  39         strfree(PS_GR_OUT_PL);
  40         strfree(PS_GR_OUT_EVL);
  41
  42         if (PS_GR_OUT_DB >= 0)
  43         {
  44                 db_close(PS_GR_OUT_DB);
  45                 PlayerStats_GameReport_Init();
  46         }
  47         if(PS_GR_OUT_DB < 0)
  48                 return;
  49
  50         for (int i = 0; i < 16; i++)
  51                 if (teamscorekeepers[i])
  52                         PlayerStats_GameReport_AddTeam(i + 1);
  53         FOREACH_CLIENT(true, {
  54                 // NOTE Adding back a player we are applying any cl_allow_uidtracking change
  55                 // usually only possible by reconnecting to the server
  56                 strfree(it.playerstats_id);
  57                 PlayerStats_GameReport_AddEvent(sprintf("kills-%d", it.playerid));
  58                 PlayerStats_GameReport_AddPlayer(it);
  59         });
  60         FOREACH(Scores, true, {
  61                 string label = scores_label(it);
  62                 if (label == "")
  63                         continue;
  64                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
  65                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
  66         });
  67         for(int i = 0; i < MAX_TEAMSCORE; ++i)
  68         {
  69                 string label = teamscores_label(i);
  70                 if (label == "")
  71                         continue;
  72                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
  73                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
  74         }
  75 }
  76
  77 void PlayerStats_GameReport_AddPlayer(entity e)
  78 {
  79         if((PS_GR_OUT_DB < 0) || (e.playerstats_id)) { return; }
  80
  81         // set up player identification
  82         string s = "";
  83
  84         if((e.crypto_idfp != "") && (CS_CVAR(e).cvar_cl_allow_uidtracking == 1))
  85                 { s = e.crypto_idfp; }
  86         else if(IS_BOT_CLIENT(e))
  87                 { s = sprintf("bot#%g#%s", skill, e.cleanname); }
  88
  89         if((s == "") || find(NULL, playerstats_id, s)) // already have one of the ID - next one can't be tracked then!
  90         {
  91                 if(IS_BOT_CLIENT(e))
  92                         { s = sprintf("bot#%d", e.playerid); }
  93                 else
  94                         { s = sprintf("player#%d", e.playerid); }
  95         }
  96
  97         e.playerstats_id = strzone(s);
  98
  99         // now add the player to the database
 100         string key = sprintf("%s:*", e.playerstats_id);
 101         string p = db_get(PS_GR_OUT_DB, key);
 102
 103         if(p == "")
 104         {
 105                 if(PS_GR_OUT_PL)
 106                 {
 107                         db_put(PS_GR_OUT_DB, key, PS_GR_OUT_PL);
 108                         strunzone(PS_GR_OUT_PL);
 109                 }
 110                 else { db_put(PS_GR_OUT_DB, key, "#"); }
 111                 PS_GR_OUT_PL = strzone(e.playerstats_id);
 112         }
 113 }
 114
 115 void PlayerStats_GameReport_AddTeam(int t)
 116 {
 117         if(PS_GR_OUT_DB < 0) { return; }
 118
 119         string key = sprintf("%d", t);
 120         string p = db_get(PS_GR_OUT_DB, key);
 121
 122         if(p == "")
 123         {
 124                 if(PS_GR_OUT_TL)
 125                 {
 126                         db_put(PS_GR_OUT_DB, key, PS_GR_OUT_TL);
 127                         strunzone(PS_GR_OUT_TL);
 128                 }
 129                 else { db_put(PS_GR_OUT_DB, key, "#"); }
 130                 PS_GR_OUT_TL = strzone(key);
 131         }
 132 }
 133
 134 void PlayerStats_GameReport_AddEvent(string event_id)
 135 {
 136         if(PS_GR_OUT_DB < 0) { return; }
 137
 138         string key = sprintf("*:%s", event_id);
 139         string p = db_get(PS_GR_OUT_DB, key);
 140
 141         if(p == "")
 142         {
 143                 if(PS_GR_OUT_EVL)
 144                 {
 145                         db_put(PS_GR_OUT_DB, key, PS_GR_OUT_EVL);
 146                         strunzone(PS_GR_OUT_EVL);
 147                 }
 148                 else { db_put(PS_GR_OUT_DB, key, "#"); }
 149                 PS_GR_OUT_EVL = strzone(event_id);
 150         }
 151 }
 152
 153 float PlayerStats_GameReport_Event(string prefix, string event_id, float value)
 154 {
 155         if((prefix == "") || PS_GR_OUT_DB < 0) { return 0; }
 156
 157         string key = sprintf("%s:%s", prefix, event_id);
 158         float val = stof(db_get(PS_GR_OUT_DB, key));
 159         val += value;
 160         db_put(PS_GR_OUT_DB, key, ftos(val));
 161         return val;
 162 }
 163
 164 void PlayerStats_GameReport_Accuracy(entity p)
 165 {
 166         #define ACCMAC(suffix, field) \
 167                 PlayerStats_GameReport_Event_Player(p, \
 168                         sprintf("acc-%s-%s", it.netname, suffix), CS(p).accuracy.(field[i-1]));
 169         FOREACH(Weapons, it != WEP_Null, {
 170                 ACCMAC("hit", accuracy_hit)
 171                 ACCMAC("fired", accuracy_fired)
 172                 ACCMAC("cnt-hit", accuracy_cnt_hit)
 173                 ACCMAC("cnt-fired", accuracy_cnt_fired)
 174                 ACCMAC("frags", accuracy_frags)
 175         });
 176         #undef ACCMAC
 177 }
 178
 179 void PlayerStats_GameReport_FinalizePlayer(entity p)
 180 {
 181         if((p.playerstats_id == "") || PS_GR_OUT_DB < 0) { return; }
 182
 183         // add global info!
 184         if(p.alivetime)
 185         {
 186                 PlayerStats_GameReport_Event_Player(p, PLAYERSTATS_ALIVETIME, time - p.alivetime);
 187                 p.alivetime = 0;
 188         }
 189
 190         db_put(PS_GR_OUT_DB, sprintf("%s:_playerid", p.playerstats_id), ftos(p.playerid));
 191
 192         if(CS_CVAR(p).cvar_cl_allow_uid2name == 1 || IS_BOT_CLIENT(p))
 193                 db_put(PS_GR_OUT_DB, sprintf("%s:_netname", p.playerstats_id), playername(p.netname, p.team, false));
 194
 195         if(teamplay)
 196                 db_put(PS_GR_OUT_DB, sprintf("%s:_team", p.playerstats_id), ftos(p.team));
 197
 198         if(stof(db_get(PS_GR_OUT_DB, sprintf("%s:%s", p.playerstats_id, PLAYERSTATS_ALIVETIME))) > 0)
 199                 PlayerStats_GameReport_Event_Player(p, PLAYERSTATS_JOINS, 1);
 200
 201         PlayerStats_GameReport_Accuracy(p);
 202         anticheat_report_to_playerstats(p);
 203
 204         if(IS_REAL_CLIENT(p))
 205         {
 206                 if(CS(p).latency_cnt)
 207                 {
 208                         float latency = max(0, CS(p).latency_sum / CS(p).latency_cnt);
 209                         if(latency)
 210                         {
 211                                 // if previous average latency exists (player disconnected and reconnected)
 212                                 // make the average of previous and current average latency
 213                                 float prev_latency = PlayerStats_GameReport_Event_Player(p, PLAYERSTATS_AVGLATENCY, 0);
 214                                 float new_latency = !prev_latency ? latency : (prev_latency + latency) / 2;
 215                                 PlayerStats_GameReport_Event_Player(p, PLAYERSTATS_AVGLATENCY, -prev_latency + new_latency);
 216                         }
 217                 }
 218
 219                 db_put(PS_GR_OUT_DB, sprintf("%s:_ranked", p.playerstats_id), ftos(CS_CVAR(p).cvar_cl_allow_uidranking));
 220         }
 221
 222         strfree(p.playerstats_id);
 223 }
 224
 225 void PlayerStats_GameReport(bool finished)
 226 {
 227         if(PS_GR_OUT_DB < 0) { return; }
 228
 229         PlayerScore_Sort(score_dummyfield, 0, false, false);
 230         PlayerScore_Sort(scoreboard_pos, 1, true, true);
 231         if(teamplay) { PlayerScore_TeamStats(); }
 232
 233         FOREACH_CLIENT(true, {
 234                 // add personal score rank
 235                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_RANK, it.score_dummyfield);
 236
 237                 // scoreboard data
 238                 if(it.scoreboard_pos)
 239                 {
 240                         // scoreboard is valid!
 241                         PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_SCOREBOARD_VALID, 1);
 242
 243                         // add scoreboard position
 244                         PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_SCOREBOARD_POS, it.scoreboard_pos);
 245
 246                         // add scoreboard data
 247                         PlayerScore_PlayerStats(it);
 248
 249                         // if the match ended normally, add winning info
 250                         if(finished)
 251                         {
 252                                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_WINS, it.winning);
 253                                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_MATCHES, 1);
 254                         }
 255                 }
 256
 257                 // collect final player information
 258                 PlayerStats_GameReport_FinalizePlayer(it);
 259         });
 260
 261         if(autocvar_g_playerstats_gamereport_uri == "" || warmup_stage)
 262         {
 263                 PlayerStats_GameReport_DelayMapVote = false;
 264                 db_close(PS_GR_OUT_DB);
 265                 PS_GR_OUT_DB = -1;
 266                 return;
 267         }
 268
 269         PlayerStats_GameReport_DelayMapVote = true;
 270         url_multi_fopen(
 271                 autocvar_g_playerstats_gamereport_uri,
 272                 FILE_APPEND,
 273                 PlayerStats_GameReport_Handler,
 274                 NULL
 275         );
 276 }
 277
 278 void PlayerStats_GameReport_Init() // initiated before InitGameplayMode so that scores are added properly
 279 {
 280         serverflags &= ~SERVERFLAG_PLAYERSTATS;
 281         serverflags &= ~SERVERFLAG_PLAYERSTATS_CUSTOM;
 282
 283         if(autocvar_g_playerstats_gamereport_uri == "") { return; }
 284
 285         PS_GR_OUT_DB = db_create();
 286
 287         if(PS_GR_OUT_DB >= 0)
 288         {
 289                 PlayerStats_GameReport_DelayMapVote = true;
 290
 291                 if(autocvar_g_playerstats_gamereport_uri != cvar_defstring("g_playerstats_gamereport_uri"))
 292                         serverflags |= SERVERFLAG_PLAYERSTATS | SERVERFLAG_PLAYERSTATS_CUSTOM;
 293                 else if(checkextension("DP_CRYPTO")) // xonstat requires player and server IDs
 294                         serverflags |= SERVERFLAG_PLAYERSTATS;
 295
 296                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ALIVETIME);
 297                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_AVGLATENCY);
 298                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_WINS);
 299                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_MATCHES);
 300                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_JOINS);
 301                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_SCOREBOARD_VALID);
 302                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_SCOREBOARD_POS);
 303                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_RANK);
 304
 305                 // accuracy stats
 306                 FOREACH(Weapons, it != WEP_Null, {
 307                         PlayerStats_GameReport_AddEvent(strcat("acc-", it.netname, "-hit"));
 308                         PlayerStats_GameReport_AddEvent(strcat("acc-", it.netname, "-fired"));
 309                         PlayerStats_GameReport_AddEvent(strcat("acc-", it.netname, "-cnt-hit"));
 310                         PlayerStats_GameReport_AddEvent(strcat("acc-", it.netname, "-cnt-fired"));
 311                         PlayerStats_GameReport_AddEvent(strcat("acc-", it.netname, "-frags"));
 312                 });
 313
 314                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3);
 315                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5);
 316                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10);
 317                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15);
 318                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20);
 319                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25);
 320                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30);
 321                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_BOTLIKE);
 322                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD);
 323                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM);
 324
 325                 anticheat_register_to_playerstats();
 326         }
 327         else { PlayerStats_GameReport_DelayMapVote = false; }
 328 }
 329
 330 // this... is a hack, a temporary one until we get a proper duel gametype
 331 // TODO: remove duel hack after servers have migrated to the proper duel gametype!
 332 string PlayerStats_GetGametype()
 333 {
 334         if(IS_GAMETYPE(DEATHMATCH) && autocvar_g_maxplayers == 2)
 335         {
 336                 // probably duel, but let's make sure
 337                 int plcount = 0;
 338                 FOREACH_CLIENT(IS_PLAYER(it), ++plcount);
 339                 if(plcount <= 2)
 340                         return "duel";
 341         }
 342         return GetGametype();
 343 }
 344
 345 void PlayerStats_GameReport_Handler(entity fh, entity pass, float status)
 346 {
 347         string t, tn;
 348         string p, pn;
 349         string e, en;
 350         string nn, tt;
 351         string s;
 352
 353         switch(status)
 354         {
 355                 // ======================================
 356                 // -- OUTGOING GAME REPORT INFORMATION --
 357                 // ======================================
 358                 /* SPECIFICATIONS:
 359                  * V: format version (always a fixed number) - this MUST be the first line!
 360                  * #: comment (MUST be ignored by any parser)
 361                  * R: release information on the server
 362                  * G: game type
 363                  * O: mod name (icon request) as in server browser
 364                  * M: map name
 365                  * I: match ID (see "matchid" in world.qc)
 366                  * S: "hostname" of the server
 367                  * C: number of "unpure" cvar changes
 368                  * U: UDP port number of the server
 369                  * D: duration of the match
 370                  * RP: number of rounds played
 371                  * L: "ladder" in which the server is participating in
 372                  * P: player ID of an existing player; this also sets the owner for all following "n", "e" and "t" lines (lower case!)
 373                  * Q: team number of an existing team (format: team#NN); this also sets the owner for all following "e" lines (lower case!)
 374                  * i: player index
 375                  * n: nickname of the player (optional)
 376                  * t: team ID
 377                  * r: player ranking enabled / disabled
 378                  * e: followed by an event name, a space, and the event count/score
 379                  *  event names can be:
 380                  *   alivetime: total playing time of the player
 381                  *   avglatency: average network latency compounded throughout the match
 382                  *   wins: number of games won (can only be set if matches is set)
 383                  *   matches: number of matches played to the end (not aborted by map switch)
 384                  *   joins: number of matches joined (always 1 unless player never played during the match)
 385                  *   scoreboardvalid: set to 1 if the player was there at the end of the match
 386                  *   total-<scoreboardname>: total score of that scoreboard item
 387                  *   scoreboard-<scoreboardname>: end-of-game score of that scoreboard item (can differ in non-team games)
 388                  *   achievement-<achievementname>: achievement counters (their "count" is usually 1 if nonzero at all)
 389                  *   kills-<index>: number of kills against the indexed player
 390                  *   rank <number>: rank of player
 391                  *   acc-<weapon netname>-hit: total damage dealt
 392                  *   acc-<weapon netname>-fired: total damage that all fired projectiles *could* have dealt
 393                  *   acc-<weapon netname>-cnt-hit: amount of shots that actually hit
 394                  *   acc-<weapon netname>-cnt-fired: amount of fired shots
 395                  *   acc-<weapon netname>-frags: amount of frags dealt by weapon
 396                  */
 397                 case URL_READY_CANWRITE:
 398                 {
 399                         url_fputs(fh, "V 9\n");
 400                         #ifdef WATERMARK
 401                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 402                         #endif
 403                         url_fputs(fh, sprintf("G %s\n", PlayerStats_GetGametype()));
 404                         url_fputs(fh, sprintf("O %s\n", modname));
 405                         url_fputs(fh, sprintf("M %s\n", GetMapname()));
 406                         url_fputs(fh, sprintf("I %s\n", matchid));
 407                         url_fputs(fh, sprintf("S %s\n", cvar_string("hostname")));
 408                         url_fputs(fh, sprintf("C %d\n", cvar_purechanges_count));
 409                         url_fputs(fh, sprintf("U %d\n", cvar("port")));
 410                         url_fputs(fh, sprintf("D %f\n", max(0, time - game_starttime)));
 411                         if (rounds_played > 0)
 412                                 url_fputs(fh, sprintf("RP %d\n", rounds_played));
 413                         if (autocvar_g_playerstats_gamereport_ladder != "")
 414                                 url_fputs(fh, sprintf("L %s\n", autocvar_g_playerstats_gamereport_ladder));
 415
 416                         // TEAMS
 417                         if(teamplay)
 418                         {
 419                                 for(t = PS_GR_OUT_TL; (tn = db_get(PS_GR_OUT_DB, sprintf("%d", stof(t)))) != ""; t = tn)
 420                                 {
 421                                         // start team section
 422                                         url_fputs(fh, sprintf("Q team#%s\n", t));
 423
 424                                         // output team events // todo: does this do unnecessary loops? perhaps we should do a separate "team_events_last" tracker..."
 425                                         for(e = PS_GR_OUT_EVL; (en = db_get(PS_GR_OUT_DB, sprintf("*:%s", e))) != ""; e = en)
 426                                         {
 427                                                 float v = stof(db_get(PS_GR_OUT_DB, sprintf("team#%d:%s", stof(t), e)));
 428                                                 if(v != 0) { url_fputs(fh, sprintf("e %s %g\n", e, v)); }
 429                                         }
 430                                 }
 431                         }
 432
 433                         // PLAYERS
 434                         for(p = PS_GR_OUT_PL; (pn = db_get(PS_GR_OUT_DB, sprintf("%s:*", p))) != ""; p = pn)
 435                         {
 436                                 // start player section
 437                                 url_fputs(fh, sprintf("P %s\n", p));
 438
 439                                 // playerid/index (entity number for this server)
 440                                 nn = db_get(PS_GR_OUT_DB, sprintf("%s:_playerid", p));
 441                                 if(nn != "") { url_fputs(fh, sprintf("i %s\n", nn)); }
 442
 443                                 // player name
 444                                 nn = db_get(PS_GR_OUT_DB, sprintf("%s:_netname", p));
 445                                 if(nn != "") { url_fputs(fh, sprintf("n %s\n", nn)); }
 446
 447                                 // team identification number
 448                                 if(teamplay)
 449                                 {
 450                                         tt = db_get(PS_GR_OUT_DB, sprintf("%s:_team", p));
 451                                         url_fputs(fh, sprintf("t %s\n", tt));
 452                                 }
 453
 454                                 // elo ranking enabled
 455                                 nn = db_get(PS_GR_OUT_DB, sprintf("%s:_ranked", p));
 456                                 if(nn != "") { url_fputs(fh, sprintf("r %s\n", nn)); }
 457
 458                                 // output player events
 459                                 for(e = PS_GR_OUT_EVL; (en = db_get(PS_GR_OUT_DB, sprintf("*:%s", e))) != ""; e = en)
 460                                 {
 461                                         float v = stof(db_get(PS_GR_OUT_DB, sprintf("%s:%s", p, e)));
 462                                         if(v != 0) { url_fputs(fh, sprintf("e %s %g\n", e, v)); }
 463                                 }
 464                         }
 465                         url_fputs(fh, "\n");
 466                         url_fclose(fh);
 467                         break;
 468                 }
 469
 470                 // ======================================
 471                 // -- INCOMING GAME REPORT INFORMATION --
 472                 // ======================================
 473                 /* SPECIFICATIONS:
 474                  * stuff
 475                  */
 476                 case URL_READY_CANREAD:
 477                 {
 478                         // url_fclose is processing, we got a response for writing the data
 479                         // this must come from HTTP
 480                         LOG_DEBUG("Got response from player stats server:");
 481                         while((s = url_fgets(fh))) { LOG_DEBUG("  ", s); }
 482                         LOG_DEBUG("End of response.");
 483                         url_fclose(fh);
 484                         break;
 485                 }
 486
 487                 case URL_READY_CLOSED:
 488                 {
 489                         // url_fclose has finished
 490                         LOG_DEBUG("Player stats written");
 491                         PlayerStats_GameReport_DelayMapVote = false;
 492                         if(PS_GR_OUT_DB >= 0)
 493                         {
 494                                 db_close(PS_GR_OUT_DB);
 495                                 PS_GR_OUT_DB = -1;
 496                         }
 497                         break;
 498                 }
 499
 500                 case URL_READY_ERROR:
 501                 default:
 502                 {
 503                         LOG_INFO("Player stats writing failed: ", ftos(status));
 504                         PlayerStats_GameReport_DelayMapVote = false;
 505                         if(PS_GR_OUT_DB >= 0)
 506                         {
 507                                 db_close(PS_GR_OUT_DB);
 508                                 PS_GR_OUT_DB = -1;
 509                         }
 510                         break;
 511                 }
 512         }
 513 }
 514
 515 void PlayerStats_PlayerBasic(entity joiningplayer, float newrequest)
 516 {
 517         GameRules_scoring_add(joiningplayer, ELO, -1);
 518         // http://stats.xonotic.org/player/GgXRw6piDtFIbMArMuiAi8JG4tiin8VLjZgsKB60Uds=/elo.txt
 519         if(autocvar_g_playerstats_playerbasic_uri != "")
 520         {
 521                 string uri = autocvar_g_playerstats_playerbasic_uri;
 522                 if (joiningplayer.crypto_idfp == "") {
 523                         GameRules_scoring_add(joiningplayer, ELO, -1);
 524                 } else {
 525                         // create the database if it doesn't already exist
 526                         if(PS_B_IN_DB < 0)
 527                                 PS_B_IN_DB = db_create();
 528
 529                         // now request the information
 530                         uri = strcat(uri, "/player/", uri_escape(uri_escape(uri_escape(joiningplayer.crypto_idfp))), "/elo.txt");
 531                         LOG_DEBUG("Retrieving playerstats from URL: ", uri);
 532                         url_single_fopen(
 533                                 uri,
 534                                 FILE_APPEND,
 535                                 PlayerStats_PlayerBasic_Handler,
 536                                 joiningplayer
 537                         );
 538
 539                         // set status appropriately // todo: check whether the player info exists in the database previously
 540                         if(newrequest)
 541                         {
 542                                 // database still contains useful information, so don't clear it of a useful status
 543                                 joiningplayer.playerstats_basicstatus = PS_B_STATUS_WAITING;
 544                         }
 545                         else
 546                         {
 547                                 // database was previously empty or never hit received status for some reason
 548                                 joiningplayer.playerstats_basicstatus = PS_B_STATUS_UPDATING;
 549                         }
 550                 }
 551         }
 552         else
 553         {
 554                 // server has this disabled, kill the DB and set status to idle
 555                 GameRules_scoring_add(joiningplayer, ELO, -1);
 556                 if(PS_B_IN_DB >= 0)
 557                 {
 558                         db_close(PS_B_IN_DB);
 559                         PS_B_IN_DB = -1;
 560
 561                         FOREACH_CLIENT(IS_REAL_CLIENT(it), it.playerstats_basicstatus = PS_B_STATUS_IDLE);
 562                 }
 563         }
 564 }
 565
 566 SHUTDOWN(PlayerStats_PlayerBasic_Shutdown)
 567 {
 568         if(PS_B_IN_DB >= 0)
 569         {
 570                 db_close(PS_B_IN_DB);
 571                 PS_B_IN_DB = -1;
 572         }
 573
 574         if(PS_GR_OUT_DB >= 0)
 575         {
 576                 db_close(PS_GR_OUT_DB);
 577                 PS_GR_OUT_DB = -1;
 578         }
 579 }
 580
 581 void PlayerStats_PlayerBasic_CheckUpdate(entity joiningplayer)
 582 {
 583         // determine whether we should retrieve playerbasic information again
 584
 585         LOG_DEBUGF("PlayerStats_PlayerBasic_CheckUpdate('%s'): %f",
 586                 joiningplayer.netname,
 587                 time
 588         );
 589
 590         // TODO: check to see if this playerid is inside the database already somehow...
 591         // for now we'll just check the field, but this won't work for players who disconnect and reconnect properly
 592         // although maybe we should just submit another request ANYWAY?
 593         if(!joiningplayer.playerstats_basicstatus)
 594         {
 595                 PlayerStats_PlayerBasic(
 596                         joiningplayer,
 597                         (joiningplayer.playerstats_basicstatus == PS_B_STATUS_RECEIVED)
 598                 );
 599         }
 600 }
 601
 602 void PlayerStats_PlayerBasic_Handler(entity fh, entity p, float status)
 603 {
 604         switch(status)
 605         {
 606                 case URL_READY_CANWRITE:
 607                 {
 608                         LOG_DEBUG("-- Sending data to player stats server");
 609                         /*url_fputs(fh, "V 1\n");
 610                         #ifdef WATERMARK
 611                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 612                         #endif
 613                         url_fputs(fh, sprintf("l %s\n", cvar_string("_menu_prvm_language"))); // language
 614                         url_fputs(fh, sprintf("c %s\n", cvar_string("_menu_prvm_country"))); // country
 615                         url_fputs(fh, sprintf("n %s\n", cvar_string("_cl_name"))); // name
 616                         url_fputs(fh, sprintf("m %s %s\n", cvar_string("_cl_playermodel"), cvar_string("_cl_playerskin"))); // model/skin
 617                         */url_fputs(fh, "\n");
 618                         url_fclose(fh);
 619                         return;
 620                 }
 621
 622                 case URL_READY_CANREAD:
 623                 {
 624                         bool handled = false;
 625                         string gt = string_null;
 626                         for (string s = ""; (s = url_fgets(fh)); ) {
 627                                 int n = tokenizebyseparator(s, " "); // key value? data
 628                                 if (n == 1) continue;
 629                                 string key = "", value = "", data = "";
 630                                 if (n == 2) {
 631                     key = argv(0);
 632                     data = argv(1);
 633                                 } else if (n >= 3) {
 634                     key = argv(0);
 635                     value = argv(1);
 636                     data = argv(2);
 637                                 }
 638                 switch (key) {
 639                     case "V":
 640                         // PlayerInfo_AddItem(p, "_version", data);
 641                         break;
 642                     case "R":
 643                         // PlayerInfo_AddItem(p, "_release", data);
 644                         break;
 645                     case "T":
 646                         // PlayerInfo_AddItem(p, "_time", data);
 647                         break;
 648                     case "S":
 649                         // PlayerInfo_AddItem(p, "_statsurl", data);
 650                         break;
 651                     case "P":
 652                         // PlayerInfo_AddItem(p, "_hashkey", data);
 653                         break;
 654                     case "n":
 655                         // PlayerInfo_AddItem(p, "_playernick", data);
 656                         break;
 657                     case "i":
 658                         // PlayerInfo_AddItem(p, "_playerid", data);
 659                         // p.xonstat_id = stof(data);
 660                         break;
 661                     case "G":
 662                         gt = data;
 663                         break;
 664                     case "e":
 665                         //LOG_TRACE("G: ", gt);
 666                         //LOG_TRACE("e: ", data);
 667                         if (gt == PlayerStats_GetGametype()) {
 668                             handled = true;
 669                             float e = stof(data);
 670                             GameRules_scoring_add(p, ELO, +1 + e);
 671                         }
 672                         if (gt == "") {
 673                             // PlayerInfo_AddItem(p, value, data);
 674                         } else {
 675                             // PlayerInfo_AddItem(p, sprintf("%s/%s", gt, value), data);
 676                         }
 677                         break;
 678                 }
 679                         }
 680                         url_fclose(fh);
 681                         if (handled) return;
 682                         break;
 683                 }
 684                 case URL_READY_CLOSED:
 685                 {
 686                         // url_fclose has finished
 687                         LOG_INFO("Player stats synchronized with server");
 688                         return;
 689                 }
 690
 691                 case URL_READY_ERROR:
 692                 default:
 693                 {
 694                         LOG_INFO("Receiving player stats failed: ", ftos(status));
 695                         break;
 696                 }
 697         }
 698         GameRules_scoring_add(p, ELO, -1);
 699 }
 700 #endif // SVQC
 701
 702 #ifdef MENUQC
 703
 704
 705 #if 0 // reading the entire DB at once
 706         string e = "", en = "";
 707         float i = 0;
 708         for(e = PS_D_IN_EVL; (en = db_get(PS_D_IN_DB, e)) != ""; e = en)
 709         {
 710                 LOG_INFOF("%d:%s:%s", i, e, db_get(PS_D_IN_DB, sprintf("#%s", e)));
 711                 ++i;
 712         }
 713 #endif
 714
 715 void PlayerStats_PlayerDetail_AddItem(string event, string data)
 716 {
 717         if(PS_D_IN_DB < 0) { return; }
 718
 719         // create a marker for the event so that we can access it later
 720         string marker = sprintf("%s", event);
 721         if(db_get(PS_D_IN_DB, marker) == "")
 722         {
 723                 if(PS_D_IN_EVL)
 724                 {
 725                         db_put(PS_D_IN_DB, marker, PS_D_IN_EVL);
 726                         strunzone(PS_D_IN_EVL);
 727                 }
 728                 else { db_put(PS_D_IN_DB, marker, "#"); }
 729                 PS_D_IN_EVL = strzone(marker);
 730         }
 731
 732         // now actually set the event data
 733         db_put(PS_D_IN_DB, sprintf("#%s", event), data);
 734         LOG_DEBUG("Added item ", sprintf("#%s", event), "=", data, " to PS_D_IN_DB");
 735 }
 736
 737 void PlayerStats_PlayerDetail()
 738 {
 739         // http://stats.xonotic.org/player/me
 740         if((autocvar_g_playerstats_playerdetail_uri != "") && (crypto_getmyidstatus(0) > 0))
 741         {
 742                 // create the database if it doesn't already exist
 743                 if(PS_D_IN_DB < 0)
 744                         PS_D_IN_DB = db_create();
 745
 746                 //uri = strcat(uri, "/player/", uri_escape(crypto_getmyidfp(0)));
 747                 LOG_DEBUG("Retrieving playerstats from URL: ", autocvar_g_playerstats_playerdetail_uri);
 748                 url_single_fopen(
 749                         autocvar_g_playerstats_playerdetail_uri,
 750                         FILE_APPEND,
 751                         PlayerStats_PlayerDetail_Handler,
 752                         NULL
 753                 );
 754
 755                 PlayerStats_PlayerDetail_Status = PS_D_STATUS_WAITING;
 756         }
 757         else
 758         {
 759                 // player has this disabled, kill the DB and set status to idle
 760                 if(PS_D_IN_DB >= 0)
 761                 {
 762                         db_close(PS_D_IN_DB);
 763                         PS_D_IN_DB = -1;
 764                 }
 765
 766                 PlayerStats_PlayerDetail_Status = PS_D_STATUS_IDLE;
 767         }
 768 }
 769
 770 void PlayerStats_PlayerDetail_CheckUpdate()
 771 {
 772         // determine whether we should retrieve playerdetail information again
 773         float gamecount = cvar("cl_matchcount");
 774
 775         #if 0
 776         LOG_INFOF("PlayerStats_PlayerDetail_CheckUpdate(): %f >= %f, %d > %d",
 777                 time,
 778                 PS_D_NEXTUPDATETIME,
 779                 PS_D_LASTGAMECOUNT,
 780                 gamecount
 781         );
 782         #endif
 783
 784         if(
 785                 (time >= PS_D_NEXTUPDATETIME)
 786                 ||
 787                 (gamecount > PS_D_LASTGAMECOUNT)
 788         )
 789         {
 790                 PlayerStats_PlayerDetail();
 791                 PS_D_NEXTUPDATETIME = (time + autocvar_g_playerstats_playerdetail_autoupdatetime);
 792                 PS_D_LASTGAMECOUNT = gamecount;
 793         }
 794 }
 795
 796 void PlayerStats_PlayerDetail_Handler(entity fh, entity unused, float status)
 797 {
 798         switch(status)
 799         {
 800                 case URL_READY_CANWRITE:
 801                 {
 802                         LOG_DEBUG("PlayerStats_PlayerDetail_Handler(): Sending data to player stats server...");
 803                         url_fputs(fh, "V 1\n");
 804                         #ifdef WATERMARK
 805                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 806                         #endif
 807                         url_fputs(fh, sprintf("l %s\n", cvar_string("_menu_prvm_language"))); // language
 808                         //url_fputs(fh, sprintf("c %s\n", cvar_string("_cl_country"))); // country
 809                         url_fputs(fh, sprintf("n %s\n", cvar_string("_cl_name"))); // name
 810                         url_fputs(fh, sprintf("m %s %s\n", cvar_string("_cl_playermodel"), cvar_string("_cl_playerskin"))); // model/skin
 811                         url_fputs(fh, "\n");
 812                         url_fclose(fh);
 813                         break;
 814                 }
 815
 816                 case URL_READY_CANREAD:
 817                 {
 818                         //print("PlayerStats_PlayerDetail_Handler(): Got response from player stats server:\n");
 819                         string input = "";
 820                         string gametype = "overall";
 821                         while((input = url_fgets(fh)))
 822                         {
 823                                 float count = tokenizebyseparator(input, " ");
 824                                 string key = "", event = "", data = "";
 825
 826                                 if(argv(0) == "#") { continue; }
 827
 828                                 if(count == 2)
 829                                 {
 830                                         key = argv(0);
 831                                         data = substring(input, argv_start_index(1), strlen(input) - argv_start_index(1));
 832                                 }
 833                                 else if(count >= 3)
 834                                 {
 835                                         key = argv(0);
 836                                         event = argv(1);
 837                                         data = substring(input, argv_start_index(2), strlen(input) - argv_start_index(2));
 838                                 }
 839                                 else { continue; }
 840
 841                                 switch(key)
 842                                 {
 843                                         // general info
 844                                         case "V": PlayerStats_PlayerDetail_AddItem("version", data); break;
 845                                         case "R": PlayerStats_PlayerDetail_AddItem("release", data); break;
 846                                         case "T": PlayerStats_PlayerDetail_AddItem("time", data); break;
 847
 848                                         // player info
 849                                         case "S": PlayerStats_PlayerDetail_AddItem("statsurl", data); break;
 850                                         case "P": PlayerStats_PlayerDetail_AddItem("hashkey", data); break;
 851                                         case "n": PlayerStats_PlayerDetail_AddItem("playernick", data); break;
 852                                         case "i": PlayerStats_PlayerDetail_AddItem("playerid", data); break;
 853
 854                                         // other/event info
 855                                         case "G": gametype = data; break;
 856                                         case "e":
 857                                         {
 858                                                 if(event != "" && data != "")
 859                                                 {
 860                                                         PlayerStats_PlayerDetail_AddItem(
 861                                                                 sprintf(
 862                                                                         "%s/%s",
 863                                                                         gametype,
 864                                                                         event
 865                                                                 ),
 866                                                                 data
 867                                                         );
 868                                                 }
 869                                                 break;
 870                                         }
 871
 872                                         default:
 873                                         {
 874                                                 LOG_INFOF(
 875                                                         "PlayerStats_PlayerDetail_Handler(): ERROR: "
 876                                                         "Key went unhandled? Is our version outdated?\n"
 877                                                         "PlayerStats_PlayerDetail_Handler(): "
 878                                                         "Key '%s', Event '%s', Data '%s'",
 879                                                         key,
 880                                                         event,
 881                                                         data
 882                                                 );
 883                                                 break;
 884                                         }
 885                                 }
 886
 887                                 #if 0
 888                                 LOG_INFOF(
 889                                         "PlayerStats_PlayerDetail_Handler(): "
 890                                         "Key '%s', Event '%s', Data '%s'",
 891                                         key,
 892                                         event,
 893                                         data
 894                                 );
 895                                 #endif
 896                         }
 897                         //print("PlayerStats_PlayerDetail_Handler(): End of response.\n");
 898                         url_fclose(fh);
 899                         PlayerStats_PlayerDetail_Status = PS_D_STATUS_RECEIVED;
 900                         statslist.getStats(statslist);
 901                         break;
 902                 }
 903
 904                 case URL_READY_CLOSED:
 905                 {
 906                         // url_fclose has finished
 907                         LOG_INFO("PlayerStats_PlayerDetail_Handler(): Player stats synchronized with server.");
 908                         break;
 909                 }
 910
 911                 case URL_READY_ERROR:
 912                 default:
 913                 {
 914                         LOG_INFO("PlayerStats_PlayerDetail_Handler(): Receiving player stats failed: ", ftos(status));
 915                         PlayerStats_PlayerDetail_Status = PS_D_STATUS_ERROR;
 916                         if(PS_D_IN_DB >= 0)
 917                         {
 918                                 db_close(PS_D_IN_DB);
 919                                 PS_D_IN_DB = -1;
 920                         }
 921                         break;
 922                 }
 923         }
 924 }
 925 #endif
 926
 927 /*
 928 void PlayerInfo_AddPlayer(entity e)
 929 {
 930         if(playerinfo_db < 0)
 931                 return;
 932
 933         string key;
 934         key = sprintf("#%d:*", e.playerid); // TODO: use hashkey instead?
 935
 936         string p;
 937         p = db_get(playerinfo_db, key);
 938         if(p == "")
 939         {
 940                 if(playerinfo_last)
 941                 {
 942                         db_put(playerinfo_db, key, playerinfo_last);
 943                         strunzone(playerinfo_last);
 944                 }
 945                 else
 946                         db_put(playerinfo_db, key, "#");
 947                 playerinfo_last = strzone(ftos(e.playerid));
 948                 print("  Added player ", ftos(e.playerid), " to playerinfo_db\n");//DEBUG//
 949         }
 950 }
 951
 952 void PlayerInfo_AddItem(entity e, string item_id, string val)
 953 {
 954         if(playerinfo_db < 0)
 955                 return;
 956
 957         string key;
 958         key = sprintf("*:%s", item_id);
 959
 960         string p;
 961         p = db_get(playerinfo_db, key);
 962         if(p == "")
 963         {
 964                 if(playerinfo_events_last)
 965                 {
 966                         db_put(playerinfo_db, key, playerinfo_events_last);
 967                         strunzone(playerinfo_events_last);
 968                 }
 969                 else
 970                         db_put(playerinfo_db, key, "#");
 971                 playerinfo_events_last = strzone(item_id);
 972         }
 973
 974         key = sprintf("#%d:%s", e.playerid, item_id);
 975         db_put(playerinfo_db, key, val);
 976         print("  Added item ", key, "=", val, " to playerinfo_db\n");//DEBUG//
 977 }
 978
 979 string PlayerInfo_GetItem(entity e, string item_id)
 980 {
 981         if(playerinfo_db < 0)
 982                 return "";
 983
 984         string key;
 985         key = sprintf("#%d:%s",  e.playerid, item_id);
 986         return db_get(playerinfo_db, key);
 987 }
 988
 989 string PlayerInfo_GetItemLocal(string item_id)
 990 {
 991         entity p = spawn();
 992         p.playerid = 0;
 993         return PlayerInfo_GetItem(p, item_id);
 994 }
 995
 996 void PlayerInfo_ready(entity fh, entity p, float status)
 997 {
 998         float n;
 999         string s;
1000
1001         PlayerInfo_AddPlayer(p);
1002
1003         switch(status)
1004         {
1005                 case URL_READY_CANWRITE:
1006                         print("-- Sending data to player stats server\n");
1007                         url_fputs(fh, "V 1\n");
1008 #ifdef WATERMARK
1009                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
1010 #endif
1011 #ifdef MENUQC
1012                         url_fputs(fh, sprintf("l %s\n", cvar_string("_menu_prvm_language"))); // language
1013                         url_fputs(fh, sprintf("c %s\n", cvar_string("_menu_prvm_country"))); // country
1014                         url_fputs(fh, sprintf("n %s\n", cvar_string("_cl_name"))); // name
1015                         url_fputs(fh, sprintf("m %s %s\n", cvar_string("_cl_playermodel"), cvar_string("_cl_playerskin"))); // model/skin
1016 #endif
1017                         url_fputs(fh, "\n");
1018                         url_fclose(fh);
1019                         break;
1020                 case URL_READY_CANREAD:
1021                         print("-- Got response from player stats server:\n");
1022                         string gametype = string_null;
1023                         while((s = url_fgets(fh)))
1024                         {
1025                                 print("  ", s, "\n");
1026
1027                                 string key = "", value = "", data = "";
1028
1029                                 n = tokenizebyseparator(s, " "); // key (value) data
1030                                 if (n == 1)
1031                                         continue;
1032                                 else if (n == 2)
1033                                 {
1034                                         key = argv(0);
1035                                         data = argv(1);
1036                                 }
1037                                 else if (n >= 3)
1038                                 {
1039                                         key = argv(0);
1040                                         value = argv(1);
1041                                         data = argv(2);
1042                                 }
1043
1044                                 if (data == "")
1045                                         continue;
1046
1047                                 if (key == "#")
1048                                         continue;
1049                                 else if (key == "V")
1050                                         PlayerInfo_AddItem(p, "_version", data);
1051                                 else if (key == "R")
1052                                         PlayerInfo_AddItem(p, "_release", data);
1053                                 else if (key == "T")
1054                                         PlayerInfo_AddItem(p, "_time", data);
1055                                 else if (key == "S")
1056                                         PlayerInfo_AddItem(p, "_statsurl", data);
1057                                 else if (key == "P")
1058                                         PlayerInfo_AddItem(p, "_hashkey", data);
1059                                 else if (key == "n")
1060                                         PlayerInfo_AddItem(p, "_playernick", data);
1061                                 else if (key == "i")
1062                                         PlayerInfo_AddItem(p, "_playerid", data);
1063                                 else if (key == "G")
1064                                         gametype = data;
1065                                 else if (key == "e" && value != "")
1066                                 {
1067                                         if (gametype == "")
1068                                                 PlayerInfo_AddItem(p, value, data);
1069                                         else
1070                                                 PlayerInfo_AddItem(p, sprintf("%s/%s", gametype, value), data);
1071                                 }
1072                                 else
1073                                         continue;
1074                         }
1075                         print("-- End of response.\n");
1076                         url_fclose(fh);
1077                         break;
1078                 case URL_READY_CLOSED:
1079                         // url_fclose has finished
1080                         print("Player stats synchronized with server\n");
1081                         break;
1082                 case URL_READY_ERROR:
1083                 default:
1084                         print("Receiving player stats failed: ", ftos(status), "\n");
1085                         break;
1086         }
1087 }
1088
1089 void PlayerInfo_Init()
1090 {
1091         playerinfo_db = db_create();
1092 }
1093
1094 #ifdef SVQC
1095 void PlayerInfo_Basic(entity p)
1096 {
1097         print("-- Getting basic PlayerInfo for player ",ftos(p.playerid)," (SVQC)\n");
1098
1099         if(playerinfo_db < 0)
1100                 return;
1101
1102         string uri;
1103         uri = autocvar_g_playerinfo_uri;
1104         if(uri != "" && p.crypto_idfp != "")
1105         {
1106                 uri = strcat(uri, "/elo/", uri_escape(p.crypto_idfp));
1107                 print("Retrieving playerstats from URL: ", uri, "\n");
1108                 url_single_fopen(uri, FILE_READ, PlayerInfo_ready, p);
1109         }
1110 }
1111 #endif
1112
1113 #ifdef MENUQC
1114 void PlayerInfo_Details()
1115 {
1116         print("-- Getting detailed PlayerInfo for local player (MENUQC)\n");
1117
1118         if(playerinfo_db < 0)
1119                 return;
1120
1121         string uri;
1122         uri = autocvar_g_playerinfo_uri; // FIXME
1123         if(uri != "" && crypto_getmyidstatus(0) > 0)
1124         {
1125                 //uri = strcat(uri, "/player/", uri_escape(crypto_getmyidfp(0)));
1126                 uri = strcat(uri, "/player/me");
1127                 print("Retrieving playerstats from URL: ", uri, "\n");
1128                 url_single_fopen(uri, FILE_APPEND, PlayerInfo_ready, NULL);
1129         }
1130 }
1131 #endif
1132
1133 #ifdef CSQC
1134 // FIXME - crypto_* builtin functions missing in CSQC (csprogsdefs.qh:885)
1135 void PlayerInfo_Details()
1136 {
1137         print("-- Getting detailed PlayerInfo for local player (CSQC)\n");
1138
1139         if(playerinfo_db < 0)
1140                 return;
1141
1142         string uri;
1143         uri = autocvar_g_playerinfo_uri; // FIXME
1144         if(uri != "" && crypto_getmyidstatus(0) > 0)
1145         {
1146                 uri = strcat(uri, "/player/", uri_escape(crypto_getmyidfp(0)));
1147                 print("Retrieving playerstats from URL: ", uri, "\n");
1148                 url_single_fopen(uri, FILE_READ, PlayerInfo_ready, p);
1149         }
1150 }
1151
1152 #endif
1153 */