qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 if (autocvar_cl_ghost_items_color)
  54                 {
  55                         this.alpha = autocvar_cl_ghost_items;
  56                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  57                 }
  58                 else
  59                         this.alpha = -1;
  60         }
  61
  62         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  63         {
  64                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  65                 this.alpha = autocvar_cl_weapon_stay_alpha;
  66         }
  67
  68         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  69 }
  70
  71 void ItemDraw(entity this)
  72 {
  73     if(this.gravity)
  74     {
  75         Movetype_Physics_MatchServer(this, false);
  76         if(IS_ONGROUND(this))
  77         { // For some reason avelocity gets set to '0 0 0' here ...
  78             this.oldorigin = this.origin;
  79             this.gravity = 0;
  80
  81             if(autocvar_cl_animate_items)
  82             { // ... so reset it if animations are requested.
  83                 if(this.ItemStatus & ITS_ANIMATE1)
  84                     this.avelocity = '0 180 0';
  85
  86                 if(this.ItemStatus & ITS_ANIMATE2)
  87                     this.avelocity = '0 -90 0';
  88             }
  89
  90             // delay is for blocking item's position for a while;
  91             // it's a workaround for dropped weapons that receive the position
  92             // another time right after they spawn overriding animation position
  93             this.onground_time = time + 0.5;
  94         }
  95     }
  96     else if (autocvar_cl_animate_items)
  97     {
  98         if(this.ItemStatus & ITS_ANIMATE1)
  99         {
 100                 if(!this.item_simple)
 101                 this.angles += this.avelocity * frametime;
 102             float fade_in = bound(0, time - this.onground_time, 1);
 103             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 104         }
 105
 106         if(this.ItemStatus & ITS_ANIMATE2)
 107         {
 108                 if(!this.item_simple)
 109                 this.angles += this.avelocity * frametime;
 110             float fade_in = bound(0, time - this.onground_time, 1);
 111             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 112         }
 113     }
 114
 115     Item_SetAlpha(this);
 116 }
 117
 118 void Item_PreDraw(entity this)
 119 {
 120         if(warpzone_warpzones_exist)
 121         {
 122                 setpredraw(this, func_null); // no need to keep running this
 123                 return;
 124         }
 125         float alph;
 126         vector org = getpropertyvec(VF_ORIGIN);
 127         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 128                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 129         if(this.fade_start)
 130         {
 131                 if(vdist(org - this.origin, >, this.fade_end))
 132                         alph = 0; // save on some processing
 133                 else if(vdist(org - this.origin, <, this.fade_start))
 134                         alph = 1; // more processing saved
 135                 else
 136                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 137         }
 138         else
 139                 alph = 1;
 140         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 141         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 142                 this.alpha = alph;
 143         if(alph <= 0)
 144                 this.drawmask = 0;
 145         //else
 146                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 147 }
 148
 149 void ItemRemove(entity this)
 150 {
 151         strfree(this.mdl);
 152 }
 153
 154 HashMap ENT_CLIENT_ITEM_simple;
 155 STATIC_INIT(ENT_CLIENT_ITEM_simple)
 156 {
 157         HM_NEW(ENT_CLIENT_ITEM_simple);
 158 }
 159 SHUTDOWN(ENT_CLIENT_ITEM_simple)
 160 {
 161         HM_DELETE(ENT_CLIENT_ITEM_simple);
 162 }
 163
 164 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 165 {
 166     int sf = ReadByte();
 167
 168     if(sf & ISF_LOCATION)
 169     {
 170         this.origin = ReadVector();
 171         setorigin(this, this.origin);
 172         this.oldorigin = this.origin;
 173     }
 174
 175     if(sf & ISF_ANGLES)
 176     {
 177         this.angles_x = ReadAngle();
 178         this.angles_y = ReadAngle();
 179         this.angles_z = ReadAngle();
 180     }
 181
 182     if(sf & ISF_SIZE)
 183     {
 184         float use_bigsize = ReadByte();
 185         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 186     }
 187
 188     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 189     {
 190         this.ItemStatus = ReadByte();
 191
 192         Item_SetAlpha(this);
 193
 194         if(autocvar_cl_fullbright_items)
 195             if(this.ItemStatus & ITS_ALLOWFB)
 196                 this.effects |= EF_FULLBRIGHT;
 197
 198         if(this.ItemStatus & ITS_GLOW)
 199         {
 200             if(this.ItemStatus & ITS_AVAILABLE)
 201                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 202             else
 203                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 204         }
 205     }
 206
 207     if(sf & ISF_MODEL)
 208     {
 209         this.drawmask  = MASK_NORMAL;
 210                 set_movetype(this, MOVETYPE_TOSS);
 211                 if (isnew) IL_PUSH(g_drawables, this);
 212         this.draw       = ItemDraw;
 213         this.solid = SOLID_TRIGGER;
 214         //this.flags |= FL_ITEM;
 215
 216         bool use_bigsize = ReadByte();
 217
 218         this.fade_end = ReadShort();
 219         this.fade_start = ReadShort();
 220         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 221                 setpredraw(this, Item_PreDraw);
 222
 223                 strfree(this.mdl);
 224
 225         string _fn = ReadString();
 226         this.item_simple = false; // reset it!
 227
 228         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 229         {
 230             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 231             this.item_simple = true;
 232
 233                         #define extensions(x) \
 234                                 x(md3) \
 235                                 x(dpm) \
 236                                 x(iqm) \
 237                                 x(mdl) \
 238                                 /**/
 239                         #define tryext(ext) { \
 240                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
 241                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
 242                                 if (cached == "") { \
 243                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
 244                                 } \
 245                                 if (cached != "0") { \
 246                                         strcpy(this.mdl, s); \
 247                                         break; \
 248                                 } \
 249                         }
 250                         do {
 251                                 extensions(tryext);
 252                                 this.item_simple = false;
 253                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
 254                         } while (0);
 255                         #undef tryext
 256                         #undef extensions
 257         }
 258
 259         if(!this.item_simple)
 260             strcpy(this.mdl, _fn);
 261
 262         if(this.mdl == "")
 263             LOG_WARNF("this.mdl is unset for item %s", this.classname);
 264
 265         precache_model(this.mdl);
 266         _setmodel(this, this.mdl);
 267
 268         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 269     }
 270
 271     if(sf & ISF_COLORMAP)
 272     {
 273         this.colormap = ReadShort();
 274         this.item_glowmod_x = ReadByte() / 255.0;
 275         this.item_glowmod_y = ReadByte() / 255.0;
 276         this.item_glowmod_z = ReadByte() / 255.0;
 277     }
 278
 279     if(sf & ISF_DROP)
 280     {
 281         this.gravity = 1;
 282         this.pushable = true;
 283         //this.angles = '0 0 0';
 284         set_movetype(this, MOVETYPE_TOSS);
 285         this.velocity = ReadVector();
 286         setorigin(this, this.oldorigin);
 287
 288         if(!this.move_time)
 289         {
 290             this.move_time = time;
 291             this.spawntime = time;
 292         }
 293         else
 294             this.move_time = max(this.move_time, time);
 295     }
 296
 297     if(autocvar_cl_animate_items)
 298     {
 299         if(this.ItemStatus & ITS_ANIMATE1)
 300             this.avelocity = '0 180 0';
 301
 302         if(this.ItemStatus & ITS_ANIMATE2)
 303             this.avelocity = '0 -90 0';
 304     }
 305
 306     this.entremove = ItemRemove;
 307
 308     return true;
 309 }
 310
 311 #endif
 312
 313 #ifdef SVQC
 314 bool ItemSend(entity this, entity to, int sf)
 315 {
 316         if(this.gravity)
 317                 sf |= ISF_DROP;
 318         else
 319                 sf &= ~ISF_DROP;
 320
 321         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 322         WriteByte(MSG_ENTITY, sf);
 323
 324         //WriteByte(MSG_ENTITY, this.cnt);
 325         if(sf & ISF_LOCATION)
 326         {
 327                 WriteVector(MSG_ENTITY, this.origin);
 328         }
 329
 330         if(sf & ISF_ANGLES)
 331         {
 332                 WriteAngle(MSG_ENTITY, this.angles_x);
 333                 WriteAngle(MSG_ENTITY, this.angles_y);
 334                 WriteAngle(MSG_ENTITY, this.angles_z);
 335         }
 336
 337         if(sf & ISF_SIZE)
 338         {
 339                 Pickup p = this.itemdef;
 340                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 341         }
 342
 343         if(sf & ISF_STATUS)
 344                 WriteByte(MSG_ENTITY, this.ItemStatus);
 345
 346         if(sf & ISF_MODEL)
 347         {
 348                 Pickup p = this.itemdef;
 349                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 350                 WriteShort(MSG_ENTITY, this.fade_end);
 351                 WriteShort(MSG_ENTITY, this.fade_start);
 352
 353                 if(this.mdl == "")
 354                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 355
 356                 WriteString(MSG_ENTITY, this.mdl);
 357         }
 358
 359
 360         if(sf & ISF_COLORMAP)
 361         {
 362                 WriteShort(MSG_ENTITY, this.colormap);
 363                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 364         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 365         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 366         }
 367
 368         if(sf & ISF_DROP)
 369         {
 370                 WriteVector(MSG_ENTITY, this.velocity);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.item_respawncounter += 1;
 546                 if(this.item_respawncounter == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.item_respawncounter = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 635 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 636 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 637
 638 /// Adjust respawn time according to the number of players.
 639 float adjust_respawntime(float normal_respawntime) {
 640         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 641         float o = autocvar_g_pickup_respawntime_scaling_offset;
 642         float l = autocvar_g_pickup_respawntime_scaling_linear;
 643
 644         if (r == 0 && l == 1) {
 645                 return normal_respawntime;
 646         }
 647
 648         CheckAllowedTeams(NULL);
 649         GetTeamCounts(NULL);
 650         int players = 0;
 651         if (c1 != -1) players += c1;
 652         if (c2 != -1) players += c2;
 653         if (c3 != -1) players += c3;
 654         if (c4 != -1) players += c4;
 655
 656         if (players >= 2) {
 657                 return normal_respawntime * (r / (players + o) + l);
 658         } else {
 659                 return normal_respawntime;
 660         }
 661 }
 662
 663 void Item_ScheduleRespawn(entity e)
 664 {
 665         if(e.respawntime > 0)
 666         {
 667                 Item_Show(e, 0);
 668
 669                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 670                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 671
 672                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 673                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 674                 Item_ScheduleRespawnIn(e, respawn_in);
 675         }
 676         else // if respawntime is -1, this item does not respawn
 677                 Item_Show(e, -1);
 678 }
 679
 680 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 681         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 682
 683 void Item_ScheduleInitialRespawn(entity e)
 684 {
 685         Item_Show(e, 0);
 686
 687         float spawn_in;
 688         if (autocvar_g_pickup_respawntime_initial_random == 0)
 689         {
 690                 // range: respawntime .. respawntime + respawntimejitter
 691                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 692         }
 693         else
 694         {
 695                 float rnd;
 696                 if (autocvar_g_pickup_respawntime_initial_random == 1)
 697                 {
 698                         static float shared_random = 0;
 699                         // NOTE this code works only if items are scheduled at the same time (normal case)
 700                         // NOTE2 random() can't return exactly 1 so this check always work as intended
 701                         if (!shared_random || floor(time) > shared_random)
 702                                 shared_random = floor(time) + random();
 703                         rnd = shared_random - floor(time);
 704                 }
 705                 else
 706                         rnd = random();
 707
 708                 // range:
 709                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 710                 // else: 0 .. ITEM_RESPAWN_TICKS
 711                 // this is to prevent powerups spawning unexpectedly without waypoints
 712                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 713         }
 714
 715         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 716 }
 717
 718 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 719         entity ammo_entity)
 720 {
 721         if (num_weapons == 0)
 722         {
 723                 return;
 724         }
 725         int num_potential_weapons = tokenize_console(weapon_names);
 726         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 727         {
 728                 RandomSelection_Init();
 729                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 730                         ++weapon_index)
 731                 {
 732                         string weapon = argv(weapon_index);
 733                         FOREACH(Weapons, it != WEP_Null,
 734                         {
 735                                 // Finding a weapon which player doesn't have.
 736                                 if (!(receiver.weapons & it.m_wepset) && (it.netname == weapon))
 737                                 {
 738                                         RandomSelection_AddEnt(it, 1, 1);
 739                                         break;
 740                                 }
 741                         });
 742                 }
 743                 if (RandomSelection_chosen_ent == NULL)
 744                 {
 745                         return;
 746                 }
 747                 receiver.weapons |= RandomSelection_chosen_ent.m_wepset;
 748                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
 749                 {
 750                         continue;
 751                 }
 752                 if (GetResourceAmount(receiver,
 753                         RandomSelection_chosen_ent.ammo_type) != 0)
 754                 {
 755                         continue;
 756                 }
 757                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 758                         GetResourceAmount(ammo_entity,
 759                         RandomSelection_chosen_ent.ammo_type));
 760         }
 761 }
 762
 763 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
 764 {
 765         float amount = GetResourceAmount(item, resource_type);
 766         if (amount == 0)
 767         {
 768                 return false;
 769         }
 770         float player_amount = GetResourceAmount(player, resource_type);
 771         if (item.spawnshieldtime)
 772         {
 773                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 774                 {
 775                         return false;
 776                 }
 777                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
 778                 return true;
 779         }
 780         if (g_weapon_stay != 2)
 781         {
 782                 return false;
 783         }
 784         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
 785         return true;
 786 }
 787
 788 float Item_GiveTo(entity item, entity player)
 789 {
 790         float pickedup;
 791
 792         // if nothing happens to player, just return without taking the item
 793         pickedup = false;
 794         int _switchweapon = 0;
 795         // in case the player has autoswitch enabled do the following:
 796         // if the player is using their best weapon before items are given, they
 797         // probably want to switch to an even better weapon after items are given
 798
 799         if(CS(player).autoswitch)
 800         {
 801                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 802                 {
 803                         .entity weaponentity = weaponentities[slot];
 804                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 805                         {
 806                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 807                                         _switchweapon |= BIT(slot);
 808
 809                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 810                                         _switchweapon |= BIT(slot);
 811                         }
 812                 }
 813         }
 814         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
 815         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
 816         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
 817         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
 818         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
 819         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
 820         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
 821         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
 822         if (item.itemdef.instanceOfWeaponPickup)
 823         {
 824                 WepSet w;
 825                 w = item.weapons;
 826                 w &= ~player.weapons;
 827
 828                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 829                 {
 830                         pickedup = true;
 831                         FOREACH(Weapons, it != WEP_Null, {
 832                                 if(w & (it.m_wepset))
 833                                 {
 834                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 835                                         {
 836                                                 .entity weaponentity = weaponentities[slot];
 837                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 838                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 839                                         }
 840                                         W_GiveWeapon(player, it.m_id);
 841                                 }
 842                         });
 843                 }
 844         }
 845
 846         if (item.itemdef.instanceOfPowerup)
 847         {
 848                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 849                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 850                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 851                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 852         }
 853
 854         int its;
 855         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 856         {
 857                 pickedup = true;
 858                 player.items |= its;
 859                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 860         }
 861
 862         if (item.strength_finished)
 863         {
 864                 pickedup = true;
 865                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 866         }
 867         if (item.invincible_finished)
 868         {
 869                 pickedup = true;
 870                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 871         }
 872         if (item.superweapons_finished)
 873         {
 874                 pickedup = true;
 875                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 876         }
 877
 878         // always eat teamed entities
 879         if(item.team)
 880                 pickedup = true;
 881
 882         if (!pickedup)
 883                 return 0;
 884
 885         // crude hack to enforce switching weapons
 886         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 887         {
 888                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 889                 {
 890                         .entity weaponentity = weaponentities[slot];
 891                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 892                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 893                 }
 894                 return 1;
 895         }
 896
 897         if(_switchweapon)
 898         {
 899                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 900                 {
 901                         .entity weaponentity = weaponentities[slot];
 902                         if(_switchweapon & BIT(slot))
 903                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 904                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 905                 }
 906         }
 907
 908         return 1;
 909 }
 910
 911 void Item_Touch(entity this, entity toucher)
 912 {
 913         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 914         if (Item_IsLoot(this))
 915         {
 916                 if (ITEM_TOUCH_NEEDKILL())
 917                 {
 918                         delete(this);
 919                         return;
 920                 }
 921         }
 922
 923         if(!(toucher.flags & FL_PICKUPITEMS)
 924         || STAT(FROZEN, toucher)
 925         || IS_DEAD(toucher)
 926         || (this.solid != SOLID_TRIGGER)
 927         || (this.owner == toucher)
 928         || (time < this.item_spawnshieldtime)
 929         ) { return; }
 930
 931         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 932         {
 933                 case MUT_ITEMTOUCH_RETURN: { return; }
 934                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 935         }
 936
 937         toucher = M_ARGV(1, entity);
 938
 939         if (Item_IsExpiring(this))
 940         {
 941                 this.strength_finished = max(0, this.strength_finished - time);
 942                 this.invincible_finished = max(0, this.invincible_finished - time);
 943                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 944         }
 945         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 946         if (!gave)
 947         {
 948                 if (Item_IsExpiring(this))
 949                 {
 950                         // undo what we did above
 951                         this.strength_finished += time;
 952                         this.invincible_finished += time;
 953                         this.superweapons_finished += time;
 954                 }
 955                 return;
 956         }
 957
 958 LABEL(pickup)
 959
 960         STAT(LAST_PICKUP, toucher) = time;
 961
 962         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 963         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 964
 965         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 966         if (wasfreed(this))
 967         {
 968                 return;
 969         }
 970
 971         if (Item_IsLoot(this))
 972         {
 973                 delete(this);
 974                 return;
 975         }
 976         if (!this.spawnshieldtime)
 977         {
 978                 return;
 979         }
 980         entity e;
 981         if (this.team)
 982         {
 983                 RandomSelection_Init();
 984                 IL_EACH(g_items, it.team == this.team,
 985                 {
 986                         if (it.itemdef) // is a registered item
 987                         {
 988                                 Item_Show(it, -1);
 989                                 it.scheduledrespawntime = 0;
 990                                 RandomSelection_AddEnt(it, it.cnt, 0);
 991                         }
 992                 });
 993                 e = RandomSelection_chosen_ent;
 994                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 995         }
 996         else
 997                 e = this;
 998         Item_ScheduleRespawn(e);
 999 }
