qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 if (autocvar_cl_ghost_items_color)
  54                 {
  55                         this.alpha = autocvar_cl_ghost_items;
  56                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  57                 }
  58                 else
  59                         this.alpha = -1;
  60         }
  61
  62         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  63         {
  64                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  65                 this.alpha = autocvar_cl_weapon_stay_alpha;
  66         }
  67
  68         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  69 }
  70
  71 void ItemDraw(entity this)
  72 {
  73     if(this.gravity)
  74     {
  75         Movetype_Physics_MatchServer(this, false);
  76         if(IS_ONGROUND(this))
  77         { // For some reason avelocity gets set to '0 0 0' here ...
  78             this.oldorigin = this.origin;
  79             this.gravity = 0;
  80
  81             if(autocvar_cl_animate_items)
  82             { // ... so reset it if animations are requested.
  83                 if(this.ItemStatus & ITS_ANIMATE1)
  84                     this.avelocity = '0 180 0';
  85
  86                 if(this.ItemStatus & ITS_ANIMATE2)
  87                     this.avelocity = '0 -90 0';
  88             }
  89
  90             // delay is for blocking item's position for a while;
  91             // it's a workaround for dropped weapons that receive the position
  92             // another time right after they spawn overriding animation position
  93             this.onground_time = time + 0.5;
  94         }
  95     }
  96     else if (autocvar_cl_animate_items)
  97     {
  98         if(this.ItemStatus & ITS_ANIMATE1)
  99         {
 100                 if(!this.item_simple)
 101                 this.angles += this.avelocity * frametime;
 102             float fade_in = bound(0, time - this.onground_time, 1);
 103             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 104         }
 105
 106         if(this.ItemStatus & ITS_ANIMATE2)
 107         {
 108                 if(!this.item_simple)
 109                 this.angles += this.avelocity * frametime;
 110             float fade_in = bound(0, time - this.onground_time, 1);
 111             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 112         }
 113     }
 114
 115     Item_SetAlpha(this);
 116 }
 117
 118 void Item_PreDraw(entity this)
 119 {
 120         if(warpzone_warpzones_exist)
 121         {
 122                 setpredraw(this, func_null); // no need to keep running this
 123                 return;
 124         }
 125         float alph;
 126         vector org = getpropertyvec(VF_ORIGIN);
 127         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 128                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 129         if(this.fade_start)
 130         {
 131                 if(vdist(org - this.origin, >, this.fade_end))
 132                         alph = 0; // save on some processing
 133                 else if(vdist(org - this.origin, <, this.fade_start))
 134                         alph = 1; // more processing saved
 135                 else
 136                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 137         }
 138         else
 139                 alph = 1;
 140         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 141         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 142                 this.alpha = alph;
 143         if(alph <= 0)
 144                 this.drawmask = 0;
 145         //else
 146                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 147 }
 148
 149 void ItemRemove(entity this)
 150 {
 151         if(this.mdl)
 152                 strunzone(this.mdl);
 153 }
 154
 155 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 156 {
 157     int sf = ReadByte();
 158
 159     if(sf & ISF_LOCATION)
 160     {
 161         this.origin_x = ReadCoord();
 162         this.origin_y = ReadCoord();
 163         this.origin_z = ReadCoord();
 164         setorigin(this, this.origin);
 165         this.oldorigin = this.origin;
 166     }
 167
 168     if(sf & ISF_ANGLES)
 169     {
 170         this.angles_x = ReadAngle();
 171         this.angles_y = ReadAngle();
 172         this.angles_z = ReadAngle();
 173     }
 174
 175     if(sf & ISF_SIZE)
 176     {
 177         float use_bigsize = ReadByte();
 178         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 179     }
 180
 181     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 182     {
 183         this.ItemStatus = ReadByte();
 184
 185         Item_SetAlpha(this);
 186
 187         if(autocvar_cl_fullbright_items)
 188             if(this.ItemStatus & ITS_ALLOWFB)
 189                 this.effects |= EF_FULLBRIGHT;
 190
 191         if(this.ItemStatus & ITS_GLOW)
 192         {
 193             if(this.ItemStatus & ITS_AVAILABLE)
 194                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 195             else
 196                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 197         }
 198     }
 199
 200     if(sf & ISF_MODEL)
 201     {
 202         this.drawmask  = MASK_NORMAL;
 203                 set_movetype(this, MOVETYPE_TOSS);
 204                 if (isnew) IL_PUSH(g_drawables, this);
 205         this.draw       = ItemDraw;
 206         this.solid = SOLID_TRIGGER;
 207         //this.flags |= FL_ITEM;
 208
 209         bool use_bigsize = ReadByte();
 210
 211         this.fade_end = ReadShort();
 212         this.fade_start = ReadShort();
 213         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 214                 setpredraw(this, Item_PreDraw);
 215
 216         if(this.mdl)
 217             strunzone(this.mdl);
 218
 219         this.mdl = "";
 220         string _fn = ReadString();
 221         this.item_simple = false; // reset it!
 222
 223         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 224         {
 225             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 226             this.item_simple = true;
 227
 228             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 229                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 230             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 231                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 232             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 233                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 234             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 235                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 236             else
 237             {
 238                 this.item_simple = false;
 239                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 240             }
 241         }
 242
 243         if(!this.item_simple)
 244             this.mdl = strzone(_fn);
 245
 246
 247         if(this.mdl == "")
 248             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 249
 250         precache_model(this.mdl);
 251         _setmodel(this, this.mdl);
 252
 253         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 254     }
 255
 256     if(sf & ISF_COLORMAP)
 257     {
 258         this.colormap = ReadShort();
 259         this.item_glowmod_x = ReadByte() / 255.0;
 260         this.item_glowmod_y = ReadByte() / 255.0;
 261         this.item_glowmod_z = ReadByte() / 255.0;
 262     }
 263
 264     if(sf & ISF_DROP)
 265     {
 266         this.gravity = 1;
 267         this.pushable = true;
 268         //this.angles = '0 0 0';
 269         set_movetype(this, MOVETYPE_TOSS);
 270         this.velocity_x = ReadCoord();
 271         this.velocity_y = ReadCoord();
 272         this.velocity_z = ReadCoord();
 273         setorigin(this, this.oldorigin);
 274
 275         if(!this.move_time)
 276         {
 277             this.move_time = time;
 278             this.spawntime = time;
 279         }
 280         else
 281             this.move_time = max(this.move_time, time);
 282     }
 283
 284     if(autocvar_cl_animate_items)
 285     {
 286         if(this.ItemStatus & ITS_ANIMATE1)
 287             this.avelocity = '0 180 0';
 288
 289         if(this.ItemStatus & ITS_ANIMATE2)
 290             this.avelocity = '0 -90 0';
 291     }
 292
 293     this.entremove = ItemRemove;
 294
 295     return true;
 296 }
 297
 298 #endif
 299
 300 #ifdef SVQC
 301 bool ItemSend(entity this, entity to, int sf)
 302 {
 303         if(this.gravity)
 304                 sf |= ISF_DROP;
 305         else
 306                 sf &= ~ISF_DROP;
 307
 308         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 309         WriteByte(MSG_ENTITY, sf);
 310
 311         //WriteByte(MSG_ENTITY, this.cnt);
 312         if(sf & ISF_LOCATION)
 313         {
 314                 WriteCoord(MSG_ENTITY, this.origin.x);
 315                 WriteCoord(MSG_ENTITY, this.origin.y);
 316                 WriteCoord(MSG_ENTITY, this.origin.z);
 317         }
 318
 319         if(sf & ISF_ANGLES)
 320         {
 321                 WriteAngle(MSG_ENTITY, this.angles_x);
 322                 WriteAngle(MSG_ENTITY, this.angles_y);
 323                 WriteAngle(MSG_ENTITY, this.angles_z);
 324         }
 325
 326         if(sf & ISF_SIZE)
 327         {
 328                 Pickup p = this.itemdef;
 329                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 330         }
 331
 332         if(sf & ISF_STATUS)
 333                 WriteByte(MSG_ENTITY, this.ItemStatus);
 334
 335         if(sf & ISF_MODEL)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339                 WriteShort(MSG_ENTITY, this.fade_end);
 340                 WriteShort(MSG_ENTITY, this.fade_start);
 341
 342                 if(this.mdl == "")
 343                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 344
 345                 WriteString(MSG_ENTITY, this.mdl);
 346         }
 347
 348
 349         if(sf & ISF_COLORMAP)
 350         {
 351                 WriteShort(MSG_ENTITY, this.colormap);
 352                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 353         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 354         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 355         }
 356
 357         if(sf & ISF_DROP)
 358         {
 359                 WriteCoord(MSG_ENTITY, this.velocity.x);
 360                 WriteCoord(MSG_ENTITY, this.velocity.y);
 361                 WriteCoord(MSG_ENTITY, this.velocity.z);
 362         }
 363
 364         return true;
 365 }
 366
 367 void ItemUpdate(entity this)
 368 {
 369         this.oldorigin = this.origin;
 370         this.SendFlags |= ISF_LOCATION;
 371 }
 372
 373 void UpdateItemAfterTeleport(entity this)
 374 {
 375         if(getSendEntity(this) == ItemSend)
 376                 ItemUpdate(this);
 377 }
 378
 379 bool have_pickup_item(entity this)
 380 {
 381         if(this.itemdef.instanceOfPowerup)
 382         {
 383                 if(autocvar_g_powerups > 0)
 384                         return true;
 385                 if(autocvar_g_powerups == 0)
 386                         return false;
 387         }
 388         else
 389         {
 390                 if(autocvar_g_pickup_items > 0)
 391                         return true;
 392                 if(autocvar_g_pickup_items == 0)
 393                         return false;
 394                 if(g_weaponarena)
 395                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 396                                 return false;
 397         }
 398         return true;
 399 }
 400
 401 /*
 402 float Item_Customize()
 403 {
 404         if(this.spawnshieldtime)
 405                 return true;
 406         if(this.weapons & ~other.weapons)
 407         {
 408                 this.colormod = '0 0 0';
 409                 this.glowmod = this.colormod;
 410                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 411                 return true;
 412         }
 413         else
 414         {
 415                 if(g_ghost_items)
 416                 {
 417                         this.colormod = stov(autocvar_g_ghost_items_color);
 418                         this.glowmod = this.colormod;
 419                         this.alpha = g_ghost_items;
 420                         return true;
 421                 }
 422                 else
 423                         return false;
 424         }
 425 }
 426 */
 427
 428 void Item_Show (entity e, float mode)
 429 {
 430         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 431         e.ItemStatus &= ~ITS_STAYWEP;
 432         entity def = e.itemdef;
 433         if (mode > 0)
 434         {
 435                 // make the item look normal, and be touchable
 436                 e.model = e.mdl;
 437                 e.solid = SOLID_TRIGGER;
 438                 e.spawnshieldtime = 1;
 439                 e.ItemStatus |= ITS_AVAILABLE;
 440         }
 441         else if (mode < 0)
 442         {
 443                 // hide the item completely
 444                 e.model = string_null;
 445                 e.solid = SOLID_NOT;
 446                 e.spawnshieldtime = 1;
 447                 e.ItemStatus &= ~ITS_AVAILABLE;
 448         }
 449         else
 450         {
 451                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 452                         || e.team // weapon stay isn't supported for teamed weapons
 453                         ;
 454                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 455                 {
 456                         // make the item translucent and not touchable
 457                         e.model = e.mdl;
 458                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 459                         e.effects |= EF_STARDUST;
 460                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 461                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 462                 }
 463                 else
 464                 {
 465                         //setmodel(e, "null");
 466                         e.solid = SOLID_NOT;
 467                         e.colormod = '0 0 0';
 468                         //e.glowmod = e.colormod;
 469                         e.spawnshieldtime = 1;
 470                         e.ItemStatus &= ~ITS_AVAILABLE;
 471                 }
 472         }
 473
 474         if (def.m_glow)
 475                 e.ItemStatus |= ITS_GLOW;
 476
 477         if (autocvar_g_nodepthtestitems)
 478                 e.effects |= EF_NODEPTHTEST;
 479
 480
 481         if (autocvar_g_fullbrightitems)
 482                 e.ItemStatus |= ITS_ALLOWFB;
 483
 484         if (autocvar_sv_simple_items)
 485                 e.ItemStatus |= ITS_ALLOWSI;
 486
 487         // relink entity (because solid may have changed)
 488         setorigin(e, e.origin);
 489         e.SendFlags |= ISF_STATUS;
 490 }
 491
 492 void Item_Think(entity this)
 493 {
 494         this.nextthink = time;
 495         if(this.origin != this.oldorigin)
 496                 ItemUpdate(this);
 497 }
 498
 499 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 500 bool Item_ItemsTime_Allow(GameItem it);
 501 float Item_ItemsTime_UpdateTime(entity e, float t);
 502 void Item_ItemsTime_SetTime(entity e, float t);
 503 void Item_ItemsTime_SetTimesForAllPlayers();
 504
 505 void Item_Respawn (entity this)
 506 {
 507         Item_Show(this, 1);
 508         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 509         setorigin(this, this.origin);
 510
 511     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 512         {
 513                 float t = Item_ItemsTime_UpdateTime(this, 0);
 514                 Item_ItemsTime_SetTime(this, t);
 515                 Item_ItemsTime_SetTimesForAllPlayers();
 516         }
 517
 518         setthink(this, Item_Think);
 519         this.nextthink = time;
 520
 521         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 522         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 523 }
 524
 525 void Item_RespawnCountdown (entity this)
 526 {
 527         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 528         {
 529                 if(this.waypointsprite_attached)
 530                         WaypointSprite_Kill(this.waypointsprite_attached);
 531                 Item_Respawn(this);
 532         }
 533         else
 534         {
 535                 this.nextthink = time + 1;
 536                 this.item_respawncounter += 1;
 537                 if(this.item_respawncounter == 1)
 538                 {
 539                         do {
 540                                 {
 541                                         entity wi = Weapons_from(this.weapon);
 542                                         if (wi != WEP_Null) {
 543                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 544                                                 wp.wp_extra = wi.m_id;
 545                                                 break;
 546                                         }
 547                                 }
 548                                 {
 549                                         entity ii = this.itemdef;
 550                                         if (ii != NULL) {
 551                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 552                                                 wp.wp_extra = ii.m_id;
 553                                                 break;
 554                                         }
 555                                 }
 556                         } while (0);
 557                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 558             if(this.waypointsprite_attached)
 559             {
 560                 GameItem def = this.itemdef;
 561                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 562                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 563                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 564             }
 565                 }
 566
 567                 if(this.waypointsprite_attached)
 568                 {
 569                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 570                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 571                                 {
 572                                         msg_entity = it;
 573                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 574                                 }
 575                         });
 576
 577                         WaypointSprite_Ping(this.waypointsprite_attached);
 578                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 579                 }
 580         }
 581 }
 582
 583 void Item_RespawnThink(entity this)
 584 {
 585         this.nextthink = time;
 586         if(this.origin != this.oldorigin)
 587                 ItemUpdate(this);
 588
 589         if(time >= this.wait)
 590                 Item_Respawn(this);
 591 }
 592
 593 void Item_ScheduleRespawnIn(entity e, float t)
 594 {
 595         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 596         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 597         {
 598                 setthink(e, Item_RespawnCountdown);
 599                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 600                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 601                 e.item_respawncounter = 0;
 602                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 603                 {
 604                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 605                         Item_ItemsTime_SetTime(e, t);
 606                         Item_ItemsTime_SetTimesForAllPlayers();
 607                 }
 608         }
 609         else
 610         {
 611                 setthink(e, Item_RespawnThink);
 612                 e.nextthink = time;
 613                 e.scheduledrespawntime = time + t;
 614                 e.wait = time + t;
 615
 616                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 617                 {
 618                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 619                         Item_ItemsTime_SetTime(e, t);
 620                         Item_ItemsTime_SetTimesForAllPlayers();
 621                 }
 622         }
 623 }
 624
 625 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 626 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 627 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 628
 629 /// Adjust respawn time according to the number of players.
 630 float adjust_respawntime(float normal_respawntime) {
 631         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 632         float o = autocvar_g_pickup_respawntime_scaling_offset;
 633         float l = autocvar_g_pickup_respawntime_scaling_linear;
 634
 635         if (r == 0 && l == 1) {
 636                 return normal_respawntime;
 637         }
 638
 639         CheckAllowedTeams(NULL);
 640         GetTeamCounts(NULL);
 641         int players = 0;
 642         if (c1 != -1) players += c1;
 643         if (c2 != -1) players += c2;
 644         if (c3 != -1) players += c3;
 645         if (c4 != -1) players += c4;
 646
 647         if (players >= 2) {
 648                 return normal_respawntime * (r / (players + o) + l);
 649         } else {
 650                 return normal_respawntime;
 651         }
 652 }
 653
 654 void Item_ScheduleRespawn(entity e)
 655 {
 656         if(e.respawntime > 0)
 657         {
 658                 Item_Show(e, 0);
 659
 660                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 661                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 662
 663                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 664                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 665                 Item_ScheduleRespawnIn(e, respawn_in);
 666         }
 667         else // if respawntime is -1, this item does not respawn
 668                 Item_Show(e, -1);
 669 }
 670
 671 AUTOCVAR(g_pickup_respawntime_initial_random, bool, 0, "Make the initial respawn time of items between 10 and their normal respawn time");
 672
 673 void Item_ScheduleInitialRespawn(entity e)
 674 {
 675         Item_Show(e, 0);
 676
 677         float spawn_in;
 678         if (autocvar_g_pickup_respawntime_initial_random)
 679         {
 680                 // range:
 681                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 682                 // else: 0 .. ITEM_RESPAWN_TICKS
 683                 spawn_in = ITEM_RESPAWN_TICKS + random() * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 684         }
 685         else
 686         {
 687                 // range: respawntime .. respawntime + respawntimejitter
 688                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 689         }
 690
 691         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 692 }
 693
 694 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 695         entity ammo_entity)
 696 {
 697         if (num_weapons == 0)
 698         {
 699                 return;
 700         }
 701         int num_potential_weapons = tokenize_console(weapon_names);
 702         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 703         {
 704                 RandomSelection_Init();
 705                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 706                         ++weapon_index)
 707                 {
 708                         string weapon = argv(weapon_index);
 709                         FOREACH(Weapons, it != WEP_Null,
 710                         {
 711                                 // Finding a weapon which player doesn't have.
 712                                 if (!(receiver.weapons & it.m_wepset) && (it.netname == weapon))
 713                                 {
 714                                         RandomSelection_AddEnt(it, 1, 1);
 715                                         break;
 716                                 }
 717                         });
 718                 }
 719                 if (RandomSelection_chosen_ent == NULL)
 720                 {
 721                         return;
 722                 }
 723                 receiver.weapons |= RandomSelection_chosen_ent.m_wepset;
 724                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
 725                 {
 726                         continue;
 727                 }
 728                 if (GetResourceAmount(receiver,
 729                         RandomSelection_chosen_ent.ammo_type) != 0)
 730                 {
 731                         continue;
 732                 }
 733                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 734                         GetResourceAmount(ammo_entity,
 735                         RandomSelection_chosen_ent.ammo_type));
 736         }
 737 }
 738
 739 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
 740 {
 741         float amount = GetResourceAmount(item, resource_type);
 742         if (amount == 0)
 743         {
 744                 return false;
 745         }
 746         float player_amount = GetResourceAmount(player, resource_type);
 747         if (item.spawnshieldtime)
 748         {
 749                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 750                 {
 751                         return false;
 752                 }
 753                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
 754                 return true;
 755         }
 756         if (g_weapon_stay != 2)
 757         {
 758                 return false;
 759         }
 760         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
 761         return true;
 762 }
 763
 764 float Item_GiveTo(entity item, entity player)
 765 {
 766         float pickedup;
 767
 768         // if nothing happens to player, just return without taking the item
 769         pickedup = false;
 770         int _switchweapon = 0;
 771         // in case the player has autoswitch enabled do the following:
 772         // if the player is using their best weapon before items are given, they
 773         // probably want to switch to an even better weapon after items are given
 774
 775         if(CS(player).autoswitch)
 776         {
 777                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 778                 {
 779                         .entity weaponentity = weaponentities[slot];
 780                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 781                         {
 782                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 783                                         _switchweapon |= BIT(slot);
 784
 785                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 786                                         _switchweapon |= BIT(slot);
 787                         }
 788                 }
 789         }
 790         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
 791         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
 792         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
 793         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
 794         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
 795         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
 796         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
 797         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
 798         if (item.itemdef.instanceOfWeaponPickup)
 799         {
 800                 WepSet w;
 801                 w = item.weapons;
 802                 w &= ~player.weapons;
 803
 804                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 805                 {
 806                         pickedup = true;
 807                         FOREACH(Weapons, it != WEP_Null, {
 808                                 if(w & (it.m_wepset))
 809                                 {
 810                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 811                                         {
 812                                                 .entity weaponentity = weaponentities[slot];
 813                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 814                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 815                                         }
 816                                         W_GiveWeapon(player, it.m_id);
 817                                 }
 818                         });
 819                 }
 820         }
 821
 822         if (item.itemdef.instanceOfPowerup)
 823         {
 824                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 825                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 826                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 827                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 828         }
 829
 830         int its;
 831         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 832         {
 833                 pickedup = true;
 834                 player.items |= its;
 835                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 836         }
 837
 838         if (item.strength_finished)
 839         {
 840                 pickedup = true;
 841                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 842         }
 843         if (item.invincible_finished)
 844         {
 845                 pickedup = true;
 846                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 847         }
 848         if (item.superweapons_finished)
 849         {
 850                 pickedup = true;
 851                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 852         }
 853
 854         // always eat teamed entities
 855         if(item.team)
 856                 pickedup = true;
 857
 858         if (!pickedup)
 859                 return 0;
 860
 861         // crude hack to enforce switching weapons
 862         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 863         {
 864                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 865                 {
 866                         .entity weaponentity = weaponentities[slot];
 867                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 868                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 869                 }
 870                 return 1;
 871         }
 872
 873         if(_switchweapon)
 874         {
 875                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 876                 {
 877                         .entity weaponentity = weaponentities[slot];
 878                         if(_switchweapon & BIT(slot))
 879                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 880                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 881                 }
 882         }
 883
 884         return 1;
 885 }
 886
 887 void Item_Touch(entity this, entity toucher)
 888 {
 889         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 890         if (Item_IsLoot(this))
 891         {
 892                 if (ITEM_TOUCH_NEEDKILL())
 893                 {
 894                         delete(this);
 895                         return;
 896                 }
 897         }
 898
 899         if(!(toucher.flags & FL_PICKUPITEMS)
 900         || STAT(FROZEN, toucher)
 901         || IS_DEAD(toucher)
 902         || (this.solid != SOLID_TRIGGER)
 903         || (this.owner == toucher)
 904         || (time < this.item_spawnshieldtime)
 905         ) { return; }
 906
 907         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 908         {
 909                 case MUT_ITEMTOUCH_RETURN: { return; }
 910                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 911         }
 912
 913         toucher = M_ARGV(1, entity);
 914
 915         if (Item_IsExpiring(this))
 916         {
 917                 this.strength_finished = max(0, this.strength_finished - time);
 918                 this.invincible_finished = max(0, this.invincible_finished - time);
 919                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 920         }
 921         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 922         if (!gave)
 923         {
 924                 if (Item_IsExpiring(this))
 925                 {
 926                         // undo what we did above
 927                         this.strength_finished += time;
 928                         this.invincible_finished += time;
 929                         this.superweapons_finished += time;
 930                 }
 931                 return;
 932         }
 933
 934 LABEL(pickup)
 935
 936         toucher.last_pickup = time;
 937
 938         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 939         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 940
 941         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 942         if (wasfreed(this))
 943         {
 944                 return;
 945         }
 946
 947         if (Item_IsLoot(this))
 948         {
 949                 delete(this);
 950                 return;
 951         }
 952         if (!this.spawnshieldtime)
 953         {
 954                 return;
 955         }
 956         entity e;
 957         if (this.team)
 958         {
 959                 RandomSelection_Init();
 960                 IL_EACH(g_items, it.team == this.team,
 961                 {
 962                         if (it.itemdef) // is a registered item
 963                         {
 964                                 Item_Show(it, -1);
 965                                 it.scheduledrespawntime = 0;
 966                                 RandomSelection_AddEnt(it, it.cnt, 0);
 967                         }
 968                 });
 969                 e = RandomSelection_chosen_ent;
 970                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 971         }
 972         else
 973                 e = this;
 974         Item_ScheduleRespawn(e);
 975 }
 976
 977 void Item_Reset(entity this)
 978 {
 979         Item_Show(this, !this.state);
 980         setorigin(this, this.origin);
 981
 982         if (Item_IsLoot(this))
 983         {
 984                 return;
 985         }
 986         setthink(this, Item_Think);
 987         this.nextthink = time;
 988         if (this.waypointsprite_attached)
 989         {
 990                 WaypointSprite_Kill(this.waypointsprite_attached);
 991         }
 992         if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 993         {
 994                 Item_ScheduleInitialRespawn(this);
 995         }
 996 }
 997
 998 void Item_FindTeam(entity this)
 999 {
1000         entity e;
1001
1002         if(this.effects & EF_NODRAW)
1003         {
1004                 // marker for item team search
1005                 LOG_TRACE("Initializing item team ", ftos(this.team));
1006                 RandomSelection_Init();
1007                 IL_EACH(g_items, it.team == this.team,
1008                 {
1009                         if(it.itemdef) // is a registered item
1010                                 RandomSelection_AddEnt(it, it.cnt, 0);
1011                 });
1012
1013                 e = RandomSelection_chosen_ent;
1014                 e.state = 0;
1015                 Item_Show(e, 1);
1016
1017                 IL_EACH(g_items, it.team == this.team,
1018                 {
1019                         if(it.itemdef) // is a registered item
1020                         {
1021                                 if(it != e)
1022                                 {
1023                                         // make it non-spawned
1024                                         Item_Show(it, -1);
1025                                         it.state = 1; // state 1 = initially hidden item, apparently
1026                                 }
1027                                 it.effects &= ~EF_NODRAW;
1028                         }
1029                 });
1030
1031                 Item_Reset(this);
1032         }
1033 }
1034
1035 // Savage: used for item garbage-collection
1036 void RemoveItem(entity this)
1037 {
1038         if(wasfreed(this) || !this) { return; }
1039         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1040         delete(this);
1041 }
1042
1043 // pickup evaluation functions
1044 // these functions decide how desirable an item is to the bots
1045
1046 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1047
1048 float weapon_pickupevalfunc(entity player, entity item)
1049 {
1050         // See if I have it already
1051         if(player.weapons & item.weapons)
1052         {
1053                 // If I can pick it up
1054                 if(!item.spawnshieldtime)
1055                         return 0;
1056                 return ammo_pickupevalfunc(player, item);
1057         }
1058
1059         // reduce weapon value if bot already got a good arsenal
1060         float c = 1;
1061         int weapons_value = 0;
1062         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1063                 weapons_value += it.bot_pickupbasevalue;
1064         });
1065         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1066
1067         return item.bot_pickupbasevalue * c;
1068 }
1069
1070 float ammo_pickupevalfunc(entity player, entity item)
1071 {
1072         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1073         entity wpn = NULL;
1074         float c = 0;
1075         float rating = 0;
1076
1077         // Detect needed ammo
1078         if(item.itemdef.instanceOfWeaponPickup)
1079         {
1080                 entity ammo = NULL;
1081                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1082                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1083                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1084                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1085                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1086                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1087
1088                 if(!ammo)
1089                         return 0;
1090                 wpn = item;
1091                 rating = ammo.m_botvalue;
1092         }
1093         else
1094         {
1095                 FOREACH(Weapons, it != WEP_Null, {
1096                         if(!(player.weapons & (it.m_wepset)))
1097                                 continue;
1098
1099                         switch(it.ammo_type)
1100                         {
1101                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1102                                 case RESOURCE_BULLETS: need_nails   = true; break;
1103                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1104                                 case RESOURCE_CELLS:   need_cells   = true; break;
1105                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1106                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1107                         }
1108                 });
1109                 rating = item.bot_pickupbasevalue;
1110         }
1111
1112         float noammorating = 0.5;
1113
1114         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1115                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1116
1117         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1118                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1119
1120         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1121                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1122
1123         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1124                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1125
1126         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1127                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1128
1129         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1130                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1131
1132         rating *= min(c, 2);
1133         if(wpn)
1134                 rating += wpn.bot_pickupbasevalue * 0.1;
1135         return rating;
1136 }
1137
1138 float healtharmor_pickupevalfunc(entity player, entity item)
1139 {
1140         float c = 0;
1141         float rating = item.bot_pickupbasevalue;
1142
1143         float itemarmor = item.armorvalue;
1144         float itemhealth = item.health;
1145
1146         if(item.item_group)
1147         {
1148                 itemarmor *= min(4, item.item_group_count);
1149                 itemhealth *= min(4, item.item_group_count);
1150         }
1151
1152         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1153                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1154
1155         if (itemhealth && (player.health < item.max_health))
1156                 c = itemhealth / max(1, player.health);
1157
1158         rating *= min(2, c);
1159         return rating;
1160 }
1161
1162 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1163 {
1164         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1165                 RemoveItem(this);
1166 }
1167
1168 void item_use(entity this, entity actor, entity trigger)
1169 {
1170         // use the touch function to handle collection
1171         gettouch(this)(this, actor);
1172 }
1173
1174 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1175 {
1176         string itemname = def.m_name;
1177         Model itemmodel = def.m_model;
1178     Sound pickupsound = def.m_sound;
1179         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1180         float pickupbasevalue = def.m_botvalue;
1181         int itemflags = def.m_itemflags;
1182
1183         startitem_failed = false;
1184
1185         this.item_model_ent = itemmodel;
1186     this.item_pickupsound_ent = pickupsound;
1187
1188     if(def.m_iteminit)
1189         def.m_iteminit(this);
1190
1191         if(!this.respawntime) // both need to be set
1192         {
1193                 this.respawntime = defaultrespawntime;
1194                 this.respawntimejitter = defaultrespawntimejitter;
1195         }
1196
1197         if(!this.pickup_anyway && def.m_pickupanyway)
1198                 this.pickup_anyway = def.m_pickupanyway();
1199
1200         int itemid = def.m_itemid;
1201         this.items = itemid;
1202         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1203         this.weapon = weaponid;
1204
1205         if(!this.fade_end)
1206         {
1207                 this.fade_start = autocvar_g_items_mindist;
1208                 this.fade_end = autocvar_g_items_maxdist;
1209         }
1210
1211         if(weaponid)
1212                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1213
1214         this.flags = FL_ITEM | itemflags;
1215         IL_PUSH(g_items, this);
1216
1217         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1218         {
1219                 startitem_failed = true;
1220                 delete(this);
1221                 return;
1222         }
1223
1224         if (Item_IsLoot(this))
1225         {
1226                 this.reset = SUB_Remove;
1227                 set_movetype(this, MOVETYPE_TOSS);
1228
1229                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1230                 setthink(this, RemoveItem);
1231                 this.nextthink = time + 20;
1232
1233                 this.takedamage = DAMAGE_YES;
1234                 this.event_damage = Item_Damage;
1235
1236                 if (Item_IsExpiring(this))
1237                 {
1238                         // if item is worthless after a timer, have it expire then
1239                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1240                 }
1241
1242                 // don't drop if in a NODROP zone (such as lava)
1243                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1244                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1245                 {
1246                         startitem_failed = true;
1247                         delete(this);
1248                         return;
1249                 }
1250         }
1251         else
1252         {
1253                 if(!have_pickup_item(this))
1254                 {
1255                         startitem_failed = true;
1256                         delete(this);
1257                         return;
1258                 }
1259
1260                 if(this.angles != '0 0 0')
1261                         this.SendFlags |= ISF_ANGLES;
1262
1263                 this.reset = Item_Reset;
1264                 // it's a level item
1265                 if(this.spawnflags & 1)
1266                         this.noalign = 1;
1267                 if (this.noalign > 0)
1268                         set_movetype(this, MOVETYPE_NONE);
1269                 else
1270                         set_movetype(this, MOVETYPE_TOSS);
1271                 // do item filtering according to game mode and other things
1272                 if (this.noalign <= 0)
1273                 {
1274                         // first nudge it off the floor a little bit to avoid math errors
1275                         setorigin(this, this.origin + '0 0 1');
1276                         // set item size before we spawn a spawnfunc_waypoint
1277                         setsize(this, def.m_mins, def.m_maxs);
1278                         this.SendFlags |= ISF_SIZE;
1279                         // note droptofloor returns false if stuck/or would fall too far
1280                         if (!this.noalign)
1281                                 droptofloor(this);
1282                         waypoint_spawnforitem(this);
1283                 }
1284
1285                 /*
1286                  * can't do it that way, as it would break maps
1287                  * TODO make a target_give like entity another way, that perhaps has
1288                  * the weapon name in a key
1289                 if(this.targetname)
1290                 {
1291                         // target_give not yet supported; maybe later
1292                         print("removed targeted ", this.classname, "\n");
1293                         startitem_failed = true;
1294                         delete(this);
1295                         return;
1296                 }
1297                 */
1298
1299                 if(this.targetname != "" && (this.spawnflags & 16))
1300                         this.use = item_use;
1301
1302                 if(autocvar_spawn_debug >= 2)
1303                 {
1304             // why not flags & fl_item?
1305                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1306                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1307                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1308                 error("Mapper sucks.");
1309             });
1310                         this.is_item = true;
1311                 }
1312
1313                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1314
1315                 precache_model(this.model);
1316                 precache_sound(this.item_pickupsound);
1317
1318                 if (   def.instanceOfPowerup
1319                         || def.instanceOfWeaponPickup
1320                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1321                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1322                         || (itemid & (IT_KEY1 | IT_KEY2))
1323                 ) this.target = "###item###"; // for finding the nearest item using find()
1324
1325                 Item_ItemsTime_SetTime(this, 0);
1326         }
1327
1328         this.bot_pickup = true;
1329         this.bot_pickupevalfunc = pickupevalfunc;
1330         this.bot_pickupbasevalue = pickupbasevalue;
1331         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1332         this.netname = itemname;
1333         settouch(this, Item_Touch);
1334         setmodel(this, MDL_Null); // precision set below
1335         //this.effects |= EF_LOWPRECISION;
1336
1337         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1338
1339         this.SendFlags |= ISF_SIZE;
1340
1341         if (!(this.spawnflags & 1024)) {
1342                 if(def.instanceOfPowerup)
1343                         this.ItemStatus |= ITS_ANIMATE1;
1344
1345                 if(this.armorvalue || this.health)
1346                         this.ItemStatus |= ITS_ANIMATE2;
1347         }
1348
1349         if(def.instanceOfWeaponPickup)
1350         {
1351                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1352                         this.colormap = 1024; // color shirt=0 pants=0 grey
1353                 else
1354                         this.gravity = 1;
1355                 if (!(this.spawnflags & 1024))
1356                         this.ItemStatus |= ITS_ANIMATE1;
1357                 this.SendFlags |= ISF_COLORMAP;
1358         }
1359
1360         this.state = 0;
1361         if(this.team) // broken, no idea why.
1362         {
1363                 if(!this.cnt)
1364                         this.cnt = 1; // item probability weight
1365
1366                 this.effects |= EF_NODRAW; // marker for item team search
1367                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1368         }
1369         else
1370                 Item_Reset(this);
1371
1372         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1373
1374         // call this hook after everything else has been done
1375         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1376         {
1377                 startitem_failed = true;
1378                 delete(this);
1379                 return;
1380         }
1381
1382         setItemGroup(this);
1383 }
1384
1385 void StartItem(entity this, GameItem def)
1386 {
1387     def = def.m_spawnfunc_hookreplace(def, this);
1388     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1389     {
1390         delete(this);
1391         return;
1392     }
1393     this.classname = def.m_canonical_spawnfunc;
1394     _StartItem(
1395         this,
1396         this.itemdef = def,
1397         def.m_respawntime(), // defaultrespawntime
1398         def.m_respawntimejitter() // defaultrespawntimejitter
1399         );
1400 }
1401
1402 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1403 int group_count = 1;
1404
1405 void setItemGroup(entity this)
1406 {
1407         if(!IS_SMALL(this.itemdef))
1408                 return;
1409
1410         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1411         {
1412                 if(!this.item_group)
1413                 {
1414                         if(!it.item_group)
1415                         {
1416                                 it.item_group = group_count;
1417                                 group_count++;
1418                         }
1419                         this.item_group = it.item_group;
1420                 }
1421                 else // spawning item is already part of a item_group X
1422                 {
1423                         if(!it.item_group)
1424                                 it.item_group = this.item_group;
1425                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1426                         {
1427                                 int grY = it.item_group;
1428                                 // move all items of item_group Y to item_group X
1429                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1430                                 {
1431                                         if(it.item_group == grY)
1432                                                 it.item_group = this.item_group;
1433                                 });
1434                         }
1435                 }
1436         });
1437 }
1438
1439 void setItemGroupCount()
1440 {
1441         for (int k = 1; k <= group_count; k++)
1442         {
1443                 int count = 0;
1444                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1445                 if (count)
1446                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1447         }
1448 }
1449
1450 void target_items_use(entity this, entity actor, entity trigger)
1451 {
1452         if(Item_IsLoot(actor))
1453         {
1454                 EXACTTRIGGER_TOUCH(this, trigger);
1455                 delete(actor);
1456                 return;
1457         }
1458
1459         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1460                 return;
1461
1462         if(trigger.solid == SOLID_TRIGGER)
1463         {
1464                 EXACTTRIGGER_TOUCH(this, trigger);
1465         }
1466
1467         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1468         {
1469                 delete(it);
1470         });
1471
1472         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1473                 centerprint(actor, this.message);
1474 }
1475
1476 spawnfunc(target_items)
1477 {
1478         int n;
1479         string s;
1480
1481         this.use = target_items_use;
1482         if(!this.strength_finished)
1483                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1484         if(!this.invincible_finished)
1485                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1486         if(!this.superweapons_finished)
1487                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1488
1489         n = tokenize_console(this.netname);
1490         if(argv(0) == "give")
1491         {
1492                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1493         }
1494         else
1495         {
1496                 for(int j = 0; j < n; ++j)
1497                 {
1498                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1499                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1500                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1501                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1502                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1503                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1504                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1505                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1506                         else
1507                         {
1508                                 FOREACH(Buffs, it != BUFF_Null,
1509                                 {
1510                                         s = Buff_UndeprecateName(argv(j));
1511                                         if(s == it.m_name)
1512                                         {
1513                                                 this.buffs |= (it.m_itemid);
1514                                                 break;
1515                                         }
1516                                 });
1517                                 FOREACH(Weapons, it != WEP_Null, {
1518                                         s = W_UndeprecateName(argv(j));
1519                                         if(s == it.netname)
1520                                         {
1521                                                 this.weapons |= (it.m_wepset);
1522                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1523                                                         it.wr_init(it);
1524                                                 break;
1525                                         }
1526                                 });
1527                         }
1528                 }
1529
1530                 string itemprefix, valueprefix;
1531                 if(this.spawnflags == 0)
1532                 {
1533                         itemprefix = "";
1534                         valueprefix = "";
1535                 }
1536                 else if(this.spawnflags == 1)
1537                 {
1538                         itemprefix = "max ";
1539                         valueprefix = "max ";
1540                 }
1541                 else if(this.spawnflags == 2)
1542                 {
1543                         itemprefix = "min ";
1544                         valueprefix = "min ";
1545                 }
1546                 else if(this.spawnflags == 4)
1547                 {
1548                         itemprefix = "minus ";
1549                         valueprefix = "max ";
1550                 }
1551                 else
1552                 {
1553                         error("invalid spawnflags");
1554                         itemprefix = valueprefix = string_null;
1555                 }
1556
1557                 this.netname = "";
1558                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1559                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1560                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1561                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1562                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1563                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1564                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1565                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1566                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1567                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1568                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1569                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1570                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1571                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1572                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1573                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1574                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1575         }
1576         this.netname = strzone(this.netname);
1577         //print(this.netname, "\n");
1578
1579         n = tokenize_console(this.netname);
1580         for(int j = 0; j < n; ++j)
1581         {
1582                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1583             it.wr_init(it);
1584             break;
1585                 });
1586         }
1587 }
1588
1589 float GiveWeapon(entity e, float wpn, float op, float val)
1590 {
1591         WepSet v0, v1;
1592         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1593         v0 = (e.weapons & s);
1594         switch(op)
1595         {
1596                 case OP_SET:
1597                         if(val > 0)
1598                                 e.weapons |= s;
1599                         else
1600                                 e.weapons &= ~s;
1601                         break;
1602                 case OP_MIN:
1603                 case OP_PLUS:
1604                         if(val > 0)
1605                                 e.weapons |= s;
1606                         break;
1607                 case OP_MAX:
1608                         if(val <= 0)
1609                                 e.weapons &= ~s;
1610                         break;
1611                 case OP_MINUS:
1612                         if(val > 0)
1613                                 e.weapons &= ~s;
1614                         break;
1615         }
1616         v1 = (e.weapons & s);
1617         return (v0 != v1);
1618 }
1619
1620 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1621 {
1622         bool had_buff = (e.buffs & thebuff.m_itemid);
1623         switch(op)
1624         {
1625                 case OP_SET:
1626                         if(val > 0)
1627                                 e.buffs |= thebuff.m_itemid;
1628                         else
1629                                 e.buffs &= ~thebuff.m_itemid;
1630                         break;
1631                 case OP_MIN:
1632                 case OP_PLUS:
1633                         if(val > 0)
1634                                 e.buffs |= thebuff.m_itemid;
1635                         break;
1636                 case OP_MAX:
1637                         if(val <= 0)
1638                                 e.buffs &= ~thebuff.m_itemid;
1639                         break;
1640                 case OP_MINUS:
1641                         if(val > 0)
1642                                 e.buffs &= ~thebuff.m_itemid;
1643                         break;
1644         }
1645         bool have_buff = (e.buffs & thebuff.m_itemid);
1646         return (had_buff != have_buff);
1647 }
1648
1649 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1650 {
1651         if(v1 == v0)
1652                 return;
1653         if(v1 <= v0 - t)
1654         {
1655                 if(snd_decr != NULL)
1656                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1657         }
1658         else if(v0 >= v0 + t)
1659         {
1660                 if(snd_incr != NULL)
1661                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1662         }
1663 }
1664
1665 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1666 {
1667         if(v0 < v1)
1668                 e.(rotfield) = max(e.(rotfield), time + rottime);
1669         else if(v0 > v1)
1670                 e.(regenfield) = max(e.(regenfield), time + regentime);
1671 }
1672 float GiveItems(entity e, float beginarg, float endarg)
1673 {
1674         float got, i, val, op;
1675         string cmd;
1676
1677         val = 999;
1678         op = OP_SET;
1679
1680         got = 0;
1681
1682         int _switchweapon = 0;
1683
1684         if(CS(e).autoswitch)
1685         {
1686                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1687                 {
1688                         .entity weaponentity = weaponentities[slot];
1689                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1690                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1691                                 _switchweapon |= BIT(slot);
1692                 }
1693         }
1694
1695         e.strength_finished = max(0, e.strength_finished - time);
1696         e.invincible_finished = max(0, e.invincible_finished - time);
1697         e.superweapons_finished = max(0, e.superweapons_finished - time);
1698
1699         PREGIVE(e, items);
1700         PREGIVE_WEAPONS(e);
1701         PREGIVE(e, strength_finished);
1702         PREGIVE(e, invincible_finished);
1703         PREGIVE(e, superweapons_finished);
1704         PREGIVE(e, ammo_nails);
1705         PREGIVE(e, ammo_cells);
1706         PREGIVE(e, ammo_plasma);
1707         PREGIVE(e, ammo_shells);
1708         PREGIVE(e, ammo_rockets);
1709         PREGIVE(e, ammo_fuel);
1710         PREGIVE(e, armorvalue);
1711         PREGIVE(e, health);
1712
1713         for(i = beginarg; i < endarg; ++i)
1714         {
1715                 cmd = argv(i);
1716
1717                 if(cmd == "0" || stof(cmd))
1718                 {
1719                         val = stof(cmd);
1720                         continue;
1721                 }
1722                 switch(cmd)
1723                 {
1724                         case "no":
1725                                 op = OP_MAX;
1726                                 val = 0;
1727                                 continue;
1728                         case "max":
1729                                 op = OP_MAX;
1730                                 continue;
1731                         case "min":
1732                                 op = OP_MIN;
1733                                 continue;
1734                         case "plus":
1735                                 op = OP_PLUS;
1736                                 continue;
1737                         case "minus":
1738                                 op = OP_MINUS;
1739                                 continue;
1740                         case "ALL":
1741                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1742                                 got += GiveValue(e, strength_finished, op, val);
1743                                 got += GiveValue(e, invincible_finished, op, val);
1744                                 got += GiveValue(e, superweapons_finished, op, val);
1745                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1746                         case "all":
1747                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1748                                 got += GiveValue(e, health, op, val);
1749                                 got += GiveValue(e, armorvalue, op, val);
1750                         case "allweapons":
1751                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1752                         //case "allbuffs": // all buffs makes a player god, do not want!
1753                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1754                         case "allammo":
1755                                 got += GiveValue(e, ammo_cells, op, val);
1756                                 got += GiveValue(e, ammo_plasma, op, val);
1757                                 got += GiveValue(e, ammo_shells, op, val);
1758                                 got += GiveValue(e, ammo_nails, op, val);
1759                                 got += GiveValue(e, ammo_rockets, op, val);
1760                                 got += GiveValue(e, ammo_fuel, op, val);
1761                                 break;
1762                         case "unlimited_ammo":
1763                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1764                                 break;
1765                         case "unlimited_weapon_ammo":
1766                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1767                                 break;
1768                         case "unlimited_superweapons":
1769                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1770                                 break;
1771                         case "jetpack":
1772                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1773                                 break;
1774                         case "fuel_regen":
1775                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1776                                 break;
1777                         case "strength":
1778                                 got += GiveValue(e, strength_finished, op, val);
1779                                 break;
1780                         case "invincible":
1781                                 got += GiveValue(e, invincible_finished, op, val);
1782                                 break;
1783                         case "superweapons":
1784                                 got += GiveValue(e, superweapons_finished, op, val);
1785                                 break;
1786                         case "cells":
1787                                 got += GiveValue(e, ammo_cells, op, val);
1788                                 break;
1789                         case "plasma":
1790                                 got += GiveValue(e, ammo_plasma, op, val);
1791                                 break;
1792                         case "shells":
1793                                 got += GiveValue(e, ammo_shells, op, val);
1794                                 break;
1795                         case "nails":
1796                         case "bullets":
1797                                 got += GiveValue(e, ammo_nails, op, val);
1798                                 break;
1799                         case "rockets":
1800                                 got += GiveValue(e, ammo_rockets, op, val);
1801                                 break;
1802                         case "health":
1803                                 got += GiveValue(e, health, op, val);
1804                                 break;
1805                         case "armor":
1806                                 got += GiveValue(e, armorvalue, op, val);
1807                                 break;
1808                         case "fuel":
1809                                 got += GiveValue(e, ammo_fuel, op, val);
1810                                 break;
1811                         default:
1812                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1813                                 {
1814                                         got += GiveBuff(e, it, op, val);
1815                                         break;
1816                                 });
1817                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1818                     got += GiveWeapon(e, it.m_id, op, val);
1819                     break;
1820                                 });
1821                                 break;
1822                 }
1823                 val = 999;
1824                 op = OP_SET;
1825         }
1826
1827         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1828         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1829         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1830         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1831         FOREACH(Weapons, it != WEP_Null, {
1832                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1833                 if(!(save_weapons & (it.m_wepset)))
1834                         if(e.weapons & (it.m_wepset))
1835                                 it.wr_init(it);
1836         });
1837         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1838         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1839         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1840         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1841         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1842         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1843         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1844         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1845         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1846         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1847         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1848
1849         if(e.superweapons_finished <= 0)
1850                 if(e.weapons & WEPSET_SUPERWEAPONS)
1851                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1852
1853         if(e.strength_finished <= 0)
1854                 e.strength_finished = 0;
1855         else
1856                 e.strength_finished += time;
1857         if(e.invincible_finished <= 0)
1858                 e.invincible_finished = 0;
1859         else
1860                 e.invincible_finished += time;
1861         if(e.superweapons_finished <= 0)
1862                 e.superweapons_finished = 0;
1863         else
1864                 e.superweapons_finished += time;
1865
1866         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1867         {
1868                 .entity weaponentity = weaponentities[slot];
1869                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1870                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1871                         _switchweapon |= BIT(slot);
1872         }
1873
1874         if(_switchweapon)
1875         {
1876                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1877                 {
1878                         .entity weaponentity = weaponentities[slot];
1879                         if(_switchweapon & BIT(slot))
1880                         {
1881                                 Weapon wep = w_getbestweapon(e, weaponentity);
1882                                 if(wep != e.(weaponentity).m_switchweapon)
1883                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1884                         }
1885                 }
1886         }
1887
1888         return got;
1889 }
1890 #endif