qcsrc/common/vehicles/vehicle/raptor.qc

   1 #ifndef VEHICLE_RAPTOR
   2 #define VEHICLE_RAPTOR
   3 #include "raptor.qh"
   4
   5 #include "raptor_weapons.qc"
   6
   7 CLASS(Raptor, Vehicle)
   8 /* spawnflags */ ATTRIB(Raptor, spawnflags, int, VHF_DMGSHAKE | VHF_DMGROLL);
   9 /* mins       */ ATTRIB(Raptor, mins, vector, '-80 -80 0');
  10 /* maxs       */ ATTRIB(Raptor, maxs, vector, '80 80 70');
  11 /* view offset*/ ATTRIB(Raptor, view_ofs, vector, '0 0 160');
  12 /* view dist  */ ATTRIB(Raptor, height, float, 200);
  13 /* model          */ ATTRIB(Raptor, mdl, string, "models/vehicles/raptor.dpm");
  14 /* model          */ ATTRIB(Raptor, model, string, "models/vehicles/raptor.dpm");
  15 /* head_model */ ATTRIB(Raptor, head_model, string, "");
  16 /* hud_model  */ ATTRIB(Raptor, hud_model, string, "models/vehicles/raptor_cockpit.dpm");
  17 /* tags       */ ATTRIB(Raptor, tag_head, string, "");
  18 /* tags       */ ATTRIB(Raptor, tag_hud, string, "tag_hud");
  19 /* tags       */ ATTRIB(Raptor, tag_view, string, "tag_camera");
  20 /* netname    */ ATTRIB(Raptor, netname, string, "raptor");
  21 /* fullname   */ ATTRIB(Raptor, vehicle_name, string, _("Raptor"));
  22 /* icon       */ ATTRIB(Raptor, m_icon, string, "vehicle_raptor");
  23 ENDCLASS(Raptor)
  24 REGISTER_VEHICLE(RAPTOR, NEW(Raptor));
  25
  26 #endif
  27
  28 #ifdef IMPLEMENTATION
  29
  30 #include "raptor_weapons.qc"
  31
  32 #ifdef SVQC
  33
  34 bool autocvar_g_vehicle_raptor = true;
  35
  36 float autocvar_g_vehicle_raptor_respawntime = 40;
  37 float autocvar_g_vehicle_raptor_takeofftime = 1.5;
  38
  39 // 0: go where player aims, +forward etc relative to aim angles
  40 // 1: ignore aim for up/down movement. +forward always moved forward, +jump always moves up
  41 int autocvar_g_vehicle_raptor_movestyle = 1;
  42 float autocvar_g_vehicle_raptor_turnspeed = 200;
  43 float autocvar_g_vehicle_raptor_pitchspeed = 50;
  44 float autocvar_g_vehicle_raptor_pitchlimit = 45;
  45
  46 float autocvar_g_vehicle_raptor_speed_forward = 1700;
  47 float autocvar_g_vehicle_raptor_speed_strafe = 900;
  48 float autocvar_g_vehicle_raptor_speed_up = 1700;
  49 float autocvar_g_vehicle_raptor_speed_down = 1700;
  50 float autocvar_g_vehicle_raptor_friction = 2;
  51
  52 float autocvar_g_vehicle_raptor_cannon_turnspeed = 120;
  53 float autocvar_g_vehicle_raptor_cannon_turnlimit = 20;
  54 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up = 12;
  55 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down = 32;
  56
  57 float autocvar_g_vehicle_raptor_cannon_locktarget = 0;
  58 float autocvar_g_vehicle_raptor_cannon_locking_time = 0.2;
  59 float autocvar_g_vehicle_raptor_cannon_locking_releasetime = 0.45;
  60 float autocvar_g_vehicle_raptor_cannon_locked_time = 1;
  61 float autocvar_g_vehicle_raptor_cannon_predicttarget = 1;
  62
  63 float autocvar_g_vehicle_raptor_energy = 100;
  64 float autocvar_g_vehicle_raptor_energy_regen = 25;
  65 float autocvar_g_vehicle_raptor_energy_regen_pause = 0.25;
  66
  67 float autocvar_g_vehicle_raptor_health = 150;
  68 float autocvar_g_vehicle_raptor_health_regen = 0;
  69 float autocvar_g_vehicle_raptor_health_regen_pause = 0;
  70
  71 float autocvar_g_vehicle_raptor_shield = 75;
  72 float autocvar_g_vehicle_raptor_shield_regen = 25;
  73 float autocvar_g_vehicle_raptor_shield_regen_pause = 1.5;
  74
  75 float autocvar_g_vehicle_raptor_bouncefactor = 0.2;
  76 float autocvar_g_vehicle_raptor_bouncestop = 0;
  77 vector autocvar_g_vehicle_raptor_bouncepain = '1 4 1000';
  78
  79 .entity bomb1;
  80 .entity bomb2;
  81
  82 float raptor_altitude(float amax)
  83 {SELFPARAM();
  84         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  85         return vlen(self.origin - trace_endpos);
  86 }
  87
  88 void raptor_land()
  89 {SELFPARAM();
  90         float hgt;
  91
  92         hgt = raptor_altitude(512);
  93         self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
  94         self.angles_x *= 0.95;
  95         self.angles_z *= 0.95;
  96
  97         if(hgt < 128)
  98         if(hgt > 0)
  99                 self.frame = (hgt / 128) * 25;
 100
 101         self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 102         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 103
 104         if(hgt < 16)
 105         {
 106                 self.movetype = MOVETYPE_TOSS;
 107                 self.think      = vehicles_think;
 108                 self.frame      = 0;
 109         }
 110
 111         self.nextthink  = time;
 112
 113         CSQCMODEL_AUTOUPDATE(self);
 114 }
 115
 116 void raptor_exit(float eject)
 117 {SELFPARAM();
 118         vector spot;
 119         self.tur_head.exteriormodeltoclient = world;
 120
 121         if(!IS_DEAD(self))
 122         {
 123                 self.think        = raptor_land;
 124                 self.nextthink  = time;
 125         }
 126
 127         if(!self.owner)
 128                 return;
 129
 130         makevectors(self.angles);
 131         if(eject)
 132         {
 133                 spot = self.origin + v_forward * 100 + '0 0 64';
 134                 spot = vehicles_findgoodexit(spot);
 135                 setorigin(self.owner , spot);
 136                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 137                 self.owner.oldvelocity = self.owner.velocity;
 138         }
 139         else
 140         {
 141                 if(vdist(self.velocity, >, 2 * autocvar_sv_maxairspeed))
 142                 {
 143                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 144                         self.owner.velocity_z += 200;
 145                         spot = self.origin + v_forward * 32 + '0 0 64';
 146                         spot = vehicles_findgoodexit(spot);
 147                 }
 148                 else
 149                 {
 150                         self.owner.velocity = self.velocity * 0.5;
 151                         self.owner.velocity_z += 10;
 152                         spot = self.origin - v_forward * 200 + '0 0 64';
 153                         spot = vehicles_findgoodexit(spot);
 154                 }
 155                 self.owner.oldvelocity = self.owner.velocity;
 156                 setorigin(self.owner , spot);
 157         }
 158
 159         antilag_clear(self.owner, CS(self.owner));
 160         self.owner = world;
 161 }
 162
 163 bool raptor_frame(entity this)
 164 {
 165         entity vehic = this.vehicle;
 166         return = true;
 167
 168         if(intermission_running)
 169         {
 170                 vehic.velocity = '0 0 0';
 171                 vehic.avelocity = '0 0 0';
 172                 return;
 173         }
 174
 175         vehicles_frame(vehic, this);
 176
 177         float ftmp = 0;
 178         /*
 179         ftmp = vlen(vehic.velocity);
 180         if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 181                 ftmp = 1;
 182         else
 183                 ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 184         */
 185
 186         if(vehic.sound_nexttime < time)
 187         {
 188                 vehic.sound_nexttime = time + 7.955812;
 189                 //sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_FLY, 1 - ftmp,   ATTEN_NORM );
 190                 sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, 1, ATTEN_NORM);
 191                 vehic.wait = ftmp;
 192         }
 193         /*
 194         else if(fabs(ftmp - vehic.wait) > 0.2)
 195         {
 196                 sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_Null, 1 - ftmp,   ATTEN_NORM );
 197                 sound (vehic, CH_TRIGGER_SINGLE, SND_Null, ftmp, ATTEN_NORM);
 198                 vehic.wait = ftmp;
 199         }
 200         */
 201
 202         if(IS_DEAD(vehic))
 203         {
 204                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 205                 return 1;
 206         }
 207         crosshair_trace(this);
 208
 209         //if(time - vehic.lastteleporttime < 1)
 210         //{
 211                 if(vehic.angles_z > 50 || vehic.angles_z < -50)
 212                 {
 213                         if(PHYS_INPUT_BUTTON_JUMP(this))
 214                         {
 215                                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 216                                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 217                         }
 218                 }
 219         //}
 220
 221         vector vang;
 222         vang = vehic.angles;
 223         vector df = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 224         vang_x *= -1;
 225         df_x *= -1;
 226         if(df_x > 180)  df_x -= 360;
 227         if(df_x < -180) df_x += 360;
 228         if(df_y > 180)  df_y -= 360;
 229         if(df_y < -180) df_y += 360;
 230
 231         ftmp = shortangle_f(this.v_angle_y - vang_y, vang_y);
 232         if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 233         vehic.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + vehic.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 234
 235         // Pitch
 236         ftmp = 0;
 237         if(this.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 238         else if(this.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 239
 240         df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 241         ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 242         vehic.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + vehic.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 243
 244         vehic.angles_x = anglemods(vehic.angles_x);
 245         vehic.angles_y = anglemods(vehic.angles_y);
 246         vehic.angles_z = anglemods(vehic.angles_z);
 247
 248         if(autocvar_g_vehicle_raptor_movestyle == 1)
 249                 makevectors('0 1 0' * vehic.angles_y);
 250         else
 251                 makevectors(this.v_angle);
 252
 253         df = vehic.velocity * -autocvar_g_vehicle_raptor_friction;
 254
 255         if(this.movement_x != 0)
 256         {
 257                 if(this.movement_x > 0)
 258                         df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 259                 else if(this.movement_x < 0)
 260                         df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 261         }
 262
 263         if(this.movement_y != 0)
 264         {
 265                 if(this.movement_y < 0)
 266                         df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 267                 else if(this.movement_y > 0)
 268                         df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 269
 270                 vehic.angles_z = bound(-30,vehic.angles_z + (this.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 271         }
 272         else
 273         {
 274                 vehic.angles_z *= 0.95;
 275                 if(vehic.angles_z >= -1 && vehic.angles_z <= -1)
 276                         vehic.angles_z = 0;
 277         }
 278
 279         if(PHYS_INPUT_BUTTON_CROUCH(this))
 280                 df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 281         else if (PHYS_INPUT_BUTTON_JUMP(this))
 282                 df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 283
 284         vehic.velocity  += df * frametime;
 285         this.velocity = this.movement  = vehic.velocity;
 286         setorigin(this, vehic.origin + '0 0 32');
 287
 288         this.vehicle_weapon2mode = vehic.vehicle_weapon2mode;
 289
 290         vector vf, ad;
 291         // Target lock & predict
 292         if(autocvar_g_vehicle_raptor_cannon_locktarget == 2)
 293         {
 294                 if(vehic.gun1.lock_time < time || IS_DEAD(vehic.gun1.enemy) || STAT(FROZEN, vehic.gun1.enemy))
 295                         vehic.gun1.enemy = world;
 296
 297                 if(trace_ent)
 298                 if(trace_ent.movetype)
 299                 if(trace_ent.takedamage)
 300                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 301                 {
 302                         if(teamplay)
 303                         {
 304                                 if(trace_ent.team != this.team)
 305                                 {
 306                                         vehic.gun1.enemy = trace_ent;
 307                                         vehic.gun1.lock_time = time + 5;
 308                                 }
 309                         }
 310                         else
 311                         {
 312                                 vehic.gun1.enemy = trace_ent;
 313                                 vehic.gun1.lock_time = time + 0.5;
 314                         }
 315                 }
 316
 317                 if(vehic.gun1.enemy)
 318                 {
 319                         float distance, impact_time;
 320
 321                         vf = real_origin(vehic.gun1.enemy);
 322                         UpdateAuxiliaryXhair(this, vf, '1 0 0', 1);
 323                         vector _vel = vehic.gun1.enemy.velocity;
 324                         if(vehic.gun1.enemy.movetype == MOVETYPE_WALK)
 325                                 _vel_z *= 0.1;
 326
 327                         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 328                         {
 329                                 ad = vf;
 330                                 distance = vlen(ad - this.origin);
 331                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 332                                 ad = vf + _vel * impact_time;
 333                                 trace_endpos = ad;
 334                         }
 335                         else
 336                                 trace_endpos = vf;
 337                 }
 338         }
 339         else if(autocvar_g_vehicle_raptor_cannon_locktarget == 1)
 340         {
 341
 342                 vehicles_locktarget(vehic, (1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 343                                                          (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 344                                                          autocvar_g_vehicle_raptor_cannon_locked_time);
 345
 346                 if(vehic.lock_target != world)
 347                 if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 348                 if(vehic.lock_strength == 1)
 349                 {
 350                         float i, distance, impact_time;
 351
 352                         vf = real_origin(vehic.lock_target);
 353                         ad = vf;
 354                         for(i = 0; i < 4; ++i)
 355                         {
 356                                 distance = vlen(ad - vehic.origin);
 357                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 358                                 ad = vf + vehic.lock_target.velocity * impact_time;
 359                         }
 360                         trace_endpos = ad;
 361                 }
 362
 363                 if(vehic.lock_target)
 364                 {
 365                         if(vehic.lock_strength == 1)
 366                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '1 0 0', 1);
 367                         else if(vehic.lock_strength > 0.5)
 368                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 1 0', 1);
 369                         else if(vehic.lock_strength < 0.5)
 370                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 0 1', 1);
 371                 }
 372         }
 373
 374
 375         vehicle_aimturret(vehic, trace_endpos, vehic.gun1, "fire1",
 376                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 377                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 378
 379         vehicle_aimturret(vehic, trace_endpos, vehic.gun2, "fire1",
 380                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 381                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 382
 383         /*
 384         ad = ad * 0.5;
 385         v_forward = vf * 0.5;
 386         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, vehic);
 387         UpdateAuxiliaryXhair(this, trace_endpos, '0 1 0', 0);
 388         */
 389
 390         Weapon wep1 = WEP_RAPTOR;
 391         if(!forbidWeaponUse(this))
 392         if(PHYS_INPUT_BUTTON_ATCK(this))
 393         if (wep1.wr_checkammo1(wep1))
 394         {
 395             .entity weaponentity = weaponentities[0];
 396                 wep1.wr_think(wep1, vehic, weaponentity, 1);
 397         }
 398
 399         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 400                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 401
 402         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 403                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 404
 405         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 406                 vehicles_regen(vehic, vehic.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 407
 408         Weapon wep2a = WEP_RAPTOR_BOMB;
 409         if(!forbidWeaponUse(this))
 410         if(vehic.vehicle_weapon2mode == RSM_BOMB)
 411         {
 412                 if(time > vehic.lip + autocvar_g_vehicle_raptor_bombs_refire)
 413                 if(PHYS_INPUT_BUTTON_ATCK2(this))
 414                 {
 415                     .entity weaponentity = weaponentities[1];
 416                         wep2a.wr_think(wep2a, vehic, weaponentity, 2);
 417                         vehic.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 418                         vehic.lip   = time;
 419                 }
 420         }
 421         else
 422         {
 423                 Weapon wep2b = WEP_RAPTOR_FLARE;
 424                 if(time > vehic.lip + autocvar_g_vehicle_raptor_flare_refire)
 425                 if(PHYS_INPUT_BUTTON_ATCK2(this))
 426                 {
 427                     .entity weaponentity = weaponentities[1];
 428                         wep2b.wr_think(wep2b, vehic, weaponentity, 2);
 429                         vehic.delay = time + autocvar_g_vehicle_raptor_flare_refire;
 430                         vehic.lip   = time;
 431                 }
 432         }
 433
 434         vehic.bomb1.alpha = vehic.bomb2.alpha = (time - vehic.lip) / (vehic.delay - vehic.lip);
 435         this.vehicle_reload2 = bound(0, vehic.bomb1.alpha * 100, 100);
 436         this.vehicle_ammo2 = (this.vehicle_reload2 == 100) ? 100 : 0;
 437
 438         if(vehic.bomb1.cnt < time)
 439         {
 440                 entity _missile = findchainentity(enemy, vehic);
 441                 float _incomming = 0;
 442                 while(_missile)
 443                 {
 444                         if(_missile.flags & FL_PROJECTILE)
 445                         if(MISSILE_IS_TRACKING(_missile))
 446                         if(vdist(vehic.origin - _missile.origin, <, 2 * autocvar_g_vehicle_raptor_flare_range))
 447                                 ++_incomming;
 448
 449                         _missile = _missile.chain;
 450                 }
 451
 452                 if(_incomming)
 453                         sound(vehic, CH_PAIN_SINGLE, SND_VEH_MISSILE_ALARM, VOL_BASE, ATTEN_NONE);
 454
 455                 vehic.bomb1.cnt = time + 1;
 456         }
 457
 458
 459         VEHICLE_UPDATE_PLAYER(this, vehic, health, raptor);
 460         VEHICLE_UPDATE_PLAYER(this, vehic, energy, raptor);
 461         if(vehic.vehicle_flags & VHF_HASSHIELD)
 462                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, raptor);
 463
 464         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 465 }
 466
 467 bool raptor_takeoff(entity this)
 468 {
 469         entity vehic = this.vehicle;
 470         return = true;
 471
 472         vehic.nextthink = time;
 473         CSQCMODEL_AUTOUPDATE(vehic);
 474         vehic.nextthink = 0; // will this work?
 475
 476         if(vehic.sound_nexttime < time)
 477         {
 478                 vehic.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 479                 sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, VOL_VEHICLEENGINE, ATTEN_NORM);
 480         }
 481
 482         // Takeoff sequense
 483         if(vehic.frame < 25)
 484         {
 485                 vehic.frame += 25 / (autocvar_g_vehicle_raptor_takeofftime / sys_frametime);
 486                 vehic.velocity_z = min(vehic.velocity_z * 1.5, 256);
 487                 vehic.bomb1.gun1.avelocity_y = 90 + ((vehic.frame / 25) * 25000);
 488                 vehic.bomb1.gun2.avelocity_y = -vehic.bomb1.gun1.avelocity_y;
 489                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 490
 491                 setorigin(this, vehic.origin + '0 0 32');
 492         }
 493         else
 494                 this.PlayerPhysplug = raptor_frame;
 495
 496         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 497                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 498
 499         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 500                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 501
 502         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 503                 vehicles_regen(vehic, vehic.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 504
 505
 506         vehic.bomb1.alpha = vehic.bomb2.alpha = (time - vehic.lip) / (vehic.delay - vehic.lip);
 507         this.vehicle_reload2 = bound(0, vehic.bomb1.alpha * 100, 100);
 508         this.vehicle_ammo2 = (this.vehicle_reload2 == 100) ? 100 : 0;
 509
 510         VEHICLE_UPDATE_PLAYER(this, vehic, health, raptor);
 511         VEHICLE_UPDATE_PLAYER(this, vehic, energy, raptor);
 512         if(vehic.vehicle_flags & VHF_HASSHIELD)
 513                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, raptor);
 514
 515         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 516 }
 517
 518 void raptor_blowup()
 519 {SELFPARAM();
 520         self.deadflag   = DEAD_DEAD;
 521         self.vehicle_exit(VHEF_NORMAL);
 522         RadiusDamage (self, self.enemy, 250, 15, 250, world, world, 250, DEATH_VH_RAPT_DEATH.m_id, world);
 523
 524         self.alpha                = -1;
 525         self.movetype      = MOVETYPE_NONE;
 526         self.effects            = EF_NODRAW;
 527         self.colormod      = '0 0 0';
 528         self.avelocity    = '0 0 0';
 529         self.velocity      = '0 0 0';
 530
 531         setorigin(self, self.pos1);
 532         self.touch = func_null;
 533         self.nextthink = 0;
 534 }
 535
 536 void raptor_diethink()
 537 {SELFPARAM();
 538         if(time >= self.wait)
 539                 self.think = raptor_blowup;
 540
 541         if(random() < 0.05)
 542         {
 543                 sound (self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 544                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 545         }
 546         self.nextthink = time;
 547
 548         CSQCMODEL_AUTOUPDATE(self);
 549 }
 550
 551 // If we dont do this ever now and then, the raptors rotors
 552 // stop working, presumably due to angle overflow. cute.
 553 void raptor_rotor_anglefix()
 554 {SELFPARAM();
 555         self.gun1.angles_y = anglemods(self.gun1.angles_y);
 556         self.gun2.angles_y = anglemods(self.gun2.angles_y);
 557         self.nextthink = time + 15;
 558 }
 559
 560 float raptor_impulse(float _imp)
 561 {SELFPARAM();
 562         switch(_imp)
 563         {
 564                 case IMP_weapon_group_1.impulse:
 565                         self.vehicle.vehicle_weapon2mode = RSM_BOMB;
 566                         CSQCVehicleSetup(self, 0);
 567                         return true;
 568                 case IMP_weapon_group_2.impulse:
 569                         self.vehicle.vehicle_weapon2mode = RSM_FLARE;
 570                         CSQCVehicleSetup(self, 0);
 571                         return true;
 572
 573                 case IMP_weapon_next_byid.impulse:
 574                 case IMP_weapon_next_bypriority.impulse:
 575                 case IMP_weapon_next_bygroup.impulse:
 576                         self.vehicle.vehicle_weapon2mode += 1;
 577                         if(self.vehicle.vehicle_weapon2mode > RSM_LAST)
 578                                 self.vehicle.vehicle_weapon2mode = RSM_FIRST;
 579
 580                         CSQCVehicleSetup(self, 0);
 581                         return true;
 582                 case IMP_weapon_last.impulse:
 583                 case IMP_weapon_prev_byid.impulse:
 584                 case IMP_weapon_prev_bypriority.impulse:
 585                 case IMP_weapon_prev_bygroup.impulse:
 586                         self.vehicle.vehicle_weapon2mode -= 1;
 587                         if(self.vehicle.vehicle_weapon2mode < RSM_FIRST)
 588                                 self.vehicle.vehicle_weapon2mode = RSM_LAST;
 589
 590                         CSQCVehicleSetup(self, 0);
 591                         return true;
 592
 593                 /*
 594                 case IMP_weapon_drop.impulse: // toss gun, could be used to exit?
 595                         break;
 596                 case IMP_weapon_reload.impulse: // Manual minigun reload?
 597                         break;
 598                 */
 599         }
 600         return false;
 601 }
 602
 603 spawnfunc(vehicle_raptor)
 604 {
 605         if(!autocvar_g_vehicle_raptor) { remove(self); return; }
 606         if(!vehicle_initialize(VEH_RAPTOR, false)) { remove(self); return; }
 607 }
 608
 609 METHOD(Raptor, vr_impact, void(Raptor thisveh, entity instance))
 610 {
 611     if(autocvar_g_vehicle_raptor_bouncepain)
 612         vehicles_impact(autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 613 }
 614 METHOD(Raptor, vr_enter, void(Raptor thisveh, entity instance))
 615 {
 616     SELFPARAM();
 617     self.vehicle_weapon2mode = RSM_BOMB;
 618     self.owner.PlayerPhysplug = raptor_takeoff;
 619     self.movetype          = MOVETYPE_BOUNCEMISSILE;
 620     self.solid            = SOLID_SLIDEBOX;
 621     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 622     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 623     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 624     self.tur_head.exteriormodeltoclient = self.owner;
 625
 626     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 627     self.lip   = time;
 628
 629     if(self.owner.flagcarried)
 630        setorigin(self.owner.flagcarried, '-20 0 96');
 631
 632     CSQCVehicleSetup(self.owner, 0);
 633 }
 634 METHOD(Raptor, vr_death, void(Raptor thisveh, entity instance))
 635 {
 636     instance.health                             = 0;
 637     instance.event_damage               = func_null;
 638     instance.solid                              = SOLID_CORPSE;
 639     instance.takedamage                 = DAMAGE_NO;
 640     instance.deadflag                   = DEAD_DYING;
 641     instance.movetype                   = MOVETYPE_BOUNCE;
 642     instance.think                              = raptor_diethink;
 643     instance.nextthink                  = time;
 644     instance.wait                               = time + 5 + (random() * 5);
 645
 646     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation (instance.origin, 16), '0 0 0', 1);
 647
 648     instance.velocity_z += 600;
 649
 650     instance.avelocity = '0 0.5 1' * (random() * 400);
 651     instance.avelocity -= '0 0.5 1' * (random() * 400);
 652
 653     instance.colormod = '-0.5 -0.5 -0.5';
 654     instance.touch = raptor_blowup;
 655 }
 656 METHOD(Raptor, vr_spawn, void(Raptor thisveh, entity instance))
 657 {
 658     SELFPARAM();
 659     if(!self.gun1)
 660     {
 661         entity spinner;
 662         vector ofs;
 663
 664         //FIXME: Camera is in a bad place in HUD model.
 665         //setorigin(self.vehicle_viewport, '25 0 5');
 666
 667         self.vehicles_impulse   = raptor_impulse;
 668
 669         self.frame = 0;
 670
 671         self.bomb1 = new(raptor_bomb);
 672         self.bomb2 = new(raptor_bomb);
 673         self.gun1  = new(raptor_gun);
 674         self.gun2  = new(raptor_gun);
 675
 676         setmodel(self.bomb1, MDL_VEH_RAPTOR_CB_FOLDED);
 677         setmodel(self.bomb2, MDL_VEH_RAPTOR_CB_FOLDED);
 678         setmodel(self.gun1, MDL_VEH_RAPTOR_GUN);
 679         setmodel(self.gun2, MDL_VEH_RAPTOR_GUN);
 680         setmodel(self.tur_head, MDL_VEH_RAPTOR_TAIL);
 681
 682         setattachment(self.bomb1, self, "bombmount_left");
 683         setattachment(self.bomb2, self, "bombmount_right");
 684         setattachment(self.tur_head, self,"root");
 685
 686         // FIXMODEL Guns mounts to angled bones
 687         self.bomb1.angles = self.angles;
 688         self.angles = '0 0 0';
 689         // This messes up gun-aim, so work arround it.
 690         //setattachment(self.gun1, self, "gunmount_left");
 691         ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 692         ofs -= self.origin;
 693         setattachment(self.gun1, self, "");
 694         setorigin(self.gun1, ofs);
 695
 696         //setattachment(self.gun2, self, "gunmount_right");
 697         ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 698         ofs -= self.origin;
 699         setattachment(self.gun2, self, "");
 700         setorigin(self.gun2, ofs);
 701
 702         self.angles = self.bomb1.angles;
 703         self.bomb1.angles = '0 0 0';
 704
 705         spinner = new(raptor_spinner);
 706         spinner.owner = self;
 707         setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 708         setattachment(spinner, self, "engine_left");
 709         spinner.movetype = MOVETYPE_NOCLIP;
 710         spinner.avelocity = '0 90 0';
 711         self.bomb1.gun1 = spinner;
 712
 713         spinner = new(raptor_spinner);
 714         spinner.owner = self;
 715         setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 716         setattachment(spinner, self, "engine_right");
 717         spinner.movetype = MOVETYPE_NOCLIP;
 718         spinner.avelocity = '0 -90 0';
 719         self.bomb1.gun2 = spinner;
 720
 721         // Sigh.
 722         self.bomb1.think = raptor_rotor_anglefix;
 723         self.bomb1.nextthink = time;
 724
 725         self.mass                          = 1 ;
 726     }
 727
 728     self.frame            = 0;
 729     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 730     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 731     self.movetype          = MOVETYPE_TOSS;
 732     self.solid            = SOLID_SLIDEBOX;
 733     self.vehicle_energy = 1;
 734
 735     self.PlayerPhysplug = raptor_frame;
 736
 737     self.bomb1.gun1.avelocity_y = 90;
 738     self.bomb1.gun2.avelocity_y = -90;
 739
 740     self.delay = time;
 741
 742     self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 743     self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 744     self.damageforcescale = 0.25;
 745     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 746     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 747 }
 748 METHOD(Raptor, vr_setup, void(Raptor thisveh, entity instance))
 749 {
 750     SELFPARAM();
 751     if(autocvar_g_vehicle_raptor_shield)
 752         self.vehicle_flags |= VHF_HASSHIELD;
 753
 754     if(autocvar_g_vehicle_raptor_shield_regen)
 755         self.vehicle_flags |= VHF_SHIELDREGEN;
 756
 757     if(autocvar_g_vehicle_raptor_health_regen)
 758         self.vehicle_flags |= VHF_HEALTHREGEN;
 759
 760     if(autocvar_g_vehicle_raptor_energy_regen)
 761         self.vehicle_flags |= VHF_ENERGYREGEN;
 762
 763     self.vehicle_exit = raptor_exit;
 764     self.respawntime = autocvar_g_vehicle_raptor_respawntime;
 765     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 766     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 767     self.max_health = self.vehicle_health;
 768 }
 769
 770 #endif
 771 #ifdef CSQC
 772
 773 METHOD(Raptor, vr_hud, void(Raptor thisveh))
 774 {
 775     Vehicles_drawHUD(VEH_RAPTOR.m_icon, "vehicle_raptor_weapon1", "vehicle_raptor_weapon2",
 776                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 777                      "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 778 }
 779 METHOD(Raptor, vr_crosshair, void(Raptor thisveh))
 780 {
 781     SELFPARAM();
 782     string crosshair;
 783
 784     switch(weapon2mode)
 785     {
 786         case RSM_FLARE: crosshair = vCROSS_RAIN;  break;
 787         case RSM_BOMB:  crosshair = vCROSS_BURST; break;
 788         default:        crosshair = vCROSS_BURST;
 789     }
 790
 791     vector tmpSize = '0 0 0';
 792     if(weapon2mode != RSM_FLARE)
 793     {
 794         vector where;
 795
 796         if(!dropmark)
 797         {
 798             dropmark = spawn();
 799             dropmark.owner = self;
 800             dropmark.gravity = 1;
 801         }
 802
 803         float reload2 = STAT(VEHICLESTAT_RELOAD2) * 0.01;
 804         if(reload2 == 1)
 805         {
 806             setorigin(dropmark, pmove_org);
 807             dropmark.velocity = pmove_vel;
 808             tracetoss(dropmark, self);
 809
 810             where = project_3d_to_2d(trace_endpos);
 811
 812             setorigin(dropmark, trace_endpos);
 813             tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size;
 814
 815             if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 816             {
 817                 where.x -= tmpSize.x * 0.5;
 818                 where.y -= tmpSize.y * 0.5;
 819                 where.z = 0;
 820                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 821                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 822             }
 823             dropmark.cnt = time + 5;
 824         }
 825         else
 826         {
 827             if(dropmark.cnt > time)
 828             {
 829                 where = project_3d_to_2d(dropmark.origin);
 830                 tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size * 1.25;
 831
 832                 if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 833                 {
 834                     where.x -= tmpSize.x * 0.5;
 835                     where.y -= tmpSize.y * 0.5;
 836                     where.z = 0;
 837                     drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 838                     drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 839                 }
 840             }
 841         }
 842     }
 843
 844     Vehicles_drawCrosshair(crosshair);
 845 }
 846 METHOD(Raptor, vr_setup, void(Raptor thisveh, entity instance))
 847 {
 848     AuxiliaryXhair[1].axh_image = vCROSS_LOCK;
 849 }
 850
 851 #endif
 852 #endif