qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "mapobjects/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 this.alpha = autocvar_cl_ghost_items;
  54                 this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  55         }
  56
  57         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  58         {
  59                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  60                 this.alpha = autocvar_cl_weapon_stay_alpha;
  61         }
  62
  63         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  64 }
  65
  66 void ItemDraw(entity this)
  67 {
  68     if(this.gravity)
  69     {
  70         Movetype_Physics_MatchServer(this, false);
  71         if(IS_ONGROUND(this))
  72         { // For some reason avelocity gets set to '0 0 0' here ...
  73             this.oldorigin = this.origin;
  74             this.gravity = 0;
  75
  76             if(autocvar_cl_animate_items)
  77             { // ... so reset it if animations are requested.
  78                 if(this.ItemStatus & ITS_ANIMATE1)
  79                     this.avelocity = '0 180 0';
  80
  81                 if(this.ItemStatus & ITS_ANIMATE2)
  82                     this.avelocity = '0 -90 0';
  83             }
  84
  85             // delay is for blocking item's position for a while;
  86             // it's a workaround for dropped weapons that receive the position
  87             // another time right after they spawn overriding animation position
  88             this.onground_time = time + 0.5;
  89         }
  90     }
  91     else if (autocvar_cl_animate_items && !this.item_simple) // no bobbing applied to simple items, for consistency's sake (no visual difference between ammo and weapons)
  92     {
  93         if(this.ItemStatus & ITS_ANIMATE1)
  94         {
  95                 this.angles += this.avelocity * frametime;
  96             float fade_in = bound(0, time - this.onground_time, 1);
  97             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
  98         }
  99
 100         if(this.ItemStatus & ITS_ANIMATE2)
 101         {
 102                 this.angles += this.avelocity * frametime;
 103             float fade_in = bound(0, time - this.onground_time, 1);
 104             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 105         }
 106     }
 107
 108     Item_SetAlpha(this);
 109 }
 110
 111 void Item_PreDraw(entity this)
 112 {
 113         if(warpzone_warpzones_exist)
 114         {
 115                 setpredraw(this, func_null); // no need to keep running this
 116                 return;
 117         }
 118         float alph;
 119         vector org = getpropertyvec(VF_ORIGIN);
 120         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 121                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 122         if(this.fade_start)
 123         {
 124                 if(vdist(org - this.origin, >, this.fade_end))
 125                         alph = 0; // save on some processing
 126                 else if(vdist(org - this.origin, <, this.fade_start))
 127                         alph = 1; // more processing saved
 128                 else
 129                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 130         }
 131         else
 132                 alph = 1;
 133         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 134         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 135                 this.alpha = alph;
 136         if(alph <= 0)
 137                 this.drawmask = 0;
 138         //else
 139                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 140 }
 141
 142 void ItemRemove(entity this)
 143 {
 144         strfree(this.mdl);
 145 }
 146
 147 HashMap ENT_CLIENT_ITEM_simple;
 148 STATIC_INIT(ENT_CLIENT_ITEM_simple)
 149 {
 150         HM_NEW(ENT_CLIENT_ITEM_simple);
 151 }
 152 SHUTDOWN(ENT_CLIENT_ITEM_simple)
 153 {
 154         HM_DELETE(ENT_CLIENT_ITEM_simple);
 155 }
 156
 157 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 158 {
 159     int sf = ReadByte();
 160
 161     if(sf & ISF_LOCATION)
 162     {
 163         this.origin = ReadVector();
 164         setorigin(this, this.origin);
 165         this.oldorigin = this.origin;
 166     }
 167
 168     if(sf & ISF_ANGLES)
 169     {
 170         this.angles_x = ReadAngle();
 171         this.angles_y = ReadAngle();
 172         this.angles_z = ReadAngle();
 173     }
 174
 175     if(sf & ISF_SIZE)
 176     {
 177         float use_bigsize = ReadByte();
 178         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 179     }
 180
 181     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 182     {
 183         this.ItemStatus = ReadByte();
 184
 185         Item_SetAlpha(this);
 186
 187         if(autocvar_cl_fullbright_items)
 188             if(this.ItemStatus & ITS_ALLOWFB)
 189                 this.effects |= EF_FULLBRIGHT;
 190
 191         if(this.ItemStatus & ITS_GLOW)
 192         {
 193             if(this.ItemStatus & ITS_AVAILABLE)
 194                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 195             else
 196                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 197         }
 198     }
 199
 200     if(sf & ISF_MODEL)
 201     {
 202         this.drawmask  = MASK_NORMAL;
 203                 set_movetype(this, MOVETYPE_TOSS);
 204                 if (isnew) IL_PUSH(g_drawables, this);
 205         this.draw       = ItemDraw;
 206         this.solid = SOLID_TRIGGER;
 207         //this.flags |= FL_ITEM;
 208
 209         bool use_bigsize = ReadByte();
 210
 211         this.fade_end = ReadShort();
 212         this.fade_start = ReadShort();
 213         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 214                 setpredraw(this, Item_PreDraw);
 215
 216                 strfree(this.mdl);
 217
 218         string _fn = ReadString();
 219         this.item_simple = false; // reset it!
 220
 221         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 222         {
 223             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 224             this.item_simple = true;
 225
 226                         #define extensions(x) \
 227                                 x(md3) \
 228                                 x(dpm) \
 229                                 x(iqm) \
 230                                 x(mdl) \
 231                                 /**/
 232                         #define tryext(ext) { \
 233                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
 234                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
 235                                 if (cached == "") { \
 236                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
 237                                 } \
 238                                 if (cached != "0") { \
 239                                         strcpy(this.mdl, s); \
 240                                         break; \
 241                                 } \
 242                         }
 243                         do {
 244                                 extensions(tryext);
 245                                 this.item_simple = false;
 246                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
 247                         } while (0);
 248                         #undef tryext
 249                         #undef extensions
 250         }
 251
 252         if(!this.item_simple)
 253             strcpy(this.mdl, _fn);
 254
 255         if(this.mdl == "")
 256             LOG_WARNF("this.mdl is unset for item %s", this.classname);
 257
 258         precache_model(this.mdl);
 259         _setmodel(this, this.mdl);
 260
 261         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 262     }
 263
 264     if(sf & ISF_COLORMAP)
 265     {
 266         this.colormap = ReadShort();
 267         this.item_glowmod_x = ReadByte() / 255.0;
 268         this.item_glowmod_y = ReadByte() / 255.0;
 269         this.item_glowmod_z = ReadByte() / 255.0;
 270     }
 271
 272     if(sf & ISF_DROP)
 273     {
 274         this.gravity = 1;
 275         this.pushable = true;
 276         //this.angles = '0 0 0';
 277         set_movetype(this, MOVETYPE_TOSS);
 278         this.velocity = ReadVector();
 279         setorigin(this, this.oldorigin);
 280
 281         if(!this.move_time)
 282         {
 283             this.move_time = time;
 284             this.spawntime = time;
 285         }
 286         else
 287             this.move_time = max(this.move_time, time);
 288     }
 289
 290     if(autocvar_cl_animate_items)
 291     {
 292         if(this.ItemStatus & ITS_ANIMATE1)
 293             this.avelocity = '0 180 0';
 294
 295         if(this.ItemStatus & ITS_ANIMATE2)
 296             this.avelocity = '0 -90 0';
 297     }
 298
 299     this.entremove = ItemRemove;
 300
 301     return true;
 302 }
 303
 304 #endif
 305
 306 #ifdef SVQC
 307 bool ItemSend(entity this, entity to, int sf)
 308 {
 309         if(this.gravity)
 310                 sf |= ISF_DROP;
 311         else
 312                 sf &= ~ISF_DROP;
 313
 314         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 315         WriteByte(MSG_ENTITY, sf);
 316
 317         //WriteByte(MSG_ENTITY, this.cnt);
 318         if(sf & ISF_LOCATION)
 319         {
 320                 WriteVector(MSG_ENTITY, this.origin);
 321         }
 322
 323         if(sf & ISF_ANGLES)
 324         {
 325                 WriteAngle(MSG_ENTITY, this.angles_x);
 326                 WriteAngle(MSG_ENTITY, this.angles_y);
 327                 WriteAngle(MSG_ENTITY, this.angles_z);
 328         }
 329
 330         if(sf & ISF_SIZE)
 331         {
 332                 Pickup p = this.itemdef;
 333                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 334         }
 335
 336         if(sf & ISF_STATUS)
 337                 WriteByte(MSG_ENTITY, this.ItemStatus);
 338
 339         if(sf & ISF_MODEL)
 340         {
 341                 Pickup p = this.itemdef;
 342                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 343                 WriteShort(MSG_ENTITY, this.fade_end);
 344                 WriteShort(MSG_ENTITY, this.fade_start);
 345
 346                 if(this.mdl == "")
 347                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 348
 349                 WriteString(MSG_ENTITY, this.mdl);
 350         }
 351
 352
 353         if(sf & ISF_COLORMAP)
 354         {
 355                 WriteShort(MSG_ENTITY, this.colormap);
 356                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 357                 WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 358                 WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 359         }
 360
 361         if(sf & ISF_DROP)
 362         {
 363                 WriteVector(MSG_ENTITY, this.velocity);
 364         }
 365
 366         return true;
 367 }
 368
 369 void ItemUpdate(entity this)
 370 {
 371         this.oldorigin = this.origin;
 372         this.SendFlags |= ISF_LOCATION;
 373 }
 374
 375 void UpdateItemAfterTeleport(entity this)
 376 {
 377         if(getSendEntity(this) == ItemSend)
 378                 ItemUpdate(this);
 379 }
 380
 381 bool have_pickup_item(entity this)
 382 {
 383         if(this.itemdef.instanceOfPowerup)
 384         {
 385                 if(autocvar_g_powerups > 0)
 386                         return true;
 387                 if(autocvar_g_powerups == 0)
 388                         return false;
 389         }
 390         else
 391         {
 392                 if(autocvar_g_pickup_items > 0)
 393                         return true;
 394                 if(autocvar_g_pickup_items == 0)
 395                         return false;
 396                 if(g_weaponarena)
 397                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 398                                 return false;
 399         }
 400         return true;
 401 }
 402
 403 void Item_Show(entity e, int mode)
 404 {
 405         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 406         e.ItemStatus &= ~ITS_STAYWEP;
 407         entity def = e.itemdef;
 408         if (mode > 0)
 409         {
 410                 // make the item look normal, and be touchable
 411                 e.model = e.mdl;
 412                 e.solid = SOLID_TRIGGER;
 413                 e.spawnshieldtime = 1;
 414                 e.ItemStatus |= ITS_AVAILABLE;
 415         }
 416         else if (mode < 0)
 417         {
 418                 // hide the item completely
 419                 e.model = string_null;
 420                 e.solid = SOLID_NOT;
 421                 e.spawnshieldtime = 1;
 422                 e.ItemStatus &= ~ITS_AVAILABLE;
 423         }
 424         else
 425         {
 426                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 427                         || e.team // weapon stay isn't supported for teamed weapons
 428                         ;
 429                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 430                 {
 431                         // make the item translucent and not touchable
 432                         e.model = e.mdl;
 433                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 434                         e.effects |= EF_STARDUST;
 435                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 436                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 437                 }
 438                 else
 439                 {
 440                         //setmodel(e, "null");
 441                         e.solid = SOLID_NOT;
 442                         e.colormod = '0 0 0';
 443                         //e.glowmod = e.colormod;
 444                         e.spawnshieldtime = 1;
 445                         e.ItemStatus &= ~ITS_AVAILABLE;
 446                 }
 447         }
 448
 449         if (def.m_glow)
 450                 e.ItemStatus |= ITS_GLOW;
 451
 452         if (autocvar_g_nodepthtestitems)
 453                 e.effects |= EF_NODEPTHTEST;
 454
 455
 456         if (autocvar_g_fullbrightitems)
 457                 e.ItemStatus |= ITS_ALLOWFB;
 458
 459         if (autocvar_sv_simple_items)
 460                 e.ItemStatus |= ITS_ALLOWSI;
 461
 462         // relink entity (because solid may have changed)
 463         setorigin(e, e.origin);
 464         e.SendFlags |= ISF_STATUS;
 465 }
 466
 467 void Item_Think(entity this)
 468 {
 469         this.nextthink = time;
 470         if(this.origin != this.oldorigin)
 471                 ItemUpdate(this);
 472 }
 473
 474 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 475 bool Item_ItemsTime_Allow(GameItem it);
 476 float Item_ItemsTime_UpdateTime(entity e, float t);
 477 void Item_ItemsTime_SetTime(entity e, float t);
 478 void Item_ItemsTime_SetTimesForAllPlayers();
 479
 480 void Item_Respawn(entity this)
 481 {
 482         Item_Show(this, 1);
 483         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 484         setorigin(this, this.origin);
 485
 486         if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
 487         {
 488                 float t = Item_ItemsTime_UpdateTime(this, 0);
 489                 Item_ItemsTime_SetTime(this, t);
 490                 Item_ItemsTime_SetTimesForAllPlayers();
 491         }
 492
 493         setthink(this, Item_Think);
 494         this.nextthink = time;
 495
 496         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 497         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 498 }
 499
 500 void Item_RespawnCountdown(entity this)
 501 {
 502         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 503         {
 504                 if(this.waypointsprite_attached)
 505                         WaypointSprite_Kill(this.waypointsprite_attached);
 506                 Item_Respawn(this);
 507         }
 508         else
 509         {
 510                 this.nextthink = time + 1;
 511                 this.item_respawncounter += 1;
 512                 if(this.item_respawncounter == 1)
 513                 {
 514                         do {
 515                                 {
 516                                         entity wi = Weapons_from(this.weapon);
 517                                         if (wi != WEP_Null) {
 518                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 519                                                 wp.wp_extra = wi.m_id;
 520                                                 break;
 521                                         }
 522                                 }
 523                                 {
 524                                         entity ii = this.itemdef;
 525                                         if (ii != NULL) {
 526                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 527                                                 wp.wp_extra = ii.m_id;
 528                                                 break;
 529                                         }
 530                                 }
 531                         } while (0);
 532                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 533             if(this.waypointsprite_attached)
 534             {
 535                 GameItem def = this.itemdef;
 536                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 537                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 538                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 539             }
 540                 }
 541
 542                 if(this.waypointsprite_attached)
 543                 {
 544                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 545                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 546                                 {
 547                                         msg_entity = it;
 548                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 549                                 }
 550                         });
 551
 552                         WaypointSprite_Ping(this.waypointsprite_attached);
 553                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 554                 }
 555         }
 556 }
 557
 558 void Item_RespawnThink(entity this)
 559 {
 560         this.nextthink = time;
 561         if(this.origin != this.oldorigin)
 562                 ItemUpdate(this);
 563
 564         if(time >= this.wait)
 565                 Item_Respawn(this);
 566 }
 567
 568 void Item_ScheduleRespawnIn(entity e, float t)
 569 {
 570         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 571         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 572         {
 573                 setthink(e, Item_RespawnCountdown);
 574                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 575                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 576                 e.item_respawncounter = 0;
 577                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 578                 {
 579                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 580                         Item_ItemsTime_SetTime(e, t);
 581                         Item_ItemsTime_SetTimesForAllPlayers();
 582                 }
 583         }
 584         else
 585         {
 586                 setthink(e, Item_RespawnThink);
 587                 e.nextthink = time;
 588                 e.scheduledrespawntime = time + t;
 589                 e.wait = time + t;
 590
 591                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 592                 {
 593                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 594                         Item_ItemsTime_SetTime(e, t);
 595                         Item_ItemsTime_SetTimesForAllPlayers();
 596                 }
 597         }
 598 }
 599
 600 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 601 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 602 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 603
 604 /// Adjust respawn time according to the number of players.
 605 float adjust_respawntime(float normal_respawntime) {
 606         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 607         float o = autocvar_g_pickup_respawntime_scaling_offset;
 608         float l = autocvar_g_pickup_respawntime_scaling_linear;
 609
 610         if (r == 0 && l == 1) {
 611                 return normal_respawntime;
 612         }
 613
 614         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 615         TeamBalance_GetTeamCounts(balance, NULL);
 616         int players = 0;
 617         for (int i = 1; i <= NUM_TEAMS; ++i)
 618         {
 619                 if (TeamBalance_IsTeamAllowed(balance, i))
 620                 {
 621                         players += TeamBalance_GetNumberOfPlayers(balance, i);
 622                 }
 623         }
 624         TeamBalance_Destroy(balance);
 625
 626         if (players >= 2) {
 627                 return normal_respawntime * (r / (players + o) + l);
 628         } else {
 629                 return normal_respawntime;
 630         }
 631 }
 632
 633 void Item_ScheduleRespawn(entity e)
 634 {
 635         if(e.respawntime > 0)
 636         {
 637                 Item_Show(e, 0);
 638
 639                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 640                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 641
 642                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 643                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 644                 Item_ScheduleRespawnIn(e, respawn_in);
 645         }
 646         else // if respawntime is -1, this item does not respawn
 647                 Item_Show(e, -1);
 648 }
 649
 650 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 651         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 652
 653 void Item_ScheduleInitialRespawn(entity e)
 654 {
 655         Item_Show(e, 0);
 656
 657         float spawn_in;
 658         if (autocvar_g_pickup_respawntime_initial_random == 0)
 659         {
 660                 // range: respawntime .. respawntime + respawntimejitter
 661                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 662         }
 663         else
 664         {
 665                 float rnd;
 666                 if (autocvar_g_pickup_respawntime_initial_random == 1)
 667                 {
 668                         static float shared_random = 0;
 669                         // NOTE this code works only if items are scheduled at the same time (normal case)
 670                         // NOTE2 random() can't return exactly 1 so this check always work as intended
 671                         if (!shared_random || floor(time) > shared_random)
 672                                 shared_random = floor(time) + random();
 673                         rnd = shared_random - floor(time);
 674                 }
 675                 else
 676                         rnd = random();
 677
 678                 // range:
 679                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 680                 // else: 0 .. ITEM_RESPAWN_TICKS
 681                 // this is to prevent powerups spawning unexpectedly without waypoints
 682                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 683         }
 684
 685         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 686 }
 687
 688 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 689         entity ammo_entity)
 690 {
 691         if (num_weapons == 0)
 692         {
 693                 return;
 694         }
 695         int num_potential_weapons = tokenize_console(weapon_names);
 696         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 697         {
 698                 RandomSelection_Init();
 699                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 700                         ++weapon_index)
 701                 {
 702                         string weapon = argv(weapon_index);
 703                         FOREACH(Weapons, it != WEP_Null,
 704                         {
 705                                 // Finding a weapon which player doesn't have.
 706                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
 707                                 {
 708                                         RandomSelection_AddEnt(it, 1, 1);
 709                                         break;
 710                                 }
 711                         });
 712                 }
 713                 if (RandomSelection_chosen_ent == NULL)
 714                 {
 715                         return;
 716                 }
 717                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
 718                 if (RandomSelection_chosen_ent.ammo_type == RES_NONE)
 719                 {
 720                         continue;
 721                 }
 722                 if (GetResource(receiver,
 723                         RandomSelection_chosen_ent.ammo_type) != 0)
 724                 {
 725                         continue;
 726                 }
 727                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 728                         GetResource(ammo_entity,
 729                         RandomSelection_chosen_ent.ammo_type));
 730         }
 731 }
 732
 733 bool Item_GiveAmmoTo(entity item, entity player, int res_type, float ammomax)
 734 {
 735         float amount = GetResource(item, res_type);
 736         if (amount == 0)
 737         {
 738                 return false;
 739         }
 740         float player_amount = GetResource(player, res_type);
 741         if (item.spawnshieldtime)
 742         {
 743                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 744                         return false;
 745         }
 746         else if (g_weapon_stay == 2)
 747                 ammomax = min(amount, ammomax);
 748         else
 749                 return false;
 750         if (amount < 0)
 751                 TakeResourceWithLimit(player, res_type, -amount, ammomax);
 752         else
 753                 GiveResourceWithLimit(player, res_type, amount, ammomax);
 754         return true;
 755 }
 756
 757 bool Item_GiveTo(entity item, entity player)
 758 {
 759         // if nothing happens to player, just return without taking the item
 760         int _switchweapon = 0;
 761         // in case the player has autoswitch enabled do the following:
 762         // if the player is using their best weapon before items are given, they
 763         // probably want to switch to an even better weapon after items are given
 764
 765         if(CS(player).autoswitch)
 766         {
 767                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 768                 {
 769                         .entity weaponentity = weaponentities[slot];
 770                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 771                         {
 772                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 773                                         _switchweapon |= BIT(slot);
 774
 775                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 776                                         _switchweapon |= BIT(slot);
 777                         }
 778                 }
 779         }
 780         bool pickedup = false;
 781         pickedup |= Item_GiveAmmoTo(item, player, RES_HEALTH, item.max_health);
 782         pickedup |= Item_GiveAmmoTo(item, player, RES_ARMOR, item.max_armorvalue);
 783         pickedup |= Item_GiveAmmoTo(item, player, RES_SHELLS, g_pickup_shells_max);
 784         pickedup |= Item_GiveAmmoTo(item, player, RES_BULLETS, g_pickup_nails_max);
 785         pickedup |= Item_GiveAmmoTo(item, player, RES_ROCKETS, g_pickup_rockets_max);
 786         pickedup |= Item_GiveAmmoTo(item, player, RES_CELLS, g_pickup_cells_max);
 787         pickedup |= Item_GiveAmmoTo(item, player, RES_PLASMA, g_pickup_plasma_max);
 788         pickedup |= Item_GiveAmmoTo(item, player, RES_FUEL, g_pickup_fuel_max);
 789         if (item.itemdef.instanceOfWeaponPickup)
 790         {
 791                 WepSet w;
 792                 w = STAT(WEAPONS, item);
 793                 w &= ~STAT(WEAPONS, player);
 794
 795                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 796                 {
 797                         pickedup = true;
 798                         FOREACH(Weapons, it != WEP_Null, {
 799                                 if(w & (it.m_wepset))
 800                                 {
 801                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 802                                         {
 803                                                 .entity weaponentity = weaponentities[slot];
 804                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 805                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 806                                         }
 807                                         W_GiveWeapon(player, it.m_id);
 808                                 }
 809                         });
 810                 }
 811         }
 812
 813         if (item.itemdef.instanceOfPowerup)
 814         {
 815                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 816                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 817                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 818                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 819         }
 820
 821         int its;
 822         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 823         {
 824                 pickedup = true;
 825                 player.items |= its;
 826                 // TODO: we probably want to show a message in the console, but not this one!
 827                 //Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 828         }
 829
 830         if (item.strength_finished)
 831         {
 832                 pickedup = true;
 833                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 834         }
 835         if (item.invincible_finished)
 836         {
 837                 pickedup = true;
 838                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 839         }
 840         if (item.superweapons_finished)
 841         {
 842                 pickedup = true;
 843                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 844         }
 845
 846         // always eat teamed entities
 847         if(item.team)
 848                 pickedup = true;
 849
 850         if (!pickedup)
 851                 return false;
 852
 853         // crude hack to enforce switching weapons
 854         if(g_cts && item.itemdef.instanceOfWeaponPickup && !CS(player).cvar_cl_cts_noautoswitch)
 855         {
 856                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 857                 {
 858                         .entity weaponentity = weaponentities[slot];
 859                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 860                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 861                 }
 862                 return true;
 863         }
 864
 865         if(_switchweapon)
 866         {
 867                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 868                 {
 869                         .entity weaponentity = weaponentities[slot];
 870                         if(_switchweapon & BIT(slot))
 871                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 872                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 873                 }
 874         }
 875
 876         return true;
 877 }
 878
 879 void Item_Touch(entity this, entity toucher)
 880 {
 881         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 882         if (Item_IsLoot(this))
 883         {
 884                 if (ITEM_TOUCH_NEEDKILL())
 885                 {
 886                         delete(this);
 887                         return;
 888                 }
 889         }
 890
 891         if(!(toucher.flags & FL_PICKUPITEMS)
 892         || STAT(FROZEN, toucher)
 893         || IS_DEAD(toucher)
 894         || (this.solid != SOLID_TRIGGER)
 895         || (this.owner == toucher)
 896         || (time < this.item_spawnshieldtime)
 897         ) { return; }
 898
 899         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 900         {
 901                 case MUT_ITEMTOUCH_RETURN: { return; }
 902                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 903         }
 904
 905         toucher = M_ARGV(1, entity);
 906
 907         if (Item_IsExpiring(this))
 908         {
 909                 this.strength_finished = max(0, this.strength_finished - time);
 910                 this.invincible_finished = max(0, this.invincible_finished - time);
 911                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 912         }
 913         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 914         if (!gave)
 915         {
 916                 if (Item_IsExpiring(this))
 917                 {
 918                         // undo what we did above
 919                         this.strength_finished += time;
 920                         this.invincible_finished += time;
 921                         this.superweapons_finished += time;
 922                 }
 923                 return;
 924         }
 925
 926 LABEL(pickup)
 927
 928         if(this.target && this.target != "" && this.target != "###item###") // defrag support
 929                 SUB_UseTargets(this, toucher, NULL);
 930
 931         STAT(LAST_PICKUP, toucher) = time;
 932
 933         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 934         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 935
 936         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 937         if (wasfreed(this))
 938         {
 939                 return;
 940         }
 941
 942         if (Item_IsLoot(this))
 943         {
 944                 delete(this);
 945                 return;
 946         }
 947         if (!this.spawnshieldtime)
 948         {
 949                 return;
 950         }
 951         entity e;
 952         if (this.team)
 953         {
 954                 RandomSelection_Init();
 955                 IL_EACH(g_items, it.team == this.team,
 956                 {
 957                         if (it.itemdef) // is a registered item
 958                         {
 959                                 Item_Show(it, -1);
 960                                 it.scheduledrespawntime = 0;
 961                                 RandomSelection_AddEnt(it, it.cnt, 0);
 962                         }
 963                 });
 964                 e = RandomSelection_chosen_ent;
 965                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 966         }
 967         else
 968                 e = this;
 969         Item_ScheduleRespawn(e);
 970 }
 971
 972 void Item_Reset(entity this)
 973 {
 974         Item_Show(this, !this.state);
 975         setorigin(this, this.origin);
 976
 977         if (Item_IsLoot(this))
 978         {
 979                 return;
 980         }
 981         setthink(this, Item_Think);
 982         this.nextthink = time;
 983         if (this.waypointsprite_attached)
 984         {
 985                 WaypointSprite_Kill(this.waypointsprite_attached);
 986         }
 987         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 988         {
 989                 Item_ScheduleInitialRespawn(this);
 990         }
 991 }
 992
 993 void Item_FindTeam(entity this)
 994 {
 995         entity e;
 996
 997         if(this.effects & EF_NODRAW)
 998         {
 999                 // marker for item team search
1000                 LOG_TRACE("Initializing item team ", ftos(this.team));
1001                 RandomSelection_Init();
1002                 IL_EACH(g_items, it.team == this.team,
1003                 {
1004                         if(it.itemdef) // is a registered item
1005                                 RandomSelection_AddEnt(it, it.cnt, 0);
1006                 });
1007
1008                 e = RandomSelection_chosen_ent;
1009                 if (!e)
1010                         return;
1011
1012                 IL_EACH(g_items, it.team == this.team,
1013                 {
1014                         if(it.itemdef) // is a registered item
1015                         {
1016                                 if(it != e)
1017                                 {
1018                                         // make it non-spawned
1019                                         Item_Show(it, -1);
1020                                         it.state = 1; // state 1 = initially hidden item, apparently
1021                                 }
1022                                 else
1023                                         Item_Reset(it);
1024                                 it.effects &= ~EF_NODRAW;
1025                         }
1026                 });
1027         }
1028 }
1029
1030 // Savage: used for item garbage-collection
1031 void RemoveItem(entity this)
1032 {
1033         if(wasfreed(this) || !this) { return; }
1034         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1035         delete(this);
1036 }
1037
1038 // pickup evaluation functions
1039 // these functions decide how desirable an item is to the bots
1040
1041 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1042
1043 float weapon_pickupevalfunc(entity player, entity item)
1044 {
1045         // See if I have it already
1046         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
1047         {
1048                 // If I can pick it up
1049                 if(!item.spawnshieldtime)
1050                         return 0;
1051                 return ammo_pickupevalfunc(player, item);
1052         }
1053
1054         // reduce weapon value if bot already got a good arsenal
1055         float c = 1;
1056         int weapons_value = 0;
1057         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
1058                 weapons_value += it.bot_pickupbasevalue;
1059         });
1060         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1061
1062         return item.bot_pickupbasevalue * c;
1063 }
1064
1065 float ammo_pickupevalfunc(entity player, entity item)
1066 {
1067         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1068         entity wpn = NULL;
1069         float c = 0;
1070         float rating = 0;
1071
1072         // Detect needed ammo
1073         if(item.itemdef.instanceOfWeaponPickup)
1074         {
1075                 entity ammo = NULL;
1076                 if(GetResource(item, RES_SHELLS))       { need_shells  = true; ammo = ITEM_Shells;      }
1077                 else if(GetResource(item, RES_BULLETS))   { need_nails   = true; ammo = ITEM_Bullets;     }
1078                 else if(GetResource(item, RES_ROCKETS)) { need_rockets = true; ammo = ITEM_Rockets;     }
1079                 else if(GetResource(item, RES_CELLS))   { need_cells   = true; ammo = ITEM_Cells;       }
1080                 else if(GetResource(item, RES_PLASMA))  { need_plasma  = true; ammo = ITEM_Plasma;      }
1081                 else if(GetResource(item, RES_FUEL))    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1082
1083                 if(!ammo)
1084                         return 0;
1085                 wpn = item;
1086                 rating = ammo.m_botvalue;
1087         }
1088         else
1089         {
1090                 FOREACH(Weapons, it != WEP_Null, {
1091                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
1092                                 continue;
1093
1094                         switch(it.ammo_type)
1095                         {
1096                                 case RES_SHELLS:  need_shells  = true; break;
1097                                 case RES_BULLETS: need_nails   = true; break;
1098                                 case RES_ROCKETS: need_rockets = true; break;
1099                                 case RES_CELLS:   need_cells   = true; break;
1100                                 case RES_PLASMA:  need_plasma  = true; break;
1101                                 case RES_FUEL:    need_fuel    = true; break;
1102                         }
1103                 });
1104                 rating = item.bot_pickupbasevalue;
1105         }
1106
1107         float noammorating = 0.5;
1108
1109         if ((need_shells) && GetResource(item, RES_SHELLS) && (GetResource(player, RES_SHELLS) < g_pickup_shells_max))
1110                 c = GetResource(item, RES_SHELLS) / max(noammorating, GetResource(player, RES_SHELLS));
1111
1112         if ((need_nails) && GetResource(item, RES_BULLETS) && (GetResource(player, RES_BULLETS) < g_pickup_nails_max))
1113                 c = GetResource(item, RES_BULLETS) / max(noammorating, GetResource(player, RES_BULLETS));
1114
1115         if ((need_rockets) && GetResource(item, RES_ROCKETS) && (GetResource(player, RES_ROCKETS) < g_pickup_rockets_max))
1116                 c = GetResource(item, RES_ROCKETS) / max(noammorating, GetResource(player, RES_ROCKETS));
1117
1118         if ((need_cells) && GetResource(item, RES_CELLS) && (GetResource(player, RES_CELLS) < g_pickup_cells_max))
1119                 c = GetResource(item, RES_CELLS) / max(noammorating, GetResource(player, RES_CELLS));
1120
1121         if ((need_plasma) && GetResource(item, RES_PLASMA) && (GetResource(player, RES_PLASMA) < g_pickup_plasma_max))
1122                 c = GetResource(item, RES_PLASMA) / max(noammorating, GetResource(player, RES_PLASMA));
1123
1124         if ((need_fuel) && GetResource(item, RES_FUEL) && (GetResource(player, RES_FUEL) < g_pickup_fuel_max))
1125                 c = GetResource(item, RES_FUEL) / max(noammorating, GetResource(player, RES_FUEL));
1126
1127         rating *= min(c, 2);
1128         if(wpn)
1129                 rating += wpn.bot_pickupbasevalue * 0.1;
1130         return rating;
1131 }
1132
1133 float healtharmor_pickupevalfunc(entity player, entity item)
1134 {
1135         float c = 0;
1136         float rating = item.bot_pickupbasevalue;
1137
1138         float itemarmor = GetResource(item, RES_ARMOR);
1139         float itemhealth = GetResource(item, RES_HEALTH);
1140
1141         if(item.item_group)
1142         {
1143                 itemarmor *= min(4, item.item_group_count);
1144                 itemhealth *= min(4, item.item_group_count);
1145         }
1146
1147         if (itemarmor && (GetResource(player, RES_ARMOR) < item.max_armorvalue))
1148                 c = itemarmor / max(1, GetResource(player, RES_ARMOR) * 2/3 + GetResource(player, RES_HEALTH) * 1/3);
1149
1150         if (itemhealth && (GetResource(player, RES_HEALTH) < item.max_health))
1151                 c = itemhealth / max(1, GetResource(player, RES_HEALTH));
1152
1153         rating *= min(2, c);
1154         return rating;
1155 }
1156
1157 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1158 {
1159         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1160                 RemoveItem(this);
1161 }
1162
1163 void item_use(entity this, entity actor, entity trigger)
1164 {
1165         // use the touch function to handle collection
1166         gettouch(this)(this, actor);
1167 }
1168
1169 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1170 {
1171         string itemname = def.m_name;
1172         Model itemmodel = def.m_model;
1173         Sound pickupsound = def.m_sound;
1174         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1175         float pickupbasevalue = def.m_botvalue;
1176         int itemflags = def.m_itemflags;
1177
1178         startitem_failed = false;
1179
1180         this.item_model_ent = itemmodel;
1181         this.item_pickupsound_ent = pickupsound;
1182
1183         if(def.m_iteminit)
1184                 def.m_iteminit(def, this);
1185
1186         if(!this.respawntime) // both need to be set
1187         {
1188                 this.respawntime = defaultrespawntime;
1189                 this.respawntimejitter = defaultrespawntimejitter;
1190         }
1191
1192         if(!this.pickup_anyway && def.m_pickupanyway)
1193                 this.pickup_anyway = def.m_pickupanyway();
1194
1195         int itemid = def.m_itemid;
1196         this.items = itemid;
1197         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1198         this.weapon = weaponid;
1199
1200         if(!this.fade_end)
1201         {
1202                 this.fade_start = autocvar_g_items_mindist;
1203                 this.fade_end = autocvar_g_items_maxdist;
1204         }
1205
1206         if(weaponid)
1207                 STAT(WEAPONS, this) = WepSet_FromWeapon(Weapons_from(weaponid));
1208
1209         this.flags = FL_ITEM | itemflags;
1210         IL_PUSH(g_items, this);
1211
1212         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1213         {
1214                 startitem_failed = true;
1215                 delete(this);
1216                 return;
1217         }
1218
1219         precache_model(this.model);
1220         precache_sound(this.item_pickupsound);
1221
1222         if (Item_IsLoot(this))
1223         {
1224                 this.reset = SUB_Remove;
1225                 set_movetype(this, MOVETYPE_TOSS);
1226
1227                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1228                 setthink(this, RemoveItem);
1229                 this.nextthink = time + 20;
1230
1231                 this.takedamage = DAMAGE_YES;
1232                 this.event_damage = Item_Damage;
1233
1234                 if (Item_IsExpiring(this))
1235                 {
1236                         // if item is worthless after a timer, have it expire then
1237                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1238                 }
1239
1240                 // don't drop if in a NODROP zone (such as lava)
1241                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1242                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1243                 {
1244                         startitem_failed = true;
1245                         delete(this);
1246                         return;
1247                 }
1248         }
1249         else
1250         {
1251                 if(!have_pickup_item(this))
1252                 {
1253                         startitem_failed = true;
1254                         delete(this);
1255                         return;
1256                 }
1257
1258                 if(this.angles != '0 0 0')
1259                         this.SendFlags |= ISF_ANGLES;
1260
1261                 this.reset = Item_Reset;
1262                 // it's a level item
1263                 if(this.spawnflags & 1)
1264                         this.noalign = 1;
1265                 if (this.noalign > 0)
1266                         set_movetype(this, MOVETYPE_NONE);
1267                 else
1268                         set_movetype(this, MOVETYPE_TOSS);
1269                 // do item filtering according to game mode and other things
1270                 if (this.noalign <= 0)
1271                 {
1272                         // first nudge it off the floor a little bit to avoid math errors
1273                         setorigin(this, this.origin + '0 0 1');
1274                         // set item size before we spawn a spawnfunc_waypoint
1275                         setsize(this, def.m_mins, def.m_maxs);
1276                         this.SendFlags |= ISF_SIZE;
1277                         // note droptofloor returns false if stuck/or would fall too far
1278                         if (!this.noalign)
1279                                 droptofloor(this);
1280                         waypoint_spawnforitem(this);
1281                 }
1282
1283                 /*
1284                  * can't do it that way, as it would break maps
1285                  * TODO make a target_give like entity another way, that perhaps has
1286                  * the weapon name in a key
1287                 if(this.targetname)
1288                 {
1289                         // target_give not yet supported; maybe later
1290                         print("removed targeted ", this.classname, "\n");
1291                         startitem_failed = true;
1292                         delete(this);
1293                         return;
1294                 }
1295                 */
1296
1297                 if(this.targetname != "" && (this.spawnflags & 16))
1298                         this.use = item_use;
1299
1300                 if(autocvar_spawn_debug >= 2)
1301                 {
1302             // why not flags & fl_item?
1303                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1304                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1305                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1306                 error("Mapper sucks.");
1307             });
1308                         this.is_item = true;
1309                 }
1310
1311                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1312
1313                 if (   def.instanceOfPowerup
1314                         || def.instanceOfWeaponPickup
1315                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1316                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1317                         || (itemid & (IT_KEY1 | IT_KEY2))
1318                 )
1319                 {
1320                         if(!this.target || this.target == "")
1321                                 this.target = "###item###"; // for finding the nearest item using findnearest
1322                 }
1323
1324                 Item_ItemsTime_SetTime(this, 0);
1325         }
1326
1327         this.bot_pickup = true;
1328         this.bot_pickupevalfunc = pickupevalfunc;
1329         this.bot_pickupbasevalue = pickupbasevalue;
1330         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1331         this.netname = itemname;
1332         settouch(this, Item_Touch);
1333         setmodel(this, MDL_Null); // precision set below
1334         //this.effects |= EF_LOWPRECISION;
1335
1336         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1337
1338         this.SendFlags |= ISF_SIZE;
1339
1340         if (!(this.spawnflags & 1024)) {
1341                 if(def.instanceOfPowerup)
1342                         this.ItemStatus |= ITS_ANIMATE1;
1343
1344                 if(GetResource(this, RES_ARMOR) || GetResource(this, RES_HEALTH))
1345                         this.ItemStatus |= ITS_ANIMATE2;
1346         }
1347
1348         if(Item_IsLoot(this))
1349                 this.gravity = 1;
1350
1351         if(def.instanceOfWeaponPickup)
1352         {
1353                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1354                         this.colormap = 1024; // color shirt=0 pants=0 grey
1355                 if (!(this.spawnflags & 1024))
1356                         this.ItemStatus |= ITS_ANIMATE1;
1357                 this.SendFlags |= ISF_COLORMAP;
1358         }
1359
1360         this.state = 0;
1361         if(this.team)
1362         {
1363                 if(!this.cnt)
1364                         this.cnt = 1; // item probability weight
1365
1366                 this.effects |= EF_NODRAW; // marker for item team search
1367                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1368         }
1369         else
1370                 Item_Reset(this);
1371
1372         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1373
1374         // call this hook after everything else has been done
1375         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1376         {
1377                 startitem_failed = true;
1378                 delete(this);
1379                 return;
1380         }
1381
1382         setItemGroup(this);
1383 }
1384
1385 void StartItem(entity this, GameItem def)
1386 {
1387     def = def.m_spawnfunc_hookreplace(def, this);
1388     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1389     {
1390         delete(this);
1391         return;
1392     }
1393     this.classname = def.m_canonical_spawnfunc;
1394     _StartItem(
1395         this,
1396         this.itemdef = def,
1397         def.m_respawntime(), // defaultrespawntime
1398         def.m_respawntimejitter() // defaultrespawntimejitter
1399         );
1400 }
1401
1402 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1403 int group_count = 1;
1404
1405 void setItemGroup(entity this)
1406 {
1407         if(!IS_SMALL(this.itemdef) || Item_IsLoot(this))
1408                 return;
1409
1410         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1411         {
1412                 if(!this.item_group)
1413                 {
1414                         if(!it.item_group)
1415                         {
1416                                 it.item_group = group_count;
1417                                 group_count++;
1418                         }
1419                         this.item_group = it.item_group;
1420                 }
1421                 else // spawning item is already part of a item_group X
1422                 {
1423                         if(!it.item_group)
1424                                 it.item_group = this.item_group;
1425                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1426                         {
1427                                 int grY = it.item_group;
1428                                 // move all items of item_group Y to item_group X
1429                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1430                                 {
1431                                         if(it.item_group == grY)
1432                                                 it.item_group = this.item_group;
1433                                 });
1434                         }
1435                 }
1436         });
1437 }
1438
1439 void setItemGroupCount()
1440 {
1441         for (int k = 1; k <= group_count; k++)
1442         {
1443                 int count = 0;
1444                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1445                 if (count)
1446                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1447         }
1448 }
1449
1450 void target_items_use(entity this, entity actor, entity trigger)
1451 {
1452         if(Item_IsLoot(actor))
1453         {
1454                 EXACTTRIGGER_TOUCH(this, trigger);
1455                 delete(actor);
1456                 return;
1457         }
1458
1459         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1460                 return;
1461
1462         if(trigger.solid == SOLID_TRIGGER)
1463         {
1464                 EXACTTRIGGER_TOUCH(this, trigger);
1465         }
1466
1467         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1468         {
1469                 delete(it);
1470         });
1471
1472         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1473                 centerprint(actor, this.message);
1474 }
1475
1476 spawnfunc(target_items)
1477 {
1478         this.use = target_items_use;
1479         if(!this.strength_finished)
1480                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1481         if(!this.invincible_finished)
1482                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1483         if(!this.superweapons_finished)
1484                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1485
1486         int n = tokenize_console(this.netname);
1487         if(argv(0) == "give")
1488         {
1489                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1490         }
1491         else
1492         {
1493                 for(int j = 0; j < n; ++j)
1494                 {
1495                         // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1496                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1497                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_AMMO;
1498                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1499                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1500                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1501                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1502                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1503                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1504                         else
1505                         {
1506                                 FOREACH(Buffs, it != BUFF_Null,
1507                                 {
1508                                         string s = Buff_UndeprecateName(argv(j));
1509                                         if(s == it.netname)
1510                                         {
1511                                                 STAT(BUFFS, this) |= (it.m_itemid);
1512                                                 if(!STAT(BUFF_TIME, this))
1513                                                         STAT(BUFF_TIME, this) = it.m_time(it);
1514                                                 break;
1515                                         }
1516                                 });
1517                                 FOREACH(Weapons, it != WEP_Null, {
1518                                         string s = W_UndeprecateName(argv(j));
1519                                         if(s == it.netname)
1520                                         {
1521                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1522                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1523                                                         it.wr_init(it);
1524                                                 break;
1525                                         }
1526                                 });
1527                         }
1528                 }
1529
1530                 string itemprefix, valueprefix;
1531                 if(this.spawnflags == 0)
1532                 {
1533                         itemprefix = "";
1534                         valueprefix = "";
1535                 }
1536                 else if(this.spawnflags == 1)
1537                 {
1538                         itemprefix = "max ";
1539                         valueprefix = "max ";
1540                 }
1541                 else if(this.spawnflags == 2)
1542                 {
1543                         itemprefix = "min ";
1544                         valueprefix = "min ";
1545                 }
1546                 else if(this.spawnflags == 4)
1547                 {
1548                         itemprefix = "minus ";
1549                         valueprefix = "max ";
1550                 }
1551                 else
1552                 {
1553                         error("invalid spawnflags");
1554                         itemprefix = valueprefix = string_null;
1555                 }
1556
1557                 this.netname = "";
1558                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_AMMO), "unlimited_weapon_ammo");
1559                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1560                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1561                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1562                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1563                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1564                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1565                 if(GetResource(this, RES_SHELLS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_SHELLS)), "shells");
1566                 if(GetResource(this, RES_BULLETS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_BULLETS)), "nails");
1567                 if(GetResource(this, RES_ROCKETS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_ROCKETS)), "rockets");
1568                 if(GetResource(this, RES_CELLS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_CELLS)), "cells");
1569                 if(GetResource(this, RES_PLASMA) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_PLASMA)), "plasma");
1570                 if(GetResource(this, RES_FUEL) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_FUEL)), "fuel");
1571                 if(GetResource(this, RES_HEALTH) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_HEALTH)), "health");
1572                 if(GetResource(this, RES_ARMOR) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_ARMOR)), "armor");
1573                 FOREACH(Buffs, it != BUFF_Null && (STAT(BUFFS, this) & it.m_itemid), this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, STAT(BUFF_TIME, this)), it.netname));
1574                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1575         }
1576         this.netname = strzone(this.netname);
1577         //print(this.netname, "\n");
1578
1579         n = tokenize_console(this.netname);
1580         for(int j = 0; j < n; ++j)
1581         {
1582                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1583                         it.wr_init(it);
1584                         break;
1585                 });
1586         }
1587 }
1588
1589 float GiveWeapon(entity e, float wpn, float op, float val)
1590 {
1591         WepSet v0, v1;
1592         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1593         v0 = (STAT(WEAPONS, e) & s);
1594         switch(op)
1595         {
1596                 case OP_SET:
1597                         if(val > 0)
1598                                 STAT(WEAPONS, e) |= s;
1599                         else
1600                                 STAT(WEAPONS, e) &= ~s;
1601                         break;
1602                 case OP_MIN:
1603                 case OP_PLUS:
1604                         if(val > 0)
1605                                 STAT(WEAPONS, e) |= s;
1606                         break;
1607                 case OP_MAX:
1608                         if(val <= 0)
1609                                 STAT(WEAPONS, e) &= ~s;
1610                         break;
1611                 case OP_MINUS:
1612                         if(val > 0)
1613                                 STAT(WEAPONS, e) &= ~s;
1614                         break;
1615         }
1616         v1 = (STAT(WEAPONS, e) & s);
1617         return (v0 != v1);
1618 }
1619
1620 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1621 {
1622         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1623         switch (op)
1624         {
1625                 case OP_SET:
1626                         STAT(BUFF_TIME, e) = val;
1627                         break;
1628                 case OP_MIN:
1629                         STAT(BUFF_TIME, e) = max(STAT(BUFF_TIME, e), val);
1630                         break;
1631                 case OP_MAX:
1632                         STAT(BUFF_TIME, e) = min(STAT(BUFF_TIME, e), val);
1633                         break;
1634                 case OP_PLUS:
1635                         STAT(BUFF_TIME, e) += val;
1636                         break;
1637                 case OP_MINUS:
1638                         STAT(BUFF_TIME, e) -= val;
1639                         break;
1640         }
1641         if(STAT(BUFF_TIME, e) <= 0)
1642                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1643         else
1644                 STAT(BUFFS, e) = thebuff.m_itemid; // NOTE: replaces any existing buffs on the player!
1645         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1646         return (had_buff != have_buff);
1647 }
1648
1649 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1650 {
1651         if(v1 == v0)
1652                 return;
1653         if(v1 <= v0 - t)
1654         {
1655                 if(snd_decr != NULL)
1656                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1657         }
1658         else if(v0 >= v0 + t)
1659         {
1660                 if(snd_incr != NULL)
1661                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1662         }
1663 }
1664
1665 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1666 {
1667         if(v0 < v1)
1668                 e.(rotfield) = max(e.(rotfield), time + rottime);
1669         else if(v0 > v1)
1670                 e.(regenfield) = max(e.(regenfield), time + regentime);
1671 }
1672 bool GiveResourceValue(entity e, int res_type, int op, int val)
1673 {
1674         int v0 = GetResource(e, res_type);
1675         switch (op)
1676         {
1677                 // min 100 cells = at least 100 cells
1678                 case OP_SET: SetResource(e, res_type, val); break;
1679                 case OP_MIN: SetResource(e, res_type, max(v0, val)); break;
1680                 case OP_MAX: SetResource(e, res_type, min(v0, val)); break;
1681                 case OP_PLUS: SetResource(e, res_type, v0 + val); break;
1682                 case OP_MINUS: SetResource(e, res_type, v0 - val); break;
1683         }
1684         int v1 = GetResource(e, res_type);
1685         return v0 != v1;
1686 }
1687
1688 float GiveItems(entity e, float beginarg, float endarg)
1689 {
1690         float got, i, val, op;
1691         string cmd;
1692
1693         val = 999;
1694         op = OP_SET;
1695
1696         got = 0;
1697
1698         int _switchweapon = 0;
1699
1700         if(CS(e).autoswitch)
1701         {
1702                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1703                 {
1704                         .entity weaponentity = weaponentities[slot];
1705                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1706                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1707                                 _switchweapon |= BIT(slot);
1708                 }
1709         }
1710
1711         e.strength_finished = max(0, e.strength_finished - time);
1712         e.invincible_finished = max(0, e.invincible_finished - time);
1713         e.superweapons_finished = max(0, e.superweapons_finished - time);
1714         STAT(BUFF_TIME, e) = max(0, STAT(BUFF_TIME, e) - time);
1715
1716         PREGIVE(e, items);
1717         PREGIVE_WEAPONS(e);
1718         PREGIVE(e, strength_finished);
1719         PREGIVE(e, invincible_finished);
1720         PREGIVE(e, superweapons_finished);
1721         PREGIVE_RESOURCE(e, RES_BULLETS);
1722         PREGIVE_RESOURCE(e, RES_CELLS);
1723         PREGIVE_RESOURCE(e, RES_PLASMA);
1724         PREGIVE_RESOURCE(e, RES_SHELLS);
1725         PREGIVE_RESOURCE(e, RES_ROCKETS);
1726         PREGIVE_RESOURCE(e, RES_FUEL);
1727         PREGIVE_RESOURCE(e, RES_ARMOR);
1728         PREGIVE_RESOURCE(e, RES_HEALTH);
1729
1730         for(i = beginarg; i < endarg; ++i)
1731         {
1732                 cmd = argv(i);
1733
1734                 if(cmd == "0" || stof(cmd))
1735                 {
1736                         val = stof(cmd);
1737                         continue;
1738                 }
1739                 switch(cmd)
1740                 {
1741                         case "no":
1742                                 op = OP_MAX;
1743                                 val = 0;
1744                                 continue;
1745                         case "max":
1746                                 op = OP_MAX;
1747                                 continue;
1748                         case "min":
1749                                 op = OP_MIN;
1750                                 continue;
1751                         case "plus":
1752                                 op = OP_PLUS;
1753                                 continue;
1754                         case "minus":
1755                                 op = OP_MINUS;
1756                                 continue;
1757                         case "ALL":
1758                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1759                                 got += GiveValue(e, strength_finished, op, val);
1760                                 got += GiveValue(e, invincible_finished, op, val);
1761                                 got += GiveValue(e, superweapons_finished, op, val);
1762                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1763                         case "all":
1764                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1765                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1766                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1767                         case "allweapons":
1768                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)), got += GiveWeapon(e, it.m_id, op, val));
1769                         //case "allbuffs": // all buffs makes a player god, do not want!
1770                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1771                         case "allammo":
1772                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1773                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1774                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1775                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1776                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1777                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1778                                 break;
1779                         case "unlimited_ammo":
1780                                 // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1781                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1782                                 break;
1783                         case "unlimited_weapon_ammo":
1784                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1785                                 break;
1786                         case "unlimited_superweapons":
1787                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1788                                 break;
1789                         case "jetpack":
1790                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1791                                 break;
1792                         case "fuel_regen":
1793                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1794                                 break;
1795                         case "strength":
1796                                 got += GiveValue(e, strength_finished, op, val);
1797                                 break;
1798                         case "invincible":
1799                                 got += GiveValue(e, invincible_finished, op, val);
1800                                 break;
1801                         case "superweapons":
1802                                 got += GiveValue(e, superweapons_finished, op, val);
1803                                 break;
1804                         case "cells":
1805                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1806                                 break;
1807                         case "plasma":
1808                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1809                                 break;
1810                         case "shells":
1811                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1812                                 break;
1813                         case "nails":
1814                         case "bullets":
1815                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1816                                 break;
1817                         case "rockets":
1818                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1819                                 break;
1820                         case "health":
1821                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1822                                 break;
1823                         case "armor":
1824                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1825                                 break;
1826                         case "fuel":
1827                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1828                                 break;
1829                         default:
1830                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.netname,
1831                                 {
1832                                         got += GiveBuff(e, it, op, val);
1833                                         break;
1834                                 });
1835                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1836                     got += GiveWeapon(e, it.m_id, op, val);
1837                     break;
1838                                 });
1839                                 break;
1840                 }
1841                 val = 999;
1842                 op = OP_SET;
1843         }
1844
1845         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1846         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1847         POSTGIVE_BIT(e, items, IT_UNLIMITED_AMMO, SND_POWERUP, SND_POWEROFF);
1848         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1849         FOREACH(Weapons, it != WEP_Null, {
1850                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1851                 if(!(save_weapons & (it.m_wepset)))
1852                         if(STAT(WEAPONS, e) & (it.m_wepset))
1853                                 it.wr_init(it);
1854         });
1855         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1856         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1857         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1858         POSTGIVE_RESOURCE(e, RES_BULLETS, 0, SND_ITEMPICKUP, SND_Null);
1859         POSTGIVE_RESOURCE(e, RES_CELLS, 0, SND_ITEMPICKUP, SND_Null);
1860         POSTGIVE_RESOURCE(e, RES_PLASMA, 0, SND_ITEMPICKUP, SND_Null);
1861         POSTGIVE_RESOURCE(e, RES_SHELLS, 0, SND_ITEMPICKUP, SND_Null);
1862         POSTGIVE_RESOURCE(e, RES_ROCKETS, 0, SND_ITEMPICKUP, SND_Null);
1863         POSTGIVE_RES_ROT(e, RES_FUEL, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1864         POSTGIVE_RES_ROT(e, RES_ARMOR, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1865         POSTGIVE_RES_ROT(e, RES_HEALTH, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1866
1867         if(e.superweapons_finished <= 0)
1868                 if(!g_weaponarena && (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
1869                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1870
1871         if(e.strength_finished <= 0)
1872                 e.strength_finished = 0;
1873         else
1874                 e.strength_finished += time;
1875         if(e.invincible_finished <= 0)
1876                 e.invincible_finished = 0;
1877         else
1878                 e.invincible_finished += time;
1879         if(e.superweapons_finished <= 0)
1880                 e.superweapons_finished = 0;
1881         else
1882                 e.superweapons_finished += time;
1883         if(STAT(BUFF_TIME, e) <= 0)
1884                 STAT(BUFF_TIME, e) = 0;
1885         else
1886                 STAT(BUFF_TIME, e) += time;
1887
1888         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1889         {
1890                 .entity weaponentity = weaponentities[slot];
1891                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1892                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1893                         _switchweapon |= BIT(slot);
1894         }
1895
1896         if(_switchweapon)
1897         {
1898                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1899                 {
1900                         .entity weaponentity = weaponentities[slot];
1901                         if(_switchweapon & BIT(slot))
1902                         {
1903                                 Weapon wep = w_getbestweapon(e, weaponentity);
1904                                 if(wep != e.(weaponentity).m_switchweapon)
1905                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1906                         }
1907                 }
1908         }
1909
1910         return got;
1911 }
1912 #endif