qcsrc/common/vehicles/vehicle/raptor.qc

   1 #ifndef VEHICLE_RAPTOR
   2 #define VEHICLE_RAPTOR
   3 #include "raptor.qh"
   4
   5 #include "raptor_weapons.qh"
   6
   7 CLASS(Raptor, Vehicle)
   8 /* spawnflags */ ATTRIB(Raptor, spawnflags, int, VHF_DMGSHAKE | VHF_DMGROLL);
   9 /* mins       */ ATTRIB(Raptor, mins, vector, '-80 -80 0');
  10 /* maxs       */ ATTRIB(Raptor, maxs, vector, '80 80 70');
  11 /* view offset*/ ATTRIB(Raptor, view_ofs, vector, '0 0 160');
  12 /* view dist  */ ATTRIB(Raptor, height, float, 200);
  13 /* model          */ ATTRIB(Raptor, mdl, string, "models/vehicles/raptor.dpm");
  14 /* model          */ ATTRIB(Raptor, model, string, "models/vehicles/raptor.dpm");
  15 /* head_model */ ATTRIB(Raptor, head_model, string, "");
  16 /* hud_model  */ ATTRIB(Raptor, hud_model, string, "models/vehicles/raptor_cockpit.dpm");
  17 /* tags       */ ATTRIB(Raptor, tag_head, string, "");
  18 /* tags       */ ATTRIB(Raptor, tag_hud, string, "tag_hud");
  19 /* tags       */ ATTRIB(Raptor, tag_view, string, "tag_camera");
  20 /* netname    */ ATTRIB(Raptor, netname, string, "raptor");
  21 /* fullname   */ ATTRIB(Raptor, vehicle_name, string, _("Raptor"));
  22 /* icon       */ ATTRIB(Raptor, m_icon, string, "vehicle_raptor");
  23 ENDCLASS(Raptor)
  24 REGISTER_VEHICLE(RAPTOR, NEW(Raptor));
  25
  26 #endif
  27
  28 #ifdef IMPLEMENTATION
  29
  30 #ifdef SVQC
  31
  32 bool autocvar_g_vehicle_raptor = true;
  33
  34 float autocvar_g_vehicle_raptor_respawntime = 40;
  35 float autocvar_g_vehicle_raptor_takeofftime = 1.5;
  36
  37 // 0: go where player aims, +forward etc relative to aim angles
  38 // 1: ignore aim for up/down movement. +forward always moved forward, +jump always moves up
  39 int autocvar_g_vehicle_raptor_movestyle = 1;
  40 float autocvar_g_vehicle_raptor_turnspeed = 200;
  41 float autocvar_g_vehicle_raptor_pitchspeed = 50;
  42 float autocvar_g_vehicle_raptor_pitchlimit = 45;
  43
  44 float autocvar_g_vehicle_raptor_speed_forward = 1700;
  45 float autocvar_g_vehicle_raptor_speed_strafe = 900;
  46 float autocvar_g_vehicle_raptor_speed_up = 1700;
  47 float autocvar_g_vehicle_raptor_speed_down = 1700;
  48 float autocvar_g_vehicle_raptor_friction = 2;
  49
  50 float autocvar_g_vehicle_raptor_cannon_turnspeed = 120;
  51 float autocvar_g_vehicle_raptor_cannon_turnlimit = 20;
  52 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up = 12;
  53 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down = 32;
  54
  55 float autocvar_g_vehicle_raptor_cannon_locktarget = 0;
  56 float autocvar_g_vehicle_raptor_cannon_locking_time = 0.2;
  57 float autocvar_g_vehicle_raptor_cannon_locking_releasetime = 0.45;
  58 float autocvar_g_vehicle_raptor_cannon_locked_time = 1;
  59 float autocvar_g_vehicle_raptor_cannon_predicttarget = 1;
  60
  61 float autocvar_g_vehicle_raptor_energy = 100;
  62 float autocvar_g_vehicle_raptor_energy_regen = 25;
  63 float autocvar_g_vehicle_raptor_energy_regen_pause = 0.25;
  64
  65 float autocvar_g_vehicle_raptor_health = 150;
  66 float autocvar_g_vehicle_raptor_health_regen = 0;
  67 float autocvar_g_vehicle_raptor_health_regen_pause = 0;
  68
  69 float autocvar_g_vehicle_raptor_shield = 75;
  70 float autocvar_g_vehicle_raptor_shield_regen = 25;
  71 float autocvar_g_vehicle_raptor_shield_regen_pause = 1.5;
  72
  73 float autocvar_g_vehicle_raptor_bouncefactor = 0.2;
  74 float autocvar_g_vehicle_raptor_bouncestop = 0;
  75 vector autocvar_g_vehicle_raptor_bouncepain = '1 4 1000';
  76
  77 .entity bomb1;
  78 .entity bomb2;
  79
  80 float raptor_altitude(float amax)
  81 {SELFPARAM();
  82         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  83         return vlen(self.origin - trace_endpos);
  84 }
  85
  86 void raptor_land()
  87 {SELFPARAM();
  88         float hgt;
  89
  90         hgt = raptor_altitude(512);
  91         self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
  92         self.angles_x *= 0.95;
  93         self.angles_z *= 0.95;
  94
  95         if(hgt < 128)
  96         if(hgt > 0)
  97                 self.frame = (hgt / 128) * 25;
  98
  99         self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 100         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 101
 102         if(hgt < 16)
 103         {
 104                 self.movetype = MOVETYPE_TOSS;
 105                 self.think      = vehicles_think;
 106                 self.frame      = 0;
 107         }
 108
 109         self.nextthink  = time;
 110
 111         CSQCMODEL_AUTOUPDATE(self);
 112 }
 113
 114 void raptor_exit(float eject)
 115 {SELFPARAM();
 116         vector spot;
 117         self.tur_head.exteriormodeltoclient = world;
 118
 119         if(!IS_DEAD(self))
 120         {
 121                 self.think        = raptor_land;
 122                 self.nextthink  = time;
 123         }
 124
 125         if(!self.owner)
 126                 return;
 127
 128         makevectors(self.angles);
 129         if(eject)
 130         {
 131                 spot = self.origin + v_forward * 100 + '0 0 64';
 132                 spot = vehicles_findgoodexit(spot);
 133                 setorigin(self.owner , spot);
 134                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 135                 self.owner.oldvelocity = self.owner.velocity;
 136         }
 137         else
 138         {
 139                 if(vdist(self.velocity, >, 2 * autocvar_sv_maxairspeed))
 140                 {
 141                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 142                         self.owner.velocity_z += 200;
 143                         spot = self.origin + v_forward * 32 + '0 0 64';
 144                         spot = vehicles_findgoodexit(spot);
 145                 }
 146                 else
 147                 {
 148                         self.owner.velocity = self.velocity * 0.5;
 149                         self.owner.velocity_z += 10;
 150                         spot = self.origin - v_forward * 200 + '0 0 64';
 151                         spot = vehicles_findgoodexit(spot);
 152                 }
 153                 self.owner.oldvelocity = self.owner.velocity;
 154                 setorigin(self.owner , spot);
 155         }
 156
 157         antilag_clear(self.owner, CS(self.owner));
 158         self.owner = world;
 159 }
 160
 161 bool raptor_frame(entity this)
 162 {
 163         entity vehic = this.vehicle;
 164         return = true;
 165
 166         if(intermission_running)
 167         {
 168                 vehic.velocity = '0 0 0';
 169                 vehic.avelocity = '0 0 0';
 170                 return;
 171         }
 172
 173         vehicles_frame(vehic, this);
 174
 175         float ftmp = 0;
 176         /*
 177         ftmp = vlen(vehic.velocity);
 178         if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 179                 ftmp = 1;
 180         else
 181                 ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 182         */
 183
 184         if(vehic.sound_nexttime < time)
 185         {
 186                 vehic.sound_nexttime = time + 7.955812;
 187                 //sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_FLY, 1 - ftmp,   ATTEN_NORM );
 188                 sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, 1, ATTEN_NORM);
 189                 vehic.wait = ftmp;
 190         }
 191         /*
 192         else if(fabs(ftmp - vehic.wait) > 0.2)
 193         {
 194                 sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_Null, 1 - ftmp,   ATTEN_NORM );
 195                 sound (vehic, CH_TRIGGER_SINGLE, SND_Null, ftmp, ATTEN_NORM);
 196                 vehic.wait = ftmp;
 197         }
 198         */
 199
 200         if(IS_DEAD(vehic))
 201         {
 202                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 203                 return;
 204         }
 205         crosshair_trace(this);
 206
 207         //if(time - vehic.lastteleporttime < 1)
 208         //{
 209                 if(vehic.angles_z > 50 || vehic.angles_z < -50)
 210                 {
 211                         if(PHYS_INPUT_BUTTON_JUMP(this))
 212                         {
 213                                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 214                                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 215                         }
 216                 }
 217         //}
 218
 219         vector vang;
 220         vang = vehic.angles;
 221         vector df = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 222         vang_x *= -1;
 223         df_x *= -1;
 224         if(df_x > 180)  df_x -= 360;
 225         if(df_x < -180) df_x += 360;
 226         if(df_y > 180)  df_y -= 360;
 227         if(df_y < -180) df_y += 360;
 228
 229         ftmp = shortangle_f(this.v_angle_y - vang_y, vang_y);
 230         if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 231         vehic.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + vehic.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 232
 233         // Pitch
 234         ftmp = 0;
 235         if(this.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 236         else if(this.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 237
 238         df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 239         ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 240         vehic.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + vehic.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 241
 242         vehic.angles_x = anglemods(vehic.angles_x);
 243         vehic.angles_y = anglemods(vehic.angles_y);
 244         vehic.angles_z = anglemods(vehic.angles_z);
 245
 246         if(autocvar_g_vehicle_raptor_movestyle == 1)
 247                 makevectors('0 1 0' * vehic.angles_y);
 248         else
 249                 makevectors(this.v_angle);
 250
 251         df = vehic.velocity * -autocvar_g_vehicle_raptor_friction;
 252
 253         if(this.movement_x != 0)
 254         {
 255                 if(this.movement_x > 0)
 256                         df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 257                 else if(this.movement_x < 0)
 258                         df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 259         }
 260
 261         if(this.movement_y != 0)
 262         {
 263                 if(this.movement_y < 0)
 264                         df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 265                 else if(this.movement_y > 0)
 266                         df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 267
 268                 vehic.angles_z = bound(-30,vehic.angles_z + (this.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 269         }
 270         else
 271         {
 272                 vehic.angles_z *= 0.95;
 273                 if(vehic.angles_z >= -1 && vehic.angles_z <= -1)
 274                         vehic.angles_z = 0;
 275         }
 276
 277         if(PHYS_INPUT_BUTTON_CROUCH(this))
 278                 df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 279         else if (PHYS_INPUT_BUTTON_JUMP(this))
 280                 df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 281
 282         vehic.velocity  += df * frametime;
 283         this.velocity = this.movement  = vehic.velocity;
 284         setorigin(this, vehic.origin + '0 0 32');
 285
 286         this.vehicle_weapon2mode = vehic.vehicle_weapon2mode;
 287
 288         vector vf, ad;
 289         // Target lock & predict
 290         if(autocvar_g_vehicle_raptor_cannon_locktarget == 2)
 291         {
 292                 if(vehic.gun1.lock_time < time || IS_DEAD(vehic.gun1.enemy) || STAT(FROZEN, vehic.gun1.enemy))
 293                         vehic.gun1.enemy = world;
 294
 295                 if(trace_ent)
 296                 if(trace_ent.movetype)
 297                 if(trace_ent.takedamage)
 298                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 299                 {
 300                         if(teamplay)
 301                         {
 302                                 if(trace_ent.team != this.team)
 303                                 {
 304                                         vehic.gun1.enemy = trace_ent;
 305                                         vehic.gun1.lock_time = time + 5;
 306                                 }
 307                         }
 308                         else
 309                         {
 310                                 vehic.gun1.enemy = trace_ent;
 311                                 vehic.gun1.lock_time = time + 0.5;
 312                         }
 313                 }
 314
 315                 if(vehic.gun1.enemy)
 316                 {
 317                         float distance, impact_time;
 318
 319                         vf = real_origin(vehic.gun1.enemy);
 320                         UpdateAuxiliaryXhair(this, vf, '1 0 0', 1);
 321                         vector _vel = vehic.gun1.enemy.velocity;
 322                         if(vehic.gun1.enemy.movetype == MOVETYPE_WALK)
 323                                 _vel_z *= 0.1;
 324
 325                         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 326                         {
 327                                 ad = vf;
 328                                 distance = vlen(ad - this.origin);
 329                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 330                                 ad = vf + _vel * impact_time;
 331                                 trace_endpos = ad;
 332                         }
 333                         else
 334                                 trace_endpos = vf;
 335                 }
 336         }
 337         else if(autocvar_g_vehicle_raptor_cannon_locktarget == 1)
 338         {
 339
 340                 vehicles_locktarget(vehic, (1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 341                                                          (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 342                                                          autocvar_g_vehicle_raptor_cannon_locked_time);
 343
 344                 if(vehic.lock_target != world)
 345                 if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 346                 if(vehic.lock_strength == 1)
 347                 {
 348                         float i, distance, impact_time;
 349
 350                         vf = real_origin(vehic.lock_target);
 351                         ad = vf;
 352                         for(i = 0; i < 4; ++i)
 353                         {
 354                                 distance = vlen(ad - vehic.origin);
 355                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 356                                 ad = vf + vehic.lock_target.velocity * impact_time;
 357                         }
 358                         trace_endpos = ad;
 359                 }
 360
 361                 if(vehic.lock_target)
 362                 {
 363                         if(vehic.lock_strength == 1)
 364                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '1 0 0', 1);
 365                         else if(vehic.lock_strength > 0.5)
 366                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 1 0', 1);
 367                         else if(vehic.lock_strength < 0.5)
 368                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 0 1', 1);
 369                 }
 370         }
 371
 372
 373         vehicle_aimturret(vehic, trace_endpos, vehic.gun1, "fire1",
 374                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 375                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 376
 377         vehicle_aimturret(vehic, trace_endpos, vehic.gun2, "fire1",
 378                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 379                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 380
 381         /*
 382         ad = ad * 0.5;
 383         v_forward = vf * 0.5;
 384         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, vehic);
 385         UpdateAuxiliaryXhair(this, trace_endpos, '0 1 0', 0);
 386         */
 387
 388         // TODO: fix wr_checkammo and its use of self!
 389         setself(vehic);
 390
 391         Weapon wep1 = WEP_RAPTOR;
 392         if(!forbidWeaponUse(this))
 393         if(PHYS_INPUT_BUTTON_ATCK(this))
 394         if (wep1.wr_checkammo1(wep1))
 395         {
 396             .entity weaponentity = weaponentities[0];
 397                 wep1.wr_think(wep1, vehic, weaponentity, 1);
 398         }
 399
 400         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 401                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 402
 403         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 404                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 405
 406         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 407                 vehicles_regen(vehic, vehic.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 408
 409         Weapon wep2a = WEP_RAPTOR_BOMB;
 410         if(!forbidWeaponUse(this))
 411         if(vehic.vehicle_weapon2mode == RSM_BOMB)
 412         {
 413                 if(time > vehic.lip + autocvar_g_vehicle_raptor_bombs_refire)
 414                 if(PHYS_INPUT_BUTTON_ATCK2(this))
 415                 {
 416                     .entity weaponentity = weaponentities[1];
 417                         wep2a.wr_think(wep2a, vehic, weaponentity, 2);
 418                         vehic.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 419                         vehic.lip   = time;
 420                 }
 421         }
 422         else
 423         {
 424                 Weapon wep2b = WEP_RAPTOR_FLARE;
 425                 if(time > vehic.lip + autocvar_g_vehicle_raptor_flare_refire)
 426                 if(PHYS_INPUT_BUTTON_ATCK2(this))
 427                 {
 428                     .entity weaponentity = weaponentities[1];
 429                         wep2b.wr_think(wep2b, vehic, weaponentity, 2);
 430                         vehic.delay = time + autocvar_g_vehicle_raptor_flare_refire;
 431                         vehic.lip   = time;
 432                 }
 433         }
 434
 435         setself(this);
 436
 437         vehic.bomb1.alpha = vehic.bomb2.alpha = (time - vehic.lip) / (vehic.delay - vehic.lip);
 438         this.vehicle_reload2 = bound(0, vehic.bomb1.alpha * 100, 100);
 439         this.vehicle_ammo2 = (this.vehicle_reload2 == 100) ? 100 : 0;
 440
 441         if(vehic.bomb1.cnt < time)
 442         {
 443                 bool incoming = false;
 444                 FOREACH_ENTITY_ENT(enemy, vehic,
 445                 {
 446                         if(it.flags & FL_PROJECTILE)
 447                         if(MISSILE_IS_TRACKING(it))
 448                         if(vdist(vehic.origin - it.origin, <, 2 * autocvar_g_vehicle_raptor_flare_range))
 449                         {
 450                                 incoming = true;
 451                                 break;
 452                         }
 453                 });
 454
 455                 if(incoming)
 456                 {
 457                         msg_entity = this;
 458                         soundto(MSG_ONE, vehic, CH_PAIN_SINGLE, SND(VEH_MISSILE_ALARM), VOL_BASE, ATTEN_NONE);
 459                 }
 460
 461                 vehic.bomb1.cnt = time + 1;
 462         }
 463
 464
 465         VEHICLE_UPDATE_PLAYER(this, vehic, health, raptor);
 466         VEHICLE_UPDATE_PLAYER(this, vehic, energy, raptor);
 467         if(vehic.vehicle_flags & VHF_HASSHIELD)
 468                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, raptor);
 469
 470         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 471 }
 472
 473 bool raptor_takeoff(entity this)
 474 {
 475         entity vehic = this.vehicle;
 476         return = true;
 477
 478         vehic.nextthink = time;
 479         CSQCMODEL_AUTOUPDATE(vehic);
 480         vehic.nextthink = 0; // will this work?
 481
 482         if(vehic.sound_nexttime < time)
 483         {
 484                 vehic.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 485                 sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, VOL_VEHICLEENGINE, ATTEN_NORM);
 486         }
 487
 488         // Takeoff sequense
 489         if(vehic.frame < 25)
 490         {
 491                 vehic.frame += 25 / (autocvar_g_vehicle_raptor_takeofftime / sys_frametime);
 492                 vehic.velocity_z = min(vehic.velocity_z * 1.5, 256);
 493                 vehic.bomb1.gun1.avelocity_y = 90 + ((vehic.frame / 25) * 25000);
 494                 vehic.bomb1.gun2.avelocity_y = -vehic.bomb1.gun1.avelocity_y;
 495                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 496
 497                 setorigin(this, vehic.origin + '0 0 32');
 498         }
 499         else
 500                 this.PlayerPhysplug = raptor_frame;
 501
 502         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 503                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 504
 505         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 506                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 507
 508         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 509                 vehicles_regen(vehic, vehic.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 510
 511
 512         vehic.bomb1.alpha = vehic.bomb2.alpha = (time - vehic.lip) / (vehic.delay - vehic.lip);
 513         this.vehicle_reload2 = bound(0, vehic.bomb1.alpha * 100, 100);
 514         this.vehicle_ammo2 = (this.vehicle_reload2 == 100) ? 100 : 0;
 515
 516         VEHICLE_UPDATE_PLAYER(this, vehic, health, raptor);
 517         VEHICLE_UPDATE_PLAYER(this, vehic, energy, raptor);
 518         if(vehic.vehicle_flags & VHF_HASSHIELD)
 519                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, raptor);
 520
 521         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 522 }
 523
 524 void raptor_blowup()
 525 {SELFPARAM();
 526         self.deadflag   = DEAD_DEAD;
 527         self.vehicle_exit(VHEF_NORMAL);
 528         RadiusDamage (self, self.enemy, 250, 15, 250, world, world, 250, DEATH_VH_RAPT_DEATH.m_id, world);
 529
 530         self.alpha                = -1;
 531         self.movetype      = MOVETYPE_NONE;
 532         self.effects            = EF_NODRAW;
 533         self.colormod      = '0 0 0';
 534         self.avelocity    = '0 0 0';
 535         self.velocity      = '0 0 0';
 536
 537         setorigin(self, self.pos1);
 538         self.touch = func_null;
 539         self.nextthink = 0;
 540 }
 541
 542 void raptor_diethink()
 543 {SELFPARAM();
 544         if(time >= self.wait)
 545                 self.think = raptor_blowup;
 546
 547         if(random() < 0.05)
 548         {
 549                 sound (self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 550                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 551         }
 552         self.nextthink = time;
 553
 554         CSQCMODEL_AUTOUPDATE(self);
 555 }
 556
 557 // If we dont do this ever now and then, the raptors rotors
 558 // stop working, presumably due to angle overflow. cute.
 559 void raptor_rotor_anglefix()
 560 {SELFPARAM();
 561         self.gun1.angles_y = anglemods(self.gun1.angles_y);
 562         self.gun2.angles_y = anglemods(self.gun2.angles_y);
 563         self.nextthink = time + 15;
 564 }
 565
 566 float raptor_impulse(float _imp)
 567 {SELFPARAM();
 568         switch(_imp)
 569         {
 570                 case IMP_weapon_group_1.impulse:
 571                         self.vehicle.vehicle_weapon2mode = RSM_BOMB;
 572                         CSQCVehicleSetup(self, 0);
 573                         return true;
 574                 case IMP_weapon_group_2.impulse:
 575                         self.vehicle.vehicle_weapon2mode = RSM_FLARE;
 576                         CSQCVehicleSetup(self, 0);
 577                         return true;
 578
 579                 case IMP_weapon_next_byid.impulse:
 580                 case IMP_weapon_next_bypriority.impulse:
 581                 case IMP_weapon_next_bygroup.impulse:
 582                         self.vehicle.vehicle_weapon2mode += 1;
 583                         if(self.vehicle.vehicle_weapon2mode > RSM_LAST)
 584                                 self.vehicle.vehicle_weapon2mode = RSM_FIRST;
 585
 586                         CSQCVehicleSetup(self, 0);
 587                         return true;
 588                 case IMP_weapon_last.impulse:
 589                 case IMP_weapon_prev_byid.impulse:
 590                 case IMP_weapon_prev_bypriority.impulse:
 591                 case IMP_weapon_prev_bygroup.impulse:
 592                         self.vehicle.vehicle_weapon2mode -= 1;
 593                         if(self.vehicle.vehicle_weapon2mode < RSM_FIRST)
 594                                 self.vehicle.vehicle_weapon2mode = RSM_LAST;
 595
 596                         CSQCVehicleSetup(self, 0);
 597                         return true;
 598
 599                 /*
 600                 case IMP_weapon_drop.impulse: // toss gun, could be used to exit?
 601                         break;
 602                 case IMP_weapon_reload.impulse: // Manual minigun reload?
 603                         break;
 604                 */
 605         }
 606         return false;
 607 }
 608
 609 spawnfunc(vehicle_raptor)
 610 {
 611         if(!autocvar_g_vehicle_raptor) { remove(this); return; }
 612         if(!vehicle_initialize(this, VEH_RAPTOR, false)) { remove(this); return; }
 613 }
 614
 615 METHOD(Raptor, vr_impact, void(Raptor thisveh, entity instance))
 616 {
 617     if(autocvar_g_vehicle_raptor_bouncepain)
 618         vehicles_impact(instance, autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 619 }
 620 METHOD(Raptor, vr_enter, void(Raptor thisveh, entity instance))
 621 {
 622     SELFPARAM();
 623     self.vehicle_weapon2mode = RSM_BOMB;
 624     self.owner.PlayerPhysplug = raptor_takeoff;
 625     self.movetype          = MOVETYPE_BOUNCEMISSILE;
 626     self.solid            = SOLID_SLIDEBOX;
 627     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 628     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 629     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 630     self.tur_head.exteriormodeltoclient = self.owner;
 631
 632     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 633     self.lip   = time;
 634
 635     if(self.owner.flagcarried)
 636        setorigin(self.owner.flagcarried, '-20 0 96');
 637
 638     CSQCVehicleSetup(self.owner, 0);
 639 }
 640 METHOD(Raptor, vr_death, void(Raptor thisveh, entity instance))
 641 {
 642     instance.health                             = 0;
 643     instance.event_damage               = func_null;
 644     instance.solid                              = SOLID_CORPSE;
 645     instance.takedamage                 = DAMAGE_NO;
 646     instance.deadflag                   = DEAD_DYING;
 647     instance.movetype                   = MOVETYPE_BOUNCE;
 648     instance.think                              = raptor_diethink;
 649     instance.nextthink                  = time;
 650     instance.wait                               = time + 5 + (random() * 5);
 651
 652     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation (instance.origin, 16), '0 0 0', 1);
 653
 654     instance.velocity_z += 600;
 655
 656     instance.avelocity = '0 0.5 1' * (random() * 400);
 657     instance.avelocity -= '0 0.5 1' * (random() * 400);
 658
 659     instance.colormod = '-0.5 -0.5 -0.5';
 660     instance.touch = raptor_blowup;
 661 }
 662 METHOD(Raptor, vr_spawn, void(Raptor thisveh, entity instance))
 663 {
 664     SELFPARAM();
 665     if(!self.gun1)
 666     {
 667         entity spinner;
 668         vector ofs;
 669
 670         //FIXME: Camera is in a bad place in HUD model.
 671         //setorigin(self.vehicle_viewport, '25 0 5');
 672
 673         self.vehicles_impulse   = raptor_impulse;
 674
 675         self.frame = 0;
 676
 677         self.bomb1 = new(raptor_bomb);
 678         self.bomb2 = new(raptor_bomb);
 679         self.gun1  = new(raptor_gun);
 680         self.gun2  = new(raptor_gun);
 681
 682         setmodel(self.bomb1, MDL_VEH_RAPTOR_CB_FOLDED);
 683         setmodel(self.bomb2, MDL_VEH_RAPTOR_CB_FOLDED);
 684         setmodel(self.gun1, MDL_VEH_RAPTOR_GUN);
 685         setmodel(self.gun2, MDL_VEH_RAPTOR_GUN);
 686         setmodel(self.tur_head, MDL_VEH_RAPTOR_TAIL);
 687
 688         setattachment(self.bomb1, self, "bombmount_left");
 689         setattachment(self.bomb2, self, "bombmount_right");
 690         setattachment(self.tur_head, self,"root");
 691
 692         // FIXMODEL Guns mounts to angled bones
 693         self.bomb1.angles = self.angles;
 694         self.angles = '0 0 0';
 695         // This messes up gun-aim, so work arround it.
 696         //setattachment(self.gun1, self, "gunmount_left");
 697         ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 698         ofs -= self.origin;
 699         setattachment(self.gun1, self, "");
 700         setorigin(self.gun1, ofs);
 701
 702         //setattachment(self.gun2, self, "gunmount_right");
 703         ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 704         ofs -= self.origin;
 705         setattachment(self.gun2, self, "");
 706         setorigin(self.gun2, ofs);
 707
 708         self.angles = self.bomb1.angles;
 709         self.bomb1.angles = '0 0 0';
 710
 711         spinner = new(raptor_spinner);
 712         spinner.owner = self;
 713         setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 714         setattachment(spinner, self, "engine_left");
 715         spinner.movetype = MOVETYPE_NOCLIP;
 716         spinner.avelocity = '0 90 0';
 717         self.bomb1.gun1 = spinner;
 718
 719         spinner = new(raptor_spinner);
 720         spinner.owner = self;
 721         setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 722         setattachment(spinner, self, "engine_right");
 723         spinner.movetype = MOVETYPE_NOCLIP;
 724         spinner.avelocity = '0 -90 0';
 725         self.bomb1.gun2 = spinner;
 726
 727         // Sigh.
 728         self.bomb1.think = raptor_rotor_anglefix;
 729         self.bomb1.nextthink = time;
 730
 731         self.mass                          = 1 ;
 732     }
 733
 734     self.frame            = 0;
 735     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 736     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 737     self.movetype          = MOVETYPE_TOSS;
 738     self.solid            = SOLID_SLIDEBOX;
 739     self.vehicle_energy = 1;
 740
 741     self.PlayerPhysplug = raptor_frame;
 742
 743     self.bomb1.gun1.avelocity_y = 90;
 744     self.bomb1.gun2.avelocity_y = -90;
 745
 746     self.delay = time;
 747
 748     self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 749     self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 750     self.damageforcescale = 0.25;
 751     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 752     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 753 }
 754 METHOD(Raptor, vr_setup, void(Raptor thisveh, entity instance))
 755 {
 756     if(autocvar_g_vehicle_raptor_shield)
 757         instance.vehicle_flags |= VHF_HASSHIELD;
 758
 759     if(autocvar_g_vehicle_raptor_shield_regen)
 760         instance.vehicle_flags |= VHF_SHIELDREGEN;
 761
 762     if(autocvar_g_vehicle_raptor_health_regen)
 763         instance.vehicle_flags |= VHF_HEALTHREGEN;
 764
 765     if(autocvar_g_vehicle_raptor_energy_regen)
 766         instance.vehicle_flags |= VHF_ENERGYREGEN;
 767
 768     instance.vehicle_exit = raptor_exit;
 769     instance.respawntime = autocvar_g_vehicle_raptor_respawntime;
 770     instance.vehicle_health = autocvar_g_vehicle_raptor_health;
 771     instance.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 772     instance.max_health = instance.vehicle_health;
 773 }
 774
 775 #endif
 776 #ifdef CSQC
 777
 778 METHOD(Raptor, vr_hud, void(Raptor thisveh))
 779 {
 780     Vehicles_drawHUD(VEH_RAPTOR.m_icon, "vehicle_raptor_weapon1", "vehicle_raptor_weapon2",
 781                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 782                      "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 783 }
 784 METHOD(Raptor, vr_crosshair, void(Raptor thisveh))
 785 {
 786     SELFPARAM();
 787     string crosshair;
 788
 789     switch(weapon2mode)
 790     {
 791         case RSM_FLARE: crosshair = vCROSS_RAIN;  break;
 792         case RSM_BOMB:  crosshair = vCROSS_BURST; break;
 793         default:        crosshair = vCROSS_BURST;
 794     }
 795
 796     vector tmpSize = '0 0 0';
 797     if(weapon2mode != RSM_FLARE)
 798     {
 799         vector where;
 800
 801         if(!dropmark)
 802         {
 803             dropmark = spawn();
 804             dropmark.owner = self;
 805             dropmark.gravity = 1;
 806         }
 807
 808         float reload2 = STAT(VEHICLESTAT_RELOAD2) * 0.01;
 809         if(reload2 == 1)
 810         {
 811             setorigin(dropmark, pmove_org);
 812             dropmark.velocity = pmove_vel;
 813             tracetoss(dropmark, self);
 814
 815             where = project_3d_to_2d(trace_endpos);
 816
 817             setorigin(dropmark, trace_endpos);
 818             tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size;
 819
 820             if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 821             {
 822                 where.x -= tmpSize.x * 0.5;
 823                 where.y -= tmpSize.y * 0.5;
 824                 where.z = 0;
 825                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 826                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 827             }
 828             dropmark.cnt = time + 5;
 829         }
 830         else
 831         {
 832             if(dropmark.cnt > time)
 833             {
 834                 where = project_3d_to_2d(dropmark.origin);
 835                 tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size * 1.25;
 836
 837                 if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 838                 {
 839                     where.x -= tmpSize.x * 0.5;
 840                     where.y -= tmpSize.y * 0.5;
 841                     where.z = 0;
 842                     drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 843                     drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 844                 }
 845             }
 846         }
 847     }
 848
 849     Vehicles_drawCrosshair(crosshair);
 850 }
 851 METHOD(Raptor, vr_setup, void(Raptor thisveh, entity instance))
 852 {
 853     AuxiliaryXhair[1].axh_image = vCROSS_LOCK;
 854 }
 855
 856 #endif
 857 #endif