qcsrc/common/playerstats.qc

   1 #include "playerstats.qh"
   2 #if defined(CSQC)
   3 #elif defined(MENUQC)
   4 #elif defined(SVQC)
   5     #include "constants.qh"
   6     #include "util.qh"
   7     #include <common/weapons/_all.qh>
   8     #include <server/client.qh>
   9     #include "../server/anticheat.qh"
  10     #include <common/stats.qh>
  11     #include <server/intermission.qh>
  12     #include "../server/scores.qh"
  13         #include <server/world.qh>
  14     #include "../server/weapons/accuracy.qh"
  15 #endif
  16
  17 #ifdef SVQC
  18 void PlayerStats_Prematch()
  19 {
  20         //foobar
  21 }
  22
  23 void PlayerStats_GameReport_AddPlayer(entity e)
  24 {
  25         if((PS_GR_OUT_DB < 0) || (e.playerstats_id)) { return; }
  26
  27         // set up player identification
  28         string s = "";
  29
  30         if((e.crypto_idfp != "") && (CS(e).cvar_cl_allow_uidtracking == 1))
  31                 { s = e.crypto_idfp; }
  32         else if(IS_BOT_CLIENT(e))
  33                 { s = sprintf("bot#%g#%s", skill, e.cleanname); }
  34
  35         if((s == "") || find(NULL, playerstats_id, s)) // already have one of the ID - next one can't be tracked then!
  36         {
  37                 if(IS_BOT_CLIENT(e))
  38                         { s = sprintf("bot#%d", e.playerid); }
  39                 else
  40                         { s = sprintf("player#%d", e.playerid); }
  41         }
  42
  43         e.playerstats_id = strzone(s);
  44
  45         // now add the player to the database
  46         string key = sprintf("%s:*", e.playerstats_id);
  47         string p = db_get(PS_GR_OUT_DB, key);
  48
  49         if(p == "")
  50         {
  51                 if(PS_GR_OUT_PL)
  52                 {
  53                         db_put(PS_GR_OUT_DB, key, PS_GR_OUT_PL);
  54                         strunzone(PS_GR_OUT_PL);
  55                 }
  56                 else { db_put(PS_GR_OUT_DB, key, "#"); }
  57                 PS_GR_OUT_PL = strzone(e.playerstats_id);
  58         }
  59 }
  60
  61 void PlayerStats_GameReport_AddTeam(int t)
  62 {
  63         if(PS_GR_OUT_DB < 0) { return; }
  64
  65         string key = sprintf("%d", t);
  66         string p = db_get(PS_GR_OUT_DB, key);
  67
  68         if(p == "")
  69         {
  70                 if(PS_GR_OUT_TL)
  71                 {
  72                         db_put(PS_GR_OUT_DB, key, PS_GR_OUT_TL);
  73                         strunzone(PS_GR_OUT_TL);
  74                 }
  75                 else { db_put(PS_GR_OUT_DB, key, "#"); }
  76                 PS_GR_OUT_TL = strzone(key);
  77         }
  78 }
  79
  80 void PlayerStats_GameReport_AddEvent(string event_id)
  81 {
  82         if(PS_GR_OUT_DB < 0) { return; }
  83
  84         string key = sprintf("*:%s", event_id);
  85         string p = db_get(PS_GR_OUT_DB, key);
  86
  87         if(p == "")
  88         {
  89                 if(PS_GR_OUT_EVL)
  90                 {
  91                         db_put(PS_GR_OUT_DB, key, PS_GR_OUT_EVL);
  92                         strunzone(PS_GR_OUT_EVL);
  93                 }
  94                 else { db_put(PS_GR_OUT_DB, key, "#"); }
  95                 PS_GR_OUT_EVL = strzone(event_id);
  96         }
  97 }
  98
  99 float PlayerStats_GameReport_Event(string prefix, string event_id, float value)
 100 {
 101         if((prefix == "") || PS_GR_OUT_DB < 0) { return 0; }
 102
 103         string key = sprintf("%s:%s", prefix, event_id);
 104         float val = stof(db_get(PS_GR_OUT_DB, key));
 105         val += value;
 106         db_put(PS_GR_OUT_DB, key, ftos(val));
 107         return val;
 108 }
 109
 110 void PlayerStats_GameReport_Accuracy(entity p)
 111 {
 112         #define ACCMAC(suffix, field) \
 113                 PlayerStats_GameReport_Event_Player(p, \
 114                         sprintf("acc-%s-%s", it.netname, suffix), CS(p).accuracy.(field[i-1]));
 115         FOREACH(Weapons, it != WEP_Null, {
 116                 ACCMAC("hit", accuracy_hit)
 117                 ACCMAC("fired", accuracy_fired)
 118                 ACCMAC("cnt-hit", accuracy_cnt_hit)
 119                 ACCMAC("cnt-fired", accuracy_cnt_fired)
 120                 ACCMAC("frags", accuracy_frags)
 121         });
 122         #undef ACCMAC
 123 }
 124
 125 void PlayerStats_GameReport_FinalizePlayer(entity p)
 126 {
 127         if((p.playerstats_id == "") || PS_GR_OUT_DB < 0) { return; }
 128
 129         // add global info!
 130         if(p.alivetime)
 131         {
 132                 PlayerStats_GameReport_Event_Player(p, PLAYERSTATS_ALIVETIME, time - p.alivetime);
 133                 p.alivetime = 0;
 134         }
 135
 136         db_put(PS_GR_OUT_DB, sprintf("%s:_playerid", p.playerstats_id), ftos(p.playerid));
 137
 138         if(CS(p).cvar_cl_allow_uid2name == 1 || IS_BOT_CLIENT(p))
 139                 db_put(PS_GR_OUT_DB, sprintf("%s:_netname", p.playerstats_id), playername(p.netname, p.team, false));
 140
 141         if(teamplay)
 142                 db_put(PS_GR_OUT_DB, sprintf("%s:_team", p.playerstats_id), ftos(p.team));
 143
 144         if(stof(db_get(PS_GR_OUT_DB, sprintf("%s:%s", p.playerstats_id, PLAYERSTATS_ALIVETIME))) > 0)
 145                 PlayerStats_GameReport_Event_Player(p, PLAYERSTATS_JOINS, 1);
 146
 147         PlayerStats_GameReport_Accuracy(p);
 148         anticheat_report_to_playerstats(p);
 149
 150         if(IS_REAL_CLIENT(p))
 151         {
 152                 if(CS(p).latency_cnt)
 153                 {
 154                         float latency = (CS(p).latency_sum / CS(p).latency_cnt);
 155                         if(latency)
 156                                 PlayerStats_GameReport_Event_Player(p, PLAYERSTATS_AVGLATENCY, latency);
 157                 }
 158
 159                 db_put(PS_GR_OUT_DB, sprintf("%s:_ranked", p.playerstats_id), ftos(CS(p).cvar_cl_allow_uidranking));
 160         }
 161
 162         strfree(p.playerstats_id);
 163 }
 164
 165 void PlayerStats_GameReport(bool finished)
 166 {
 167         if(PS_GR_OUT_DB < 0) { return; }
 168
 169         PlayerScore_Sort(score_dummyfield, 0, 0, 0);
 170         PlayerScore_Sort(scoreboard_pos, 1, 1, 1);
 171         if(teamplay) { PlayerScore_TeamStats(); }
 172
 173         FOREACH_CLIENT(true, {
 174                 // add personal score rank
 175                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_RANK, it.score_dummyfield);
 176
 177                 // scoreboard data
 178                 if(it.scoreboard_pos)
 179                 {
 180                         // scoreboard is valid!
 181                         PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_SCOREBOARD_VALID, 1);
 182
 183                         // add scoreboard position
 184                         PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_SCOREBOARD_POS, it.scoreboard_pos);
 185
 186                         // add scoreboard data
 187                         PlayerScore_PlayerStats(it);
 188
 189                         // if the match ended normally, add winning info
 190                         if(finished)
 191                         {
 192                                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_WINS, it.winning);
 193                                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_MATCHES, 1);
 194                         }
 195                 }
 196
 197                 // collect final player information
 198                 PlayerStats_GameReport_FinalizePlayer(it);
 199         });
 200
 201         if(autocvar_g_playerstats_gamereport_uri != "")
 202         {
 203                 PlayerStats_GameReport_DelayMapVote = true;
 204                 url_multi_fopen(
 205                         autocvar_g_playerstats_gamereport_uri,
 206                         FILE_APPEND,
 207                         PlayerStats_GameReport_Handler,
 208                         NULL
 209                 );
 210         }
 211         else
 212         {
 213                 PlayerStats_GameReport_DelayMapVote = false;
 214                 db_close(PS_GR_OUT_DB);
 215                 PS_GR_OUT_DB = -1;
 216         }
 217 }
 218
 219 void PlayerStats_GameReport_Init() // initiated before InitGameplayMode so that scores are added properly
 220 {
 221         if(autocvar_g_playerstats_gamereport_uri == "") { return; }
 222
 223         PS_GR_OUT_DB = db_create();
 224
 225         if(PS_GR_OUT_DB >= 0)
 226         {
 227                 PlayerStats_GameReport_DelayMapVote = true;
 228
 229                 serverflags |= SERVERFLAG_PLAYERSTATS;
 230
 231                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ALIVETIME);
 232                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_AVGLATENCY);
 233                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_WINS);
 234                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_MATCHES);
 235                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_JOINS);
 236                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_SCOREBOARD_VALID);
 237                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_SCOREBOARD_POS);
 238                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_RANK);
 239
 240                 // accuracy stats
 241                 FOREACH(Weapons, it != WEP_Null, {
 242                         PlayerStats_GameReport_AddEvent(strcat("acc-", it.netname, "-hit"));
 243                         PlayerStats_GameReport_AddEvent(strcat("acc-", it.netname, "-fired"));
 244                         PlayerStats_GameReport_AddEvent(strcat("acc-", it.netname, "-cnt-hit"));
 245                         PlayerStats_GameReport_AddEvent(strcat("acc-", it.netname, "-cnt-fired"));
 246                         PlayerStats_GameReport_AddEvent(strcat("acc-", it.netname, "-frags"));
 247                 });
 248
 249                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3);
 250                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5);
 251                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10);
 252                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15);
 253                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20);
 254                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25);
 255                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30);
 256                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_BOTLIKE);
 257                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD);
 258                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM);
 259
 260                 anticheat_register_to_playerstats();
 261         }
 262         else { PlayerStats_GameReport_DelayMapVote = false; }
 263 }
 264
 265 // this... is a hack, a temporary one until we get a proper duel gametype
 266 // TODO: remove duel hack after servers have migrated to the proper duel gametype!
 267 string PlayerStats_GetGametype()
 268 {
 269         if(IS_GAMETYPE(DEATHMATCH) && autocvar_g_maxplayers == 2)
 270         {
 271                 // probably duel, but let's make sure
 272                 int plcount = 0;
 273                 FOREACH_CLIENT(IS_PLAYER(it), ++plcount);
 274                 if(plcount <= 2)
 275                         return "duel";
 276         }
 277         return GetGametype();
 278 }
 279
 280 void PlayerStats_GameReport_Handler(entity fh, entity pass, float status)
 281 {
 282         string t, tn;
 283         string p, pn;
 284         string e, en;
 285         string nn, tt;
 286         string s;
 287
 288         switch(status)
 289         {
 290                 // ======================================
 291                 // -- OUTGOING GAME REPORT INFORMATION --
 292                 // ======================================
 293                 /* SPECIFICATIONS:
 294                  * V: format version (always a fixed number) - this MUST be the first line!
 295                  * #: comment (MUST be ignored by any parser)
 296                  * R: release information on the server
 297                  * G: game type
 298                  * O: mod name (icon request) as in server browser
 299                  * M: map name
 300                  * I: match ID (see "matchid" in world.qc)
 301                  * S: "hostname" of the server
 302                  * C: number of "unpure" cvar changes
 303                  * U: UDP port number of the server
 304                  * D: duration of the match
 305                  * L: "ladder" in which the server is participating in
 306                  * P: player ID of an existing player; this also sets the owner for all following "n", "e" and "t" lines (lower case!)
 307                  * Q: team number of an existing team (format: team#NN); this also sets the owner for all following "e" lines (lower case!)
 308                  * i: player index
 309                  * n: nickname of the player (optional)
 310                  * t: team ID
 311                  * e: followed by an event name, a space, and the event count/score
 312                  *  event names can be:
 313                  *   alivetime: total playing time of the player
 314                  *   avglatency: average network latency compounded throughout the match
 315                  *   wins: number of games won (can only be set if matches is set)
 316                  *   matches: number of matches played to the end (not aborted by map switch)
 317                  *   joins: number of matches joined (always 1 unless player never played during the match)
 318                  *   scoreboardvalid: set to 1 if the player was there at the end of the match
 319                  *   total-<scoreboardname>: total score of that scoreboard item
 320                  *   scoreboard-<scoreboardname>: end-of-game score of that scoreboard item (can differ in non-team games)
 321                  *   achievement-<achievementname>: achievement counters (their "count" is usually 1 if nonzero at all)
 322                  *   kills-<index>: number of kills against the indexed player
 323                  *   rank <number>: rank of player
 324                  *   acc-<weapon netname>-hit: total damage dealt
 325                  *   acc-<weapon netname>-fired: total damage that all fired projectiles *could* have dealt
 326                  *   acc-<weapon netname>-cnt-hit: amount of shots that actually hit
 327                  *   acc-<weapon netname>-cnt-fired: amount of fired shots
 328                  *   acc-<weapon netname>-frags: amount of frags dealt by weapon
 329                  */
 330                 case URL_READY_CANWRITE:
 331                 {
 332                         url_fputs(fh, "V 9\n");
 333                         #ifdef WATERMARK
 334                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 335                         #endif
 336                         url_fputs(fh, sprintf("G %s\n", PlayerStats_GetGametype()));
 337                         url_fputs(fh, sprintf("O %s\n", modname));
 338                         url_fputs(fh, sprintf("M %s\n", GetMapname()));
 339                         url_fputs(fh, sprintf("I %s\n", matchid));
 340                         url_fputs(fh, sprintf("S %s\n", cvar_string("hostname")));
 341                         url_fputs(fh, sprintf("C %d\n", cvar_purechanges_count));
 342                         url_fputs(fh, sprintf("U %d\n", cvar("port")));
 343                         url_fputs(fh, sprintf("D %f\n", max(0, time - game_starttime)));
 344                         url_fputs(fh, sprintf("L %s\n", autocvar_g_playerstats_gamereport_ladder));
 345
 346                         // TEAMS
 347                         if(teamplay)
 348                         {
 349                                 for(t = PS_GR_OUT_TL; (tn = db_get(PS_GR_OUT_DB, sprintf("%d", stof(t)))) != ""; t = tn)
 350                                 {
 351                                         // start team section
 352                                         url_fputs(fh, sprintf("Q team#%s\n", t));
 353
 354                                         // output team events // todo: does this do unnecessary loops? perhaps we should do a separate "team_events_last" tracker..."
 355                                         for(e = PS_GR_OUT_EVL; (en = db_get(PS_GR_OUT_DB, sprintf("*:%s", e))) != ""; e = en)
 356                                         {
 357                                                 float v = stof(db_get(PS_GR_OUT_DB, sprintf("team#%d:%s", stof(t), e)));
 358                                                 if(v != 0) { url_fputs(fh, sprintf("e %s %g\n", e, v)); }
 359                                         }
 360                                 }
 361                         }
 362
 363                         // PLAYERS
 364                         for(p = PS_GR_OUT_PL; (pn = db_get(PS_GR_OUT_DB, sprintf("%s:*", p))) != ""; p = pn)
 365                         {
 366                                 // start player section
 367                                 url_fputs(fh, sprintf("P %s\n", p));
 368
 369                                 // playerid/index (entity number for this server)
 370                                 nn = db_get(PS_GR_OUT_DB, sprintf("%s:_playerid", p));
 371                                 if(nn != "") { url_fputs(fh, sprintf("i %s\n", nn)); }
 372
 373                                 // player name
 374                                 nn = db_get(PS_GR_OUT_DB, sprintf("%s:_netname", p));
 375                                 if(nn != "") { url_fputs(fh, sprintf("n %s\n", nn)); }
 376
 377                                 // team identification number
 378                                 if(teamplay)
 379                                 {
 380                                         tt = db_get(PS_GR_OUT_DB, sprintf("%s:_team", p));
 381                                         url_fputs(fh, sprintf("t %s\n", tt));
 382                                 }
 383
 384                                 // elo ranking enabled
 385                                 nn = db_get(PS_GR_OUT_DB, sprintf("%s:_ranked", p));
 386                                 if(nn != "") { url_fputs(fh, sprintf("r %s\n", nn)); }
 387
 388                                 // output player events
 389                                 for(e = PS_GR_OUT_EVL; (en = db_get(PS_GR_OUT_DB, sprintf("*:%s", e))) != ""; e = en)
 390                                 {
 391                                         float v = stof(db_get(PS_GR_OUT_DB, sprintf("%s:%s", p, e)));
 392                                         if(v != 0) { url_fputs(fh, sprintf("e %s %g\n", e, v)); }
 393                                 }
 394                         }
 395                         url_fputs(fh, "\n");
 396                         url_fclose(fh);
 397                         break;
 398                 }
 399
 400                 // ======================================
 401                 // -- INCOMING GAME REPORT INFORMATION --
 402                 // ======================================
 403                 /* SPECIFICATIONS:
 404                  * stuff
 405                  */
 406                 case URL_READY_CANREAD:
 407                 {
 408                         // url_fclose is processing, we got a response for writing the data
 409                         // this must come from HTTP
 410                         LOG_DEBUG("Got response from player stats server:");
 411                         while((s = url_fgets(fh))) { LOG_DEBUG("  ", s); }
 412                         LOG_DEBUG("End of response.");
 413                         url_fclose(fh);
 414                         break;
 415                 }
 416
 417                 case URL_READY_CLOSED:
 418                 {
 419                         // url_fclose has finished
 420                         LOG_DEBUG("Player stats written");
 421                         PlayerStats_GameReport_DelayMapVote = false;
 422                         if(PS_GR_OUT_DB >= 0)
 423                         {
 424                                 db_close(PS_GR_OUT_DB);
 425                                 PS_GR_OUT_DB = -1;
 426                         }
 427                         break;
 428                 }
 429
 430                 case URL_READY_ERROR:
 431                 default:
 432                 {
 433                         LOG_INFO("Player stats writing failed: ", ftos(status));
 434                         PlayerStats_GameReport_DelayMapVote = false;
 435                         if(PS_GR_OUT_DB >= 0)
 436                         {
 437                                 db_close(PS_GR_OUT_DB);
 438                                 PS_GR_OUT_DB = -1;
 439                         }
 440                         break;
 441                 }
 442         }
 443 }
 444
 445 void PlayerStats_PlayerBasic(entity joiningplayer, float newrequest)
 446 {
 447         GameRules_scoring_add(joiningplayer, ELO, -1);
 448         // http://stats.xonotic.org/player/GgXRw6piDtFIbMArMuiAi8JG4tiin8VLjZgsKB60Uds=/elo.txt
 449         if(autocvar_g_playerstats_playerbasic_uri != "")
 450         {
 451                 string uri = autocvar_g_playerstats_playerbasic_uri;
 452                 if (joiningplayer.crypto_idfp == "") {
 453                         GameRules_scoring_add(joiningplayer, ELO, -1);
 454                 } else {
 455                         // create the database if it doesn't already exist
 456                         if(PS_B_IN_DB < 0)
 457                                 PS_B_IN_DB = db_create();
 458
 459                         // now request the information
 460                         uri = strcat(uri, "/player/", uri_escape(uri_escape(uri_escape(joiningplayer.crypto_idfp))), "/elo.txt");
 461                         LOG_DEBUG("Retrieving playerstats from URL: ", uri);
 462                         url_single_fopen(
 463                                 uri,
 464                                 FILE_APPEND,
 465                                 PlayerStats_PlayerBasic_Handler,
 466                                 joiningplayer
 467                         );
 468
 469                         // set status appropriately // todo: check whether the player info exists in the database previously
 470                         if(newrequest)
 471                         {
 472                                 // database still contains useful information, so don't clear it of a useful status
 473                                 joiningplayer.playerstats_basicstatus = PS_B_STATUS_WAITING;
 474                         }
 475                         else
 476                         {
 477                                 // database was previously empty or never hit received status for some reason
 478                                 joiningplayer.playerstats_basicstatus = PS_B_STATUS_UPDATING;
 479                         }
 480                 }
 481         }
 482         else
 483         {
 484                 // server has this disabled, kill the DB and set status to idle
 485                 GameRules_scoring_add(joiningplayer, ELO, -1);
 486                 if(PS_B_IN_DB >= 0)
 487                 {
 488                         db_close(PS_B_IN_DB);
 489                         PS_B_IN_DB = -1;
 490
 491                         FOREACH_CLIENT(IS_REAL_CLIENT(it), it.playerstats_basicstatus = PS_B_STATUS_IDLE);
 492                 }
 493         }
 494 }
 495
 496 SHUTDOWN(PlayerStats_PlayerBasic_Shutdown)
 497 {
 498         if(PS_B_IN_DB >= 0)
 499         {
 500                 db_close(PS_B_IN_DB);
 501                 PS_B_IN_DB = -1;
 502         }
 503
 504         if(PS_GR_OUT_DB >= 0)
 505         {
 506                 db_close(PS_GR_OUT_DB);
 507                 PS_GR_OUT_DB = -1;
 508         }
 509 }
 510
 511 void PlayerStats_PlayerBasic_CheckUpdate(entity joiningplayer)
 512 {
 513         // determine whether we should retrieve playerbasic information again
 514
 515         LOG_DEBUGF("PlayerStats_PlayerBasic_CheckUpdate('%s'): %f",
 516                 joiningplayer.netname,
 517                 time
 518         );
 519
 520         // TODO: check to see if this playerid is inside the database already somehow...
 521         // for now we'll just check the field, but this won't work for players who disconnect and reconnect properly
 522         // although maybe we should just submit another request ANYWAY?
 523         if(!joiningplayer.playerstats_basicstatus)
 524         {
 525                 PlayerStats_PlayerBasic(
 526                         joiningplayer,
 527                         (joiningplayer.playerstats_basicstatus == PS_B_STATUS_RECEIVED)
 528                 );
 529         }
 530 }
 531
 532 void PlayerStats_PlayerBasic_Handler(entity fh, entity p, float status)
 533 {
 534         switch(status)
 535         {
 536                 case URL_READY_CANWRITE:
 537                 {
 538                         LOG_DEBUG("-- Sending data to player stats server");
 539                         /*url_fputs(fh, "V 1\n");
 540                         #ifdef WATERMARK
 541                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 542                         #endif
 543                         url_fputs(fh, sprintf("l %s\n", cvar_string("_menu_prvm_language"))); // language
 544                         url_fputs(fh, sprintf("c %s\n", cvar_string("_menu_prvm_country"))); // country
 545                         url_fputs(fh, sprintf("g %s\n", cvar_string("_cl_gender"))); // gender
 546                         url_fputs(fh, sprintf("n %s\n", cvar_string("_cl_name"))); // name
 547                         url_fputs(fh, sprintf("m %s %s\n", cvar_string("_cl_playermodel"), cvar_string("_cl_playerskin"))); // model/skin
 548                         */url_fputs(fh, "\n");
 549                         url_fclose(fh);
 550                         return;
 551                 }
 552
 553                 case URL_READY_CANREAD:
 554                 {
 555                         bool handled = false;
 556                         string gt = string_null;
 557                         for (string s = ""; (s = url_fgets(fh)); ) {
 558                                 int n = tokenizebyseparator(s, " "); // key value? data
 559                                 if (n == 1) continue;
 560                                 string key = "", value = "", data = "";
 561                                 if (n == 2) {
 562                     key = argv(0);
 563                     data = argv(1);
 564                                 } else if (n >= 3) {
 565                     key = argv(0);
 566                     value = argv(1);
 567                     data = argv(2);
 568                                 }
 569                 switch (key) {
 570                     case "V":
 571                         // PlayerInfo_AddItem(p, "_version", data);
 572                         break;
 573                     case "R":
 574                         // PlayerInfo_AddItem(p, "_release", data);
 575                         break;
 576                     case "T":
 577                         // PlayerInfo_AddItem(p, "_time", data);
 578                         break;
 579                     case "S":
 580                         // PlayerInfo_AddItem(p, "_statsurl", data);
 581                         break;
 582                     case "P":
 583                         // PlayerInfo_AddItem(p, "_hashkey", data);
 584                         break;
 585                     case "n":
 586                         // PlayerInfo_AddItem(p, "_playernick", data);
 587                         break;
 588                     case "i":
 589                         // PlayerInfo_AddItem(p, "_playerid", data);
 590                         // p.xonstat_id = stof(data);
 591                         break;
 592                     case "G":
 593                         gt = data;
 594                         break;
 595                     case "e":
 596                         //LOG_TRACE("G: ", gt);
 597                         //LOG_TRACE("e: ", data);
 598                         if (gt == PlayerStats_GetGametype()) {
 599                             handled = true;
 600                             float e = stof(data);
 601                             GameRules_scoring_add(p, ELO, +1 + e);
 602                         }
 603                         if (gt == "") {
 604                             // PlayerInfo_AddItem(p, value, data);
 605                         } else {
 606                             // PlayerInfo_AddItem(p, sprintf("%s/%s", gt, value), data);
 607                         }
 608                         break;
 609                 }
 610                         }
 611                         url_fclose(fh);
 612                         if (handled) return;
 613                         break;
 614                 }
 615                 case URL_READY_CLOSED:
 616                 {
 617                         // url_fclose has finished
 618                         LOG_INFO("Player stats synchronized with server");
 619                         return;
 620                 }
 621
 622                 case URL_READY_ERROR:
 623                 default:
 624                 {
 625                         LOG_INFO("Receiving player stats failed: ", ftos(status));
 626                         break;
 627                 }
 628         }
 629         GameRules_scoring_add(p, ELO, -1);
 630 }
 631 #endif // SVQC
 632
 633 #ifdef MENUQC
 634
 635
 636 #if 0 // reading the entire DB at once
 637         string e = "", en = "";
 638         float i = 0;
 639         for(e = PS_D_IN_EVL; (en = db_get(PS_D_IN_DB, e)) != ""; e = en)
 640         {
 641                 LOG_INFOF("%d:%s:%s", i, e, db_get(PS_D_IN_DB, sprintf("#%s", e)));
 642                 ++i;
 643         }
 644 #endif
 645
 646 void PlayerStats_PlayerDetail_AddItem(string event, string data)
 647 {
 648         if(PS_D_IN_DB < 0) { return; }
 649
 650         // create a marker for the event so that we can access it later
 651         string marker = sprintf("%s", event);
 652         if(db_get(PS_D_IN_DB, marker) == "")
 653         {
 654                 if(PS_D_IN_EVL)
 655                 {
 656                         db_put(PS_D_IN_DB, marker, PS_D_IN_EVL);
 657                         strunzone(PS_D_IN_EVL);
 658                 }
 659                 else { db_put(PS_D_IN_DB, marker, "#"); }
 660                 PS_D_IN_EVL = strzone(marker);
 661         }
 662
 663         // now actually set the event data
 664         db_put(PS_D_IN_DB, sprintf("#%s", event), data);
 665         LOG_DEBUG("Added item ", sprintf("#%s", event), "=", data, " to PS_D_IN_DB");
 666 }
 667
 668 void PlayerStats_PlayerDetail()
 669 {
 670         // http://stats.xonotic.org/player/me
 671         if((autocvar_g_playerstats_playerdetail_uri != "") && (crypto_getmyidstatus(0) > 0))
 672         {
 673                 // create the database if it doesn't already exist
 674                 if(PS_D_IN_DB < 0)
 675                         PS_D_IN_DB = db_create();
 676
 677                 //uri = strcat(uri, "/player/", uri_escape(crypto_getmyidfp(0)));
 678                 LOG_DEBUG("Retrieving playerstats from URL: ", autocvar_g_playerstats_playerdetail_uri);
 679                 url_single_fopen(
 680                         autocvar_g_playerstats_playerdetail_uri,
 681                         FILE_APPEND,
 682                         PlayerStats_PlayerDetail_Handler,
 683                         NULL
 684                 );
 685
 686                 PlayerStats_PlayerDetail_Status = PS_D_STATUS_WAITING;
 687         }
 688         else
 689         {
 690                 // player has this disabled, kill the DB and set status to idle
 691                 if(PS_D_IN_DB >= 0)
 692                 {
 693                         db_close(PS_D_IN_DB);
 694                         PS_D_IN_DB = -1;
 695                 }
 696
 697                 PlayerStats_PlayerDetail_Status = PS_D_STATUS_IDLE;
 698         }
 699 }
 700
 701 void PlayerStats_PlayerDetail_CheckUpdate()
 702 {
 703         // determine whether we should retrieve playerdetail information again
 704         float gamecount = cvar("cl_matchcount");
 705
 706         #if 0
 707         LOG_INFOF("PlayerStats_PlayerDetail_CheckUpdate(): %f >= %f, %d > %d",
 708                 time,
 709                 PS_D_NEXTUPDATETIME,
 710                 PS_D_LASTGAMECOUNT,
 711                 gamecount
 712         );
 713         #endif
 714
 715         if(
 716                 (time >= PS_D_NEXTUPDATETIME)
 717                 ||
 718                 (gamecount > PS_D_LASTGAMECOUNT)
 719         )
 720         {
 721                 PlayerStats_PlayerDetail();
 722                 PS_D_NEXTUPDATETIME = (time + autocvar_g_playerstats_playerdetail_autoupdatetime);
 723                 PS_D_LASTGAMECOUNT = gamecount;
 724         }
 725 }
 726
 727 void PlayerStats_PlayerDetail_Handler(entity fh, entity unused, float status)
 728 {
 729         switch(status)
 730         {
 731                 case URL_READY_CANWRITE:
 732                 {
 733                         LOG_DEBUG("PlayerStats_PlayerDetail_Handler(): Sending data to player stats server...");
 734                         url_fputs(fh, "V 1\n");
 735                         #ifdef WATERMARK
 736                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 737                         #endif
 738                         url_fputs(fh, sprintf("l %s\n", cvar_string("_menu_prvm_language"))); // language
 739                         //url_fputs(fh, sprintf("c %s\n", cvar_string("_cl_country"))); // country
 740                         //url_fputs(fh, sprintf("g %s\n", cvar_string("_cl_gender"))); // gender
 741                         url_fputs(fh, sprintf("n %s\n", cvar_string("_cl_name"))); // name
 742                         url_fputs(fh, sprintf("m %s %s\n", cvar_string("_cl_playermodel"), cvar_string("_cl_playerskin"))); // model/skin
 743                         url_fputs(fh, "\n");
 744                         url_fclose(fh);
 745                         break;
 746                 }
 747
 748                 case URL_READY_CANREAD:
 749                 {
 750                         //print("PlayerStats_PlayerDetail_Handler(): Got response from player stats server:\n");
 751                         string input = "";
 752                         string gametype = "overall";
 753                         while((input = url_fgets(fh)))
 754                         {
 755                                 float count = tokenizebyseparator(input, " ");
 756                                 string key = "", event = "", data = "";
 757
 758                                 if(argv(0) == "#") { continue; }
 759
 760                                 if(count == 2)
 761                                 {
 762                                         key = argv(0);
 763                                         data = substring(input, argv_start_index(1), strlen(input) - argv_start_index(1));
 764                                 }
 765                                 else if(count >= 3)
 766                                 {
 767                                         key = argv(0);
 768                                         event = argv(1);
 769                                         data = substring(input, argv_start_index(2), strlen(input) - argv_start_index(2));
 770                                 }
 771                                 else { continue; }
 772
 773                                 switch(key)
 774                                 {
 775                                         // general info
 776                                         case "V": PlayerStats_PlayerDetail_AddItem("version", data); break;
 777                                         case "R": PlayerStats_PlayerDetail_AddItem("release", data); break;
 778                                         case "T": PlayerStats_PlayerDetail_AddItem("time", data); break;
 779
 780                                         // player info
 781                                         case "S": PlayerStats_PlayerDetail_AddItem("statsurl", data); break;
 782                                         case "P": PlayerStats_PlayerDetail_AddItem("hashkey", data); break;
 783                                         case "n": PlayerStats_PlayerDetail_AddItem("playernick", data); break;
 784                                         case "i": PlayerStats_PlayerDetail_AddItem("playerid", data); break;
 785
 786                                         // other/event info
 787                                         case "G": gametype = data; break;
 788                                         case "e":
 789                                         {
 790                                                 if(event != "" && data != "")
 791                                                 {
 792                                                         PlayerStats_PlayerDetail_AddItem(
 793                                                                 sprintf(
 794                                                                         "%s/%s",
 795                                                                         gametype,
 796                                                                         event
 797                                                                 ),
 798                                                                 data
 799                                                         );
 800                                                 }
 801                                                 break;
 802                                         }
 803
 804                                         default:
 805                                         {
 806                                                 LOG_INFOF(
 807                                                         "PlayerStats_PlayerDetail_Handler(): ERROR: "
 808                                                         "Key went unhandled? Is our version outdated?\n"
 809                                                         "PlayerStats_PlayerDetail_Handler(): "
 810                                                         "Key '%s', Event '%s', Data '%s'",
 811                                                         key,
 812                                                         event,
 813                                                         data
 814                                                 );
 815                                                 break;
 816                                         }
 817                                 }
 818
 819                                 #if 0
 820                                 LOG_INFOF(
 821                                         "PlayerStats_PlayerDetail_Handler(): "
 822                                         "Key '%s', Event '%s', Data '%s'",
 823                                         key,
 824                                         event,
 825                                         data
 826                                 );
 827                                 #endif
 828                         }
 829                         //print("PlayerStats_PlayerDetail_Handler(): End of response.\n");
 830                         url_fclose(fh);
 831                         PlayerStats_PlayerDetail_Status = PS_D_STATUS_RECEIVED;
 832                         statslist.getStats(statslist);
 833                         break;
 834                 }
 835
 836                 case URL_READY_CLOSED:
 837                 {
 838                         // url_fclose has finished
 839                         LOG_INFO("PlayerStats_PlayerDetail_Handler(): Player stats synchronized with server.");
 840                         break;
 841                 }
 842
 843                 case URL_READY_ERROR:
 844                 default:
 845                 {
 846                         LOG_INFO("PlayerStats_PlayerDetail_Handler(): Receiving player stats failed: ", ftos(status));
 847                         PlayerStats_PlayerDetail_Status = PS_D_STATUS_ERROR;
 848                         if(PS_D_IN_DB >= 0)
 849                         {
 850                                 db_close(PS_D_IN_DB);
 851                                 PS_D_IN_DB = -1;
 852                         }
 853                         break;
 854                 }
 855         }
 856 }
 857 #endif
 858
 859 /*
 860 void PlayerInfo_AddPlayer(entity e)
 861 {
 862         if(playerinfo_db < 0)
 863                 return;
 864
 865         string key;
 866         key = sprintf("#%d:*", e.playerid); // TODO: use hashkey instead?
 867
 868         string p;
 869         p = db_get(playerinfo_db, key);
 870         if(p == "")
 871         {
 872                 if(playerinfo_last)
 873                 {
 874                         db_put(playerinfo_db, key, playerinfo_last);
 875                         strunzone(playerinfo_last);
 876                 }
 877                 else
 878                         db_put(playerinfo_db, key, "#");
 879                 playerinfo_last = strzone(ftos(e.playerid));
 880                 print("  Added player ", ftos(e.playerid), " to playerinfo_db\n");//DEBUG//
 881         }
 882 }
 883
 884 void PlayerInfo_AddItem(entity e, string item_id, string val)
 885 {
 886         if(playerinfo_db < 0)
 887                 return;
 888
 889         string key;
 890         key = sprintf("*:%s", item_id);
 891
 892         string p;
 893         p = db_get(playerinfo_db, key);
 894         if(p == "")
 895         {
 896                 if(playerinfo_events_last)
 897                 {
 898                         db_put(playerinfo_db, key, playerinfo_events_last);
 899                         strunzone(playerinfo_events_last);
 900                 }
 901                 else
 902                         db_put(playerinfo_db, key, "#");
 903                 playerinfo_events_last = strzone(item_id);
 904         }
 905
 906         key = sprintf("#%d:%s", e.playerid, item_id);
 907         db_put(playerinfo_db, key, val);
 908         print("  Added item ", key, "=", val, " to playerinfo_db\n");//DEBUG//
 909 }
 910
 911 string PlayerInfo_GetItem(entity e, string item_id)
 912 {
 913         if(playerinfo_db < 0)
 914                 return "";
 915
 916         string key;
 917         key = sprintf("#%d:%s",  e.playerid, item_id);
 918         return db_get(playerinfo_db, key);
 919 }
 920
 921 string PlayerInfo_GetItemLocal(string item_id)
 922 {
 923         entity p = spawn();
 924         p.playerid = 0;
 925         return PlayerInfo_GetItem(p, item_id);
 926 }
 927
 928 void PlayerInfo_ready(entity fh, entity p, float status)
 929 {
 930         float n;
 931         string s;
 932
 933         PlayerInfo_AddPlayer(p);
 934
 935         switch(status)
 936         {
 937                 case URL_READY_CANWRITE:
 938                         print("-- Sending data to player stats server\n");
 939                         url_fputs(fh, "V 1\n");
 940 #ifdef WATERMARK
 941                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 942 #endif
 943 #ifdef MENUQC
 944                         url_fputs(fh, sprintf("l %s\n", cvar_string("_menu_prvm_language"))); // language
 945                         url_fputs(fh, sprintf("c %s\n", cvar_string("_menu_prvm_country"))); // country
 946                         url_fputs(fh, sprintf("g %s\n", cvar_string("_cl_gender"))); // gender
 947                         url_fputs(fh, sprintf("n %s\n", cvar_string("_cl_name"))); // name
 948                         url_fputs(fh, sprintf("m %s %s\n", cvar_string("_cl_playermodel"), cvar_string("_cl_playerskin"))); // model/skin
 949 #endif
 950                         url_fputs(fh, "\n");
 951                         url_fclose(fh);
 952                         break;
 953                 case URL_READY_CANREAD:
 954                         print("-- Got response from player stats server:\n");
 955                         string gametype = string_null;
 956                         while((s = url_fgets(fh)))
 957                         {
 958                                 print("  ", s, "\n");
 959
 960                                 string key = "", value = "", data = "";
 961
 962                                 n = tokenizebyseparator(s, " "); // key (value) data
 963                                 if (n == 1)
 964                                         continue;
 965                                 else if (n == 2)
 966                                 {
 967                                         key = argv(0);
 968                                         data = argv(1);
 969                                 }
 970                                 else if (n >= 3)
 971                                 {
 972                                         key = argv(0);
 973                                         value = argv(1);
 974                                         data = argv(2);
 975                                 }
 976
 977                                 if (data == "")
 978                                         continue;
 979
 980                                 if (key == "#")
 981                                         continue;
 982                                 else if (key == "V")
 983                                         PlayerInfo_AddItem(p, "_version", data);
 984                                 else if (key == "R")
 985                                         PlayerInfo_AddItem(p, "_release", data);
 986                                 else if (key == "T")
 987                                         PlayerInfo_AddItem(p, "_time", data);
 988                                 else if (key == "S")
 989                                         PlayerInfo_AddItem(p, "_statsurl", data);
 990                                 else if (key == "P")
 991                                         PlayerInfo_AddItem(p, "_hashkey", data);
 992                                 else if (key == "n")
 993                                         PlayerInfo_AddItem(p, "_playernick", data);
 994                                 else if (key == "i")
 995                                         PlayerInfo_AddItem(p, "_playerid", data);
 996                                 else if (key == "G")
 997                                         gametype = data;
 998                                 else if (key == "e" && value != "")
 999                                 {
1000                                         if (gametype == "")
1001                                                 PlayerInfo_AddItem(p, value, data);
1002                                         else
1003                                                 PlayerInfo_AddItem(p, sprintf("%s/%s", gametype, value), data);
1004                                 }
1005                                 else
1006                                         continue;
1007                         }
1008                         print("-- End of response.\n");
1009                         url_fclose(fh);
1010                         break;
1011                 case URL_READY_CLOSED:
1012                         // url_fclose has finished
1013                         print("Player stats synchronized with server\n");
1014                         break;
1015                 case URL_READY_ERROR:
1016                 default:
1017                         print("Receiving player stats failed: ", ftos(status), "\n");
1018                         break;
1019         }
1020 }
1021
1022 void PlayerInfo_Init()
1023 {
1024         playerinfo_db = db_create();
1025 }
1026
1027 #ifdef SVQC
1028 void PlayerInfo_Basic(entity p)
1029 {
1030         print("-- Getting basic PlayerInfo for player ",ftos(p.playerid)," (SVQC)\n");
1031
1032         if(playerinfo_db < 0)
1033                 return;
1034
1035         string uri;
1036         uri = autocvar_g_playerinfo_uri;
1037         if(uri != "" && p.crypto_idfp != "")
1038         {
1039                 uri = strcat(uri, "/elo/", uri_escape(p.crypto_idfp));
1040                 print("Retrieving playerstats from URL: ", uri, "\n");
1041                 url_single_fopen(uri, FILE_READ, PlayerInfo_ready, p);
1042         }
1043 }
1044 #endif
1045
1046 #ifdef MENUQC
1047 void PlayerInfo_Details()
1048 {
1049         print("-- Getting detailed PlayerInfo for local player (MENUQC)\n");
1050
1051         if(playerinfo_db < 0)
1052                 return;
1053
1054         string uri;
1055         uri = autocvar_g_playerinfo_uri; // FIXME
1056         if(uri != "" && crypto_getmyidstatus(0) > 0)
1057         {
1058                 //uri = strcat(uri, "/player/", uri_escape(crypto_getmyidfp(0)));
1059                 uri = strcat(uri, "/player/me");
1060                 print("Retrieving playerstats from URL: ", uri, "\n");
1061                 url_single_fopen(uri, FILE_APPEND, PlayerInfo_ready, NULL);
1062         }
1063 }
1064 #endif
1065
1066 #ifdef CSQC
1067 // FIXME - crypto_* builtin functions missing in CSQC (csprogsdefs.qh:885)
1068 void PlayerInfo_Details()
1069 {
1070         print("-- Getting detailed PlayerInfo for local player (CSQC)\n");
1071
1072         if(playerinfo_db < 0)
1073                 return;
1074
1075         string uri;
1076         uri = autocvar_g_playerinfo_uri; // FIXME
1077         if(uri != "" && crypto_getmyidstatus(0) > 0)
1078         {
1079                 uri = strcat(uri, "/player/", uri_escape(crypto_getmyidfp(0)));
1080                 print("Retrieving playerstats from URL: ", uri, "\n");
1081                 url_single_fopen(uri, FILE_READ, PlayerInfo_ready, p);
1082         }
1083 }
1084
1085 #endif
1086 */