qcsrc/common/vehicles/unit/spiderbot.qc

   1 #ifdef REGISTER_VEHICLE
   2 REGISTER_VEHICLE(
   3 /* VEH_##id   */ SPIDERBOT,
   4 /* function   */ v_spiderbot,
   5 /* spawnflags */ VHF_DMGSHAKE,
   6 /* mins,maxs  */ '-75 -75 10', '75 75 125',
   7 /* model          */ "models/vehicles/spiderbot.dpm",
   8 /* head_model */ "models/vehicles/spiderbot_top.dpm",
   9 /* hud_model  */ "models/vehicles/spiderbot_cockpit.dpm",
  10 /* tags           */ "tag_head", "tag_hud", "",
  11 /* netname        */ "spiderbot",
  12 /* fullname   */ _("Spiderbot")
  13 );
  14 #else
  15
  16 #ifdef SVQC
  17 float autocvar_g_vehicle_spiderbot;
  18
  19 float autocvar_g_vehicle_spiderbot_respawntime;
  20
  21 float autocvar_g_vehicle_spiderbot_speed_stop;
  22 float autocvar_g_vehicle_spiderbot_speed_strafe;
  23 float autocvar_g_vehicle_spiderbot_speed_walk;
  24 float autocvar_g_vehicle_spiderbot_turnspeed;
  25 float autocvar_g_vehicle_spiderbot_turnspeed_strafe;
  26 float autocvar_g_vehicle_spiderbot_movement_inertia;
  27
  28 float autocvar_g_vehicle_spiderbot_springlength;
  29 float autocvar_g_vehicle_spiderbot_springup;
  30 float autocvar_g_vehicle_spiderbot_springblend;
  31 float autocvar_g_vehicle_spiderbot_tiltlimit;
  32
  33 float autocvar_g_vehicle_spiderbot_head_pitchlimit_down;
  34 float autocvar_g_vehicle_spiderbot_head_pitchlimit_up;
  35 float autocvar_g_vehicle_spiderbot_head_turnlimit;
  36 float autocvar_g_vehicle_spiderbot_head_turnspeed;
  37
  38 float autocvar_g_vehicle_spiderbot_health;
  39 float autocvar_g_vehicle_spiderbot_health_regen;
  40 float autocvar_g_vehicle_spiderbot_health_regen_pause;
  41
  42 float autocvar_g_vehicle_spiderbot_shield;
  43 float autocvar_g_vehicle_spiderbot_shield_regen;
  44 float autocvar_g_vehicle_spiderbot_shield_regen_pause;
  45
  46 float autocvar_g_vehicle_spiderbot_minigun_damage;
  47 float autocvar_g_vehicle_spiderbot_minigun_refire;
  48 float autocvar_g_vehicle_spiderbot_minigun_spread;
  49 float autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
  50 float autocvar_g_vehicle_spiderbot_minigun_ammo_max;
  51 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen;
  52 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause;
  53 float autocvar_g_vehicle_spiderbot_minigun_force;
  54 float autocvar_g_vehicle_spiderbot_minigun_speed;
  55 float autocvar_g_vehicle_spiderbot_minigun_bulletconstant;
  56
  57 float autocvar_g_vehicle_spiderbot_rocket_damage;
  58 float autocvar_g_vehicle_spiderbot_rocket_force;
  59 float autocvar_g_vehicle_spiderbot_rocket_radius;
  60 float autocvar_g_vehicle_spiderbot_rocket_speed;
  61 float autocvar_g_vehicle_spiderbot_rocket_spread;
  62 float autocvar_g_vehicle_spiderbot_rocket_refire;
  63 float autocvar_g_vehicle_spiderbot_rocket_refire2;
  64 float autocvar_g_vehicle_spiderbot_rocket_reload;
  65 float autocvar_g_vehicle_spiderbot_rocket_health;
  66 float autocvar_g_vehicle_spiderbot_rocket_noise;
  67 float autocvar_g_vehicle_spiderbot_rocket_turnrate;
  68 float autocvar_g_vehicle_spiderbot_rocket_lifetime;
  69
  70 #define SBRM_FIRST 0
  71 #define SBRM_VOLLY 0
  72 #define SBRM_GUIDE 1
  73 #define SBRM_ARTILLERY 2
  74 #define SBRM_LAST 2
  75
  76 vector autocvar_g_vehicle_spiderbot_bouncepain;
  77
  78 void spiderbot_rocket_artillery()
  79 {
  80         self.nextthink = time;
  81         UpdateCSQCProjectile(self);
  82 }
  83
  84 void spiderbot_rocket_unguided()
  85 {
  86         vector newdir, olddir;
  87
  88         self.nextthink  = time;
  89
  90         olddir = normalize(self.velocity);
  91         newdir = normalize(self.pos1 - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  92         self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  93
  94         UpdateCSQCProjectile(self);
  95
  96         if (self.owner.deadflag != DEAD_NO || self.cnt < time || vlen(self.pos1 - self.origin) < 16)
  97                 self.use();
  98 }
  99
 100 void spiderbot_rocket_guided()
 101 {
 102         vector newdir, olddir;
 103
 104         self.nextthink  = time;
 105
 106         if not (self.realowner.vehicle)
 107                 self.think = spiderbot_rocket_unguided;
 108
 109         crosshair_trace(self.realowner);
 110         olddir = normalize(self.velocity);
 111         newdir = normalize(trace_endpos - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
 112         self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
 113
 114         UpdateCSQCProjectile(self);
 115
 116         if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 117                 self.use();
 118 }
 119
 120 void spiderbot_guide_release()
 121 {
 122         entity rkt;
 123         rkt = findchainentity(realowner, self.owner);
 124         if not (rkt)
 125                 return;
 126
 127         crosshair_trace(self.owner);
 128         while(rkt)
 129         {
 130                 if(rkt.think == spiderbot_rocket_guided)
 131                 {
 132                         rkt.pos1 = trace_endpos;
 133                         rkt.think = spiderbot_rocket_unguided;
 134                 }
 135                 rkt = rkt.chain;
 136         }
 137 }
 138
 139 float spiberbot_calcartillery_flighttime;
 140 vector spiberbot_calcartillery(vector org, vector tgt, float ht)
 141 {
 142         float grav, sdist, zdist, vs, vz, jumpheight;
 143         vector sdir;
 144
 145         grav  = autocvar_sv_gravity;
 146         zdist = tgt_z - org_z;
 147         sdist = vlen(tgt - org - zdist * '0 0 1');
 148         sdir  = normalize(tgt - org - zdist * '0 0 1');
 149
 150         // how high do we need to go?
 151         jumpheight = fabs(ht);
 152         if(zdist > 0)
 153                 jumpheight = jumpheight + zdist;
 154
 155         // push so high...
 156         vz = sqrt(2 * grav * jumpheight); // NOTE: sqrt(positive)!
 157
 158         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
 159         if(ht < 0)
 160                 if(zdist < 0)
 161                         vz = -vz;
 162
 163         vector solution;
 164         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
 165         // ALWAYS solvable because jumpheight >= zdist
 166         if(!solution_z)
 167                 solution_y = solution_x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
 168         if(zdist == 0)
 169                 solution_x = solution_y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
 170
 171         if(zdist < 0)
 172         {
 173                 // down-jump
 174                 if(ht < 0)
 175                 {
 176                         // almost straight line type
 177                         // jump apex is before the jump
 178                         // we must take the larger one
 179                         spiberbot_calcartillery_flighttime = solution_y;
 180                 }
 181                 else
 182                 {
 183                         // regular jump
 184                         // jump apex is during the jump
 185                         // we must take the larger one too
 186                         spiberbot_calcartillery_flighttime = solution_y;
 187                 }
 188         }
 189         else
 190         {
 191                 // up-jump
 192                 if(ht < 0)
 193                 {
 194                         // almost straight line type
 195                         // jump apex is after the jump
 196                         // we must take the smaller one
 197                         spiberbot_calcartillery_flighttime = solution_x;
 198                 }
 199                 else
 200                 {
 201                         // regular jump
 202                         // jump apex is during the jump
 203                         // we must take the larger one
 204                         spiberbot_calcartillery_flighttime = solution_y;
 205                 }
 206         }
 207         vs = sdist / spiberbot_calcartillery_flighttime;
 208
 209         // finally calculate the velocity
 210         return sdir * vs + '0 0 1' * vz;
 211 }
 212
 213 void spiderbot_rocket_do()
 214 {
 215         vector v;
 216         entity rocket = world;
 217
 218         if (self.wait != -10)
 219         {
 220                 if (self.owner.BUTTON_ATCK2 && self.vehicle_weapon2mode == SBRM_GUIDE)
 221                 {
 222                         if (self.wait == 1)
 223                         if (self.tur_head.frame == 9 || self.tur_head.frame == 1)
 224                         {
 225                                 if(self.gun2.cnt < time && self.tur_head.frame == 9)
 226                                         self.tur_head.frame = 1;
 227
 228                                 return;
 229                         }
 230                         self.wait = 1;
 231                 }
 232                 else
 233                 {
 234                         if(self.wait)
 235                                 spiderbot_guide_release();
 236
 237                         self.wait = 0;
 238                 }
 239         }
 240
 241         if(self.gun2.cnt > time)
 242                 return;
 243
 244         if (self.tur_head.frame >= 9)
 245         {
 246                 self.tur_head.frame = 1;
 247                 self.wait = 0;
 248         }
 249
 250         if (self.wait != -10)
 251                 if not (self.owner.BUTTON_ATCK2)
 252                         return;
 253
 254
 255         v = gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire"));
 256
 257         switch(self.vehicle_weapon2mode)
 258         {
 259                 case SBRM_VOLLY:
 260                         rocket = vehicles_projectile("spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 261                                                                    v, normalize(randomvec() * autocvar_g_vehicle_spiderbot_rocket_spread + v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 262                                                                    autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 263                                                                    DEATH_VH_SPID_ROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health, FALSE, TRUE, self.owner);
 264                         crosshair_trace(self.owner);
 265                         float _dist = (random() * autocvar_g_vehicle_spiderbot_rocket_radius) + vlen(v - trace_endpos);
 266                         _dist -= (random() * autocvar_g_vehicle_spiderbot_rocket_radius) ;
 267                         rocket.nextthink  = time + (_dist / autocvar_g_vehicle_spiderbot_rocket_speed);
 268                         rocket.think     = vehicles_projectile_explode;
 269
 270                         if(self.owner.BUTTON_ATCK2 && self.tur_head.frame == 1)
 271                                 self.wait = -10;
 272                         break;
 273                 case SBRM_GUIDE:
 274                         rocket = vehicles_projectile("spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 275                                                                    v, normalize(v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 276                                                                    autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 277                                                                    DEATH_VH_SPID_ROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health, FALSE, FALSE, self.owner);
 278                         crosshair_trace(self.owner);
 279                         rocket.pos1        = trace_endpos;
 280                         rocket.nextthink  = time;
 281                         rocket.think      = spiderbot_rocket_guided;
 282
 283
 284                 break;
 285                 case SBRM_ARTILLERY:
 286                         rocket = vehicles_projectile("spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 287                                                                    v, normalize(v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 288                                                                    autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 289                                                                    DEATH_VH_SPID_ROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health, FALSE, TRUE, self.owner);
 290
 291                         crosshair_trace(self.owner);
 292
 293                         rocket.pos1        = trace_endpos + randomvec() * (0.75 * autocvar_g_vehicle_spiderbot_rocket_radius);
 294                         rocket.pos1_z      = trace_endpos_z;
 295
 296                         traceline(v, v + '0 0 1' * MAX_SHOT_DISTANCE, MOVE_WORLDONLY, self);
 297                         float h1 = 0.75 * vlen(v - trace_endpos);
 298
 299                         //v = trace_endpos;
 300                         traceline(v , rocket.pos1 + '0 0 1' * MAX_SHOT_DISTANCE, MOVE_WORLDONLY, self);
 301                         float h2 = 0.75 * vlen(rocket.pos1 - v);
 302
 303                         rocket.velocity  = spiberbot_calcartillery(v, rocket.pos1, ((h1 < h2) ? h1 : h2));
 304                         rocket.movetype  = MOVETYPE_TOSS;
 305                         rocket.gravity   = 1;
 306                         //rocket.think   = spiderbot_rocket_artillery;
 307                 break;
 308         }
 309         rocket.classname  = "spiderbot_rocket";
 310
 311         rocket.cnt = time + autocvar_g_vehicle_spiderbot_rocket_lifetime;
 312
 313         self.tur_head.frame += 1;
 314         if (self.tur_head.frame == 9)
 315                 self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_reload;
 316         else
 317                 self.attack_finished_single = ((self.vehicle_weapon2mode ==  SBRM_VOLLY) ? autocvar_g_vehicle_spiderbot_rocket_refire2 : autocvar_g_vehicle_spiderbot_rocket_refire);
 318
 319         self.gun2.cnt = time + self.attack_finished_single;
 320 }
 321
 322 float spiderbot_frame()
 323 {
 324         vector ad, vf;
 325         entity player, spider;
 326         float ftmp;
 327
 328         if(intermission_running)
 329                 return 1;
 330
 331         player = self;
 332         spider = self.vehicle;
 333         self   = spider;
 334
 335         vehicles_painframe();
 336
 337         player.BUTTON_ZOOM        = 0;
 338         player.BUTTON_CROUCH    = 0;
 339         player.switchweapon      = 0;
 340
 341
 342 #if 1 // 0 to enable per-gun impact aux crosshairs
 343         // Avarage gun impact point's -> aux cross
 344         ad = gettaginfo(spider.tur_head, gettagindex(spider.tur_head, "tag_hardpoint01"));
 345         vf = v_forward;
 346         ad += gettaginfo(spider.tur_head, gettagindex(spider.tur_head, "tag_hardpoint02"));
 347         vf += v_forward;
 348         ad = ad * 0.5;
 349         v_forward = vf * 0.5;
 350         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 351         UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 352 #else
 353         ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 354         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 355         UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 356         vf = ad;
 357         ad = gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 358         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 359         UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 1);
 360         ad = 0.5 * (ad + vf);
 361 #endif
 362
 363         crosshair_trace(player);
 364         ad = vectoangles(normalize(trace_endpos - ad));
 365         ad = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(spider.angles), AnglesTransform_FromAngles(ad))) - spider.tur_head.angles;
 366         ad = AnglesTransform_Normalize(ad, TRUE);
 367         //UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload2) + ('0 1 0' * (1 - player.vehicle_reload2)), 2);
 368
 369         // Rotate head
 370         ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 371         ad_y = bound(-ftmp, ad_y, ftmp);
 372         spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 373
 374         // Pitch head
 375         ad_x = bound(ftmp * -1, ad_x, ftmp);
 376         spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 377
 378
 379         //fixedmakevectors(spider.angles);
 380         makevectors(spider.angles + '-2 0 0' * spider.angles_x);
 381
 382         movelib_groundalign4point(autocvar_g_vehicle_spiderbot_springlength, autocvar_g_vehicle_spiderbot_springup, autocvar_g_vehicle_spiderbot_springblend, autocvar_g_vehicle_spiderbot_tiltlimit);
 383
 384         if(spider.flags & FL_ONGROUND)
 385         {
 386                 if(spider.frame == 4 && self.tur_head.wait != 0)
 387                 {
 388                         sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_land.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 389                         spider.frame = 5;
 390                 }
 391
 392                 if(player.BUTTON_JUMP && self.tur_head.wait < time)
 393                 {
 394                         sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_jump.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 395                         //dprint("spiderbot_jump:", ftos(soundlength("vehicles/spiderbot_jump.wav")), "\n");
 396                         self.delay = 0;
 397
 398                         self.tur_head.wait = time + 2;
 399                         player.BUTTON_JUMP = 0;
 400                         spider.velocity   = v_forward * 700 + v_up * 600;
 401                         spider.frame = 4;
 402                 }
 403                 else
 404                 {
 405                         if(vlen(player.movement) == 0)
 406                         {
 407                                 if(self.sound_nexttime < time || self.delay != 3)
 408                                 {
 409                                         self.delay = 3;
 410                                         self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_idle.wav");
 411                                         //dprint("spiderbot_idle:", ftos(soundlength("vehicles/spiderbot_idle.wav")), "\n");
 412                                         sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_idle.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 413                                 }
 414                                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 415                                 spider.frame = 5;
 416                         }
 417                         else
 418                         {
 419                                 // Turn Body
 420                                 if(player.movement_x == 0 && player.movement_y != 0)
 421                                         ftmp = autocvar_g_vehicle_spiderbot_turnspeed_strafe * sys_frametime;
 422                                 else
 423                                         ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 424
 425                                 ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 426                                 spider.angles_y = anglemods(spider.angles_y + ftmp);
 427                                 spider.tur_head.angles_y -= ftmp;
 428
 429                                 if(player.movement_x != 0)
 430                                 {
 431                                         if(player.movement_x > 0)
 432                                         {
 433                                                 player.movement_x = 1;
 434                                                 spider.frame = 0;
 435                                         }
 436                                         else if(player.movement_x < 0)
 437                                         {
 438                                                 player.movement_x = -1;
 439                                                 spider.frame = 1;
 440                                         }
 441                                         player.movement_y = 0;
 442                                         movelib_move_simple(normalize(v_forward * player.movement_x),autocvar_g_vehicle_spiderbot_speed_walk,autocvar_g_vehicle_spiderbot_movement_inertia);
 443
 444                                         if(self.sound_nexttime < time || self.delay != 1)
 445                                         {
 446                                                 self.delay = 1;
 447                                                 self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_walk.wav");
 448                                                 sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_walk.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 449                                                 //dprint("spiderbot_walk:", ftos(soundlength("vehicles/spiderbot_walk.wav")), "\n");
 450                                         }
 451                                 }
 452                                 else if(player.movement_y != 0)
 453                                 {
 454                                         if(player.movement_y < 0)
 455                                         {
 456                                                 player.movement_y = -1;
 457                                                 spider.frame = 2;
 458                                         }
 459                                         else if(player.movement_y > 0)
 460                                         {
 461                                                 player.movement_y = 1;
 462                                                 spider.frame = 3;
 463                                         }
 464                                         movelib_move_simple(normalize(v_right * player.movement_y),autocvar_g_vehicle_spiderbot_speed_strafe,autocvar_g_vehicle_spiderbot_movement_inertia);
 465                                         if(self.sound_nexttime < time || self.delay != 2)
 466                                         {
 467                                                 self.delay = 2;
 468                                                 self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_strafe.wav");
 469                                                 sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_strafe.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 470                                                 //dprint("spiderbot_strafe:", ftos(soundlength("vehicles/spiderbot_strafe.wav")), "\n");
 471                                         }
 472                                 }
 473                         }
 474                 }
 475         }
 476
 477         self.angles_x = bound(-autocvar_g_vehicle_spiderbot_tiltlimit, self.angles_x, autocvar_g_vehicle_spiderbot_tiltlimit);
 478         self.angles_z = bound(-autocvar_g_vehicle_spiderbot_tiltlimit, self.angles_z, autocvar_g_vehicle_spiderbot_tiltlimit);
 479
 480         if(player.BUTTON_ATCK)
 481         {
 482                 spider.cnt = time;
 483                 if(spider.vehicle_ammo1 >= autocvar_g_vehicle_spiderbot_minigun_ammo_cost && spider.tur_head.attack_finished_single <= time)
 484                 {
 485                         entity gun;
 486                         vector v;
 487                         spider.misc_bulletcounter += 1;
 488
 489                         self = player;
 490
 491                         mod(spider.misc_bulletcounter, 2) ? gun = spider.gun1 : gun = spider.gun2;
 492                         v = gettaginfo(gun, gettagindex(gun, "barrels"));
 493                         v_forward = normalize(v_forward);
 494                         v += v_forward * 50;
 495
 496 //void fireBallisticBullet(vector start, vector dir, float spread, float pSpeed, float lifetime, float damage, float force, float dtype, float tracereffects, float gravityfactor, float bulletconstant)
 497
 498                         fireBallisticBullet(v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_speed,
 499                                                                 5, autocvar_g_vehicle_spiderbot_minigun_damage, autocvar_g_vehicle_spiderbot_minigun_force, DEATH_VH_SPID_MINIGUN, 0, autocvar_g_vehicle_spiderbot_minigun_bulletconstant);
 500
 501                         endFireBallisticBullet();
 502
 503 //                      fireBullet (v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_damage,
 504 //                              autocvar_g_vehicle_spiderbot_minigun_spread, DEATH_VH_SPID_MINIGUN, 0);
 505
 506                         sound (gun, CH_WEAPON_A, "weapons/uzi_fire.wav", VOL_BASE, ATTEN_NORM);
 507                         //trailparticles(self, particleeffectnum("spiderbot_minigun_trail"), v, trace_endpos);
 508                         pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), v, v_forward * 2500, 1);
 509
 510                         self = spider;
 511
 512                         spider.vehicle_ammo1 -= autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
 513                         spider.tur_head.attack_finished_single = time + autocvar_g_vehicle_spiderbot_minigun_refire;
 514                         player.vehicle_ammo1 = (spider.vehicle_ammo1 / autocvar_g_vehicle_spiderbot_minigun_ammo_max) * 100;
 515                         spider.gun1.angles_z += 45;
 516                         spider.gun2.angles_z -= 45;
 517                         if(spider.gun1.angles_z >= 360)
 518                         {
 519                                 spider.gun1.angles_z = 0;
 520                                 spider.gun2.angles_z = 0;
 521                         }
 522                 }
 523         }
 524         else
 525                 vehicles_regen(spider.cnt, vehicle_ammo1, autocvar_g_vehicle_spiderbot_minigun_ammo_max,
 526                                                                                    autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause,
 527                                                                                    autocvar_g_vehicle_spiderbot_minigun_ammo_regen, frametime, FALSE);
 528
 529
 530         spiderbot_rocket_do();
 531
 532         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 533                 vehicles_regen(spider.dmg_time, vehicle_shield, autocvar_g_vehicle_spiderbot_shield, autocvar_g_vehicle_spiderbot_shield_regen_pause, autocvar_g_vehicle_spiderbot_shield_regen, frametime, TRUE);
 534
 535         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 536                 vehicles_regen(spider.dmg_time, vehicle_health, autocvar_g_vehicle_spiderbot_health, autocvar_g_vehicle_spiderbot_health_regen_pause, autocvar_g_vehicle_spiderbot_health_regen, frametime, FALSE);
 537
 538         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 539         player.vehicle_ammo2 = spider.tur_head.frame;
 540
 541         if(spider.gun2.cnt <= time)
 542                 player.vehicle_reload2 = 100;
 543         else
 544                 player.vehicle_reload2 = 100 - ((spider.gun2.cnt - time) / spider.attack_finished_single) * 100;
 545
 546         setorigin(player, spider.origin + '0 0 1' * spider.maxs_z);
 547         player.velocity = spider.velocity;
 548
 549         VEHICLE_UPDATE_PLAYER(player, health, spiderbot);
 550
 551         if(self.vehicle_flags & VHF_HASSHIELD)
 552                 VEHICLE_UPDATE_PLAYER(player, shield, spiderbot);
 553
 554         self = player;
 555         return 1;
 556 }
 557
 558 void spiderbot_exit(float eject)
 559 {
 560         entity e;
 561         vector spot;
 562
 563         e = findchain(classname,"spiderbot_rocket");
 564         while(e)
 565         {
 566                 if(e.owner == self.owner)
 567                 {
 568                         e.realowner = self.owner;
 569                         e.owner = world;
 570                 }
 571                 e = e.chain;
 572         }
 573
 574         self.think = vehicles_think;
 575         self.nextthink = time;
 576         self.frame = 5;
 577         self.movetype = MOVETYPE_WALK;
 578
 579         if not(self.owner)
 580                 return;
 581
 582         makevectors(self.angles);
 583         if(eject)
 584         {
 585                 spot = self.origin + v_forward * 100 + '0 0 64';
 586                 spot = vehicles_findgoodexit(spot);
 587                 setorigin(self.owner , spot);
 588                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 589                 self.owner.oldvelocity = self.owner.velocity;
 590         }
 591         else
 592         {
 593                 if(vlen(self.velocity) > autocvar_g_vehicle_spiderbot_speed_strafe)
 594                 {
 595                         self.owner.velocity = normalize(self.velocity) * vlen(self.velocity);
 596                         self.owner.velocity_z += 200;
 597                         spot = self.origin + v_forward * 128 + '0 0 64';
 598                         spot = vehicles_findgoodexit(spot);
 599                 }
 600                 else
 601                 {
 602                         self.owner.velocity = self.velocity * 0.5;
 603                         self.owner.velocity_z += 10;
 604                         spot = self.origin + v_forward * 256 + '0 0 64';
 605                         spot = vehicles_findgoodexit(spot);
 606                 }
 607                 self.owner.oldvelocity = self.owner.velocity;
 608                 setorigin(self.owner , spot);
 609         }
 610
 611         antilag_clear(self.owner);
 612         self.owner = world;
 613 }
 614
 615 void spiderbot_headfade()
 616 {
 617         self.think = spiderbot_headfade;
 618         self.nextthink = self.fade_time;
 619         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 620
 621         if(self.cnt < time || self.alpha < 0.1)
 622         {
 623                 if(self.alpha > 0.1)
 624                 {
 625                         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 626                         pointparticles(particleeffectnum("explosion_big"), self.origin + '0 0 100', '0 0 0', 1);
 627                 }
 628                 remove(self);
 629         }
 630 }
 631
 632 void spiderbot_blowup()
 633 {
 634         if(self.cnt > time)
 635         {
 636                 if(random() < 0.1)
 637                 {
 638                         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 639                         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 640                 }
 641                 self.nextthink = time + 0.1;
 642                 return;
 643         }
 644
 645         entity h, g1, g2, b;
 646         b = spawn();
 647         h = spawn();
 648         g1 = spawn();
 649         g2 = spawn();
 650
 651         setmodel(b, "models/vehicles/spiderbot.dpm");
 652         setmodel(h, "models/vehicles/spiderbot_top.dpm");
 653         setmodel(g1, "models/vehicles/spiderbot_barrels.dpm");
 654         setmodel(g2, "models/vehicles/spiderbot_barrels.dpm");
 655
 656         setorigin(b, self.origin);
 657         b.frame = 11;
 658         b.angles = self.angles;
 659         setsize(b, self.mins, self.maxs);
 660
 661         setorigin(h, gettaginfo(self, gettagindex(self, "tag_head")));
 662         h.movetype = MOVETYPE_BOUNCE;
 663         h.solid = SOLID_BBOX;
 664         h.velocity = v_up * (500 + random() * 500) + randomvec() * 128;
 665         h.modelflags = MF_ROCKET;
 666         h.effects = EF_FLAME | EF_LOWPRECISION;
 667         h.avelocity = randomvec() * 360;
 668
 669         h.alpha = 1;
 670         h.cnt = time + (3.5 * random());
 671         h.fade_rate = 1 / min(self.respawntime, 10);
 672         h.fade_time = time;
 673         h.think = spiderbot_headfade;
 674         h.nextthink = time;
 675
 676         setorigin(g1, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint01")));
 677         g1.movetype = MOVETYPE_TOSS;
 678         g1.solid = SOLID_CORPSE;
 679         g1.velocity = v_forward * 700 + (randomvec() * 32);
 680         g1.avelocity = randomvec() * 180;
 681
 682         setorigin(g2, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint02")));
 683         g2.movetype = MOVETYPE_TOSS;
 684         g2.solid = SOLID_CORPSE;
 685         g2.velocity = v_forward * 700 + (randomvec() * 32);
 686         g2.avelocity = randomvec() * 180;
 687
 688         h.colormod = b.colormod = g1.colormod = g2.colormod = '-2 -2 -2';
 689
 690         SUB_SetFade(b,  time + 5, min(self.respawntime, 1));
 691         //SUB_SetFade(h,  time, min(self.respawntime, 10));
 692         SUB_SetFade(g1, time, min(self.respawntime, 10));
 693         SUB_SetFade(g2, time, min(self.respawntime, 10));
 694
 695         RadiusDamage (self, self.enemy, 250, 15, 250, world, 250, DEATH_VH_SPID_DEATH, world);
 696
 697         self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = -1;
 698         self.movetype = MOVETYPE_NONE;
 699         self.deadflag = DEAD_DEAD;
 700         self.solid = SOLID_NOT;
 701         self.tur_head.effects &= ~EF_FLAME;
 702         self.vehicle_hudmodel.viewmodelforclient = self;
 703 }
 704
 705 float spiderbot_impulse(float _imp)
 706 {
 707         switch(_imp)
 708         {
 709                 case 10:
 710                 case 15:
 711                 case 18:
 712                         self.vehicle.vehicle_weapon2mode += 1;
 713                         if(self.vehicle.vehicle_weapon2mode > SBRM_LAST)
 714                                 self.vehicle.vehicle_weapon2mode = SBRM_FIRST;
 715
 716                         //centerprint(self, strcat("Rocket mode is ", ftos(self.vehicle.vehicle_weapon2mode)));
 717                         CSQCVehicleSetup(self, 0);
 718                         return TRUE;
 719                 case 12:
 720                 case 16:
 721                 case 19:
 722                         self.vehicle.vehicle_weapon2mode -= 1;
 723                         if(self.vehicle.vehicle_weapon2mode < SBRM_FIRST)
 724                                 self.vehicle.vehicle_weapon2mode = SBRM_LAST;
 725
 726                         //centerprint(self, strcat("Rocket mode is ", ftos(self.vehicle.vehicle_weapon2mode)));
 727                         CSQCVehicleSetup(self, 0);
 728                         return TRUE;
 729
 730                 /*
 731                 case 17: // toss gun, could be used to exit?
 732                         break;
 733                 case 20: // Manual minigun reload?
 734                         break;
 735                 */
 736         }
 737         return FALSE;
 738 }
 739
 740 void spawnfunc_vehicle_spiderbot()
 741 {
 742         if not(autocvar_g_vehicle_spiderbot) { remove(self); return; }
 743         if not(vehicle_initialize(VEH_SPIDERBOT, FALSE)) { remove(self); return; }
 744 }
 745
 746 float v_spiderbot(float req)
 747 {
 748         switch(req)
 749         {
 750                 case VR_IMPACT:
 751                 {
 752                         if(autocvar_g_vehicle_spiderbot_bouncepain)
 753                                 vehicles_impact(autocvar_g_vehicle_spiderbot_bouncepain_x, autocvar_g_vehicle_spiderbot_bouncepain_y, autocvar_g_vehicle_spiderbot_bouncepain_z);
 754
 755                         return TRUE;
 756                 }
 757                 case VR_ENTER:
 758                 {
 759                         self.vehicle_weapon2mode = SBRM_GUIDE;
 760                         self.movetype = MOVETYPE_WALK;
 761                         CSQCVehicleSetup(self.owner, 0);
 762                         self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_spiderbot_health) * 100;
 763                         self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_spiderbot_shield) * 100;
 764
 765                         if(self.owner.flagcarried)
 766                         {
 767                                 setattachment(self.owner.flagcarried, self.tur_head, "");
 768                                 setorigin(self.owner.flagcarried, '-20 0 120');
 769                         }
 770
 771                         return TRUE;
 772                 }
 773                 case VR_THINK:
 774                 {
 775                         if(self.flags & FL_ONGROUND)
 776                                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 777
 778                         return TRUE;
 779                 }
 780                 case VR_DEATH:
 781                 {
 782                         self.health                             = 0;
 783                         self.event_damage               = func_null;
 784                         self.takedamage                 = DAMAGE_NO;
 785                         self.touch                              = func_null;
 786                         self.cnt                                = 3.4 + time + random() * 2;
 787                         self.think                              = spiderbot_blowup;
 788                         self.nextthink                  = time;
 789                         self.deadflag                   = DEAD_DYING;
 790                         self.frame                              = 5;
 791                         self.tur_head.effects  |= EF_FLAME;
 792                         self.colormod                   = self.tur_head.colormod = '-1 -1 -1';
 793                         self.frame                              = 10;
 794                         self.movetype                   = MOVETYPE_TOSS;
 795
 796                         return TRUE;
 797                 }
 798                 case VR_SPAWN:
 799                 {
 800                         if not(self.gun1)
 801                         {
 802                                 self.vehicles_impulse = spiderbot_impulse;
 803                                 self.gun1 = spawn();
 804                                 self.gun2 = spawn();
 805                                 setmodel(self.gun1, "models/vehicles/spiderbot_barrels.dpm");
 806                                 setmodel(self.gun2, "models/vehicles/spiderbot_barrels.dpm");
 807                                 setattachment(self.gun1, self.tur_head, "tag_hardpoint01");
 808                                 setattachment(self.gun2, self.tur_head, "tag_hardpoint02");
 809                                 self.gravity = 2;
 810                                 self.mass = 5000;
 811                         }
 812
 813                         self.frame = 5;
 814                         self.tur_head.frame = 1;
 815                         self.movetype = MOVETYPE_WALK;
 816                         self.solid = SOLID_SLIDEBOX;
 817                         self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = 1;
 818                         self.tur_head.angles = '0 0 0';
 819                         self.vehicle_exit = spiderbot_exit;
 820
 821                         setorigin(self, self.pos1 + '0 0 128');
 822                         self.angles = self.pos2;
 823                         self.damageforcescale = 0.03;
 824                         self.vehicle_health = autocvar_g_vehicle_spiderbot_health;
 825                         self.vehicle_shield = autocvar_g_vehicle_spiderbot_shield;
 826
 827                         self.PlayerPhysplug = spiderbot_frame;
 828
 829                         return TRUE;
 830                 }
 831                 case VR_SETUP:
 832                 {
 833                         if(autocvar_g_vehicle_spiderbot_shield)
 834                                 self.vehicle_flags |= VHF_HASSHIELD;
 835
 836                         if(autocvar_g_vehicle_spiderbot_shield_regen)
 837                                 self.vehicle_flags |= VHF_SHIELDREGEN;
 838
 839                         if(autocvar_g_vehicle_spiderbot_health_regen)
 840                                 self.vehicle_flags |= VHF_HEALTHREGEN;
 841
 842                         self.respawntime = autocvar_g_vehicle_spiderbot_respawntime;
 843                         self.vehicle_health = autocvar_g_vehicle_spiderbot_health;
 844                         self.vehicle_shield = autocvar_g_vehicle_spiderbot_shield;
 845                         self.max_health = self.vehicle_health;
 846
 847                         return TRUE;
 848                 }
 849                 case VR_PRECACHE:
 850                 {
 851                         precache_model ("models/vhshield.md3");
 852                         precache_model ("models/vehicles/spiderbot.dpm");
 853                         precache_model ("models/vehicles/spiderbot_top.dpm");
 854                         precache_model ("models/vehicles/spiderbot_barrels.dpm");
 855                         precache_model ("models/vehicles/spiderbot_cockpit.dpm");
 856                         precache_model ( "models/uziflash.md3");
 857
 858                         precache_sound ("weapons/uzi_fire.wav" );
 859                         precache_sound ("weapons/rocket_impact.wav");
 860
 861                         precache_sound ("vehicles/spiderbot_die.wav");
 862                         precache_sound ("vehicles/spiderbot_idle.wav");
 863                         precache_sound ("vehicles/spiderbot_jump.wav");
 864                         precache_sound ("vehicles/spiderbot_strafe.wav");
 865                         precache_sound ("vehicles/spiderbot_walk.wav");
 866                         precache_sound ("vehicles/spiderbot_land.wav");
 867                         return TRUE;
 868                 }
 869         }
 870
 871         return TRUE;
 872 }
 873
 874 #endif // SVQC
 875 #ifdef CSQC
 876
 877 #define spider_ico  "gfx/vehicles/sbot.tga"
 878 #define spider_rkt  "gfx/vehicles/sbot_rpods.tga"
 879 #define spider_mgun "gfx/vehicles/sbot_mguns.tga"
 880 string spider_xhair; // = "gfx/vehicles/axh-special1.tga";
 881
 882 #define SBRM_FIRST 1
 883 #define SBRM_VOLLY 1
 884 #define SBRM_GUIDE 2
 885 #define SBRM_ARTILLERY 3
 886 #define SBRM_LAST 3
 887
 888 float v_spiderbot(float req)
 889 {
 890         switch(req)
 891         {
 892                 case VR_HUD:
 893                 {
 894                         if(autocvar_r_letterbox)
 895                                 return TRUE;
 896
 897                         vector picsize, hudloc = '0 0 0', pic2size, picloc;
 898                         float i;
 899
 900                         // Fetch health & ammo stats
 901                         HUD_GETVEHICLESTATS
 902
 903                         picsize = draw_getimagesize(hud_bg) * autocvar_cl_vehicles_hudscale;
 904                         hudloc_y = vid_conheight - picsize_y;
 905                         hudloc_x = vid_conwidth * 0.5 - picsize_x * 0.5;
 906
 907                         drawpic(hudloc, hud_bg, picsize, '1 1 1', autocvar_cl_vehicles_hudalpha, DRAWFLAG_NORMAL);
 908
 909                         ammo1   *= 0.01;
 910                         shield  *= 0.01;
 911                         vh_health  *= 0.01;
 912                         reload2 *= 0.01;
 913
 914                         pic2size = draw_getimagesize(spider_ico) * (autocvar_cl_vehicles_hudscale * 0.8);
 915                         picloc = picsize * 0.5 - pic2size * 0.5;
 916                         if(vh_health < 0.25)
 917                                 drawpic(hudloc + picloc, spider_ico, pic2size,  '1 0 0' + '0 1 1' * sin(time * 8),  1, DRAWFLAG_NORMAL);
 918                         else
 919                                 drawpic(hudloc + picloc, spider_ico, pic2size,  '1 1 1' * vh_health  + '1 0 0' * (1 - vh_health),  1, DRAWFLAG_NORMAL);
 920                         drawpic(hudloc + picloc, spider_rkt, pic2size,  '1 1 1' * reload2 + '1 0 0' * (1 - reload2), 1, DRAWFLAG_NORMAL);
 921                         drawpic(hudloc + picloc, spider_mgun, pic2size, '1 1 1' * ammo1   + '1 0 0' * (1 - ammo1),   1, DRAWFLAG_NORMAL);
 922                         drawpic(hudloc + picloc, hud_sh, pic2size,  '1 1 1', shield, DRAWFLAG_NORMAL);
 923
 924                 // Health bar
 925                         picsize = draw_getimagesize(hud_hp_bar) * autocvar_cl_vehicles_hudscale;
 926                         picloc = '69 69 0' * autocvar_cl_vehicles_hudscale;
 927                         drawsetcliparea(hudloc_x + picloc_x + (picsize_x * (1 - vh_health)), 0, vid_conwidth, vid_conheight);
 928                         drawpic(hudloc + picloc, hud_hp_bar, picsize, '1 1 1', 1 , DRAWFLAG_NORMAL);
 929                         drawresetcliparea();
 930                 // ..  and icon
 931                         picsize = draw_getimagesize(hud_hp_ico) * autocvar_cl_vehicles_hudscale;
 932                         picloc = '37 65 0' * autocvar_cl_vehicles_hudscale;
 933                         if(vh_health < 0.25)
 934                         {
 935                                 if(alarm1time < time)
 936                                 {
 937                                         alarm1time = time + 2;
 938                                         sound(self, CH_PAIN_SINGLE, "vehicles/alarm.wav", VOL_BASEVOICE, ATTEN_NONE);
 939                                 }
 940                                 drawpic(hudloc + picloc, hud_hp_ico, picsize, '1 0 0' + '0 1 1' * sin(time * 8), 1, DRAWFLAG_NORMAL);
 941                         }
 942                         else
 943                         {
 944                                 drawpic(hudloc + picloc, hud_hp_ico, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 945                                 if(alarm1time)
 946                                 {
 947                                         sound(self, CH_PAIN_SINGLE, "misc/null.wav", VOL_BASEVOICE, ATTEN_NONE);
 948                                         alarm1time = 0;
 949                                 }
 950                         }
 951                 // Shield bar
 952                         picsize = draw_getimagesize(hud_sh_bar) * autocvar_cl_vehicles_hudscale;
 953                         picloc = '69 140 0' * autocvar_cl_vehicles_hudscale;
 954                         drawsetcliparea(hudloc_x + picloc_x + (picsize_x * (1 - shield)), 0, vid_conwidth, vid_conheight);
 955                         drawpic(hudloc + picloc, hud_sh_bar, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 956                         drawresetcliparea();
 957                 // ..  and icon
 958                         picloc = '40 136 0' * autocvar_cl_vehicles_hudscale;
 959                         picsize = draw_getimagesize(hud_sh_ico) * autocvar_cl_vehicles_hudscale;
 960                         if(shield < 0.25)
 961                         {
 962                                 if(alarm2time < time)
 963                                 {
 964                                         alarm2time = time + 1;
 965                                         sound(self, CH_TRIGGER_SINGLE, "vehicles/alarm_shield.wav", VOL_BASEVOICE, ATTEN_NONE);
 966                                 }
 967                                 drawpic(hudloc + picloc, hud_sh_ico, picsize, '1 0 0' + '0 1 1' * sin(time * 8), 1, DRAWFLAG_NORMAL);
 968                         }
 969                         else
 970                         {
 971                                 drawpic(hudloc + picloc, hud_sh_ico, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 972                                 if(alarm2time)
 973                                 {
 974                                         sound(self, CH_TRIGGER_SINGLE, "misc/null.wav", VOL_BASEVOICE, ATTEN_NONE);
 975                                         alarm2time = 0;
 976                                 }
 977                         }
 978
 979                 // Minigun bar
 980                         picsize = draw_getimagesize(hud_ammo1_bar) * autocvar_cl_vehicles_hudscale;
 981                         picloc = '450 69 0' * autocvar_cl_vehicles_hudscale;
 982                         drawsetcliparea(hudloc_x + picloc_x, picloc_y, picsize_x * ammo1, vid_conheight);
 983                         drawpic(hudloc + picloc, hud_ammo1_bar, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 984                         drawresetcliparea();
 985                 // ..  and icon
 986                         picsize = draw_getimagesize(hud_ammo1_ico) * autocvar_cl_vehicles_hudscale;
 987                         picloc = '664 60 0' * autocvar_cl_vehicles_hudscale;
 988                         if(ammo1 < 0.2)
 989                                 drawpic(hudloc + picloc, hud_ammo1_ico, picsize, '1 0 0' + '0 1 1' * sin(time * 8), 1, DRAWFLAG_NORMAL);
 990                         else
 991                                 drawpic(hudloc + picloc, hud_ammo1_ico, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 992
 993                 // Rocket ammo bar
 994                         picsize = draw_getimagesize(hud_ammo2_bar) * autocvar_cl_vehicles_hudscale;
 995                         ammo1 = picsize_x / 8;
 996                         picloc = '450 140 0' * autocvar_cl_vehicles_hudscale;
 997                         drawsetcliparea(hudloc_x + picloc_x, hudloc_y + picloc_y, picsize_x * reload2, vid_conheight);
 998                         drawpic(hudloc + picloc, hud_ammo2_bar, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 999                         drawresetcliparea();
1000
1001                 // ..  and icons
1002                         pic2size = 0.35 * draw_getimagesize(hud_ammo2_ico) * autocvar_cl_vehicles_hudscale;
1003                         picloc_x -= pic2size_x;
1004                         picloc_y += pic2size_y * 2.25;
1005                         if(ammo2 == 9)
1006                         {
1007                                 for(i = 1; i < 9; ++i)
1008                                 {
1009                                         picloc_x += ammo1;
1010                                         drawpic(hudloc + picloc, hud_ammo2_ico, pic2size, ((8 * reload2 <= i) ? '0 0 0' : '1 1 1'), 0.75, DRAWFLAG_NORMAL);
1011                                 }
1012                         }
1013                         else
1014                         {
1015                                 for(i = 1; i < 9; ++i)
1016                                 {
1017                                         picloc_x += ammo1;
1018                                         drawpic(hudloc + picloc, hud_ammo2_ico, pic2size, ((i >= ammo2) ? '1 1 1' : '0 0 0'), 0.75, DRAWFLAG_NORMAL);
1019                                 }
1020                         }
1021                         pic2size = draw_getimagesize(hud_ammo2_ico) * autocvar_cl_vehicles_hudscale;
1022                         picloc = '664 130 0' * autocvar_cl_vehicles_hudscale;
1023                         if(ammo2 == 9)
1024                                 drawpic(hudloc + picloc, hud_ammo2_ico, pic2size, '1 0 0' + '0 1 1' * sin(time * 8), 1, DRAWFLAG_NORMAL);
1025                         else
1026                                 drawpic(hudloc + picloc, hud_ammo2_ico, pic2size, '1 1 1', 1, DRAWFLAG_NORMAL);
1027
1028                         if (scoreboard_showscores)
1029                                 HUD_DrawScoreboard();
1030                         else
1031                         {
1032                                 switch(weapon2mode)
1033                                 {
1034                                         case SBRM_VOLLY:
1035                                                 spider_xhair = "gfx/vehicles/axh-bracket.tga";
1036                                                 break;
1037                                         case SBRM_GUIDE:
1038                                                 spider_xhair = "gfx/vehicles/axh-cross.tga";
1039                                                 break;
1040                                         case SBRM_ARTILLERY:
1041                                                 spider_xhair = "gfx/vehicles/axh-tag.tga";
1042                                                 break;
1043                                         default:
1044                                                 spider_xhair= "gfx/vehicles/axh-tag.tga";
1045                                 }
1046
1047                                 picsize = draw_getimagesize(spider_xhair);
1048                                 picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1049                                 picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1050
1051                                 drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), spider_xhair, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_ADDITIVE);
1052                         }
1053
1054                         return TRUE;
1055                 }
1056                 case VR_SETUP:
1057                 {
1058                         // Minigun1
1059                         AuxiliaryXhair[0].axh_image   = "gfx/vehicles/axh-ring.tga";
1060                         AuxiliaryXhair[0].axh_scale   = 0.25;
1061                         // Minigun2
1062                         AuxiliaryXhair[1].axh_image   = "gfx/vehicles/axh-ring.tga";
1063                         AuxiliaryXhair[1].axh_scale   = 0.25;
1064                         // Rocket
1065                         AuxiliaryXhair[2].axh_image   = "gfx/vehicles/axh-special1.tga";
1066                         AuxiliaryXhair[2].axh_scale   = 0.5;
1067
1068                         return TRUE;
1069                 }
1070                 case VR_PRECACHE:
1071                 {
1072                         precache_model ("models/vhshield.md3");
1073                         precache_model ("models/vehicles/spiderbot.dpm");
1074                         precache_model ("models/vehicles/spiderbot_top.dpm");
1075                         precache_model ("models/vehicles/spiderbot_barrels.dpm");
1076                         precache_model ("models/vehicles/spiderbot_cockpit.dpm");
1077                         return TRUE;
1078                 }
1079         }
1080
1081         return TRUE;
1082 }
1083
1084 #endif // CSQC
1085 #endif // REGISTER_VEHICLE