qcsrc/common/triggers/trigger/jumppads.qc

   1 #include "jumppads.qh"
   2 // TODO: split target_push and put it in the target folder
   3 #ifdef SVQC
   4 #include "jumppads.qh"
   5 #include <common/physics/movetypes/movetypes.qh>
   6
   7 void trigger_push_use(entity this, entity actor, entity trigger)
   8 {
   9         if(teamplay)
  10         {
  11                 this.team = actor.team;
  12                 this.SendFlags |= 2;
  13         }
  14 }
  15 #endif
  16
  17 REGISTER_NET_LINKED(ENT_CLIENT_TRIGGER_PUSH)
  18 REGISTER_NET_LINKED(ENT_CLIENT_TARGET_PUSH)
  19
  20 /*
  21         trigger_push_calculatevelocity
  22
  23         Arguments:
  24           org - origin of the object which is to be pushed
  25           tgt - target entity (can be either a point or a model entity; if it is
  26                 the latter, its midpoint is used)
  27           ht  - jump height, measured from the higher one of org and tgt's midpoint
  28
  29         Returns: velocity for the jump
  30         the global trigger_push_calculatevelocity_flighttime is set to the total
  31         jump time
  32  */
  33
  34 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  35 {
  36         float grav, sdist, zdist, vs, vz, jumpheight;
  37         vector sdir, torg;
  38
  39         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  40
  41         grav = PHYS_GRAVITY(other);
  42         if(PHYS_ENTGRAVITY(other))
  43                 grav *= PHYS_ENTGRAVITY(other);
  44
  45         zdist = torg.z - org.z;
  46         sdist = vlen(torg - org - zdist * '0 0 1');
  47         sdir = normalize(torg - org - zdist * '0 0 1');
  48
  49         // how high do we need to push the player?
  50         jumpheight = fabs(ht);
  51         if(zdist > 0)
  52                 jumpheight = jumpheight + zdist;
  53
  54         /*
  55                 STOP.
  56
  57                 You will not understand the following equations anyway...
  58                 But here is what I did to get them.
  59
  60                 I used the functions
  61
  62                   s(t) = t * vs
  63                   z(t) = t * vz - 1/2 grav t^2
  64
  65                 and solved for:
  66
  67                   s(ti) = sdist
  68                   z(ti) = zdist
  69                   max(z, ti) = jumpheight
  70
  71                 From these three equations, you will find the three parameters vs, vz
  72                 and ti.
  73          */
  74
  75         // push him so high...
  76         vz = sqrt(fabs(2 * grav * jumpheight)); // NOTE: sqrt(positive)!
  77
  78         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  79         if(ht < 0)
  80                 if(zdist < 0)
  81                         vz = -vz;
  82
  83         vector solution;
  84         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  85         // ALWAYS solvable because jumpheight >= zdist
  86         if(!solution.z)
  87                 solution_y = solution.x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  88         if(zdist == 0)
  89                 solution_x = solution.y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  90
  91         if(zdist < 0)
  92         {
  93                 // down-jump
  94                 if(ht < 0)
  95                 {
  96                         // almost straight line type
  97                         // jump apex is before the jump
  98                         // we must take the larger one
  99                         trigger_push_calculatevelocity_flighttime = solution.y;
 100                 }
 101                 else
 102                 {
 103                         // regular jump
 104                         // jump apex is during the jump
 105                         // we must take the larger one too
 106                         trigger_push_calculatevelocity_flighttime = solution.y;
 107                 }
 108         }
 109         else
 110         {
 111                 // up-jump
 112                 if(ht < 0)
 113                 {
 114                         // almost straight line type
 115                         // jump apex is after the jump
 116                         // we must take the smaller one
 117                         trigger_push_calculatevelocity_flighttime = solution.x;
 118                 }
 119                 else
 120                 {
 121                         // regular jump
 122                         // jump apex is during the jump
 123                         // we must take the larger one
 124                         trigger_push_calculatevelocity_flighttime = solution.y;
 125                 }
 126         }
 127         vs = sdist / trigger_push_calculatevelocity_flighttime;
 128
 129         // finally calculate the velocity
 130         return sdir * vs + '0 0 1' * vz;
 131 }
 132
 133 bool jumppad_push(entity this, entity targ)
 134 {
 135         if (!isPushable(targ))
 136                 return false;
 137
 138         if(this.enemy)
 139         {
 140                 targ.velocity = trigger_push_calculatevelocity(targ.origin, this.enemy, this.height);
 141         }
 142         else if(this.target && this.target != "")
 143         {
 144                 entity e;
 145                 RandomSelection_Init();
 146                 for(e = NULL; (e = find(e, targetname, this.target)); )
 147                 {
 148                         if(e.cnt)
 149                                 RandomSelection_AddEnt(e, e.cnt, 1);
 150                         else
 151                                 RandomSelection_AddEnt(e, 1, 1);
 152                 }
 153                 targ.velocity = trigger_push_calculatevelocity(targ.origin, RandomSelection_chosen_ent, this.height);
 154         }
 155         else
 156         {
 157                 targ.velocity = this.movedir;
 158         }
 159
 160         UNSET_ONGROUND(targ);
 161
 162 #ifdef CSQC
 163         if (targ.flags & FL_PROJECTILE)
 164         {
 165                 targ.angles = vectoangles (targ.velocity);
 166                 switch(targ.move_movetype)
 167                 {
 168                         case MOVETYPE_FLY:
 169                                 set_movetype(targ, MOVETYPE_TOSS);
 170                                 targ.gravity = 1;
 171                                 break;
 172                         case MOVETYPE_BOUNCEMISSILE:
 173                                 set_movetype(targ, MOVETYPE_BOUNCE);
 174                                 targ.gravity = 1;
 175                                 break;
 176                 }
 177         }
 178 #endif
 179
 180 #ifdef SVQC
 181         if (IS_PLAYER(targ))
 182         {
 183                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 184                 targ.oldvelocity = targ.velocity;
 185
 186                 if(this.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 187                 {
 188                         // flash when activated
 189                         Send_Effect(EFFECT_JUMPPAD, targ.origin, targ.velocity, 1);
 190                         _sound (targ, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 191                         this.pushltime = time + 0.2;
 192                 }
 193                 if(IS_REAL_CLIENT(targ) || IS_BOT_CLIENT(targ))
 194                 {
 195                         bool found = false;
 196                         for(int i = 0; i < targ.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 197                                 if(targ.(jumppadsused[i]) == this)
 198                                         found = true;
 199                         if(!found)
 200                         {
 201                                 targ.(jumppadsused[targ.jumppadcount % NUM_JUMPPADSUSED]) = this;
 202                                 targ.jumppadcount = targ.jumppadcount + 1;
 203                         }
 204
 205                         if(IS_REAL_CLIENT(targ))
 206                         {
 207                                 if(this.message)
 208                                         centerprint(targ, this.message);
 209                         }
 210                         else
 211                                 targ.lastteleporttime = time;
 212
 213                         if (!IS_DEAD(targ))
 214                                 animdecide_setaction(targ, ANIMACTION_JUMP, true);
 215                 }
 216                 else
 217                         targ.jumppadcount = true;
 218
 219                 // reset tracking of who pushed you into a hazard (for kill credit)
 220                 targ.pushltime = 0;
 221                 targ.istypefrag = 0;
 222         }
 223
 224         if(this.enemy.target)
 225                 SUB_UseTargets(this.enemy, targ, this);
 226
 227         if (targ.flags & FL_PROJECTILE)
 228         {
 229                 targ.angles = vectoangles (targ.velocity);
 230                 targ.com_phys_gravity_factor = 1;
 231                 switch(targ.move_movetype)
 232                 {
 233                         case MOVETYPE_FLY:
 234                                 set_movetype(targ, MOVETYPE_TOSS);
 235                                 targ.gravity = 1;
 236                                 break;
 237                         case MOVETYPE_BOUNCEMISSILE:
 238                                 set_movetype(targ, MOVETYPE_BOUNCE);
 239                                 targ.gravity = 1;
 240                                 break;
 241                 }
 242                 UpdateCSQCProjectile(targ);
 243         }
 244 #endif
 245
 246         return true;
 247 }
 248
 249 void trigger_push_touch(entity this, entity toucher)
 250 {
 251         if (this.active == ACTIVE_NOT)
 252                 return;
 253
 254         if(this.team)
 255                 if(((this.spawnflags & 4) == 0) == (DIFF_TEAM(this, toucher)))
 256                         return;
 257
 258         EXACTTRIGGER_TOUCH(this, toucher);
 259
 260         noref bool success = jumppad_push(this, toucher);
 261
 262 #ifdef SVQC
 263         if (success && (this.spawnflags & PUSH_ONCE))
 264         {
 265                 settouch(this, func_null);
 266                 setthink(this, SUB_Remove);
 267                 this.nextthink = time;
 268         }
 269 #endif
 270 }
 271
 272 #ifdef SVQC
 273 void trigger_push_link(entity this);
 274 void trigger_push_updatelink(entity this);
 275 bool trigger_push_testorigin(entity e, entity targ, entity jp, vector org)
 276 {
 277         setorigin(e, org);
 278         tracetoss(e, e);
 279         if(trace_startsolid)
 280                 return false;
 281
 282         if(!jp.height)
 283         {
 284                 // since tracetoss starting from jumppad's origin often fails when target
 285                 // is very close to real destination, start it directly from target's
 286                 // origin instead
 287                 e.velocity_z = 0;
 288                 setorigin(e, targ.origin + stepheightvec);
 289                 tracetoss(e, e);
 290                 if(trace_startsolid)
 291                 {
 292                         setorigin(e, targ.origin + stepheightvec / 2);
 293                         tracetoss(e, e);
 294                         if(trace_startsolid)
 295                         {
 296                                 setorigin(e, targ.origin);
 297                                 tracetoss(e, e);
 298                                 if(trace_startsolid)
 299                                         return false;
 300                         }
 301                 }
 302         }
 303         return true;
 304 }
 305 #endif
 306 void trigger_push_findtarget(entity this)
 307 {
 308         // first calculate a typical start point for the jump
 309         vector org = (this.absmin + this.absmax) * 0.5;
 310         org.z = this.absmax.z - PL_MIN_CONST.z;
 311
 312         if (this.target)
 313         {
 314                 int n = 0;
 315 #ifdef SVQC
 316                 vector vel = '0 0 0';
 317 #endif
 318                 for(entity t = NULL; (t = find(t, targetname, this.target)); )
 319                 {
 320                         ++n;
 321 #ifdef SVQC
 322                         if(t.move_movetype != MOVETYPE_NONE)
 323                                 continue;
 324
 325                         entity e = spawn();
 326                         setsize(e, PL_MIN_CONST, PL_MAX_CONST);
 327                         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 328                         e.velocity = trigger_push_calculatevelocity(org, t, this.height);
 329                         vel = e.velocity;
 330                         vector best_target = '0 0 0';
 331                         vector best_org = '0 0 0';
 332                         vector best_vel = '0 0 0';
 333                         bool valid_best_target = false;
 334                         if (trigger_push_testorigin(e, t, this, org))
 335                         {
 336                                 best_target = trace_endpos;
 337                                 best_org = org;
 338                                 best_vel = e.velocity;
 339                                 valid_best_target = true;
 340                         }
 341
 342                         vector new_org;
 343                         vector dist = t.origin - org;
 344                         if (dist.x || dist.y) // if not perfectly vertical
 345                         {
 346                                 // test trajectory with different starting points, sometimes the trajectory
 347                                 // starting from the jumppad origin can't reach the real destination
 348                                 // and destination waypoint ends up near the jumppad itself
 349                                 vector flatdir = normalize(dist - eZ * dist.z);
 350                                 vector ofs = flatdir * 0.5 * min(fabs(this.absmax.x - this.absmin.x), fabs(this.absmax.y - this.absmin.y));
 351                                 new_org = org + ofs;
 352                                 e.velocity = trigger_push_calculatevelocity(new_org, t, this.height);
 353                                 vel = e.velocity;
 354                                 if (vdist(vec2(e.velocity), <, autocvar_sv_maxspeed))
 355                                         e.velocity = autocvar_sv_maxspeed * flatdir;
 356                                 if (trigger_push_testorigin(e, t, this, new_org) && (!valid_best_target || trace_endpos.z > best_target.z + 50))
 357                                 {
 358                                         best_target = trace_endpos;
 359                                         best_org = new_org;
 360                                         best_vel = vel;
 361                                         valid_best_target = true;
 362                                 }
 363                                 new_org = org - ofs;
 364                                 e.velocity = trigger_push_calculatevelocity(new_org, t, this.height);
 365                                 vel = e.velocity;
 366                                 if (vdist(vec2(e.velocity), <, autocvar_sv_maxspeed))
 367                                         e.velocity = autocvar_sv_maxspeed * flatdir;
 368                                 if (trigger_push_testorigin(e, t, this, new_org) && (!valid_best_target || trace_endpos.z > best_target.z + 50))
 369                                 {
 370                                         best_target = trace_endpos;
 371                                         best_org = new_org;
 372                                         best_vel = vel;
 373                                         valid_best_target = true;
 374                                 }
 375                         }
 376
 377                         if (valid_best_target)
 378                         {
 379                                 if (!(boxesoverlap(this.absmin, this.absmax + eZ * 50, best_target + PL_MIN_CONST, best_target + PL_MAX_CONST)))
 380                                 {
 381                                         float velxy = vlen(vec2(best_vel));
 382                                         float cost = vlen(vec2(t.origin - best_org)) / velxy;
 383                                         if(velxy < autocvar_sv_maxspeed)
 384                                                 velxy = autocvar_sv_maxspeed;
 385                                         cost += vlen(vec2(best_target - t.origin)) / velxy;
 386                                         waypoint_spawnforteleporter(this, best_target, cost, e);
 387                                 }
 388                         }
 389                         delete(e);
 390 #endif
 391                 }
 392
 393                 if(!n)
 394                 {
 395                         // no dest!
 396 #ifdef SVQC
 397                         objerror (this, "Jumppad with nonexistant target");
 398 #endif
 399                         return;
 400                 }
 401                 else if(n == 1)
 402                 {
 403                         // exactly one dest - bots love that
 404                         this.enemy = find(NULL, targetname, this.target);
 405                 }
 406                 else
 407                 {
 408                         // have to use random selection every single time
 409                         this.enemy = NULL;
 410                 }
 411         }
 412 #ifdef SVQC
 413         else
 414         {
 415                 entity e = spawn();
 416                 setsize(e, PL_MIN_CONST, PL_MAX_CONST);
 417                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 418                 setorigin(e, org);
 419                 e.velocity = this.movedir;
 420                 tracetoss(e, e);
 421                 if (!(boxesoverlap(this.absmin, this.absmax + eZ * 50, trace_endpos + PL_MIN_CONST, trace_endpos + PL_MAX_CONST)))
 422                         waypoint_spawnforteleporter(this, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity), e);
 423                 delete(e);
 424         }
 425
 426         defer(this, 0.1, trigger_push_updatelink);
 427 #endif
 428 }
 429
 430 #ifdef SVQC
 431 float trigger_push_send(entity this, entity to, float sf)
 432 {
 433         WriteHeader(MSG_ENTITY, ENT_CLIENT_TRIGGER_PUSH);
 434
 435         WriteByte(MSG_ENTITY, this.team);
 436         WriteInt24_t(MSG_ENTITY, this.spawnflags);
 437         WriteByte(MSG_ENTITY, this.active);
 438         WriteCoord(MSG_ENTITY, this.height);
 439
 440         WriteCoord(MSG_ENTITY, this.movedir_x);
 441         WriteCoord(MSG_ENTITY, this.movedir_y);
 442         WriteCoord(MSG_ENTITY, this.movedir_z);
 443
 444         trigger_common_write(this, true);
 445
 446         return true;
 447 }
 448
 449 void trigger_push_updatelink(entity this)
 450 {
 451         this.SendFlags |= 1;
 452 }
 453
 454 void trigger_push_link(entity this)
 455 {
 456         trigger_link(this, trigger_push_send);
 457 }
 458
 459 /*
 460  * ENTITY PARAMETERS:
 461  *
 462  *   target:  target of jump
 463  *   height:  the absolute value is the height of the highest point of the jump
 464  *            trajectory above the higher one of the player and the target.
 465  *            the sign indicates whether the highest point is INSIDE (positive)
 466  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 467  *            positive values for targets mounted on the floor, and use negative
 468  *            values to target a point on the ceiling.
 469  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 470  */
 471 spawnfunc(trigger_push)
 472 {
 473         SetMovedir(this);
 474
 475         trigger_init(this);
 476
 477         this.active = ACTIVE_ACTIVE;
 478         this.use = trigger_push_use;
 479         settouch(this, trigger_push_touch);
 480
 481         // normal push setup
 482         if (!this.speed)
 483                 this.speed = 1000;
 484         this.movedir = this.movedir * this.speed * 10;
 485
 486         if (!this.noise)
 487                 this.noise = "misc/jumppad.wav";
 488         precache_sound (this.noise);
 489
 490         trigger_push_link(this); // link it now
 491
 492         // this must be called to spawn the teleport waypoints for bots
 493         InitializeEntity(this, trigger_push_findtarget, INITPRIO_FINDTARGET);
 494 }
 495
 496
 497 bool target_push_send(entity this, entity to, float sf)
 498 {
 499         WriteHeader(MSG_ENTITY, ENT_CLIENT_TARGET_PUSH);
 500
 501         WriteByte(MSG_ENTITY, this.cnt);
 502         WriteString(MSG_ENTITY, this.targetname);
 503         WriteCoord(MSG_ENTITY, this.origin_x);
 504         WriteCoord(MSG_ENTITY, this.origin_y);
 505         WriteCoord(MSG_ENTITY, this.origin_z);
 506
 507         WriteAngle(MSG_ENTITY, this.angles_x);
 508         WriteAngle(MSG_ENTITY, this.angles_y);
 509         WriteAngle(MSG_ENTITY, this.angles_z);
 510
 511         return true;
 512 }
 513
 514 void target_push_use(entity this, entity actor, entity trigger)
 515 {
 516         if(trigger.classname == "trigger_push" || trigger == this)
 517                 return; // WTF, why is this a thing
 518
 519         jumppad_push(this, actor);
 520 }
 521
 522 void target_push_link(entity this)
 523 {
 524         BITSET_ASSIGN(this.effects, EF_NODEPTHTEST);
 525         Net_LinkEntity(this, false, 0, target_push_send);
 526         //this.SendFlags |= 1; // update
 527 }
 528
 529 void target_push_init(entity this)
 530 {
 531         this.mangle = this.angles;
 532         setorigin(this, this.origin);
 533         target_push_link(this);
 534 }
 535
 536 void target_push_init2(entity this)
 537 {
 538         if(this.target && this.target != "") // we have an old style pusher!
 539         {
 540                 InitializeEntity(this, trigger_push_findtarget, INITPRIO_FINDTARGET);
 541                 this.use = target_push_use;
 542         }
 543
 544         target_push_init(this); // normal push target behaviour can be combined with a legacy pusher?
 545 }
 546
 547 spawnfunc(target_push) { target_push_init2(this); }
 548 spawnfunc(info_notnull) { target_push_init(this); }
 549 spawnfunc(target_position) { target_push_init(this); }
 550
 551 #elif defined(CSQC)
 552
 553 NET_HANDLE(ENT_CLIENT_TRIGGER_PUSH, bool isnew)
 554 {
 555         this.classname = "jumppad";
 556         int mytm = ReadByte(); if(mytm) { this.team = mytm - 1; }
 557         this.spawnflags = ReadInt24_t();
 558         this.active = ReadByte();
 559         this.height = ReadCoord();
 560
 561         this.movedir_x = ReadCoord();
 562         this.movedir_y = ReadCoord();
 563         this.movedir_z = ReadCoord();
 564
 565         trigger_common_read(this, true);
 566
 567         this.entremove = trigger_remove_generic;
 568         this.solid = SOLID_TRIGGER;
 569         settouch(this, trigger_push_touch);
 570         this.move_time = time;
 571         defer(this, 0.25, trigger_push_findtarget);
 572
 573         return true;
 574 }
 575
 576 void target_push_remove(entity this)
 577 {
 578         //if(this.classname)
 579                 //strunzone(this.classname);
 580         //this.classname = string_null;
 581
 582         if(this.targetname)
 583                 strunzone(this.targetname);
 584         this.targetname = string_null;
 585 }
 586
 587 NET_HANDLE(ENT_CLIENT_TARGET_PUSH, bool isnew)
 588 {
 589         this.classname = "push_target";
 590         this.cnt = ReadByte();
 591         this.targetname = strzone(ReadString());
 592         this.origin_x = ReadCoord();
 593         this.origin_y = ReadCoord();
 594         this.origin_z = ReadCoord();
 595
 596         this.angles_x = ReadAngle();
 597         this.angles_y = ReadAngle();
 598         this.angles_z = ReadAngle();
 599
 600         return = true;
 601
 602         setorigin(this, this.origin);
 603
 604         this.drawmask = MASK_NORMAL;
 605         this.entremove = target_push_remove;
 606 }
 607 #endif