1000
1001 void Item_Reset(entity this)
1002 {
1003         Item_Show(this, !this.state);
1004         setorigin(this, this.origin);
1005
1006         if (Item_IsLoot(this))
1007         {
1008                 return;
1009         }
1010         setthink(this, Item_Think);
1011         this.nextthink = time;
1012         if (this.waypointsprite_attached)
1013         {
1014                 WaypointSprite_Kill(this.waypointsprite_attached);
1015         }
1016         if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1017         {
1018                 Item_ScheduleInitialRespawn(this);
1019         }
1020 }
1021
1022 void Item_FindTeam(entity this)
1023 {
1024         entity e;
1025
1026         if(this.effects & EF_NODRAW)
1027         {
1028                 // marker for item team search
1029                 LOG_TRACE("Initializing item team ", ftos(this.team));
1030                 RandomSelection_Init();
1031                 IL_EACH(g_items, it.team == this.team,
1032                 {
1033                         if(it.itemdef) // is a registered item
1034                                 RandomSelection_AddEnt(it, it.cnt, 0);
1035                 });
1036
1037                 e = RandomSelection_chosen_ent;
1038                 e.state = 0;
1039                 Item_Show(e, 1);
1040
1041                 IL_EACH(g_items, it.team == this.team,
1042                 {
1043                         if(it.itemdef) // is a registered item
1044                         {
1045                                 if(it != e)
1046                                 {
1047                                         // make it non-spawned
1048                                         Item_Show(it, -1);
1049                                         it.state = 1; // state 1 = initially hidden item, apparently
1050                                 }
1051                                 it.effects &= ~EF_NODRAW;
1052                         }
1053                 });
1054
1055                 Item_Reset(this);
1056         }
1057 }
1058
1059 // Savage: used for item garbage-collection
1060 void RemoveItem(entity this)
1061 {
1062         if(wasfreed(this) || !this) { return; }
1063         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1064         delete(this);
1065 }
1066
1067 // pickup evaluation functions
1068 // these functions decide how desirable an item is to the bots
1069
1070 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1071
1072 float weapon_pickupevalfunc(entity player, entity item)
1073 {
1074         // See if I have it already
1075         if(player.weapons & item.weapons)
1076         {
1077                 // If I can pick it up
1078                 if(!item.spawnshieldtime)
1079                         return 0;
1080                 return ammo_pickupevalfunc(player, item);
1081         }
1082
1083         // reduce weapon value if bot already got a good arsenal
1084         float c = 1;
1085         int weapons_value = 0;
1086         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1087                 weapons_value += it.bot_pickupbasevalue;
1088         });
1089         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1090
1091         return item.bot_pickupbasevalue * c;
1092 }
1093
1094 float ammo_pickupevalfunc(entity player, entity item)
1095 {
1096         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1097         entity wpn = NULL;
1098         float c = 0;
1099         float rating = 0;
1100
1101         // Detect needed ammo
1102         if(item.itemdef.instanceOfWeaponPickup)
1103         {
1104                 entity ammo = NULL;
1105                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1106                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1107                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1108                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1109                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1110                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1111
1112                 if(!ammo)
1113                         return 0;
1114                 wpn = item;
1115                 rating = ammo.m_botvalue;
1116         }
1117         else
1118         {
1119                 FOREACH(Weapons, it != WEP_Null, {
1120                         if(!(player.weapons & (it.m_wepset)))
1121                                 continue;
1122
1123                         switch(it.ammo_type)
1124                         {
1125                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1126                                 case RESOURCE_BULLETS: need_nails   = true; break;
1127                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1128                                 case RESOURCE_CELLS:   need_cells   = true; break;
1129                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1130                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1131                         }
1132                 });
1133                 rating = item.bot_pickupbasevalue;
1134         }
1135
1136         float noammorating = 0.5;
1137
1138         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1139                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1140
1141         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1142                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1143
1144         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1145                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1146
1147         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1148                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1149
1150         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1151                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1152
1153         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1154                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1155
1156         rating *= min(c, 2);
1157         if(wpn)
1158                 rating += wpn.bot_pickupbasevalue * 0.1;
1159         return rating;
1160 }
1161
1162 float healtharmor_pickupevalfunc(entity player, entity item)
1163 {
1164         float c = 0;
1165         float rating = item.bot_pickupbasevalue;
1166
1167         float itemarmor = item.armorvalue;
1168         float itemhealth = item.health;
1169
1170         if(item.item_group)
1171         {
1172                 itemarmor *= min(4, item.item_group_count);
1173                 itemhealth *= min(4, item.item_group_count);
1174         }
1175
1176         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1177                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1178
1179         if (itemhealth && (player.health < item.max_health))
1180                 c = itemhealth / max(1, player.health);
1181
1182         rating *= min(2, c);
1183         return rating;
1184 }
1185
1186 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1187 {
1188         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1189                 RemoveItem(this);
1190 }
1191
1192 void item_use(entity this, entity actor, entity trigger)
1193 {
1194         // use the touch function to handle collection
1195         gettouch(this)(this, actor);
1196 }
1197
1198 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1199 {
1200         string itemname = def.m_name;
1201         Model itemmodel = def.m_model;
1202     Sound pickupsound = def.m_sound;
1203         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1204         float pickupbasevalue = def.m_botvalue;
1205         int itemflags = def.m_itemflags;
1206
1207         startitem_failed = false;
1208
1209         this.item_model_ent = itemmodel;
1210     this.item_pickupsound_ent = pickupsound;
1211
1212     if(def.m_iteminit)
1213         def.m_iteminit(this);
1214
1215         if(!this.respawntime) // both need to be set
1216         {
1217                 this.respawntime = defaultrespawntime;
1218                 this.respawntimejitter = defaultrespawntimejitter;
1219         }
1220
1221         if(!this.pickup_anyway && def.m_pickupanyway)
1222                 this.pickup_anyway = def.m_pickupanyway();
1223
1224         int itemid = def.m_itemid;
1225         this.items = itemid;
1226         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1227         this.weapon = weaponid;
1228
1229         if(!this.fade_end)
1230         {
1231                 this.fade_start = autocvar_g_items_mindist;
1232                 this.fade_end = autocvar_g_items_maxdist;
1233         }
1234
1235         if(weaponid)
1236                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1237
1238         this.flags = FL_ITEM | itemflags;
1239         IL_PUSH(g_items, this);
1240
1241         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1242         {
1243                 startitem_failed = true;
1244                 delete(this);
1245                 return;
1246         }
1247
1248         if (Item_IsLoot(this))
1249         {
1250                 this.reset = SUB_Remove;
1251                 set_movetype(this, MOVETYPE_TOSS);
1252
1253                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1254                 setthink(this, RemoveItem);
1255                 this.nextthink = time + 20;
1256
1257                 this.takedamage = DAMAGE_YES;
1258                 this.event_damage = Item_Damage;
1259
1260                 if (Item_IsExpiring(this))
1261                 {
1262                         // if item is worthless after a timer, have it expire then
1263                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1264                 }
1265
1266                 // don't drop if in a NODROP zone (such as lava)
1267                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1268                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1269                 {
1270                         startitem_failed = true;
1271                         delete(this);
1272                         return;
1273                 }
1274         }
1275         else
1276         {
1277                 if(!have_pickup_item(this))
1278                 {
1279                         startitem_failed = true;
1280                         delete(this);
1281                         return;
1282                 }
1283
1284                 if(this.angles != '0 0 0')
1285                         this.SendFlags |= ISF_ANGLES;
1286
1287                 this.reset = Item_Reset;
1288                 // it's a level item
1289                 if(this.spawnflags & 1)
1290                         this.noalign = 1;
1291                 if (this.noalign > 0)
1292                         set_movetype(this, MOVETYPE_NONE);
1293                 else
1294                         set_movetype(this, MOVETYPE_TOSS);
1295                 // do item filtering according to game mode and other things
1296                 if (this.noalign <= 0)
1297                 {
1298                         // first nudge it off the floor a little bit to avoid math errors
1299                         setorigin(this, this.origin + '0 0 1');
1300                         // set item size before we spawn a spawnfunc_waypoint
1301                         setsize(this, def.m_mins, def.m_maxs);
1302                         this.SendFlags |= ISF_SIZE;
1303                         // note droptofloor returns false if stuck/or would fall too far
1304                         if (!this.noalign)
1305                                 droptofloor(this);
1306                         waypoint_spawnforitem(this);
1307                 }
1308
1309                 /*
1310                  * can't do it that way, as it would break maps
1311                  * TODO make a target_give like entity another way, that perhaps has
1312                  * the weapon name in a key
1313                 if(this.targetname)
1314                 {
1315                         // target_give not yet supported; maybe later
1316                         print("removed targeted ", this.classname, "\n");
1317                         startitem_failed = true;
1318                         delete(this);
1319                         return;
1320                 }
1321                 */
1322
1323                 if(this.targetname != "" && (this.spawnflags & 16))
1324                         this.use = item_use;
1325
1326                 if(autocvar_spawn_debug >= 2)
1327                 {
1328             // why not flags & fl_item?
1329                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1330                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1331                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1332                 error("Mapper sucks.");
1333             });
1334                         this.is_item = true;
1335                 }
1336
1337                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1338
1339                 precache_model(this.model);
1340                 precache_sound(this.item_pickupsound);
1341
1342                 if (   def.instanceOfPowerup
1343                         || def.instanceOfWeaponPickup
1344                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1345                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1346                         || (itemid & (IT_KEY1 | IT_KEY2))
1347                 ) this.target = "###item###"; // for finding the nearest item using find()
1348
1349                 Item_ItemsTime_SetTime(this, 0);
1350         }
1351
1352         this.bot_pickup = true;
1353         this.bot_pickupevalfunc = pickupevalfunc;
1354         this.bot_pickupbasevalue = pickupbasevalue;
1355         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1356         this.netname = itemname;
1357         settouch(this, Item_Touch);
1358         setmodel(this, MDL_Null); // precision set below
1359         //this.effects |= EF_LOWPRECISION;
1360
1361         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1362
1363         this.SendFlags |= ISF_SIZE;
1364
1365         if (!(this.spawnflags & 1024)) {
1366                 if(def.instanceOfPowerup)
1367                         this.ItemStatus |= ITS_ANIMATE1;
1368
1369                 if(this.armorvalue || this.health)
1370                         this.ItemStatus |= ITS_ANIMATE2;
1371         }
1372
1373         if(def.instanceOfWeaponPickup)
1374         {
1375                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1376                         this.colormap = 1024; // color shirt=0 pants=0 grey
1377                 else
1378                         this.gravity = 1;
1379                 if (!(this.spawnflags & 1024))
1380                         this.ItemStatus |= ITS_ANIMATE1;
1381                 this.SendFlags |= ISF_COLORMAP;
1382         }
1383
1384         this.state = 0;
1385         if(this.team) // broken, no idea why.
1386         {
1387                 if(!this.cnt)
1388                         this.cnt = 1; // item probability weight
1389
1390                 this.effects |= EF_NODRAW; // marker for item team search
1391                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1392         }
1393         else
1394                 Item_Reset(this);
1395
1396         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1397
1398         // call this hook after everything else has been done
1399         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1400         {
1401                 startitem_failed = true;
1402                 delete(this);
1403                 return;
1404         }
1405
1406         setItemGroup(this);
1407 }
1408
1409 void StartItem(entity this, GameItem def)
1410 {
1411     def = def.m_spawnfunc_hookreplace(def, this);
1412     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1413     {
1414         delete(this);
1415         return;
1416     }
1417     this.classname = def.m_canonical_spawnfunc;
1418     _StartItem(
1419         this,
1420         this.itemdef = def,
1421         def.m_respawntime(), // defaultrespawntime
1422         def.m_respawntimejitter() // defaultrespawntimejitter
1423         );
1424 }
1425
1426 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1427 int group_count = 1;
1428
1429 void setItemGroup(entity this)
1430 {
1431         if(!IS_SMALL(this.itemdef))
1432                 return;
1433
1434         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1435         {
1436                 if(!this.item_group)
1437                 {
1438                         if(!it.item_group)
1439                         {
1440                                 it.item_group = group_count;
1441                                 group_count++;
1442                         }
1443                         this.item_group = it.item_group;
1444                 }
1445                 else // spawning item is already part of a item_group X
1446                 {
1447                         if(!it.item_group)
1448                                 it.item_group = this.item_group;
1449                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1450                         {
1451                                 int grY = it.item_group;
1452                                 // move all items of item_group Y to item_group X
1453                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1454                                 {
1455                                         if(it.item_group == grY)
1456                                                 it.item_group = this.item_group;
1457                                 });
1458                         }
1459                 }
1460         });
1461 }
1462
1463 void setItemGroupCount()
1464 {
1465         for (int k = 1; k <= group_count; k++)
1466         {
1467                 int count = 0;
1468                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1469                 if (count)
1470                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1471         }
1472 }
1473
1474 void target_items_use(entity this, entity actor, entity trigger)
1475 {
1476         if(Item_IsLoot(actor))
1477         {
1478                 EXACTTRIGGER_TOUCH(this, trigger);
1479                 delete(actor);
1480                 return;
1481         }
1482
1483         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1484                 return;
1485
1486         if(trigger.solid == SOLID_TRIGGER)
1487         {
1488                 EXACTTRIGGER_TOUCH(this, trigger);
1489         }
1490
1491         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1492         {
1493                 delete(it);
1494         });
1495
1496         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1497                 centerprint(actor, this.message);
1498 }
1499
1500 spawnfunc(target_items)
1501 {
1502         int n;
1503         string s;
1504
1505         this.use = target_items_use;
1506         if(!this.strength_finished)
1507                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1508         if(!this.invincible_finished)
1509                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1510         if(!this.superweapons_finished)
1511                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1512
1513         n = tokenize_console(this.netname);
1514         if(argv(0) == "give")
1515         {
1516                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1517         }
1518         else
1519         {
1520                 for(int j = 0; j < n; ++j)
1521                 {
1522                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1523                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1524                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1525                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1526                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1527                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1528                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1529                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1530                         else
1531                         {
1532                                 FOREACH(Buffs, it != BUFF_Null,
1533                                 {
1534                                         s = Buff_UndeprecateName(argv(j));
1535                                         if(s == it.m_name)
1536                                         {
1537                                                 STAT(BUFFS, this) |= (it.m_itemid);
1538                                                 break;
1539                                         }
1540                                 });
1541                                 FOREACH(Weapons, it != WEP_Null, {
1542                                         s = W_UndeprecateName(argv(j));
1543                                         if(s == it.netname)
1544                                         {
1545                                                 this.weapons |= (it.m_wepset);
1546                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1547                                                         it.wr_init(it);
1548                                                 break;
1549                                         }
1550                                 });
1551                         }
1552                 }
1553
1554                 string itemprefix, valueprefix;
1555                 if(this.spawnflags == 0)
1556                 {
1557                         itemprefix = "";
1558                         valueprefix = "";
1559                 }
1560                 else if(this.spawnflags == 1)
1561                 {
1562                         itemprefix = "max ";
1563                         valueprefix = "max ";
1564                 }
1565                 else if(this.spawnflags == 2)
1566                 {
1567                         itemprefix = "min ";
1568                         valueprefix = "min ";
1569                 }
1570                 else if(this.spawnflags == 4)
1571                 {
1572                         itemprefix = "minus ";
1573                         valueprefix = "max ";
1574                 }
1575                 else
1576                 {
1577                         error("invalid spawnflags");
1578                         itemprefix = valueprefix = string_null;
1579                 }
1580
1581                 this.netname = "";
1582                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1583                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1584                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1585                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1586                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1587                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1588                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1589                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1590                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1591                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1592                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1593                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1594                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1595                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1596                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1597                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(BUFFS, this) & (it.m_itemid)), it.m_name));
1598                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1599         }
1600         this.netname = strzone(this.netname);
1601         //print(this.netname, "\n");
1602
1603         n = tokenize_console(this.netname);
1604         for(int j = 0; j < n; ++j)
1605         {
1606                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1607             it.wr_init(it);
1608             break;
1609                 });
1610         }
1611 }
1612
1613 float GiveWeapon(entity e, float wpn, float op, float val)
1614 {
1615         WepSet v0, v1;
1616         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1617         v0 = (e.weapons & s);
1618         switch(op)
1619         {
1620                 case OP_SET:
1621                         if(val > 0)
1622                                 e.weapons |= s;
1623                         else
1624                                 e.weapons &= ~s;
1625                         break;
1626                 case OP_MIN:
1627                 case OP_PLUS:
1628                         if(val > 0)
1629                                 e.weapons |= s;
1630                         break;
1631                 case OP_MAX:
1632                         if(val <= 0)
1633                                 e.weapons &= ~s;
1634                         break;
1635                 case OP_MINUS:
1636                         if(val > 0)
1637                                 e.weapons &= ~s;
1638                         break;
1639         }
1640         v1 = (e.weapons & s);
1641         return (v0 != v1);
1642 }
1643
1644 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1645 {
1646         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1647         switch(op)
1648         {
1649                 case OP_SET:
1650                         if(val > 0)
1651                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1652                         else
1653                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1654                         break;
1655                 case OP_MIN:
1656                 case OP_PLUS:
1657                         if(val > 0)
1658                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1659                         break;
1660                 case OP_MAX:
1661                         if(val <= 0)
1662                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1663                         break;
1664                 case OP_MINUS:
1665                         if(val > 0)
1666                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1667                         break;
1668         }
1669         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1670         return (had_buff != have_buff);
1671 }
1672
1673 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1674 {
1675         if(v1 == v0)
1676                 return;
1677         if(v1 <= v0 - t)
1678         {
1679                 if(snd_decr != NULL)
1680                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1681         }
1682         else if(v0 >= v0 + t)
1683         {
1684                 if(snd_incr != NULL)
1685                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1686         }
1687 }
1688
1689 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1690 {
1691         if(v0 < v1)
1692                 e.(rotfield) = max(e.(rotfield), time + rottime);
1693         else if(v0 > v1)
1694                 e.(regenfield) = max(e.(regenfield), time + regentime);
1695 }
1696 float GiveItems(entity e, float beginarg, float endarg)
1697 {
1698         float got, i, val, op;
1699         string cmd;
1700
1701         val = 999;
1702         op = OP_SET;
1703
1704         got = 0;
1705
1706         int _switchweapon = 0;
1707
1708         if(CS(e).autoswitch)
1709         {
1710                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1711                 {
1712                         .entity weaponentity = weaponentities[slot];
1713                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1714                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1715                                 _switchweapon |= BIT(slot);
1716                 }
1717         }
1718
1719         e.strength_finished = max(0, e.strength_finished - time);
1720         e.invincible_finished = max(0, e.invincible_finished - time);
1721         e.superweapons_finished = max(0, e.superweapons_finished - time);
1722
1723         PREGIVE(e, items);
1724         PREGIVE_WEAPONS(e);
1725         PREGIVE(e, strength_finished);
1726         PREGIVE(e, invincible_finished);
1727         PREGIVE(e, superweapons_finished);
1728         PREGIVE(e, ammo_nails);
1729         PREGIVE(e, ammo_cells);
1730         PREGIVE(e, ammo_plasma);
1731         PREGIVE(e, ammo_shells);
1732         PREGIVE(e, ammo_rockets);
1733         PREGIVE(e, ammo_fuel);
1734         PREGIVE(e, armorvalue);
1735         PREGIVE(e, health);
1736
1737         for(i = beginarg; i < endarg; ++i)
1738         {
1739                 cmd = argv(i);
1740
1741                 if(cmd == "0" || stof(cmd))
1742                 {
1743                         val = stof(cmd);
1744                         continue;
1745                 }
1746                 switch(cmd)
1747                 {
1748                         case "no":
1749                                 op = OP_MAX;
1750                                 val = 0;
1751                                 continue;
1752                         case "max":
1753                                 op = OP_MAX;
1754                                 continue;
1755                         case "min":
1756                                 op = OP_MIN;
1757                                 continue;
1758                         case "plus":
1759                                 op = OP_PLUS;
1760                                 continue;
1761                         case "minus":
1762                                 op = OP_MINUS;
1763                                 continue;
1764                         case "ALL":
1765                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1766                                 got += GiveValue(e, strength_finished, op, val);
1767                                 got += GiveValue(e, invincible_finished, op, val);
1768                                 got += GiveValue(e, superweapons_finished, op, val);
1769                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1770                         case "all":
1771                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1772                                 got += GiveValue(e, health, op, val);
1773                                 got += GiveValue(e, armorvalue, op, val);
1774                         case "allweapons":
1775                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1776                         //case "allbuffs": // all buffs makes a player god, do not want!
1777                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1778                         case "allammo":
1779                                 got += GiveValue(e, ammo_cells, op, val);
1780                                 got += GiveValue(e, ammo_plasma, op, val);
1781                                 got += GiveValue(e, ammo_shells, op, val);
1782                                 got += GiveValue(e, ammo_nails, op, val);
1783                                 got += GiveValue(e, ammo_rockets, op, val);
1784                                 got += GiveValue(e, ammo_fuel, op, val);
1785                                 break;
1786                         case "unlimited_ammo":
1787                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1788                                 break;
1789                         case "unlimited_weapon_ammo":
1790                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1791                                 break;
1792                         case "unlimited_superweapons":
1793                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1794                                 break;
1795                         case "jetpack":
1796                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1797                                 break;
1798                         case "fuel_regen":
1799                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1800                                 break;
1801                         case "strength":
1802                                 got += GiveValue(e, strength_finished, op, val);
1803                                 break;
1804                         case "invincible":
1805                                 got += GiveValue(e, invincible_finished, op, val);
1806                                 break;
1807                         case "superweapons":
1808                                 got += GiveValue(e, superweapons_finished, op, val);
1809                                 break;
1810                         case "cells":
1811                                 got += GiveValue(e, ammo_cells, op, val);
1812                                 break;
1813                         case "plasma":
1814                                 got += GiveValue(e, ammo_plasma, op, val);
1815                                 break;
1816                         case "shells":
1817                                 got += GiveValue(e, ammo_shells, op, val);
1818                                 break;
1819                         case "nails":
1820                         case "bullets":
1821                                 got += GiveValue(e, ammo_nails, op, val);
1822                                 break;
1823                         case "rockets":
1824                                 got += GiveValue(e, ammo_rockets, op, val);
1825                                 break;
1826                         case "health":
1827                                 got += GiveValue(e, health, op, val);
1828                                 break;
1829                         case "armor":
1830                                 got += GiveValue(e, armorvalue, op, val);
1831                                 break;
1832                         case "fuel":
1833                                 got += GiveValue(e, ammo_fuel, op, val);
1834                                 break;
1835                         default:
1836                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1837                                 {
1838                                         got += GiveBuff(e, it, op, val);
1839                                         break;
1840                                 });
1841                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1842                     got += GiveWeapon(e, it.m_id, op, val);
1843                     break;
1844                                 });
1845                                 break;
1846                 }
1847                 val = 999;
1848                 op = OP_SET;
1849         }
1850
1851         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1852         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1853         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1854         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1855         FOREACH(Weapons, it != WEP_Null, {
1856                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1857                 if(!(save_weapons & (it.m_wepset)))
1858                         if(e.weapons & (it.m_wepset))
1859                                 it.wr_init(it);
1860         });
1861         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1862         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1863         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1864         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1865         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1866         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1867         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1868         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1869         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1870         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1871         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1872
1873         if(e.superweapons_finished <= 0)
1874                 if(e.weapons & WEPSET_SUPERWEAPONS)
1875                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1876
1877         if(e.strength_finished <= 0)
1878                 e.strength_finished = 0;
1879         else
1880                 e.strength_finished += time;
1881         if(e.invincible_finished <= 0)
1882                 e.invincible_finished = 0;
1883         else
1884                 e.invincible_finished += time;
1885         if(e.superweapons_finished <= 0)
1886                 e.superweapons_finished = 0;
1887         else
1888                 e.superweapons_finished += time;
1889
1890         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1891         {
1892                 .entity weaponentity = weaponentities[slot];
1893                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1894                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1895                         _switchweapon |= BIT(slot);
1896         }
1897
1898         if(_switchweapon)
1899         {
1900                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1901                 {
1902                         .entity weaponentity = weaponentities[slot];
1903                         if(_switchweapon & BIT(slot))
1904                         {
1905                                 Weapon wep = w_getbestweapon(e, weaponentity);
1906                                 if(wep != e.(weaponentity).m_switchweapon)
1907                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1908                         }
1909                 }
1910         }
1911
1912         return got;
1913 }
1914 #endif