qcsrc/common/vehicles/vehicle/raptor.qc

   1 #ifndef VEHICLE_RAPTOR
   2 #define VEHICLE_RAPTOR
   3 #include "raptor.qh"
   4
   5 #include "raptor_weapons.qc"
   6
   7 CLASS(Raptor, Vehicle)
   8 /* spawnflags */ ATTRIB(Raptor, spawnflags, int, VHF_DMGSHAKE | VHF_DMGROLL);
   9 /* mins       */ ATTRIB(Raptor, mins, vector, '-80 -80 0');
  10 /* maxs       */ ATTRIB(Raptor, maxs, vector, '80 80 70');
  11 /* view offset*/ ATTRIB(Raptor, view_ofs, vector, '0 0 160');
  12 /* view dist  */ ATTRIB(Raptor, height, float, 200);
  13 /* model          */ ATTRIB(Raptor, mdl, string, "models/vehicles/raptor.dpm");
  14 /* model          */ ATTRIB(Raptor, model, string, "models/vehicles/raptor.dpm");
  15 /* head_model */ ATTRIB(Raptor, head_model, string, "");
  16 /* hud_model  */ ATTRIB(Raptor, hud_model, string, "models/vehicles/raptor_cockpit.dpm");
  17 /* tags       */ ATTRIB(Raptor, tag_head, string, "");
  18 /* tags       */ ATTRIB(Raptor, tag_hud, string, "tag_hud");
  19 /* tags       */ ATTRIB(Raptor, tag_view, string, "tag_camera");
  20 /* netname    */ ATTRIB(Raptor, netname, string, "raptor");
  21 /* fullname   */ ATTRIB(Raptor, vehicle_name, string, _("Raptor"));
  22 /* icon       */ ATTRIB(Raptor, m_icon, string, "vehicle_raptor");
  23 ENDCLASS(Raptor)
  24 REGISTER_VEHICLE(RAPTOR, NEW(Raptor));
  25
  26 #endif
  27
  28 #ifdef IMPLEMENTATION
  29
  30 #include "raptor_weapons.qc"
  31
  32 #ifdef SVQC
  33
  34 bool autocvar_g_vehicle_raptor = true;
  35
  36 float autocvar_g_vehicle_raptor_respawntime = 40;
  37 float autocvar_g_vehicle_raptor_takeofftime = 1.5;
  38
  39 // 0: go where player aims, +forward etc relative to aim angles
  40 // 1: ignore aim for up/down movement. +forward always moved forward, +jump always moves up
  41 int autocvar_g_vehicle_raptor_movestyle = 1;
  42 float autocvar_g_vehicle_raptor_turnspeed = 200;
  43 float autocvar_g_vehicle_raptor_pitchspeed = 50;
  44 float autocvar_g_vehicle_raptor_pitchlimit = 45;
  45
  46 float autocvar_g_vehicle_raptor_speed_forward = 1700;
  47 float autocvar_g_vehicle_raptor_speed_strafe = 900;
  48 float autocvar_g_vehicle_raptor_speed_up = 1700;
  49 float autocvar_g_vehicle_raptor_speed_down = 1700;
  50 float autocvar_g_vehicle_raptor_friction = 2;
  51
  52 float autocvar_g_vehicle_raptor_cannon_turnspeed = 120;
  53 float autocvar_g_vehicle_raptor_cannon_turnlimit = 20;
  54 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up = 12;
  55 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down = 32;
  56
  57 float autocvar_g_vehicle_raptor_cannon_locktarget = 0;
  58 float autocvar_g_vehicle_raptor_cannon_locking_time = 0.2;
  59 float autocvar_g_vehicle_raptor_cannon_locking_releasetime = 0.45;
  60 float autocvar_g_vehicle_raptor_cannon_locked_time = 1;
  61 float autocvar_g_vehicle_raptor_cannon_predicttarget = 1;
  62
  63 float autocvar_g_vehicle_raptor_energy = 100;
  64 float autocvar_g_vehicle_raptor_energy_regen = 25;
  65 float autocvar_g_vehicle_raptor_energy_regen_pause = 0.25;
  66
  67 float autocvar_g_vehicle_raptor_health = 150;
  68 float autocvar_g_vehicle_raptor_health_regen = 0;
  69 float autocvar_g_vehicle_raptor_health_regen_pause = 0;
  70
  71 float autocvar_g_vehicle_raptor_shield = 75;
  72 float autocvar_g_vehicle_raptor_shield_regen = 25;
  73 float autocvar_g_vehicle_raptor_shield_regen_pause = 1.5;
  74
  75 float autocvar_g_vehicle_raptor_bouncefactor = 0.2;
  76 float autocvar_g_vehicle_raptor_bouncestop = 0;
  77 vector autocvar_g_vehicle_raptor_bouncepain = '1 4 1000';
  78
  79 .entity bomb1;
  80 .entity bomb2;
  81
  82 float raptor_altitude(float amax)
  83 {SELFPARAM();
  84         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  85         return vlen(self.origin - trace_endpos);
  86 }
  87
  88 void raptor_land()
  89 {SELFPARAM();
  90         float hgt;
  91
  92         hgt = raptor_altitude(512);
  93         self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
  94         self.angles_x *= 0.95;
  95         self.angles_z *= 0.95;
  96
  97         if(hgt < 128)
  98         if(hgt > 0)
  99                 self.frame = (hgt / 128) * 25;
 100
 101         self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 102         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 103
 104         if(hgt < 16)
 105         {
 106                 self.movetype = MOVETYPE_TOSS;
 107                 self.think      = vehicles_think;
 108                 self.frame      = 0;
 109         }
 110
 111         self.nextthink  = time;
 112
 113         CSQCMODEL_AUTOUPDATE(self);
 114 }
 115
 116 void raptor_exit(float eject)
 117 {SELFPARAM();
 118         vector spot;
 119         self.tur_head.exteriormodeltoclient = world;
 120
 121         if(!IS_DEAD(self))
 122         {
 123                 self.think        = raptor_land;
 124                 self.nextthink  = time;
 125         }
 126
 127         if(!self.owner)
 128                 return;
 129
 130         makevectors(self.angles);
 131         if(eject)
 132         {
 133                 spot = self.origin + v_forward * 100 + '0 0 64';
 134                 spot = vehicles_findgoodexit(spot);
 135                 setorigin(self.owner , spot);
 136                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 137                 self.owner.oldvelocity = self.owner.velocity;
 138         }
 139         else
 140         {
 141                 if(vdist(self.velocity, >, 2 * autocvar_sv_maxairspeed))
 142                 {
 143                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 144                         self.owner.velocity_z += 200;
 145                         spot = self.origin + v_forward * 32 + '0 0 64';
 146                         spot = vehicles_findgoodexit(spot);
 147                 }
 148                 else
 149                 {
 150                         self.owner.velocity = self.velocity * 0.5;
 151                         self.owner.velocity_z += 10;
 152                         spot = self.origin - v_forward * 200 + '0 0 64';
 153                         spot = vehicles_findgoodexit(spot);
 154                 }
 155                 self.owner.oldvelocity = self.owner.velocity;
 156                 setorigin(self.owner , spot);
 157         }
 158
 159         antilag_clear(self.owner, CS(self.owner));
 160         self.owner = world;
 161 }
 162
 163 float raptor_frame()
 164 {SELFPARAM();
 165         entity player, raptor;
 166         float ftmp = 0;
 167         vector df;
 168
 169         if(intermission_running)
 170         {
 171                 self.vehicle.velocity = '0 0 0';
 172                 self.vehicle.avelocity = '0 0 0';
 173                 return 1;
 174         }
 175
 176         player = self;
 177         raptor = self.vehicle;
 178         setself(raptor);
 179
 180         vehicles_frame(raptor, player);
 181
 182         /*
 183         ftmp = vlen(self.velocity);
 184         if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 185                 ftmp = 1;
 186         else
 187                 ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 188         */
 189
 190         if(self.sound_nexttime < time)
 191         {
 192                 self.sound_nexttime = time + 7.955812;
 193                 //sound (self.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_FLY, 1 - ftmp,   ATTEN_NORM );
 194                 sound (self, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, 1, ATTEN_NORM);
 195                 self.wait = ftmp;
 196         }
 197         /*
 198         else if(fabs(ftmp - self.wait) > 0.2)
 199         {
 200                 sound (self.tur_head, CH_TRIGGER_SINGLE, SND_Null, 1 - ftmp,   ATTEN_NORM );
 201                 sound (self, CH_TRIGGER_SINGLE, SND_Null, ftmp, ATTEN_NORM);
 202                 self.wait = ftmp;
 203         }
 204         */
 205
 206         if(IS_DEAD(raptor))
 207         {
 208                 setself(player);
 209                 PHYS_INPUT_BUTTON_ATCK(player) = PHYS_INPUT_BUTTON_ATCK2(player) = false;
 210                 return 1;
 211         }
 212         crosshair_trace(player);
 213
 214         //if(time - self.lastteleporttime < 1)
 215         //{
 216                 if(raptor.angles_z > 50 || raptor.angles_z < -50)
 217                 {
 218                         if(PHYS_INPUT_BUTTON_JUMP(player))
 219                         {
 220                                 PHYS_INPUT_BUTTON_CROUCH(player) = true;
 221                                 PHYS_INPUT_BUTTON_JUMP(player) = false;
 222                         }
 223                 }
 224         //}
 225
 226         vector vang;
 227         vang = raptor.angles;
 228         df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 229         vang_x *= -1;
 230         df_x *= -1;
 231         if(df_x > 180)  df_x -= 360;
 232         if(df_x < -180) df_x += 360;
 233         if(df_y > 180)  df_y -= 360;
 234         if(df_y < -180) df_y += 360;
 235
 236         ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 237         if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 238         raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 239
 240         // Pitch
 241         ftmp = 0;
 242         if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 243         else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 244
 245         df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 246         ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 247         raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 248
 249         raptor.angles_x = anglemods(raptor.angles_x);
 250         raptor.angles_y = anglemods(raptor.angles_y);
 251         raptor.angles_z = anglemods(raptor.angles_z);
 252
 253         if(autocvar_g_vehicle_raptor_movestyle == 1)
 254                 makevectors('0 1 0' * raptor.angles_y);
 255         else
 256                 makevectors(player.v_angle);
 257
 258         df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 259
 260         if(player.movement_x != 0)
 261         {
 262                 if(player.movement_x > 0)
 263                         df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 264                 else if(player.movement_x < 0)
 265                         df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 266         }
 267
 268         if(player.movement_y != 0)
 269         {
 270                 if(player.movement_y < 0)
 271                         df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 272                 else if(player.movement_y > 0)
 273                         df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 274
 275                 raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 276         }
 277         else
 278         {
 279                 raptor.angles_z *= 0.95;
 280                 if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 281                         raptor.angles_z = 0;
 282         }
 283
 284         if(PHYS_INPUT_BUTTON_CROUCH(player))
 285                 df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 286         else if (PHYS_INPUT_BUTTON_JUMP(player))
 287                 df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 288
 289         raptor.velocity  += df * frametime;
 290         player.velocity = player.movement  = raptor.velocity;
 291         setorigin(player, raptor.origin + '0 0 32');
 292
 293         player.vehicle_weapon2mode = raptor.vehicle_weapon2mode;
 294
 295         vector vf, ad;
 296         // Target lock & predict
 297         if(autocvar_g_vehicle_raptor_cannon_locktarget == 2)
 298         {
 299                 if(raptor.gun1.lock_time < time || IS_DEAD(raptor.gun1.enemy) || STAT(FROZEN, raptor.gun1.enemy))
 300                         raptor.gun1.enemy = world;
 301
 302                 if(trace_ent)
 303                 if(trace_ent.movetype)
 304                 if(trace_ent.takedamage)
 305                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 306                 {
 307                         if(teamplay)
 308                         {
 309                                 if(trace_ent.team != player.team)
 310                                 {
 311                                         raptor.gun1.enemy = trace_ent;
 312                                         raptor.gun1.lock_time = time + 5;
 313                                 }
 314                         }
 315                         else
 316                         {
 317                                 raptor.gun1.enemy = trace_ent;
 318                                 raptor.gun1.lock_time = time + 0.5;
 319                         }
 320                 }
 321
 322                 if(raptor.gun1.enemy)
 323                 {
 324                         float distance, impact_time;
 325
 326                         vf = real_origin(raptor.gun1.enemy);
 327                         UpdateAuxiliaryXhair(player, vf, '1 0 0', 1);
 328                         vector _vel = raptor.gun1.enemy.velocity;
 329                         if(raptor.gun1.enemy.movetype == MOVETYPE_WALK)
 330                                 _vel_z *= 0.1;
 331
 332                         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 333                         {
 334                                 ad = vf;
 335                                 distance = vlen(ad - player.origin);
 336                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 337                                 ad = vf + _vel * impact_time;
 338                                 trace_endpos = ad;
 339                         }
 340                         else
 341                                 trace_endpos = vf;
 342                 }
 343         }
 344         else if(autocvar_g_vehicle_raptor_cannon_locktarget == 1)
 345         {
 346
 347                 vehicles_locktarget(self, (1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 348                                                          (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 349                                                          autocvar_g_vehicle_raptor_cannon_locked_time);
 350
 351                 if(self.lock_target != world)
 352                 if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 353                 if(self.lock_strength == 1)
 354                 {
 355                         float i, distance, impact_time;
 356
 357                         vf = real_origin(raptor.lock_target);
 358                         ad = vf;
 359                         for(i = 0; i < 4; ++i)
 360                         {
 361                                 distance = vlen(ad - raptor.origin);
 362                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 363                                 ad = vf + raptor.lock_target.velocity * impact_time;
 364                         }
 365                         trace_endpos = ad;
 366                 }
 367
 368                 if(self.lock_target)
 369                 {
 370                         if(raptor.lock_strength == 1)
 371                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 372                         else if(self.lock_strength > 0.5)
 373                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 374                         else if(self.lock_strength < 0.5)
 375                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 376                 }
 377         }
 378
 379
 380         vehicle_aimturret(raptor, trace_endpos, raptor.gun1, "fire1",
 381                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 382                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 383
 384         vehicle_aimturret(raptor, trace_endpos, raptor.gun2, "fire1",
 385                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 386                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 387
 388         /*
 389         ad = ad * 0.5;
 390         v_forward = vf * 0.5;
 391         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 392         UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 393         */
 394
 395         Weapon wep1 = WEP_RAPTOR;
 396         if(!forbidWeaponUse(player))
 397         if(PHYS_INPUT_BUTTON_ATCK(player))
 398         if (wep1.wr_checkammo1(wep1))
 399         {
 400             .entity weaponentity = weaponentities[0];
 401                 wep1.wr_think(wep1, self, weaponentity, 1);
 402         }
 403
 404         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 405                 vehicles_regen(raptor.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 406
 407         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 408                 vehicles_regen(raptor.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 409
 410         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 411                 vehicles_regen(raptor.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 412
 413         Weapon wep2a = WEP_RAPTOR_BOMB;
 414         if(!forbidWeaponUse(player))
 415         if(raptor.vehicle_weapon2mode == RSM_BOMB)
 416         {
 417                 if(time > raptor.lip + autocvar_g_vehicle_raptor_bombs_refire)
 418                 if(PHYS_INPUT_BUTTON_ATCK2(player))
 419                 {
 420                     .entity weaponentity = weaponentities[1];
 421                         wep2a.wr_think(wep2a, self, weaponentity, 2);
 422                         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 423                         raptor.lip   = time;
 424                 }
 425         }
 426         else
 427         {
 428                 Weapon wep2b = WEP_RAPTOR_FLARE;
 429                 if(time > raptor.lip + autocvar_g_vehicle_raptor_flare_refire)
 430                 if(PHYS_INPUT_BUTTON_ATCK2(player))
 431                 {
 432                     .entity weaponentity = weaponentities[1];
 433                         wep2b.wr_think(wep2b, self, weaponentity, 2);
 434                         raptor.delay = time + autocvar_g_vehicle_raptor_flare_refire;
 435                         raptor.lip   = time;
 436                 }
 437         }
 438
 439         raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 440         player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 441         player.vehicle_ammo2 = (player.vehicle_reload2 == 100) ? 100 : 0;
 442
 443         if(self.bomb1.cnt < time)
 444         {
 445                 entity _missile = findchainentity(enemy, raptor);
 446                 float _incomming = 0;
 447                 while(_missile)
 448                 {
 449                         if(_missile.flags & FL_PROJECTILE)
 450                         if(MISSILE_IS_TRACKING(_missile))
 451                         if(vdist(self.origin - _missile.origin, <, 2 * autocvar_g_vehicle_raptor_flare_range))
 452                                 ++_incomming;
 453
 454                         _missile = _missile.chain;
 455                 }
 456
 457                 if(_incomming)
 458                         sound(self, CH_PAIN_SINGLE, SND_VEH_MISSILE_ALARM, VOL_BASE, ATTEN_NONE);
 459
 460                 self.bomb1.cnt = time + 1;
 461         }
 462
 463
 464         VEHICLE_UPDATE_PLAYER(player, health, raptor);
 465         VEHICLE_UPDATE_PLAYER(player, energy, raptor);
 466         if(self.vehicle_flags & VHF_HASSHIELD)
 467                 VEHICLE_UPDATE_PLAYER(player, shield, raptor);
 468
 469         PHYS_INPUT_BUTTON_ATCK(player) = PHYS_INPUT_BUTTON_ATCK2(player) = PHYS_INPUT_BUTTON_CROUCH(player) = false;
 470
 471         setself(player);
 472         return 1;
 473 }
 474
 475 float raptor_takeoff()
 476 {SELFPARAM();
 477         entity player, raptor;
 478
 479         player = self;
 480         raptor = self.vehicle;
 481         setself(raptor);
 482
 483         self.nextthink = time;
 484         CSQCMODEL_AUTOUPDATE(self);
 485         self.nextthink = 0; // will this work?
 486
 487         if(self.sound_nexttime < time)
 488         {
 489                 self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 490                 sound (self, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, VOL_VEHICLEENGINE, ATTEN_NORM);
 491         }
 492
 493         // Takeoff sequense
 494         if(raptor.frame < 25)
 495         {
 496                 raptor.frame += 25 / (autocvar_g_vehicle_raptor_takeofftime / sys_frametime);
 497                 raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 498                 self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 499                 self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 500                 PHYS_INPUT_BUTTON_ATCK(player) = PHYS_INPUT_BUTTON_ATCK2(player) = PHYS_INPUT_BUTTON_CROUCH(player) = false;
 501
 502                 setorigin(player, raptor.origin + '0 0 32');
 503         }
 504         else
 505                 player.PlayerPhysplug = raptor_frame;
 506
 507         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 508                 vehicles_regen(raptor.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 509
 510         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 511                 vehicles_regen(raptor.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 512
 513         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 514                 vehicles_regen(raptor.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 515
 516
 517         raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 518         player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 519         player.vehicle_ammo2 = (player.vehicle_reload2 == 100) ? 100 : 0;
 520
 521         VEHICLE_UPDATE_PLAYER(player, health, raptor);
 522         VEHICLE_UPDATE_PLAYER(player, energy, raptor);
 523         if(self.vehicle_flags & VHF_HASSHIELD)
 524                 VEHICLE_UPDATE_PLAYER(player, shield, raptor);
 525
 526         PHYS_INPUT_BUTTON_ATCK(player) = PHYS_INPUT_BUTTON_ATCK2(player) = PHYS_INPUT_BUTTON_CROUCH(player) = false;
 527         setself(player);
 528         return 1;
 529 }
 530
 531 void raptor_blowup()
 532 {SELFPARAM();
 533         self.deadflag   = DEAD_DEAD;
 534         self.vehicle_exit(VHEF_NORMAL);
 535         RadiusDamage (self, self.enemy, 250, 15, 250, world, world, 250, DEATH_VH_RAPT_DEATH.m_id, world);
 536
 537         self.alpha                = -1;
 538         self.movetype      = MOVETYPE_NONE;
 539         self.effects            = EF_NODRAW;
 540         self.colormod      = '0 0 0';
 541         self.avelocity    = '0 0 0';
 542         self.velocity      = '0 0 0';
 543
 544         setorigin(self, self.pos1);
 545         self.touch = func_null;
 546         self.nextthink = 0;
 547 }
 548
 549 void raptor_diethink()
 550 {SELFPARAM();
 551         if(time >= self.wait)
 552                 self.think = raptor_blowup;
 553
 554         if(random() < 0.05)
 555         {
 556                 sound (self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 557                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 558         }
 559         self.nextthink = time;
 560
 561         CSQCMODEL_AUTOUPDATE(self);
 562 }
 563
 564 // If we dont do this ever now and then, the raptors rotors
 565 // stop working, presumably due to angle overflow. cute.
 566 void raptor_rotor_anglefix()
 567 {SELFPARAM();
 568         self.gun1.angles_y = anglemods(self.gun1.angles_y);
 569         self.gun2.angles_y = anglemods(self.gun2.angles_y);
 570         self.nextthink = time + 15;
 571 }
 572
 573 float raptor_impulse(float _imp)
 574 {SELFPARAM();
 575         switch(_imp)
 576         {
 577                 case IMP_weapon_group_1.impulse:
 578                         self.vehicle.vehicle_weapon2mode = RSM_BOMB;
 579                         CSQCVehicleSetup(self, 0);
 580                         return true;
 581                 case IMP_weapon_group_2.impulse:
 582                         self.vehicle.vehicle_weapon2mode = RSM_FLARE;
 583                         CSQCVehicleSetup(self, 0);
 584                         return true;
 585
 586                 case IMP_weapon_next_byid.impulse:
 587                 case IMP_weapon_next_bypriority.impulse:
 588                 case IMP_weapon_next_bygroup.impulse:
 589                         self.vehicle.vehicle_weapon2mode += 1;
 590                         if(self.vehicle.vehicle_weapon2mode > RSM_LAST)
 591                                 self.vehicle.vehicle_weapon2mode = RSM_FIRST;
 592
 593                         CSQCVehicleSetup(self, 0);
 594                         return true;
 595                 case IMP_weapon_last.impulse:
 596                 case IMP_weapon_prev_byid.impulse:
 597                 case IMP_weapon_prev_bypriority.impulse:
 598                 case IMP_weapon_prev_bygroup.impulse:
 599                         self.vehicle.vehicle_weapon2mode -= 1;
 600                         if(self.vehicle.vehicle_weapon2mode < RSM_FIRST)
 601                                 self.vehicle.vehicle_weapon2mode = RSM_LAST;
 602
 603                         CSQCVehicleSetup(self, 0);
 604                         return true;
 605
 606                 /*
 607                 case IMP_weapon_drop.impulse: // toss gun, could be used to exit?
 608                         break;
 609                 case IMP_weapon_reload.impulse: // Manual minigun reload?
 610                         break;
 611                 */
 612         }
 613         return false;
 614 }
 615
 616 spawnfunc(vehicle_raptor)
 617 {
 618         if(!autocvar_g_vehicle_raptor) { remove(self); return; }
 619         if(!vehicle_initialize(VEH_RAPTOR, false)) { remove(self); return; }
 620 }
 621
 622 METHOD(Raptor, vr_impact, void(Raptor thisveh, entity instance))
 623 {
 624     if(autocvar_g_vehicle_raptor_bouncepain)
 625         vehicles_impact(autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 626 }
 627 METHOD(Raptor, vr_enter, void(Raptor thisveh, entity instance))
 628 {
 629     self.vehicle_weapon2mode = RSM_BOMB;
 630     self.owner.PlayerPhysplug = raptor_takeoff;
 631     self.movetype          = MOVETYPE_BOUNCEMISSILE;
 632     self.solid            = SOLID_SLIDEBOX;
 633     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 634     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 635     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 636     self.tur_head.exteriormodeltoclient = self.owner;
 637
 638     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 639     self.lip   = time;
 640
 641     if(self.owner.flagcarried)
 642        setorigin(self.owner.flagcarried, '-20 0 96');
 643
 644     CSQCVehicleSetup(self.owner, 0);
 645 }
 646 METHOD(Raptor, vr_death, void(Raptor thisveh, entity instance))
 647 {
 648     instance.health                             = 0;
 649     instance.event_damage               = func_null;
 650     instance.solid                              = SOLID_CORPSE;
 651     instance.takedamage                 = DAMAGE_NO;
 652     instance.deadflag                   = DEAD_DYING;
 653     instance.movetype                   = MOVETYPE_BOUNCE;
 654     instance.think                              = raptor_diethink;
 655     instance.nextthink                  = time;
 656     instance.wait                               = time + 5 + (random() * 5);
 657
 658     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation (instance.origin, 16), '0 0 0', 1);
 659
 660     instance.velocity_z += 600;
 661
 662     instance.avelocity = '0 0.5 1' * (random() * 400);
 663     instance.avelocity -= '0 0.5 1' * (random() * 400);
 664
 665     instance.colormod = '-0.5 -0.5 -0.5';
 666     instance.touch = raptor_blowup;
 667 }
 668 METHOD(Raptor, vr_spawn, void(Raptor thisveh, entity instance))
 669 {
 670     if(!self.gun1)
 671     {
 672         entity spinner;
 673         vector ofs;
 674
 675         //FIXME: Camera is in a bad place in HUD model.
 676         //setorigin(self.vehicle_viewport, '25 0 5');
 677
 678         self.vehicles_impulse   = raptor_impulse;
 679
 680         self.frame = 0;
 681
 682         self.bomb1 = new(raptor_bomb);
 683         self.bomb2 = new(raptor_bomb);
 684         self.gun1  = new(raptor_gun);
 685         self.gun2  = new(raptor_gun);
 686
 687         setmodel(self.bomb1, MDL_VEH_RAPTOR_CB_FOLDED);
 688         setmodel(self.bomb2, MDL_VEH_RAPTOR_CB_FOLDED);
 689         setmodel(self.gun1, MDL_VEH_RAPTOR_GUN);
 690         setmodel(self.gun2, MDL_VEH_RAPTOR_GUN);
 691         setmodel(self.tur_head, MDL_VEH_RAPTOR_TAIL);
 692
 693         setattachment(self.bomb1, self, "bombmount_left");
 694         setattachment(self.bomb2, self, "bombmount_right");
 695         setattachment(self.tur_head, self,"root");
 696
 697         // FIXMODEL Guns mounts to angled bones
 698         self.bomb1.angles = self.angles;
 699         self.angles = '0 0 0';
 700         // This messes up gun-aim, so work arround it.
 701         //setattachment(self.gun1, self, "gunmount_left");
 702         ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 703         ofs -= self.origin;
 704         setattachment(self.gun1, self, "");
 705         setorigin(self.gun1, ofs);
 706
 707         //setattachment(self.gun2, self, "gunmount_right");
 708         ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 709         ofs -= self.origin;
 710         setattachment(self.gun2, self, "");
 711         setorigin(self.gun2, ofs);
 712
 713         self.angles = self.bomb1.angles;
 714         self.bomb1.angles = '0 0 0';
 715
 716         spinner = new(raptor_spinner);
 717         spinner.owner = self;
 718         setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 719         setattachment(spinner, self, "engine_left");
 720         spinner.movetype = MOVETYPE_NOCLIP;
 721         spinner.avelocity = '0 90 0';
 722         self.bomb1.gun1 = spinner;
 723
 724         spinner = new(raptor_spinner);
 725         spinner.owner = self;
 726         setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 727         setattachment(spinner, self, "engine_right");
 728         spinner.movetype = MOVETYPE_NOCLIP;
 729         spinner.avelocity = '0 -90 0';
 730         self.bomb1.gun2 = spinner;
 731
 732         // Sigh.
 733         self.bomb1.think = raptor_rotor_anglefix;
 734         self.bomb1.nextthink = time;
 735
 736         self.mass                          = 1 ;
 737     }
 738
 739     self.frame            = 0;
 740     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 741     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 742     self.movetype          = MOVETYPE_TOSS;
 743     self.solid            = SOLID_SLIDEBOX;
 744     self.vehicle_energy = 1;
 745
 746     self.PlayerPhysplug = raptor_frame;
 747
 748     self.bomb1.gun1.avelocity_y = 90;
 749     self.bomb1.gun2.avelocity_y = -90;
 750
 751     self.delay = time;
 752
 753     self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 754     self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 755     self.damageforcescale = 0.25;
 756     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 757     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 758 }
 759 METHOD(Raptor, vr_setup, void(Raptor thisveh, entity instance))
 760 {
 761     if(autocvar_g_vehicle_raptor_shield)
 762         self.vehicle_flags |= VHF_HASSHIELD;
 763
 764     if(autocvar_g_vehicle_raptor_shield_regen)
 765         self.vehicle_flags |= VHF_SHIELDREGEN;
 766
 767     if(autocvar_g_vehicle_raptor_health_regen)
 768         self.vehicle_flags |= VHF_HEALTHREGEN;
 769
 770     if(autocvar_g_vehicle_raptor_energy_regen)
 771         self.vehicle_flags |= VHF_ENERGYREGEN;
 772
 773     self.vehicle_exit = raptor_exit;
 774     self.respawntime = autocvar_g_vehicle_raptor_respawntime;
 775     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 776     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 777     self.max_health = self.vehicle_health;
 778 }
 779
 780 #endif
 781 #ifdef CSQC
 782
 783 METHOD(Raptor, vr_hud, void(Raptor thisveh))
 784 {
 785     Vehicles_drawHUD(VEH_RAPTOR.m_icon, "vehicle_raptor_weapon1", "vehicle_raptor_weapon2",
 786                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 787                      "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 788 }
 789 METHOD(Raptor, vr_crosshair, void(Raptor thisveh))
 790 {
 791     string crosshair;
 792
 793     switch(weapon2mode)
 794     {
 795         case RSM_FLARE: crosshair = vCROSS_RAIN;  break;
 796         case RSM_BOMB:  crosshair = vCROSS_BURST; break;
 797         default:        crosshair = vCROSS_BURST;
 798     }
 799
 800     vector tmpSize = '0 0 0';
 801     if(weapon2mode != RSM_FLARE)
 802     {
 803         vector where;
 804
 805         if(!dropmark)
 806         {
 807             dropmark = spawn();
 808             dropmark.owner = self;
 809             dropmark.gravity = 1;
 810         }
 811
 812         float reload2 = STAT(VEHICLESTAT_RELOAD2) * 0.01;
 813         if(reload2 == 1)
 814         {
 815             setorigin(dropmark, pmove_org);
 816             dropmark.velocity = pmove_vel;
 817             tracetoss(dropmark, self);
 818
 819             where = project_3d_to_2d(trace_endpos);
 820
 821             setorigin(dropmark, trace_endpos);
 822             tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size;
 823
 824             if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 825             {
 826                 where.x -= tmpSize.x * 0.5;
 827                 where.y -= tmpSize.y * 0.5;
 828                 where.z = 0;
 829                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 830                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 831             }
 832             dropmark.cnt = time + 5;
 833         }
 834         else
 835         {
 836             if(dropmark.cnt > time)
 837             {
 838                 where = project_3d_to_2d(dropmark.origin);
 839                 tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size * 1.25;
 840
 841                 if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 842                 {
 843                     where.x -= tmpSize.x * 0.5;
 844                     where.y -= tmpSize.y * 0.5;
 845                     where.z = 0;
 846                     drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 847                     drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 848                 }
 849             }
 850         }
 851     }
 852
 853     Vehicles_drawCrosshair(crosshair);
 854 }
 855 METHOD(Raptor, vr_setup, void(Raptor thisveh, entity instance))
 856 {
 857     AuxiliaryXhair[1].axh_image = vCROSS_LOCK;
 858 }
 859
 860 #endif
 861 #endif