qcsrc/common/turrets/sv_turrets.qc

   1 #include "sv_turrets.qh"
   2 #ifdef SVQC
   3 #include <server/autocvars.qh>
   4
   5 // Generic aiming
   6 vector turret_aim_generic(entity this)
   7 {
   8
   9         vector pre_pos, prep;
  10         float distance, impact_time = 0, i, mintime;
  11
  12         turret_tag_fire_update(this);
  13
  14         if(this.aim_flags & TFL_AIM_SIMPLE)
  15                 return real_origin(this.enemy);
  16
  17         mintime = max(this.attack_finished_single[0] - time,0) + sys_frametime;
  18
  19         // Baseline
  20         pre_pos = real_origin(this.enemy);
  21
  22         // Lead?
  23         if (this.aim_flags & TFL_AIM_LEAD)
  24         {
  25                 if (this.aim_flags & TFL_AIM_SHOTTIMECOMPENSATE)           // Need to conpensate for shot traveltime
  26                 {
  27                         prep = pre_pos;
  28
  29                         distance = vlen(prep - this.tur_shotorg);
  30                         impact_time = distance / this.shot_speed;
  31
  32                         prep = pre_pos + (this.enemy.velocity * (impact_time + mintime));
  33
  34                         if(this.aim_flags & TFL_AIM_ZPREDICT)
  35                         if(!IS_ONGROUND(this.enemy))
  36                         if(this.enemy.move_movetype == MOVETYPE_WALK || this.enemy.move_movetype == MOVETYPE_TOSS || this.enemy.move_movetype == MOVETYPE_BOUNCE)
  37                         {
  38                                 float vz;
  39                                 prep_z = pre_pos_z;
  40                                 vz = this.enemy.velocity_z;
  41                                 for(i = 0; i < impact_time; i += sys_frametime)
  42                                 {
  43                                         vz = vz - (autocvar_sv_gravity * sys_frametime);
  44                                         prep_z = prep_z + vz * sys_frametime;
  45                                 }
  46                         }
  47                         pre_pos = prep;
  48                 }
  49                 else
  50                         pre_pos = pre_pos + this.enemy.velocity * mintime;
  51         }
  52
  53         if(this.aim_flags & TFL_AIM_SPLASH)
  54         {
  55                 //tracebox(pre_pos + '0 0 32',this.enemy.mins,this.enemy.maxs,pre_pos -'0 0 64',MOVE_WORLDONLY,this.enemy);
  56                 traceline(pre_pos + '0 0 32',pre_pos -'0 0 64',MOVE_WORLDONLY,this.enemy);
  57                 if(trace_fraction != 1.0)
  58                         pre_pos = trace_endpos;
  59         }
  60
  61         return pre_pos;
  62 }
  63
  64 float turret_targetscore_support(entity _turret,entity _target)
  65 {
  66         float score;            // Total score
  67         float s_score = 0, d_score;
  68
  69         if (_turret.enemy == _target) s_score = 1;
  70
  71         d_score = min(_turret.target_range_optimal,tvt_dist) / max(_turret.target_range_optimal,tvt_dist);
  72
  73         score = (d_score * _turret.target_select_rangebias) +
  74                         (s_score * _turret.target_select_samebias);
  75
  76         return score;
  77 }
  78
  79 /*
  80 * Generic bias aware score system.
  81 */
  82 float turret_targetscore_generic(entity _turret, entity _target)
  83 {
  84         float d_dist;      // Defendmode Distance
  85         float score;            // Total score
  86         float d_score;    // Distance score
  87         float a_score;    // Angular score
  88         float m_score = 0;  // missile score
  89         float p_score = 0;  // player score
  90         float ikr;                // ideal kill range
  91
  92         if (_turret.tur_defend)
  93         {
  94                 d_dist = vlen(real_origin(_target) - _turret.tur_defend.origin);
  95                 ikr = vlen(_turret.origin - _turret.tur_defend.origin);
  96                 d_score = 1 - d_dist / _turret.target_range;
  97         }
  98         else
  99         {
 100                 // Make a normlized value base on the targets distance from our optimal killzone
 101                 ikr = _turret.target_range_optimal;
 102                 d_score = min(ikr, tvt_dist) / max(ikr, tvt_dist);
 103         }
 104
 105         a_score = 1 - tvt_thadf / _turret.aim_maxrotate;
 106
 107         if ((_turret.target_select_missilebias > 0) && (_target.flags & FL_PROJECTILE))
 108                 m_score = 1;
 109
 110         if ((_turret.target_select_playerbias > 0) && IS_CLIENT(_target))
 111                 p_score = 1;
 112
 113         d_score = max(d_score, 0);
 114         a_score = max(a_score, 0);
 115         m_score = max(m_score, 0);
 116         p_score = max(p_score, 0);
 117
 118         score = (d_score * _turret.target_select_rangebias) +
 119                         (a_score * _turret.target_select_anglebias) +
 120                         (m_score * _turret.target_select_missilebias) +
 121                         (p_score * _turret.target_select_playerbias);
 122
 123         if(vdist((_turret.tur_shotorg - real_origin(_target)), >, _turret.target_range))
 124         {
 125                 //dprint("Wtf?\n");
 126                 score *= 0.001;
 127         }
 128
 129 #ifdef TURRET_DEBUG
 130         string sd,sa,sm,sp,ss;
 131         string sdt,sat,smt,spt;
 132
 133         sd = ftos(d_score);
 134         d_score *= _turret.target_select_rangebias;
 135         sdt = ftos(d_score);
 136
 137         //sv = ftos(v_score);
 138         //v_score *= _turret.target_select_samebias;
 139         //svt = ftos(v_score);
 140
 141         sa = ftos(a_score);
 142         a_score *= _turret.target_select_anglebias;
 143         sat = ftos(a_score);
 144
 145         sm = ftos(m_score);
 146         m_score *= _turret.target_select_missilebias;
 147         smt = ftos(m_score);
 148
 149         sp = ftos(p_score);
 150         p_score *= _turret.target_select_playerbias;
 151         spt = ftos(p_score);
 152
 153
 154         ss = ftos(score);
 155         bprint("^3Target scores^7 \[  ",_turret.netname, "  \] ^3for^7 \[  ", _target.netname,"  \]\n");
 156         bprint("^5Range:\[  ",sd,  "  \]^2+bias:\[  ",sdt,"  \]\n");
 157         bprint("^5Angle:\[  ",sa,  "  \]^2+bias:\[  ",sat,"  \]\n");
 158         bprint("^5Missile:\[  ",sm,"  \]^2+bias:\[  ",smt,"  \]\n");
 159         bprint("^5Player:\[  ",sp, "  \]^2+bias:\[  ",spt,"  \]\n");
 160         bprint("^3Total (w/bias):\[^1",ss,"\]\n");
 161
 162 #endif
 163
 164         return score;
 165 }
 166
 167 // Generic damage handling
 168 void turret_hide(entity this)
 169 {
 170         this.effects   |= EF_NODRAW;
 171         this.nextthink = time + this.respawntime - 0.2;
 172         setthink(this, turret_respawn);
 173 }
 174
 175 void turret_die(entity this)
 176 {
 177         this.deadflag             = DEAD_DEAD;
 178         this.tur_head.deadflag = this.deadflag;
 179
 180 // Unsolidify and hide real parts
 181         this.solid                       = SOLID_NOT;
 182         this.tur_head.solid      = this.solid;
 183
 184         this.event_damage                 = func_null;
 185         this.event_heal = func_null;
 186         this.takedamage                  = DAMAGE_NO;
 187
 188         SetResourceExplicit(this, RES_HEALTH, 0);
 189
 190 // Go boom
 191         //RadiusDamage (this,this, min(this.ammo,50),min(this.ammo,50) * 0.25,250,NULL,min(this.ammo,50)*5,DEATH_TURRET,NULL);
 192
 193         Turret tur = get_turretinfo(this.m_id);
 194         if(this.damage_flags & TFL_DMG_DEATH_NORESPAWN)
 195         {
 196                 // do a simple explosion effect here, since CSQC can't do it on a to-be-removed entity
 197                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 198                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 199
 200                 tur.tr_death(tur, this);
 201
 202                 delete(this.tur_head);
 203                 delete(this);
 204         }
 205         else
 206         {
 207                 // Setup respawn
 208                 this.SendFlags    |= TNSF_STATUS;
 209                 this.nextthink   = time + 0.2;
 210                 setthink(this, turret_hide);
 211
 212                 tur.tr_death(tur, this);
 213         }
 214 }
 215
 216 void turret_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector vforce)
 217 {
 218         // Enough already!
 219         if(this.deadflag == DEAD_DEAD)
 220                 return;
 221
 222         // Inactive turrets take no damage. (hm..)
 223         if(!this.active)
 224                 return;
 225
 226         if(SAME_TEAM(this, attacker))
 227         {
 228                 if(autocvar_g_friendlyfire)
 229                         damage = damage * autocvar_g_friendlyfire;
 230                 else
 231                         return;
 232         }
 233
 234         TakeResource(this, RES_HEALTH, damage);
 235
 236         // thorw head slightly off aim when hit?
 237         if (this.damage_flags & TFL_DMG_HEADSHAKE)
 238         {
 239                 this.tur_head.angles_x = this.tur_head.angles_x + (-0.5 + random()) * damage;
 240                 this.tur_head.angles_y = this.tur_head.angles_y + (-0.5 + random()) * damage;
 241
 242                 this.SendFlags  |= TNSF_ANG;
 243         }
 244
 245         if (this.turret_flags & TUR_FLAG_MOVE)
 246                 this.velocity = this.velocity + vforce;
 247
 248         if (GetResource(this, RES_HEALTH) <= 0)
 249         {
 250                 this.event_damage                 = func_null;
 251                 this.tur_head.event_damage = func_null;
 252                 this.event_heal = func_null;
 253                 this.tur_head.event_heal = func_null;
 254                 this.takedamage                  = DAMAGE_NO;
 255                 this.nextthink = time;
 256                 setthink(this, turret_die);
 257         }
 258
 259         this.SendFlags  |= TNSF_STATUS;
 260 }
 261
 262 bool turret_heal(entity targ, entity inflictor, float amount, float limit)
 263 {
 264         float true_limit = ((limit != RES_LIMIT_NONE) ? limit : targ.max_health);
 265         if(GetResource(targ, RES_HEALTH) <= 0 || GetResource(targ, RES_HEALTH) >= true_limit)
 266                 return false;
 267
 268         GiveResourceWithLimit(targ, RES_HEALTH, amount, true_limit);
 269         targ.SendFlags |= TNSF_STATUS;
 270         return true;
 271 }
 272
 273 void turret_think(entity this);
 274 void turret_respawn(entity this)
 275 {
 276         // Make sure all parts belong to the same team since
 277         // this function doubles as "teamchange" function.
 278         this.tur_head.team      = this.team;
 279         this.effects                       &= ~EF_NODRAW;
 280         this.deadflag                           = DEAD_NO;
 281         this.effects                            = EF_LOWPRECISION;
 282         this.solid                                      = SOLID_BBOX;
 283         this.takedamage                         = DAMAGE_AIM;
 284         this.event_damage                       = turret_damage;
 285         this.event_heal                         = turret_heal;
 286         this.avelocity                          = '0 0 0';
 287         this.tur_head.avelocity         = this.avelocity;
 288         this.tur_head.angles            = this.idle_aim;
 289         SetResourceExplicit(this, RES_HEALTH, this.max_health);
 290         this.enemy                                      = NULL;
 291         this.volly_counter                      = this.shot_volly;
 292         this.ammo                                       = this.ammo_max;
 293
 294         this.nextthink = time + this.ticrate;
 295         setthink(this, turret_think);
 296
 297         this.SendFlags = TNSF_FULL_UPDATE;
 298
 299         Turret tur = get_turretinfo(this.m_id);
 300         tur.tr_setup(tur, this);
 301 }
 302
 303
 304 // Main functions
 305 #define cvar_base "g_turrets_unit_"
 306 .float clientframe;
 307 void turrets_setframe(entity this, float _frame, float client_only)
 308 {
 309         if((client_only ? this.clientframe : this.frame ) != _frame)
 310         {
 311                 this.SendFlags |= TNSF_ANIM;
 312                 this.anim_start_time = time;
 313         }
 314
 315          if(client_only)
 316                 this.clientframe = _frame;
 317         else
 318                 this.frame = _frame;
 319
 320 }
 321
 322 bool turret_send(entity this, entity to, float sf)
 323 {
 324
 325         WriteHeader(MSG_ENTITY, ENT_CLIENT_TURRET);
 326         WriteByte(MSG_ENTITY, sf);
 327         if(sf & TNSF_SETUP)
 328         {
 329                 WriteByte(MSG_ENTITY, this.m_id);
 330
 331                 WriteVector(MSG_ENTITY, this.origin);
 332
 333                 WriteAngle(MSG_ENTITY, this.angles_x);
 334                 WriteAngle(MSG_ENTITY, this.angles_y);
 335         }
 336
 337         if(sf & TNSF_ANG)
 338         {
 339                 WriteShort(MSG_ENTITY, rint(this.tur_head.angles_x));
 340                 WriteShort(MSG_ENTITY, rint(this.tur_head.angles_y));
 341         }
 342
 343         if(sf & TNSF_AVEL)
 344         {
 345                 WriteShort(MSG_ENTITY, rint(this.tur_head.avelocity_x));
 346                 WriteShort(MSG_ENTITY, rint(this.tur_head.avelocity_y));
 347         }
 348
 349         if(sf & TNSF_MOVE)
 350         {
 351                 WriteVector(MSG_ENTITY, this.origin);
 352
 353                 WriteVector(MSG_ENTITY, this.velocity);
 354
 355                 WriteShort(MSG_ENTITY, rint(this.angles_y));
 356         }
 357
 358         if(sf & TNSF_ANIM)
 359         {
 360                 WriteCoord(MSG_ENTITY, this.anim_start_time);
 361                 WriteByte(MSG_ENTITY, this.frame);
 362         }
 363
 364         if(sf & TNSF_STATUS)
 365         {
 366                 WriteByte(MSG_ENTITY, this.team);
 367
 368                 if(GetResource(this, RES_HEALTH) <= 0)
 369                         WriteByte(MSG_ENTITY, 0);
 370                 else
 371                         WriteByte(MSG_ENTITY, ceil((GetResource(this, RES_HEALTH) / this.max_health) * 255));
 372         }
 373
 374         return true;
 375 }
 376
 377 void load_unit_settings(entity ent, bool is_reload)
 378 {
 379         string unitname = ent.netname;
 380         string sbase;
 381
 382         if (ent == NULL)
 383                 return;
 384
 385         if(!ent.turret_scale_damage)    ent.turret_scale_damage = 1;
 386         if(!ent.turret_scale_range)             ent.turret_scale_range  = 1;
 387         if(!ent.turret_scale_refire)    ent.turret_scale_refire = 1;
 388         if(!ent.turret_scale_ammo)              ent.turret_scale_ammo   = 1;
 389         if(!ent.turret_scale_aim)               ent.turret_scale_aim     = 1;
 390         if(!ent.turret_scale_health)    ent.turret_scale_health = 1;
 391         if(!ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
 392
 393         sbase = strcat(cvar_base,unitname);
 394         if (is_reload)
 395         {
 396                 ent.enemy = NULL;
 397                 ent.tur_head.avelocity = '0 0 0';
 398
 399                 ent.tur_head.angles = '0 0 0';
 400         }
 401
 402         SetResourceExplicit(ent, RES_HEALTH, cvar(strcat(sbase,"_health")) * ent.turret_scale_health);
 403         ent.respawntime = cvar(strcat(sbase,"_respawntime")) * ent.turret_scale_respawn;
 404
 405         ent.shot_dmg             = cvar(strcat(sbase,"_shot_dmg")) * ent.turret_scale_damage;
 406         ent.shot_refire   = cvar(strcat(sbase,"_shot_refire")) * ent.turret_scale_refire;
 407         ent.shot_radius   = cvar(strcat(sbase,"_shot_radius")) * ent.turret_scale_damage;
 408         ent.shot_speed          = cvar(strcat(sbase,"_shot_speed"));
 409         ent.shot_spread   = cvar(strcat(sbase,"_shot_spread"));
 410         ent.shot_force          = cvar(strcat(sbase,"_shot_force")) * ent.turret_scale_damage;
 411         ent.shot_volly          = cvar(strcat(sbase,"_shot_volly"));
 412         ent.shot_volly_refire = cvar(strcat(sbase,"_shot_volly_refire")) * ent.turret_scale_refire;
 413
 414         ent.target_range                 = cvar(strcat(sbase,"_target_range")) * ent.turret_scale_range;
 415         ent.target_range_min     = cvar(strcat(sbase,"_target_range_min")) * ent.turret_scale_range;
 416         ent.target_range_optimal = cvar(strcat(sbase,"_target_range_optimal")) * ent.turret_scale_range;
 417         //ent.target_range_fire = cvar(strcat(sbase,"_target_range_fire")) * ent.turret_scale_range;
 418
 419         ent.target_select_rangebias = cvar(strcat(sbase,"_target_select_rangebias"));
 420         ent.target_select_samebias  = cvar(strcat(sbase,"_target_select_samebias"));
 421         ent.target_select_anglebias = cvar(strcat(sbase,"_target_select_anglebias"));
 422         ent.target_select_missilebias = cvar(strcat(sbase,"_target_select_missilebias"));
 423         ent.target_select_playerbias = cvar(strcat(sbase,"_target_select_playerbias"));
 424         //ent.target_select_fov = cvar(cvar_gets(sbase,"_target_select_fov"));
 425
 426         ent.ammo_max     = cvar(strcat(sbase,"_ammo_max")) * ent.turret_scale_ammo;
 427         ent.ammo_recharge = cvar(strcat(sbase,"_ammo_recharge")) * ent.turret_scale_ammo;
 428
 429         ent.aim_firetolerance_dist = cvar(strcat(sbase,"_aim_firetolerance_dist"));
 430         ent.aim_speed   = cvar(strcat(sbase,"_aim_speed")) * ent.turret_scale_aim;
 431         ent.aim_maxrotate  = cvar(strcat(sbase,"_aim_maxrot"));
 432         ent.aim_maxpitch = cvar(strcat(sbase,"_aim_maxpitch"));
 433
 434         ent.track_type          = cvar(strcat(sbase,"_track_type"));
 435         ent.track_accel_pitch = cvar(strcat(sbase,"_track_accel_pitch"));
 436         ent.track_accel_rotate  = cvar(strcat(sbase,"_track_accel_rot"));
 437         ent.track_blendrate  = cvar(strcat(sbase,"_track_blendrate"));
 438
 439         if(is_reload) {
 440                 Turret tur = get_turretinfo(ent.m_id);
 441                 tur.tr_setup(tur, ent);
 442         }
 443 }
 444
 445 void turret_projectile_explode(entity this)
 446 {
 447
 448         this.takedamage = DAMAGE_NO;
 449         this.event_damage = func_null;
 450 #ifdef TURRET_DEBUG
 451         float d;
 452         d = RadiusDamage (this, this.owner, this.owner.shot_dmg, 0, this.owner.shot_radius, this, NULL, this.owner.shot_force, this.totalfrags, DMG_NOWEP, NULL);
 453         this.owner.tur_debug_dmg_t_h = this.owner.tur_debug_dmg_t_h + d;
 454         this.owner.tur_debug_dmg_t_f = this.owner.tur_debug_dmg_t_f + this.owner.shot_dmg;
 455 #else
 456         RadiusDamage (this, this.realowner, this.owner.shot_dmg, 0, this.owner.shot_radius, this, NULL, this.owner.shot_force, this.totalfrags, DMG_NOWEP, NULL);
 457 #endif
 458         delete(this);
 459 }
 460
 461 void turret_projectile_touch(entity this, entity toucher)
 462 {
 463         PROJECTILE_TOUCH(this, toucher);
 464         turret_projectile_explode(this);
 465 }
 466
 467 void turret_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector vforce)
 468 {
 469         this.velocity  += vforce;
 470         TakeResource(this, RES_HEALTH, damage);
 471         //this.realowner = attacker; // Dont change realowner, it does not make much sense for turrets
 472         if(GetResource(this, RES_HEALTH) <= 0)
 473                 W_PrepareExplosionByDamage(this, this.owner, turret_projectile_explode);
 474 }
 475
 476 entity turret_projectile(entity actor, Sound _snd, float _size, float _health, float _death, float _proj_type, float _cull, float _cli_anim)
 477 {
 478         TC(Sound, _snd);
 479         entity proj;
 480
 481         sound (actor, CH_WEAPON_A, _snd, VOL_BASE, ATTEN_NORM);
 482         proj                             = spawn ();
 483         setorigin(proj, actor.tur_shotorg);
 484         setsize(proj, '-0.5 -0.5 -0.5' * _size, '0.5 0.5 0.5' * _size);
 485         proj.owner                = actor;
 486         proj.realowner    = actor;
 487         proj.bot_dodge    = true;
 488         proj.bot_dodgerating = actor.shot_dmg;
 489         setthink(proj, turret_projectile_explode);
 490         settouch(proj, turret_projectile_touch);
 491         proj.nextthink    = time + 9;
 492         set_movetype(proj, MOVETYPE_FLYMISSILE);
 493         proj.velocity           = normalize(actor.tur_shotdir_updated + randomvec() * actor.shot_spread) * actor.shot_speed;
 494         proj.flags = FL_PROJECTILE;
 495         IL_PUSH(g_projectiles, proj);
 496         IL_PUSH(g_bot_dodge, proj);
 497         proj.enemy                = actor.enemy;
 498         proj.totalfrags  = _death;
 499         PROJECTILE_MAKETRIGGER(proj);
 500         if(_health)
 501         {
 502                 SetResourceExplicit(proj, RES_HEALTH, _health);
 503                 proj.takedamage  = DAMAGE_YES;
 504                 proj.event_damage  = turret_projectile_damage;
 505         }
 506         else
 507                 proj.flags |= FL_NOTARGET;
 508
 509         CSQCProjectile(proj, _cli_anim, _proj_type, _cull);
 510
 511         return proj;
 512 }
 513
 514 /**
 515 ** updates enemy distances, predicted impact point/time
 516 ** and updated aim<->predict impact distance.
 517 **/
 518 void turret_do_updates(entity t_turret)
 519 {
 520         vector enemy_pos = real_origin(t_turret.enemy);
 521
 522         turret_tag_fire_update(t_turret);
 523
 524         t_turret.tur_shotdir_updated = v_forward;
 525         t_turret.tur_dist_enemy = vlen(t_turret.tur_shotorg - enemy_pos);
 526         t_turret.tur_dist_aimpos = vlen(t_turret.tur_shotorg - t_turret.tur_aimpos);
 527
 528         /*if((t_turret.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (t_turret.enemy))
 529         {
 530                 oldpos = t_turret.enemy.origin;
 531                 setorigin(t_turret.enemy, t_turret.tur_aimpos);
 532                 tracebox(t_turret.tur_shotorg, '-1 -1 -1', '1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
 533                 setorigin(t_turret.enemy, oldpos);
 534
 535                 if(trace_ent == t_turret.enemy)
 536                         t_turret.tur_dist_impact_to_aimpos = 0;
 537                 else
 538                         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos);
 539         }
 540         else*/
 541                 tracebox(t_turret.tur_shotorg, '-1 -1 -1','1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
 542
 543         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos) - (vlen(t_turret.enemy.maxs - t_turret.enemy.mins) * 0.5);
 544         t_turret.tur_impactent                   = trace_ent;
 545         t_turret.tur_impacttime                 = vlen(t_turret.tur_shotorg - trace_endpos) / t_turret.shot_speed;
 546 }
 547
 548 /**
 549 ** Handles head rotation according to
 550 ** the units .track_type and .track_flags
 551 **/
 552 .float turret_framecounter;
 553 void turret_track(entity this)
 554 {
 555         vector target_angle; // This is where we want to aim
 556         vector move_angle;   // This is where we can aim
 557         float f_tmp;
 558         vector v1, v2;
 559         v1 = this.tur_head.angles;
 560         v2 = this.tur_head.avelocity;
 561
 562         if (this.track_flags == TFL_TRACK_NO)
 563                 return;
 564
 565         if(!this.active)
 566                 target_angle = this.idle_aim - ('1 0 0' * this.aim_maxpitch);
 567         else if (this.enemy == NULL)
 568         {
 569                 if(time > this.lip)
 570                         target_angle = this.idle_aim + this.angles;
 571                 else
 572                         target_angle = vectoangles(normalize(this.tur_aimpos - this.tur_shotorg));
 573         }
 574         else
 575         {
 576                 target_angle = vectoangles(normalize(this.tur_aimpos - this.tur_shotorg));
 577         }
 578
 579         this.tur_head.angles_x = anglemods(this.tur_head.angles_x);
 580         this.tur_head.angles_y = anglemods(this.tur_head.angles_y);
 581
 582         // Find the diffrence between where we currently aim and where we want to aim
 583         //move_angle = target_angle - (this.angles + this.tur_head.angles);
 584         //move_angle = shortangle_vxy(move_angle,(this.angles + this.tur_head.angles));
 585
 586         move_angle = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(this.angles), AnglesTransform_FromAngles(target_angle))) - this.tur_head.angles;
 587         move_angle = shortangle_vxy(move_angle, this.tur_head.angles);
 588
 589         switch(this.track_type)
 590         {
 591                 case TFL_TRACKTYPE_STEPMOTOR:
 592                         f_tmp = this.aim_speed * this.ticrate; // dgr/sec -> dgr/tic
 593                         if (this.track_flags & TFL_TRACK_PITCH)
 594                         {
 595                                 this.tur_head.angles_x += bound(-f_tmp,move_angle_x, f_tmp);
 596                                 if(this.tur_head.angles_x > this.aim_maxpitch)
 597                                         this.tur_head.angles_x = this.aim_maxpitch;
 598
 599                                 if(this.tur_head.angles_x  < -this.aim_maxpitch)
 600                                         this.tur_head.angles_x = this.aim_maxpitch;
 601                         }
 602
 603                         if (this.track_flags & TFL_TRACK_ROTATE)
 604                         {
 605                                 this.tur_head.angles_y += bound(-f_tmp, move_angle_y, f_tmp);
 606                                 if(this.tur_head.angles_y > this.aim_maxrotate)
 607                                         this.tur_head.angles_y = this.aim_maxrotate;
 608
 609                                 if(this.tur_head.angles_y  < -this.aim_maxrotate)
 610                                         this.tur_head.angles_y = this.aim_maxrotate;
 611                         }
 612
 613                         // CSQC
 614                         this.SendFlags  |= TNSF_ANG;
 615
 616                         return;
 617
 618                 case TFL_TRACKTYPE_FLUIDINERTIA:
 619                         f_tmp = this.aim_speed * this.ticrate; // dgr/sec -> dgr/tic
 620                         move_angle_x = bound(-this.aim_speed, move_angle_x * this.track_accel_pitch * f_tmp, this.aim_speed);
 621                         move_angle_y = bound(-this.aim_speed, move_angle_y * this.track_accel_rotate * f_tmp, this.aim_speed);
 622                         move_angle = (this.tur_head.avelocity * this.track_blendrate) + (move_angle * (1 - this.track_blendrate));
 623                         break;
 624
 625                 case TFL_TRACKTYPE_FLUIDPRECISE:
 626
 627                         move_angle_y = bound(-this.aim_speed, move_angle_y, this.aim_speed);
 628                         move_angle_x = bound(-this.aim_speed, move_angle_x, this.aim_speed);
 629
 630                         break;
 631         }
 632
 633         //  pitch
 634         if (this.track_flags & TFL_TRACK_PITCH)
 635         {
 636                 this.tur_head.avelocity_x = move_angle_x;
 637                 if((this.tur_head.angles_x + this.tur_head.avelocity_x * this.ticrate) > this.aim_maxpitch)
 638                 {
 639                         this.tur_head.avelocity_x = 0;
 640                         this.tur_head.angles_x = this.aim_maxpitch;
 641
 642                         this.SendFlags  |= TNSF_ANG;
 643                 }
 644
 645                 if((this.tur_head.angles_x + this.tur_head.avelocity_x * this.ticrate) < -this.aim_maxpitch)
 646                 {
 647                         this.tur_head.avelocity_x = 0;
 648                         this.tur_head.angles_x = -this.aim_maxpitch;
 649
 650                         this.SendFlags  |= TNSF_ANG;
 651                 }
 652         }
 653
 654         //  rot
 655         if (this.track_flags & TFL_TRACK_ROTATE)
 656         {
 657                 this.tur_head.avelocity_y = move_angle_y;
 658
 659                 if((this.tur_head.angles_y + this.tur_head.avelocity_y * this.ticrate) > this.aim_maxrotate)
 660                 {
 661                         this.tur_head.avelocity_y = 0;
 662                         this.tur_head.angles_y = this.aim_maxrotate;
 663
 664                         this.SendFlags  |= TNSF_ANG;
 665                 }
 666
 667                 if((this.tur_head.angles_y + this.tur_head.avelocity_y * this.ticrate) < -this.aim_maxrotate)
 668                 {
 669                         this.tur_head.avelocity_y = 0;
 670                         this.tur_head.angles_y = -this.aim_maxrotate;
 671
 672                         this.SendFlags  |= TNSF_ANG;
 673                 }
 674         }
 675
 676         this.SendFlags  |= TNSF_AVEL;
 677
 678         // Force a angle update every 10'th frame
 679         this.turret_framecounter += 1;
 680         if(this.turret_framecounter >= 10)
 681         {
 682                 this.SendFlags |= TNSF_ANG;
 683                 this.turret_framecounter = 0;
 684         }
 685 }
 686
 687 /*
 688  + TFL_TARGETSELECT_NO
 689  + TFL_TARGETSELECT_LOS
 690  + TFL_TARGETSELECT_PLAYERS
 691  + TFL_TARGETSELECT_MISSILES
 692  + TFL_TARGETSELECT_VEHICLES
 693  - TFL_TARGETSELECT_TRIGGERTARGET
 694  + TFL_TARGETSELECT_ANGLELIMITS
 695  + TFL_TARGETSELECT_RANGELIMITS
 696  + TFL_TARGETSELECT_TEAMCHECK
 697  - TFL_TARGETSELECT_NOBUILTIN
 698  + TFL_TARGETSELECT_OWNTEAM
 699 */
 700
 701 /**
 702 ** Evaluate a entity for target valitity based on validate_flags
 703 ** NOTE: the caller must check takedamage before calling this, to inline this check.
 704 **/
 705 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
 706 {
 707         vector v_tmp;
 708
 709         //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
 710         //      return -0.5;
 711
 712         if(!e_target)
 713                 return -2;
 714
 715         if(e_target.owner == e_turret)
 716                 return -0.5;
 717
 718         if(!checkpvs(e_target.origin, e_turret))
 719                 return -1;
 720
 721         if(e_target.alpha != 0 && e_target.alpha <= 0.3)
 722                 return -1;
 723
 724         if(MUTATOR_CALLHOOK(TurretValidateTarget, e_turret, e_target, validate_flags))
 725                 return M_ARGV(3, float);
 726
 727         if (validate_flags & TFL_TARGETSELECT_NO)
 728                 return -4;
 729
 730         // If only this was used more..
 731         if (e_target.flags & FL_NOTARGET)
 732                 return -5;
 733
 734         // Cant touch this
 735         if (GetResource(e_target, RES_HEALTH) <= 0)
 736                 return -6;
 737         else if (STAT(FROZEN, e_target))
 738                 return -6;
 739
 740         // vehicle
 741         if(IS_VEHICLE(e_target))
 742         {
 743                 if ((validate_flags & TFL_TARGETSELECT_VEHICLES) && !e_target.owner)
 744                         return -7;
 745         }
 746
 747         // player
 748         if (IS_CLIENT(e_target))
 749         {
 750                 if(!(validate_flags & TFL_TARGETSELECT_PLAYERS))
 751                         return -7;
 752
 753                 if (IS_DEAD(e_target))
 754                         return -8;
 755         }
 756
 757         // enemy turrets
 758         if(validate_flags & TFL_TARGETSELECT_NOTURRETS)
 759         if(e_target.owner.tur_head == e_target)
 760         if(e_target.team != e_turret.team) // Dont break support units.
 761                 return -9;
 762
 763         // Missile
 764         if (e_target.flags & FL_PROJECTILE)
 765         if(!(validate_flags & TFL_TARGETSELECT_MISSILES))
 766                 return -10;
 767
 768         if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
 769         if(!(e_target.flags & FL_PROJECTILE))
 770                 return -10.5;
 771
 772         // Team check
 773         if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
 774         {
 775                 if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
 776                 {
 777                         if (e_target.team != e_turret.team)
 778                                 return -11;
 779
 780                         if (e_turret.team != e_target.owner.team)
 781                                 return -12;
 782                 }
 783                 else
 784                 {
 785                         if (e_target.team == e_turret.team)
 786                                 return -13;
 787
 788                         if (e_turret.team == e_target.owner.team)
 789                                 return -14;
 790                 }
 791         }
 792
 793         // Range limits?
 794         tvt_dist = vlen(e_turret.origin - real_origin(e_target));
 795         if (validate_flags & TFL_TARGETSELECT_RANGELIMITS)
 796         {
 797                 if (tvt_dist < e_turret.target_range_min)
 798                         return -15;
 799
 800                 if (tvt_dist > e_turret.target_range)
 801                         return -16;
 802         }
 803
 804         // Can we even aim this thing?
 805         tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target.origin);
 806         tvt_tadv = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
 807         tvt_thadf = vlen(tvt_thadv);
 808         tvt_tadf = vlen(tvt_tadv);
 809
 810         /*
 811         if(validate_flags & TFL_TARGETSELECT_FOV)
 812         {
 813                 if(e_turret.target_select_fov < tvt_thadf)
 814                         return -21;
 815         }
 816         */
 817
 818         if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
 819         {
 820                 if (fabs(tvt_tadv_x) > e_turret.aim_maxpitch)
 821                         return -17;
 822
 823                 if (fabs(tvt_tadv_y) > e_turret.aim_maxrotate)
 824                         return -18;
 825         }
 826
 827         // Line of sight?
 828         if (validate_flags & TFL_TARGETSELECT_LOS)
 829         {
 830                 v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
 831
 832                 traceline(e_turret.origin + '0 0 16', v_tmp, 0, e_turret);
 833
 834                 if(vdist(v_tmp - trace_endpos, >, e_turret.aim_firetolerance_dist))
 835                         return -19;
 836         }
 837
 838         if (e_target.classname == "grapplinghook")
 839                 return -20;
 840
 841         /*
 842         if (e_target.classname == "func_button")
 843                 return -21;
 844         */
 845
 846 #ifdef TURRET_DEBUG_TARGETSELECT
 847         LOG_TRACE("Target:",e_target.netname," is a valid target for ",e_turret.netname);
 848 #endif
 849
 850         return 1;
 851 }
 852
 853 entity turret_select_target(entity this)
 854 {
 855         entity e;               // target looper entity
 856         float  score;   // target looper entity score
 857         entity e_enemy;  // currently best scoreing target
 858         float  m_score;  // currently best scoreing target's score
 859
 860         m_score = 0;
 861         if(this.enemy && this.enemy.takedamage && turret_validate_target(this,this.enemy,this.target_validate_flags) > 0)
 862         {
 863                 e_enemy = this.enemy;
 864                 m_score = this.turret_score_target(this,e_enemy) * this.target_select_samebias;
 865         }
 866         else
 867                 e_enemy = this.enemy = NULL;
 868
 869         e = findradius(this.origin, this.target_range);
 870
 871         // Nothing to aim at?
 872         if (!e)
 873                 return NULL;
 874
 875         while (e)
 876         {
 877                 if(e.takedamage)
 878                 {
 879                         float f = turret_validate_target(this, e, this.target_select_flags);
 880                         //dprint("F is: ", ftos(f), "\n");
 881                         if ( f > 0)
 882                         {
 883                                 score = this.turret_score_target(this,e);
 884                                 if ((score > m_score) && (score > 0))
 885                                 {
 886                                         e_enemy = e;
 887                                         m_score = score;
 888                                 }
 889                         }
 890                 }
 891                 e = e.chain;
 892         }
 893
 894         return e_enemy;
 895 }
 896
 897
 898 /*
 899  + = implemented
 900  - = not implemented
 901
 902  + TFL_FIRECHECK_NO
 903  + TFL_FIRECHECK_WORLD
 904  + TFL_FIRECHECK_DEAD
 905  + TFL_FIRECHECK_DISTANCES
 906  - TFL_FIRECHECK_LOS
 907  + TFL_FIRECHECK_AIMDIST
 908  + TFL_FIRECHECK_REALDIST
 909  - TFL_FIRECHECK_ANGLEDIST
 910  - TFL_FIRECHECK_TEAMCECK
 911  + TFL_FIRECHECK_AFF
 912  + TFL_FIRECHECK_AMMO_OWN
 913  + TFL_FIRECHECK_AMMO_OTHER
 914  + TFL_FIRECHECK_REFIRE
 915 */
 916
 917 /**
 918 ** Preforms pre-fire checks based on the uints firecheck_flags
 919 **/
 920 bool turret_firecheck(entity this)
 921 {
 922         // This one just dont care =)
 923         if (this.firecheck_flags & TFL_FIRECHECK_NO)
 924                 return true;
 925
 926         if (this.enemy == NULL)
 927                 return false;
 928
 929         // Ready?
 930         if (this.firecheck_flags & TFL_FIRECHECK_REFIRE)
 931                 if (this.attack_finished_single[0] > time) return false;
 932
 933         // Special case: volly fire turret that has to fire a full volly if a shot was fired.
 934         if (this.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 935                 if (this.volly_counter != this.shot_volly)
 936                         if(this.ammo >= this.shot_dmg)
 937                                 return true;
 938
 939         // Lack of zombies makes shooting dead things unnecessary :P
 940         if (this.firecheck_flags & TFL_FIRECHECK_DEAD)
 941                 if (IS_DEAD(this.enemy))
 942                         return false;
 943
 944         // Own ammo?
 945         if (this.firecheck_flags & TFL_FIRECHECK_AMMO_OWN)
 946                 if (this.ammo < this.shot_dmg)
 947                         return false;
 948
 949         // Other's ammo? (support-supply units)
 950         if (this.firecheck_flags & TFL_FIRECHECK_AMMO_OTHER)
 951                 if (this.enemy.ammo >= this.enemy.ammo_max)
 952                         return false;
 953
 954         // Target of opertunity?
 955         if(turret_validate_target(this, this.tur_impactent, this.target_validate_flags) > 0)
 956         {
 957                 this.enemy = this.tur_impactent;
 958                 return true;
 959         }
 960
 961         if (this.firecheck_flags & TFL_FIRECHECK_DISTANCES)
 962         {
 963                 // To close?
 964                 if (this.tur_dist_aimpos < this.target_range_min)
 965                 {
 966                         if(turret_validate_target(this, this.tur_impactent, this.target_validate_flags) > 0)
 967                                 return true; // Target of opertunity?
 968                         return false;
 969                 }
 970         }
 971
 972         // Try to avoid FF?
 973         if (this.firecheck_flags & TFL_FIRECHECK_AFF)
 974                 if (this.tur_impactent.team == this.team)
 975                         return false;
 976
 977         // aim<->predicted impact
 978         if (this.firecheck_flags & TFL_FIRECHECK_AIMDIST)
 979                 if (this.tur_dist_impact_to_aimpos > this.aim_firetolerance_dist)
 980                         return false;
 981
 982         // Volly status
 983         if (this.shot_volly > 1)
 984                 if (this.volly_counter == this.shot_volly)
 985                         if (this.ammo < (this.shot_dmg * this.shot_volly))
 986                                 return false;
 987
 988         /*if(this.firecheck_flags & TFL_FIRECHECK_VERIFIED)
 989                 if(this.tur_impactent != this.enemy)
 990                         return false;*/
 991
 992         return true;
 993 }
 994
 995 bool turret_checkfire(entity this)
 996 {
 997         if(MUTATOR_CALLHOOK(Turret_CheckFire, this))
 998                 return M_ARGV(1, bool);
 999
1000         return this.turret_firecheckfunc(this);
1001 }
1002
1003 void turret_fire(entity this)
1004 {
1005         if (autocvar_g_turrets_nofire != 0)
1006                 return;
1007
1008         if(MUTATOR_CALLHOOK(TurretFire, this))
1009                 return;
1010
1011         Turret info = get_turretinfo(this.m_id);
1012         info.tr_attack(info, this);
1013
1014         this.attack_finished_single[0] = time + this.shot_refire;
1015         this.ammo -= this.shot_dmg;
1016         this.volly_counter = this.volly_counter - 1;
1017
1018         if (this.volly_counter <= 0)
1019         {
1020                 this.volly_counter = this.shot_volly;
1021
1022                 if (this.shoot_flags & TFL_SHOOT_CLEARTARGET)
1023                         this.enemy = NULL;
1024
1025                 if (this.shot_volly > 1)
1026                         this.attack_finished_single[0] = time + this.shot_volly_refire;
1027         }
1028
1029 #ifdef TURRET_DEBUG
1030         if (this.enemy) paint_target3(this.tur_aimpos, 64, this.tur_debug_rvec, this.tur_impacttime + 0.25);
1031 #endif
1032 }
1033
1034 void turret_think(entity this)
1035 {
1036         this.nextthink = time + this.ticrate;
1037
1038         MUTATOR_CALLHOOK(TurretThink, this);
1039
1040 #ifdef TURRET_DEBUG
1041         if (this.tur_debug_tmr1 < time)
1042         {
1043                 if (this.enemy) paint_target (this.enemy,128,this.tur_debug_rvec,0.9);
1044                 paint_target(this,256,this.tur_debug_rvec,0.9);
1045                 this.tur_debug_tmr1 = time + 1;
1046         }
1047 #endif
1048
1049         // Handle ammo
1050         if (!(this.spawnflags & TSF_NO_AMMO_REGEN))
1051         if (this.ammo < this.ammo_max)
1052                 this.ammo = min(this.ammo + this.ammo_recharge, this.ammo_max);
1053
1054         // Inactive turrets needs to run the think loop,
1055         // So they can handle animation and wake up if need be.
1056         if(!this.active)
1057         {
1058                 turret_track(this);
1059                 return;
1060         }
1061
1062         // This is typicaly used for zaping every target in range
1063         // turret_fusionreactor uses this to recharge friendlys.
1064         if (this.shoot_flags & TFL_SHOOT_HITALLVALID)
1065         {
1066                 // Do a this.turret_fire for every valid target.
1067                 entity e = findradius(this.origin,this.target_range);
1068                 while (e)
1069                 {
1070                         if(e.takedamage)
1071                         {
1072                                 if (turret_validate_target(this,e,this.target_validate_flags))
1073                                 {
1074                                         this.enemy = e;
1075
1076                                         turret_do_updates(this);
1077
1078                                         if (turret_checkfire(this))
1079                                                 turret_fire(this);
1080                                 }
1081                         }
1082
1083                         e = e.chain;
1084                 }
1085                 this.enemy = NULL;
1086         }
1087         else if(this.shoot_flags & TFL_SHOOT_CUSTOM)
1088         {
1089                 // This one is doing something.. oddball. assume its handles what needs to be handled.
1090
1091                 // Predict?
1092                 if(!(this.aim_flags & TFL_AIM_NO))
1093                         this.tur_aimpos = turret_aim_generic(this);
1094
1095                 // Turn & pitch?
1096                 if(!(this.track_flags & TFL_TRACK_NO))
1097                         turret_track(this);
1098
1099                 turret_do_updates(this);
1100
1101                 // Fire?
1102                 if (turret_checkfire(this))
1103                         turret_fire(this);
1104         }
1105         else
1106         {
1107                 // Special case for volly always. if it fired once it must compleate the volly.
1108                 if(this.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
1109                         if(this.volly_counter != this.shot_volly)
1110                         {
1111                                 // Predict or whatnot
1112                                 if(!(this.aim_flags & TFL_AIM_NO))
1113                                         this.tur_aimpos = turret_aim_generic(this);
1114
1115                                 // Turn & pitch
1116                                 if(!(this.track_flags & TFL_TRACK_NO))
1117                                         turret_track(this);
1118
1119                                 turret_do_updates(this);
1120
1121                                 // Fire!
1122                                 if (turret_checkfire(this))
1123                                         turret_fire(this);
1124
1125                                 Turret tur = get_turretinfo(this.m_id);
1126                                 tur.tr_think(tur, this);
1127
1128                                 return;
1129                         }
1130
1131                 // Check if we have a vailid enemy, and try to find one if we dont.
1132
1133                 // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
1134                 float do_target_scan = 0;
1135                 if((this.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
1136                         do_target_scan = 1;
1137
1138                 // Old target (if any) invalid?
1139                 if(this.target_validate_time < time)
1140                 if (turret_validate_target(this, this.enemy, this.target_validate_flags) <= 0)
1141                 {
1142                         this.enemy = NULL;
1143                         this.target_validate_time = time + 0.5;
1144                         do_target_scan = 1;
1145                 }
1146
1147                 // But never more often then g_turrets_targetscan_mindelay!
1148                 if (this.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
1149                         do_target_scan = 0;
1150
1151                 if(do_target_scan)
1152                 {
1153                         this.enemy = turret_select_target(this);
1154                         this.target_select_time = time;
1155                 }
1156
1157                 // No target, just go to idle, do any custom stuff and bail.
1158                 if (this.enemy == NULL)
1159                 {
1160                         // Turn & pitch
1161                         if(!(this.track_flags & TFL_TRACK_NO))
1162                                 turret_track(this);
1163
1164                         Turret tur = get_turretinfo(this.m_id);
1165                         tur.tr_think(tur, this);
1166
1167                         // And bail.
1168                         return;
1169                 }
1170                 else
1171                         this.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
1172
1173                 // Predict?
1174                 if(!(this.aim_flags & TFL_AIM_NO))
1175                         this.tur_aimpos = turret_aim_generic(this);
1176
1177                 // Turn & pitch?
1178                 if(!(this.track_flags & TFL_TRACK_NO))
1179                         turret_track(this);
1180
1181                 turret_do_updates(this);
1182
1183                 // Fire?
1184                 if (turret_checkfire(this))
1185                         turret_fire(this);
1186         }
1187
1188         Turret tur = get_turretinfo(this.m_id);
1189         tur.tr_think(tur, this);
1190 }
1191
1192 /*
1193         When .used a turret switch team to activator.team.
1194         If activator is NULL, the turret go inactive.
1195 */
1196 void turret_use(entity this, entity actor, entity trigger)
1197 {
1198         LOG_TRACE("Turret ",this.netname, " used by ", actor.classname);
1199
1200         this.team = actor.team;
1201
1202         if(this.team == 0)
1203                 this.active = ACTIVE_NOT;
1204         else
1205                 this.active = ACTIVE_ACTIVE;
1206
1207 }
1208
1209 void turret_link(entity this)
1210 {
1211         Net_LinkEntity(this, true, 0, turret_send);
1212         setthink(this, turret_think);
1213         this.nextthink = time;
1214         this.tur_head.effects = EF_NODRAW;
1215 }
1216
1217 void turrets_manager_think(entity this)
1218 {
1219         this.nextthink = time + 1;
1220
1221         if (autocvar_g_turrets_reloadcvars == 1)
1222         {
1223                 IL_EACH(g_turrets, true,
1224                 {
1225                         load_unit_settings(it, true);
1226                         Turret tur = get_turretinfo(it.m_id);
1227                         tur.tr_think(tur, it);
1228                 });
1229                 cvar_set("g_turrets_reloadcvars", "0");
1230         }
1231 }
1232
1233 void turret_initparams(entity tur)
1234 {
1235         #define TRY(x) (x) ? (x)
1236         tur.respawntime                 = max  (-1,              (TRY(tur.respawntime)               :  60                                         ));
1237         tur.shot_refire                 = bound(0.01,            (TRY(tur.shot_refire)               :  1                                          ), 9999);
1238         tur.shot_dmg                    = max  (1,               (TRY(tur.shot_dmg)                  :  tur.shot_refire * 50                       ));
1239         tur.shot_radius                 = max  (1,               (TRY(tur.shot_radius)               :  tur.shot_dmg * 0.5                         ));
1240         tur.shot_speed                  = max  (1,               (TRY(tur.shot_speed)                :  2500                                       ));
1241         tur.shot_spread                 = bound(0.0001,          (TRY(tur.shot_spread)               :  0.0125                                     ), 500);
1242         tur.shot_force                  = bound(0.001,           (TRY(tur.shot_force)                :  tur.shot_dmg * 0.5 + tur.shot_radius * 0.5 ), 5000);
1243         tur.shot_volly                  = bound(1,               (TRY(tur.shot_volly)                :  1                                          ), floor(tur.ammo_max / tur.shot_dmg));
1244         tur.shot_volly_refire           = bound(tur.shot_refire, (TRY(tur.shot_volly_refire)         :  tur.shot_refire * tur.shot_volly           ), 60);
1245         tur.target_range                = bound(0,               (TRY(tur.target_range)              :  tur.shot_speed * 0.5                       ), max_shot_distance);
1246         tur.target_range_min            = bound(0,               (TRY(tur.target_range_min)          :  tur.shot_radius * 2                        ), max_shot_distance);
1247         tur.target_range_optimal        = bound(0,               (TRY(tur.target_range_optimal)      :  tur.target_range * 0.5                     ), max_shot_distance);
1248         tur.aim_maxrotate               = bound(0,               (TRY(tur.aim_maxrotate)             :  90                                         ), 360);
1249         tur.aim_maxpitch                = bound(0,               (TRY(tur.aim_maxpitch)              :  20                                         ), 90);
1250         tur.aim_speed                   = bound(0.1,             (TRY(tur.aim_speed)                 :  36                                         ), 1000);
1251         tur.aim_firetolerance_dist      = bound(0.1,             (TRY(tur.aim_firetolerance_dist)    :  5 + (tur.shot_radius * 2)                  ), max_shot_distance);
1252         tur.target_select_rangebias     = bound(-10,             (TRY(tur.target_select_rangebias)   :  1                                          ), 10);
1253         tur.target_select_samebias      = bound(-10,             (TRY(tur.target_select_samebias)    :  1                                          ), 10);
1254         tur.target_select_anglebias     = bound(-10,             (TRY(tur.target_select_anglebias)   :  1                                          ), 10);
1255         tur.target_select_missilebias   = bound(-10,             (TRY(tur.target_select_missilebias) :  1                                          ), 10);
1256         tur.target_select_playerbias    = bound(-10,             (TRY(tur.target_select_playerbias)  :  1                                          ), 10);
1257         tur.ammo_max                    = max  (tur.shot_dmg,    (TRY(tur.ammo_max)                  :  tur.shot_dmg * 10                          ));
1258         tur.ammo_recharge               = max  (0,               (TRY(tur.ammo_recharge)             :  tur.shot_dmg * 0.5                         ));
1259         #undef TRY
1260 }
1261
1262 bool turret_closetotarget(entity this, vector targ)
1263 {
1264         vector path_extra_size = '64 64 64';
1265         return boxesoverlap(targ - path_extra_size, targ + path_extra_size, this.absmin - path_extra_size, this.absmax + path_extra_size);
1266 }
1267
1268 void turret_findtarget(entity this)
1269 {
1270         entity e = find(NULL, classname, "turret_manager");
1271         if(!e)
1272         {
1273                 e = new(turret_manager);
1274                 setthink(e, turrets_manager_think);
1275                 e.nextthink = time + 2;
1276         }
1277
1278         entity targ = find(NULL, targetname, this.target);
1279         if(targ.classname == "turret_checkpoint")
1280                 return; // turrets don't defend checkpoints?
1281
1282         if (!targ)
1283         {
1284                 this.target = "";
1285                 LOG_TRACE("Turret has invalid defendpoint!");
1286         }
1287
1288         this.tur_defend = targ;
1289         this.idle_aim = this.tur_head.angles + angleofs(this.tur_head, targ);
1290 }
1291
1292 bool turret_initialize(entity this, Turret tur)
1293 {
1294         if(!autocvar_g_turrets)
1295                 return false;
1296
1297         if(tur.m_id == 0)
1298                 return false; // invalid turret
1299
1300         // if tur_head exists, we can assume this turret re-spawned
1301         if(!this.tur_head) {
1302                 tur.tr_precache(tur);
1303                 IL_PUSH(g_turrets, this);
1304                 IL_PUSH(g_bot_targets, this);
1305         }
1306
1307         if(!(this.spawnflags & TSF_SUSPENDED))
1308                 droptofloor(this);
1309
1310         this.netname = tur.netname;
1311         load_unit_settings(this, 0);
1312
1313         if(!this.team || !teamplay)             { this.team = FLOAT_MAX; }
1314         if(!this.ticrate)                               { this.ticrate = ((this.turret_flags & TUR_FLAG_SUPPORT) ? 0.2 : 0.1); }
1315         if(!GetResource(this, RES_HEALTH)) { SetResourceExplicit(this, RES_HEALTH, 1000); }
1316         if(!this.shot_refire)                   { this.shot_refire = 1; }
1317         if(!this.tur_shotorg)                   { this.tur_shotorg = '50 0 50'; }
1318         if(!this.turret_flags)                  { this.turret_flags = TUR_FLAG_SPLASH | TUR_FLAG_MEDPROJ | TUR_FLAG_PLAYER; }
1319         if(!this.damage_flags)                  { this.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE; }
1320         if(!this.aim_flags)                             { this.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE; }
1321         if(!this.track_type)                    { this.track_type = TFL_TRACKTYPE_STEPMOTOR; }
1322         if(!this.track_flags)                   { this.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROTATE; }
1323         if(!this.ammo_flags)                    { this.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE; }
1324         if(!this.target_select_flags)   { this.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_ANGLELIMITS; }
1325         if(!this.firecheck_flags)               { this.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES | TFL_FIRECHECK_LOS
1326                                                                                                                    | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCHECK | TFL_FIRECHECK_AMMO_OWN | TFL_FIRECHECK_REFIRE; }
1327
1328         if(this.track_type != TFL_TRACKTYPE_STEPMOTOR)
1329         {
1330                 // Fluid / Ineria mode. Looks mutch nicer.
1331                 // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1332
1333                 this.aim_speed = bound(0.1, ((!this.aim_speed) ? 180 : this.aim_speed), 1000);
1334
1335                 if(!this.track_accel_pitch)             { this.track_accel_pitch = 0.5; }
1336                 if(!this.track_accel_rotate)    { this.track_accel_rotate = 0.5; }
1337                 if(!this.track_blendrate)               { this.track_blendrate = 0.35; }
1338         }
1339
1340         turret_initparams(this);
1341
1342         this.turret_flags = TUR_FLAG_ISTURRET | (tur.spawnflags);
1343
1344         if(this.turret_flags & TUR_FLAG_SPLASH)
1345                 this.aim_flags |= TFL_AIM_SPLASH;
1346
1347         if(this.turret_flags & TUR_FLAG_MISSILE)
1348                 this.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1349
1350         if(this.turret_flags & TUR_FLAG_PLAYER)
1351                 this.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1352
1353         if(this.spawnflags & TSL_NO_RESPAWN)
1354                 this.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1355
1356         if (this.turret_flags & TUR_FLAG_SUPPORT)
1357                 this.turret_score_target = turret_targetscore_support;
1358         else
1359                 this.turret_score_target = turret_targetscore_generic;
1360
1361         ++turret_count;
1362
1363         _setmodel(this, tur.model);
1364         setsize(this, tur.m_mins, tur.m_maxs);
1365
1366         this.m_id                                       = tur.m_id;
1367         this.classname                          = "turret_main";
1368         this.active                                     = ACTIVE_ACTIVE;
1369         this.effects                            = EF_NODRAW;
1370         this.netname                            = tur.turret_name;
1371         this.ticrate                            = bound(sys_frametime, this.ticrate, 60);
1372         this.max_health                         = GetResource(this, RES_HEALTH);
1373         this.target_validate_flags      = this.target_select_flags;
1374         this.ammo                                       = this.ammo_max;
1375         this.ammo_recharge                 *= this.ticrate;
1376         this.solid                                      = SOLID_BBOX;
1377         this.takedamage                         = DAMAGE_AIM;
1378         set_movetype(this, MOVETYPE_NOCLIP);
1379         this.view_ofs                           = '0 0 0';
1380         this.idle_aim                           = '0 0 0';
1381         this.turret_firecheckfunc       = turret_firecheck;
1382         this.event_damage                       = turret_damage;
1383         this.event_heal                         = turret_heal;
1384         this.use                                        = turret_use;
1385         this.bot_attack                         = true;
1386         this.nextthink                          = time + 1;
1387         this.nextthink                     += turret_count * sys_frametime;
1388
1389         this.tur_head = new(turret_head);
1390         _setmodel(this.tur_head, tur.head_model);
1391         setsize(this.tur_head, '0 0 0', '0 0 0');
1392         setorigin(this.tur_head, '0 0 0');
1393         setattachment(this.tur_head, this, "tag_head");
1394
1395         this.tur_head.netname           = this.tur_head.classname;
1396         this.tur_head.team                      = this.team;
1397         this.tur_head.owner                     = this;
1398         this.tur_head.takedamage        = DAMAGE_NO;
1399         this.tur_head.solid                     = SOLID_NOT;
1400         set_movetype(this.tur_head, this.move_movetype);
1401
1402         this.weaponentities[0] = this; // lol
1403
1404         if(!this.tur_defend && this.target != "")
1405                 InitializeEntity(this, turret_findtarget, INITPRIO_FINDTARGET);
1406
1407 #ifdef TURRET_DEBUG
1408         this.tur_debug_start = this.nextthink;
1409         while(vdist(this.tur_debug_rvec, <, 2))
1410                 this.tur_debug_rvec = randomvec() * 4;
1411
1412         this.tur_debug_rvec_x = fabs(this.tur_debug_rvec_x);
1413         this.tur_debug_rvec_y = fabs(this.tur_debug_rvec_y);
1414         this.tur_debug_rvec_z = fabs(this.tur_debug_rvec_z);
1415 #endif
1416
1417         turret_link(this);
1418         turret_respawn(this);
1419         turret_tag_fire_update(this);
1420
1421         tur.tr_setup(tur, this);
1422
1423         if(MUTATOR_CALLHOOK(TurretSpawn, this))
1424                 return false;
1425
1426         return true;
1427 }
1428 #endif